Adding metadata

6 files changed, 113 insertions, 214 deletions

diff --git a/dev-python/jaraco-test/Manifest b/dev-python/jaraco-test/Manifest
index 1372386c1643..0f460dbc2328 100644
--- a/dev-python/jaraco-test/Manifest
+++ b/dev-python/jaraco-test/Manifest
@@ -1 +1,2 @@
 DIST jaraco.test-5.1.0.tar.gz 6700 BLAKE2B 69ac08ab7e1c8aeff45d25483f2bb2648ad57a5977dbff8aab844f114a15f054b782ad5b424d9baa805ab80fc7483362dc97320965ef0abe86573b1e7f40b97b SHA512 d1d93eab85068fcba94530df50da9221b7f574e58b2c4ed519c8c4dec7231aa982d588e29137418226f23e0f94bd98f47c0859cf14d7a58c1683ac8ccc24d900
+DIST jaraco.test-5.2.0.tar.gz 8000 BLAKE2B 21e0714537a9966cc285eb1458f313c354226903ee3da816d7a6620676716cf9c220f82963c8b8ea7ac7a1d641f174d5c72dcca43c68c62e4f929c411aa00d62 SHA512 25cd7d5defda6941569958ce61cf41b54555d54c7dc1e115de409d6da352f8e8c09b8671adbdfdc00cf6f1c60a0d43201680c40dbeda44bdcf11a0e64cb23751
diff --git a/dev-python/jaraco-test/jaraco-test-5.2.0.ebuild b/dev-python/jaraco-test/jaraco-test-5.2.0.ebuild
new file mode 100644
index 000000000000..ed4a48b8cd71
--- /dev/null
+++ b/dev-python/jaraco-test/jaraco-test-5.2.0.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Testing support by jaraco"
+HOMEPAGE="
+	https://github.com/jaraco/jaraco.test/
+	https://pypi.org/project/jaraco.test/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~x86"
+
+RDEPEND="
+	dev-python/jaraco-context[${PYTHON_USEDEP}]
+	dev-python/jaraco-functools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pydantic/Manifest b/dev-python/pydantic/Manifest
index 83a961beb5b7..58ab5d422376 100644
--- a/dev-python/pydantic/Manifest
+++ b/dev-python/pydantic/Manifest
@@ -1,2 +1,3 @@
 DIST pydantic-1.10.2.gh.tar.gz 888288 BLAKE2B 9aac69ace185ccc56255cf36f9af472caf4c6bcbdcbb81eec66353f755673e9a240e7713c0a2ecff00a02e07b0069e4b3f1edda41f345698a979b79dd54b354a SHA512 dc2acfb271cd62b6de08bbaa48dbc76ec8d3a3f3142778ffa2cb9a2a1cad62dbdb3c7470a50e9a2825837b65a48c6aefb8736411f32c398aa9ca779841b53ac5
 DIST pydantic-1.10.3.gh.tar.gz 898768 BLAKE2B e8cec71f0d3f66e2c71e421505f624f7e92827f8fe4ef3a7c637b4f2cbc543d43e63739f8fed1a84246458d6675f19de9f83c7fc2a1d8f6e9fb18807ad5ace6f SHA512 7c9db4a010f14ab41b0e7782e59e51caded5de31798e4dd83e01037e3365e34537b30c79c12a6451fdee875e1bfe1a3d981cae58aa373917f71489231df2e6a6
