Adding metadata

40 files changed, 976 insertions, 3 deletions

diff --git a/dev-python/Faker/Faker-20.1.0.ebuild b/dev-python/Faker/Faker-20.1.0.ebuild
new file mode 100644
index 000000000000..974dc4b9560b
--- /dev/null
+++ b/dev-python/Faker/Faker-20.1.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="
+	https://github.com/joke2k/faker/
+	https://pypi.org/project/Faker/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	!dev-ruby/faker
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=faker.contrib.pytest.plugin
+	epytest
+}
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index 17d8ff55214e..f288574f4b11 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -3,3 +3,4 @@ DIST Faker-19.12.1.tar.gz 1697827 BLAKE2B 64398d85fa5492811c9a5319a88f17ecdda570
 DIST Faker-19.13.0.tar.gz 1699872 BLAKE2B a53236812e17b1b8d5329e97b29f137b980b7069c02e558bfd7f118726203116ef99699f6fcf3d60f247507c82d9b159dbcb02d9b40dd8116ba1f4bbb5cdd26e SHA512 ce9e2b854027169697834f7dc081e601d13878315c39ef955378860b6d8d6671f3e6d525c45a843c76073348c6e87abf942daadae69f7aae55b3692432d949b7
 DIST Faker-20.0.0.tar.gz 1700246 BLAKE2B dbb37b4f5256493b8d8eeb493c22d4b6698a316288aa73055061f3cc7bd36ebda460df185d38c7578a9c372a7d2cdc30304ddf43728aaec6e6a5f35304de9799 SHA512 56f2fee8dc184e0826fc3d30331830d03ed93974b2815931a0e6aa4df173efc621158dbda9e38af771cfe22a8f5a9ceac042edca14b30220ec303cf5d3bbf42e
 DIST Faker-20.0.3.tar.gz 1700384 BLAKE2B 95d2070b05694219d66d6a62f22ce7aa4d4b72f0b3bce762b900f66972627fbb8bf0e5a41f33bf7d5831f3c9ed7fde2dd7f42a54e3207026ce3f3e860090a299 SHA512 44080c6c28d2033fe81b8bb5306983176fbed797c626329ae84d6971521306c13cf020a34d2edf14fc17c0ea932dcca8d3886e9bd7faa5fe5651d670f1acff01
+DIST Faker-20.1.0.tar.gz 1701717 BLAKE2B c213aa69326c80adf2b68b093fb7aa9e9d7aaee06f235d9d8dc3d3b24d9e7b4ad15c7412a9c3539749c58ad47bb63d5f4a0c94dd6318a8539a225450b65ab6b3 SHA512 6241c90d6233e58e763d5de3d6550b9fd9bb33af0f736209edcd60b8d6e0e57eebe3e86fd86c141816ad1817cea949b2a6d16f212413d8748b82370c2bae57b0
diff --git a/dev-python/agate-excel/Manifest b/dev-python/agate-excel/Manifest
index cc85849ca33a..5e3cf1cf52dc 100644
--- a/dev-python/agate-excel/Manifest
+++ b/dev-python/agate-excel/Manifest
@@ -1,3 +1,4 @@
 DIST agate-excel-0.2.5.tar.gz 161131 BLAKE2B ed7306dabf8b5da722aec9005da9bdba74a9cc585ea72b429eecc4b1fcbdfed698af8e582c464081867c0d4a285b9bc892efc339f0a08c657d87e61fd1174496 SHA512 5686c3faf8b817589a62d9fac558bebe7f47124685be9f8146d74c206023530d0cec2ad88fa4ba7ac049516f5bec6783ce8f0ff47f8eb8b2ed8aad7316f1771b
 DIST agate-excel-0.3.0.tar.gz 164113 BLAKE2B f5d9d3c2225bd5df38b0f3028fdcaa61000f5bd6de05d5e490beb1f4b3184e82e76aa8a1d46845ff9795792a8dd58de075da74c27df3a4d4f7a3b6f8ffb7b501 SHA512 7d795f1086d38e736d594d9514dd154da31bb9c5de321ecaea0ce66525f2cb9bc2c1dc8bd51480fa8f4e506626560b1865de6db4c17f67148fa9269085ca53f0
 DIST agate-excel-0.4.0.tar.gz 164270 BLAKE2B a45edd9b705ab6673ee4283fc4af7337f6d0ae4a8961b96f4917a4fe74709f5c8d94193e351a996b2d08c548ac9c232f0b1f352a7bd4d22b3f8281840900f75d SHA512 ecacba1ea75a91220e2462c44b1690d4d7ef1db3bee117ef1f4993614392137197f9fd2e4aaddf27a607179c529558fde3d4faa8d2c3fbbac86926ce860ed12c
+DIST agate-excel-0.4.1.tar.gz 271433 BLAKE2B 855f60c42726d73e76cd233c607b23b2c227404dc393afa38f6bf9dc4a65708f2644a252faede3d105c440a96e51181e30f7fcf5e80f57434d47d42ca17f9ca7 SHA512 934e8c0416df2e57b617095454aca14e202df1301779814841934452faf672e27a65628efee344df2873bece3731435fa40a6831321ed59a606810bd472d23b8
diff --git a/dev-python/agate-excel/agate-excel-0.4.1.ebuild b/dev-python/agate-excel/agate-excel-0.4.1.ebuild
new file mode 100644
index 000000000000..221f829e1a75
--- /dev/null
+++ b/dev-python/agate-excel/agate-excel-0.4.1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Adds read support for Excel files (xls and xlsx) to agate"
+HOMEPAGE="
+	https://github.com/wireservice/agate-excel/
+	https://pypi.org/project/agate-excel/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64-macos ~x64-macos"
+
+RDEPEND="
+	>=dev-python/agate-1.5.0[${PYTHON_USEDEP}]
+	dev-python/olefile[${PYTHON_USEDEP}]
+	>=dev-python/openpyxl-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/xlrd-0.9.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/aioresponses/Manifest b/dev-python/aioresponses/Manifest
index f2ca88e292df..2987e5f86499 100644
--- a/dev-python/aioresponses/Manifest
+++ b/dev-python/aioresponses/Manifest
@@ -1,2 +1,3 @@
 DIST aioresponses-0.7.4.tar.gz 35248 BLAKE2B e3046de1db4911429ff2bb50b011c7cdb33ad8460771bbe7cce969e29a74f29e5fe86b1ed488cbd9462706ce31e84a3bef08aec0e83ac6175c803d2e81900fbc SHA512 00392f8481e600e2c18563193aaf5b75a324ea49e90606e43a28ea787f75c55712bc2caff0a70411f51a9615b01a252fca1ebb9efd2cc314f6358eeeef6d1e59
 DIST aioresponses-0.7.5.tar.gz 35676 BLAKE2B 4d42137f67e27b0a91d3452630a7353db453c970a5689ab5f98aecfdf0877217b174d807f260c3d9736ceaadbab5fe84b7a025fc6233410029aeb5e5785925a1 SHA512 bae24aced48702f7971ba2ebb9268bbabf820270f321a87e840aa33421bdcf339d3c5375cc6df587889462f5d77276f8b1fd8e1f97da7f5d215247c0a58c85bb
