Adding metadata

35 files changed, 525 insertions, 15 deletions

diff --git a/dev-python/Faker/Faker-8.10.3.ebuild b/dev-python/Faker/Faker-8.10.3.ebuild
new file mode 100644
index 000000000000..b9fd92931d21
--- /dev/null
+++ b/dev-python/Faker/Faker-8.10.3.ebuild
@@ -0,0 +1,28 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="https://github.com/joke2k/faker"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	>=dev-python/text-unidecode-1.3[${PYTHON_USEDEP}]
+	!dev-ruby/faker"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/random2[${PYTHON_USEDEP}]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index 768b6de0251c..bd730957d801 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -1,6 +1,7 @@
 DIST Faker-8.10.0.tar.gz 1149474 BLAKE2B 2a5304acb1ce88230660a468756ee79abc7ae0b6aeb850e3d05bb694cb9e5b596b1d9de4c8f1e82c208a3281efc026a290b6d96cd17bc6c523d22fcd61eaf756 SHA512 0d035663677bea9ef4a66c6f0cf5fb1e648e948deb4db07b352a8b8881f5774a9432524bef10e60f28d5d586ac66f0e207c3ad218edffd6071fa6ac614ac950b
 DIST Faker-8.10.1.tar.gz 1144158 BLAKE2B 7463566a8bf2f510ab89b7fd67ee3aea80ce65725063f83798a6f7ce959a1e5c4eef82504adc124add6ff028d6e248871123d0992f715d46485daa6d64d4179b SHA512 c5bb3b376757fe025255de67a184dfae959c834e937825515eaae083a2ce931f2c00ed1ade7ccba49adf182570cf533526e583e6a45c4fa08b41e22544139227
 DIST Faker-8.10.2.tar.gz 1150102 BLAKE2B 5ca744d201a7822cbe35791757a73628d3c12f6521ca55bc2d340c974cb6e76362f87395cbc858e4681738440cf676e9f9bf7a8002b908ff564dc6703ef794e0 SHA512 5a148327df7c34623c0d8c154e6181a183a0aa484659e5872013f0b9c510418690278550ebbed6eb984c87cef588fd862b213295a379b5be3433afe312181103
+DIST Faker-8.10.3.tar.gz 1149954 BLAKE2B 665ed95be11f734ed2ae9b593a4e287cc53b041521ab223efc045f061133e983de500ef12a858d7420342a500926297565b7c50674fe5533b985a00816251031 SHA512 a5969f04dd96660b3e62ece20ce4d92de9c781faa1742e45404b0a6f04dc7521c9532c519df06c4b3e9a815dde43837b7ab7628ef25ed3b60bda49c927b8ace7
 DIST Faker-8.8.2.tar.gz 1148529 BLAKE2B 279984479ad4f790dc7acd74b5ccd1cf5f32689b8b1ccf2152d7dfaa6fc7b4699d9827c16f83bb86e298723b6906a5cc40c2fa7f75439b5af5fc78c1af99a3f6 SHA512 4273008bf9ab693a40da2f93ff1fe40e9e7b102a2d5439f09096b6754b82dc26310666da65723b363f628365c97d44dd290e1e7065b7a9d862130baa292325b7
 DIST Faker-8.9.0.tar.gz 1148829 BLAKE2B b24a7fa87886cb38850808de2ffe1ceafab3c548c694af30d53b1f415d329264fe7e53f33f46b913d16310dd83d95fe591689a308bb7d4c653254e39defaa24b SHA512 d2e26ae140c30ae8069f8e0fd75bb9bf54aa00a7271b327e37dd248520256e137d192082071bc36a584fc864c54c050107ddecb40624288636c6b41caf1ea574
 DIST Faker-8.9.1.tar.gz 1148890 BLAKE2B 2cab6461bf6067d9dfd8872c19c8c11fa25ffef82b61b7e7676ffc187346d228703424a73278678f19263423716c74ecd47cfc1c17bf54d38bba712e456650b8 SHA512 f7016b320c7394b0eccc06e833a80e227cdbad9c0f34eb9f8f4413f56a4743f58bbd7ec5eac3b8c0642e7764c6c5986707d493f0c84daa75575a12061631c9c5
