Adding metadata

17 files changed, 282 insertions, 33 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 762a8040e99e..5c6258a59ef1 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,4 +3,5 @@ DIST boto3-1.18.15.tar.gz 400374 BLAKE2B 2170319480578b9ac7b6c0da9e9a2f256ce907b
 DIST boto3-1.18.18.tar.gz 401335 BLAKE2B c5bdccfe065444d726a7115042de4bb4294905da589fe31e7576f99ad53e4c4eea5940909ee39adf2f2dc4457dc049ef5905d2b2523300009cf00fc772506b0f SHA512 201c97c8c7d5fb7d4dffe050d7dba38a5b9188729be8ca3094f266e42ef3568dec198df24525bf26ea19560657100d63a32fd914917ec55ade6da42f1973bf5d
 DIST boto3-1.18.19.tar.gz 401907 BLAKE2B 6b333fad48a06c6c047bf415bf30620f81846a1c7862af47767588c6f5cf34f8f3342131ca511ffadb6d16a899c9fa499273a17e8db226c7314b69645a90ef2c SHA512 055d0d2d6f0ae51d311df8a9af742c82ae4224a1f5adaa873bf8e688ffa98310553630c147622fbdda304ef8a271c188c187d9e7851ea009cbf0c1bc2d5947d0
 DIST boto3-1.18.20.tar.gz 402208 BLAKE2B 6bf4ccdb388590bbc182c76204b3a82f91cd31332cd8c386872ed8be504931592cef01ae24786d8f8e7d2128f427570eba39a365c0f23dacaac4ddfd2eb9df13 SHA512 b91f1f38fa4832b8f9a3da6aef180f910cd676ef82b029735b984158115ad69fe4d87a86d8a915aebeda56d8cd0c3158a6a93ca37876bfeaafadb2f0364a3032
+DIST boto3-1.18.21.tar.gz 402611 BLAKE2B 39974c66ed5ad0697be6df04dbb141ce28e9a09863349f7adfcf756666d58ed02232453a9d86d46e62380c0b7f197a52b6869469309dff0c532e50a6bfc88403 SHA512 9920891b7be9d98c3a3d2f3065183532624e78fd2ff7a94d26594d2499cd5d17db0ac4ba6adf27f0e0f67fa836020dfac648babc144e4339a3dd717a1bd56ef7
 DIST boto3-1.18.7.tar.gz 395640 BLAKE2B 6a9fa1dd55644806fe93271805f35fbe0c4cb65d1de08dded2d2f57fcefa96e32c4ebe7b60743c52c0898222bc06d33dbd03d304bbef327b88022450a7943e2c SHA512 20e7fedab7d061ab02f391e9baf36cb554e7f194f38d24d5a75f76715b2acf1b51b6adce5d8cf5a2a0d29df73566db00b8813a219d45a194d9a8eb93d0dab570
diff --git a/dev-python/boto3/boto3-1.18.21.ebuild b/dev-python/boto3/boto3-1.18.21.ebuild
new file mode 100644
index 000000000000..bee358e1c595
--- /dev/null
+++ b/dev-python/boto3/boto3-1.18.21.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ ||
+		die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 11c9d8bac50e..a8b44a9b2bfa 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,4 +3,5 @@ DIST botocore-1.21.15.tar.gz 8012673 BLAKE2B cdd2b4128e67c85879e85f61265b10c1e57
 DIST botocore-1.21.18.tar.gz 8034404 BLAKE2B f28cd392a0ca34bc5baa6316bcc9b040ab7cf429c6b16b1c9cb832d310640a75df21ac22634a565d91eeefcb1476f50487e2e80b52cfbfca1cdb9683e76d801f SHA512 485e3d293684659731061592082582678035ad657fe47cacd9f7608cf09d801bfd73951a3c0de77c65a79e6070638f0b3dddfa357d7f0ddbb773c70334b214b8
 DIST botocore-1.21.19.tar.gz 8042956 BLAKE2B 69f1ac5ad0282308998374fb4625c3a4e1203dc338c4f945b75f8c18c02754b02fdf88e65e9333876ea6495d7d2ee45e2b6592f6602676ace57f65b5f3fe6fd0 SHA512 2fcb1e8879ef963c54100e81923a05bef2830238c67f44f0627003be65335a019153c4537d375a54e5f180ac37cf99f30bef3b4f41edd350259128de48d1ea74
 DIST botocore-1.21.20.tar.gz 8041821 BLAKE2B 3691f5bf248c3d9d63e0ae46ce460e9d72662c1b6c526048cd2cf5ee4868892a2e86b41b37abd9fa8e9f90be92a1a171bc260a4de97de110aa3aea35f0170120 SHA512 b142fc293242f7364dfb29837436f84371c44289547668446a31180eae3615b31da6cc3a0634bca6d8cbebc990524009fd059b492979fb76250338d952fc99e1