+DIST aioresponses-0.7.6.tar.gz 35846 BLAKE2B f5cb820ee410e1203526ac6731c73f02993684679d788c8e3db830189d9874991b6fabf2e0738d14d3e54e2fa2b44af788f054137590ffea78df49056389673b SHA512 d02fa848a5d6588e32c203591f842cb212aae60d5e060a3fa13993bbb575922e516f04d47f9428c5f4b8103bc9990aa45cdde3c17bd2c47d8eff714f93976450
diff --git a/dev-python/aioresponses/aioresponses-0.7.6.ebuild b/dev-python/aioresponses/aioresponses-0.7.6.ebuild
new file mode 100644
index 000000000000..f5352053c644
--- /dev/null
+++ b/dev-python/aioresponses/aioresponses-0.7.6.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Helper to mock/fake web requests in Python's aiohttp package"
+HOMEPAGE="
+	https://github.com/pnuckowski/aioresponses/
+	https://pypi.org/project/aioresponses/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aiohttp-3.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# These tests require Internet access
+	tests/test_aioresponses.py::AIOResponsesTestCase::test_address_as_instance_of_url_combined_with_pass_through
+	tests/test_aioresponses.py::AIOResponsesTestCase::test_pass_through_with_origin_params
+)
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index e3a4b47310f9..8bc71d11afab 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -5,3 +5,4 @@ DIST boto3-1.29.0.gh.tar.gz 730038 BLAKE2B 3f6f853eaa18d66ffef1e159fb641e6e3d069
 DIST boto3-1.29.1.gh.tar.gz 731491 BLAKE2B 15d7aa771369afac957d1c0fac1c0cca9fb4322a7643d9dc2cb688908ab80c9f3815b92e9645266be0547d45959b6f2f20891ced2da0ab33df2de966dcfa510b SHA512 c07fb0bc3daab7aa6c21cec278b246b4df20f9e665b379f8005d2239a1d0bb637304d7308f1479b772ee314b99559bdb7f5c37503d6a9ef6801999270637cf87
 DIST boto3-1.29.2.gh.tar.gz 734398 BLAKE2B bc2816fd37130d4957873964b4020ec90f106fef5d034c4b47e9485610d577cdcac3106b66dcf20175335fcc49773dadcdabab9de65fb85caeddf5bea0845184 SHA512 dc5faf76f2949506db24888780cc07c792903707e54853258182a016b4b1b4f91ae79467e5f140ba0ce822d99e4fc570a16168211b10296bd9820eb245d9cbc5
 DIST boto3-1.29.3.gh.tar.gz 737012 BLAKE2B 4282de0bbe03b61cf6884b08cf0a16e93c1e27a0323d2eee93277f8ac62f5ef440612292ebc245f13de0bbac9c156cae0cd5c76e8ae5b7d018a125cd49a682df SHA512 e42064e2c825376dfe2a5aa0c92715d06d6d29c3cf8b194d8742c688a4743e216ba32111bba080d88505907e48ff26086106eaef62fa5048f34fcbf08355ab60
+DIST boto3-1.29.4.gh.tar.gz 737422 BLAKE2B afc98796b95bc82ca80e6fc20be8d3dd1ee786a23647628ff20822cb676bb520facd370828df1340d7515771fe879acbfde2d381109d0bb76c8fd430b1af9085 SHA512 a6b3d1aebc2594e0389acf090602276bea8ef1590f2beea285bb4dd9a8f5a81cf141a6f566c64fce5ab474830b84721f7d2833b80f06f0a531d6f64ac8c905c4
diff --git a/dev-python/boto3/boto3-1.29.4.ebuild b/dev-python/boto3/boto3-1.29.4.ebuild
new file mode 100644
index 000000000000..09d8c6679458
--- /dev/null
+++ b/dev-python/boto3/boto3-1.29.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index b61177cef1d0..f26e0ec0127c 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -5,3 +5,4 @@ DIST botocore-1.32.0.gh.tar.gz 12086167 BLAKE2B 54e580c4d034b437d1e2e7748f1dd478
 DIST botocore-1.32.1.gh.tar.gz 12098630 BLAKE2B 3a2501da4bd2ec8d29f032a2df4d7946840682df426b4496f60bab487b0eb47580314b4c3029dded6a589463a8636c362c560fd4c2da02c113647ee10ebf079d SHA512 4ec58dcf896ef46f27f3c4af7c6e58efad62e5c2e3fb9aa8de9a90ee390d65b036116d9d8ba7c766b95b03e6e85e909cc620b838511152004dbcfb67968525b4
 DIST botocore-1.32.2.gh.tar.gz 12148168 BLAKE2B 29a70ed37526b8b5e3439a183b194d350505dd4ad0ac1e5d2ff729be29813b4b99b2b0806ca2f20a776efdcefc2b46295432af281e026ecf014fe45d5317c528 SHA512 775c5076e691605d6efe392e5565b84314ed7c93300ea394e5598ee34f4bb9e708a2c8479fbd646fdb619d36e0122fd4f6854e9ed40430c069677345bd76e335
 DIST botocore-1.32.3.gh.tar.gz 12176739 BLAKE2B b119a54fb4770757c8f2c75b7404e009be1c7b35598d8a97e892aa644bbcc301b5f6bb44fa0f37bc8f4523af5ca9771daeda877937e640dd557038c8283967e1 SHA512 398127e140edc33750553f33a14cdc140048f5ee03c162705c6681b9bf08d871c9ba29f824ba2b6f1b11592260c6f0614ab4c06464cdda98172e8ca81bce73e9
+DIST botocore-1.32.4.gh.tar.gz 12176332 BLAKE2B 0b0c2b1b481f88b23dad830f22dee4a79e947705a7b975cfda8f33e0154554eda930bf6e9f2d8e96b639706ae62c7b3b880e210d61e480afcd66f24375a4e754 SHA512 b3f8202a9144be2b7fa3d4030816d87a88959cb0d8340d100038e2d5c115071d272337d1570f1ff19d372bdd70a8d2643fb2e86f286e9a1d466cf0c8d84f9a1f
diff --git a/dev-python/botocore/botocore-1.32.4.ebuild b/dev-python/botocore/botocore-1.32.4.ebuild
new file mode 100644
index 000000000000..9a0240c45f2a
--- /dev/null
+++ b/dev-python/botocore/botocore-1.32.4.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x EPYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/django-filter/Manifest b/dev-python/django-filter/Manifest
index 8625d3e489d2..8cd33a357042 100644
--- a/dev-python/django-filter/Manifest
+++ b/dev-python/django-filter/Manifest
@@ -1 +1,2 @@
 DIST django-filter-23.3.gh.tar.gz 137495 BLAKE2B 70049e744ec87a1dab9680144093684d3d23dd338a9b2d697de302b45e65bcd6f93c03c55ad5386ba1a7187e7ff5d1c43904f19cb17652ef6644b47a0f23101c SHA512 1da3f9bb1988d0b89d25f4101c26f4102d38e4717cdbd8d0cd4ae03a97658bfcc050afd3468ef6d0e33dc6533c7679f1906ddaccba8e7096a4bd570282a93c0a