+DIST pydantic-1.10.4.gh.tar.gz 898916 BLAKE2B 506a53de6a59f858a7c8fd56cf18f8079d48eb4f6d3ba36d149141a7e2d471819a466bfc1c34c879f5ec90c0de385b2b89d58beb75660da7de282278092e901f SHA512 0566f89518c6f0171c9b49b5fb57e568286ed421d64655dde90a1565d0672bfef6237ed99e4120564ca2562c7e29e08d86db4fcec47e605aaa98d60845688e72
diff --git a/dev-python/pydantic/pydantic-1.10.4.ebuild b/dev-python/pydantic/pydantic-1.10.4.ebuild
new file mode 100644
index 000000000000..f7bba52912d1
--- /dev/null
+++ b/dev-python/pydantic/pydantic-1.10.4.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_beta/b}
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+	https://github.com/pydantic/pydantic/
+	https://pypi.org/project/pydantic/
+"
+SRC_URI="
+	https://github.com/pydantic/pydantic/archive/v${PV/_beta/b}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+RDEPEND="
+	>=dev-python/typing-extensions-4.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		>=dev-python/python-email-validator-1.2.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/CFLAGS/d' setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	if [[ ${EPYTHON} == pypy3 ]] || ! use native-extensions; then
+		# do not build extensions on PyPy to workaround
+		# https://github.com/cython/cython/issues/4763
+		local -x SKIP_CYTHON=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_mock
+
+	local EPYTEST_DESELECT=(
+		# flaky test, known upstream
+		tests/test_hypothesis_plugin.py::test_can_construct_models_with_all_fields
+		# mypy linting causes regressions with new mypy versions
+		tests/mypy
+	)
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				tests/test_private_attributes.py::test_private_attribute
+				tests/test_private_attributes.py::test_private_attribute_annotation
+				tests/test_private_attributes.py::test_private_attribute_factory
+				tests/test_private_attributes.py::test_private_attribute_multiple_inheritance
+				tests/test_private_attributes.py::test_underscore_attrs_are_private
+			)
+			;;
+	esac
+	rm -rf pydantic || die
+	epytest
+}
diff --git a/dev-python/pypy3/Manifest b/dev-python/pypy3/Manifest
index 0daea7358f91..c04d96f5f6e5 100644
--- a/dev-python/pypy3/Manifest
+++ b/dev-python/pypy3/Manifest
@@ -1,6 +1,4 @@
 DIST pypy3.9-gentoo-patches-7.3.10.tar.xz 10012 BLAKE2B 45186cf6e8608995af6c0d763a2d676d862ba886acb3a0e0f0056309123d0db75240a175ecf90e24889a139f228dffc788872a5ca84736f4ce0901eda0acb789 SHA512 e6c39666f34bb7e2db72f153fad2d89421b30c04de88812637027a7e8a73bccc7620a7296b2b205464ad7fd0c911bc7a7f0dc0fc504dc8d163f7087b8b0c61b3
 DIST pypy3.9-gentoo-patches-7.3.11.tar.xz 6444 BLAKE2B adcc1ae4c3ae2c5317a05d6de51785945625d8bcc7cb35bd6608fa80f09b37c483c95663eacb0353013a5abec308d25b12666699c65512f5f3a6d7345f2b5b18 SHA512 f2064ecffa09ba23f5f8c281ca4c8c0740cb6b57185d66c02eec2bcb77cfb566b1a2db4f52c472bcaf0d5fb759ee8003b27761af37785d12465c2010fd73c49d
-DIST pypy3.9-gentoo-patches-7.3.9.tar.xz 1564 BLAKE2B fe0875ef002842a78fb31589f6d0b255c3dea10f2bd014231ae9b17641f65f810ac84fe7961de1a4614249b0166f2127c3aa37947f7d1d4c85860a31b89110f1 SHA512 a1dc3ee36e908e29b2bbbb100a97b7910bd4325c5dc55c0455cdca450d6b272d1463708b383e0607e9499b1932da4442f97d2da57e47ed3a4ff8fd3c78a54732
 DIST pypy3.9-v7.3.10-src.tar.bz2 23416039 BLAKE2B 1b13e8bbe6c38c4b9183a632063aeed593986bc7906cfe527fa7534d29f9b1ae0f1e6d3795ff73be19f5737c3fd9d1b3cc2777f30d9237d853e4266bea60a5bb SHA512 1ed3fc9cdda7f3144141fc6a37b124e7141cb3f294ce8b5ca3c3aa30a3c58715e168879decaa796c890a9a287c82c2dbabb81db5f6b8d17f4215d7d3261fe9a8
 DIST pypy3.9-v7.3.11-src.tar.bz2 23460769 BLAKE2B fa8a827c28813243926c8689addb008c0a43acdc3f81a18749a8f2c1926b6294f2c0c95a4c315e3b77ce84b4f337af7a0bce5daf8dcb60ead965532d4af183cb SHA512 33c978ffbeeb39453028d1d1646ccfdace062ce48a5d939245bea41643038dd3687e80e34f88fa0622bcb175d7dd78f75cbe36b24229c8052f09d2d17dcdfd8c
