Adding metadata

15 files changed, 557 insertions, 0 deletions

diff --git a/dev-python/Faker/Faker-26.2.0.ebuild b/dev-python/Faker/Faker-26.2.0.ebuild
new file mode 100644
index 000000000000..cca5ce1813b1
--- /dev/null
+++ b/dev-python/Faker/Faker-26.2.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="
+	https://github.com/joke2k/faker/
+	https://pypi.org/project/Faker/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	!dev-ruby/faker
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)
+"
+
+# note: tests are flaky with xdist
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=faker.contrib.pytest.plugin
+	epytest
+	epytest --exclusive-faker-session tests/pytest/session_overrides
+}
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index 221ae2b3dae4..51a939b4ea7e 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -1,2 +1,3 @@
 DIST Faker-26.0.0.tar.gz 1763318 BLAKE2B 63cf76993c3e4fc229d5d80f3cd03d964f5f7f6fc7f9cb1aa272c075360ebec57289139d09d11d181436b30cdb5abc7fe7d7e5cc11d63e12b0e8746605f85d6a SHA512 ea09d4222b258f52e9d9b2c315ee46f42beb624c038f63d4a82baadafbf4a9cc382b92076bb7c421026c1761cadb246364bfc71a05177458a8e23d2eca2fd6e6
 DIST Faker-26.1.0.tar.gz 1763636 BLAKE2B 997d2449c70fd179a7bea5be93e05a916804b552bd7ac19360d99c9ec56f96a28838ccd854aa846842fed7d7cb83c6ed013d73696a551444a0f81a9236403f24 SHA512 8e2df35549c52f86cbca6f75629227bba45026b2174ba3757b9c80350b8e48674bd71412552db9133020f0b93065940fcbefbbc37d391cdddcddc6344fc1431b
+DIST Faker-26.2.0.tar.gz 1764867 BLAKE2B aa1a5bdb5b9867c3fced1b9fdcb53f600d7311b27122d0c7895c419c18e3c04d48ba07897e9052f99583f8319bad4b2262925b54dbe6434ca193c085c2c93bae SHA512 f5d1bb832f3f4e21b694ea77e941b6862066514a2970c665e36b1bfec76b3b05a19d7bfb0a962b08bb39cae53a3ed57b329a7a8f447d9f327ecf1bfd61e99d6d
diff --git a/dev-python/argcomplete/Manifest b/dev-python/argcomplete/Manifest
index 13a5306894b2..0741c0f41e79 100644
--- a/dev-python/argcomplete/Manifest
+++ b/dev-python/argcomplete/Manifest
@@ -1 +1,2 @@
 DIST argcomplete-3.4.0.tar.gz 82275 BLAKE2B 18b81aa5ee0c148a3b935f157f4c39b0ade79b36c8e3aa94aa7af8a424a08793a4cf661cb2431c201d5eead02e12c35b78d351310ff4e4e750bf7d7dc702ca89 SHA512 bd619a34edf1f1d05bdfab7fa830d1fc5375bc292dc95b95ddc4d3bfaced5728067e6ad0a901f672b7e0d5a550c10b00e0851f83cf9b358301c037da256a4a56
