Adding metadata

28 files changed, 925 insertions, 8 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 831c79451ba3..c0c1ee9f2f87 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -10,3 +10,4 @@ DIST boto3-1.42.73.gh.tar.gz 1101832 BLAKE2B 2f187945feb18a6d8a4576f0f5766235095
 DIST boto3-1.42.78.gh.tar.gz 1104761 BLAKE2B 989dc99fbe05c2e5fa28bda83897a411dbf929e1e5df3c78e0a52bbb5df61a5331aeceb48c6ba8e3ae7a6d8e0587d4a1f6094be7936bf107d75c15d0291d7701 SHA512 4a28b614b39591cca6f4e7f0c00612dffd701f39d6128d81b95e4022f5da833434897b6428dda50bb4280a715eaca289f863785f599e8149a7115ecc12cd9d36
 DIST boto3-1.42.79.gh.tar.gz 1106670 BLAKE2B 8d923b7100c7f7ca13fa901bd44eeb0f92708eb9037b9de24dc50ec86d1fa07b216a74cf2cd171a1665e09031b77c6041329ec91d79ebb248747a47835ac3c86 SHA512 9efca961e98bc8a2ec48f75add7986a72f6127f0f04d38975ee5714d4df5655a5e63aefff25233c363cfc9509155d06ed7d9f85aecbf08ff82178dc41bdb896f
 DIST boto3-1.42.80.gh.tar.gz 1109800 BLAKE2B e06367dd5352ce86e8728f1fec3f532c5454db1e4e56c29acbd89836aee9fc9f9334526281c8f3fb556f37c14e4fca1b3ed0f9b0f52681a0f057df17aec7dfa2 SHA512 42a68bc87c467e486e46a6a5d8f245e30c26bc1e6adce1eb4e80bc0a5f5eee8a8dadc480893e57de81e754962428713e5463c4584a303460098ce8cd379b91d6
+DIST boto3-1.42.81.gh.tar.gz 1111714 BLAKE2B e1fcbd03038945e05019f78c25fd75ae864089c56267109abb4ef4a7d3d26ef526aadc193fae30b4c3bb62654b748e3821c08a4a63b1af9f204e37ec0e11a7ea SHA512 8e9396ce48c825bbac269296eaf008c0cce3a1db962bc4200d88527caa8dcd37629a30a68ea03c7f69a349e74440114dbd7066e7e8142bb95b8234dc684ecc1a
diff --git a/dev-python/boto3/boto3-1.42.81.ebuild b/dev-python/boto3/boto3-1.42.81.ebuild
new file mode 100644
index 000000000000..6e5f06a012ad
--- /dev/null
+++ b/dev-python/boto3/boto3-1.42.81.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.16.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index a8c6a424da56..e5db7607d560 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -10,3 +10,4 @@ DIST botocore-1.42.73.gh.tar.gz 15909831 BLAKE2B a7032e431644adda779bcdc5241af66
 DIST botocore-1.42.78.gh.tar.gz 15931724 BLAKE2B d0732ac14bb37ce0fd326b2edcdf06665306c7c06c3004f78aa5405ea8c2335eb1267e31c9cfe803ca6e551617c14177ea3319bcb2e1eafe4acd35e7f5e5b610 SHA512 18ad9458ee5ede54ab43eebc2d235371c84fc5fe8cb21a067a54612a4cfd14fedca54ae45f40516ec5a91aa4049837f94fa3fced2ea0f4deb8089f78a13f59a2
 DIST botocore-1.42.79.gh.tar.gz 15971759 BLAKE2B 8955138791758156fcb2466a9349fe6484acf1154ef94cdfa1a219d2f45074ea412d361cea1679be36105e258b7a9bc30c3a9ae2d8120670cf95b82c9e053cb9 SHA512 8c06fdb9eacdcb41206004ed9c4c5eafb4e7bc7f0863e3a20917c5e57b0564ed5d997bef4ca6c1aa549a1b251260b77d6ab835a31750176944024bd9ba731718
 DIST botocore-1.42.80.gh.tar.gz 16017374 BLAKE2B 9dcde4cff744a4750697fe29a7ff77d1499ebe0fd84d69eedebe48bfa77d40f471b9cd453ba10ee32c463e209e370bc3b09bdcb2c833f80844e2865da3e906b1 SHA512 3c176c11b59d650ca8aca9fb3a8ad04b34c7f237285f242cc7aa44dffb4240551e938f312ee691edb1cfae6da4230172259a6209a67eea2885cee65beb516c65
+DIST botocore-1.42.81.gh.tar.gz 16039038 BLAKE2B d19b15cd1d86f22fce8e5d37700563d43f9a741a7112c50d5a81ead2250809a57d9d6c3d4a1949bae4c3a256cd0d29227ffa4b934442a6cbb022468060e4f49d SHA512 f2355d6586e54c80c7c242fe9a8867acba91c778e963a493720196dd1fae25cb87c6a5cba54f8b7a1a0311b13981dddae599af197a201eb6e235bb1b881e9c94
diff --git a/dev-python/botocore/botocore-1.42.81.ebuild b/dev-python/botocore/botocore-1.42.81.ebuild
new file mode 100644
index 000000000000..f6ce0d9ed8d5
--- /dev/null
+++ b/dev-python/botocore/botocore-1.42.81.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/dbus-fast/Manifest b/dev-python/dbus-fast/Manifest
index cbc597464cbe..4cc5aed70462 100644
--- a/dev-python/dbus-fast/Manifest
+++ b/dev-python/dbus-fast/Manifest
@@ -1,2 +1,3 @@
 DIST dbus-fast-3.1.2.gh.tar.gz 205618 BLAKE2B 83d92eaa8477849238d5fd814a73c223a43adfcfa8752ac287c8f6cc9116e804a3300fc25ebb9cccbbb51c0db3c1495328822666ff1fdf993ac87758b7be21ad SHA512 d897a2612dfedb07005f212e48c6eaf7271b58145d690a0fbe66d1a39085739ccf626c6155aebae9f96ce9e9136fc496d6d3ba806813acc1f3023b1e4e924897
 DIST dbus-fast-4.0.0.gh.tar.gz 208875 BLAKE2B 8382f28e46e0600af414329d017606a5d4d47ad6d2cc146ec95e3276bdac869a92b1727e0bc4ab4068b74b71549efd01174de183d5417f2790282b51947d10b7 SHA512 768b054f8475658e7bab3d88c573f916e38f81c2f17c7f39b46adac592377b5d5238f653068b2a594e587bd4d2f2295dd797df08901c9ed30ca33027f5761088
