Adding metadata

24 files changed, 536 insertions, 4 deletions

diff --git a/dev-python/Levenshtein/Levenshtein-0.21.0.ebuild b/dev-python/Levenshtein/Levenshtein-0.21.0.ebuild
new file mode 100644
index 000000000000..d5e9e1d65a5f
--- /dev/null
+++ b/dev-python/Levenshtein/Levenshtein-0.21.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Functions for fast computation of Levenshtein distance, and edit operations"
+HOMEPAGE="
+	https://pypi.org/project/Levenshtein/
+	https://github.com/maxbachmann/Levenshtein/
+"
+SRC_URI="
+	https://github.com/maxbachmann/Levenshtein/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+DEPEND="
+	>=dev-cpp/rapidfuzz-cpp-1.7.0
+"
+RDEPEND="
+	<dev-python/rapidfuzz-4.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.13.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/Levenshtein/Manifest b/dev-python/Levenshtein/Manifest
index 7ff5f981e527..0e626911f513 100644
--- a/dev-python/Levenshtein/Manifest
+++ b/dev-python/Levenshtein/Manifest
@@ -1,2 +1,3 @@
 DIST Levenshtein-0.20.9.gh.tar.gz 36617 BLAKE2B 8e995f1c1648c81bea20844f7afc3c5dddd7dc31e5b6fc99a96930130c7f85bb32c4c4c85b319149d8511f6591ede96098038ea1b502a3e33a42ca3d21db4e2a SHA512 1d5dccd33ae8bd19b234861435212c7a57ba330a5f76a45c9e5b8ac3e401bc3d5eb3c72aea20e66bf0ebaaa6b760131dfef07fb5a2cf4d7191b595e1d962d93c
+DIST Levenshtein-0.21.0.gh.tar.gz 36616 BLAKE2B 8408ba8231a8ff3f6bf9e6cc7ea763061ca1c826236d74877213caef0ce736695865dc3c02565cce960b794d07f96f6413ca144565d6693debf90a1b5718524b SHA512 bb1cf70497e89db5b427eb4ac79708d205fc9edfc9588d30c63ef6e3e77b9369c8892edc31c32cb135d54947e8eedb770d06a7d5c6f8743d44378d7d1a12d459
 DIST python-Levenshtein-0.12.2.tar.gz 50502 BLAKE2B d8992d30639e36aac1b85fada8f5273ed867aa3019208ffeb9972e999dad783d4ee16e1f6988c9306eb80f622b61fcf3a0a937b380c7a5acf50223268ed8de1d SHA512 97eac9d19121758af7620ad3963846e48434ceabb5376a83f28452015adf1a620620bfb53edb1c4f60b0fc8ec2b0faf35a105d7e2a0fc5df7a45fce81ba0dcdb
diff --git a/dev-python/aws-sam-translator/Manifest b/dev-python/aws-sam-translator/Manifest
index 9541624dae5d..e403dabbe987 100644
--- a/dev-python/aws-sam-translator/Manifest
+++ b/dev-python/aws-sam-translator/Manifest
@@ -1,3 +1,4 @@
 DIST serverless-application-model-1.62.0.gh.tar.gz 5177544 BLAKE2B ad0fdca32821e9b5dab86d03e65ad1a458493ecba0e75f6b2dc8b9978a6085ae5269496e231a2f09cd228e6bd2a66b3803953d2ca5aa7c265fa1019305aa1a9c SHA512 42f1d3ff352a02ab73f5a16cfeb800a80852986b09f71d9468b23c22b8dafff3a20e8ac92956020280884e4318bd80369b5b04ea6e9f0a28067dd792f1623747
 DIST serverless-application-model-1.63.0.gh.tar.gz 5213667 BLAKE2B b75315d1c28789e9f0b8aa4774292ff2531806c1d59a8c16ab683fee439d188025c9cc62c2de037f2d947ad3b7eaa8bb4fbe8a5507ef1a4f3619f758cdf2eadc SHA512 eb6dc0f545550f726b59a2ea1994f8dfcc8eaf7a1fbca6ab12bfbe891813b208d869e25c0b320411aa6476dcf8c86fb19db9e13ddf0419d90d3c3403bd57485c
 DIST serverless-application-model-1.64.0.gh.tar.gz 5231257 BLAKE2B 53eeb37d69ae0f133b936eb8bb20005ecdad5d71956becd61a9e9080be9bead1bebe98b89d0f67604ac74731b2ac7061f74fae67f0c8e12bf10f7a9dfc40eb3e SHA512 9584657026ca7c260fb9851e8669b19c896a88a4455c6e50e734c1d9b375b69d5cf85b64f960fa0987e8a34823343de3e8c8080413da07fcfb69dc491e72c761