+DIST django-filter-23.4.gh.tar.gz 137524 BLAKE2B 2ba4697e72f2a211860cd5571e76e4cb2c74a588112ea1570ea53cbb57358b178f9f64f651df471fbc06034ab6713e21e61ad83576adb29e3d758bbba965fa1f SHA512 ee564b3b67e355e6598adcc7b9046e4a3855a0dfd99cf551793c3a5c9797b0d87805b2b78b29f1e20de7e68337e6e1472205908f3b5cf26e36f554345b99cce9
diff --git a/dev-python/django-filter/django-filter-23.4.ebuild b/dev-python/django-filter/django-filter-23.4.ebuild
new file mode 100644
index 000000000000..b50704f477e2
--- /dev/null
+++ b/dev-python/django-filter/django-filter-23.4.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Django app allowing declarative dynamic QuerySet filtering from URL parameters"
+HOMEPAGE="
+	https://github.com/carltongibson/django-filter/
+	https://pypi.org/project/django-filter/
+"
+SRC_URI="
+	https://github.com/carltongibson/django-filter/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/djangorestframework[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		!!dev-python/coreapi
+	)
+"
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.settings
+	"${EPYTHON}" -m django test -v 2 || die
+}
diff --git a/dev-python/ensurepip-setuptools/Manifest b/dev-python/ensurepip-setuptools/Manifest
index 8b38c4be8ddd..381980d0266c 100644
--- a/dev-python/ensurepip-setuptools/Manifest
+++ b/dev-python/ensurepip-setuptools/Manifest
@@ -1 +1,2 @@
 DIST setuptools-68.2.2-py3-none-any.whl 807864 BLAKE2B 1ae4dab8a589c95281cac145c3e06b4027b585065a5191a9d6dd9c77730a096b592154863c555d8098c10425dfef315de3b79c6b631e8f6aacc0f234795f95fc SHA512 6e0d854040baff861e1647d2bece7d090bc793b2bd9819c56105b94090df54881a6a9b43ebd82578cd7c76d47181571b671e60672afd9def389d03c9dae84fcf
+DIST setuptools-69.0.0-py3-none-any.whl 819391 BLAKE2B 69b296d3f91a9aa35b9f01a3a9a49625677a9fc292163fbeac7e97b9ac7b2ac1a592feaf5c638705a8a586498f32adef187f24ed8f122014431a3c96f5d1c3bb SHA512 e52aeabb115aa65340b94ac4cede3c21b6a07f770fc2f17a59cc876557ee29f82d9149055b9c729b328271983bf0089f1b8392b4a77c9452bec2a0ff13cf353f
diff --git a/dev-python/ensurepip-setuptools/ensurepip-setuptools-69.0.0.ebuild b/dev-python/ensurepip-setuptools/ensurepip-setuptools-69.0.0.ebuild
new file mode 100644
index 000000000000..8346a1bd0f6d
--- /dev/null
+++ b/dev-python/ensurepip-setuptools/ensurepip-setuptools-69.0.0.ebuild
@@ -0,0 +1,24 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pypi
+
+DESCRIPTION="Shared setuptools wheel for ensurepip Python module"
+HOMEPAGE="https://pypi.org/project/setuptools/"
+SRC_URI="$(pypi_wheel_url "${PN#ensurepip-}")"
+S=${DISTDIR}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	!<dev-python/ensurepip-wheels-100
+"
+
+src_install() {
+	insinto /usr/lib/python/ensurepip
+	doins "${A}"
+}
diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index 1dbea020632f..36b556deeec7 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -2,3 +2,4 @@ DIST fonttools-4.43.1.gh.tar.gz 3770153 BLAKE2B d5abb086605126bbb814f4631e1da412
 DIST fonttools-4.44.0.gh.tar.gz 3771969 BLAKE2B 26a9bef8e6f5595bca8a27ca1b46cfa16c2bb5741d82fdf203be163510f1380b76307e3fb4921200b49d422ef602134f399a502087dd4dc6ff959871deb92ef6 SHA512 c665e0cae9b486f5373eb775d3a38a2b5a794ce64a112cf83f1e86d1433481944c8db1b30a5c6ed047f3639ebe63ddcad800a871a9289d186be67c9c8c0afa0a
 DIST fonttools-4.44.1.gh.tar.gz 3772404 BLAKE2B 75ea507c234846e26d3e1693c3ae8c23ac45c1ed0496958cf9589928e2918b496038f8729c7418080adf64e94a1ae0cb156e2b5925b69885660225daa8596359 SHA512 574dc1661c5b6cd63d70f4195f06e2dc6fe75bf84912720390314c2b3ed5edaaf05cc8879520b356857aef4cfd23ef2ae4c42c5cf5048359be63f757644d95b2
 DIST fonttools-4.44.3.gh.tar.gz 3775926 BLAKE2B fcc482ffa6163f895cf6ea8721dae3ce85beea3bbf3d19c30e5f2a681356e66ff5ffc3ee4b228244eaebbcc76e397ec1e841ed3f96fda2eb2561e26f0b90a174 SHA512 cedac35c1273d95785095678a90aef58307b5c66bcd3c2e4f72f6642412265e783afc5e0e1e4cff77ceb31f1f5406ae24d130856c41821998da94e088628823e
+DIST fonttools-4.45.0.gh.tar.gz 3785706 BLAKE2B d5e9d4ec5b04e789379834846b4545a3aac7c793127aff017a09fd07439413890919241a3692416b7f570ccb8b41e86d46a7f3a132d86357b1c8f63a1cbc1b9f SHA512 6132912f547e5b74f06749bf098cd31e27b1ff4ecfee874a29a1b82d339575b94e5f1580ee4d5b8b7588ae7382f298fd5ef537b165477a2f37e9112d51c58c2d
diff --git a/dev-python/fonttools/fonttools-4.45.0.ebuild b/dev-python/fonttools/fonttools-4.45.0.ebuild
new file mode 100644
index 000000000000..359187240e25
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.45.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="
+	https://github.com/fonttools/fonttools/
+	https://pypi.org/project/fonttools/
+"
+SRC_URI="
+	https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="+native-extensions"
+
+RDEPEND="
+	>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	local -x FONTTOOLS_WITH_CYTHON=$(usex native-extensions)
+	[[ ${EPYTHON} == pypy3 ]] && FONTTOOLS_WITH_CYTHON=0
+	distutils-r1_python_compile
+}
+
+src_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	if [[ ${EPYTHON} == pypy3 ]] &&
+		has_version "dev-python/pyxattr[${PYTHON_USEDEP}]"
+	then
+		EPYTEST_DESELECT+=(
+			# affected by a bug in PyPy/pyxattr
+			# https://github.com/iustin/pyxattr/issues/41
+			Tests/t1Lib/t1Lib_test.py::ReadWriteTest::test_read_with_path
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest Tests fontTools || die -n "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/keystoneauth1/Manifest b/dev-python/keystoneauth1/Manifest
index d4fbd09d6211..d137c911bd60 100644
--- a/dev-python/keystoneauth1/Manifest
+++ b/dev-python/keystoneauth1/Manifest
@@ -1 +1,2 @@
 DIST keystoneauth1-5.3.0.tar.gz 274216 BLAKE2B 873a0bde2507b4b4b2bfc748d77b1c0b8be321c51cff0376020e84a63cebd030b118c90765302ce8cd51467f5c615a9b289480a1105f4d7a4a86e96fe44f7089 SHA512 91a9f9359926932a2e78a9164f8a1f2d08da306cc83f011f9a19535795b6a7faa3af0673665444532893325a2fe752f1d6a18e04b84ea1b3db8c9d1647b4f3cb
+DIST keystoneauth1-5.4.0.tar.gz 275020 BLAKE2B 10ef3799f4f3d06e966816cb6e6802511597e7371f96a75f31abfb2ad33832e90588b466fe0653ab0e7fb6728564e4b056bd208ee08184d7e44a6f230ac1b66f SHA512 874de3a0dded74ca96727b7c0149cdaddf2e3576632e76f84ca4d1810379f9db46ad4139317e36c5815d3340d18e12372bc1c942868c07e9f2800a53356142fc
diff --git a/dev-python/keystoneauth1/keystoneauth1-5.4.0.ebuild b/dev-python/keystoneauth1/keystoneauth1-5.4.0.ebuild
new file mode 100644
index 000000000000..3de8180cff78
--- /dev/null
+++ b/dev-python/keystoneauth1/keystoneauth1-5.4.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="This package contains tools for authenticating to an OpenStack-based cloud"
+HOMEPAGE="
+	https://opendev.org/openstack/keystoneauth/
+	https://github.com/openstack/keystoneauth/
+	https://pypi.org/project/keystoneauth1/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/betamax-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oauthlib-0.6.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+		>=dev-python/requests-kerberos-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/testresources-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fragile to test runner name
+	keystoneauth1/tests/unit/test_session.py::SessionTests::test_user_agent
+)
+
+EPYTEST_IGNORE=(
+	# require hacking
+	keystoneauth1/tests/unit/test_hacking_checks.py
+)
diff --git a/dev-python/nbval/nbval-0.10.0-r1.ebuild b/dev-python/nbval/nbval-0.10.0-r1.ebuild
index f0e49d208abf..f4eabffae9aa 100644
--- a/dev-python/nbval/nbval-0.10.0-r1.ebuild
+++ b/dev-python/nbval/nbval-0.10.0-r1.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
 
 inherit distutils-r1 pypi
 
