Adding metadata

34 files changed, 935 insertions, 17 deletions

diff --git a/dev-python/aiohttp/Manifest b/dev-python/aiohttp/Manifest
index 8885d1300d46..f1566c460eb4 100644
--- a/dev-python/aiohttp/Manifest
+++ b/dev-python/aiohttp/Manifest
@@ -1 +1,2 @@
 DIST aiohttp-3.8.6.tar.gz 7352172 BLAKE2B 4dc602abb4f9bd7c65bda7d11cde3e703bbc7786fb3f8ef36922caef42912b2c10a198ebdcecd3fcd022c3a9a729766a2023636f756a8fa10663bf988554f967 SHA512 43f1dd6670d90aefee7f0f30411b13c643ea684815b493cc4437e5f1981f4fdf4b718a40543d7c3c8c70d8b27470b8f3bf1609e46146362e0490ce0990a057f5
+DIST aiohttp-3.9.0.tar.gz 7475063 BLAKE2B 0447b9b095b3004b16eef37bd4d815f864dbfad7efb3021cb97676487cdf6d3007de47cb80daa773cc645ca60b21c79768fdc7a15163bb60578b4d05e17db924 SHA512 3001ea211985c26aa4f8a20210d80d6e72a904c1ea93a5aed5d08eb191dd253155ec5a44ae14d961c6ebbc747cbc8e602866ee7eb0b8963cf783a68dcf8b3ba6
diff --git a/dev-python/aiohttp/aiohttp-3.9.0.ebuild b/dev-python/aiohttp/aiohttp-3.9.0.ebuild
new file mode 100644
index 000000000000..cd54c35422f1
--- /dev/null
+++ b/dev-python/aiohttp/aiohttp-3.9.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="HTTP client/server for asyncio"
+HOMEPAGE="
+	https://github.com/aio-libs/aiohttp/
+	https://pypi.org/project/aiohttp/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/aiosignal-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
+	dev-python/brotlicffi[${PYTHON_USEDEP}]
+	>=dev-python/frozenlist-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		<dev-python/async-timeout-5[${PYTHON_USEDEP}]
+		>=dev-python/async-timeout-4.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python3*')
+		test-rust? (
+			dev-python/trustme[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+DOCS=( CHANGES.rst CONTRIBUTORS.txt README.rst )
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# increase the timeout a little
+	sed -e '/abs=/s/0.001/0.01/' -i tests/test_helpers.py || die
+	# xfail_strict fails on py3.10
+	sed -i -e '/--cov/d' -e '/xfail_strict/d' setup.cfg || die
+	sed -i -e 's:-Werror::' Makefile || die
+
+	distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	# workaround missing files
+	mkdir requirements tools || die
+	> requirements/cython.txt || die
+	> tools/gen.py || die
+	chmod +x tools/gen.py || die
+	# force rehashing first
+	emake requirements/.hash/cython.txt.hash
+	> .update-pip || die
+	> .install-cython || die
+	emake cythonize
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# proxy is not packaged
+		tests/test_proxy_functional.py
+		# python_on_whales is not packaged
+		tests/autobahn/test_autobahn.py
+	)
+
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/test_client_session.py::test_client_session_timeout_zero
+		# broken by irrelevant deprecation warnings
+		tests/test_circular_imports.py::test_no_warnings
+		# TODO
+		tests/test_client_session.py::test_request_tracing_url_params
+		# fragile timing test
+		tests/test_imports.py::test_import_time
+		# crash in time-machine
+		# https://github.com/aio-libs/aiohttp/issues/7851
+		# https://github.com/adamchainz/time-machine/issues/403
+		tests/test_cookiejar.py::TestCookieJarSafe::test_max_age
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			# upstream unconditionally blocks building C extensions
+			# on PyPy3 but the test suite needs an explicit switch,
+			# sigh
+			local -x AIOHTTP_NO_EXTENSIONS=1
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_mock,xdist.plugin,pytest_forked
+	rm -rf aiohttp || die
+	epytest --forked
+}
diff --git a/dev-python/clang-python/Manifest b/dev-python/clang-python/Manifest
index ee507a828566..a1ddcbd2429b 100644
--- a/dev-python/clang-python/Manifest
+++ b/dev-python/clang-python/Manifest
@@ -9,4 +9,5 @@ DIST llvm-project-17.0.4.src.tar.xz 127828636 BLAKE2B bd91ef7f07e085b935500b056f
 DIST llvm-project-17.0.4.src.tar.xz.sig 438 BLAKE2B e417c14d0af8c2f13eccec7a42d0e4d5a6a834d7a3d31061b9f56f7e880cd982c2b1e84322bcf8f6a3d3167519c31f16c7acb8fc725ab5b453f467a196ca2688 SHA512 4e79bb1d2b41289c092d4ec2759d7cfd4f12df8d107f9510aa9e2354691e7f878e3929b2b50e29fd6c65bd5a3aa13baf6b791847c1cd99817adbf59700cf2bdd
 DIST llvm-project-17.0.5.src.tar.xz 127842560 BLAKE2B 2d657ff14ad2dc932a5cdc6605ad30cba8e22ed8f4adb5ed53bfd9b5b654496023df9eb895f9691e98bba6b6a341b81d8a17361daf81ce4c3cd6a2b3602cd90e SHA512 793b63aa875b6d02e3a2803815cc9361b76c9ab1506967e18630fc3d6811bf51c73f53c51d148a5fc72e87e35dc2b88cb18b48419939c436451fe65c5a326022
 DIST llvm-project-17.0.5.src.tar.xz.sig 438 BLAKE2B d65bfe2816c49a4b3dda2c70fe5ca6a6b7e922338219e7a62b2f33082d88b700781e184f2b3b0758c1d46825cf369ddd6f8824f3be8d8f3a70a88cfbc06bba45 SHA512 509a61434471463459d3ec837e3f3cce662650d4e72ffc7d28fbeb0d5cfe92d5b1dc4fa568e40f48757b1e708de793bc157de7225ac15a00221191e6c1e660d9