+DIST serverless-application-model-1.65.0.gh.tar.gz 5310251 BLAKE2B 41d4b2a8902dc1bbd2b01f534475005b2c288d33d5bc76049af8b034d428f40b063de71830e4ea3552ab00b7b437e197cf561982d28d74f9762b175a956d587b SHA512 d4a7475f955145e9d141b1d3795bef5e1eb1c330e07b01e5f0e6207f33b73622dcce4ab9bbf10413513321f64e09d59f61aaf01d9fe9f0760b9b31d10c6e3d68
diff --git a/dev-python/aws-sam-translator/aws-sam-translator-1.65.0.ebuild b/dev-python/aws-sam-translator/aws-sam-translator-1.65.0.ebuild
new file mode 100644
index 000000000000..5a83e871d7a8
--- /dev/null
+++ b/dev-python/aws-sam-translator/aws-sam-translator-1.65.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+MY_P=serverless-application-model-${PV}
+DESCRIPTION="A library that transform SAM templates into AWS CloudFormation templates"
+HOMEPAGE="
+	https://github.com/aws/serverless-application-model/
+	https://pypi.org/project/aws-sam-translator/
+"
+SRC_URI="
+	https://github.com/aws/serverless-application-model/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/boto3-2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.19.5[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2[${PYTHON_USEDEP}]
+	<dev-python/pydantic-2[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-1.8[${PYTHON_USEDEP}]
+	<dev-python/typing-extensions-5[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.4[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# so much noise...
+	sed -i -e '/log_cli/d' pytest.ini || die
+
+	# deps are installed by ebuild, don't try to reinstall them via pip
+	truncate --size=0 requirements/*.txt || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x AWS_DEFAULT_REGION=us-east-1
+	epytest -o addopts=
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 94a255404b51..b4d252ecb006 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -4,3 +4,4 @@ DIST boto3-1.26.112.gh.tar.gz 636498 BLAKE2B 2768bdc1fec35eca4a3079bf12933fc2832
 DIST boto3-1.26.113.gh.tar.gz 636722 BLAKE2B 0b5c3819c004ba425294208f114b4b11713730a18e45cf274b8bfe1f762f59e2c404e0a4ccbbec16be934931e7b37c2bd462b7df7d6d47275b1de26300de216e SHA512 bafda63eddb19b97538224e9c12bc3178a0999cc4d2547cb7ec7335f28a7fe3875130573d4fab2fe21000cc1e3bc4e3a7a5ae99bc8f0e9dc7e2b40ad6fb5a2e0
 DIST boto3-1.26.114.gh.tar.gz 637000 BLAKE2B 06f74ac214f4c2161ebe464e1c8fc42c74cb4429110c8ce979db3962fde5240c62ac94b4b9ca002fff89a36659a8830265ac693bd9522082b8cae21108e16cf9 SHA512 324ea177c8ee98a0935d1935f08b31f1640eedf8a7dd19f2bc958f6c1c2fb9deea29f0482b1f4c903d70860a93274dd0d70eafe0564116361daf5e7df51abd26
 DIST boto3-1.26.115.gh.tar.gz 637877 BLAKE2B 861cf3a197002bcfac3f1ca3428bd01f1a8e103462e0de83ed33bb7575de0056f4222195c70dcd0e40dcf3744467e8c017bfe361e589eaf641fec76d6d3eea94 SHA512 337e90d91bb9efcff89b410d5222dead7ce1d0f35257bebe0309cd5fa657facd1a0352bee0ea23d3b94ad852da03a182b7dabf4c2d854390fd227bd58fabc6d3
+DIST boto3-1.26.116.gh.tar.gz 638605 BLAKE2B 946634bfaa4f0b4bd3689a11d8dc3e982dd8166c2b4409335bd1be58c356bbcbf2e5d22c7f319d29a549c69d4a14a3d2afb369c345c643cfa369fb3c9843e04f SHA512 2434fbf7ef2434365863ae8c67c16209a6537afb21697e24efd466146f6fe03566bec220943392139231d55aa570ba3d696a086fc087e4f9d1908da96794c77a
diff --git a/dev-python/boto3/boto3-1.26.116.ebuild b/dev-python/boto3/boto3-1.26.116.ebuild
new file mode 100644
index 000000000000..2a4a7643203e
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.116.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index d5eb677f84a1..6fa721da61cc 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -4,3 +4,4 @@ DIST botocore-1.29.112.gh.tar.gz 11380151 BLAKE2B 0392abe4e6be29a9e3eae1e693d7cc
 DIST botocore-1.29.113.gh.tar.gz 11386284 BLAKE2B a3611f356f25080f00f675b20a8b49952bcf1e464b9a114bf37392ebdf4573ac1e9eb6373c61dbf87f8101e055f4f6600f7825f45b00c5723c1528d74865dd6c SHA512 8a16fdde7099ae75a3587ee0c0108c12a6c5c27dbbbfc2d98eb3ccd4c66b45f0389a722f1b10ac3f3cc69ea7ba9135cc0604e35126cc2691a26f4a6173d5258a
 DIST botocore-1.29.114.gh.tar.gz 11388772 BLAKE2B 6c9ce892cccf2f85ba4bcd49b31309528016313bb699efbca3b00d3cf3797de5e1b35bd71a3b5bd6d471e9c411ad7750ebd25c03571aa18c34cd42bc2f47bc19 SHA512 6633a2aaf2865a89976ba4097fa64cee4167a9144d4eadc7d9be711e65735bab08d2c03c18ae52c4901fea47265301cb95c91306b261fb48b4119bec66cde376
 DIST botocore-1.29.115.gh.tar.gz 11394187 BLAKE2B 621be4a22b7f06d520bcd630ed6e1a8721d11d5c7822f56f54907177d0773b69247b627a42cfbb1b8e053f54ea16f7238acc0d485379c1e071b6e917ea625596 SHA512 525d8f219cad541c4cc125c2d5eeb7595fba6192bda23e7bcc02a65e4ec413756ae3d8ab5bcb3185b5c837bc7214c22146e52716ff010cc396bc8d32cd98b956
+DIST botocore-1.29.116.gh.tar.gz 11399292 BLAKE2B 47a53b2612804911465f6f56a78f79e389ac7bd2e29e3f45c60f25ec1e700df8956dac034d058974bb453623d5ed5edc416d07b45427cb1ef3c584b5ec4b97f3 SHA512 81636c104a0c4b4f04ebeb066171be206929d5eaf2c40e6f383e701a9dc917f84d4b2f9ef2d7a26b278960af7561316d289be4150eede9a56be20dbf606aa57c
diff --git a/dev-python/botocore/botocore-1.29.116.ebuild b/dev-python/botocore/botocore-1.29.116.ebuild
new file mode 100644
index 000000000000..491b6bbc21f2
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.116.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/cfn-lint/Manifest b/dev-python/cfn-lint/Manifest
index fbf0dae66bc9..5fca0a1ef0ad 100644
--- a/dev-python/cfn-lint/Manifest
+++ b/dev-python/cfn-lint/Manifest
@@ -4,3 +4,4 @@ DIST cfn-lint-0.76.1.gh.tar.gz 3631194 BLAKE2B 95d395369fc230fe4e6c5d5e2a0e4bf24
 DIST cfn-lint-0.76.2.tar.gz 3402554 BLAKE2B e5f9405d2852e3b81140a24d94c90a3bf8c919eb6823280a0a887c6acc56ec71d991cbc76532cc49d1189a8f64750ba3e9db02fb3b46b27a28ec3468f4dd268e SHA512 96351ade16308be18baace1351e263a179eacc0b3635e9baa959baadaebb6a08825f6cb9cd83cb83b8635785c7f54405bfcf00f85d6d95d101d3298919cd1ea7
 DIST cfn-lint-0.77.0.tar.gz 3474124 BLAKE2B 5715618f6b44a7a88ef3af8d21d038fa4ce4707973e64eb9712ff524cd5276e71802ad4b9a55580ac469b6474c7d48a8ccee04660bcaf7934df7a23cab1e5a9a SHA512 6509197ef29d8bcbfc416df0a63f89736f704b147bbeb489586b6a06e1818f1d91e59429c73a9e9e23dadb20325a3c79d0b8e1b4637cd0e131f9673422e36734
 DIST cfn-lint-0.77.1.tar.gz 3483399 BLAKE2B 6eaaba9cf70044c673164bce3a062b00ae7703b091e2c0e8d5065e815278fdb88d75f2592695cd1be1612421f95c806f6eaf3be9f4725abec0cf5e39070ff175 SHA512 0d18e7bc19d5562c88194f834267fa6d2fd8125754399ef281598beb68752e7935a653fbe3a0573f4887cb7a76c41b49ad8e268d390db59dd79794cde4939f31
+DIST cfn-lint-0.77.2.tar.gz 3483728 BLAKE2B f7c3cb5be3fbc81f10515bec145030c21c9a754ecbb887267ee85ea9fecd41e57be8572d30f204a54c3e22191c58d2c7d7112115e2c6cd0a23490c4c7633d270 SHA512 8e901564b34e601e62a276b8f8a4b5687de651aafa6da6dc295e846b04e703bda24e6a72b71797c82d2c2f4c93978da92a08999cb73be6a48c9ffd4a40ccb0e6
diff --git a/dev-python/cfn-lint/cfn-lint-0.77.2.ebuild b/dev-python/cfn-lint/cfn-lint-0.77.2.ebuild
new file mode 100644
index 000000000000..2b6753f1c840
--- /dev/null
+++ b/dev-python/cfn-lint/cfn-lint-0.77.2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="CloudFormation Linter"
+HOMEPAGE="
+	https://github.com/aws-cloudformation/cfn-lint/
+	https://pypi.org/project/cfn-lint/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-sam-translator-1.64.0[${PYTHON_USEDEP}]
+	dev-python/jsonpatch[${PYTHON_USEDEP}]
+	>=dev-python/jschema_to_python-1.2.3[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.0[${PYTHON_USEDEP}]
+	dev-python/junit-xml[${PYTHON_USEDEP}]
+	<dev-python/networkx-4[${PYTHON_USEDEP}]
+	>dev-python/pyyaml-5.4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.15.0[${PYTHON_USEDEP}]
+	dev-python/regex[${PYTHON_USEDEP}]
+	>=dev-python/sarif_om-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/sympy-1.0.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin the deps
+	sed -e 's:~=[0-9.]*::' -i setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		test/unit/module/test_template.py::TestTemplate::test_build_graph
+		# requires git repo
+		test/unit/module/maintenance/test_update_documentation.py::TestUpdateDocumentation::test_update_docs
+		# Internet
+		test/unit/module/formatters/test_formatters.py::TestFormatters::test_sarif_formatter
+		test/unit/module/maintenance/test_update_resource_specs.py::TestUpdateResourceSpecs::test_update_resource_specs_python_3
+		# TODO: it looks as if AWS_DEFAULT_REGION didn't work
+		test/unit/module/core/test_run_cli.py::TestCli::test_bad_config
+		test/unit/module/core/test_run_cli.py::TestCli::test_override_parameters
+		test/unit/module/core/test_run_cli.py::TestCli::test_positional_template_parameters
+		test/unit/module/core/test_run_cli.py::TestCli::test_template_config
+	)
+
+	# from tox.ini
+	local -x AWS_DEFAULT_REGION=us-east-1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/fake-useragent/fake-useragent-1.1.2.ebuild b/dev-python/fake-useragent/fake-useragent-1.1.2.ebuild
index 9895864f9221..88bdb312af1c 100644
--- a/dev-python/fake-useragent/fake-useragent-1.1.2.ebuild
+++ b/dev-python/fake-useragent/fake-useragent-1.1.2.ebuild
@@ -20,7 +20,7 @@ KEYWORDS="~amd64"
 
 RDEPEND="
 	$(python_gen_cond_dep \
-		'dev-python/importlib_resources[${PYTHON_USEDEP}]' python3_9
+		'dev-python/importlib-resources[${PYTHON_USEDEP}]' python3_9
 	)
 "
 
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index ecddc684586a..59489898d296 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -5,3 +5,4 @@ DIST hypothesis-6.70.1.gh.tar.gz 9351685 BLAKE2B 99488f4caae4da403ebe28c2c18829d
 DIST hypothesis-6.70.2.gh.tar.gz 9351849 BLAKE2B 074003592741cd89ae9ae44b3857daa3f5d1c8cbb0ab3513f3930b27fcc4e27417994c4240fbbba4649cb04716820db0e9c4f4ac745c194535a81b8a6197f7c3 SHA512 20f812ca8e005877893eacde1bac796495f8697ecbbd6da5f807a9ce6d7e310682030323a8b7bb3e646040253968d2f15cb6fcc858f47be631ef62af4924ac78
 DIST hypothesis-6.71.0.gh.tar.gz 9357031 BLAKE2B e4a83a94bb6971c3ecba4cc69655f9da23a83ab48332a7a748ca7364d9e549a671bf466e32f6e65447f809a9917fc8fd2548dd26764173ea5849a4df3e027b54 SHA512 dea1d5ec1b753649345edd784183f171531adb583e33d0e5d12b14554169fa054e05f4c16135171c708c208b42968082b3ce79cc0441efccf1eff6da37c59f97
 DIST hypothesis-6.72.0.gh.tar.gz 9357320 BLAKE2B a688d3bfa90d4b335c022ed823e3ab3c9bb7b6e4404e62259e65faf7d2867d6cb8379b14a8328294c325506278c6523b9a14f6798110d67c9b636a89720a3ab9 SHA512 7d5cdf91114a34267edcca10295ee84005f2799ed58e7125c584fcc49171e60383a80c7a0040e41d24b3225113cb354966d40f61c94a28bcdbd596582577372b
+DIST hypothesis-6.72.1.gh.tar.gz 9358351 BLAKE2B fbb760194c944cc939e9a9b83a461be22f9e5081d865f0dfa3834375d464714178dca64b9e1993fa4b0855e90f6e133a81d22699acc91560f60f137e8589798c SHA512 1a9d4b103f714e27ec5e33efbdfda0cc3febbe77caf6f605db7fb3b2df857712682a3cce80e75f45f9cd88b1715789d7fc2c5a7d50edbf66a699f5381e2671e5
diff --git a/dev-python/hypothesis/hypothesis-6.71.0.ebuild b/dev-python/hypothesis/hypothesis-6.71.0.ebuild
index 651999ecf666..3161f387e515 100644
--- a/dev-python/hypothesis/hypothesis-6.71.0.ebuild
+++ b/dev-python/hypothesis/hypothesis-6.71.0.ebuild
@@ -25,7 +25,7 @@ S="${WORKDIR}/${MY_P}/hypothesis-python"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 IUSE="cli"
 
 RDEPEND="
diff --git a/dev-python/hypothesis/hypothesis-6.72.1.ebuild b/dev-python/hypothesis/hypothesis-6.72.1.ebuild
new file mode 100644
index 000000000000..891854a7fd81
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.72.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{9..11} )
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+	epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/pyasn1-modules/Manifest b/dev-python/pyasn1-modules/Manifest
index c9a9bae71388..649eaa476534 100644
--- a/dev-python/pyasn1-modules/Manifest
+++ b/dev-python/pyasn1-modules/Manifest
@@ -1 +1,2 @@
 DIST pyasn1-modules-0.2.8.tar.gz 242864 BLAKE2B 22b6cc27d45d19d8e7f5b12c8aeff1fa379bd567fda6b1dc0fafd00c0f4367d32f21cd48cf3cba140f2f11ba7d258140e8014c8420300451ab1acff475d28da7 SHA512 fdfcaa065deffdd732deaa1fa30dec2fc4a90ffe15bd12de40636ce0212f447611096d2f4e652ed786b5c47544439e6a93721fabe121f3320f13965692a1ca5b
+DIST pyasn1_modules-0.3.0.tar.gz 307901 BLAKE2B bfcfd1442b3e9cd542d4f47160b54308ff5ab0373394f55007a1a3963342b8217bd89b5b71dba9e4a69071e805610c3060a28df40249c9b8a1898f941d40e35a SHA512 fedcf95e0452e133fc0735a1be29fb5e7df563243203463c66b85d9af6194a550c78a96fec2d915be1aa6b98428f51b6ed4feb7ed3838c515d044fbafeb2cb46
diff --git a/dev-python/pyasn1-modules/pyasn1-modules-0.3.0.ebuild b/dev-python/pyasn1-modules/pyasn1-modules-0.3.0.ebuild
new file mode 100644
index 000000000000..c07fba634b56
--- /dev/null
+++ b/dev-python/pyasn1-modules/pyasn1-modules-0.3.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="pyasn1 modules"
+HOMEPAGE="
+	https://pypi.org/project/pyasn1-modules/
+	https://github.com/etingof/pyasn1-modules/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+RDEPEND="
+	<dev-python/pyasn1-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.4.6[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	insinto /usr/share/${P}
+	doins -r tools
+}
diff --git a/dev-python/pyasn1/Manifest b/dev-python/pyasn1/Manifest
index 491c89541136..ab867c625aa7 100644
--- a/dev-python/pyasn1/Manifest
+++ b/dev-python/pyasn1/Manifest
@@ -1 +1,2 @@
 DIST pyasn1-0.4.8.tar.gz 146820 BLAKE2B 5c00b47c2014e599d1aa2e14c3004b3688786c7afd160c85709d5a0f324166abb1d29ebbd9f3e13100166e7176710e4dc6e1b8fcf80db5f5bdaa202912f8a023 SHA512 e64e70b325c8067f87ace7c0673149e82fe564aa4b0fa146d29b43cb588ecd6e81b1b82803b8cfa7a17d3d0489b6d88b4af5afb3aa0052bf92e8a1769fe8f7b0
+DIST pyasn1-0.5.0.tar.gz 145117 BLAKE2B dbbec0bebcfe11b8de983716fedf1bf28e6bcf7d5f89e3dcba929884347cc7cd3a8ef8b5ec44bbc799a7bae3de39c90cf5e48111384de571dc2034a79c3bb52b SHA512 763690184ce891555564d76902042791865815e59e1325100fca692140110e5e182ef3da84ffdf96b1876edeb2757bbb09c06d26e752a8110760dafbf9e3ca00
diff --git a/dev-python/pyasn1/pyasn1-0.5.0.ebuild b/dev-python/pyasn1/pyasn1-0.5.0.ebuild
new file mode 100644
index 000000000000..64011b6f4dd8
--- /dev/null
+++ b/dev-python/pyasn1/pyasn1-0.5.0.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="ASN.1 library for Python"
+HOMEPAGE="
+	https://pypi.org/project/pyasn1/
+	https://github.com/etingof/pyasn1/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-macos"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx "docs/source"
diff --git a/dev-python/python-email-validator/Manifest b/dev-python/python-email-validator/Manifest
index 188f4322e606..7fb2462944b0 100644
--- a/dev-python/python-email-validator/Manifest
+++ b/dev-python/python-email-validator/Manifest
@@ -1,3 +1,4 @@
 DIST email_validator-2.0.0.post1.tar.gz 45136 BLAKE2B d800462f55ee0693917a5348107bd68af2a9c0b6e1a3ccbf28aa22716bbf6da2998bbf4b16352e719c13761b895a85566911bfd4422a516d77214a729da41aca SHA512 0e72d88dea00ade9a8727a4d3ff9a239f581afc14bf7c7a22a582d69e70c7653371c035451493b89fc1a49c70aab8cdfe6159285ea5e8976e645199319004029
+DIST email_validator-2.0.0.post2.tar.gz 45253 BLAKE2B b213ebab2a10acf6c2ab95d382fa78ef92f41ff85ce25c1cfa5a65403e728fd05c66df3dccbaec77eea469d0665701ad5d8047c31e69b57ed8e6fe52f3a1f9c5 SHA512 8c4abc955d909ef05ca89d6c6931bce06de199c33c5f8d0744d44ff00ee69c1841f295882af3da03963cc90ef031da46cdaef90249f73e0c7b47f19dfb816b62
 DIST python-email-validator-1.3.1.gh.tar.gz 28691 BLAKE2B eb69028066e969a935117f51a32d75595468797a82608bcb7f6ebcbebada01aac29e3e223efc849dc519d85897a375cdc584760f3cb5a431e2c39aa566c20514 SHA512 7806ef35c07cf0cfef3d8c6c7fe6dd3cb58da091a134b57d879a2cfcdf6425f8729ab8b03194135749ae47b369da47434c1d130432cfaa8eeaf5d07149c15dc2
 DIST python-email-validator-2.0.0.gh.tar.gz 39007 BLAKE2B 319fa94979fdb6b701c1c8f754f2915e02a53de7ee6f06a5409980b1e4dedca75d08cd24e4f5ee35e7803c7ff4dbb03c1e75645dd7e0443ccaa2b26b6035648a SHA512 6448c55dea3d43d1d457f4b3f24360aaaa6e4ea8f81db891e94d2ff685ae1d8bc1023d4a6329fc495ff6069fc1a6861185e66eada9d2ed6546e6c6b8716df802
diff --git a/dev-python/python-email-validator/python-email-validator-2.0.0_p2.ebuild b/dev-python/python-email-validator/python-email-validator-2.0.0_p2.ebuild
new file mode 100644
index 000000000000..25784d4729f2
--- /dev/null
+++ b/dev-python/python-email-validator/python-email-validator-2.0.0_p2.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=email-validator
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A robust email syntax and deliverability validation library"
+HOMEPAGE="
+	https://github.com/JoshData/python-email-validator/
+	https://pypi.org/project/email-validator/
+"
+
+LICENSE="CC0-1.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/idna-2.8[${PYTHON_USEDEP}]
+	>=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -m "not network"
+}
diff --git a/dev-python/python-engineio/Manifest b/dev-python/python-engineio/Manifest
index 745fb1d04195..0b773e63d3b5 100644
--- a/dev-python/python-engineio/Manifest
+++ b/dev-python/python-engineio/Manifest
@@ -1 +1,2 @@
 DIST python-engineio-4.4.0.gh.tar.gz 309353 BLAKE2B 4cf40802fddcce2e53e205bdbe73bdf0ec822e15581fe4a9939b8d05c3eb6ba82a99d089d4708169b197aa79e5b5f14001ff86f72025fc6d96c99ed6d73fe620 SHA512 b7995aaf2583ec58ac87f048608653ade3846dd103616ee90b3dc12cc7e27c7d37959cd3e1ebf6e138395ff6fad8cd011407b6660258715e513bf72c8a3e1f6f
+DIST python-engineio-4.4.1.gh.tar.gz 309475 BLAKE2B 4ae5dd9887f4d3a70d4983d2a0f0de29b1a54d30961bfc430b8850ff4af73fa1cd9abad6caeb8248a44def42b02e26ecb0632dd9b4d57e2a7f44b33762659304 SHA512 a903ae4f5a4679f6d46fda09901b637ef8dcf2896ece8781460d27aab7c8da606e16a89ac5dea94c156d8196a7e931626b2310b41ddc61d4241b5e004ad2ca64
diff --git a/dev-python/python-engineio/python-engineio-4.4.1.ebuild b/dev-python/python-engineio/python-engineio-4.4.1.ebuild
new file mode 100644
index 000000000000..f8623866bbb6
--- /dev/null
+++ b/dev-python/python-engineio/python-engineio-4.4.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python implementation of the Engine.IO realtime server"
+HOMEPAGE="
+	https://python-engineio.readthedocs.io/
+	https://github.com/miguelgrinberg/python-engineio/
+	https://pypi.org/project/python-engineio/"
+SRC_URI="
+	https://github.com/miguelgrinberg/python-engineio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+# Can use eventlet, werkzeug, or gevent, but no tests for werkzeug
+BDEPEND="
+	test? (
+		dev-python/tornado[${PYTHON_USEDEP}]
+		dev-python/websockets[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+EPYTEST_IGNORE=(
+	# eventlet is masked for removal
+	tests/common/test_async_eventlet.py
+)
+
+EPYTEST_DESELECT=(
+	# also eventlet
+	tests/common/test_server.py::TestServer::test_async_mode_eventlet
+	tests/common/test_server.py::TestServer::test_connect
+	tests/common/test_server.py::TestServer::test_service_task_started
+	tests/common/test_server.py::TestServer::test_upgrades
+)
diff --git a/dev-python/sphinxcontrib-zopeext/sphinxcontrib-zopeext-0.4.2.ebuild b/dev-python/sphinxcontrib-zopeext/sphinxcontrib-zopeext-0.4.2.ebuild
index 11d36263fe8d..94f12eaa8ea3 100644
--- a/dev-python/sphinxcontrib-zopeext/sphinxcontrib-zopeext-0.4.2.ebuild
+++ b/dev-python/sphinxcontrib-zopeext/sphinxcontrib-zopeext-0.4.2.ebuild
@@ -16,7 +16,7 @@ SLOT="0"
 KEYWORDS="~amd64"
 
 RDEPEND="
-	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	dev-python/importlib-metadata[${PYTHON_USEDEP}]
 	dev-python/zope-interface[${PYTHON_USEDEP}]
 "
 
diff --git a/dev-python/wxpython/wxpython-4.2.0.ebuild b/dev-python/wxpython/wxpython-4.2.0.ebuild
index d940bd118be3..183ccb652f69 100644
--- a/dev-python/wxpython/wxpython-4.2.0.ebuild
+++ b/dev-python/wxpython/wxpython-4.2.0.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="https://www.wxpython.org/"
 
 LICENSE="wxWinLL-3"
 SLOT="4.0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
 IUSE="test webkit"
 # Tests broken: #726812, #722716
 # Nearly there as of 4.2.0 but still quite flaky (inconsistent set of failures)