@@ -26,7 +26,6 @@ RDEPEND="
 "
 BDEPEND="
 	test? (
-		dev-python/nbdime[${PYTHON_USEDEP}]
 		$(python_gen_cond_dep '
 			dev-python/sympy[${PYTHON_USEDEP}]
 		' python3_{10..11})
diff --git a/dev-python/notebook/notebook-7.0.6.ebuild b/dev-python/notebook/notebook-7.0.6.ebuild
index a8ce8a7e2389..9fb257fae910 100644
--- a/dev-python/notebook/notebook-7.0.6.ebuild
+++ b/dev-python/notebook/notebook-7.0.6.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
 PYTHON_REQ_USE="threads(+)"
 
 inherit distutils-r1 pypi xdg-utils
diff --git a/dev-python/prometheus-client/Manifest b/dev-python/prometheus-client/Manifest
index 30fcf10e9c98..82c5df90907d 100644
--- a/dev-python/prometheus-client/Manifest
+++ b/dev-python/prometheus-client/Manifest
@@ -1,2 +1,3 @@
 DIST prometheus_client-0.17.1.tar.gz 90360 BLAKE2B 3927d5b6829a04cd72a99ac3b0b6a12726865b41d17f165a53f83a6a3791f18e25e03995088152ac7eae016eab7c6e29bef1e605f4c444f9963be04483ca2f02 SHA512 c8c776d646ea4a18a85fd26c858158b67979173dcf52d0a337cdb87fe907ff4081d8e0771176ba8be0ea6e244ee9b9097396c9aeb6f6db170a2c0f5a4898c771
 DIST prometheus_client-0.18.0.tar.gz 92365 BLAKE2B 2443fda2ae6f23cc817d4adbb63799501d7e688c2f10b876ed7dbb0f5efdd31d5ca7300fefc059a65533205155682e567c31eebe3e10b173bde4c018a17c65c9 SHA512 97ae14d549b3559f8e8136f56cde593ed2ef6303577e98e6f20367589d5df0e9630e9c13accf57609dfbb364527632c665e21f0778b0fd14cea5446495432ffb
+DIST prometheus_client-0.19.0.tar.gz 77791 BLAKE2B 494895efc0b08dc0494f82db3c3f23ff07669579b65ad150b7c2ca64d1807c6da8cd0889244c6294f3b7eb5fb07058a260da03f30ae5fd4c47e3d8b118d1bc8a SHA512 8d0f14130916d79fe43380d3eb38ed16e9883c83528131067f147f1651a4509557b32243e7cfa92242de1e31a2bfd7784f77cc0e4e6723bdccb841fd0fe139d7
diff --git a/dev-python/prometheus-client/prometheus-client-0.19.0.ebuild b/dev-python/prometheus-client/prometheus-client-0.19.0.ebuild
new file mode 100644
index 000000000000..b7f6178e331b
--- /dev/null
+++ b/dev-python/prometheus-client/prometheus-client-0.19.0.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python client for the Prometheus monitoring system"
+HOMEPAGE="
+	https://github.com/prometheus/client_python/
+	https://pypi.org/project/prometheus-client/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/twisted[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pyasn1/Manifest b/dev-python/pyasn1/Manifest
index 57a8e949c090..1c1c94004c59 100644
--- a/dev-python/pyasn1/Manifest
+++ b/dev-python/pyasn1/Manifest
@@ -1 +1,2 @@
 DIST pyasn1-0.5.0.tar.gz 145117 BLAKE2B dbbec0bebcfe11b8de983716fedf1bf28e6bcf7d5f89e3dcba929884347cc7cd3a8ef8b5ec44bbc799a7bae3de39c90cf5e48111384de571dc2034a79c3bb52b SHA512 763690184ce891555564d76902042791865815e59e1325100fca692140110e5e182ef3da84ffdf96b1876edeb2757bbb09c06d26e752a8110760dafbf9e3ca00
+DIST pyasn1-0.5.1.tar.gz 147134 BLAKE2B 3f209b845af307cf17d701ff6c6a1674978ed6a14b5132cfe1171d2560f0932c7f940364b247e5e2162b27bb807c44720a08af1b490d2ff665cea86fdfb66b6b SHA512 19478d810d000fb4435f6a1776f290b1618a693539ff8ffad8c41f9ac316938f1c0ae988db8571a838443407d312b5566887e20284a779ccf427888739f13833
diff --git a/dev-python/pyasn1/pyasn1-0.5.1.ebuild b/dev-python/pyasn1/pyasn1-0.5.1.ebuild
new file mode 100644
index 000000000000..ba56e0c988fc
--- /dev/null
+++ b/dev-python/pyasn1/pyasn1-0.5.1.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="ASN.1 library for Python"
+HOMEPAGE="
+	https://pypi.org/project/pyasn1/
+	https://github.com/etingof/pyasn1/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx "docs/source"
diff --git a/dev-python/pygal/Manifest b/dev-python/pygal/Manifest
index 3f19d1211fe4..576ee1221c43 100644
--- a/dev-python/pygal/Manifest
+++ b/dev-python/pygal/Manifest
@@ -1 +1,2 @@
 DIST pygal-3.0.0.gh.tar.gz 3575455 BLAKE2B 9b64cf441aeb25b0a0b9834f07e5892fe163f28a5da796d37083f8f3a10d8737a69bad39e503d722e6a36f2de4367b4fd2bdc3a06c5bc30bce66a370690d9c88 SHA512 71ac9f197d711c8cf5bb47caef128754f81b1cb0ba98c4cc67de78b68fca5d40baae9fbb5c978f6abaed4c73b8edfea2de07de2fda1aa7c15e0d81387518cc49
+DIST pygal-3.0.3.gh.tar.gz 3575707 BLAKE2B 32dfb09f7dc5f97c758ff516a131da7ab82afb58028d710017af01220dbee57579cadc56e4b9ae207d71ad7d71d05dd14bd876c563f61f18263a0c2a839c0183 SHA512 052852552e0f07194acc832a953cc69131f2640216c22d5f7e5860b98ad80f24a5532a58b52903fedfcdb6e48331e4c8c02be54e90468476ca3f720be8845985
diff --git a/dev-python/pygal/pygal-3.0.3.ebuild b/dev-python/pygal/pygal-3.0.3.ebuild
new file mode 100644
index 000000000000..2d5afdff7f49
--- /dev/null
+++ b/dev-python/pygal/pygal-3.0.3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A python SVG charts generator"
+HOMEPAGE="
+	https://github.com/Kozea/pygal/
+	https://pypi.org/project/pygal/
+"
+SRC_URI="
+	https://github.com/Kozea/pygal/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pyquery[${PYTHON_USEDEP}]
+		media-gfx/cairosvg[${PYTHON_USEDEP}]
+	)
+"
+
+# CHANGELOG is a symlink to docs/changelog.rst
+DOCS=( docs/changelog.rst README.md )
+
+distutils_enable_sphinx docs
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Not actually required unless we want to do setup.py test
+	# https://github.com/Kozea/pygal/issues/430
+	sed -i -e "/setup_requires/d" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "improving rendering speed" "dev-python/lxml"
+	optfeature "png rendering" "dev-python/cairosvg"
+}
diff --git a/dev-python/recurring-ical-events/Manifest b/dev-python/recurring-ical-events/Manifest
index c16611a6a023..0188b3b9ebd0 100644
--- a/dev-python/recurring-ical-events/Manifest
+++ b/dev-python/recurring-ical-events/Manifest
@@ -1,2 +1,3 @@
 DIST python-recurring-ical-events-2.0.2.gh.tar.gz 326754 BLAKE2B 1df6ffaf08e991ca49360f586abda344a9967e9fe0446a367920d6fe502aea20af35bb976b7a030d47f0b34388e7f169027e4106fc7c317d3a68358af812d40f SHA512 377f2f974cf0ce141d6c4f32aafe1b55339121229a74d66647d6779c1bec3ec4ede47a0c1353692c5eb3d5a6144b53f1fef3150343b503884c1d1d241138b65d
 DIST python-recurring-ical-events-2.1.0.gh.tar.gz 327954 BLAKE2B 8dae03b538e961fa18b51d6ecfd3d0818a64a44ebd9811370a7c78e8b897f38cad520d692fcc6e1c93751f500d8fd6072f0ce86ee9ac947b0aab7c82fcc3d9f7 SHA512 8e8e0d18e110be01f60a4834d21794d7a595413d109af88f44896d75db4c37176020f1f4fd74dc81c2f76d1e3654bc77c97240a6163444b0449a08178bb22c27