diff --git a/dev-python/backports-entry_points_selectable/backports-entry_points_selectable-1.1.0.ebuild b/dev-python/backports-entry_points_selectable/backports-entry_points_selectable-1.1.0.ebuild
index 2f8c9719ab92..d38705efaabc 100644
--- a/dev-python/backports-entry_points_selectable/backports-entry_points_selectable-1.1.0.ebuild
+++ b/dev-python/backports-entry_points_selectable/backports-entry_points_selectable-1.1.0.ebuild
@@ -18,7 +18,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~hppa ~x86"
 
 RDEPEND="
 	$(python_gen_cond_dep '
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 03f1f160a326..9a42e0724ae8 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -7,3 +7,4 @@ DIST boto3-1.18.3.tar.gz 393645 BLAKE2B 4967ac751e9ff5a86f6f571961df31d82f6012ad
 DIST boto3-1.18.4.tar.gz 394442 BLAKE2B e82726143b353b843e915ea78ea2e033077ee495b1d416866f5c231f8bd864372496736d266b2b848ed8afd3134bd865c507291fd2fbdd5cae00a92ce3c5e76d SHA512 b3ba1328476a1c642c6b813afc3879e904bc14da69e062156df0405b3da6d2a15a4a40602f24d0a067a83cc441ce5a5e353dacb84869b0fe24e9984c0dec719f
 DIST boto3-1.18.5.tar.gz 394930 BLAKE2B a7f58699a4a27c85f00f47eb34d861509446d159434db8d492edb8d93f3d872757dde5adb358b89af80d9fb3f489fb424a4de6f8c62ac14220b22588bfb1ff0e SHA512 9292241055684dfdda22ec2243b0d64b00b3fa3ec73b3209db8eb8d90c14aa5aa2d7a77cdd0670350227ed6b923b9142842ed5bc8a4fecbaa4705a90af546022
 DIST boto3-1.18.6.tar.gz 394941 BLAKE2B c7ef6f85fea5a12c248afd03cbe5cca2475c32de0d5b90e8390837e4e1980390e07bc99b6dd1e1831c34135503fe5859e0a837e0aff88f7af2bd8ddcad804a1d SHA512 01cdc6e71b8cd04da7e6f2bf9268625824c12b53fc7322343ae635d5fdd6ed30170fb698d7c4a788b4095fbfc186ef72a11fb6f785a1006fe7861d2db6108da9
+DIST boto3-1.18.7.tar.gz 395640 BLAKE2B 6a9fa1dd55644806fe93271805f35fbe0c4cb65d1de08dded2d2f57fcefa96e32c4ebe7b60743c52c0898222bc06d33dbd03d304bbef327b88022450a7943e2c SHA512 20e7fedab7d061ab02f391e9baf36cb554e7f194f38d24d5a75f76715b2acf1b51b6adce5d8cf5a2a0d29df73566db00b8813a219d45a194d9a8eb93d0dab570
diff --git a/dev-python/boto3/boto3-1.18.7.ebuild b/dev-python/boto3/boto3-1.18.7.ebuild
new file mode 100644
index 000000000000..bee358e1c595
--- /dev/null
+++ b/dev-python/boto3/boto3-1.18.7.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ ||
+		die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 671598615578..1c8400d35b61 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -7,3 +7,4 @@ DIST botocore-1.21.3.tar.gz 7959023 BLAKE2B aab15319b9f36c25ee88f2bf0b2efcb6bbff
 DIST botocore-1.21.4.tar.gz 7964960 BLAKE2B 71d55b47633aa658a9dc921375c77230a6ebb89460d9de5a9982d730e03247972476400dbcf292da0a885789860117c1abc9bf803c79547049b242feb8755d15 SHA512 4a36e5870d9996973e2258f2e6afeb7381ac94d14075eaa9885f6f89afb87fa5b4461b02ab234b4ecc8e24630434dbb839e8ad30f622de6ffa5402f872f84a97
 DIST botocore-1.21.5.tar.gz 7968981 BLAKE2B cea2c648e5f8d6f99bd1f11f430511abdc413bb3a2e36b2ca149f4edb0b8b750cba1149474351ab52a04e08018de81fab93607eb65e19b452a80a249cefb5871 SHA512 ad84b3f75883279452ba9922492e1a63b9f951ed54767feb573000d077335eb50685727ae1924d02f23d5342bcd8f96d2a56b06efedcded4b718e8ec68f6d636
 DIST botocore-1.21.6.tar.gz 7974218 BLAKE2B f3391b620a21d04712e1254c4e8ffc090956bc1e0a41278be2c0e02a659ada639af2cc4e94bf607492164a8425988c16e8b899726fe645871b1cf6d1f98ef04d SHA512 1a74f2450a1c57a61c704550c0f08fd518b8d4fc463acdd8622ca8bf7fa51293c52c54999e1a1d563815cb0fd35585072753d623739a6738367b0bae94f655b7
+DIST botocore-1.21.7.tar.gz 7977343 BLAKE2B 19c5bf5de40ab131585e30bb85486fcffc3428808811b312b33578174ce31a691f4f4d955462120f05d2aad2cd5e5772789704eee641760fb67099aa3cddc9b5 SHA512 db1bb36faa6857a1cc717e5d591954415bb948178ee2be90ab9c32c11b1fb45c5b5aff87dfacd907c2f11bc7cdd2cd4de2ee9c847fa8cda4e5f0814a828b1019
diff --git a/dev-python/botocore/botocore-1.21.7.ebuild b/dev-python/botocore/botocore-1.21.7.ebuild
new file mode 100644
index 000000000000..5684261bd4b3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.21.7.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/cheetah3/cheetah3-3.2.6.ebuild b/dev-python/cheetah3/cheetah3-3.2.6.ebuild
index fbd759eccb93..0153b3cc350a 100644
--- a/dev-python/cheetah3/cheetah3-3.2.6.ebuild
+++ b/dev-python/cheetah3/cheetah3-3.2.6.ebuild
@@ -11,7 +11,7 @@ HOMEPAGE="https://cheetahtemplate.org/ https://pypi.org/project/Cheetah3/"
 SRC_URI="https://github.com/CheetahTemplate3/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
-KEYWORDS="amd64 ~arm ~arm64 x86"
+KEYWORDS="amd64 ~arm ~arm64 ~riscv x86"
 SLOT="0"
 
 RDEPEND="
diff --git a/dev-python/cssselect/cssselect-1.1.0-r1.ebuild b/dev-python/cssselect/cssselect-1.1.0-r1.ebuild
index c469b4d52c90..35c82e7f2b7a 100644
--- a/dev-python/cssselect/cssselect-1.1.0-r1.ebuild
+++ b/dev-python/cssselect/cssselect-1.1.0-r1.ebuild
@@ -15,7 +15,7 @@ SRC_URI="https://github.com/scrapy/cssselect/archive/v${PV}.tar.gz -> ${P}.tar.g
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
 
 BDEPEND="
 	test? ( dev-python/lxml[${PYTHON_USEDEP}] )"
diff --git a/dev-python/flexmock/flexmock-0.10.4.ebuild b/dev-python/flexmock/flexmock-0.10.4.ebuild
index 275b6d140f8e..d9d0f4ea3483 100644
--- a/dev-python/flexmock/flexmock-0.10.4.ebuild
+++ b/dev-python/flexmock/flexmock-0.10.4.ebuild
@@ -13,7 +13,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64"
+KEYWORDS="amd64 ~riscv"
 
 distutils_enable_tests pytest
 
diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index 0c4f5f52e2b1..9d09f7346da7 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1,3 +1,4 @@
 DIST fonttools-4.24.4.tar.gz 2556059 BLAKE2B c415ae5214b6df7171a5f8a7ea179b1a4adbc6646598d773f0d3d6a8cd777e8fd3c74c14f00e6c4735a73e712e3fd42ddfc96f3f101d34b122fb9c471d4d94a3 SHA512 aa4ee8f0a7f9cb6d8a84497e6f33f891491cd06cc477a785715f8fde8e5b33cf781ef8b848bfab8cf9a97fc15c018d493c6baf0fb8fd314b8a348c36ff627f41
 DIST fonttools-4.25.0.tar.gz 2576777 BLAKE2B 802236b120ae78e2721d734875fba794fb9eafc125fbfea6b70c68d6a18a8b3c1ce685da18c83ee3364ff38f72707e42ed0ae25bc62d362c6271fff90da56d0c SHA512 c8f7512053ce611fa07bbc1fe844ee9d50cf09e19a2a27bed7df9d37d362b7daa910fbb651147f3690a03ec4d8adc8d96e8f0310eda24bb40208240182dc9b54
 DIST fonttools-4.25.1.tar.gz 2577170 BLAKE2B 8cb03ef1f9cf4e61d5e6d4963bb5c43ec48838e0453cc293de1c763a29b34d69701b87430d8a85085f06c26671e00a91c89e4c50ba8d2fad4a9cc72b1f17d0e9 SHA512 ca3732bcc5e2b373983d34bd72e0ea36488f24aa442d25d0d16f6a473ef35323547f900b1ae87c42e64c451afe4f760291095738a4442c11c5566c9efd0aa944
+DIST fonttools-4.25.2.tar.gz 2577630 BLAKE2B ba03dcc25672008722bb7f5ad4238e9216988f5ed1d545297937e771bf076ae516172cd90bd450ded04ca28fe158c83247bd6b6aaaf4687a5893c0980630210b SHA512 b5c94e76a09aeb92061cf792f53eccc0ab369c5458aeac103f865f6110b2764677ad7c63d1367fb027c891a11d7eb158469748ec495c3a7aa6b86029e7c95223
diff --git a/dev-python/fonttools/fonttools-4.25.2.ebuild b/dev-python/fonttools/fonttools-4.25.2.ebuild
new file mode 100644
index 000000000000..c079f50b216a
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.25.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="https://github.com/fonttools/fonttools/"
+SRC_URI="https://github.com/fonttools/fonttools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+RDEPEND=">=dev-python/fs-2.4.9[${PYTHON_USEDEP}]"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx epytest Tests fontTools
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index c1c3fcd164c4..8580a2911891 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -2,4 +2,5 @@ DIST google-api-python-client-2.11.0.tar.gz 25408815 BLAKE2B 9bc7d0163961f5b6341
 DIST google-api-python-client-2.12.0.tar.gz 25476570 BLAKE2B 7d5f53c19f00878ef717515f406a56d22ce520a0de4f8c5b4142de56263a5bdef76aaa64b3b87301f8c704ad279554f66425c746c8bb869ef735c061fc5d1b6a SHA512 47bfebe8649a4dbf2f8570f71ec4a0c4ececccf6734138e3c84e0501328f949485b5476227c123493b5874e43cc0ab72622ce9fb44484502e21e364f6c8cea54
 DIST google-api-python-client-2.13.0.tar.gz 25562934 BLAKE2B 6ce955995c0f2fa5d09e1c90e65d38a7f321421199f53957fb58934c1f067de03a48f47f1d161c9ad2cb852663316c5d0f873a32b9eedd7fffaa2b067d84ae05 SHA512 d2b0cf3c250a500e774970790390025119102e24eaf8c7a0c170139cf322c37f4c8cd3f406a41d18deb2597dfeb21e6304e173cfaafb4d6faeff23b2215d4072
 DIST google-api-python-client-2.14.0.tar.gz 25412673 BLAKE2B e8c14c069f2900d560ab2ed70855cd0ebcf1191f0932cefa385858466a482f92934df97cb994801a0d85514bcc33d918ce50ee2e980f1957f11c1cb8cfbb34dd SHA512 4c644d7acb5eb9853672a17fb3cb08796c3afa172b3b1c56027b8ef20734cdc2995d972006a6803ed806171f88a0652910a0fd1682f3427c546312cf1a719e42
+DIST google-api-python-client-2.14.1.tar.gz 25415625 BLAKE2B 2b843a6ec6345e51c5a92c0285c2b8ae195928bec61b73033fbc64d8e55c34ae39d8d542534d89edac36d6ddc6c12b6acf11a25dbcbc06f72776799a70606659 SHA512 e22600b9b87d646775780d0f45043753e4dea24e898faf16ae49f2c91677282700b45de993d085923c006f2948747a6afa2e58b38f42f934f1602401faa30d22
 DIST google-api-python-client-2.8.0.tar.gz 25286774 BLAKE2B b21aebda062984b9eb8f2f5c563016f0f8f663883dc8ddb913053ff3df32c652c6a83f924f3e19136e5edec085e12c43cc584bc9898630122c77a219810033bc SHA512 cc3c55438b2f5835b52d17d04a749919c4865991ff78cf95920d0941a55e1493eae502a13f6565cfe1db799ce9950659e8baaa690bada058d711309861c8d07e
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.14.1.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.14.1.ebuild
new file mode 100644
index 000000000000..af887d1703c7
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.14.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.16.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-4[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests --install pytest
+
+src_prepare() {
+	find tests -name '*.py' -exec \
+		sed -i -e 's:unittest2 as ::' {} + || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local deselect=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	distutils_install_for_testing
+	epytest tests ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index ba80c2258be7..66063e034445 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,3 +1,4 @@
 DIST hypothesis-python-6.14.0.tar.gz 9135056 BLAKE2B 47d1efcee5e1c4037f1a20f08e3bc873fc143a2182bbde07e897812622c4d68923f78ac356bd97ef541566a27a874705eb2438747daaebe84f95fc2a2262bac1 SHA512 f7821449d3bf7f3656b52dad09027e40ea4af1779fcc7c0b995dac55843953fdab3f2ba69eb1b8de8258616f49cf8e5098c6a222d01071916c6f0c9fe184c80b
 DIST hypothesis-python-6.14.2.tar.gz 9135496 BLAKE2B f77f0668c4d0c2f5a952e06a40ae7898631804d3406c9711eb30a4e5a11e73ba2772be3cb437aacea2a75cd65f688a2485b98885c19cf743020900b0cf70f08c SHA512 e495e1c471fd4b185e23326700e85bf90635fcc8bf316c758c3285803ff0f7ad0269351b3a7631033495bb6498a8f19cb8661c55248ec5e14ff2a09e0c3af3c1
 DIST hypothesis-python-6.14.3.tar.gz 9135537 BLAKE2B 2effb0c68cf3a7a2f7d56c0c46c2ba36cbed4fed35b8a617ec68a721990247370772b986f0492aab112f7420c07409f8d738485ca28f42e7aea919af52611b10 SHA512 1722c5dcf1eb7375fd09d4208851826582808449fcaaa0345f1461d9a531961500a9c888bec5a457efbbb34f8178464b3358a3187b94bb5c783af42b4e7287ce
+DIST hypothesis-python-6.14.5.tar.gz 9135819 BLAKE2B 2e42949f81024038b901231a8446203388c8052ebaacf4a87d21356265fd1c09c9aa8b191dcd65780d45cc52ed9d48bb16440fc553addb4671e0ad901213ef64 SHA512 d047eea19129d5855bee5f012f5c91fe1f0de40228600fadad9c76709f951c003450f613f59848064b58f9d0e559b54b44744ae0aae689687488b6506cc8fe1a
diff --git a/dev-python/hypothesis/hypothesis-6.14.5.ebuild b/dev-python/hypothesis/hypothesis-6.14.5.ebuild
new file mode 100644
index 000000000000..01270134d6dc
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.14.5.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' python3_{7..9})
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!dev-python/pytest-describe
+		!!<dev-python/typing-3.7.4.1
+	)
+"
+
+distutils_enable_tests --install pytest
+
+python_prepare() {
+	if ! use cli || ! has "${EPYTHON}" python3.{7..9}; then
+		sed -i -e '/console_scripts/d' setup.py || die
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	epytest tests/cover tests/pytest tests/quality \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 0b33f6869237..075dc8a2d92a 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -10,3 +10,4 @@ DIST moto-2.0.7.tar.gz 1565849 BLAKE2B 1c6491828a43156fd347bcce80f3440cd8d4964e2
 DIST moto-2.0.8.tar.gz 1569426 BLAKE2B 746313241d49558ab49d7e2116406f128a315a9fca40956808e7f901e91518551a1f75c95c9ce5c92534221d1db3e01a3baa2cef6cadab9a9d024cc30d8ce0e2 SHA512 5cf1a47c97100b76ad9b69787ce4df00f24f93ba1a36a242cea535ede649af457ff043b44f1cce4a4e44b6735844652f69271f18edac0748b636f4e519545018
 DIST moto-2.0.9.tar.gz 1614328 BLAKE2B 0bb9e3dcc0c25476b7fdabeecc31be6904a21d6a77f6ce3d9c9c176625873d30c55321c8939ecb8bbc91ee64faab9cd7231150dfdcbd4d5d7d3dc8eae614d9f2 SHA512 41b32aa192dd5c5052a90f345f29e696f9cc6abb3698ea0b738f8805fc920f4abf7d418a64aecf6efd66162aad631c88754d5e4e349ca2ba5b393771038219cb
 DIST moto-2.1.0.tar.gz 1638267 BLAKE2B ee778cab1a9a448408bbc495a148201bb016c2ba29076062360db23d86d725758303c32e1fb1a3f9e11112deb1cbca686fc956ddafd259fd942654510ba12147 SHA512 cae18324200d827a1750c5dbe2df2ea68dc66a5b8ff40b4c873f7511d576417c1a2b20203cc126d84b99b1aec5ef8700825271893933e6cc4bd61c0082b9e9be
+DIST moto-2.2.0.tar.gz 1650655 BLAKE2B 9969de2fb323b2deb272eb47727884054a35827a5db382f83a4177cf6cac5339f89164d05c288a977bc1895a204d13d02069e8b37880ea3d04374f6ed4d6be47 SHA512 7eabb515f94920af9b8f028afaaa51e27983f7bfd73f66c29fc191e2f3dd3e8939ddac67de0127c67c35cbc17c3500a7390103b26c85056780c865aadeb5e1d9
diff --git a/dev-python/moto/moto-2.2.0.ebuild b/dev-python/moto/moto-2.2.0.ebuild
new file mode 100644
index 000000000000..923cec7e26d2
--- /dev/null
+++ b/dev-python/moto/moto-2.2.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/boto[${PYTHON_USEDEP}]
+	dev-python/cfn-python-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	dev-python/dicttoxml[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.9.201[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.12.201[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# unpin indirect dep on ecdsa that's supposed to workaround pip bugs
+	sed -i -e '/ecdsa/s:<0.15::' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local ignore=(
+		# incompatible versions?
+		tests/test_core/test_decorator_calls.py
+		tests/test_s3/test_s3_classdecorator.py
+	)
+
+	# pytest-django causes freezegun try to mangle stuff inside django
+	# which fails when django is not really used
+	epytest -p no:django -m 'not network' ${ignore[@]/#/--ignore }
+}
diff --git a/dev-python/networkx/Manifest b/dev-python/networkx/Manifest
index 6be01154f151..9dca0f11ce21 100644
--- a/dev-python/networkx/Manifest
+++ b/dev-python/networkx/Manifest
@@ -1,2 +1,3 @@
 DIST networkx-2.5.tar.gz 1542085 BLAKE2B a4d1d1f65a09f8e7cd830a9e670cf540c19b800dffb90aa1cc6ebda8b6116b6181969382f90339254746a3f277d786020506a3c8f10c90ff48999d3b2c3c433e SHA512 ab51198072d20bdba7c9ceb6856631a20a7e9527a7cadb41271a999f57bf60da5488269c6e4e1f3f4f33420ec6493af665386842c216ea1cfadd1792ccb6444e
 DIST networkx-2.6.1.tar.gz 1842369 BLAKE2B bac0106758fa7d33000d970873ee221ee9b367ad895f2f8fbfdfb29908851c69f632214dac06c48ab433e3b6251a439199fe3675517252c959ba2a29076cc866 SHA512 132f34eb8790fb366263cfbb501ec5ca0f9c9082562215a06a114b2ec80baf72f5489f27e7fe1cbea49749eab48116e8772ff953339de0caabf37096ce097500
+DIST networkx-2.6.2.tar.gz 1842077 BLAKE2B 8493e2d6a64d140b012ea443e9b1dc2409f8208dc1678c1d21cfd19bbdc07df6e9051aefe994d5fa6460db48320d563bb3051150782545ab5f671b7aafda4d0a SHA512 7006dcd209cce79f0f6cac4884797775422bd90fd3e8abb2eee70e6e00c9a25a785dd5856fc1657019a2b5c13a6fa5f705ea2e650c15a1f9d7d93580bc299219
diff --git a/dev-python/networkx/networkx-2.6.2.ebuild b/dev-python/networkx/networkx-2.6.2.ebuild
new file mode 100644
index 000000000000..fa496dd79558
--- /dev/null
+++ b/dev-python/networkx/networkx-2.6.2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Python tools to manipulate graphs and complex networks"
+HOMEPAGE="https://networkx.org/ https://github.com/networkx/networkx"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="examples extras xml yaml"
+
+RDEPEND="
+	>=dev-python/matplotlib-3.3[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.19[${PYTHON_USEDEP}]
+	>=dev-python/pandas-1.1[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.6.2[${PYTHON_USEDEP}]
+	extras? (
+		>=dev-python/pydot-1.4.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/pygraphviz-1.7[${PYTHON_USEDEP}]
+			>=sci-libs/gdal-1.10.0[python,${PYTHON_USEDEP}]
+		' python3_{8..9})
+	)
+	xml? ( >=dev-python/lxml-4.5[${PYTHON_USEDEP}] )
+	yaml? ( >=dev-python/pyyaml-3.13[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=()
+	virtx epytest -p no:django ${deselect[@]/#/--deselect }
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/path-py/Manifest b/dev-python/path-py/Manifest
index 6d9cfca27f91..a500521b455a 100644
--- a/dev-python/path-py/Manifest
+++ b/dev-python/path-py/Manifest
@@ -1,2 +1,3 @@
 DIST path-16.0.0.tar.gz 44187 BLAKE2B 839c8a9d10cf4ac3f738a9e661fbfb1059554f965fc8224457c05c249578a18118129b69b46276fe569fc8bc33b398be1462d660bb20b905ecc6ab2b4db3f8fc SHA512 3874321d488543219a081adcb692739fcc4935cddaf563b58fe5a97c2cee4b5b683b2be52d220854b2f2224d15ec2bde054a53862352c249f14f1460a72d5e72
 DIST path-16.1.0.tar.gz 45551 BLAKE2B bb22684f9b8d1996d8dec5bfc3d6b116595338a6d9f55f3c6084e0c6a41d6a708174ddd6fbcfa29e37f042f65e85465f4155f71569a1851994f03ddd4e4eaad7 SHA512 85d2d0415e28eb737f9fb6eaf669b687af768c5a1c4cf20a3c36706209fe6a97b44c34ff07468d8fefae372049e18d277e245f080dc6001adb14f794654ebfaf
+DIST path-16.2.0.tar.gz 45276 BLAKE2B 40b8eacc7e28398324f24b955adef11e5fc0bd512cd711cd3117f35a322ce0c3959b55255d4c96bbae64f914b5f3768088eb73fb45511c09f2e21bf99b3e9911 SHA512 f893d9fe3539eff0b43e4945076f770ffa7c3125151774d6accaa3a609fce351bc121562deb7ef695c0b1fc7aba12ce7487ae09a0b5daba2d5340586fc41ec79
diff --git a/dev-python/path-py/path-py-16.2.0.ebuild b/dev-python/path-py/path-py-16.2.0.ebuild
new file mode 100644
index 000000000000..c3e086ac7d1d
--- /dev/null
+++ b/dev-python/path-py/path-py-16.2.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+MY_P="path-${PV}"
+DESCRIPTION="A module wrapper for os.path"
+HOMEPAGE="https://pypi.org/project/path/ https://github.com/jaraco/path"
+SRC_URI="mirror://pypi/p/path/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+RDEPEND="
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	!<dev-python/pytest-shutil-1.7.0-r1
+	!<dev-python/pytest-virtualenv-1.7.0-r1"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# unreliable, not really meaningful for end users
+		test_path.py::TestPerformance
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/platformdirs/platformdirs-2.0.2.ebuild b/dev-python/platformdirs/platformdirs-2.0.2.ebuild
index 0ad7751a2922..70f79d4a9130 100644
--- a/dev-python/platformdirs/platformdirs-2.0.2.ebuild
+++ b/dev-python/platformdirs/platformdirs-2.0.2.ebuild
@@ -16,7 +16,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~hppa ~x86"
 
 BDEPEND="
 	test? ( dev-python/appdirs[${PYTHON_USEDEP}] )"
diff --git a/dev-python/pyamg/Manifest b/dev-python/pyamg/Manifest
index a1a195d67593..8c133042a3f8 100644
--- a/dev-python/pyamg/Manifest
+++ b/dev-python/pyamg/Manifest
@@ -1 +1,2 @@
 DIST pyamg-4.0.0.tar.gz 717171 BLAKE2B 16483d829e8a938359827ca8ebe3093c890685244125576e05220910b66e9aeec278472134d10c589e58dfbd363930cdd7ae13d16c9b9d54c1bd5250e66f4677 SHA512 cdd27834c12ef18f023e78b5b946c06bc2c35f73cf65fc4c76da2fab75f23466e6c1a4b3dccb8506be3ada7e0bafda38122d3d7315deebc7959d2e5300d9add1
+DIST pyamg-4.1.0.tar.gz 749906 BLAKE2B 31c05d64317b32cbdbd616e982557f0a94bc17b2fce3d982fe93e629d56ad526516603032b3cba9785bf5ebed038481ae641f55a5a1ad621442dde08791981cb SHA512 311642cbbe8dca621cb58bebb1bb05b7dc7b2364713886df96937ba56575137bcb4fb7006a232d2c14380cd41f4337f6f09a8a9794e279a155f27287497d2b08
diff --git a/dev-python/pyamg/pyamg-4.1.0.ebuild b/dev-python/pyamg/pyamg-4.1.0.ebuild
new file mode 100644
index 000000000000..19863be6819a
--- /dev/null
+++ b/dev-python/pyamg/pyamg-4.1.0.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=bdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Algebraic multigrid solvers in Python"
+HOMEPAGE="https://pyamg.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]"
+# cannot be enabled by "distutils_enable_tests pytest"
+BDEPEND="
+	dev-python/pybind11[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests setup.py
+
+PATCHES=( "${FILESDIR}"/${PN}-4.0.0-test.patch )
diff --git a/dev-python/pymongo/pymongo-3.11.4.ebuild b/dev-python/pymongo/pymongo-3.11.4.ebuild
index 8cef1348f1db..69a52cf961c4 100644
--- a/dev-python/pymongo/pymongo-3.11.4.ebuild
+++ b/dev-python/pymongo/pymongo-3.11.4.ebuild
@@ -16,7 +16,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="amd64 ~arm64 ~hppa x86"
+KEYWORDS="amd64 ~arm64 ~hppa ~riscv x86"
 IUSE="doc kerberos"
 
 RDEPEND="
diff --git a/dev-python/python-docs/python-docs-3.6.14.ebuild b/dev-python/python-docs/python-docs-3.6.14.ebuild
index bfc00bc95def..207c5a70de08 100644
--- a/dev-python/python-docs/python-docs-3.6.14.ebuild
+++ b/dev-python/python-docs/python-docs-3.6.14.ebuild
@@ -10,7 +10,7 @@ S="${WORKDIR}/python-${PV}-docs-html"
 
 LICENSE="PSF-2"
 SLOT="$(ver_cut 1-2)"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 sparc ~x86"
 
 src_install() {
 	rm -r _sources || die
diff --git a/dev-python/python-docs/python-docs-3.7.11.ebuild b/dev-python/python-docs/python-docs-3.7.11.ebuild
index bfc00bc95def..2bdebf85b6b0 100644
--- a/dev-python/python-docs/python-docs-3.7.11.ebuild
+++ b/dev-python/python-docs/python-docs-3.7.11.ebuild
@@ -10,7 +10,7 @@ S="${WORKDIR}/python-${PV}-docs-html"
 
 LICENSE="PSF-2"
 SLOT="$(ver_cut 1-2)"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
 
 src_install() {
 	rm -r _sources || die
diff --git a/dev-python/python-docs/python-docs-3.9.6.ebuild b/dev-python/python-docs/python-docs-3.9.6.ebuild
index 207c5a70de08..e68a93923813 100644
--- a/dev-python/python-docs/python-docs-3.9.6.ebuild
+++ b/dev-python/python-docs/python-docs-3.9.6.ebuild
@@ -10,7 +10,7 @@ S="${WORKDIR}/python-${PV}-docs-html"
 
 LICENSE="PSF-2"
 SLOT="$(ver_cut 1-2)"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ~ia64 ~m68k ~mips ppc ~ppc64 ~s390 sparc ~x86"
 
 src_install() {
 	rm -r _sources || die
diff --git a/dev-python/sphinx-issues/sphinx-issues-1.2.0.ebuild b/dev-python/sphinx-issues/sphinx-issues-1.2.0.ebuild
index 253888e2982e..36db0ddbb34e 100644
--- a/dev-python/sphinx-issues/sphinx-issues-1.2.0.ebuild
+++ b/dev-python/sphinx-issues/sphinx-issues-1.2.0.ebuild
@@ -12,7 +12,7 @@ SRC_URI="https://github.com/sloria/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
 
 RDEPEND="dev-python/sphinx[${PYTHON_USEDEP}]"
 
diff --git a/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild b/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild
index 7e3b2672033c..478c73dfda01 100644
--- a/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild
+++ b/dev-python/sphinxcontrib-websupport/sphinxcontrib-websupport-1.2.4.ebuild
@@ -14,7 +14,7 @@ SRC_URI="https://github.com/sphinx-doc/sphinxcontrib-websupport/archive/${PV}.ta
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-solaris"
 
 RDEPEND="
 	>=dev-python/six-1.5[${PYTHON_USEDEP}]
diff --git a/dev-python/testresources/testresources-2.0.1.ebuild b/dev-python/testresources/testresources-2.0.1.ebuild
index 7265a524b260..441407852145 100644
--- a/dev-python/testresources/testresources-2.0.1.ebuild
+++ b/dev-python/testresources/testresources-2.0.1.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
 
 BDEPEND="
 	dev-python/pbr[${PYTHON_USEDEP}]
diff --git a/dev-python/virtualenv/virtualenv-20.6.0.ebuild b/dev-python/virtualenv/virtualenv-20.6.0.ebuild
index 739be165cbe5..b57a3bff6713 100644
--- a/dev-python/virtualenv/virtualenv-20.6.0.ebuild
+++ b/dev-python/virtualenv/virtualenv-20.6.0.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~hppa ~x86"
 SLOT="0"
 
 RDEPEND="
diff --git a/dev-python/websockets/websockets-9.1.ebuild b/dev-python/websockets/websockets-9.1.ebuild
index f901d3cbac5f..0ce165c2bab6 100644
--- a/dev-python/websockets/websockets-9.1.ebuild
+++ b/dev-python/websockets/websockets-9.1.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 
@@ -16,3 +16,12 @@ SLOT="0"
 KEYWORDS="amd64 arm arm64 ppc ppc64 sparc x86"
 
 distutils_enable_tests unittest
+
+src_prepare() {
+	# these fail due to timeouts on slower hardware
+	sed -e 's:test_keepalive_ping_with_no_ping_timeout:_&:' \
+		-e 's:test_keepalive_ping(:_&:' \
+		-i tests/legacy/test_protocol.py || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/whoosh/whoosh-2.7.4-r1.ebuild b/dev-python/whoosh/whoosh-2.7.4-r1.ebuild
index b703f9f63b86..5d3c758b0800 100644
--- a/dev-python/whoosh/whoosh-2.7.4-r1.ebuild
+++ b/dev-python/whoosh/whoosh-2.7.4-r1.ebuild
@@ -14,7 +14,7 @@ S="${WORKDIR}/${P^}"
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~x64-solaris"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-solaris"
 
 PATCHES=(
 	"${FILESDIR}"/${PN}-2.7.4-tests-specify-utf8.patch