+DIST botocore-1.21.21.tar.gz 8042971 BLAKE2B 888abb929e1d66c293bff9d3d25682590e0fce3173ca6e121b969d1ef92dd4bb3fd010f72ab4bed664ed6e2df94fd61a9211a3aad72742eb1d4ee2b192cb4f7d SHA512 f8f47c2a2ed07f90263fd5eefe593bf14e8bb2a8df599660f2c84c504a16eb1c370ff8edea0b809be34f1fe9c7e8a3d604b74689b9e16c0686e6ff7c640534a4
 DIST botocore-1.21.7.tar.gz 7977343 BLAKE2B 19c5bf5de40ab131585e30bb85486fcffc3428808811b312b33578174ce31a691f4f4d955462120f05d2aad2cd5e5772789704eee641760fb67099aa3cddc9b5 SHA512 db1bb36faa6857a1cc717e5d591954415bb948178ee2be90ab9c32c11b1fb45c5b5aff87dfacd907c2f11bc7cdd2cd4de2ee9c847fa8cda4e5f0814a828b1019
diff --git a/dev-python/botocore/botocore-1.21.21.ebuild b/dev-python/botocore/botocore-1.21.21.ebuild
new file mode 100644
index 000000000000..5684261bd4b3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.21.21.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index e02eca46bef4..f9170743c8dc 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -2,3 +2,4 @@ DIST dask-2021.6.2.tar.gz 3725731 BLAKE2B 957cf70c328462c87eb52bb2fe3d471705ab6b
 DIST dask-2021.7.0.tar.gz 3730549 BLAKE2B 8f76648614adbef8ca1feb01f5b39d4ad217eb5178c4b7ace72d3764062b172d83b74e9fad5eeff0a745025e0cb2bf47bdb14beb03b1520130332ece00c3e318 SHA512 3dbeefe08af6536f19a03ead69372dfa7a26eff66d768fa8e238341822136a2314fca0291694ad22bdfe3618a4ed6785d836ceb5cc4231f361d97f0cbba0edbf
 DIST dask-2021.7.1.tar.gz 3734645 BLAKE2B 4dfd98c72a54712dc4bee97305811bf411bceb5e5ad60d6a82e94b785be51ea8e2ea6ae853b85f45a9765f0220f4c35b526582f1587932178d53884df1d697d7 SHA512 0b5ab5e08503468ca26ee2b0e195979055c9fa439e62f1c47e73521856f7ddb2fa608457cd1e4a0edcd3162254d404ae4995319b73b142bf6bd804c6b63b3f22
 DIST dask-2021.7.2.tar.gz 3739041 BLAKE2B e32389a5d6a47a9c0f741a33d2f9aeb8887c951d4a53ad7e2bdc5d7007e2e7b8db9b639b95725bb70cfdf1f3568aa2541c7f46c5c87cbb50b5433866b7f0e870 SHA512 029832ea2db342cc63dcfc4e5a563e6e92f5d26298ca19d7815548acceb8098e94b53acb5df1a6923172e7014b6235ddb34921f2855701921556db83a9411afa