+DIST python-recurring-ical-events-2.1.1.gh.tar.gz 328303 BLAKE2B 204ca63f87829cab0b4fd972027fbdabdcd027a0cc2fb1d42b70c517b5de69aa177a68e3a0ec051b326bce69cb4d341939ab4e53020f4fe5155476ad7dba5205 SHA512 d77f71317da8df3d71105b5c2ce08f33854df423b0b10e2dba117737832cc7b2257bd3d3b6f6d8470bea0beb7b5e6bc695e8204e02e3d8118cedf6a16e45f0cf
diff --git a/dev-python/recurring-ical-events/recurring-ical-events-2.1.1.ebuild b/dev-python/recurring-ical-events/recurring-ical-events-2.1.1.ebuild
new file mode 100644
index 000000000000..323439f4e47d
--- /dev/null
+++ b/dev-python/recurring-ical-events/recurring-ical-events-2.1.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P=python-${P}
+DESCRIPTION="Repeat ICalendar events by RRULE, RDATE and EXDATE"
+HOMEPAGE="
+	https://github.com/niccokunzmann/python-recurring-ical-events/
+	https://pypi.org/project/recurring-ical-events/
+"
+SRC_URI="
+	https://github.com/niccokunzmann/python-recurring-ical-events/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/icalendar-6[${PYTHON_USEDEP}]
+	>=dev-python/icalendar-5.0.9[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2023.3[${PYTHON_USEDEP}]
+	<dev-python/x-wr-timezone-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/x-wr-timezone-0.0.5[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	test/test_readme.py
+)
+
+EPYTEST_DESELECT=(
+	# a test checking if tzdata package is installed that is apparently
+	# needed for other tests, except it isn't
+	test/test_zoneinfo_issue_57.py::test_zoneinfo_must_be_installed_if_it_is_possible
+)
diff --git a/dev-python/rpds-py/Manifest b/dev-python/rpds-py/Manifest
index f5ac3fed79a3..985ecd337cb8 100644
--- a/dev-python/rpds-py/Manifest
+++ b/dev-python/rpds-py/Manifest
@@ -32,6 +32,7 @@ DIST rpds_py-0.10.4.tar.gz 16496 BLAKE2B b9e9c67cbd1f49e1f495d9ec455ac07354e5441
 DIST rpds_py-0.10.6.tar.gz 16514 BLAKE2B b3df3d79b22fe102e96b5d56cfac97d30b2de0ce05ecc82227f411aca2ae39aa3c10171e08f850e58c60faac5dd9cfb5f1f0eb0559d8dc3ac18d530b8c6b95d3 SHA512 4e887e57c59372f48b87ec10a810a65d0ff1ba2fc7587cc4f4da78d8394a78a91d84a7a7b8ad810bd1f34f4e73ad706628dbc2bd25662c9e4f83e4183c280ab1
 DIST rpds_py-0.12.0.tar.gz 16723 BLAKE2B b4839a0d463a22cbd36956c171afa625b9e3faffc8b63d907268b4b50ee95b4130f8105bb67da46458959d9800c035364f85375e5f038b918595fc53ad551043 SHA512 8495862fb41f3e1272428fa8262e4738b9fe2b85c38e50f5b786ed11ee20a98e28c421c9090dc9d21ee5f1065df0f89d8cffd19cff6f245c17d027b8733d8928
 DIST rpds_py-0.13.0.tar.gz 17004 BLAKE2B 02c813d7d24aca2e2227f25aeeb9083af19c5a98f45674b7c624e927cfee46e6dfde817638e2ebb6696cce755b151a458cd374ab6db755af751c12ced0274ee7 SHA512 8832552e486ed217a84ebfba8c9f09ca1e117acca4206d6936aaa0120b6e2944fdcc4fa10a69350443926169e7a1401fd64163f81db86611122b985e216a5045
+DIST rpds_py-0.13.1.tar.gz 17008 BLAKE2B e8fbc559ead936ae378d26dd6c0b704ab53b5bc41fe0a1bab67e48b8a627b43060b454f6915b2653d78f2f8e0f1d623f77db96c821bc2a25a3141fa145b5f5a3 SHA512 1cc901ae5bbfbbfdd14df4ff988dc3ffd75c5ac60acdec4dea9ddc30b9849ee12bf9ac05377bdf29a8db58919ceda51ef2fbb66885567608f1268baa1fa3eba1
 DIST scopeguard-1.1.0.crate 11470 BLAKE2B f774eb90b7d3ffb2efba47518e9d1dead4017ab4b38a4bd74914daa84a5af4bf9eb63da0496e3924499d79cd0439c37447aeda4a21226f95645bddcd6becfabe SHA512 368fa5726df8f42b599993681579a9ffd0196480ee3cd0f9f671e8493f3bedd1e1779bdf2beb329e77e0005fa09b816e3385f309490c0f2781568db275d4d17d
 DIST smallvec-1.11.0.crate 34680 BLAKE2B e54d56f6bbffbfa7ce5fe5f04e325b2e5cf19d290e4be278bc00a136e26284625b9c18c7c2b10b7fb8fad0ea7e3770f3cdbcfbaa913f5ac08d0a2f8b4e0de188 SHA512 41bfbecbc2c244497568a41724d65791ec3fd6d8057813d521367cca316c09c2b28fb3973826236b01c1f5d2f905d8d22b0c3c47f957a9ff5d7685591f15ccd7
 DIST static_assertions-1.1.0.crate 18480 BLAKE2B 358dd5ac413d06f62da0388e2016c5fcb8ec68fd7dceb0dbbcb97665c032b7509b7e083c20701648b6a9174485f117c02682ae4bde7ef037e80a85cdf6a0c86e SHA512 46d0e35f77941dee6f60f574c130472248063dc38494c1c4f84f7c048244cc2a58a86fe17c0990e3f0f01406b75ed385a13d00058612b27cf0e867c8d31c92ee
diff --git a/dev-python/rpds-py/rpds-py-0.13.1.ebuild b/dev-python/rpds-py/rpds-py-0.13.1.ebuild
new file mode 100644
index 000000000000..eecf229f538e
--- /dev/null
+++ b/dev-python/rpds-py/rpds-py-0.13.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=maturin
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+CRATES="
+	archery@1.1.0
+	autocfg@1.1.0
+	bitflags@1.3.2
+	cfg-if@1.0.0
+	heck@0.4.1
+	indoc@2.0.4
+	libc@0.2.147
+	lock_api@0.4.10
+	memoffset@0.9.0
+	once_cell@1.18.0
+	parking_lot@0.12.1
+	parking_lot_core@0.9.8
+	proc-macro2@1.0.66
+	pyo3-build-config@0.20.0
+	pyo3-ffi@0.20.0
+	pyo3-macros-backend@0.20.0
+	pyo3-macros@0.20.0
+	pyo3@0.20.0
+	quote@1.0.31
+	redox_syscall@0.3.5
+	rpds@1.1.0
+	scopeguard@1.1.0
+	smallvec@1.11.0
+	static_assertions@1.1.0
+	syn@2.0.32
+	target-lexicon@0.12.9
+	triomphe@0.1.9
+	unicode-ident@1.0.11
+	unindent@0.2.3
+	windows-targets@0.48.1
+	windows_aarch64_gnullvm@0.48.0
+	windows_aarch64_msvc@0.48.0
+	windows_i686_gnu@0.48.0
+	windows_i686_msvc@0.48.0
+	windows_x86_64_gnu@0.48.0
+	windows_x86_64_gnullvm@0.48.0
+	windows_x86_64_msvc@0.48.0
+"
+
+inherit cargo distutils-r1 pypi
+
+DESCRIPTION="Python bindings to Rust's persistent data structures (rpds)"
+HOMEPAGE="
+	https://github.com/crate-py/rpds/
+	https://pypi.org/project/rpds-py/
+"
+SRC_URI+="
+	${CARGO_CRATE_URIS}
+"
+
+LICENSE="MIT"
+# Dependent crate licenses
+LICENSE+=" Apache-2.0-with-LLVM-exceptions MIT MPL-2.0 Unicode-DFS-2016"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/rpds/rpds.*.so"
+
+distutils_enable_tests pytest
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index ec745d1fee82..ecc86b6dd142 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -1 +1,2 @@
 DIST setuptools-68.2.2.tar.gz 2203338 BLAKE2B 3d91bd4b4be1fb7a01b0cca1736187b80f9b07d0e647b49b483d6b8da55f69a678d2c910cde46bd9645dbd10b0b1d14c124d111817cbd7be8d5fab909f787998 SHA512 ed3138a39e8ae47d695e71835024d66d63b8de51aa336bd8524de81a5036aa26cf587caca5d6b46c833f77a6e9c8c1ae6b64e8310f712bd9c4e760196778b2ca
+DIST setuptools-69.0.0.tar.gz 2219067 BLAKE2B 3df4e54e2c958b07af0d8ceb58678991ebb01952db90115eaabeb59f1643a67173add5f12fd1ad2e3992f2fcf9bacbfcbbb72e8c7e9d76bdfeaf0556ecc600bf SHA512 652d237fb15d187ede8f1da0406fdf5ba59b04278daf6b24f1ad2e938dabf6c543615926715037ee4f92809ef51c0201a6b595c6034e4d4c3c768ec47bb5e694
diff --git a/dev-python/setuptools/setuptools-69.0.0.ebuild b/dev-python/setuptools/setuptools-69.0.0.ebuild
new file mode 100644
index 000000000000..0b9b53161043
--- /dev/null
+++ b/dev-python/setuptools/setuptools-69.0.0.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+# setuptools-scm is here because installing plugins apparently breaks stuff at
+# runtime, so let's pull it early. See bug #663324.
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+	)
+
+	distutils-r1_src_prepare
+
+	# remove bundled dependencies
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# fails with importlib-metadata-6.6.0
+		setuptools/tests/test_egg_info.py::TestWriteEntries::test_invalid_entry_point
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+	)
+
+	if has_version "<dev-python/packaging-22"; then
+		EPYTEST_DESELECT+=(
+			# old packaging is more lenient
+			setuptools/tests/config/test_setupcfg.py::TestOptions::test_raises_accidental_env_marker_misconfig
+		)
+	fi
+
+	local EPYTEST_XDIST=1
+	epytest setuptools
+}
diff --git a/dev-python/sphinx-gallery/Manifest b/dev-python/sphinx-gallery/Manifest
index 3e1bc69619c8..71a48b6566c9 100644
--- a/dev-python/sphinx-gallery/Manifest
+++ b/dev-python/sphinx-gallery/Manifest
@@ -1 +1,2 @@
 DIST sphinx-gallery-0.14.0.tar.gz 408734 BLAKE2B f527eb58b565353722d669edf81a667b7c3e784480500ff03b5567b9214c27951438052db3f2dcba92b24e7224d5cd0017bfbe770132dc96ce3427ca463329a8 SHA512 c8a69af9dec9adf042214de0cb48d510ebb41d7bc4bb1e5767f3982b0e83d9dfa1a26028d939a1785d3894894d396840e437dc5c196bfc5318152d06240d84b9
