Adding metadata

19 files changed, 236 insertions, 14 deletions

diff --git a/dev-python/docutils-glep/docutils-glep-1.2.ebuild b/dev-python/docutils-glep/docutils-glep-1.2.ebuild
index 1e3b5224e5f5..3c986bb637d7 100644
--- a/dev-python/docutils-glep/docutils-glep-1.2.ebuild
+++ b/dev-python/docutils-glep/docutils-glep-1.2.ebuild
@@ -1,11 +1,9 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-DISTUTILS_USE_SETUPTOOLS=rdepend
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-
 inherit distutils-r1
 
 MY_PN=${PN/-/_}
@@ -13,11 +11,10 @@ MY_P=${MY_PN}-${PV}
 DESCRIPTION="Gentoo GLEP support for docutils"
 HOMEPAGE="https://github.com/mgorny/docutils-glep/"
 SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
 
 LICENSE="public-domain"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 
 RDEPEND=">=dev-python/docutils-0.10[${PYTHON_USEDEP}]"
-
-S=${WORKDIR}/${MY_P}
diff --git a/dev-python/fasteners/Manifest b/dev-python/fasteners/Manifest
index 00076f3a57be..c571a9b13ca3 100644
--- a/dev-python/fasteners/Manifest
+++ b/dev-python/fasteners/Manifest
@@ -1 +1,2 @@
+DIST fasteners-0.16.1.gh.tar.gz 28572 BLAKE2B 8434f2b47eae01bc3eb239df7adf1106299d76e577724291aef82fca2b68c7a7b5b82fa37a80d1d9ca0315615586c61b29bd4f6ac5cfce6fad798b4423eae64d SHA512 e2f94ad4d19fb425f507236ffa4611127d6254485daef4a818e4508ce935aa7a7100c2bb91343697d6005f4c220d8060fbcba19ca1e2dc257be756b0e24454df
 DIST fasteners-0.16.tar.gz 24824 BLAKE2B 5072c1e0633bcf83ad71176dd7f9e2a2179ce4abdddee4bdcfa28f90d7f617759dc855e7fd91afb8b734d5b455d2597e748c169538780927e4d17c93e829453c SHA512 aac91be8f732bcda238c40317359c7faaad632b26473eff940fef0c6c2c227cd83942122c0ec26da236ca8c19d3024798590244ec761c2d2700ffdc7142533da