+DIST dask-2021.8.0.tar.gz 3742254 BLAKE2B a4f086181dc5dd36561d365ac929c0399d05fbb9d39e025ad06a609477cd4e257abb93760244032285812409c413a110f213ad2918ec1042e1526f847da1056f SHA512 b205c05965aec419650b9125193d96383ad9ffa96e8aef92ac15da339e0ba9d1c40ba6bc176e56aca0ef6f84d7a523d7157aba90e146317aef58fe34dc07e2bc
diff --git a/dev-python/dask/dask-2021.8.0.ebuild b/dev-python/dask/dask-2021.8.0.ebuild
new file mode 100644
index 000000000000..56fed399ca27
--- /dev/null
+++ b/dev-python/dask/dask-2021.8.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="https://dask.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/cloudpickle-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.15.1[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.25.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/partd-0.3.10[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	test? (
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# require old sqlalchemy
+		dask/dataframe/io/tests/test_sql.py
+	)
+
+	epytest -p no:flaky -m "not network" ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/importlib_metadata/Manifest b/dev-python/importlib_metadata/Manifest
index f7ea67efa8a5..4fe7dcf15fc4 100644
--- a/dev-python/importlib_metadata/Manifest
+++ b/dev-python/importlib_metadata/Manifest
@@ -1,2 +1,3 @@
 DIST importlib_metadata-4.6.1.tar.gz 39801 BLAKE2B 89a792eee17f31a86c27820a0b3972cd8f6a06314763930ccdf0cfce31435f8074e6f8f27050d1618713ee6d517f0cd8dfba6a86b1e8917af2769ae22ac40cf5 SHA512 2a0bcef3d49de00a1013eac48f1ce020cb89ab895f5e4a1673b46a1ad8f84515148eff33608847331de8ee05d7e10040e128b2c887065d3ca16d0bd338c761c0
 DIST importlib_metadata-4.6.3.tar.gz 39852 BLAKE2B a6ab735a8471cddbdd1cefcbbabb29664a8dc96c4163a361422066081f00ffb627612a4b7522cd636de9cb030d0add61dcbb38d085dc759f810239017bb5f681 SHA512 b34b3384bfa1043a1b366505c43fb8a8f0a3a055637cd745009095026dc8a1424c1065fbff5a9170523a3b9b0a48951b615dc64b7bf096bbc2c40261fa200e60
+DIST importlib_metadata-4.6.4.tar.gz 39881 BLAKE2B b7ae57ee18506807a4a0c03d657408047548535e5b6be5f654ba70eb34a1f92701a063a39f4bbc4c67fee3afbda5bb76e87caf588c2915416113547edbdab57a SHA512 20aad4adbea8bc417a77cd67a6e22e690e95913ee34822d79e4bb0472f396ece2137ab4cabc455a8154251fe563ed7f56a68bdb7b08a91c8a32f735608cb4a7c
diff --git a/dev-python/importlib_metadata/importlib_metadata-4.6.4.ebuild b/dev-python/importlib_metadata/importlib_metadata-4.6.4.ebuild
new file mode 100644
index 000000000000..ff9c09d60191
--- /dev/null
+++ b/dev-python/importlib_metadata/importlib_metadata-4.6.4.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# NB: this package extends beyond built-in importlib stuff in py3.8+
+# new entry_point API not yet included in cpython release
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="https://github.com/python/importlib_metadata"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' pypy3)
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/importlib_resources[${PYTHON_USEDEP}]
+		' pypy3 python3_8)
+	)
+"
+
+distutils_enable_sphinx docs dev-python/jaraco-packaging dev-python/rst-linker
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# Skip a test that requires pep517 which is not in the tree
+	sed -e 's:test_find_local:_&:' -i tests/test_integration.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/pydantic/pydantic-1.8.2.ebuild b/dev-python/pydantic/pydantic-1.8.2.ebuild
index b6d23b4c69a0..7d2f9c0d6686 100644
--- a/dev-python/pydantic/pydantic-1.8.2.ebuild
+++ b/dev-python/pydantic/pydantic-1.8.2.ebuild
@@ -4,7 +4,6 @@
 EAPI=7
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-
 inherit distutils-r1
 
 DESCRIPTION="Data parsing and validation using Python type hints"