+DIST sphinx-gallery-0.15.0.tar.gz 422363 BLAKE2B cbca8ec252e03e9cacc0df27da43ebc9bbed8531d5df65bf9cb7f54f7ae8b127582f353cb245bcc459d6fa86240207346a05d777504163d49be0fabb029a172b SHA512 b6b0d5022da9de27417f8cc72ba24f0d51e57f83c68b17a296269b074888a711d61fcf933fbbfaf4d6977702b3f020d4b0eaa89e78e51185ee2dd26e911fe8be
diff --git a/dev-python/sphinx-gallery/sphinx-gallery-0.15.0.ebuild b/dev-python/sphinx-gallery/sphinx-gallery-0.15.0.ebuild
new file mode 100644
index 000000000000..e8ab7415c421
--- /dev/null
+++ b/dev-python/sphinx-gallery/sphinx-gallery-0.15.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Sphinx extension to automatically generate an examples gallery"
+HOMEPAGE="
+	https://github.com/sphinx-gallery/sphinx-gallery/
+	https://sphinx-gallery.github.io/
+	https://pypi.org/project/sphinx-gallery/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/joblib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		sphinx_gallery/tests/test_docs_resolv.py::test_embed_code_links_get_data
+		sphinx_gallery/tests/test_full.py::test_run_sphinx
+		sphinx_gallery/tests/test_full.py::test_embed_links_and_styles
+		# require jupyterlite_sphinx
+		sphinx_gallery/tests/test_full.py
+		sphinx_gallery/tests/test_full_noexec.py
+		sphinx_gallery/tests/test_gen_gallery.py::test_create_jupyterlite_contents
+		sphinx_gallery/tests/test_gen_gallery.py::test_create_jupyterlite_contents_non_default_contents
+		sphinx_gallery/tests/test_gen_gallery.py::test_create_jupyterlite_contents_with_jupyterlite_disabled_via_config
+	)
+
+	epytest -o addopts=
+}
diff --git a/dev-python/sqlglot/Manifest b/dev-python/sqlglot/Manifest
index 2960c4648157..213c93630a24 100644
--- a/dev-python/sqlglot/Manifest
+++ b/dev-python/sqlglot/Manifest
@@ -1,3 +1,4 @@
 DIST sqlglot-19.4.0.tar.gz 9056050 BLAKE2B 23d5a9bdd7bfa27128e624406f52488e90ec475c355fde6e5e7ac77bee5ae84dd1abeb2c87896f3fbc418dbe0b818e66f1d76b7e24514315e194b6bd58677203 SHA512 f0f6f4d4eca3d97ac9cd200e6a5e8df5a2c2b9e6d84dd87f19ab29b1af0c6cb55c62e28c9c7faa34425a6cfb0583b02d387b7cd744fec40419927016cd05d51e
 DIST sqlglot-19.5.0.tar.gz 9060496 BLAKE2B 190c4b507e3c630a46a493f72698f48749fc4f0e6444a2ee61499d35a5f56563b402e8947531b20c100df8ffc3af86cc45b8e1e11e7b467ec3bcd6261b880619 SHA512 3e3cbf7c9bac33b9dc0ad26021a78d534cb6ac61aae6d96c5f652938fd4efb5eca52854ca7ef02fa9ec6a989a6c80eaab31b210c932cb286b2ea8e4aace7fcf9
 DIST sqlglot-19.5.1.tar.gz 9062537 BLAKE2B dece9479e8333cf90481e7f72bfd58c0d36506b4e1bc1282b4e2c677ccfd24da7e04a6eddf1ecca16ccc83e8079b61eef8cabe3a6ef6a2b96df56c1a5b3e89a7 SHA512 eaf6090a001c162612503714d47225f1fdb5f0d19974e93bb76f87aa4e101fec5ed0045c4f74f2e55b58368170b449eabbd87569f16fc3ea73a14df909b007c4