diff --git a/dev-python/fasteners/fasteners-0.16.1.ebuild b/dev-python/fasteners/fasteners-0.16.1.ebuild
new file mode 100644
index 000000000000..2a7cb114a7d0
--- /dev/null
+++ b/dev-python/fasteners/fasteners-0.16.1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python package that provides useful locks"
+HOMEPAGE="https://github.com/harlowja/fasteners/"
+SRC_URI="
+	https://github.com/harlowja/fasteners/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+BDEPEND="
+	test? (
+		dev-python/diskcache[${PYTHON_USEDEP}]
+		dev-python/more-itertools[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_install() {
+	# https://github.com/harlowja/fasteners/pull/70
+	rm -r "${BUILD_DIR}"/lib/tests || die
+	distutils-r1_python_install
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 55bca9156656..d59f3bf32796 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -3,6 +3,7 @@ DIST hypothesis-python-6.13.0.tar.gz 9128293 BLAKE2B be618d42639602bc6617f8b5e93
 DIST hypothesis-python-6.13.10.tar.gz 9132876 BLAKE2B fb9b48465fd6e6ce08423384753ef3149aac6e2b57230f44119ad685c530ac68fac0b1a1925f2ab98586265055151e9564fa287262b06aefe68c2a78d8b3ae4d SHA512 f166a025dee3ec31033d8f8a3909e6f9ee4b2e14420ae41777a41163384502cfe9f20632fb134e38797817ee19972a7068e4233e64417fb4cf5af51427a1963c
 DIST hypothesis-python-6.13.11.tar.gz 9133504 BLAKE2B b9cb54dc05aafd57424a2f9fff097a66e3ba5e55408f8a4587eb7aee079f1ad494e3a9cc18a7797c09fa4444715290dc49c58b98e722dc0722d8cad0d6cbbe0d SHA512 9cb8ce31a7062ab98db829300c1f68e1e24bf02a39ebf4ffbbf47554741dd0bdb96edd69aa7a360570405ca85b1fd7956eb26c5b9a6898f6f8f6f79177522bf6
 DIST hypothesis-python-6.13.12.tar.gz 9133873 BLAKE2B 161e323d9dad6d6a91641336b6e66fe0b00bcc902d844480ed0cea59b89c455eaaf8f57122636af464719d63cf96d0dfeb42dbd855d5599856636b4f4e1520bd SHA512 e58d9a676b9f6592134f4f4997d7585001c28980697e77f8f3216c5bba65256c15784e7eec5458f58684b61cc5a0d9ef2465748412a601a867a70e5b72fde91d
+DIST hypothesis-python-6.13.13.tar.gz 9133621 BLAKE2B b21d2b566aac70d30abd8dbd96aafbe0f16b9d4cfe997d88bbd36724bd90ba7c747c87275d47d977a065431c87a5b75814a774fa34c9360f973829382e94e6d2 SHA512 87564b6b1d3c917d50feb1ee3b0f3f16fb880d42f8226f50ede28b175471b65cac4286d0569d4a33c82f5924df7941c0b2b49862f9e79fc851ec4d3e556a2a2d
 DIST hypothesis-python-6.13.2.tar.gz 9130008 BLAKE2B 3ca5c306ac402002a1435b8ccbc034f2a7acf1553eb6095e0394ff1ddf778f47ef6f72359cb5219db924edc18623b22732b4a94bd7c269217ec632b8d59adc1c SHA512 8c7e1a5de011ef66f5105009aa82f2b23ff36f0b0906554ae65e2e55e10c4df743c894b6264002c86bae3fc5e1dd7ded7e913f0866ed725e1afd4c9f54022b7c
 DIST hypothesis-python-6.13.4.tar.gz 9130435 BLAKE2B eeb78cc647df49ea11fb0e0f4d8412e20095e7c33bb0601dcbaad2b9e9929423729b25b1bfbf2a27b05e87ae38ced4e9aeba5bae4de76cfc81aae2d073248de0 SHA512 93db99bdbe408ddbad4baf983b00b3e7624fd28d15a0d4c1453437328a51b0733db13e3b7b04b40bc60aa05e2e8364ce5b186d81a2d33e50b49f5a406fec95d6
 DIST hypothesis-python-6.13.5.tar.gz 9131314 BLAKE2B 3de7ba681ab9c0907920ea7ad562a4434f06009a7bced47b98bf46da5d15aea35085350f4aca24fd41ba9fd14957e4de1d56092d49e757ea60a1575f59371add SHA512 06765607be1a49d92382d426105021ed9dca91c5b41674ba45f0a29ce7cb06537edf706ea7305300f9aae7d8c9b1827bcaf807e3c4aece9594a55b3c0122c622
diff --git a/dev-python/hypothesis/hypothesis-6.13.13.ebuild b/dev-python/hypothesis/hypothesis-6.13.13.ebuild
new file mode 100644
index 000000000000..3858e9c1e208
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.13.13.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' python3_{7..9})
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!dev-python/pytest-describe
+		!!<dev-python/typing-3.7.4.1
+	)
+"
+
+distutils_enable_tests --install pytest
+
+python_prepare() {
+	if ! use cli || ! has "${EPYTHON}" python3_{7..9}; then
+		sed -i -e '/console_scripts/d' setup.py || die
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	epytest tests/cover tests/pytest tests/quality \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/importlib_metadata/Manifest b/dev-python/importlib_metadata/Manifest
index 36de8fa18f15..28edfadf9004 100644
--- a/dev-python/importlib_metadata/Manifest
+++ b/dev-python/importlib_metadata/Manifest
@@ -3,3 +3,4 @@ DIST importlib_metadata-4.0.0.tar.gz 41881 BLAKE2B cd0330e2a5959f651ef6ceee72276
 DIST importlib_metadata-4.3.0.tar.gz 38461 BLAKE2B 5c8387aa618b6561910adf48a701b28556574abe0a4aacc6ae8fbecb258cd0308f637a95402a07c2452ba92daca39034a5fdaac03608e5112534c379e66aa4b9 SHA512 44e3da5207ae6900059758ab26636798fafa9d186d045096e382660083909305887e28c63c2147c940f0af5870d1781f69968c9cc992e50811b5f9b055048459
 DIST importlib_metadata-4.3.1.tar.gz 38637 BLAKE2B f9c9330fd9b63bbea3fc30ed6d3cc384f9b241f0089ca7b0b5fe1934214e9f644c3884ecfc866b9b9e6af6c0fd7d04fc5e8af83e252d2e1b0e274fcf408a7323 SHA512 2202be5f7b7f1c1fdad4c6b290da60fa5c9576c665c11f9c62012791b50ee0b6da029bbe424c9501ac1f663f4df883fbd3c6cb9179cb80491b2b350cfa2eec30
 DIST importlib_metadata-4.4.0.tar.gz 39577 BLAKE2B 1c1536b72385380176febfe012b5e47bc4d1b1382e048dd6383b5097f8047404a9a726438100e6f812f397f425e4d0d92ff296530e1f81cf16d3f26a57f47e48 SHA512 d227caaa1130d5023a87e5fa32aa1cd473ff0ae09cd82969be86f4301402cacee068dfc5d744bff82a18abb86848780013b6e6b2ebfa8a568ee027c270b90efd
+DIST importlib_metadata-4.5.0.tar.gz 39595 BLAKE2B 22ef03a47637f523b583cb8c442f7351e0b94633772978fea47dab9be583f35daa32691997b4110b832709658568b6eb79a006f109b969c6f25a638dcfcd4702 SHA512 62b9cefa502d751d36b5f43606ea86c46574fea159941b68319e5dd9aa53d6d990e630c36d72830c54eb2bba2f2be53201be2482974f833cc1da8869eb2a8dc2
diff --git a/dev-python/importlib_metadata/importlib_metadata-4.5.0.ebuild b/dev-python/importlib_metadata/importlib_metadata-4.5.0.ebuild
new file mode 100644
index 000000000000..d8ffe7900793
--- /dev/null
+++ b/dev-python/importlib_metadata/importlib_metadata-4.5.0.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# NB: this package extends beyond built-in importlib stuff in py3.8+
+# new entry_point API not yet included in cpython release
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="https://github.com/python/importlib_metadata"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	$(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' pypy3)
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/importlib_resources[${PYTHON_USEDEP}]
+		' pypy3 python3_8)
+	)
+"
+
+distutils_enable_sphinx docs dev-python/jaraco-packaging dev-python/rst-linker
+distutils_enable_tests unittest
+
+python_prepare_all() {
+	# Skip a test that requires pep517 which is not in the tree
+	sed -e 's:test_find_local:_&:' -i tests/test_integration.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/libsass/libsass-0.21.0.ebuild b/dev-python/libsass/libsass-0.21.0.ebuild
index aaf64cec739a..83447302c25a 100644
--- a/dev-python/libsass/libsass-0.21.0.ebuild
+++ b/dev-python/libsass/libsass-0.21.0.ebuild
@@ -4,7 +4,7 @@
 EAPI=7
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-inherit distutils-r1
+inherit distutils-r1 toolchain-funcs
 
 MY_P="libsass-python-${PV}"
 DESCRIPTION="A straightforward binding of libsass for Python"
@@ -37,6 +37,10 @@ src_prepare() {
 	echo "${PV}" > .libsass-upstream-version || die
 	distutils-r1_src_prepare
 	export SYSTEM_SASS=1
+	# https://bugs.gentoo.org/730244
+	if tc-is-clang; then
+		sed -i -e 's/-std=gnu++0x//g' setup.py || die
+	fi
 }
 
 python_test() {
diff --git a/dev-python/sphinx/files/sphinx-4.0.2-py310.patch b/dev-python/sphinx/files/sphinx-4.0.2-py310.patch
new file mode 100644
index 000000000000..db0facafed5f
--- /dev/null
+++ b/dev-python/sphinx/files/sphinx-4.0.2-py310.patch
@@ -0,0 +1,28 @@
+From 531a5ae9ef855761407d44fb49064ae6227868f5 Mon Sep 17 00:00:00 2001
+From: Takeshi KOMIYA <i.tkomiya@gmail.com>
+Date: Wed, 5 May 2021 22:11:41 +0900
+Subject: [PATCH] test: Adjust type annotataions in python 3.10.0b1
+
+---
+ tests/test_util_inspect.py | 5 +----
+ 1 file changed, 1 insertion(+), 4 deletions(-)
+
+diff --git a/tests/test_util_inspect.py b/tests/test_util_inspect.py
+index 7b86c6ade..8df06a865 100644
+--- a/tests/test_util_inspect.py
++++ b/tests/test_util_inspect.py
+@@ -183,10 +183,7 @@ def test_signature_annotations():
+ 
+     # Instance annotations
+     sig = inspect.signature(f11)
+-    if sys.version_info < (3, 10):
+-        assert stringify_signature(sig) == '(x: CustomAnnotation, y: 123) -> None'
+-    else:
+-        assert stringify_signature(sig) == '(x: CustomAnnotation(), y: 123) -> None'
++    assert stringify_signature(sig) == '(x: CustomAnnotation, y: 123) -> None'
+ 
+     # tuple with more than two items
+     sig = inspect.signature(f12)
+-- 
+2.31.1
+
diff --git a/dev-python/sphinx/sphinx-4.0.2.ebuild b/dev-python/sphinx/sphinx-4.0.2.ebuild
index 107c5d1787be..19361d922342 100644
--- a/dev-python/sphinx/sphinx-4.0.2.ebuild
+++ b/dev-python/sphinx/sphinx-4.0.2.ebuild
@@ -60,6 +60,7 @@ BDEPEND="
 
 PATCHES=(
 	"${FILESDIR}/${PN}-3.2.1-doc-link.patch"
+	"${FILESDIR}/${P}-py310.patch"
 )
 
 distutils_enable_tests pytest
diff --git a/dev-python/sphinxcontrib-applehelp/sphinxcontrib-applehelp-1.0.2.ebuild b/dev-python/sphinxcontrib-applehelp/sphinxcontrib-applehelp-1.0.2.ebuild
index 9261e6a94d11..aaf31ea0844c 100644
--- a/dev-python/sphinxcontrib-applehelp/sphinxcontrib-applehelp-1.0.2.ebuild
+++ b/dev-python/sphinxcontrib-applehelp/sphinxcontrib-applehelp-1.0.2.ebuild
@@ -2,8 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="Sphinx extension which outputs Apple help book"
diff --git a/dev-python/sphinxcontrib-devhelp/sphinxcontrib-devhelp-1.0.2.ebuild b/dev-python/sphinxcontrib-devhelp/sphinxcontrib-devhelp-1.0.2.ebuild
index 613f96fb4e75..649e6dafb751 100644
--- a/dev-python/sphinxcontrib-devhelp/sphinxcontrib-devhelp-1.0.2.ebuild
+++ b/dev-python/sphinxcontrib-devhelp/sphinxcontrib-devhelp-1.0.2.ebuild
@@ -2,8 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="Sphinx extension which outputs Devhelp documents"
diff --git a/dev-python/sphinxcontrib-htmlhelp/sphinxcontrib-htmlhelp-2.0.0.ebuild b/dev-python/sphinxcontrib-htmlhelp/sphinxcontrib-htmlhelp-2.0.0.ebuild
index 28afa2dc324f..7bc42e4c2f91 100644
--- a/dev-python/sphinxcontrib-htmlhelp/sphinxcontrib-htmlhelp-2.0.0.ebuild
+++ b/dev-python/sphinxcontrib-htmlhelp/sphinxcontrib-htmlhelp-2.0.0.ebuild
@@ -2,8 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="Sphinx extension which outputs HTML help book"
diff --git a/dev-python/sphinxcontrib-jsmath/sphinxcontrib-jsmath-1.0.1-r1.ebuild b/dev-python/sphinxcontrib-jsmath/sphinxcontrib-jsmath-1.0.1-r1.ebuild
index 99b356e2feb3..ea050be27d75 100644
--- a/dev-python/sphinxcontrib-jsmath/sphinxcontrib-jsmath-1.0.1-r1.ebuild
+++ b/dev-python/sphinxcontrib-jsmath/sphinxcontrib-jsmath-1.0.1-r1.ebuild
@@ -2,8 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="Sphinx extension which renders display math in HTML via JavaScript"
diff --git a/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3.ebuild b/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3.ebuild
index a89013f00230..1820f79af552 100644
--- a/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3.ebuild
+++ b/dev-python/sphinxcontrib-qthelp/sphinxcontrib-qthelp-1.0.3.ebuild
@@ -2,8 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="Sphinx extension which outputs QtHelp documents"
diff --git a/dev-python/sphinxcontrib-serializinghtml/sphinxcontrib-serializinghtml-1.1.5.ebuild b/dev-python/sphinxcontrib-serializinghtml/sphinxcontrib-serializinghtml-1.1.5.ebuild
index 19a17b7ca706..b0c8f9f9c4b5 100644
--- a/dev-python/sphinxcontrib-serializinghtml/sphinxcontrib-serializinghtml-1.1.5.ebuild
+++ b/dev-python/sphinxcontrib-serializinghtml/sphinxcontrib-serializinghtml-1.1.5.ebuild
@@ -2,8 +2,8 @@
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
-PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
 inherit distutils-r1
 
 DESCRIPTION="Sphinx extension which outputs outputs serialized HTML files"
diff --git a/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild b/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild
index aeef9597e35a..7e3b2672033c 100644
--- a/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild
+++ b/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild
@@ -3,9 +3,7 @@
 
 EAPI=7
 
-DISTUTILS_USE_SETUPTOOLS=rdepend
 PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
-
 inherit distutils-r1
 
 DESCRIPTION="Sphinx websupport extension"
diff --git a/dev-python/tree-sitter/Manifest b/dev-python/tree-sitter/Manifest
index 6d7f8ad9d681..71065f45dee1 100644
--- a/dev-python/tree-sitter/Manifest
+++ b/dev-python/tree-sitter/Manifest
@@ -1,3 +1,7 @@
 DIST py-tree-sitter-0.19.0.tar.gz 112342 BLAKE2B f64db1bb078bd7b4a9b9e9c93c5eb449b9833870914ae5489dfc9d232c6f43d1779a5e9da47457f3152faae6997062c0a989893255bc66ec4747918342610bac SHA512 c06e921aa1a2fde97612fcbde61f0baa92730d927798076b3b6476bc26a84529d8a3299f4d4092ee85af84824c5d4444bf0800fe3cf1d15c66bcb2bf49a430e8
+DIST py-tree-sitter-b4db17e4d43f27a040b4bf087695cc200512e4ea.tar.gz 13411 BLAKE2B fa7e7f969a9136286ef18220f5776def84404121f9b7cce35422c925e194380d4a5a3fadc3da50d2d52d85f4100abeab1456e9749f93be20af9f3dd0854d5177 SHA512 4de7084928990ae61628599a8d6440606d70589b8becef6ee58ffdc1ac632660d050cab3947727dab6161dd74ccf6b9f74e83bfe4ff30c41d01caf25fbf6b8e5
+DIST tree-sitter-0.19.5.gh.tar.gz 2871077 BLAKE2B 487b846ac6ea4177d2b61721484cbde63636dde2dca0c15a35d4c4f0e18a9167aa11b750584d711632c2f42d67712b0818b57fb5815f62d95025022ecbc8cde9 SHA512 5d8669a2de6d261dfb083f0df07697156a703f56fea282babcaa7d391ef5538891b2c1103494a788bcb850cf494c184b05df5152f9276befab16f0fe6b23a9a9
+DIST tree-sitter-javascript-0.19.0.tar.gz 257637 BLAKE2B dc28bcbb003d623f5930dbf575f94f51c00eb008a77ba080f05e730fae63fb24d29c02ebb62d179a59d0f9cb8a02dbd3971440f299d952b1ec29b25bc6d21e34 SHA512 ef842787742e76d2534528ec710800df91958feaa4ba351558b5315f58a4bd85c729d088d139e15e0395726a690a97c05e03846c9176af0fd482777ae57087ed
+DIST tree-sitter-python-0.19.0.tar.gz 129336 BLAKE2B 8a37b0d74ab89aa56d7164bd38ac527b7b9676cafd8f53faaee3d10316f91decd30c02078b1bb785a474615ae58e6edba1b28bc3311e6ff094435e5f53d64cd6 SHA512 df7c72f988a62af0774df1b3a60c86397725aaeb1e2ffaa9b1295ab22eec09bffaf391cad20fb0d08a20914b22af430c2248c26cad179fd68c9f2b32419c0b60
 DIST tree_sitter-0.2.1.tar.gz 110417 BLAKE2B 263f47b9c8beab4b99fbfeb40521467f7f507ead77b20eb1bea7d6f076398d4f0db02299290a552aaa35959dff4a87866d010d628269e64cebeb06d86856fdc6 SHA512 72fd602689a78f51184820fb15891863873f8b290811152ea568cfa6fbd2d3f182ae8627f028c8d485d0e9bbe7b81a9d6ed57e7a8b551ba38f8dd738fb7c858a
 DIST tree_sitter-0.2.2.tar.gz 110585 BLAKE2B 2798469b65bdc2447697797f937242dcfd2fe0dbb0afa7a41fe05463ec6c93afa63b26ee4e3e65585b57a2592ac444c2522469472cb0562f313f1261c358e5b3 SHA512 b32d7e3be408eedf52b53a5ae7613b3c423eb84d175d0fb31d63c052c2c4d3a7539b53d45276629a2a02c460289e877efa519c2055cdee477e23fe50cc452892
diff --git a/dev-python/tree-sitter/tree-sitter-0.19.0_p20210506.ebuild b/dev-python/tree-sitter/tree-sitter-0.19.0_p20210506.ebuild
new file mode 100644
index 000000000000..766cea5573a7
--- /dev/null
+++ b/dev-python/tree-sitter/tree-sitter-0.19.0_p20210506.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+EGIT_COMMIT="b4db17e4d43f27a040b4bf087695cc200512e4ea"
+MY_P=py-tree-sitter-${EGIT_COMMIT}
+
+# TODO: unbundle
+TS_PV=0.19.5
+FIXTURE_PV=0.19.0
+
+DESCRIPTION="Python bindings to the Tree-sitter parsing library"
+HOMEPAGE="https://github.com/tree-sitter/py-tree-sitter/"
+SRC_URI="
+	https://github.com/tree-sitter/py-tree-sitter/archive/${EGIT_COMMIT}.tar.gz
+		-> ${MY_P}.tar.gz
+	https://github.com/tree-sitter/tree-sitter/archive/v${TS_PV}.tar.gz
+		-> tree-sitter-${TS_PV}.gh.tar.gz
+	test? (
+		https://github.com/tree-sitter/tree-sitter-javascript/archive/v${FIXTURE_PV}.tar.gz
+			-> tree-sitter-javascript-${FIXTURE_PV}.tar.gz
+		https://github.com/tree-sitter/tree-sitter-python/archive/v${FIXTURE_PV}.tar.gz
+			-> tree-sitter-python-${FIXTURE_PV}.tar.gz
+	)"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+distutils_enable_tests setup.py
+
+src_unpack() {
+	default
+	rmdir "${S}/tree_sitter/core" || die
+	mv "tree-sitter-${TS_PV}" "${S}/tree_sitter/core" || die
+
+	if use test; then
+		mkdir "${S}/tests/fixtures" || die
+		local f
+		for f in tree-sitter-{javascript,python}; do
+			mv "${f}-${FIXTURE_PV}" "${S}/tests/fixtures/${f}" || die
+		done
+	fi
+}