@@ -36,6 +35,11 @@ src_prepare() {
 }
 
 python_test() {
-	# TODO
-	epytest --deselect tests/test_hypothesis_plugin.py
+	local ignore=(
+		# mypy results depend on version
+		tests/mypy/test_mypy.py
+		# TODO
+		tests/test_hypothesis_plugin.py
+	)
+	epytest ${ignore[@]/#/--ignore }
 }
diff --git a/dev-python/texttable/Manifest b/dev-python/texttable/Manifest
index f0c8b27431b1..c1d05a13eca8 100644
--- a/dev-python/texttable/Manifest
+++ b/dev-python/texttable/Manifest
@@ -1,2 +1 @@
-DIST texttable-1.6.3.tar.gz 11574 BLAKE2B aebb306acb89f62963e9473ab6e22291a1ec93993a0106ddd2943f656737cb0960a10e680a69b6577ebb8ac0af3c6ecdfd8c58647a6ce37d9a6531e41f61f480 SHA512 89a26ef7d9947ec4edfc5791c91f2ac327c79bbc5aa0e0f89c0a63dbd80bc420027af073da935254faa143b9e8bef85a7bb352791b45b0cd60c7bcf569869f2d
 DIST texttable-1.6.4.tar.gz 11611 BLAKE2B a97a9beefc9547fe7487af5b6411effd7391e303a13161d7e1c9304a1b580cf47bb10c8649dfea5c6f8ba05bc6c3fd7595662e8b74b282696d9ee3a110746212 SHA512 300b02f5b682f1c09a3eb5abfd4ee9c724354505a3f9e8f68207fd7d244402f234437807d68b6b526c3d4ade9e527e66c921bcd47a5e86d680698d559da3fe1a
diff --git a/dev-python/texttable/texttable-1.6.3.ebuild b/dev-python/texttable/texttable-1.6.3.ebuild
deleted file mode 100644
index 4ebd4d5d09d7..000000000000
--- a/dev-python/texttable/texttable-1.6.3.ebuild
+++ /dev/null
@@ -1,28 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-
-inherit distutils-r1 optfeature
-
-DESCRIPTION="Module for creating simple ASCII tables"
-HOMEPAGE="https://github.com/foutaise/texttable https://pypi.org/project/texttable/"
-SRC_URI="https://github.com/foutaise/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 arm64 x86"
-
-RDEPEND="dev-python/wcwidth[${PYTHON_USEDEP}]"
-
-distutils_enable_tests pytest
-
-python_test() {
-	pytest -vv tests.py || die
-}
-
-pkg_postinst() {
-	optfeature "better wrapping of CJK text" dev-python/cjkwrap
-}
diff --git a/dev-python/texttable/texttable-1.6.4.ebuild b/dev-python/texttable/texttable-1.6.4.ebuild
index 5e820a2bc3e9..4ebd4d5d09d7 100644
--- a/dev-python/texttable/texttable-1.6.4.ebuild
+++ b/dev-python/texttable/texttable-1.6.4.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/foutaise/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
+KEYWORDS="amd64 arm64 x86"
 
 RDEPEND="dev-python/wcwidth[${PYTHON_USEDEP}]"
 
diff --git a/dev-python/tzlocal/Manifest b/dev-python/tzlocal/Manifest
index 9cf06a42b4da..46b125b77b5d 100644
--- a/dev-python/tzlocal/Manifest
+++ b/dev-python/tzlocal/Manifest
@@ -1 +1,2 @@
 DIST tzlocal-2.1.gh.tar.gz 18463 BLAKE2B 73e886cfb6d13bebc1a15a222da60f368a15dc5a097acac74990b1d76bdaa229be8f12ff735d1828ccd78c4c8d06eb5bc0a07da695d70251af1e67e4fb71037e SHA512 2679cebdc2692d9e0e1c9b714994ad881896f53e75ef407229a67c9fee9d27617638a2919865cb67e21e2bbd6e3bc13f2568343037e06603236f25a96aa6863d
+DIST tzlocal-3.0.gh.tar.gz 18924 BLAKE2B 340739015ce0fae245ddcb2d3f6250886261a81a49c9db7960515e178090183d3a826ee494763503023c033d3d9c19771aad865d4c1150350a118250aab23362 SHA512 9060eb325783d183bfaf7038476031a2ea22fd4ba50f6b5caf3d8eda15d9c90e557c64a0218c7e3c3df51f385378fe8a17f10871abb038012e1d05a9547918c3
diff --git a/dev-python/tzlocal/tzlocal-3.0.ebuild b/dev-python/tzlocal/tzlocal-3.0.ebuild
new file mode 100644
index 000000000000..e99ac6fcb87d
--- /dev/null
+++ b/dev-python/tzlocal/tzlocal-3.0.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="tzinfo object for the local timezone"
+HOMEPAGE="https://github.com/regebro/tzlocal"
+SRC_URI="https://github.com/regebro/tzlocal/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' python3_8 pypy3)"
+
+distutils_enable_tests pytest
diff --git a/dev-python/zeep/metadata.xml b/dev-python/zeep/metadata.xml
index ca4750a1bfcd..e0bc0f02a346 100644
--- a/dev-python/zeep/metadata.xml
+++ b/dev-python/zeep/metadata.xml
@@ -6,6 +6,7 @@
  </maintainer>
  <upstream>
   <remote-id type="pypi">zeep</remote-id>
+  <bugs-to>https://github.com/mvantellingen/python-zeep/issues</bugs-to>
  </upstream>
  <use>
   <flag name="async">Add async support</flag>
diff --git a/dev-python/zeroconf/Manifest b/dev-python/zeroconf/Manifest
index 18676cee6bfa..6be000ec3bfd 100644
--- a/dev-python/zeroconf/Manifest
+++ b/dev-python/zeroconf/Manifest
@@ -4,3 +4,4 @@ DIST python-zeroconf-0.33.3.gh.tar.gz 121202 BLAKE2B f457a65d26b58e4dac6c83b66be
 DIST python-zeroconf-0.33.4.gh.tar.gz 121380 BLAKE2B a1a8ac266aaded65337aa9d5c26d8a52b6329500a1a18354148590fdb47988f200b0658a41e18b78694cd9f95f1322cce0ff289a795bf9459ab6d383d5ee13f9 SHA512 fa6dd453ea22beb113c53941ce750e214da3211b6fc14d8b0cb575b927cff14759c49fec4e9ada4a2fd4ebc0bb3b0b355a2454ca0e128a3213fc8be41f096af7
 DIST python-zeroconf-0.34.2.gh.tar.gz 125452 BLAKE2B 704ab1400a01eae93b1f706c2ccd4554b7ffbbcfcaebfc28bacf6e28354894185a7ed5cffddb3b96ff05dc3521d2507160a5f43c11a600c5b5043882d15c39e6 SHA512 958d01316ef307d08d68abe975f45d77e84cede8334f8ad023080b7d46f965f890b1c74de640807681d3aaa647e01902de01309e3520fba8ba18cb4b6af1f4ba
 DIST python-zeroconf-0.34.3.gh.tar.gz 125454 BLAKE2B d80c25fa8bb79b6c5a3d491efc0e891b08e808d9c2619d917a19d9d76ebdf13d32ddb684a3f68abd7ae6dce3597de30027557033a5ccacfe8dcc5bf624b45f25 SHA512 d9f1ab126dd68fdef2e2983a11efe7d3703bbacd7b74b9a82a781361b0282bf20d8c16bcf96beda7112958eab54e0b819f709d840a9e5f0f2da8c9003e9943fe
+DIST python-zeroconf-0.35.0.gh.tar.gz 126620 BLAKE2B 1c2a7e78c32305be0c35fcef513e26c1834dee71b7714479c70c44a09378fb96a15f39fb4d9de4a8bde607cc4ef67798b5e6cb09e613f1a86cd9934123ab2ca9 SHA512 440871dd5fa861950187bf0c4593b2212d91477d4adbd41a43fd3adec820543628d684dfc042e38e4b69cd94e8b23d10298e660da32f8c221faf16e03135b925
diff --git a/dev-python/zeroconf/zeroconf-0.35.0.ebuild b/dev-python/zeroconf/zeroconf-0.35.0.ebuild
new file mode 100644
index 000000000000..c406eead3ace
--- /dev/null
+++ b/dev-python/zeroconf/zeroconf-0.35.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+MY_P=python-zeroconf-${PV}
+DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
+HOMEPAGE="
+	https://github.com/jstasiak/python-zeroconf/
+	https://pypi.org/project/zeroconf/"
+SRC_URI="
+	https://github.com/jstasiak/python-zeroconf/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND=">=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local excludes=(
+		# network
+		tests/test_core.py::Framework::test_close_multiple_times
+		tests/test_core.py::Framework::test_launch_and_close
+		tests/test_core.py::Framework::test_launch_and_close_context_manager
+		tests/test_core.py::Framework::test_launch_and_close_v4_v6
+		tests/test_core.py::Framework::test_launch_and_close_v6_only
+		tests/services/test_types.py::ServiceTypesQuery::test_integration_with_listener_ipv6
+	)
+
+	epytest ${excludes[@]/#/--deselect }
+}