+DIST sqlglot-19.6.0.tar.gz 9063326 BLAKE2B ad2d12f511d8bf713fc51b67364133b648186b91351137f339dbb97500a50450db5cc39f016f03260d4c79f4341338dd4fee88fe6f5491bf556d93a4806ac411 SHA512 9f5d2fd6364fbeacca328f9fdcb84204ef65906fd024059464ecac9cc7c7865cf4736cc17a3661af1fda5ca0e52fb24f3939a263349c75a962216af8bd6841f4
diff --git a/dev-python/sqlglot/sqlglot-19.6.0.ebuild b/dev-python/sqlglot/sqlglot-19.6.0.ebuild
new file mode 100644
index 000000000000..ac53f7b0ad7d
--- /dev/null
+++ b/dev-python/sqlglot/sqlglot-19.6.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi optfeature
+
+DESCRIPTION="An easily customizable SQL parser and transpiler"
+HOMEPAGE="
+	https://sqlglot.com/
+	https://github.com/tobymao/sqlglot/
+	https://pypi.org/project/sqlglot/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+EPYTEST_IGNORE=(
+	# Tests require pyspark or duckdb which aren't in the tree.
+	# Pandas would be a requirement normally, but it gets ignored by proxy.
+	"tests/dataframe/integration/test_dataframe.py"
+	"tests/dataframe/integration/test_grouped_data.py"
+	"tests/dataframe/integration/test_session.py"
+	"tests/test_executor.py"
+	"tests/test_optimizer.py"
+)
+
+distutils_enable_tests pytest
+
+pkg_postinst() {
+	optfeature "simplifying timedelta expressions" dev-python/python-dateutil
+}
diff --git a/dev-python/txtorcon/Manifest b/dev-python/txtorcon/Manifest
index 021c0fbb9e57..6907e7a34aa5 100644
--- a/dev-python/txtorcon/Manifest
+++ b/dev-python/txtorcon/Manifest
@@ -1 +1,2 @@
+DIST txtorcon-23.11.0.gh.tar.gz 395211 BLAKE2B 156c1c1d7e1d88939051ea19f4cd955e3a329dd1a550ea1a35d6c984db66d9b8e7fff35b2aa5caa12589273b46c1ce65d802fe89ce2a57443e0b5ce592247ee0 SHA512 815aecd8b6f3d12be1f903ba4dbb037e5f5920d925ca06c9f92a040d8258c4c1182ae5fca0be26fd2adb529c1726ad9ee080ddcada56e3e8b9922f7295731df3
 DIST txtorcon-23.5.0.gh.tar.gz 394188 BLAKE2B ee63d2815a9b697aa37d27697ef6085dc91e750ba0cad854c8610eed7afcfec9b50cf5aead24f75676e2b0ee39167c50fbebc43a51911a3ebe17eb784b18d31e SHA512 33610c043084273f5dc06b797fff11bb0fccaae14229dbd07286e13e40ebc199594f6e52c64b87e4060e37bcb44bd90ccf7ff7217d923fdb33a581fb95144d56