+DIST dbus-fast-4.0.3.gh.tar.gz 208955 BLAKE2B 5ab575387468940da13c526ddf1d36ea2802745d50e0828a0632ab6dcd600f28d3598734bfdfc158e8e2286a58ea22c37998c562d8bcb095d4a44522618dbe08 SHA512 d117ce93c991f8a4e46581800fcce7b6863d8ed2a170ebfbff07dc00a936a4d2a4e46c1dd9dab879f234fef4392f9cfddf631ac82cd76748235205c634bf9d22
diff --git a/dev-python/dbus-fast/dbus-fast-4.0.3.ebuild b/dev-python/dbus-fast/dbus-fast-4.0.3.ebuild
new file mode 100644
index 000000000000..99ccc67c3c1c
--- /dev/null
+++ b/dev-python/dbus-fast/dbus-fast-4.0.3.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+# TODO: freethreading compatible
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="A faster version of dbus-next"
+HOMEPAGE="
+	https://github.com/bluetooth-devices/dbus-fast/
+	https://pypi.org/project/dbus-fast/
+"
+SRC_URI="
+	https://github.com/Bluetooth-Devices/dbus-fast/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+BDEPEND="
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.4.1[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/pycairo-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.50[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{asyncio,timeout} )
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+src_test() {
+	local dbus_params=(
+		$(dbus-daemon --session --print-address --fork --print-pid)
+	)
+	local -x DBUS_SESSION_BUS_ADDRESS=${dbus_params[0]}
+
+	virtx distutils-r1_src_test
+
+	kill "${dbus_params[1]}" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# interface not found on this object: org.freedesktop.DBus.Debug.Stats
+		tests/client/test_signals.py::test_signals
+	)
+	local EPYTEST_IGNORE=(
+		tests/benchmarks
+	)
+
+	nonfatal epytest -o addopts= || die
+}
diff --git a/dev-python/environs/Manifest b/dev-python/environs/Manifest
index 14d733df08b9..681e89024d6a 100644
--- a/dev-python/environs/Manifest
+++ b/dev-python/environs/Manifest
@@ -1,3 +1,4 @@
-DIST environs-14.5.0.gh.tar.gz 48055 BLAKE2B efb67a9f947169020ab2337ffd065a095f49bd8bbefe51ba45f00f78f105f276b2a8775d1c778c8f5929b667933189752a99fbe814760cacf8fc340650d6eb7f SHA512 421328d2b3bb563cfb3b4ce8eeb7d3032f01f637cdbd481a0c2fc3c05e5768e1b94169386a7ec39c7f7a4a36116dacba7f2ced25c3dc31e43de5dcadcb941f14
 DIST environs-14.6.0.tar.gz 35563 BLAKE2B 8a8d3777cbb8e8c160f9b5b87387be8a3f20f7a49ead34555b5e1b1bb2545d2c2ee14bf5671013ca6708f4f27ddc17fdd15f6ce5ca51fa1e551ef7a462a0dca3 SHA512 740b8182d7c8807ea3f50db05b71d19b2b06486909c80fa2269bf2beefe8d1624d8994ad0137bd33118825376d65d2fd94d2cf8c3c7d8cdea307e1c43880b928
 DIST environs-14.6.0.tar.gz.provenance 9487 BLAKE2B 10d482292d3f5b9bc27d4613d6aad880633b16c6e3f99e7f88d0d36a5ee2a03710acf19c52e4c77658e7731d055354b166058f1451792cf78aa8cf587aeb4bf5 SHA512 8496f565d3cf7a6f3261444a00b0e142bac1b532de4715d097377d5bd210b0bd8c69e7b5c3dcc3d250baf13130436acddfdabb2ee665c1d8ad86613d53f06f3c
+DIST environs-15.0.0.tar.gz 36264 BLAKE2B 1064538d19aaec7803d1a2aa142239a2665c1eb97596ccf7c80c53000ecaf1633f1691a366c05f84953edc163f9adfcb33136c1676b9886f24c59860ab8d042e SHA512 d56266342b02f5486abb38f9cfd2151a166b15f3549a6b061ec3af2bb2a5cdc7c6b43efa815e3299cfd413429c12e2ffbf368d90e195362abd4650cdfd63e4c0
+DIST environs-15.0.0.tar.gz.provenance 9291 BLAKE2B 0309afc0df7ddd682268d27841e4f3387744c9507d234f527fe72ca2451bb94145b7cb880ede8242df5ead2e2055dfa1aead74991fce85499b9c6c768474e0ed SHA512 31070c4c588af4702b2f29588d6844df027068df9ba5906acc5629c1006cd75fcb08777e856d8705a3272d83e2c02e8391625e0291c49bf7dbbf00792f0b416d
diff --git a/dev-python/environs/environs-14.5.0.ebuild b/dev-python/environs/environs-15.0.0.ebuild
index 7e140f03e826..a06c7589a95a 100644
--- a/dev-python/environs/environs-14.5.0.ebuild
+++ b/dev-python/environs/environs-15.0.0.ebuild
@@ -1,22 +1,19 @@
-# Copyright 2021-2025 Gentoo Authors
+# Copyright 2021-2026 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 DISTUTILS_USE_PEP517=flit
+PYPI_VERIFY_REPO=https://github.com/sloria/environs
 PYTHON_COMPAT=( python3_{10..14} )
 
-inherit distutils-r1
+inherit distutils-r1 pypi
 
 DESCRIPTION="Python library for simplified environment variable parsing"
 HOMEPAGE="
 	https://github.com/sloria/environs/
 	https://pypi.org/project/environs/
 "
-SRC_URI="
-	https://github.com/sloria/environs/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
 
 LICENSE="MIT"
 SLOT="0"
@@ -24,7 +21,7 @@ KEYWORDS="~amd64 ~arm64"
 
 RDEPEND="
 	dev-python/python-dotenv[${PYTHON_USEDEP}]