+DIST llvm-project-5237193b87721134541f228e28edfd544a9c8ac8.tar.gz 201404340 BLAKE2B f028b8b100721202007e3106d8ee91bcf2ac90588f9268ec835dc4ea3941363d4b796338146c65d1a9e88957d18738030f713b3fed770616c79cb40043e706db SHA512 40a4d4f99f1a690a0f8737261aeeaa61af6124eeadcb6bab5c3828e88b36b8cce42a8caee6d3f01e675047c59b62210de017d207e341f680eff97758f798ad45
 DIST llvm-project-83888a5404d46667647fe36d6fa510d075ed57ea.tar.gz 200867834 BLAKE2B 20f5afa071089852abfdcc316e5db77681afe0fdb189a515d7724a0abaf1c545f37ba4b946414c7b8afca62636107bd4e1c7c99d8ba6a514bb413b13f5f634b0 SHA512 4cd7680a227388382076d5735a97a379546f5bdde33272a5a3d317d98c2847e34917dd38a3cfb3f1f677f6d9a9b2163b29f89dd9c4b92506f5be34a3072e0509
diff --git a/dev-python/clang-python/clang-python-18.0.0_pre20231119.ebuild b/dev-python/clang-python/clang-python-18.0.0_pre20231119.ebuild
new file mode 100644
index 000000000000..e99a4396b062
--- /dev/null
+++ b/dev-python/clang-python/clang-python-18.0.0_pre20231119.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+DEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	test? (
+		sys-devel/clang:${LLVM_MAJOR}
+	)
+"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	# tests rely on results from a specific clang version, so override
+	# the search path
+	local -x CLANG_LIBRARY_PATH=${BROOT}/usr/lib/llvm/${LLVM_MAJOR}/$(get_libdir)
+	local -x CLANG_NO_DEFAULT_CONFIG=1
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/identify/Manifest b/dev-python/identify/Manifest
index 3cc744dde4e3..9fda44126e9f 100644
--- a/dev-python/identify/Manifest
+++ b/dev-python/identify/Manifest
@@ -1 +1,2 @@
 DIST identify-2.5.31.gh.tar.gz 101612 BLAKE2B 1b74bf8b352cc0f6f0051ccdba192515a1436bfa9e41f971ac929e356737c586c48d1684b982d468e42489e97913a46357dc705a766066c9edb6e6d43f1bbf89 SHA512 00116339c82625087c58a7393bf88800608a152a56fd03b13d1e9ff8c404fa9cfc6ac6824ac1b6eadba572f0e13fb0010789bcdefb7f551b15df4c3de98f77bc
+DIST identify-2.5.32.gh.tar.gz 101673 BLAKE2B a24c0df85c482fbc04adce0be258aa96ffa387eb569365fcdf589cf5fc4d3823ade3c60a0e2e9df65610506bc0d74c532b9964af1fea367191e3c4572e62388f SHA512 104326e2c1529c89425eeaf738a65bf9fc7f2dfa99e7aae18b33c8250aa34f3ead0371dbd2dad9253100de59f618c6c8d3c033f406eec179f1dcce47fe43fc36
diff --git a/dev-python/identify/identify-2.5.32.ebuild b/dev-python/identify/identify-2.5.32.ebuild
new file mode 100644
index 000000000000..1eb5bb52d90d
--- /dev/null
+++ b/dev-python/identify/identify-2.5.32.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="File identification library for Python"
+HOMEPAGE="
+	https://github.com/pre-commit/identify/
+	https://pypi.org/project/identify/
+"
+SRC_URI="
+	https://github.com/pre-commit/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/ukkonen[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/jupyterlab/Manifest b/dev-python/jupyterlab/Manifest
index f862d26197d2..2400f079a7f8 100644
--- a/dev-python/jupyterlab/Manifest
+++ b/dev-python/jupyterlab/Manifest
@@ -1,3 +1,4 @@
 DIST jupyterlab-4.0.6.tar.gz 18236816 BLAKE2B e39e7cb6fbdecfee0b5e592091f989fe94907369d057457130f8bc2f391ca4c83cc09542bc9da766413821eb4c4e9eaaca3adfeccf26b0b2f61ab5e65dac9e45 SHA512 fc4acde65f2bb24adbf95e5cde17e0225390a0c8aca10e04b7c9cf5b2bcebe529608b53ce259f081508b86216b94c71fb260c857b9fe3a2bef16cb4e7af3dcda
 DIST jupyterlab-4.0.7.tar.gz 18316994 BLAKE2B 9965a2bcb0b926af17626e9aef7b37e62144685e4e6cb17b029f3b760d4d4ba583c772683078c3f7cf7fbb09d31e5214193757116873e4457596d7522ddbbf04 SHA512 2f65f8aba9db17574d5caa030437c57ca98808561645f0b30b9fd4fe2cc49f6234776a36db474051cdfeebf1d9e7f3b874189110c955edecb89506580d8917e3
 DIST jupyterlab-4.0.8.tar.gz 18345373 BLAKE2B f6d3b1f53e23f5107775c442b4c69b435091035a9369423e7f474d6a6b77c163ba49b766cc4368b1764d08beea89b881389699920e9f076ad02c8266809bfee9 SHA512 991d17b1338cd172364f812698c989b1d9f853a24d97ce3eb0f89f1ebbe78bc740ab2eafb37e929ac623ac8c06188ed0dcc7ec85ab8d3d9103019c33b45fcf6b