diff --git a/dev-python/txtorcon/txtorcon-23.11.0.ebuild b/dev-python/txtorcon/txtorcon-23.11.0.ebuild
new file mode 100644
index 000000000000..23ce15a10b67
--- /dev/null
+++ b/dev-python/txtorcon/txtorcon-23.11.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="Twisted-based Tor controller client, with state-tracking abstractions"
+HOMEPAGE="
+	https://txtorcon.readthedocs.org/
+	https://github.com/meejah/txtorcon/
+	https://pypi.org/project/txtorcon/
+"
+SRC_URI="
+	https://github.com/meejah/txtorcon/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/automat[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/twisted[ssl,${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		sys-process/lsof
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/wcwidth/Manifest b/dev-python/wcwidth/Manifest
index fda859daf7c8..18695f193f21 100644
--- a/dev-python/wcwidth/Manifest
+++ b/dev-python/wcwidth/Manifest
@@ -1,3 +1,4 @@
 DIST wcwidth-0.2.10.gh.tar.gz 92276 BLAKE2B 69347446b6571feb68871a6195bfe6718f23d8a21332cda839bb41f2a540d222265065a1194e26d22a166d1d90fb4d5237703af96a8f1737c2f09d126ec2d623 SHA512 207e0086080e33f1e42728eb81c4543ebb21f08e2a743fbd29d64f3f5ee21a1f12c9b298fcc64df6eae646900c7858ba4a845a9b510d525f2582359b7c6a50aa
+DIST wcwidth-0.2.11.tar.gz 99709 BLAKE2B 543eb98d7b49958a04a298705eacddf4bca954a0a5f2da25e49da1d2bc7226b1fe5b58079bbf372e6ddc27d66302527cc6440fc034748a1a035458fd658349be SHA512 798a5f062fb3825ac6a4942e50dbff270962715e05e2ed40e465040264cfb4096aa6c857b4338fa2dc14918365e9e73cf9b722ee140bc257d79b00941ed1b705
 DIST wcwidth-0.2.8.tar.gz 61713 BLAKE2B ca3d0c58e2ccab0fbb5493aacc8df81e9dc1faf7572543b7aa277875d617e0d4dc0c5ff6032f5f0f3846f52f26c407ddc5dd941780411572bce8ddc467a33dd7 SHA512 4a9ac4a3068c8ac25a7073d6c5e5782c3915184929ee191a2169eca510668e6e0b15856e71bd8b8d4c580767542d695b25a370329e95da317295104b962737f1
 DIST wcwidth-0.2.9.tar.gz 66133 BLAKE2B 7df656c139c228324427e6be9cefe3496b7b5e55d7353f062ae4cb3d7d5988f1e5e03e11122c0e045b7a93abd95139fc2ac8a81a4d079518cc8c6fa747d2ff00 SHA512 8aff2ce67d8f331c4c75907f14ec602f4829d39e3f89af640d598e075165a011e41a5451a333bc2f6c95f33a4b9ca8ae1a5d02efe4f79acc988d60b85bf5929b
diff --git a/dev-python/wcwidth/wcwidth-0.2.11.ebuild b/dev-python/wcwidth/wcwidth-0.2.11.ebuild
new file mode 100644
index 000000000000..d7000ef04ce3
--- /dev/null
+++ b/dev-python/wcwidth/wcwidth-0.2.11.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Measures number of Terminal column cells of wide-character codes"
+HOMEPAGE="
+	https://pypi.org/project/wcwidth/
+	https://github.com/jquast/wcwidth/
+"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -o addopts=
+}
+
+python_install_all() {
+	docinto docs
+	dodoc docs/intro.rst
+	distutils-r1_python_install_all
+}