Adding metadata

30 files changed, 950 insertions, 25 deletions

diff --git a/dev-python/PyGithub/PyGithub-1.55-r1.ebuild b/dev-python/PyGithub/PyGithub-1.55-r1.ebuild
new file mode 100644
index 000000000000..55fa80007403
--- /dev/null
+++ b/dev-python/PyGithub/PyGithub-1.55-r1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library to access the Github API v3"
+HOMEPAGE="https://github.com/PyGithub/PyGithub/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/deprecated[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pynacl-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		>=dev-python/httpretty-0.9.6[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/aiohttp-cors/aiohttp-cors-0.7.0-r2.ebuild b/dev-python/aiohttp-cors/aiohttp-cors-0.7.0-r2.ebuild
new file mode 100644
index 000000000000..e46a4b31d3ee
--- /dev/null
+++ b/dev-python/aiohttp-cors/aiohttp-cors-0.7.0-r2.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Implements CORS support for aiohttp asyncio-powered asynchronous HTTP server"
+HOMEPAGE="https://github.com/aio-libs/aiohttp-cors"
+SRC_URI="https://github.com/aio-libs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/aiohttp-1.1.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+# https://github.com/aio-libs/aiohttp-cors/pull/278
+PATCHES=(
+	"${FILESDIR}/${P}-tests.patch"
+	"${FILESDIR}/${P}-py3_7.patch"
+)
+
+src_prepare() {
+	sed -i -e '/^addopts=/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/blosc/blosc-1.10.5-r1.ebuild b/dev-python/blosc/blosc-1.10.5-r1.ebuild
new file mode 100644
index 000000000000..c50eaf2a3031
--- /dev/null
+++ b/dev-python/blosc/blosc-1.10.5-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=python-blosc-${PV}
+DESCRIPTION="High performance compressor optimized for binary data"
+HOMEPAGE="http://python-blosc.blosc.org"
+SRC_URI="
+	https://github.com/Blosc/python-blosc/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=dev-libs/c-blosc-1.19.0:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/scikit-build[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( ANNOUNCE.rst README.rst RELEASE_NOTES.rst )
+
+src_configure() {
+	export USE_SYSTEM_BLOSC=1
+	export BLOSC_DIR="${EPREFIX}/usr"
+}
+
+python_test() {
+	"${EPYTHON}" -m blosc.test -v || die
+}
diff --git a/dev-python/defcon/defcon-0.10.0-r1.ebuild b/dev-python/defcon/defcon-0.10.0-r1.ebuild
new file mode 100644
index 000000000000..384521522525
--- /dev/null
+++ b/dev-python/defcon/defcon-0.10.0-r1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A set of UFO based objects for use in font editing applications"
+HOMEPAGE="https://github.com/robotools/defcon"
+SRC_URI="https://github.com/robotools/defcon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/fonttools-4.28.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/fs[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
diff --git a/dev-python/diskcache/diskcache-5.4.0-r1.ebuild b/dev-python/diskcache/diskcache-5.4.0-r1.ebuild
new file mode 100644
index 000000000000..4cf43bfe6010
--- /dev/null
+++ b/dev-python/diskcache/diskcache-5.4.0-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+HOMEPAGE="
+	https://www.grantjenks.com/docs/diskcache/
+	https://github.com/grantjenks/python-diskcache/
+"
+DESCRIPTION="Disk and file backed cache"
+SRC_URI="
+	https://github.com/grantjenks/python-diskcache/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/python-diskcache-${PV}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+BDEPEND="
+	test? (
+		>=dev-python/django-3.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove dep on pytest-xdist and pytest-cov
+	sed -i -e '/-n auto/d' -e '/--cov/d' tox.ini || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/irc/irc-20.0.0-r1.ebuild b/dev-python/irc/irc-20.0.0-r1.ebuild
new file mode 100644
index 000000000000..f9733a464e1d
--- /dev/null
+++ b/dev-python/irc/irc-20.0.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="IRC client framework written in Python"
+HOMEPAGE="https://github.com/jaraco/irc"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-functools-1.20[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
+	dev-python/jaraco-logging[${PYTHON_USEDEP}]
+	dev-python/jaraco-stream[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/tempora-1.6[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-3.4.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs '>=dev-python/jaraco-packaging-3.2' \
+	'>=dev-python/rst-linker-1.9'
+distutils_enable_tests pytest
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/scripts"
+		dodoc -r scripts
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/jellyfish/jellyfish-0.9.0-r1.ebuild b/dev-python/jellyfish/jellyfish-0.9.0-r1.ebuild
new file mode 100644
index 000000000000..00853b9f7db1
--- /dev/null
+++ b/dev-python/jellyfish/jellyfish-0.9.0-r1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python module for doing approximate and phonetic matching of strings"
+HOMEPAGE="https://github.com/jamesturk/jellyfish https://pypi.org/project/jellyfish/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/unicodecsv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	rm -r jellyfish || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	epytest --pyargs jellyfish.test
+}
diff --git a/dev-python/makefun/makefun-1.13.1.ebuild b/dev-python/makefun/makefun-1.13.1.ebuild
index ad2c6f0b3475..a00164942e12 100644
--- a/dev-python/makefun/makefun-1.13.1.ebuild
+++ b/dev-python/makefun/makefun-1.13.1.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~riscv ~x86"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
 
 BDEPEND="dev-python/setuptools_scm[${PYTHON_USEDEP}]"
 
diff --git a/dev-python/openpyxl/openpyxl-3.0.9-r1.ebuild b/dev-python/openpyxl/openpyxl-3.0.9-r1.ebuild
new file mode 100644
index 000000000000..966c17bd9319
--- /dev/null
+++ b/dev-python/openpyxl/openpyxl-3.0.9-r1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure python reader and writer of Excel OpenXML files"
+HOMEPAGE="https://openpyxl.readthedocs.io/en/stable/"
+SRC_URI="https://foss.heptapod.net/openpyxl/openpyxl/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/et_xmlfile[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff,jpeg]
+	)
+"
+
+distutils_enable_sphinx doc
+distutils_enable_tests pytest
diff --git a/dev-python/parameterized/parameterized-0.8.1-r1.ebuild b/dev-python/parameterized/parameterized-0.8.1-r1.ebuild
new file mode 100644
index 000000000000..e59950d269a6
--- /dev/null
+++ b/dev-python/parameterized/parameterized-0.8.1-r1.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Parameterized testing with any Python test framework"
+HOMEPAGE="https://github.com/wolever/parameterized/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests nose
diff --git a/dev-python/paramiko/paramiko-2.9.2-r1.ebuild b/dev-python/paramiko/paramiko-2.9.2-r1.ebuild
new file mode 100644
index 000000000000..83aaa1de9350
--- /dev/null
+++ b/dev-python/paramiko/paramiko-2.9.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="SSH2 protocol library"
+HOMEPAGE="https://www.paramiko.org/ https://github.com/paramiko/paramiko/ https://pypi.org/project/paramiko/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris"
+IUSE="examples server"
+
+RDEPEND="
+	>=dev-python/bcrypt-3.1.3[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.5[${PYTHON_USEDEP}]
+	>=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx sites/docs
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/${PN}-2.7.1-tests.patch"
+	)
+
+	if ! use server; then
+		PATCHES+=( "${FILESDIR}/${PN}-2.4.2-disable-server.patch" )
+	fi
+	distutils-r1_src_prepare
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		docinto examples
+		dodoc -r demos/*
+	fi
+}
diff --git a/dev-python/plumbum/plumbum-1.7.2-r1.ebuild b/dev-python/plumbum/plumbum-1.7.2-r1.ebuild
new file mode 100644
index 000000000000..e0c0a659930f
--- /dev/null
+++ b/dev-python/plumbum/plumbum-1.7.2-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A library for shell script-like programs in python"
+HOMEPAGE="https://plumbum.readthedocs.io/en/latest/ https://github.com/tomerfiliba/plumbum"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Need sshd running
+	tests/test_remote.py
+	tests/test_utils.py
+	# Windows specific
+	tests/test_putty.py
+	# Needs sudo without password
+	tests/test_sudo.py
+	# Wrong assumptions about env handling
+	tests/test_env.py::TestEnv::test_change_env
+	tests/test_env.py::TestEnv::test_dictlike
+	tests/test_local.py::TestLocalPath::test_iterdir
+)
+
+src_prepare() {
+	sed -e '/addopts/d' -i setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+pkg_postinst() {
+	optfeature "remote commands via ssh" dev-python/paramiko
+	optfeature "progress bars in jupyter" dev-python/ipywidgets
+	optfeature "colored output in jupyter" dev-python/ipython
+	optfeature "images on the command line" dev-python/pillow
+}
diff --git a/dev-python/py-amqp/py-amqp-5.0.9-r1.ebuild b/dev-python/py-amqp/py-amqp-5.0.9-r1.ebuild
new file mode 100644
index 000000000000..e30290e01de4
--- /dev/null
+++ b/dev-python/py-amqp/py-amqp-5.0.9-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P="amqp-${PV}"
+DESCRIPTION="Low-level AMQP client for Python (fork of amqplib)"
+HOMEPAGE="https://github.com/celery/py-amqp https://pypi.org/project/amqp/"
+SRC_URI="mirror://pypi/${MY_P:0:1}/amqp/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="extras"
+
+BDEPEND="
+	>=dev-python/vine-5.0.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/case-1.3.1[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/pytest-rerunfailures-6.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs dev-python/sphinx_celery
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# rmq tests require a rabbitmq instance
+	t/integration/test_rmq.py
+)
+
+EPYTEST_DESELECT=(
+	# fails when gssapi is installed (how does that test make sense?!)
+	t/unit/test_sasl.py::test_SASL::test_gssapi_missing
+)
+
+python_install_all() {
+	if use extras; then
+		insinto /usr/share/${PF}/extras
+		doins -r extra
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pygal/pygal-3.0.0-r2.ebuild b/dev-python/pygal/pygal-3.0.0-r2.ebuild
new file mode 100644
index 000000000000..3c4bde16f643
--- /dev/null
+++ b/dev-python/pygal/pygal-3.0.0-r2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="A python SVG charts generator"
+HOMEPAGE="https://github.com/Kozea/pygal/"
+SRC_URI="https://github.com/Kozea/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pyquery[${PYTHON_USEDEP}]
+		media-gfx/cairosvg[${PYTHON_USEDEP}]
+	)
+"
+
+# CHANGELOG is a symlink to docs/changelog.rst
+DOCS=( docs/changelog.rst README.md )
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Not actually required unless we want to do setup.py test
+	# https://github.com/Kozea/pygal/issues/430
+	sed -i -e "/setup_requires/d" setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+pkg_postinst() {
+	optfeature "improving rendering speed" "dev-python/lxml"
+	optfeature "png rendering" "dev-python/cairosvg"
+}
diff --git a/dev-python/python-slugify/Manifest b/dev-python/python-slugify/Manifest
index 32bd4446bc88..8ab1a8877e4c 100644
--- a/dev-python/python-slugify/Manifest
+++ b/dev-python/python-slugify/Manifest
@@ -1,4 +1,3 @@
-DIST python-slugify-4.0.1.tar.gz 11509 BLAKE2B b505c62c959dae3823db4441b8811ed98ec8afa0278325cb2715abb63a84b5de1506362699bc39216bbac4100ae265671f940dbbbdaf9164fd251bdaa7af462a SHA512 c1d99a9dc891c4cfa927e4d2bc5701f47b23b7882cce22350283a53c6ded18e1290196c3bb9838883c29c9cb3582e5e684edffd50dfbb4e9da9c2b821ea54bb5
 DIST python-slugify-5.0.2.tar.gz 11728 BLAKE2B 701fb3f679cd4f714b5c57c14fb8cbfefa5b8268e9c4b877dd1e558e8a7dac325d69519b8e666043b70540908dcb250f561cebf0c5f444f9a3cfae34d97456b1 SHA512 79cdd1d0312c9e34b07dca2e898f177a85b31d3f290403375032ae962df61f3a9c4167f4bdf10f47afd17d544731d6961810f8a081ef615d76d8758c1207e6b7
 DIST python-slugify-6.0.1.tar.gz 12184 BLAKE2B ecc39ad73ba4bf68a630c105b22c234c9f8089c5063457c02b21ae5bbe5c021741ce754eabec51bb125ae549274b26f6cf8d986b66ce0ede5a653e70b4528712 SHA512 b97aba9f3b74009a802b1a7bd356d1eb27d239a05d8617c8f0107391e9f09e9a7cb6b45437755a1c86c4eed966e8975f74f6b760e17090d2c56e4db5935c0b69
 DIST python-slugify-6.1.0.tar.gz 13279 BLAKE2B ecc51c97638f675573576457f6e6dee14fd2f07b9292e3a32134215887adf945e6b7cc0e373b558c7311a49cfbac1b760191b3e77597a86dac1ea48527d549ac SHA512 4a274d5490bbddb8a600357200d44621cf3304c42a303148156cc732650431e76466099e4eee308e81c881b0da4e39b92146561cfd909a796e153411b22405c9
diff --git a/dev-python/python-slugify/python-slugify-4.0.1.ebuild b/dev-python/python-slugify/python-slugify-4.0.1.ebuild
deleted file mode 100644
index 3fa078a90a1a..000000000000
--- a/dev-python/python-slugify/python-slugify-4.0.1.ebuild
+++ /dev/null
@@ -1,21 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-
-inherit distutils-r1
-
-DESCRIPTION="A Python Slugify application that handles Unicode"
-HOMEPAGE="https://github.com/un33k/python-slugify https://pypi.org/project/python-slugify/"
-SRC_URI="https://github.com/un33k/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 ~ppc64 x86"
-IUSE=""
-
-RDEPEND="dev-python/text-unidecode[${PYTHON_USEDEP}]"
-
-distutils_enable_tests unittest
diff --git a/dev-python/python-xmlsec/python-xmlsec-1.3.12-r1.ebuild b/dev-python/python-xmlsec/python-xmlsec-1.3.12-r1.ebuild
new file mode 100644
index 000000000000..7bc693721333
--- /dev/null
+++ b/dev-python/python-xmlsec/python-xmlsec-1.3.12-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for the XML Security Library"
+HOMEPAGE="https://github.com/mehcode/python-xmlsec"
+SRC_URI="https://github.com/mehcode/python-xmlsec/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+RDEPEND="
+	dev-libs/xmlsec:=
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3.11-fix-xml-testfail.patch"
+)
+
+EPYTEST_DESELECT=(
+	# Fragile based on black version?
+	tests/test_type_stubs.py::test_xmlsec_constants_stub
+)
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
diff --git a/dev-python/python-xmp-toolkit/python-xmp-toolkit-2.0.1-r2.ebuild b/dev-python/python-xmp-toolkit/python-xmp-toolkit-2.0.1-r2.ebuild
new file mode 100644
index 000000000000..be8420346777
--- /dev/null
+++ b/dev-python/python-xmp-toolkit/python-xmp-toolkit-2.0.1-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/python-xmp-toolkit/${PN}.git"
+else
+	SRC_URI="https://github.com/python-xmp-toolkit/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Library for working with XMP metadata"
+HOMEPAGE="https://github.com/python-xmp-toolkit/python-xmp-toolkit/ https://pypi.org/project/python-xmp-toolkit/"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( media-libs/exempi )
+"
+RDEPEND="
+	dev-python/pytz[${PYTHON_USEDEP}]
+"
+
+PATCHES=( "${FILESDIR}"/${P}-test.patch )
+
+distutils_enable_tests unittest
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/.build/html/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pywinrm/pywinrm-0.4.2-r1.ebuild b/dev-python/pywinrm/pywinrm-0.4.2-r1.ebuild
new file mode 100644
index 000000000000..f715e6c0ad1e
--- /dev/null
+++ b/dev-python/pywinrm/pywinrm-0.4.2-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for the Windows Remote Management (WinRM) service"
+HOMEPAGE="https://github.com/diyan/pywinrm/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="kerberos"
+
+RDEPEND="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests-ntlm[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	kerberos? (
+		<dev-python/pykerberos-2.0.0[${PYTHON_USEDEP}]
+		dev-python/requests-credssp[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/random2/random2-1.0.1-r2.ebuild b/dev-python/random2/random2-1.0.1-r2.ebuild
new file mode 100644
index 000000000000..da128774253b
--- /dev/null
+++ b/dev-python/random2/random2-1.0.1-r2.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python-2.7 random module ported to python-3"
+HOMEPAGE="https://pypi.org/project/random2/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+BDEPEND="app-arch/unzip"
+
+distutils_enable_tests setup.py
+
+PATCHES=( "${FILESDIR}/${P}-py39-tests.patch" )
diff --git a/dev-python/rjsmin/Manifest b/dev-python/rjsmin/Manifest
index 6e72f9cc9972..bca876d12621 100644
--- a/dev-python/rjsmin/Manifest
+++ b/dev-python/rjsmin/Manifest
@@ -1,2 +1 @@
-DIST rjsmin-1.1.0.gh.tar.gz 437054 BLAKE2B 83b24f1ee94ded66a70ed75b3e494b3e6948edf82fecc80f261964fd2bb032a8cb496ed919f461131b3381c402a6397e65bfa5031f46691c4badfc5e9e2faea2 SHA512 5e168e51e1716fe35a3520fba828d721638094a6f6f73deb4c49183d8cd51531131962e2c7092ada092da63c4ddd615215088bd1a9e474d508f80dc0603d3118
 DIST rjsmin-1.2.0.gh.tar.gz 443279 BLAKE2B 7cb000485fd134fdc590b90766357b0eea5b33a9baf2fb12623ad5a882ac545aa7dd3f447a23c95da3cdf79f44e4f369d48b1cb2e08b790ef7376e9b6c9fa4d8 SHA512 bc40dd59d7dd4e106170db473ef3c3c6df74abdc93d098521f91212a08476541f13a97663c9f56498188c59b3876242c6c81a5633fea84d83e8ab2f7a4d918ad
diff --git a/dev-python/rjsmin/rjsmin-1.1.0.ebuild b/dev-python/rjsmin/rjsmin-1.2.0-r1.ebuild
index 303861961d12..278a2775ebd3 100644
--- a/dev-python/rjsmin/rjsmin-1.1.0.ebuild
+++ b/dev-python/rjsmin/rjsmin-1.2.0-r1.ebuild
@@ -1,9 +1,11 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
+DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} )
+
 inherit distutils-r1
 
 DESCRIPTION="Javascript minifier written in python"
diff --git a/dev-python/rope/rope-0.22.0-r1.ebuild b/dev-python/rope/rope-0.22.0-r1.ebuild
new file mode 100644
index 000000000000..fe040c792cce
--- /dev/null
+++ b/dev-python/rope/rope-0.22.0-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python refactoring library"
+HOMEPAGE="https://github.com/python-rope/rope"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc"
+
+BDEPEND="
+	doc? ( dev-python/docutils[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest-timeout[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	if use doc; then
+		pushd docs > /dev/null || die
+		mkdir build || die
+		local i
+		for i in ./*.rst; do
+			rst2html.py $i > ./build/${i/rst/html} || die
+		done
+		popd > /dev/null || die
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/twython/twython-3.9.1-r1.ebuild b/dev-python/twython/twython-3.9.1-r1.ebuild
new file mode 100644
index 000000000000..60352049de80
--- /dev/null
+++ b/dev-python/twython/twython-3.9.1-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="An easy way to access Twitter data with Python"
+HOMEPAGE="https://github.com/ryanmcgrath/twython"
+SRC_URI="
+	https://github.com/ryanmcgrath/twython/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-oauthlib-0.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# tests are largely unmaintained and outdated
+	tests/test_core.py::TwythonAPITestCase::test_get_lastfunction_header_should_return_header
+	tests/test_core.py::TwythonAPITestCase::test_request_should_handle_400_for_missing_auth_data
+	tests/test_core.py::TwythonAPITestCase::test_request_should_handle_400_that_is_not_auth_related
+	tests/test_core.py::TwythonAPITestCase::test_request_should_handle_401
+	tests/test_core.py::TwythonAPITestCase::test_request_should_handle_rate_limit
+	tests/test_core.py::TwythonAPITestCase::test_sends_correct_accept_encoding_header
+)
diff --git a/dev-python/unicodecsv/unicodecsv-0.14.1-r2.ebuild b/dev-python/unicodecsv/unicodecsv-0.14.1-r2.ebuild
new file mode 100644
index 000000000000..391056a481c8
--- /dev/null
+++ b/dev-python/unicodecsv/unicodecsv-0.14.1-r2.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Drop-in replacement for python stdlib csv module supporting unicode"
+HOMEPAGE="
+	https://pypi.org/project/unicodecsv/
+	https://github.com/jdunck/python-unicodecsv/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# un-depend on unittest2
+	sed -i -e 's:unittest2 as ::' unicodecsv/test.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/validators/validators-0.18.2-r1.ebuild b/dev-python/validators/validators-0.18.2-r1.ebuild
new file mode 100644
index 000000000000..4eb94c24f88c
--- /dev/null
+++ b/dev-python/validators/validators-0.18.2-r1.ebuild
@@ -0,0 +1,24 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Data Validation for Humans"
+HOMEPAGE="https://github.com/kvesteri/validators"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/decorator-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/wsproto/wsproto-1.0.0-r1.ebuild b/dev-python/wsproto/wsproto-1.0.0-r1.ebuild
new file mode 100644
index 000000000000..daf5146eada4
--- /dev/null
+++ b/dev-python/wsproto/wsproto-1.0.0-r1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="WebSockets state-machine based protocol implementation"
+HOMEPAGE="
+	https://github.com/python-hyper/wsproto/
+	https://pypi.org/project/wsproto/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/h11-0.9[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/xlrd/xlrd-2.0.1-r1.ebuild b/dev-python/xlrd/xlrd-2.0.1-r1.ebuild
new file mode 100644
index 000000000000..3aee34e15581
--- /dev/null
+++ b/dev-python/xlrd/xlrd-2.0.1-r1.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library to extract data from Microsoft Excel spreadsheets"
+HOMEPAGE="
+	https://www.python-excel.org/
+	https://github.com/python-excel/xlrd/
+"
+SRC_URI="
+	https://github.com/python-excel/xlrd/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+distutils_enable_tests pytest
diff --git a/dev-python/xlwt/xlwt-1.3.0-r2.ebuild b/dev-python/xlwt/xlwt-1.3.0-r2.ebuild
new file mode 100644
index 000000000000..ea8b3b6ee46e
--- /dev/null
+++ b/dev-python/xlwt/xlwt-1.3.0-r2.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library to create spreadsheet files compatible with Excel"
+HOMEPAGE="https://pypi.org/project/xlwt/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+distutils_enable_sphinx docs \
+	dev-python/pkginfo
+distutils_enable_tests nose
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/zeep/zeep-4.1.0-r2.ebuild b/dev-python/zeep/zeep-4.1.0-r2.ebuild
new file mode 100644
index 000000000000..e0ad45f0acd7
--- /dev/null
+++ b/dev-python/zeep/zeep-4.1.0-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A modern/fast Python SOAP client based on lxml / requests"
+HOMEPAGE="https://docs.python-zeep.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="async"
+
+RDEPEND="
+	>=dev-python/attrs-17.2.0[${PYTHON_USEDEP}]
+	>=dev-python/isodate-0.5.4[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.6.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-file-1.5.1[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.7.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	async? ( >=dev-python/aiohttp-1.0[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/aioresponses[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/python-xmlsec[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-httpx[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${P}-cached-prop.patch
+)
+
+EPYTEST_DESELECT=(
+	# broken by new pytest-httpx?
+	tests/test_async_transport.py::test_load
+	tests/test_async_transport.py::test_load_cache
+	tests/test_async_transport.py::test_post
+	tests/test_async_transport.py::test_http_error
+)