-	>=dev-python/marshmallow-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/marshmallow-4.0.0[${PYTHON_USEDEP}]
 "
 BDEPEND="
 	test? (
diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index d355105366fd..87204cd1e7fa 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1,2 +1,3 @@
 DIST pdm-backend-2.4.6.gh.tar.gz 162757 BLAKE2B 2e2de500fa61f059d350388c73b9585c582f1bf4b6a45a2215e97a8c130873d2ffad3113fdf0db7ea16eb49066e09539d7db7cf3a55be4098180837c51efa8d0 SHA512 132bfe38fe7a70e99f5d6dc92963068d057ed08b811324f379eb0e3feb7108cf52c930e5aa67ce8ae6ff21201f33a8b6c74dcd3afbd1d6e711569cb26ffc7248
 DIST pdm-backend-2.4.7.gh.tar.gz 162824 BLAKE2B 113e69b1ec8a667331ad17779cea5b32ce04f8d72a4e17a8ff857d45ac64d962e767aaaf50d402fcc57fb274b9b28db1838016638cf39c4ec2165ac88ee8b3e9 SHA512 2582487b825fbeadd673c430cb22fbd1b79b0e080a3aac45aaa716cad56d606f5a96d74faf7e68e6f028a1c2ef11c69d7713de6d3ae7947a9f99e0a30828e4a2
+DIST pdm-backend-2.4.8.gh.tar.gz 159228 BLAKE2B ddba89eab214262813cbe003f2793a5cd8edf03cf0650b7b4a625d2b6e54233cb63bd06e5f8ed4a47ca061e68d796d509555d53657fbb64b34ceaf2d48cf047c SHA512 ba5ff3926b3dfaa194b9faa2bb3727343aa36f28a60d5a33dc39d822900c0c650a39c34338c95f4c8ffaf1736aac24a215812ff5ea2c58e3e68cf2d431826c79
diff --git a/dev-python/pdm-backend/pdm-backend-2.4.8.ebuild b/dev-python/pdm-backend/pdm-backend-2.4.8.ebuild
new file mode 100644
index 000000000000..1801539979a0
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.4.8.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# see src/pdm/backend/_vendor/vendor.txt
+RDEPEND="
+	>=dev-python/editables-0.5[${PYTHON_USEDEP}]
+	>=dev-python/packaging-24.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.9.0_beta7[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	# this must not be set during src_test()
+	local -x PDM_BUILD_SCM_VERSION=${PV}
+	distutils-r1_src_compile
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	epytest -k "not [hg"
+}
diff --git a/dev-python/phonenumbers/Manifest b/dev-python/phonenumbers/Manifest
index 5d79c90cf7a4..1996064c3a34 100644
--- a/dev-python/phonenumbers/Manifest
+++ b/dev-python/phonenumbers/Manifest
@@ -4,3 +4,4 @@ DIST phonenumbers-9.0.23.tar.gz 2298342 BLAKE2B 28ac9678230caed10e6575b5f4df925c
 DIST phonenumbers-9.0.24.tar.gz 2298138 BLAKE2B cb9a0a1f7e962ced422aa8961254ce8df9fbfdd6ca31c711df20def32fc43adc85a461416a046bd9808e2421d7eaec77444543c4d98785e986eea338887a8d5c SHA512 32a963b54e1ac69749d24b4c902257958754b993d09bb93e964a2bbf492c5828fcff4cf284c9ca28b4746206f3ec7e47a8564b55c467cdb2e7653bf051eb27fe
 DIST phonenumbers-9.0.25.tar.gz 2298295 BLAKE2B e1a13e783d0a44aea7973033faeadca260cf33f9ac307dbf54601a36e3960b105a4c20213995dca48c6830bfc995967cbebca9497b44c48d26159dd4746fe7e8 SHA512 81ad4f4c982bb11d9591e2f6d423846a4c27f20ff8f2eb53f1df0946bfb8e0382cee9cb838cfb0cc21e4be2a10398de8949a4b7c7370463fc0e6742f6ed7e79e
 DIST phonenumbers-9.0.26.tar.gz 2298587 BLAKE2B 5fe7da13c7084bd56984aea7a2072ec8952e835321ecbb96cda264ce1799f4b0c9edde9fd0a2bdd0c22d64006192ac044910ca62d9915db8eea9c614f02e44f4 SHA512 a1821cb641b1d3c7f5a29472581c66f27ab4728fad12274d6bf0de8d63b4b032130b428429742f82644df0e40a089d97983305e5b6695aef9a214663508bcf4e
+DIST phonenumbers-9.0.27.tar.gz 2298619 BLAKE2B e103dd46a9239452e52526cf4a30029acd8bad0198b96e824cd6aa7bcc2b440ae8ff29af74c27212f5d5b081dc2e1a91555a3b2f3d31e294d1125fe56ec9a1ee SHA512 2fb7b3ce6c8ddf0439d27126cf318a30998489d4fb1e208419634a2cef3fd521ac911344df41ebbfc1977fa3c07833893e9d01e7adcc69da60e8084a475883fa
diff --git a/dev-python/phonenumbers/phonenumbers-9.0.27.ebuild b/dev-python/phonenumbers/phonenumbers-9.0.27.ebuild
new file mode 100644
index 000000000000..56b0d243a266
--- /dev/null
+++ b/dev-python/phonenumbers/phonenumbers-9.0.27.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python port of Google's libphonenumber"
+HOMEPAGE="
+	https://github.com/daviddrysdale/python-phonenumbers/
+	https://pypi.org/project/phonenumbers/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/protobuf[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	"${EPYTHON}" testwrapper.py -v || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index 6150ded23987..639fea843530 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -2,4 +2,5 @@ DIST pillow-11.3.0.gh.tar.gz 47173056 BLAKE2B 1260c7025e6013c50782024756a0c891d3
 DIST pillow-12.0.0.gh.tar.gz 47078314 BLAKE2B 14540f6b016004de56e5736f66f23999ebc2683c4be5053631fd6890502d7416d05e9ef858460fec4473d873893303b51f251ed3b50facb11616211b0629e79c SHA512 816237bf65b65a8f7ec941db6ea07814af602efe6f214e2a253b1d0b6b9dbbe9895a9822c6de67af40bd507e658b8c088707440f689d5fd237985f4ee0f7bfc2
 DIST pillow-12.1.0.gh.tar.gz 47045570 BLAKE2B 1ba09d4a9540584c6649f29f03c8f2673fa675a8309f0a7ff45eb95b878498d3adfa239a755dda2d14035c2d4ac22920b78d2caeaa1c2f403ad4da0c50960f8e SHA512 f542780a7894ca4eade3ee2c806f2bb0866cd93967ce45228ffaff9d0c9fb09eb3193a5afc9aa08caff1ed7f495031414fbd4a1addb3c373f8fa76a373a0be8d
 DIST pillow-12.1.1.gh.tar.gz 47047606 BLAKE2B 7e646b2d16bd7653f1579fb2e752c40b2945e3de97d115e5c9769102af6e4030d1903e2bf0d0926b41586d61bb070dd849c67404d164a0ea7c0827bec7ae6b61 SHA512 791c8972d913b616bd903aa4e9a468b1886faf5a477414fdd07cd37a29253f3e158988adf613969ea3f3efcef716d74b8d667efbac0d85ba12c15da2137c32a3
+DIST pillow-12.2.0.gh.tar.gz 47057046 BLAKE2B 448a928cdaef49c21db4b0b61e2045610ff6bf6c9c52c7ab541d531205149b8a60aa02b1e286c7dc15dac98fa23a07a4c685f524df6e7592013b0914e65a8cc8 SHA512 cd66b5b033f82127934624c474aed55c014d10d5e7cc9455ea6a3470d1b7e9f0b94ad2c0a5f1559e01ce003fc179b01fee89aa1b51d78dff3f04927d8252a41e
 DIST pillow-test-images-7077675d2cda485d63de4aefe0fefbf6f655c5a0.gh.tar.gz 57430276 BLAKE2B 6e8dcde60832004f5a0ea0e14024fdcd0b08cf0e225f27e39b7c2058582d6d5efe7fcaccb5bd28754affa6fe4125735fb4beeaa2075e6aceea0a998ebc0747fe SHA512 795f015c9b73a8c941fb5cd880b1ab36b24d38612db53367ab0e6c05dd1cdbfd47034decb7e36d7de940eeea1582d644ca7bee3b131577578692569c2c60c32b
diff --git a/dev-python/pillow/pillow-12.2.0.ebuild b/dev-python/pillow/pillow-12.2.0.ebuild
new file mode 100644
index 000000000000..ea1d6093fec9
--- /dev/null
+++ b/dev-python/pillow/pillow-12.2.0.ebuild
@@ -0,0 +1,169 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+# setuptools wrapper
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..14} )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 toolchain-funcs virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+# upstream always fetches from main
+TEST_IMAGE_COMMIT="7077675d2cda485d63de4aefe0fefbf6f655c5a0"
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="
+	https://python-pillow.github.io/
+	https://github.com/python-pillow/Pillow/
+	https://pypi.org/project/pillow/
+"
+SRC_URI="
+	https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/python-pillow/test-images/archive/${TEST_IMAGE_COMMIT}.tar.gz
+			-> pillow-test-images-${TEST_IMAGE_COMMIT}.gh.tar.gz
+	)
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="avif examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
+REQUIRED_USE="test? ( jpeg jpeg2k lcms tiff truetype )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	avif? ( media-libs/libavif:= )
+	imagequant? ( media-gfx/libimagequant:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2= )
+	tiff? ( media-libs/tiff:=[jpeg,zlib] )
+	truetype? (
+		media-libs/freetype:2=
+		media-libs/harfbuzz:=
+	)
+	webp? ( media-libs/libwebp:= )
+	xcb? ( x11-libs/libxcb )
+	zlib? ( virtual/zlib:= )
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/olefile[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pybind11[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-77[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	test? (
+		dev-python/defusedxml[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		|| (
+			media-gfx/imagemagick[png]
+			media-gfx/graphicsmagick[png]
+		)
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-timeout )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		# https://github.com/python-pillow/pillow/pull/7634
+		"${FILESDIR}/${PN}-10.2.0-cross.patch"
+	)
+
+	distutils-r1_src_prepare
+
+	if use test; then
+		mv "${WORKDIR}/test-images-${TEST_IMAGE_COMMIT}"/* \
+			Tests/images || die
+	fi
+}
+
+usepil() {
+	usex "${1}" enable disable
+}
+
+python_configure_all() {
+	cat >> setup.cfg <<-EOF || die
+		[build_ext]
+		debug = True
+		disable_platform_guessing = True
+		$(usepil avif)_avif = True
+		$(usepil truetype)_freetype = True
+		$(usepil jpeg)_jpeg = True
+		$(usepil jpeg2k)_jpeg2000 = True
+		$(usepil lcms)_lcms = True
+		$(usepil tiff)_tiff = True
+		$(usepil imagequant)_imagequant = True
+		$(usepil webp)_webp = True
+		$(usepil xcb)_xcb = True
+		$(usepil zlib)_zlib = True
+	EOF
+	if use truetype; then
+		# these dependencies are implicitly disabled by USE=-truetype
+		# and we can't pass both disable_* and vendor_*
+		# https://bugs.gentoo.org/935124
+		cat >> setup.cfg <<-EOF || die
+			vendor_raqm = False
+			vendor_fribidi = False
+		EOF
+	fi
+
+	tc-export PKG_CONFIG
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO (is clipboard unreliable in Xvfb?)
+		Tests/test_imagegrab.py::TestImageGrab::test_grabclipboard
+		# requires xz-utils[extra-filters]?
+		Tests/test_file_libtiff.py::TestFileLibTiff::test_lzma
+	)
+
+	case ${ARCH} in
+		ppc)
+			EPYTEST_DESELECT+=(
+				# https://github.com/python-pillow/Pillow/issues/7008
+				# (we've reverted the upstream patch because it was worse
+				# than the original issue)
+				Tests/test_file_libtiff.py::TestFileLibTiff::test_exif_ifd
+			)
+			;;
+	esac
+
+	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+	# leak tests are fragile and broken under xdist
+	# nonfatal implied by xvfb
+	nonfatal epytest -k "not leak" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	python_doheader src/libImaging/*.h
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	if use examples ; then
+		docinto example
+		dodoc docs/example/*
+		docompress -x /usr/share/doc/${PF}/example
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/python-lsp-ruff/Manifest b/dev-python/python-lsp-ruff/Manifest
index 854f2008f124..f8069daa4d7a 100644
--- a/dev-python/python-lsp-ruff/Manifest
+++ b/dev-python/python-lsp-ruff/Manifest
@@ -1 +1,2 @@
 DIST python_lsp_ruff-2.3.0.tar.gz 17268 BLAKE2B 4856ef31446fcc3d6e6d5c56b3cfe547e2360f97ace27093cf450d44cef54feb8b1587d6752ecf8fe4c8014afe34a6765204311c4533c764cde1fcb4e9e32185 SHA512 d7ea00489407eb9b2ceb864c3efff5e5f5835ab203d2e02bb2d2f41518a158ea39f2c8c36f2f7369e6b56fbfe19cf16f345e85e7707ab9d68be3b2f1459a225a
+DIST python_lsp_ruff-2.3.1.tar.gz 17421 BLAKE2B 304db767fbe03857f85c54257d431146b812ddf1a0186b31eec48a73565cafe998453af19ef7c6919f9a007b5775ac361a619ee762589d00ee7f53e641158235 SHA512 a30e7a40a9962b59b61e9d9501c67e615e7f74da041aa13a68818f2c4746e17f576ea1bce486cf0057442b96e4795c7b4be3a6b22dde8f7f94bff14db920dca1
diff --git a/dev-python/python-lsp-ruff/python-lsp-ruff-2.3.1.ebuild b/dev-python/python-lsp-ruff/python-lsp-ruff-2.3.1.ebuild
new file mode 100644
index 000000000000..1fb7c09a6a1e
--- /dev/null
+++ b/dev-python/python-lsp-ruff/python-lsp-ruff-2.3.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Ruff linting plugin for the Python LSP Server"
+HOMEPAGE="
+	https://github.com/python-lsp/python-lsp-ruff/
+	https://pypi.org/project/python-lsp-ruff/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-util/ruff-0.8.0
+	dev-python/cattrs[${PYTHON_USEDEP}]
+	dev-python/python-lsp-server[${PYTHON_USEDEP}]
+	>=dev-python/lsprotocol-2023.0.1[${PYTHON_USEDEP}]
+"
+
+EPYTEST_DESELECT=(
+	# Fails due to Gentoofied calling of ruff
+	"tests/test_ruff_lint.py::test_ruff_config_param"
+	"tests/test_ruff_lint.py::test_ruff_settings"
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
diff --git a/dev-python/stripe/Manifest b/dev-python/stripe/Manifest
index b3b5650a8193..67fda9d73cc4 100644
--- a/dev-python/stripe/Manifest
+++ b/dev-python/stripe/Manifest
@@ -3,3 +3,4 @@ DIST stripe-14.3.0.tar.gz 1463618 BLAKE2B 6783b412c94089d13dc1efd14eb43bf2cbed93
 DIST stripe-14.4.0.tar.gz 1472370 BLAKE2B 5f120bf7f0592d923d8d31ada37d1ba4d7426e61671d7a98fb41bd00783b8f4aefa10434e751f671fc16d3126bad322346e7b0434553775db83ec97b7416be6a SHA512 81198fcfb3b42b82aed612e9b602f2d3e4e3d22529d9d78147e5bc42b0cd91f3042771e56496f4fddb8bf554b1c5f881c8d836f8260d812d676dfa4e941078d7
 DIST stripe-14.4.1.tar.gz 1473321 BLAKE2B ec9f7a96f8777b7239baef145de3534e43bdd56d308ace8387ce8cd5f3bf1a17438fd806c6e3200076411aac55796b3b41c2cf635a204a73e57cf6698b1498c7 SHA512 9e7f267363629294b81d8f132a371846a407a7f96d57e40fc9ba3597eb5cf34572afac405d5244aa2d1fc8bce0c3c81dc2321926560b9d3c4cd99b80d59c8a32
 DIST stripe-15.0.0.tar.gz 1486873 BLAKE2B 9f88b8ec81084a23113403297cb000a1e96ed586e927616486b90c3c6ae987497e9c562a7cafc64fde19cb376ee4cd7dcb3b938d1e785c1ca7a12337c04b0672 SHA512 19ecfe897de7428b305eec390fd996b74de9e7e1ba7271d359ba21b7a1cfc27e77e62fe7cc966287d7131d381570e205c66e0e6ab3be9953284811d78a72eb45
+DIST stripe-15.0.1.tar.gz 1490326 BLAKE2B 8afe273c6f91a5d43a055f3de32c4c3188537a26267242ab4be281b90f88297811129251379be9ed5652f0eb998691cfef74c11bf20db7c0ffbdc631b9795ed9 SHA512 4bbdfdacf421164b15d1b7329d723b24986e978f04f416e9c2c526a1e72692dbb66075feea5cef3660ea950e6c26d4fb2e6eaaf1d06aac125a5a51fe3af1caec
diff --git a/dev-python/stripe/stripe-15.0.1.ebuild b/dev-python/stripe/stripe-15.0.1.ebuild
new file mode 100644
index 000000000000..c5285afc42cd
--- /dev/null
+++ b/dev-python/stripe/stripe-15.0.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Stripe Python bindings"
+HOMEPAGE="
+	https://github.com/stripe/stripe-python/
+	https://pypi.org/project/stripe/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="telemetry"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.7.0[${PYTHON_USEDEP}]
+"
+# please bump dev-util/stripe-mock dep to the latest version on every bump
+BDEPEND="
+	test? (
+		>=dev-util/stripe-mock-0.197.0
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		net-misc/curl
+	)
+"
+
+EPYTEST_PLUGINS=( anyio pytest-mock )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	if ! use telemetry; then
+		sed -i -e '/enable_telemetry/s:True:False:' stripe/__init__.py || die
+	fi
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/test_http_client.py::TestLiveHTTPClients::test_httpx_request_async_https
+		'tests/test_integration.py::TestIntegration::test_async_raw_request_timeout[asyncio-aiohttp]'
+		# timing
+		tests/test_integration.py::TestIntegration::test_passes_client_telemetry_when_enabled
+	)
+
+	epytest tests
+}
+
+src_test() {
+	local stripe_mock_port=12111
+	local stripe_mock_max_port=12121
+	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
+	# Try to start stripe-mock until we find a free port
+	while [[ ${stripe_mock_port} -le ${stripe_mock_max_port} ]]; do
+		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
+		stripe-mock --http-port "${stripe_mock_port}" &> "${stripe_mock_logfile}" &
+		local stripe_mock_pid=${!}
+		sleep 2
+		# Did stripe-mock start?
+		curl --fail -u "sk_test_123:" \
+			"http://127.0.0.1:${stripe_mock_port}/v1/customers" &> /dev/null
+		eend ${?} "Port ${stripe_mock_port} unavailable"
+		if [[ ${?} -eq 0 ]]; then
+			einfo "stripe-mock running on port ${stripe_mock_port}"
+			break
+		fi
+		(( stripe_mock_port++ ))
+	done
+	if [[ ${stripe_mock_port} -gt ${stripe_mock_max_port} ]]; then
+		eerror "Unable to start stripe-mock for tests"
+		die "Please see the logfile located at: ${stripe_mock_logfile}"
+	fi
+
+	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
+	distutils-r1_src_test
+
+	# Tear down stripe-mock
+	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
+}
diff --git a/dev-python/types-psutil/Manifest b/dev-python/types-psutil/Manifest
index 4b6a62dc5eec..ac9f7e89a299 100644
--- a/dev-python/types-psutil/Manifest
+++ b/dev-python/types-psutil/Manifest
@@ -3,3 +3,4 @@ DIST types_psutil-7.2.0.20251228.tar.gz 25400 BLAKE2B 93c589636c46a7034d73e898c5
 DIST types_psutil-7.2.1.20251231.tar.gz 25620 BLAKE2B 6ca4bb77cd1d90a9eda26166aa38ff2b68c200b90f8d3cdeb731ec68a3145a3c5ba8c969983a5eeeeaf6adf92b0e32363c9908d1384413b266ccbc0c6b3cdfea SHA512 39e5c66245b9cdef7b08a42384baa16a9fcad06b2c284fcb97d290677c04d935e435c8a43b22b145a48e3af84a3a521caf5ff756268c06b805929309ae013951
 DIST types_psutil-7.2.1.20260116.tar.gz 26121 BLAKE2B 98f4e4f56ef89bf3055568ea48324a5be79fb44bb4c639b4964f55ccc0b9896e3e90bb20406df649a13cfb581abe820f4ea48dcfa7d7e71c9e5c48cccc4dbd52 SHA512 0a1b8025c82f8544f4ef2e6a401d1f4600665136053d509cb08aa77d7534fb267d5de5e207527cf4e789c6d1a7aa4547c8313ce4e2073245d4bca8f9c5287b94
 DIST types_psutil-7.2.2.20260130.tar.gz 26535 BLAKE2B 9012a4c2f3af6b5a6bf324377ab7f0c817dc61b8c9cf83b3f52252d802061e63edbbb26d63282da3ce96cd2be3beac2682f9580cc6202dbfba7cd9dda3476a7c SHA512 5c187fee31d31112db70675dc1b45efe0cdc4bd4af04fd10ffb91eed6b0ccc1cdf91c7363c9b38f4264751bfc94577339ede49888f8fc9c02f16511fd3b48421
+DIST types_psutil-7.2.2.20260402.tar.gz 26522 BLAKE2B 1e2adbb06992e359312b6cfd96cfde896281a82dbe346309b81355365dfe05704934669057c6e3d026c1cb86b9d64c467941fa3a0ab46d6046cad125f0fe53c9 SHA512 aaa50a56c3f50cd0eb8fc7e51216fcfa05a3878394f2cf612d7a9ac66021b7dcd044fff00e8358dce30ff8c382e6db0c6f72c178921b9f06a0086d2324815b42
diff --git a/dev-python/types-psutil/types-psutil-7.2.2.20260402.ebuild b/dev-python/types-psutil/types-psutil-7.2.2.20260402.ebuild
new file mode 100644
index 000000000000..2ecb6de47a46
--- /dev/null
+++ b/dev-python/types-psutil/types-psutil-7.2.2.20260402.ebuild
@@ -0,0 +1,20 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Typing stubs for psutil"
+HOMEPAGE="https://pypi.org/project/types-psutil/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	>=dev-python/setuptools-82.0.1[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/types-python-dateutil/Manifest b/dev-python/types-python-dateutil/Manifest
index 7f4fa4f08a0f..f9d5dfe2d3ea 100644
--- a/dev-python/types-python-dateutil/Manifest
+++ b/dev-python/types-python-dateutil/Manifest
@@ -1,2 +1,3 @@
 DIST types_python_dateutil-2.9.0.20260305.tar.gz 16885 BLAKE2B 9e1bca39abbf9cceea425e7113e775203a16fe11bb845fa510b3db8e3db7313b08cf9013c621a219c72dac034d67ef74e28b86610c1896e1e0ae479d9efdc8cb SHA512 c30ed86c9f78765e0a0634c3f99733c1003c5357eacd0f93e06fb7b22022809ee08b008ddc84074526cd220569c2155736c3b49672f57f4a4c349932be82121a
 DIST types_python_dateutil-2.9.0.20260323.tar.gz 16897 BLAKE2B 05708ab3b55ff1c6047313b3e69506f21f1116f57b6a974774278ccf9076e170a56031e68eaa6d475f619ac35e58a2e888a64e357af1679cbce1865e0f9f82bd SHA512 c0c6edf869db6ced75dc20c42a3c9399bb4018f068251c9861bd5acd3767cbcddfa9a79fef036468e1126e69adc92b26ac5be5100982f4d5d5daad174f6e1ae8
+DIST types_python_dateutil-2.9.0.20260402.tar.gz 16941 BLAKE2B 8f5bcd0b848915ced25bb31cf19d4387234030122de5011c0fff6df1ba31b77082afb43341a11362d32be095f0a01b8144c380867f2a04341a4a1746feece70b SHA512 856eed7a6b1dfb5d655ca6a0521f48275c4560888028c42327e956993350617ed9d11751d70c0239b6a331c557b6c91f743d5dc02b9e5fe256f64973536c588a
diff --git a/dev-python/types-python-dateutil/types-python-dateutil-2.9.0.20260402.ebuild b/dev-python/types-python-dateutil/types-python-dateutil-2.9.0.20260402.ebuild
new file mode 100644
index 000000000000..9ee72fee1d13
--- /dev/null
+++ b/dev-python/types-python-dateutil/types-python-dateutil-2.9.0.20260402.ebuild
@@ -0,0 +1,23 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Typing stubs for python-dateutil"
+HOMEPAGE="
+	https://github.com/python/typeshed/
+	https://pypi.org/project/types-python-dateutil/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+BDEPEND="
+	>=dev-python/setuptools-82.0.1[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/types-setuptools/Manifest b/dev-python/types-setuptools/Manifest
index c16078a18937..ba271498cb7e 100644
--- a/dev-python/types-setuptools/Manifest
+++ b/dev-python/types-setuptools/Manifest
@@ -1,3 +1,4 @@
 DIST types_setuptools-80.10.0.20260124.tar.gz 43299 BLAKE2B a8b2a540aabd60c4ea028a99beb868765654eb1849221b2d110f54f921e298c97333e77b35eab501126864e42c56197f5bce451caed115a9574dd685d0578487 SHA512 567c74b5090478a95384bfbed8c74b9d575abb610dd9c3cb2301316c7217374b8d39b1948f9e07ad7bbedd747ab47259afec70d7a0b57895e6bb211c1014bed3
 DIST types_setuptools-80.9.0.20251223.tar.gz 42420 BLAKE2B 1c023a586b1898ab3e7d262e83f8e7c05b700a0c52362732c4f1a8b0b02f395b71373d0dca11121c230e0b4feece8175c5239a1dd8eaf214ba60ed019cd8fd35 SHA512 1cad22757d1ddce329f0b61c0f76f0c4b293b9fdc035330650cd0820e6554f0f5b430f4d76e0f8e3d3a9a74d192490aa65bdc89bda177456f8a905313307bcbe
 DIST types_setuptools-82.0.0.20260210.tar.gz 44768 BLAKE2B 6c5b14731a8ece67e233dcaf3ae65a058351eba85865954dfdca5ccee563c5aa552d5731350b9bde92b5e16c2afd63f964ad3115cc45ca7609591f0ec36dba34 SHA512 e1ec89d826df32a77dbba33721402588fe363fb17f098df6473e6711d1ac67e90dce3d20c47774c28d08aceb1f134c15dbc9bfc3ca6306d10773ec7c80979aa0
+DIST types_setuptools-82.0.0.20260402.tar.gz 44805 BLAKE2B fa5cc5ea424f428de58d8d0f6abb50fc6b9ddfa2d328a1fcdd3a34cce4a195507846cbf1cb4d7ace47c66fb3d4e1668310f64f8e3a3fd84ee80676f635e46d8e SHA512 89262a9894ecfad36e6f2dcf570b0f61f4cca6786eb863cab3e945012dd3b4556184a437cb79db4da3a66e83c051eb652daf524a2957a79aa52e4743c1e49cc8
diff --git a/dev-python/types-setuptools/types-setuptools-82.0.0.20260402.ebuild b/dev-python/types-setuptools/types-setuptools-82.0.0.20260402.ebuild
new file mode 100644
index 000000000000..6eb6ca6acfff
--- /dev/null
+++ b/dev-python/types-setuptools/types-setuptools-82.0.0.20260402.ebuild
@@ -0,0 +1,20 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Typing stubs for setuptools"
+HOMEPAGE="https://pypi.org/project/types-setuptools/"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	>=dev-python/setuptools-82.0.1[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/uv-build/Manifest b/dev-python/uv-build/Manifest
index 7544c6b76003..679b08e9f7b0 100644
--- a/dev-python/uv-build/Manifest
+++ b/dev-python/uv-build/Manifest
@@ -2,3 +2,4 @@ DIST uv_build-0.10.12.tar.gz 378676 BLAKE2B f3d3dfa1a4ea289cd1923527c27f0806f3b5
 DIST uv_build-0.11.0.tar.gz 381349 BLAKE2B 67141bb1d0a77ccff1e05e132a458ac6f62aad406c44cdec030e89266deda76fda580fcdecf3eca1adb85652b896e53e8e3a20c2a84564a82f11276e2363408c SHA512 6e928f5448a0b178f39dc7a87cde035829186e28b4965d39b8e789dd69c674d86993f556872cf149b50c1f10edc2e28fff3163371c7d0989bdd46188bb3079f9
 DIST uv_build-0.11.1.tar.gz 381246 BLAKE2B 57bd4e5366899c745294e967b9c632ff12587faf5d016cf5dab90c722fa61ff999ec0d95274c88372b27f5ff4878ffe6a9a476bfea62ca4eccb1796666a09599 SHA512 7d1421bfd46635e7e927be951eaf4f5044dc6dceec99178a2c0204b6bafd54648f98107d9ac68ebf0685132c3a34fdbfb6a6b684455caa9acd9b4bb9cb9dfcab
 DIST uv_build-0.11.2.tar.gz 381227 BLAKE2B a0989816b2c4f224fe78d88a0dbee2f87b6426d0cb67299ae7f5caec644bf11ba0a3503919103d5c2a747cf696f2e7447a618a8b11156ffad9c308eeb3fb1e7b SHA512 66ce17d053002eb3c7fe82bf0c0e9953770dbc5b75822fa6bacdddd3092b5899d5416cd669e633a58b644e6fb6ceb6a8ff940878d7874c08b5d23b02564f2ba3
+DIST uv_build-0.11.3.tar.gz 382592 BLAKE2B c212ba9dbd57d588f229a6972a20824cb1439c1770d677a7754a2ccad598a0b9235edbd4c6e178bae99c04c2a31a104a6213335e2c8e005728b25500c1b3a729 SHA512 3ed531b2ac111a8446336861eb80e90d5e7aa595cc65de7e83c79f94f4b2a0183028e3738ed30169b00430ef380574701fd1beffd120bc2cf7510d3bcb28bf11
diff --git a/dev-python/uv-build/uv-build-0.11.3.ebuild b/dev-python/uv-build/uv-build-0.11.3.ebuild
new file mode 100644
index 000000000000..2ab229426f84
--- /dev/null
+++ b/dev-python/uv-build/uv-build-0.11.3.ebuild
@@ -0,0 +1,99 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Maturin compiles uv-build executable for every impl, we do not want
+# that, so we use another backend.  And since we use another backend,
+# why not dogfood it in the first place?
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="PEP517 uv build backend"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv-build/
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/uv-${PV}
+"
+BDEPEND="
+	test? (
+		app-arch/unzip
+		dev-python/build[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# use the executable from dev-python/uv instead of building
+	# a largely overlapping uv-build executable (at least for now)
+	sed -i -e '/USE_UV_EXECUTABLE/s:False:True:' python/uv_build/__init__.py || die
+
+	# replace the build-system section
+	sed -i -e '/\[build-system\]/,$d' pyproject.toml || die
+	cat >> pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["uv_build<9999"]
+		build-backend = "uv_build"
+		backend-path = ["src"]
+	EOF
+
+	# rename to make uv-build find it
+	mv python src || die
+}
+
+python_test() {
+	"${EPYTHON}" -m build -n || die "Self-build failed with ${EPYTHON}"
+
+	local zip_result=$(
+		unzip -t "dist/uv_build-${PV}-py3-none-any.whl" || die
+	)
+	local zip_expected="\
+Archive:  dist/uv_build-${PV}-py3-none-any.whl
+    testing: uv_build/                OK
+    testing: uv_build/__init__.py     OK
+    testing: uv_build/__main__.py     OK
+    testing: uv_build/py.typed        OK
+    testing: uv_build-${PV}.dist-info/   OK
+    testing: uv_build-${PV}.dist-info/WHEEL   OK
+    testing: uv_build-${PV}.dist-info/METADATA   OK
+    testing: uv_build-${PV}.dist-info/RECORD   OK
+No errors detected in compressed data of dist/uv_build-${PV}-py3-none-any.whl.\
+"
+	if [[ ${zip_result} != ${zip_expected} ]]; then
+		eerror ".zip result:\n${zip_result}"
+		eerror ".zip expected:\n${zip_expected}"
+		die ".whl result mismatch"
+	fi
+
+	local tar_result=$(
+		tar -tf "dist/uv_build-${PV}.tar.gz" || die
+	)
+	local tar_expected="\
+uv_build-${PV}/PKG-INFO
+uv_build-${PV}/
+uv_build-${PV}/README.md
+uv_build-${PV}/pyproject.toml
+uv_build-${PV}/src
+uv_build-${PV}/src/uv_build
+uv_build-${PV}/src/uv_build/__init__.py
+uv_build-${PV}/src/uv_build/__main__.py
+uv_build-${PV}/src/uv_build/py.typed\
+"
+	if [[ ${tar_result} != ${tar_expected} ]]; then
+		eerror ".tar.gz result:\n${tar_result}"
+		eerror ".tar.gz expected:\n${tar_expected}"
+		die ".tar.gz result mismatch"
+	fi
+}
diff --git a/dev-python/uv/Manifest b/dev-python/uv/Manifest
index 3b33f097f8e0..0ffafcf7f258 100644
--- a/dev-python/uv/Manifest
+++ b/dev-python/uv/Manifest
@@ -6,3 +6,5 @@ DIST uv-0.11.1-crates.tar.xz 46998940 BLAKE2B d3447d8f11e14a01abb7531249a3c5806e
 DIST uv-0.11.1.gh.tar.gz 5126423 BLAKE2B f22419906c1b6955a73418969d1c2e953daca1e53aee2c3427fe47a6421650197abedf4ec10548d99300f9409249c382df950dffbd6e9d7b78a46f6fc185d4f4 SHA512 8012635e9905913db0028a735979ac66d7b42328fca8d351129f4ba6c394b9ffc12ff1522f79120bf23489fad373dddb64591df744eac435b99fcb16d577887c
 DIST uv-0.11.2-crates.tar.xz 46998940 BLAKE2B d3447d8f11e14a01abb7531249a3c5806e9de8bc981897863d2018efc498ab0d01291b400a522030a73ae98e5b80e1451203f060c1925e044c8eb7c323b37014 SHA512 768bf9ee90e4728d853255bdb5eb68ba61ddb49f389e4264feeb2a5efae92b18be1ac403f64d37c073f7c4455113b365bd4b298293623abd598a0795b0909adf
 DIST uv-0.11.2.gh.tar.gz 5135705 BLAKE2B abcedb5bbf0ef2c6585580818a7b11046a1555559254c2255a929050a61d3906fe176007ca8d39d0b4a2fc8582ce70376a73b7b6c4856af796056099750ecea1 SHA512 5db8253e1403a21a82c172429f8a2ee336d19a7b1e640942bd8b6a523defa8308f60b035c8ffae40d1de9292a598a5619f36debf5bf7bb3663b1f630e311cfd4
+DIST uv-0.11.3-crates.tar.xz 46981748 BLAKE2B be42ea0a2997d23ddbd1e2772c4ad1e7a2ab8866624fa3e8eee31638e65293a5241ae0a3b3c2cecab64250b8e166f548c041145ed840a91e8c90d4d1d79ffcb8 SHA512 99686a97e1f630c396b6e7b282e85b37642b3fefb05233ec0276f4fc8fc297738c600c2348c5f15c5744242dfe121412f0bf2d4339f59b254b02ab9f4612d614
+DIST uv-0.11.3.gh.tar.gz 5161685 BLAKE2B 901bb7292d0febd3970ff84913143bc3d31252f6e2bad08ef67bdb3638eb00760b0eea5717f5b5e40e2fd862c065fafe1ac23b57b186434fe5f0899835795c44 SHA512 5694bbb75136052b929356d8a7c66d16af515709a5f68c8d5d0a8353fa51a724677bab16c6288a53d128e95614898444f6ee3cc686bb34817ff15796d4dc46f9
diff --git a/dev-python/uv/uv-0.11.3.ebuild b/dev-python/uv/uv-0.11.3.ebuild
new file mode 100644
index 000000000000..ea2607714c56
--- /dev/null
+++ b/dev-python/uv/uv-0.11.3.ebuild
@@ -0,0 +1,164 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+RUST_MIN_VER="1.92.0"
+
+inherit cargo check-reqs
+
+CRATE_PV=${PV}
+DESCRIPTION="A Python package installer and resolver, written in Rust"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv/
+"
+# pypi sdist misses scripts/, needed for tests
+SRC_URI="
+	https://github.com/astral-sh/uv/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://github.com/gentoo-crate-dist/uv/releases/download/${CRATE_PV}/uv-${CRATE_PV}-crates.tar.xz
+	"
+fi
+
+# most of the code
+LICENSE="|| ( Apache-2.0 MIT )"
+# crates/pep508-rs is || ( Apache-2.0 BSD-2 ) which is covered below
+# Dependent crate licenses
+LICENSE+="
+	0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD CC0-1.0
+	CDLA-Permissive-2.0 ISC MIT MPL-2.0 Unicode-3.0 Unicode-DFS-2016
+	ZLIB BZIP2
+"
+# ring crate
+LICENSE+=" openssl"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~x86"
+IUSE="test"
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils:=
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-lang/python:3.9
+		dev-lang/python:3.10
+		dev-lang/python:3.11
+		dev-lang/python:3.12
+		dev-lang/python:3.13
+		!!~dev-python/uv-0.5.0
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/.*"
+
+check_space() {
+	local CHECKREQS_DISK_BUILD=3G
+	use debug && CHECKREQS_DISK_BUILD=9G
+	check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+	check_space
+}
+
+pkg_setup() {
+	check_space
+	rust_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# force thin lto, makes build much faster and less memory hungry
+	# (i.e. makes it possible to actually build uv on 32-bit PPC)
+	sed -i -e '/lto/s:fat:thin:' Cargo.toml || die
+
+	# enable system libraries where supported
+	export ZSTD_SYS_USE_PKG_CONFIG=1
+	# TODO: unbundle libz-ng-sys, tikv-jemalloc-sys?
+
+	# remove unbundled sources, just in case
+	find "${ECARGO_VENDOR}"/{bzip2,lzma,zstd}-sys-*/ -name '*.c' -delete || die
+
+	# bzip2-sys requires a pkg-config file
+	# https://github.com/alexcrichton/bzip2-rs/issues/104
+	mkdir "${T}/pkg-config" || die
+	export PKG_CONFIG_PATH=${T}/pkg-config${PKG_CONFIG_PATH+:${PKG_CONFIG_PATH}}
+	cat >> "${T}/pkg-config/bzip2.pc" <<-EOF || die
+		Name: bzip2
+		Version: 9999
+		Description:
+		Libs: -lbz2
+	EOF
+
+	# uv is now forcing bundled liblzma, sigh
+	sed -i -e '/xz/s:"static"::' Cargo.toml || die
+}
+
+src_configure() {
+	local myfeatures=(
+		test-git
+		test-pypi
+		test-python
+	)
+
+	cargo_src_configure --no-default-features
+}
+
+src_compile() {
+	cd crates/uv || die
+	cargo_src_compile
+}
+
+src_test() {
+	cd crates/uv || die
+	cargo_src_test --no-fail-fast
+}
+
+src_install() {
+	cd crates/uv || die
+	cargo_src_install
+
+	insinto /etc/xdg/uv
+	newins - uv.toml <<-EOF || die
+		# These defaults match Fedora, see:
+		# https://src.fedoraproject.org/rpms/uv/pull-request/18
+
+		# By default ("automatic"), uv downloads missing Python versions
+		# automatically and keeps them in the user's home directory.
+		# Disable that to make downloading opt-in, and especially
+		# to avoid unnecessarily fetching custom Python when the distro
+		# package would be preferable.  Python builds can still be
+		# downloaded manually via "uv python install".
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-downloads
+		python-downloads = "manual"
+
+		# By default ("managed"), uv always prefers self-installed
+		# Python versions over the system Python, independently
+		# of versions.  Since we generally expect users to use that
+		# to install old Python versions not in ::gentoo anymore,
+		# this effectively means that uv would end up preferring very
+		# old Python versions over the newer ones that are provided
+		# by the system.  Default to using the system versions to avoid
+		# this counter-intuitive behavior.
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-preference
+		python-preference = "system"
+	EOF
+}