+DIST jupyterlab-4.0.9.tar.gz 18347162 BLAKE2B b4a62088dd8b3b646af1ea02a57c915d659f31e716e6db27c076c945340a53c742cff49518e5b13ada32a9b00f83f143e5504ae897a7abf454a7c997f72e00e6 SHA512 c87451821afa28e7016acdcff315cc48578ea1735b74c2732ed2570c326901acc38fa333344e89ba1c15799ac6bf3f9332c67cdd0ce8ac38713e0be6973d1c1a
diff --git a/dev-python/jupyterlab/jupyterlab-4.0.9.ebuild b/dev-python/jupyterlab/jupyterlab-4.0.9.ebuild
new file mode 100644
index 000000000000..5eb97854b550
--- /dev/null
+++ b/dev-python/jupyterlab/jupyterlab-4.0.9.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi xdg
+
+DESCRIPTION="JupyterLab computational environment"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyterlab/jupyterlab/
+	https://pypi.org/project/jupyterlab/
+"
+
+LICENSE="BSD MIT GPL-3 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/async-lru[${PYTHON_USEDEP}]
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.3[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-lsp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-server-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-server-2.19[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-server-3[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	net-libs/nodejs
+"
+
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		>=dev-python/pytest-jupyter-0.5.3[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-cache[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# These tests call npm and want internet
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_uninstall_core_extension
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned_folder
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom_minimal_core_config
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_check
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_clear
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_build
+)
+
+EPYTEST_IGNORE=(
+	jupyterlab/tests/test_announcements.py
+)
+
+distutils_enable_tests pytest
+# TODO: package sphinx_copybutton
+#distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme dev-python/myst-parser
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index e9da2ac43cac..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..736a1167c898 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,12 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
- </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/lit/Manifest b/dev-python/lit/Manifest
index ee507a828566..a1ddcbd2429b 100644
--- a/dev-python/lit/Manifest
+++ b/dev-python/lit/Manifest
@@ -9,4 +9,5 @@ DIST llvm-project-17.0.4.src.tar.xz 127828636 BLAKE2B bd91ef7f07e085b935500b056f
 DIST llvm-project-17.0.4.src.tar.xz.sig 438 BLAKE2B e417c14d0af8c2f13eccec7a42d0e4d5a6a834d7a3d31061b9f56f7e880cd982c2b1e84322bcf8f6a3d3167519c31f16c7acb8fc725ab5b453f467a196ca2688 SHA512 4e79bb1d2b41289c092d4ec2759d7cfd4f12df8d107f9510aa9e2354691e7f878e3929b2b50e29fd6c65bd5a3aa13baf6b791847c1cd99817adbf59700cf2bdd
 DIST llvm-project-17.0.5.src.tar.xz 127842560 BLAKE2B 2d657ff14ad2dc932a5cdc6605ad30cba8e22ed8f4adb5ed53bfd9b5b654496023df9eb895f9691e98bba6b6a341b81d8a17361daf81ce4c3cd6a2b3602cd90e SHA512 793b63aa875b6d02e3a2803815cc9361b76c9ab1506967e18630fc3d6811bf51c73f53c51d148a5fc72e87e35dc2b88cb18b48419939c436451fe65c5a326022
 DIST llvm-project-17.0.5.src.tar.xz.sig 438 BLAKE2B d65bfe2816c49a4b3dda2c70fe5ca6a6b7e922338219e7a62b2f33082d88b700781e184f2b3b0758c1d46825cf369ddd6f8824f3be8d8f3a70a88cfbc06bba45 SHA512 509a61434471463459d3ec837e3f3cce662650d4e72ffc7d28fbeb0d5cfe92d5b1dc4fa568e40f48757b1e708de793bc157de7225ac15a00221191e6c1e660d9
+DIST llvm-project-5237193b87721134541f228e28edfd544a9c8ac8.tar.gz 201404340 BLAKE2B f028b8b100721202007e3106d8ee91bcf2ac90588f9268ec835dc4ea3941363d4b796338146c65d1a9e88957d18738030f713b3fed770616c79cb40043e706db SHA512 40a4d4f99f1a690a0f8737261aeeaa61af6124eeadcb6bab5c3828e88b36b8cce42a8caee6d3f01e675047c59b62210de017d207e341f680eff97758f798ad45
 DIST llvm-project-83888a5404d46667647fe36d6fa510d075ed57ea.tar.gz 200867834 BLAKE2B 20f5afa071089852abfdcc316e5db77681afe0fdb189a515d7724a0abaf1c545f37ba4b946414c7b8afca62636107bd4e1c7c99d8ba6a514bb413b13f5f634b0 SHA512 4cd7680a227388382076d5735a97a379546f5bdde33272a5a3d317d98c2847e34917dd38a3cfb3f1f677f6d9a9b2163b29f89dd9c4b92506f5be34a3072e0509
diff --git a/dev-python/lit/lit-18.0.0_pre20231119.ebuild b/dev-python/lit/lit-18.0.0_pre20231119.ebuild
new file mode 100644
index 000000000000..6680285a5660
--- /dev/null
+++ b/dev-python/lit/lit-18.0.0_pre20231119.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm
+	)
+"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	# flaky test
+	# https://github.com/llvm/llvm-project/issues/72022
+	rm tests/progress-bar.py || die
+
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}
diff --git a/dev-python/lxml/lxml-4.9.3-r2.ebuild b/dev-python/lxml/lxml-4.9.3-r2.ebuild
index 88b5879a3842..611ab03165ac 100644
--- a/dev-python/lxml/lxml-4.9.3-r2.ebuild
+++ b/dev-python/lxml/lxml-4.9.3-r2.ebuild
@@ -76,6 +76,10 @@ python_prepare_all() {
 }
 
 python_compile() {
+	local DISTUTILS_ARGS=(
+		# by default it adds -w to CFLAGS
+		--warnings
+	)
 	tc-export PKG_CONFIG
 	distutils-r1_python_compile
 }
diff --git a/dev-python/mkdocs-material/Manifest b/dev-python/mkdocs-material/Manifest
index a76041297c96..b02d42910140 100644
--- a/dev-python/mkdocs-material/Manifest
+++ b/dev-python/mkdocs-material/Manifest
@@ -1,3 +1,4 @@
+DIST mkdocs-material-9.4.10.gh.tar.gz 14552628 BLAKE2B 167cc7388d18c4db4c763b50356932a5e1fe03c19232fb79a6cfdecefb6295c67fabfc089ccd83660bebba6098ad1ba24ecb9afcf58d91e46401821466fce502 SHA512 62905520b8ad9ede2357f4b4208a9409aa7134d77b51efdcd87de2a69ba6b4200da297a8b654ff9c96a9147b322c753b66e6106f5d0b872a9b993494801b7e22
 DIST mkdocs-material-9.4.7.gh.tar.gz 14556029 BLAKE2B a3f0289afcd38dc9af2bb18205e19e78565fbe4230ed5a730736945d6b12edbcf598b337ad0715b96184059d434b6589d133bc93cec7624a72bc89ce4c30c352 SHA512 31feb4bdb5ad54fdfbe0cc054fce76e2af3b2c87424c1f3ffbda7500852074994a09de94c51b87fa40145afce6e82911b3e7399691a6c736e8c0858cc094107b
 DIST mkdocs-material-9.4.8.gh.tar.gz 14556346 BLAKE2B 21cdf8e9c4d0e236db1d3bc34510be57ea273ec8b8761d896b82f32e1001313f4e00716a9b90c956ef81b522370e622bc6ad83c342a5c29cdd83e3006aae0bdf SHA512 d6f89071b60f1259f34e96e5ff3562c80096a1b3ac2b5ff44f1bf20818bdff32067d125c24d15c3b8e794e3649c42f6681417dbf1b72f0c0bd10e345e20b5be9
 DIST mkdocs-material-9.4.9.gh.tar.gz 14552215 BLAKE2B 69411102e874017f9a74991cda8552d9ea2422ba5717bfe31e89f99f1e042711ea2c12cf4eb1bcd1b897d260c262869c9c230c5c4ec8c9a110be5583546dd882 SHA512 cb7535b2989f752a4cbd4bf783358dcc388e4cff03273898273b1c65332471dcd7a21571e9bf1c55666339e0462bf356d1d6c17f59f75a54ab388bb357e1c6a3
diff --git a/dev-python/mkdocs-material/mkdocs-material-9.4.10.ebuild b/dev-python/mkdocs-material/mkdocs-material-9.4.10.ebuild
new file mode 100644
index 000000000000..31c55fa06872
--- /dev/null
+++ b/dev-python/mkdocs-material/mkdocs-material-9.4.10.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-material-extensions
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-redirects
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="A Material Design theme for MkDocs"
+HOMEPAGE="
+	https://github.com/squidfunk/mkdocs-material/
+	https://pypi.org/project/mkdocs-material/
+"
+SRC_URI="
+	https://github.com/squidfunk/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="social"
+
+RDEPEND="
+	>=dev-python/Babel-2.10.3[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.6[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.5.3[${PYTHON_USEDEP}]
+	>=dev-python/paginate-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.16[${PYTHON_USEDEP}]
+	>=dev-python/pymdown-extensions-10.2[${PYTHON_USEDEP}]
+	>=dev-python/readtime-2.0[${PYTHON_USEDEP}]
+	>=dev-python/regex-2022.4.24[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26[${PYTHON_USEDEP}]
+	social? (
+		>=dev-python/pillow-9.0[${PYTHON_USEDEP}]
+		>=media-gfx/cairosvg-2.5[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/trove-classifiers-2023.10.18[${PYTHON_USEDEP}]
+"
+# mkdocs-material-extensions depends on mkdocs-material creating a circular dep
+PDEPEND="
+	>=dev-python/mkdocs-material-extensions-1.2[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	# simplify pyproject to remove extra deps for metadata
+	"${FILESDIR}/${PN}-8.5.7-simplify-build.patch"
+)
+
+src_prepare() {
+	echo "__version__ = '${PV}'" > gentoo_version.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/pyfakefs/Manifest b/dev-python/pyfakefs/Manifest
index f81f5fd28755..fee4178481bd 100644
--- a/dev-python/pyfakefs/Manifest
+++ b/dev-python/pyfakefs/Manifest
@@ -1 +1,2 @@
 DIST pyfakefs-5.3.0.gh.tar.gz 224241 BLAKE2B de6d1b420bcfe710bef00c4f8d9cd4fa838341a7285d89a02607701f0011ccbe7f1974c5eec502994f787661496f74332bc4d4aa3389023ae02607a968c33be5 SHA512 25d967390f66ba5881429a37b62110ef129aae989efe66740c3a04fccfcbc601476d23427ac23d5df82a1e1a8102d557f0cca39b94fa0c7e69b6dca80d1e435e
+DIST pyfakefs-5.3.1.gh.tar.gz 225234 BLAKE2B 2688a40ce22a112ce80de8795e3c0b0dd7e2cd46b41c442c5e13085ec614e323a5558cfa48e0e5c79c7c418a739b3f0a6202bb007e8c201ac3fbcc3b209a3d9f SHA512 6d2b16327e8f40d98ac84ea8662dc359aa1b590e1de71761d511b084268d44ee2950cd2af1ec4e722fcb6e7dd14b93e01969fa5cc12e178e97ca2ce69073deea
diff --git a/dev-python/pyfakefs/pyfakefs-5.3.0.ebuild b/dev-python/pyfakefs/pyfakefs-5.3.0.ebuild
index 382bdecc8a01..fcc471ab6d86 100644
--- a/dev-python/pyfakefs/pyfakefs-5.3.0.ebuild
+++ b/dev-python/pyfakefs/pyfakefs-5.3.0.ebuild
@@ -25,11 +25,22 @@ KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv
 distutils_enable_tests pytest
 
 python_test() {
+	local EPYTEST_DESELECT=()
 	local EPYTEST_IGNORE=(
 		# test for regression with opentimelineio package
 		pyfakefs/pytest_tests/segfault_test.py
 	)
 
+	case ${EPYTHON} in
+		python3.12)
+			EPYTEST_DESELECT+=(
+				# happens with pandas + zstandard [cffi backend]
+				# https://github.com/pytest-dev/pyfakefs/issues/910
+				pyfakefs/tests/patched_packages_test.py::TestPatchedPackages::test_read_{csv,table}
+			)
+			;;
+	esac
+
 	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
 	epytest -p pyfakefs.pytest_plugin
 }
diff --git a/dev-python/pyfakefs/pyfakefs-5.3.1.ebuild b/dev-python/pyfakefs/pyfakefs-5.3.1.ebuild
new file mode 100644
index 000000000000..295cd124ec5c
--- /dev/null
+++ b/dev-python/pyfakefs/pyfakefs-5.3.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A fake file system that mocks the Python file system modules"
+HOMEPAGE="
+	https://github.com/pytest-dev/pyfakefs/
+	https://pypi.org/project/pyfakefs/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pyfakefs/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	local EPYTEST_IGNORE=(
+		# test for regression with opentimelineio package
+		pyfakefs/pytest_tests/segfault_test.py
+	)
+
+	case ${EPYTHON} in
+		python3.12)
+			EPYTEST_DESELECT+=(
+				# happens with pandas + zstandard [cffi backend]
+				# https://github.com/pytest-dev/pyfakefs/issues/910
+				pyfakefs/tests/patched_packages_test.py::TestPatchedPackages::test_read_{csv,table}
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pyfakefs.pytest_plugin
+}
diff --git a/dev-python/pygments/Manifest b/dev-python/pygments/Manifest
index 0e53d345f375..98bd6da5a29d 100644
--- a/dev-python/pygments/Manifest
+++ b/dev-python/pygments/Manifest
@@ -1,2 +1,3 @@
 DIST Pygments-2.16.1.tar.gz 4872980 BLAKE2B 57ec4f52f2bca3d9df993f583434d61ad0adbc2719f2d0b4ac84160672a3a57ec144509c520f2724a15f0222548abfbe0e743fa31a8dac64d54111b2d7393ae4 SHA512 9b66c79c03e7ecd36cc00efd428a0a6b372e70dbccdcaae26eff4d56c07a17e2e00d2cf0291eb6624ffd1c896b797789b973e80ccbca4240d56daad95eacfd80
 DIST pygments-2.17.0.tar.gz 4827657 BLAKE2B 53ab36177bb88a3a19cd14a86bedab5aecf3286e2b08432f643d31d22179c4bf7e938dc8fffc3a5ecfcfead747d26085730dd611d050ae649cea62353639941e SHA512 b385f58bb7dba6b193e6c9715e0a34a883d810d2ee919a24268d7b9fffaf7501c0964c8d84aa26edcb503141330e6b752fe52d11b3d146177d42ecd3ab9211de
+DIST pygments-2.17.1.tar.gz 4827687 BLAKE2B 71e5311b15ece8463a5062a4a83796b5e652b3d67ab2d4578cc03d139816fb3de9dff204c1d35ef9e959e502d57ef22b1507212d3ed477866757e596c6c488f4 SHA512 587f9d32bbb6c9bdbe53db2f5a24b93323905cd515acf3a0e73318c00bdbb71e109d9258de54ac45a1d85fe285ffdd1b9b0397b41391124754f41af4c9e02e4b
diff --git a/dev-python/pygments/pygments-2.17.1.ebuild b/dev-python/pygments/pygments-2.17.1.ebuild
new file mode 100644
index 000000000000..f11e1128e382
--- /dev/null
+++ b/dev-python/pygments/pygments-2.17.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 bash-completion-r1 pypi
+
+DESCRIPTION="Pygments is a syntax highlighting package written in Python"
+HOMEPAGE="
+	https://pygments.org/
+	https://github.com/pygments/pygments/
+	https://pypi.org/project/Pygments/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/wcag-contrast-ratio[${PYTHON_USEDEP}]
+		virtual/ttf-fonts
+	)
+"
+
+EPYTEST_DESELECT=(
+	# fuzzing tests, very slow
+	tests/test_basic_api.py::test_random_input
+	# incompatibility with python-ctags3, apparently
+	# https://github.com/pygments/pygments/issues/2486
+	tests/test_html_formatter.py::test_ctags
+)
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp external/pygments.bashcomp pygmentize
+}
diff --git a/dev-python/requests-cache/Manifest b/dev-python/requests-cache/Manifest
index 462156bb6e08..830fe161ad1a 100644
--- a/dev-python/requests-cache/Manifest
+++ b/dev-python/requests-cache/Manifest
@@ -1 +1,2 @@
 DIST requests-cache-1.1.0.gh.tar.gz 2918734 BLAKE2B 4f420a607631568b40999a904598504e0917f50f33715d1d041e0c11dc196abc88cf96ed57860632a1e1f1fb74f3fcabde3df6096821dc0a0967aabca868f7ad SHA512 8fa9fdf4f47d67a6ad877fc181e04378b4540b35cef200735caff14e4907519aa5de74acaf61c6588856d5c8b2f9529768250a8e5fe28962b7861daf2279bb94
+DIST requests-cache-1.1.1.gh.tar.gz 2927360 BLAKE2B 2db8b71d4f219f2b61e4477a57af9dee09783ea47e86dfcc7b7726acb2507043186433ee6a9f67162c0a01c5f1439fd52ea9b74b89daa94cbe351341ef6b1f53 SHA512 99782fe635daa0834709b254b0d51c5d2b2ad37d26201acdc143f963b613bb6b4e5863e2246a2bf9d099c773e229157a983b04a40740e6207e2c356dc48bdba6
diff --git a/dev-python/requests-cache/requests-cache-1.1.1.ebuild b/dev-python/requests-cache/requests-cache-1.1.1.ebuild
new file mode 100644
index 000000000000..e705484ad768
--- /dev/null
+++ b/dev-python/requests-cache/requests-cache-1.1.1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 optfeature
+
+HOMEPAGE="
+	https://pypi.org/project/requests-cache/
+	https://github.com/requests-cache/requests-cache/
+"
+DESCRIPTION="Persistent cache for requests library"
+SRC_URI="
+	https://github.com/requests-cache/requests-cache/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	>=dev-python/cattrs-22.2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.5[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	>=dev-python/url-normalize-1.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/itsdangerous[${PYTHON_USEDEP}]
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/rich-10.0[${PYTHON_USEDEP}]
+		dev-python/timeout-decorator[${PYTHON_USEDEP}]
+		>=dev-python/ujson-5.4[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# These require extra servers running
+		tests/integration/test_dynamodb.py
+		tests/integration/test_gridfs.py
+		tests/integration/test_mongodb.py
+		tests/integration/test_redis.py
+	)
+	local EPYTEST_DESELECT=(
+		# Requires Internet access
+		tests/integration/test_upgrade.py::test_version_upgrade
+	)
+
+	case ${EPYTHON} in
+		python3.12)
+			# https://github.com/requests-cache/requests-cache/issues/845
+			EPYTEST_DESELECT+=(
+				tests/integration/test_memory.py::TestMemoryCache::test_response_no_duplicate_read
+				tests/integration/test_sqlite.py::TestSQLiteCache::test_concurrency
+			)
+			;;
+	esac
+
+	local -x USE_PYTEST_HTTPBIN=true
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "redis backend" "dev-python/redis"
+	optfeature "MongoDB backend" "dev-python/pymongo"
+
+	optfeature "JSON serialization" "dev-python/ujson"
+	optfeature "YAML serialization" "dev-python/pyyaml"
+	optfeature "signing serialized data" "dev-python/itsdangerous"
+}
diff --git a/dev-python/scipy/Manifest b/dev-python/scipy/Manifest
index 85dd8b3c9e2d..456596767a77 100644
--- a/dev-python/scipy/Manifest
+++ b/dev-python/scipy/Manifest
@@ -3,5 +3,7 @@ DIST scipy-1.11.0.tar.gz 56030121 BLAKE2B e700bf8f9cffa7bc0f4832722010dcf2e03d8f
 DIST scipy-1.11.1.tar.gz 56031509 BLAKE2B 456a80103f8c31c456f80e06b25d765f7ad5655dbdd49e99f476e78273f4291c578a8e99fda3f3a1e848c0e75e08629a09a8146b4a798e85edcaffb7ed1d34a9 SHA512 2859fc73c4fef713497f450b76a57d274bb46477a08ac909714823225f065a13c1e42a61ce67575cfc475e1e4612090cc4ca0920411fe32370c5b5c476352f97
 DIST scipy-1.11.2.tar.gz 56045065 BLAKE2B c92a27ef7b560c17bea7dbbc5ca7e192cc7ee8297b65887c3bad50509cca0f83314b688e8c9ef14228c7891e4c16e9d45920de7cb39a0456c7712ae752839203 SHA512 f6902d48617827d01f69c057f3c4790c7388bc58df0791ade96e073740253bc0529475f9fc22d00c23c0b649acaeb820792528d3805d0ac68588c329aa87b3f2
 DIST scipy-1.11.3.tar.gz 56335652 BLAKE2B 2b35c24522b2bd498b4ebe84a854c8ec1e62917e7b899b3e3526abb9780c1e56f8e776a3bb1eab1bedb17a273fac881e5ffdaac808084a4f5a5f97428bff1029 SHA512 6491c4e479d9f4f02e677396a25ddca947a0dc6c009fc2ec34c658012a6224c0b535f14045bb011fbde9973ea987d184574ed64e6760c31798ec860eb0896fcf
+DIST scipy-1.11.4.tar.gz 56336202 BLAKE2B a2091a1edb54eb73c2de6ed8c62a7e571f37b247c9af50947aa97b739342c96b87b20a82b1a238c859fa532c84249cbadde228366dcea3555e9a506c1ae55031 SHA512 2eb403f6de9723b411d948b8e1b5457078704c605b8e760d42362c82d802e167eaaf701ddb8b480af2bdf2efe4dbf66fcc4e97321519bb8dab19b0e2a8976beb
 DIST scipy-html-1.10.1.zip 49191107 BLAKE2B 5163ae3a62745992bcf94ab02ca2bb13fcf6d2ae0eb2a113ba29bc37a8e8f40ec70e39fe16e6371ce0bc31d4c8f0f46746be91b4fe2ad41c68a985c6f00fb8e7 SHA512 f3252452d3bfd400890f29460de2f97bf72732e0fc864582e906b78808e856ead5b1bf97cba531f2150e396408e585499d127004231421d20108e96040316232
 DIST scipy-html-1.11.0.zip 50421508 BLAKE2B cb5e4a4f8817a80f54ae73b4a47ba22d2438df46ebfe27ef5fdc2695fdd983226f4ccae925bf82b15d01ced4f4b6807384ecadac5e1aa7700aa887ad06b7d065 SHA512 33718bbd5e828687d93fccc441a53b6a2e8f54ac4952d3b69d4c4668f55cb6ef5aba33df9acda20b2400effa5ae71767b2a5602a365ad2045a6edd24ff89c253
+DIST scipy-html-1.11.2.zip 50435722 BLAKE2B 460c67509a8bf50986f866ee2f90e634af21ddd71508efeef5681c2ee2130c3f79b4b428bc21277bfb310bb45ccad1fb38221ada43620055377cdc4839b9d1e5 SHA512 986a6e37f9e01dc4925ef22af6ff660bae1e4b66e57270262974c207dfb70285e3f8f548774d6e81d5f457b9198c0ba1c06e6d689fe5d54fdea878c1e5a7f797
diff --git a/dev-python/scipy/scipy-1.11.3-r1.ebuild b/dev-python/scipy/scipy-1.11.3-r1.ebuild
index b3ca5dfa9759..5ad8d60731ea 100644
--- a/dev-python/scipy/scipy-1.11.3-r1.ebuild
+++ b/dev-python/scipy/scipy-1.11.3-r1.ebuild
@@ -110,6 +110,12 @@ python_test() {
 		# Crashes with assertion, not a regression
 		# https://github.com/scipy/scipy/issues/19321
 		scipy/signal/tests/test_signaltools.py::test_lfilter_bad_object
+
+		# timeouts
+		scipy/sparse/linalg/tests/test_propack.py::test_examples
+		# hang or incredibly slow
+		scipy/optimize/tests/test_lsq_linear.py::TestBVLS::test_large_rank_deficient
+		scipy/optimize/tests/test_lsq_linear.py::TestTRF::test_large_rank_deficient
 	)
 	local EPYTEST_IGNORE=()
 
@@ -122,13 +128,9 @@ python_test() {
 	case ${EPYTHON} in
 		pypy3)
 			EPYTEST_DESELECT+=(
-				# TODO: fd leaks?
+				# fd leaks in tests
+				# https://github.com/scipy/scipy/issues/19553
 				scipy/fft/_pocketfft/tests/test_real_transforms.py
-				# timeouts
-				scipy/sparse/linalg/tests/test_propack.py::test_examples
-				# hang or incredibly slow
-				scipy/optimize/tests/test_lsq_linear.py::TestBVLS::test_large_rank_deficient
-				scipy/optimize/tests/test_lsq_linear.py::TestTRF::test_large_rank_deficient
 				# TODO
 				'scipy/special/tests/test_data.py::test_boost[<Data for expi: expinti_data_long_ipp-expinti_data_long>]'
 			)
diff --git a/dev-python/scipy/scipy-1.11.4.ebuild b/dev-python/scipy/scipy-1.11.4.ebuild
new file mode 100644
index 000000000000..6ffd60c1c972
--- /dev/null
+++ b/dev-python/scipy/scipy-1.11.4.ebuild
@@ -0,0 +1,147 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+FORTRAN_NEEDED=fortran
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit fortran-2 distutils-r1 multiprocessing
+
+DESCRIPTION="Scientific algorithms library for Python"
+HOMEPAGE="
+	https://scipy.org/
+	https://github.com/scipy/scipy/
+	https://pypi.org/project/scipy/
+"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+
+	# Need submodules, so git for now.
+	EGIT_REPO_URI="https://github.com/scipy/scipy"
+	EGIT_BRANCH="maintenance/$(ver_cut 1-2).x"
+	EGIT_SUBMODULES=( '*' )
+else
+	inherit pypi
+
+	# Upstream is often behind with doc updates
+	#DOC_PV=${PV}
+	DOC_PV=1.11.2
+
+	SRC_URI+="
+		doc? (
+			https://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-html-${DOC_PV}.zip
+		)"
+
+	if [[ ${PV} != *rc* ]] ; then
+		KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~sparc ~x86"
+	fi
+fi
+
+LICENSE="BSD LGPL-2"
+SLOT="0"
+IUSE="doc +fortran test-rust"
+
+# umfpack is technically optional but it's preferred to have it available.
+DEPEND="
+	>=dev-python/numpy-1.21.6[lapack,${PYTHON_USEDEP}]
+	sci-libs/arpack:=
+	sci-libs/umfpack
+	virtual/cblas
+	>=virtual/lapack-3.8
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/pillow[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-lang/swig
+	>=dev-python/cython-0.29.35[${PYTHON_USEDEP}]
+	>=dev-python/meson-python-0.12.1[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.10.4[${PYTHON_USEDEP}]
+	>=dev-util/meson-1.1.0
+	!kernel_Darwin? ( dev-util/patchelf )
+	virtual/pkgconfig
+	doc? ( app-arch/unzip )
+	fortran? ( dev-python/pythran[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+	test-rust? (
+		dev-python/pooch[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_unpack() {
+	default
+
+	if use doc; then
+		unzip -qo "${DISTDIR}"/${PN}-html-${DOC_PV}.zip -d html || die
+	fi
+}
+
+python_configure_all() {
+	DISTUTILS_ARGS=(
+		-Dblas=blas
+		-Dlapack=lapack
+		-Duse-pythran=$(usex fortran true false)
+	)
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+
+	local EPYTEST_DESELECT=(
+		# Network
+		scipy/datasets/tests/test_data.py::TestDatasets::test_existence_all
+		scipy/datasets/tests/test_data.py::TestDatasets::test_ascent
+		scipy/datasets/tests/test_data.py::TestDatasets::test_face
+		scipy/datasets/tests/test_data.py::TestDatasets::test_electrocardiogram
+
+		# Precision issue with diff. blas?
+		scipy/optimize/tests/test__basinhopping.py::Test_Metropolis::test_gh7799
+
+		# Crashes with assertion, not a regression
+		# https://github.com/scipy/scipy/issues/19321
+		scipy/signal/tests/test_signaltools.py::test_lfilter_bad_object
+
+		# timeouts
+		scipy/sparse/linalg/tests/test_propack.py::test_examples
+		# hang or incredibly slow
+		scipy/optimize/tests/test_lsq_linear.py::TestBVLS::test_large_rank_deficient
+		scipy/optimize/tests/test_lsq_linear.py::TestTRF::test_large_rank_deficient
+	)
+	local EPYTEST_IGNORE=()
+
+	if ! has_version -b "dev-python/pooch[${PYTHON_USEDEP}]" ; then
+		EPYTEST_IGNORE+=(
+			scipy/datasets/tests/test_data.py
+		)
+	fi
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# fd leaks in tests
+				# https://github.com/scipy/scipy/issues/19553
+				scipy/fft/_pocketfft/tests/test_real_transforms.py
+				# TODO
+				'scipy/special/tests/test_data.py::test_boost[<Data for expi: expinti_data_long_ipp-expinti_data_long>]'
+			)
+			;;
+	esac
+
+	epytest -n "$(makeopts_jobs)" --dist=worksteal scipy
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${WORKDIR}"/html/. )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/slixmpp/metadata.xml b/dev-python/slixmpp/metadata.xml
index f92dd44bbba6..06c35a99a4f0 100644
--- a/dev-python/slixmpp/metadata.xml
+++ b/dev-python/slixmpp/metadata.xml
@@ -10,7 +10,6 @@
   <name>Python</name>
  </maintainer>
  <upstream>
-  <remote-id type="codeberg">poezio/slixmpp</remote-id>
   <remote-id type="cpe">cpe:/a:slixmpp_project:slixmpp</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
diff --git a/dev-python/sphinx-design/Manifest b/dev-python/sphinx-design/Manifest
new file mode 100644
index 000000000000..cbd0bc11f54b
--- /dev/null
+++ b/dev-python/sphinx-design/Manifest
@@ -0,0 +1 @@
+DIST sphinx-design-0.5.0.gh.tar.gz 2588276 BLAKE2B 2262c8ddcaf108307e2e9d3eab2bfa8e04b7bb891a19450f3c235e81043fe7f886ea74373bb7d8929f6c8fdeae57b7d6b50cd91a9c3a4894d3dc19fbd81ef458 SHA512 26369c17d519e9a8f6a4bfdb68db60599e33c1db867037fdced6292439a9fcbe6a312c2d17ada058b14c95878ced7679bf6b64d7d4f13194f19502cd9be93b69
diff --git a/dev-python/sphinx-design/metadata.xml b/dev-python/sphinx-design/metadata.xml
new file mode 100644
index 000000000000..36acccda7221
--- /dev/null
+++ b/dev-python/sphinx-design/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>dev@liguros.net</email>
+  <name>Development</name>
+ </maintainer>
+ 
+ <origin>ports</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/sphinx-design/sphinx-design-0.5.0.ebuild b/dev-python/sphinx-design/sphinx-design-0.5.0.ebuild
new file mode 100644
index 000000000000..c09765272562
--- /dev/null
+++ b/dev-python/sphinx-design/sphinx-design-0.5.0.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2023 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A sphinx extension for designing beautiful, view size responsive web components"
+HOMEPAGE="https://sphinx-design.readthedocs.io"
+SRC_URI="https://github.com/executablebooks/sphinx-design/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="code_style rtd theme_furo theme_pydata theme_rtd theme_sbt"
+
+RDEPEND="<dev-python/sphinx-8[${PYTHON_USEDEP}]
+	code_style? ( dev-vcs/pre-commit )
+	rtd? ( <dev-python/myst-parser-3[${PYTHON_USEDEP}] )
+	theme_furo? ( >=dev-python/furo-2022.06.04[${PYTHON_USEDEP}] )
+	theme_pydata? ( dev-python/pydata-sphinx-theme[${PYTHON_USEDEP}] )
+	theme_rtd? ( dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}] )
+	theme_sbt? ( dev-python/sphinx-book-theme[${PYTHON_USEDEP}] )
+"
+BDEPEND="test? (
+		dev-python/pytest-regressions[${PYTHON_USEDEP}]
+		<dev-python/myst-parser-3[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/myst-parser
diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index e0b05f1bdc22..0e2c84708c58 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -1,2 +1,3 @@
 DIST tavern-2.3.0.gh.tar.gz 211676 BLAKE2B 80506d846036c7a68bf27c30e734a92983eadaff07e68a101e120a6284be750bc195817f1686cdaabe8dfe906720e5b41d22098db8f91e911438a60a2cbdd5db SHA512 2c1292cd047195b6e2059514f517b29caebeac3af370b298938cbbc8b5bc861dd818c3e45e25a65fa1acbbae96f36aa2d024edcee49b0086d459f3d41d4052ed
 DIST tavern-2.5.0.gh.tar.gz 217343 BLAKE2B bcb9d7f753b14351cd98e12e9d392f9effa716651f8686d053dc72080a2b738b02f78665f2bb07012b4c6ec7b39a661dfdc74a0272c036718cc13e2d731b4cee SHA512 9d957f815b57ba01d9707c1a3e8f715f062194efd0b24d82ebb99aec4bb83965e31a6538f3ff7748d3acd52b32cd38a097a4d36fe71faf1703dbf70ff0454111
+DIST tavern-2.6.0.gh.tar.gz 217509 BLAKE2B 99d9990757930a45a86a914fcf656b63266266869542cbd9b59850c7d648f54993ad5f409f12d09fbb12383c7586ecaeed323b04b478d62c7331cf514faa970a SHA512 1165dcc41244259d2ef7f69370dd35a40a9411b2a5c05e5dae45fc413d88478cd49aa540175a4a65dcf7dcd0eb2ee06b4f97059eb5d69ed5684893a8d5e8fcdc
diff --git a/dev-python/tavern/files/tavern-2.6.0-py312.patch b/dev-python/tavern/files/tavern-2.6.0-py312.patch
new file mode 100644
index 000000000000..679b0c9d2358
--- /dev/null
+++ b/dev-python/tavern/files/tavern-2.6.0-py312.patch
@@ -0,0 +1,38 @@
+From 8c09a6f31d84904dcf411e50102ac1ad159e4dd9 Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
+Date: Sun, 19 Nov 2023 08:56:20 +0100
+Subject: [PATCH] Fix assertion in TestCheckParseValues::test_warns_bad_type
+
+Fix the assertion in TestCheckParseValues::test_warns_bad_type
+to use `.assert_called_with()` rather than non-existing `.called_with()`
+method.  The latter is wrongly interpreted as calling a mocked method
+in Python < 3.12, and therefore does not test anything at all.  Starting
+with Python 3.12, it results in an error:
+
+    AttributeError: 'called_with' is not a valid assertion. Use a spec for the mock if 'called_with' is meant to be an attribute.
+
+Fixing the call also revealed that the assertion was incorrect, so I've
+updated it to match the current call.
+---
+ tests/unit/test_helpers.py | 8 ++++----
+ 1 file changed, 4 insertions(+), 4 deletions(-)
+
+diff --git a/tests/unit/test_helpers.py b/tests/unit/test_helpers.py
+index 0d3da1c4..19fddc08 100644
+--- a/tests/unit/test_helpers.py
++++ b/tests/unit/test_helpers.py
+@@ -300,10 +300,10 @@ def test_warns_bad_type(self, item):
+         with patch("tavern._core.dict_util.logger.warning") as wmock:
+             _check_and_format_values("{fd}", {"fd": item})
+ 
+-        assert wmock.called_with(
+-            "Formatting 'fd' will result in it being coerced to a string (it is a {})".format(
+-                type(item)
+-            )
++        wmock.assert_called_with(
++            "Formatting '%s' will result in it being coerced to a string (it is a %s)",
++            "fd",
++            type(item),
+         )
+ 
+     @pytest.mark.parametrize("item", [1, "a", 1.3, format_keys("{s}", {"s": 2})])
diff --git a/dev-python/tavern/tavern-2.6.0.ebuild b/dev-python/tavern/tavern-2.6.0.ebuild
new file mode 100644
index 000000000000..1513b445afae
--- /dev/null
+++ b/dev-python/tavern/tavern-2.6.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="
+	https://github.com/taverntesting/tavern/
+	https://pypi.org/project/tavern/
+"
+SRC_URI="
+	https://github.com/taverntesting/tavern/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/paho-mqtt[${PYTHON_USEDEP}]
+	>=dev-python/pyjwt-2.6.0[${PYTHON_USEDEP}]
+	dev-python/pykwalify[${PYTHON_USEDEP}]
+	dev-python/pytest[${PYTHON_USEDEP}]
+	dev-python/python-box[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0.1[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/stevedore[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/Faker[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		"${FILESDIR}/${P}-py312.patch"
+	)
+
+	# strip unnecessary pins, upstream doesn't update them a lot
+	sed -i -E -e 's:,?<=?[0-9.]+::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p tavern
+}
diff --git a/dev-python/versioningit/Manifest b/dev-python/versioningit/Manifest
index 6e764479922b..b657baa5f60d 100644
--- a/dev-python/versioningit/Manifest
+++ b/dev-python/versioningit/Manifest
@@ -1 +1,2 @@
 DIST versioningit-2.2.1.tar.gz 743942 BLAKE2B f0f84b2323cdeac79144d842bbebfc196aecb35752da4dc0e343a709fc539eba50f33079dc652e95dc06bda8ddb761b5a68179b50f533434aafd7d4b1263af63 SHA512 9ec8d4cf26392fd3bfd29d5c3e573a6af8e6a42c6aff1d0f9dbf68a17b667c55859d64d91d5715bf232f4eea22a6f300cbfc6da2be8364186c23b5023fa0e6ad
+DIST versioningit-2.3.0.tar.gz 209785 BLAKE2B 392706b969a3a94be6dee2bbd8935cf97e3f0ab0b102c5ae1ef2d65b25d6e44faf9e50301639aca77c8d81e0265875c548a9d28d331cbc07aaae7ed589c6ab04 SHA512 2e91ab8bf7be333b4783e8e7ad6cf4897694a5d3e14f41cad0f3683291078fb88845d629ee1e41885408bf07d5ea6250588af6e6cf6d6596df1bae4bee5ddf0b
diff --git a/dev-python/versioningit/versioningit-2.3.0.ebuild b/dev-python/versioningit/versioningit-2.3.0.ebuild
new file mode 100644
index 000000000000..74d8a679c711
--- /dev/null
+++ b/dev-python/versioningit/versioningit-2.3.0.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A setuptools plugin for versioning based on git tags"
+HOMEPAGE="
+	https://github.com/jwodder/versioningit/
+	https://pypi.org/project/versioningit/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-17.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		<dev-python/tomli-3[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		dev-python/pydantic[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Tries to do wheel/pip installs
+	test/test_end2end.py
+)
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -o addopts=
+}