+DIST argcomplete-3.5.0.tar.gz 82237 BLAKE2B 7a5acd6f1311ec153333363e207037634b6901cca1415bd68d8e009888fa8cdfdfc3a50189f14c5da4bddfa5c861bbc009cf0d34248ff168caaa6ebad6ad8a7d SHA512 89c305a97b0808301976a48f9c8cb914e7cc12e33540cebd1c6514bbed8017db27b2232e3526abb74fe4f152f23c211be5a48aeafd63bbfca2dcc42f92b4877e
diff --git a/dev-python/argcomplete/argcomplete-3.5.0.ebuild b/dev-python/argcomplete/argcomplete-3.5.0.ebuild
new file mode 100644
index 000000000000..7c1ca19cd6e2
--- /dev/null
+++ b/dev-python/argcomplete/argcomplete-3.5.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Bash tab completion for argparse"
+HOMEPAGE="
+	https://github.com/kislyuk/argcomplete/
+	https://pypi.org/project/argcomplete/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# pip is called as an external tool
+BDEPEND="
+	test? (
+		app-shells/fish
+		app-shells/tcsh
+		app-shells/zsh
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pip-19
+	)
+"
+
+PATCHES=(
+	# increase test timeouts -- this is particularly necessary
+	# for entry point tests because they read metadata of all installed
+	# packages which can take real long on systems with lots of packages
+	"${FILESDIR}/argcomplete-3.1.6-timeout.patch"
+)
+
+python_test() {
+	"${EPYTHON}" test/test.py -v || die
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 74f42f839b23..d246b9b2970a 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,3 +2,4 @@ DIST boto3-1.34.145.gh.tar.gz 841776 BLAKE2B e93a6c4d634c2df22ed27e58c2abe0a6cc8
 DIST boto3-1.34.149.gh.tar.gz 845064 BLAKE2B 25e77483b8ac8a52e7f5586794839dcab694cf8db3cc27112db25fc77b55845cb84dd2750a45dd5097b49e62e62403077fd741d7f1610fc7f735d8344e6fd23c SHA512 21a942ca15023b3e2732678ee79d1b8c7b027e89958b5761a8d543b91c434d06d7c84e137177e1fde52440c801f62dfa4caed309ec92400f6516720bbcc11690
 DIST boto3-1.34.153.gh.tar.gz 847038 BLAKE2B f29aec887fd57d2bc4b6be125787384438e0dba65dd01effcc91016b9301be2fdde315a2fbdc8f122350ae52f904ba1c281aee9a5dc52994ddd11b45ead3f8a3 SHA512 a8d8f75ef48ad8418aafddbdea4fb021f64b041e7beabf68a0c2f6c461c3aa0b3f2f20c33122ac87d57296fd0d14ee8834b96257085c522b556f6aa1d99ea0d1
 DIST boto3-1.34.154.gh.tar.gz 847586 BLAKE2B 6ae763f1e112f865f8711951ac52f4ff28976928470ac3d8c468278e0abde23750457b8f92a9346b1468f94da4282b5b71eba09f7b442fd448ab8c1501e79914 SHA512 22eb130dbeaf9dfc87d2e01dddd00d3bd10a2fa91c8c7994add2ad3d739769dbd56717d9d034a0edb8e02ad15b8b956a31737269b303a3ec3508d8cfc00482ed
+DIST boto3-1.34.155.gh.tar.gz 847949 BLAKE2B 922377411d5535ff98b81f96cdb15dfd98de23bda40acabb172c889b221936083ad91403f59926fb29ca480f6d0056fb0441371dcfbd2b94d05158c34503bb8c SHA512 c8d7764c10a81fa8fb32eecdd242a36032db451bf4afe1bbc1974de422e0dc387d18e9ef78dcbdb41b19a05db4da8d66131d246b074463a33ae072a61141c362
diff --git a/dev-python/boto3/boto3-1.34.155.ebuild b/dev-python/boto3/boto3-1.34.155.ebuild
new file mode 100644
index 000000000000..509842b2699d
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.155.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 77c7092d4ae3..850625a13c7d 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,3 +2,4 @@ DIST botocore-1.34.145.gh.tar.gz 13230154 BLAKE2B ebcf6acdd7ab01bca4032eaa9bc94f
 DIST botocore-1.34.149.gh.tar.gz 13245965 BLAKE2B 6bc05c1d93eaa62fa9acb3c0e42acdc67272df442452892cb8e833d93edaafd0dfe03f9467e5f305d2827a12bcc9f0658e13a889f9165e1a83250a9ba1bd5f5b SHA512 e44ab480c611b43e13474db97642b92ac59c4b9e641d45ca0967aca385c608f37dd77541088161e7ac1b05ff9b5e4fa544e8d8711d7fbe0a8a4e78e7d7710722
 DIST botocore-1.34.153.gh.tar.gz 13269606 BLAKE2B 1b2ec1af3b699c18c5761fe72b8488361f843e1b2abc5f311736e7c93a52574738a8e72708791657d0d86586d64ee3c85804514779c6dc75c6c2e37035517be1 SHA512 9a7b3359f4304bcb4d3605e2516514360e8898d7b8b1fdee8fab5dc6026a7d8197b09199da4e9aefcf1ab0b094a2e0e336ad13942ce0364f7b5ac87d86fdc4fd
 DIST botocore-1.34.154.gh.tar.gz 13272973 BLAKE2B ce1616749d9baddf6fbbf08be1dc0c5343b3b9ec3bf2b357690ca31076d52f814e7a7d4f61f2a2e2629d35c55894bd56e6fa4ada8834e1df1b072638ec6dd874 SHA512 5b5d8efb5834ddfac08216a9919f2e1d3ac92823b635530a429e45b90f16fbf426dabec7da98e965f5e540fb471eba49d3ccbf55e771d956fa200f6196612837
+DIST botocore-1.34.155.gh.tar.gz 13274262 BLAKE2B ec3602e31e2091877faa07841494e63b169624992c88a7eb9fa0315c2dcb205b7903e1eba101291caeadc89f078365e1fb605ffd1dc096cbb748e206d9bc5df1 SHA512 6582c286304cb667048325c7b2710fc040f41a822497732919e7982791d686af21e9f7851239b736e0b2f7e463f00fdb9e0e2793004d04c3fce7831d10f46e60
diff --git a/dev-python/botocore/botocore-1.34.155.ebuild b/dev-python/botocore/botocore-1.34.155.ebuild
new file mode 100644
index 000000000000..64a61a30c80b
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.155.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	case ${EPYTHON} in
+		python3.13)
+			EPYTEST_DESELECT+=(
+				# memory use tests, probably fragile
+				tests/functional/leak/test_resource_leaks.py::TestDoesNotLeakMemory
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 687c0f27c2c6..ab391baedcdf 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,7 +1,11 @@
 DIST Django-4.2.14.checksum.txt 2579 BLAKE2B 9cf59d23c8fa0ad9b86f30a492d981a3084c31fd0c7e8ea212c62377385bcb45369ee3f29573c8e129f8d248ca4e94d4c1a4172048b9a9b2f66cc3291e972367 SHA512 c36efc19f8cc90db89dfe3ffaedff724f4b5a049f6def7acb194f8114a2ae519c5c07dea5452c09618629c9d585867de4b028bcef382f43d24f753f4a100c1c6
 DIST Django-4.2.14.tar.gz 10432993 BLAKE2B 0139669111f834bcb79fea5fa2bc43386d62a65790fda9d762f8ac4e2a32f2a3740629e31c863b2643fa13b893938c33b066c21f27857f391715b7cec88dfad7 SHA512 2663454c48f57a441d1620faad30ac25750d1e71bf34eddbdef3e6d8dd208913752ab657447ffea5e9d3a0676a4a4d501fa88a40a0ca0fd361df0782a6b3306b
+DIST Django-4.2.15.checksum.txt 2418 BLAKE2B 06338f990952736d1368c11bc0a14df4fcb756c7e33b0a843d692c1ca23a9bf5073c552513cf2846c16da24da475ff122f59122f90da528c2cb8875072fa7748 SHA512 b4e8eb163a889c2aa556217b2ba6280916c891b2f8af862d66e09b5ec643dee9281e58e2382fdfdee1d0e1a9a80267c93993374ae3e0f33f3ec5051bae69f145
+DIST Django-4.2.15.tar.gz 10418066 BLAKE2B 4abf7205995fbc8dd90ca43aadfdd6737c5f731fea4054f987ae851e0b6f0a5f0f799441f94ca322e31c07c2a810903a00b4432b71a7517b2a261c4844ddba90 SHA512 8f334dcaa36b3bce5184ddf1a1508bf42614be6ab486c9e0d87e9bfd212511c43081ad5fb02d2dd7b54f8236fc1f7ee9cd7b7f6f94ac8edc1cb52d1c0c698880
 DIST Django-5.0.7.checksum.txt 2569 BLAKE2B 0d4cecf064da9313058606569fcb014c5f3d5ec3c60a5a056cd8242ed9a8349b6d273c38010ba3d41fac85e5551a21748a7739772ad310f8c64224243745eac5 SHA512 9ec2e5e3ac0cb99be9349373c2cf47c6055e0bb729e5bb7e476350cd39595c4c82e7eab9a7eb286a9199834bed65d7f3d31ba59509d6e2e827b0f9c743aa9fcd
 DIST Django-5.0.7.tar.gz 10642686 BLAKE2B 559c3e3dd3971081e8572a707f59054ec84d9922493caddec9e008c5e850e8beb7bfbca291e4e7157e94d4fcd655983e3444f1c8f078342c8b66b3e8ce122ab7 SHA512 29aa4cd7bfdc5c00479c9d60d988653bab76dcfd8cd553ab446f6c274f99677ccaef0571b0afdf1579215918f500d87a0b098a98452c7526e89b1ab64f00b037
+DIST Django-5.0.8.checksum.txt 2408 BLAKE2B 18751733d7abaa4e98039bf0cfa3773a999df4351371939803ec77850c25d75392abc7e4136e8c4a79620017c224bafcd8552c2446ee0817249abebcc3b0e1bb SHA512 c05027bdec0928dd51239ba5c72b97b737ad73dbbdbdc1c4bef2b9faf8afc188cd854e1dcd3b5ffbdc9c3a30dea5a27e4b899f9d257bcee6f80fbfdfd30e7a20
+DIST Django-5.0.8.tar.gz 10630791 BLAKE2B 0a5408b46b69b701f3ff88717b41b22cd4abd776a0b46f46025febd423e4b9c5f395da50a5be9e479bc0047405330231da400f3f2324bbb69ca5ab07966bc168 SHA512 b835d01f76f0e0082f299c2b15483aa3a8aef79f873b09dac546d3b4ecfa8a6fb84d9377e06e18a858bd24bcdd2db89c4cf05811b3af133b7da6609f6c2d917c
 DIST Django-5.1rc1.tar.gz 10747906 BLAKE2B a254c19d3e1713962e42736a99f2775c79ed7ad9b337280688402e7f564bc21c4b190f4887eb8aefee8ed17ab11cc51b490eb99bad967f2ad2e1321f70de9e80 SHA512 52d07fbfa031962a12109aa79ff44e93de3cba40c410be0707b46d1c47e352f066e5b58495f3aec5e60bd0b3844c667014b959965a248c4b6d997b8ced953622
 DIST django-4.2.8-pypy3.patch.xz 5900 BLAKE2B b7dc5c5fc162817a218ee6d025ed8a65559b80e4506e49ac393428c26e2621f9e7c5010b36f2412dea8194a9f1086ab21f97286eabd696c6a786285eb07393cf SHA512 f953b5adbd1364f1d84dde55087ccb493256b1327701275fd2fe99f3cd41751d18e002b6e21afc96892e1671428a6b8f3c2e4b88252c3c278f1a79e286bb73e3
 DIST django-5.0-pypy3.patch.xz 6124 BLAKE2B 7eba7cc70b30743cf4e186a2c5b0f27c13f49114a7a80bcaa2b25fdd7a959583c115a302c9bc6da97c32f6401cf8f3616818ba759190d317c5b033a0f0088766 SHA512 c550e2b2c1243d13cd1f4908f4b6df606355d1491e3bf72042e4b4777a4474306ff0f67b1c2eb4ab4d137cc85bde52dcdbd54bec245d2ba2e092545be8a2993b
diff --git a/dev-python/django/django-4.2.15.ebuild b/dev-python/django/django-4.2.15.ebuild
new file mode 100644
index 000000000000..7df9240f65e9
--- /dev/null
+++ b/dev-python/django/django-4.2.15.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 multiprocessing optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/python/django-4.2.8-pypy3.patch.xz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.6.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+	sys-libs/timezone-data
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20240807 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/django-4.0-bashcomp.patch
+	"${WORKDIR}"/django-4.2.8-pypy3.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite \
+		-v2 --parallel="${EPYTEST_JOBS:-$(makeopts_jobs)}" ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:0
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}
diff --git a/dev-python/django/django-5.0.8.ebuild b/dev-python/django/django-5.0.8.ebuild
new file mode 100644
index 000000000000..03ae7b1257b8
--- /dev/null
+++ b/dev-python/django/django-5.0.8.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 multiprocessing optfeature verify-sig
+
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://github.com/django/django/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${P^}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/python/django-5.0-pypy3.patch.xz
+	verify-sig? ( https://media.djangoproject.com/pgp/${P^}.checksum.txt )
+"
+S="${WORKDIR}/${P^}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/asgiref-4[${PYTHON_USEDEP}]
+	>=dev-python/asgiref-3.7.0[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.3.1[${PYTHON_USEDEP}]
+	sys-libs/timezone-data
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		>=dev-python/docutils-0.19[${PYTHON_USEDEP}]
+		>=dev-python/jinja-2.11.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		>=dev-python/selenium-4.8.0[${PYTHON_USEDEP}]
+		>=dev-python/tblib-1.5.0[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20240807 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/django-4.0-bashcomp.patch
+	"${WORKDIR}"/django-5.0-pypy3.patch
+	# https://github.com/django/django/commit/3426a5c33c36266af42128ee9eca4921e68ea876
+	"${FILESDIR}"/django-5.0.6-py313.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${P^}.checksum.txt" sha256 "${P^}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite \
+		-v2 --parallel="${EPYTEST_JOBS:-$(makeopts_jobs)}" ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:0
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+}
diff --git a/dev-python/rapidfuzz/Manifest b/dev-python/rapidfuzz/Manifest
index a6d17e9a7119..d1d4d202eee0 100644
--- a/dev-python/rapidfuzz/Manifest
+++ b/dev-python/rapidfuzz/Manifest
@@ -1,2 +1,3 @@
 DIST rapidfuzz-3.9.4.tar.gz 1595863 BLAKE2B ba835b6d1c5bc7da99ae7202ae469d9a1d069ea0351b732a701abbadfbe1539a389efb051cd58e462505ebcf6020b60ec6413d9f44bbfd63a0dc8419cded9722 SHA512 4494d86f17e7b4ae51639f1d2941d4e313c26739787f3a47261a5d5bf26da4091d918e1603e2199774edd5e1b91d67446b762a81e6b98496d67fbddb93effe21
 DIST rapidfuzz-3.9.5.tar.gz 1595894 BLAKE2B ce46f5fdc15e3c4aeef801055569f5452512bd2b0d85a9c738672e4f98a7ca8de9b4ca451da4e031ffbd661075bcd00e8929ad46b6990a693e1aa137d8097c7b SHA512 ddbb9b70ac9d3a0dce3d2632ee97bdb10afef5b33e73bb14ff51b70eb7c7e94dbc46132867a8279df4c15bddf6a85c0fa705f0d13bb157456b1e6dbc59e64a8f
+DIST rapidfuzz-3.9.6.tar.gz 1596107 BLAKE2B e108320e05ad3ad194b1ffa05d5fddc5bb6080e73ecb031117a0552d5685734870af4a87503022fceadf3fd38b31e71f85c05483b4aaaf4a9d7358d4566699b4 SHA512 015b947dcfd12ee48c7592ac2fc204833d8aa8e43110dab12dff7650e9f309a9a2017d2faf89b3c154cead23d9dc7fc1658f0ff5d2f8b5b3c73b2c97f021c7d9
diff --git a/dev-python/rapidfuzz/rapidfuzz-3.9.6.ebuild b/dev-python/rapidfuzz/rapidfuzz-3.9.6.ebuild
new file mode 100644
index 000000000000..9904a5fa775e
--- /dev/null
+++ b/dev-python/rapidfuzz/rapidfuzz-3.9.6.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Rapid fuzzy string matching in Python using various string metrics"
+HOMEPAGE="
+	https://github.com/rapidfuzz/RapidFuzz/
+	https://pypi.org/project/rapidfuzz/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# all these are header-only libraries
+DEPEND="
+	>=dev-cpp/taskflow-3.0.0
+	>=dev-cpp/rapidfuzz-cpp-3.0.5
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.16.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+	# remove bundled libraries
+	rm -r extern || die
+	# force recythonization
+	find src -name '*.cxx' -delete || die
+	# do not require exact taskflow version
+	sed -i -e '/Taskflow/s:3\.7\.0::' CMakeLists.txt || die
+
+	distutils-r1_src_prepare
+
+	export RAPIDFUZZ_BUILD_EXTENSION=1
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# scikit-build is broken and reuses the same build
+	# https://github.com/scikit-build/scikit-build/issues/633
+	rm -r _skbuild || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/scikit-build-core/Manifest b/dev-python/scikit-build-core/Manifest
index e90638f2bbc4..eaef8b4742bf 100644
--- a/dev-python/scikit-build-core/Manifest
+++ b/dev-python/scikit-build-core/Manifest
@@ -1,3 +1,4 @@
+DIST scikit_build_core-0.10.1.tar.gz 251300 BLAKE2B 2727e70c4bfe4e4cf558aaedd3a00eb07268c3e160c6fdfcceb8212842ee1e7e4a6a606c7d1670d25ee1fd45cadf2e40dee847fd5eb627bcf144f239f1ab0f0a SHA512 eebe14d79d339f4c39ab60b05fc6b92f1cd181b6e7ccef74e6976fb990dc51a2db6e6f72c830f6285ca700a48dd3e2ccfc87dafaad9ce26aa32d02fa1795a2b9
 DIST scikit_build_core-0.9.10.tar.gz 230104 BLAKE2B e3c4605b4b33260d8deac2cedb7bbb20a08729a36214b13c6071fe9b12f9bddc882c18da0e1ee14d7f1b4845ca0dd02b1c2d5c30c43b96a420c35a8b5cbd2d5e SHA512 0e1cb649f9965f4b13093432a2e36ea9be532ba3b7447c36f898284571dcbcf266b7012a445b464ac9129ec2b91e4155016be1fbab52fc2a979e440b0ea73cac
 DIST scikit_build_core-0.9.8.tar.gz 229845 BLAKE2B 419d8891dd3f95bee7f8f7dcc1addb94d2698f8ff392eef19a67e851f57b58d09b9878705d0e8d728d3c6f2b316d538c76471164781fcd1fb5d02dfbfd9d7a85 SHA512 f1206715eef1bdeccddc5987cae4f455522c4ef4dbca305ad7d3772c61f5615c5742b109c5527a5ad5e25a2348abff69ea5ae7153ac18c43cca63783872aa3d5
 DIST scikit_build_core-0.9.9.tar.gz 229971 BLAKE2B 2e41f59e053a44db07c84df4a03aab7c574b658d51f4b4517228ef0e12618f8de879e3ef704b7be398b5378e1f19b0a8c8dafcd20e3bd15dece9d387306427ac SHA512 c4b826353be3b34dc7f37f571088b7674f6ad8c984fd9985feb4e1b611c503dbf1a5c0e4e8ad1123c9f2e9538572da319f9104145abd598817ca3e29824cc61d
diff --git a/dev-python/scikit-build-core/scikit-build-core-0.10.1.ebuild b/dev-python/scikit-build-core/scikit-build-core-0.10.1.ebuild
new file mode 100644
index 000000000000..863b9216949e
--- /dev/null
+++ b/dev-python/scikit-build-core/scikit-build-core-0.10.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Build backend for CMake based projects"
+HOMEPAGE="
+	https://github.com/scikit-build/scikit-build-core/
+	https://pypi.org/project/scikit-build-core/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# we always want [pyproject] extra
+RDEPEND="
+	app-alternatives/ninja
+	dev-build/cmake
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.5[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		>=dev-python/cattrs-22.2.0[${PYTHON_USEDEP}]
+		dev-python/fastjsonschema[${PYTHON_USEDEP}]
+		dev-python/pybind11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-subprocess-1.5[${PYTHON_USEDEP}]
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local _EPYTEST_DESELECT=(
+		# TODO / we don't package validate_pyproject anyway
+		tests/test_schema.py::test_compare_schemas
+		# setuptools now respects PEP 625
+		tests/test_setuptools_pep517.py::test_pep517_sdist
+	)
+	local EPYTEST_IGNORE=(
+		# needs unpackaged validate_pyproject
+		tests/test_schema.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest-subprocess -m "not isolated and not network"
+}