-DIST pypy3.9-v7.3.9-src.tar.bz2 26976726 BLAKE2B bf1ed21c575901abac020120aaff07ab57f1404713211b19cbd1eb4d6ffc675b7933be8c6fffc2b69ab467963d6598534cd5aa90c02feddad596611d2a6b6581 SHA512 83f8a6a2da351c190d2d224242cbc35e35529c7a8e8d842eaf5c945cbce2e172b02a340f32af3d49df8d5288370d794d5bc95fc12dd4a13d817c925abf06198a
diff --git a/dev-python/pypy3/pypy3-7.3.9-r1.ebuild b/dev-python/pypy3/pypy3-7.3.9-r1.ebuild
deleted file mode 100644
index 5f860f40a8f4..000000000000
--- a/dev-python/pypy3/pypy3-7.3.9-r1.ebuild
+++ /dev/null
@@ -1,212 +0,0 @@
-# Copyright 2022 Liguros Authors
-# Distributed under the terms of the GNU General Public License v2
-EAPI=8
-
-PYTHON_COMPAT=( python2_7 )
-inherit pax-utils python-any-r1 toolchain-funcs
-
-PYPY_PV=${PV%_p*}
-MY_P=pypy3.9-v${PYPY_PV/_rc/rc}
-PATCHSET="pypy3.9-gentoo-patches-${PV/_rc/rc}"
-
-DESCRIPTION="A fast, compliant alternative implementation of the Python (3.9) language"
-HOMEPAGE="https://www.pypy.org/"
-SRC_URI="
-	https://buildbot.pypy.org/pypy/${MY_P}-src.tar.bz2
-	https://dev.gentoo.org/~mgorny/dist/python/${PATCHSET}.tar.xz
-"
-S="${WORKDIR}/${MY_P}-src"
-
-LICENSE="MIT"
-# pypy3 -c 'import sysconfig; print(sysconfig.get_config_var("SOABI"))'
-# also check pypy/interpreter/pycode.py -> pypy_incremental_magic
-SLOT="0/pypy39-pp73"
-KEYWORDS="amd64 ~arm64 ~ppc64 x86 ~amd64-linux ~x86-linux"
-IUSE="bzip2 gdbm +jit libressl ncurses sqlite test tk"
-# many tests are failing upstream
-# see https://buildbot.pypy.org/summary?branch=py3.9
-RESTRICT="test"
-
-RDEPEND="
-	|| (
-		>=dev-python/pypy3-exe-${PYPY_PV}:3.9-${PYPY_PV}[bzip2?,ncurses?]
-		>=dev-python/pypy3-exe-bin-${PYPY_PV}:3.9-${PYPY_PV}
-	)
-	dev-lang/python-exec[python_targets_pypy3(-)]
-	!libressl? ( dev-libs/openssl:0= )
-	libressl? ( >=dev-libs/libressl-3.6.0:0= )
-	gdbm? ( sys-libs/gdbm:0= )
-	sqlite? ( dev-db/sqlite:3= )
-	tk? (
-		dev-lang/tk:0=
-		dev-tcltk/tix:0=
-	)
-	!<dev-python/pypy3-bin-7.3.0:0
-"
-DEPEND="
-	${RDEPEND}
-	test? (
-		${PYTHON_DEPS}
-		!!dev-python/pytest-forked
-	)
-"
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	local PATCHES=(
-		"${WORKDIR}/${PATCHSET}"
-	)
-	default
-
-	eapply_user
-	eapply -p0 ${FILESDIR}/openssl_ct.patch
-	eapply -p0 ${FILESDIR}/openssl_dh.patch
-	eapply -p0 ${FILESDIR}/openssl_evp.patch
-	eapply -p0 ${FILESDIR}/openssl_hmac.patch
-	eapply -p0 ${FILESDIR}/openssl_ocsp.patch
-	eapply -p0 ${FILESDIR}/openssl_ssl.patch
-	eapply -p0 ${FILESDIR}/openssl_x509.patch
-	eapply -p0 ${FILESDIR}/openssl_x509name.patch
-	eapply -p1 ${FILESDIR}/openssl_proto.patch
-	eapply -p1 ${FILESDIR}/ssl_python.patch
-	eapply -p1 ${FILESDIR}/cryptography.patch
-	eapply -p1 ${FILESDIR}/openssl_cleanup.patch
-}
-
-src_configure() {
-	tc-export CC
-}
-
-src_compile() {
-	mkdir bin || die
-	# switch to the layout expected for cffi module builds
-	mkdir include/pypy3.9 || die
-	# copy over to make sys.prefix happy
-	cp -p "${BROOT}"/usr/bin/pypy3.9-c-${PYPY_PV} pypy3.9-c || die
-	cp -p "${BROOT}"/usr/include/pypy3.9/${PYPY_PV}/* include/pypy3.9/ || die
-	# (not installed by pypy-exe)
-	rm pypy/module/cpyext/include/_numpypy/numpy/README || die
-	mv pypy/module/cpyext/include/* include/pypy3.9/ || die
-	mv pypy/module/cpyext/parse/*.h include/pypy3.9/ || die
-	pax-mark m pypy3.9-c
-
-	# verify the subslot
-	local soabi=$(
-		./pypy3.9-c - <<-EOF
-			import sysconfig
-			print(sysconfig.get_config_var("SOABI"))
-		EOF
-	)
-	[[ ${soabi} == ${SLOT#*/} ]] || die "update subslot to ${soabi}"
-
-	einfo "Generating caches and CFFI modules ..."
-
-	# Generate Grammar and PatternGrammar pickles.
-	./pypy3.9-c - <<-EOF || die "Generation of Grammar and PatternGrammar pickles failed"
-		import lib2to3.pygram
-		import lib2to3.patcomp
-		lib2to3.patcomp.PatternCompiler()
-	EOF
-
-	# Generate cffi modules
-	# Please keep in sync with pypy/tool/build_cffi_imports.py!
-	# (NB: we build CFFI modules first to avoid error log when importing
-	# build_cffi_imports).
-	cffi_targets=( pypy_util blake2/_blake2 sha3/_sha3 ssl
-		audioop syslog pwdgrp resource lzma posixshmem )
-	use gdbm && cffi_targets+=( gdbm )
-	use ncurses && cffi_targets+=( curses )
-	use sqlite && cffi_targets+=( sqlite3 )
-	use tk && cffi_targets+=( tkinter/tklib )
-
-	local t
-	# all modules except tkinter output to .
-	# tkinter outputs to the correct dir ...
-	cd lib_pypy || die
-	for t in "${cffi_targets[@]}"; do
-		# tkinter doesn't work via -m
-		../pypy3.9-c "_${t}_build.py" || die "Failed to build CFFI bindings for ${t}"
-	done
-
-	# Verify that CFFI module list is up-to-date
-	local expected_cksum=63d4659f
-	local local_cksum=$(
-		../pypy3.9-c - <<-EOF
-			import binascii
-			import json
-			from pypy_tools.build_cffi_imports import cffi_build_scripts as x
-			print("%08x" % (binascii.crc32(json.dumps(x).encode()),))
-		EOF
-	)
-	if [[ ${local_cksum} != ${expected_cksum} ]]; then
-		die "Please verify cffi_targets and update checksum to ${local_cksum}"
-	fi
-
-	# Cleanup temporary objects
-	find -name "*_cffi.[co]" -delete || die
-	find -type d -empty -delete || die
-}
-
-src_test() {
-	# (unset)
-	local -x PYTHONDONTWRITEBYTECODE=
-	local -x COLUMNS=80
-
-	# Test runner requires Python 2 too. However, it spawns PyPy3
-	# internally so that we end up testing the correct interpreter.
-	# (--deselect for failing doctests)
-	"${EPYTHON}" ./pypy/test_all.py --pypy=./pypy3.9-c -vv lib-python || die
-}
-
-src_install() {
-	einfo "Installing PyPy ..."
-	dodir /usr/bin
-	dosym pypy3.9-c-${PYPY_PV} /usr/bin/pypy3.9
-	dosym pypy3.9 /usr/bin/pypy3
-	insinto /usr/lib/pypy3.9
-	# preserve mtimes to avoid obsoleting caches
-	insopts -p
-	doins -r lib-python/3/. lib_pypy/.
-	insinto /usr/include
-	doins -r include/pypy3.9
-
-	# replace copied headers with symlinks
-	for x in "${BROOT}"/usr/include/pypy3.9/${PYPY_PV}/*; do
-		dosym "${PYPY_PV}/${x##*/}" "/usr/include/pypy3.9/${x##*/}"
-	done
-
-	dodoc README.rst
-
-	local dest=/usr/lib/pypy3.9
-	if ! use gdbm; then
-		rm -r "${ED}${dest}"/_gdbm* || die
-	fi
-	if ! use sqlite; then
-		rm -r "${ED}${dest}"/sqlite3 \
-			"${ED}${dest}"/_sqlite3* \
-			"${ED}${dest}"/test/test_sqlite.py || die
-	fi
-	if ! use tk; then
-		rm -r "${ED}${dest}"/{idlelib,tkinter} \
-			"${ED}${dest}"/_tkinter \
-			"${ED}${dest}"/test/test_{tcl,tk,ttk*}.py || die
-	fi
-
-	local -x EPYTHON=pypy3
-	local -x PYTHON=${ED}/usr/bin/pypy3.9-c-${PYPY_PV}
-	# temporarily copy to build tree to facilitate module builds
-	cp -p "${BROOT}/usr/bin/pypy3.9-c-${PYPY_PV}" "${PYTHON}" || die
-
-	echo "EPYTHON='${EPYTHON}'" > epython.py || die
-	python_moduleinto "${dest}"/site-packages
-	python_domodule epython.py
-
-	einfo "Byte-compiling Python standard library..."
-	python_optimize "${ED}${dest}"
-
-	# remove to avoid collisions
-	rm "${PYTHON}" || die
-}