Adding metadata

35 files changed, 900 insertions, 3 deletions

diff --git a/dev-python/blosc/Manifest b/dev-python/blosc/Manifest
index 3e4bd98e47ad..d30dd2914f04 100644
--- a/dev-python/blosc/Manifest
+++ b/dev-python/blosc/Manifest
@@ -1 +1,2 @@
 DIST python-blosc-1.10.6.gh.tar.gz 1570504 BLAKE2B 44f444fa5050a6198e83649973fc82d6804eec50bf79c332ed6a974e417f2a58baf09480a9bb5c5b7abcef2a961cd7bc61f962c12db625b1a7c48799ace0b39a SHA512 e283b132ebb91e7ce362ec65a1d6760e3793046371ea545a9e842372084182bcc194c3a0e1cb20914de58554063995a238ea0a129214731689e8cd5f4203d3ed
+DIST python-blosc-1.11.0.gh.tar.gz 111589 BLAKE2B 6bc5dda4e40ceb9770dd5b6e6db1fced42e257475b220bcb530c8b291bf132f61013ece5934a7d47778fdac716fcea0e6d57b7543b1cc76ccd95201cad072bdd SHA512 94c6f470b9f6e8d1fec0e44709e84582cd595291dddcd07ea174665a6fc12e029c6f0c781c8e506e95d4f9ee9fc27cbbfb5bc2789f341df3e84f342626dcfdb0
diff --git a/dev-python/blosc/blosc-1.11.0.ebuild b/dev-python/blosc/blosc-1.11.0.ebuild
new file mode 100644
index 000000000000..6cb23d1ec422
--- /dev/null
+++ b/dev-python/blosc/blosc-1.11.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=python-blosc-${PV}
+DESCRIPTION="High performance compressor optimized for binary data"
+HOMEPAGE="
+	https://www.blosc.org/
+	https://github.com/Blosc/python-blosc/
+	https://pypi.org/project/blosc/
+"
+SRC_URI="
+	https://github.com/Blosc/python-blosc/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/c-blosc-1.19.0:=
+"
+DEPEND="
+	${RDEPEND}
+"
+# py-cpuinfo dep is irrelevant for us, as it is only used to configure
+# bundled c-blosc build
+BDEPEND="
+	dev-python/scikit-build[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( ANNOUNCE.rst README.rst RELEASE_NOTES.rst )
+
+src_configure() {
+	export USE_SYSTEM_BLOSC=1
+	export BLOSC_DIR="${EPREFIX}/usr"
+}
+
+python_test() {
+	"${EPYTHON}" -m blosc.test -v || die
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index ccd6059f3559..edde922c5446 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -6,4 +6,5 @@ DIST boto3-1.26.21.gh.tar.gz 573776 BLAKE2B a608b875d052cb895cae4bc20924836284dd
 DIST boto3-1.26.22.gh.tar.gz 574580 BLAKE2B 35027efcfaa0ec27ff7e8769af32c4ea621fea842a84b689f76ef412305318a16fd3fe3b139f00a66f91892455a14cbb9753ea4f3d07ac24e4e18725cb6c7fb7 SHA512 5035f8be58384b1c8634ab801dd3930043febfbcc5d23f1c4385ce7e4aac37fda61a04ca3adcf86010db21f8d26403b491990746c578d91fa173c9629bb501bb
 DIST boto3-1.26.23.gh.tar.gz 575113 BLAKE2B a39f1546f5733de801f00df97a383f45a6f96ba608f441f4e889ed9b9362bef4b84bfe61a817e4e39cafb25777d4f75021130b05fe14e328006c409a77dd7eeb SHA512 92de04f42e5e94ab1b7dd6aa1d4048fdd372814ecec7742ade8b0a49a871748921f5ac600a421c412c50474e21334e910eb64ce2f3abfaf1e1add391e6dc346b
 DIST boto3-1.26.24.gh.tar.gz 575745 BLAKE2B 2dd132d9daf9dafd81549664b23bb457211adfde1da5279de9519b1a30e0f5921f763f4770f7061011de97d7a52a05cdff57ddede2c3b95f8d048398bd160e9c SHA512 ab1943be54a5979a7e73f9fafc2937528c9a010f3c8244e2951fe802a7a20e57414b2565d6b6628890f913c76386aeaa0583c01901798bcc5080e48aa7da74e4
+DIST boto3-1.26.25.gh.tar.gz 576015 BLAKE2B 55d94441c1fa2668efa31390dbe972b354a4ab69d7825b2ecdcee47d03d44cb2533b428595dfdecc374a1164429166bb1740550334e2da1ff4a20ae31a53bb83 SHA512 c85b3b591926881a08e5143413848fd14b9cbe11c376970e71fe5fc6851a43448941583b73dc40cc0335c6749e7ea31eb8b4ef4d38dcf630d68693b94757bb07
 DIST boto3-1.26.8.gh.tar.gz 557012 BLAKE2B 211bb7441acc8b1f901ebf5251288dc7c9073fa6e34f5a34426424ef064efb0fb3031deaf48ef336ec43bb015f95f618598da43d12ec83cbf814e1b4097b28a0 SHA512 738190cedfb0b85d3a1e9558b03e7f2fb14e43b152bc9627fd95c8ecc4a0ddc17f4c87ccb6129c1fbf5f47db9eea4dbc5c2cfbb69b903bc6f3ff417ef86b6f6b
diff --git a/dev-python/boto3/boto3-1.26.25.ebuild b/dev-python/boto3/boto3-1.26.25.ebuild
new file mode 100644
index 000000000000..3d7d652a3b69
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.25.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index daff95b3af4d..4b4030e8af1f 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -6,4 +6,5 @@ DIST botocore-1.29.21.gh.tar.gz 10994190 BLAKE2B 00a40dd701f659f63c0c0862e96922a
 DIST botocore-1.29.22.gh.tar.gz 10999477 BLAKE2B 90987611453768b9c7c00ea8f6b1645bb8e5bed8ecb8b75c95452a2f20208ffed22182f8ea24bedb03f213826c3d46963f393ffc3f1465ae99620ff7f35240b7 SHA512 23c6ed2d0a9fed97467d568773d886773a06f6e4efffabbfad3b285f4d8f1844e82025b73e7fadd8c29d304c4f27e5385f63896b6ce0250e2af8b950b9a3e014
 DIST botocore-1.29.23.gh.tar.gz 11001723 BLAKE2B d1cfefb3bc25094948a1450ee7159e81d640301eca756702e8debcfa30858c22c77c273043584641888d85c46d3be800c65c2c800ecfc83b2760e7ea40e9a03b SHA512 454ac41097385838d286f3a3d9cc44e076fea8608313895ae657683ea5441328704eaa1b46a22076cad5b7e91eead5291cd036a188ab907b80173f2b755d6160
 DIST botocore-1.29.24.gh.tar.gz 11006663 BLAKE2B 195933b78bd0c5c5881cd697c1c61c6f40557d51edb7510e40ecdd31aae80a72fe3c33946e718a98b19a1f8af6d8cc687e047e5cd0b662de9f2d0ca3b53583e3 SHA512 e6dd5a88bf6539f02d27054d5825688b80a2a582e5ebd04d31d887e6baa31a4ba54aa0ba0c0e03156b4ad22815f6aa8f8f8986c3767180a04b284341223f4c60
+DIST botocore-1.29.25.gh.tar.gz 11008437 BLAKE2B 5a569d52065c2f448adb8c765e51e8338ce0bc2ae4b13e0f39a98af319aa1a31ef3a1eb4014aae8c497ab68a234dc2d16798a0d8b7c626e0ea81da4d2489ed7a SHA512 274a713d26cc723914824cdaf729d7537b5104957751b6d4b0c974e9f45a54ee09bd1853d1ab89dec2fb3b5a5b74102fa658c1f9478a4b4301b950e44f0f1fd5
 DIST botocore-1.29.8.gh.tar.gz 10636661 BLAKE2B 3ebd9e5cb6cc1a9d4ddb877e806e0a845e6a19a4604b4489dbdb9a0f35251201de5d7062f3b0193db3e28f5170d8c3315fdc0b2bec7668a61880ff3e9305d3bc SHA512 c4a1a3993576bd0340de4eeb25e10650219e9d74c21f7e51e5298120bc92a8359143c38d5a991b940316fc5eac483e4e838298881a5c068fa91dc3ebf92a7f5a
diff --git a/dev-python/botocore/botocore-1.29.25.ebuild b/dev-python/botocore/botocore-1.29.25.ebuild
new file mode 100644
index 000000000000..40131f66e350
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.25.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/cbor2/Manifest b/dev-python/cbor2/Manifest
index effd07d11997..afc0fe10da09 100644
--- a/dev-python/cbor2/Manifest
+++ b/dev-python/cbor2/Manifest
@@ -1,3 +1,4 @@
 DIST cbor2-5.4.3.tar.gz 86499 BLAKE2B 0303ed49a1c468a3aa13e12a4bebef17479f106bc3f0a92e35c6029ff1bd86aea6a77f557ac0c8acb5e055ec0b56c82e5c95e9417d00715a1fb244bd94d0f60d SHA512 9527bec5a36464bb7dc9a8c0ece3ad72f1c6182272a7edf0526668b264c957b72bc031d2398dc6af38af09bb298219c316da194084fab410bae5f9100b22328b
 DIST cbor2-5.4.4.tar.gz 86755 BLAKE2B 616a5e3d10f979f7f5923b0226d6ca52392e79bf1c4dcdef6d44143af75b02a91846e1a8f0c571f096f2168908137a5f31995199c13383b4d81cb1f17062b1fd SHA512 f8754423490b8a9643ca3309c99254f6be5e9eeab2163b57631fd2e6fd3f5f5dbd8495e24bbfcf96720f07467797eb3f4e3603822a7d6999f1ee4fa66651f2d7
 DIST cbor2-5.4.5.tar.gz 86800 BLAKE2B 2911cf15d31ec77aab79129719f9fc869392da8383b8a1afbff7e7d9c0d90ad341f66b5b76ae5142eae7036b7446dd54d545a48695de43aaf54e0824e9d8052c SHA512 ee360318c24ab6cdd93162ef78b0ab099990630ebd14c581012b0d86b1a30c9aa1e4b45d285d33da5684f5385db976189e89d32589d68272f79fcd8f7130bf7b
+DIST cbor2-5.4.6.tar.gz 86909 BLAKE2B df24c786f32819f9a93a2db28536b78349db6185108188d0a20e7298ff8c083d1feb59110865b4e21190e0363b113201ccddaa0d36b49bd7bbacf9d5ee7695f4 SHA512 44fb3e2e2249c79b1454487670d53eb672ffae4c22374d2a2bb9e314ac15470e4e7913e4eb1981a8bd4d722e6827328dde7e57c5f0556843e951c4723ae5bd8e
diff --git a/dev-python/cbor2/cbor2-5.4.6.ebuild b/dev-python/cbor2/cbor2-5.4.6.ebuild
new file mode 100644
index 000000000000..eb0ac3d389f9
--- /dev/null
+++ b/dev-python/cbor2/cbor2-5.4.6.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure Python CBOR (de)serializer with extensive tag support"
+HOMEPAGE="
+	https://github.com/agronholm/cbor2/
+	https://pypi.org/project/cbor2/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+BDEPEND="
+	>=dev-python/setuptools-61[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-6.4[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e "s/--cov//" pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/certifi/Manifest b/dev-python/certifi/Manifest
index 5cca7d35f2d7..3d7d985f25fa 100644
--- a/dev-python/certifi/Manifest
+++ b/dev-python/certifi/Manifest
@@ -1,2 +1,2 @@
-DIST certifi-2022.09.14.tar.gz 162894 BLAKE2B 6afd33463d665576295b076deacd717b807d00fc3b3c89b494cc0c632d835d3360d0c4bee3d62d366370a775f8135d3c1213ad85e4101134fc36c67775701bd9 SHA512 09ecd867619dd5282fab92212f8a41557cf6899fc5b6a46be3e4dbb2b7f3af7fe51272e3d6c5dab9345d8988fd282752b08e0f04e505be8046d2afbf09fa2ffc
 DIST certifi-2022.09.24.tar.gz 161341 BLAKE2B acfc2179c320deb318265186887dc1103182f860b668b00521e6e3759e4470353f596a04f2ce699d569ee032b684bf326c7e1870de99a2f58273a7054ec7fd09 SHA512 a7b5ffa2cc3de39c8a204ed7da077c63971d4305565d6663292fc6b530fb6bbb9cfc6777b5998c54f8a06506f871063aae02692ec8508f903f716c73852487e4
+DIST certifi-2022.12.07.tar.gz 155924 BLAKE2B b367fe347e0566d605799323499a6f17b306abc1f2ec342076f4c5331b81da9bdba8c1c3728d234973c782c784cf27abcc1ad47ff07e1b083ac0e64ed54b87c8 SHA512 4e255c0d5998e98c999464ea27dff61831e97de2c812d7b06feb7ad1038c3070f2e48c58fc939485f5d806d419f0273716442c3c86165b861f0d81f0b3393f6b
diff --git a/dev-python/certifi/certifi-2022.09.14.ebuild b/dev-python/certifi/certifi-2022.12.07.ebuild
index 6f339c20a7d6..6f339c20a7d6 100644
--- a/dev-python/certifi/certifi-2022.09.14.ebuild
+++ b/dev-python/certifi/certifi-2022.12.07.ebuild
diff --git a/dev-python/comm/Manifest b/dev-python/comm/Manifest
index 0b1bdf251c69..f90ad630cb08 100644
--- a/dev-python/comm/Manifest
+++ b/dev-python/comm/Manifest
@@ -1,2 +1,3 @@
 DIST comm-0.1.0.tar.gz 5364 BLAKE2B 25715bce2ca51ef81de742ab04dd17120cab1f2f6d563ef566bbefda71daeafe5c2361a56944329d7549610c8c8fbe84100dc5e85f550eb93056d81eb7081f28 SHA512 075c1c1126d4de4321470de4e5cce5b6c9bcbe3f3cc1676f80a464bd559977816d92ce609b58884a195699e1f1713f535045f6070ecf2726e47ff61feedc66f0
 DIST comm-0.1.1.gh.tar.gz 5382 BLAKE2B 8749ae33ecead77c1e3e0130c7d68082ac465fb733ad0908cf42a91d5a1aeca90c987fc469bcf47b5a384e108bafadbe009368162507c8a751b9e16eb5bbc2b0 SHA512 31ce4a1f1f35a3e1790e5a9896fd3f453a952c5fb0de094286bb31b806138a6661b143c1beb076b6fb73328304768e52c0ae6015f040b0451540a2d850f9d448
+DIST comm-0.1.2.gh.tar.gz 5382 BLAKE2B 698cd4823c86d5e589c6bfa1e99d534fc05c34d9c12ea417c0702f6e5b1397db9e334a78fcc445e59b55e4693e5460cb980357c7e299f01db8df3d0bdb2b6ddc SHA512 9cec9909676edc0c8abf41e6d90f83a6ebfa88266023b3b5fd9c1ffe3fe16ba324b68ab92e788bfa01d5304d5de6e6dc96c7238973f3b39f8c77fa5165df8379
diff --git a/dev-python/comm/comm-0.1.2.ebuild b/dev-python/comm/comm-0.1.2.ebuild
new file mode 100644
index 000000000000..b35f01d0fce7
--- /dev/null
+++ b/dev-python/comm/comm-0.1.2.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Jupyter Python Comm implementation, for usage in ipykernel, xeus-python"
+HOMEPAGE="
+	https://github.com/ipython/comm/
+	https://pypi.org/project/comm/
+"
+SRC_URI="
+	https://github.com/ipython/comm/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/traitlets-5.3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 54bfb40c0d30..2268a5244f17 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -5,3 +5,4 @@ DIST ipykernel-6.18.0.tar.gz 137928 BLAKE2B dd296b1fcf7d9fcf81a3315e22d6c488086d
 DIST ipykernel-6.18.1.tar.gz 141559 BLAKE2B 4c12ff56d2e9c34a278e68e141032768ede70f86119193bab22e2ea58faec6e723dbc4d4411565f8c7974e67d55e053b6821e88f5c105cd9f2e2ae7049d137f2 SHA512 ff9fe59c646487483e979b757ea34d884b0bf9749430daf5ae6dd0cf7381c67e51712624938800d49c53f9ca70cb63fc8c38f10851084d4a5b68f3b1e2762b0a
 DIST ipykernel-6.18.2.tar.gz 141693 BLAKE2B 6990354a26dcf9572e52e8d12b3df4f2b34cfff79afd05905f23a3957d3d79c0f28fa27d4bdb8978616fff272d626fb60e1ad8094c05020b2307b8aa5d3e68c6 SHA512 c8c2a1132e8cefec0e5b66cd3cfec14ce18d62d48119e644e1f8849d1472baf3b95b158feb6887cb1788229ac4a0bdff95d0d71141b32930e4e4962688ae5bfd
 DIST ipykernel-6.18.3.tar.gz 141999 BLAKE2B da5b0b2a36a58f2c91fdeab95a7e4bb33e09f9663eccb6d394f69a5a25e7e55e3f18315d017aaf435607efa73acca955665f7720b75ac4aa3256aa034698082d SHA512 0687ac146bac38bbdd6abad11df31572cb105bd41b79de98b40c18b60cdcb550b7ea10d68acf99f26d70c00ed4ef371d6dc2b6a4ce27eccae3f736955754ca1a
+DIST ipykernel-6.19.1.tar.gz 143329 BLAKE2B 324744ab8633338d15d9d72e931fe1c708909ab50c41f2c82192c2c7dd1ad6ffd04b6564265b9d4d09919767b496793aa639bec60fdad8f3e9b2de49f3a6333b SHA512 8c0a3a4cdef050d5fc059bd416a139a89bdacac6d68e31af8c800a7a0cfebf069c2df968b256ac8af1528fdd1d499a020428529ead10c0d96f2205b28906f690
diff --git a/dev-python/ipykernel/ipykernel-6.19.1.ebuild b/dev-python/ipykernel/ipykernel-6.19.1.ebuild
new file mode 100644
index 000000000000..caf88dc23796
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.19.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/debugpy-1.0[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	ipykernel/tests/test_debugger.py::test_attach_debug
+	ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+	ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_set_breakpoints
+	ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+)
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
diff --git a/dev-python/nuitka/Manifest b/dev-python/nuitka/Manifest
index ca0ae7ff7cb6..b38feb53ac76 100644
--- a/dev-python/nuitka/Manifest
+++ b/dev-python/nuitka/Manifest
@@ -1,2 +1,3 @@
 DIST Nuitka-1.2.3.tar.gz 3958335 BLAKE2B c2d47e7ff355492fb72f224be92445849c3fce13768ba7957cf4bbbbc9cd4e0ec7c3904e5465ad543e16d1419a01b42cd4399b816e1ff56e2c8ea5c57fddbc04 SHA512 1c842c21764bd0dc9bf68bb26506959b35e54d03c1d6d6b9c179289ec073ed07b75d6709a3c73ac3e14bb988a7b2f5a88f7dfcce55a25eab1c5e4b294b15d4f4
 DIST Nuitka-1.2.4.tar.gz 3958942 BLAKE2B ca3be2453815949b05f8a74dc783c58125ebbda038a86f22d273c6e4ef6c8b3fe3d238b3abedb0062ace59a0f60545312f8ad8af056b13c975106ee0c7563fa7 SHA512 7a160f7b12ba9dd66af2d3c798bafd4b2d4f60068acb18be5dc9246c811df58b6f2e6b1c3610ed045d7a73042728b53b92c36b239cb88931d500c904e7018847
+DIST Nuitka-1.2.6.tar.gz 3959091 BLAKE2B b326409f49d722bcac7df3e2c5caae7fb9ccf2b2991d2cf003a4db7bd268af95b7423da3b69b93b45c2aa1e3461faac90872b01f2d2277c5e9f7c71bedb0df56 SHA512 b12f694f8ac26213fd1242c66c2a37be1940bafef8a4949f0e401f056a1f72a010d1df237a828317ed0c88530206c31e617f03e4bccf6c934b967f8ddaef330f
diff --git a/dev-python/nuitka/nuitka-1.2.6.ebuild b/dev-python/nuitka/nuitka-1.2.6.ebuild
new file mode 100644
index 000000000000..d2196214be46
--- /dev/null
+++ b/dev-python/nuitka/nuitka-1.2.6.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 flag-o-matic optfeature
+
+DESCRIPTION="Python to native compiler"
+HOMEPAGE="
+	https://www.nuitka.net/
+	https://github.com/Nuitka/Nuitka/
+	https://pypi.org/project/Nuitka/
+"
+SRC_URI="https://nuitka.net/releases/${P^}.tar.gz"
+S=${WORKDIR}/${P^}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~loong ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-util/scons[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? ( dev-util/ccache )
+"
+
+DOCS=( Changelog.pdf Developer_Manual.pdf README.pdf )
+
+distutils-r1_src_prepare() {
+	# remove vendored version of SCons that is Python2 only
+	# this should be removed when upstream removes support for Python2
+	rm -vR "${PN}/build/inline_copy/lib/scons-2.3.2/SCons" || die
+	eapply_user
+}
+
+python_install() {
+	distutils-r1_python_install
+	doman doc/nuitka3.1 doc/nuitka3-run.1
+}
+
+python_test() {
+	append-ldflags -Wl,--no-warn-search-mismatch
+	./tests/basics/run_all.py search || die
+}
+
+pkg_postinst() {
+	optfeature "support for stand-alone executables" app-admin/chrpath
+}
diff --git a/dev-python/packaging/Manifest b/dev-python/packaging/Manifest
index 9cb854a5d2cd..c6cdfbeb954d 100644
--- a/dev-python/packaging/Manifest
+++ b/dev-python/packaging/Manifest
@@ -1 +1,2 @@
 DIST packaging-21.3.gh.tar.gz 80471 BLAKE2B a16ba1e74f0c868816131a7cb07b7aa0c14760cf3ad4c3d6737ac30ef99276c33b1f018d29e710f28e8d0cfb0e3e6b91e375d1d17e2b7ec6302164377cd503d0 SHA512 8960deacda26877b73d98a3b632e760e902a16ec7a04707f84044980e4d4fb33e4f584db115c9008066aa876079f28633bafe37fbd5ce9a23830b6b89eb4ae7a
+DIST packaging-22.0.gh.tar.gz 83340 BLAKE2B 6f8e36c1bed71d4d5902fb833a7c011f3eac5e5e00f9e73a7258bbb6c79cfd30c6c175ad5778c5a5dd88bc275a66f69448ec59937159553d229f93510e189d41 SHA512 2189dec11dd9fd78a6d816bda08f881e5aa54fde09d51450ceb460a37ba87231fcfdb5ad4f58d262face44dfb0f1c4b420f759491008f8c26cef7e8317c414a8
diff --git a/dev-python/packaging/packaging-22.0.ebuild b/dev-python/packaging/packaging-22.0.ebuild
new file mode 100644
index 000000000000..23cbfdbe285c
--- /dev/null
+++ b/dev-python/packaging/packaging-22.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Core utilities for Python packages"
+HOMEPAGE="
+	https://github.com/pypa/packaging/
+	https://pypi.org/project/packaging/"
+SRC_URI="
+	https://github.com/pypa/packaging/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+SLOT="0"
+LICENSE="|| ( Apache-2.0 BSD-2 )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	>=dev-python/pyparsing-3.0.7-r1[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest --capture=no
+}
diff --git a/dev-python/phonenumbers/Manifest b/dev-python/phonenumbers/Manifest
index 44531bb51ca4..54ea4e0ef40e 100644
--- a/dev-python/phonenumbers/Manifest
+++ b/dev-python/phonenumbers/Manifest
@@ -1,3 +1,4 @@
 DIST python-phonenumbers-8.12.57.gh.tar.gz 4906700 BLAKE2B b755e6e27c3006ce2b72f8e8900937ac2b7d2bd464052cd9a788ba5cdbd08ead4628963ea794a5dee962531753f6674342a3eed092edfb421c1d8f203d90b2b3 SHA512 8da340dd88c4bd41fd18af264667211e7d9dea97dcb71306c901feb3f32ee7a7012dfa1a66b8ddac746ceaab972529c32d9fc19e331893296f9938c7249173ba
 DIST python-phonenumbers-8.13.0.gh.tar.gz 4907144 BLAKE2B 8441eb3bae743c92aacd581c0dfbea32d04353dbb6e45a3fd24ed4b9ef2e6a80ee70167b59ad288383cf409bdad73ed9bded6c991b7809d6ff2bbcc68519aab3 SHA512 1f8e78b3fa1418dec1cc89c02a7e8544847f343912be99d2b62aa49250aa0d89d67d27f0f9c40481ef6125872be7cc772de25bdd9ce26df512e7715f4f8281f2
 DIST python-phonenumbers-8.13.1.gh.tar.gz 4906086 BLAKE2B 3287df69f8246d241ee41b7fb71e1d49ed6393715a1bed31a60755e170c74f8a88c4b5a2dfe4dd87fa7e8049cefb930d33fe0821bff34745e18402bcc8a1e424 SHA512 2a3d7ac670db1f20a6409a705f654b7802266d9bc4f562b50beace67bc6af188b685159192c73078009fae787ad5de6bb191a8695d1c1626e2fd564f01c55592
+DIST python-phonenumbers-8.13.2.gh.tar.gz 4906335 BLAKE2B 720489d11d10a8277557688040f7b893ecdffba9269ea78d61f3612d0d3ad87cb1eeae04a113e16bc222c2eefc0f792357d06e83faec527ad990695aa25e3946 SHA512 30a668214e9b6f4fdc50fe604ebaa566a90a93c3bcbad0626c5f834dbc2127e3a38897ab60bf89090118bfadef92538508e7636c370b8069a4d46522df628fea
diff --git a/dev-python/phonenumbers/phonenumbers-8.13.2.ebuild b/dev-python/phonenumbers/phonenumbers-8.13.2.ebuild
new file mode 100644
index 000000000000..99028fc767a1
--- /dev/null
+++ b/dev-python/phonenumbers/phonenumbers-8.13.2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=python-${P}
+DESCRIPTION="Python port of Google's libphonenumber"
+HOMEPAGE="
+	https://github.com/daviddrysdale/python-phonenumbers/
+	https://pypi.org/project/phonenumbers/
+"
+SRC_URI="
+	https://github.com/daviddrysdale/python-phonenumbers/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/python
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( ../README.md )
+
+python_test() {
+	"${EPYTHON}" testwrapper.py -v || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/pytest-asyncio/Manifest b/dev-python/pytest-asyncio/Manifest
index 58cd6a091b2a..6be45977307f 100644
--- a/dev-python/pytest-asyncio/Manifest
+++ b/dev-python/pytest-asyncio/Manifest
@@ -1,2 +1,3 @@
 DIST pytest-asyncio-0.20.1.gh.tar.gz 25425 BLAKE2B 90ab8ebdb854b78b0e910b26ffeab4841f0e6dc122bd8c12fa908a59e125473770bac553a8046be37679222016c204c83d9e01db27f6eca765fb3d9b6461d090 SHA512 994b942bc6452bd3972070d1eee3d88c6680a818ad38d6ed5ffa1faba51473227c838eaf24316c74479e7bb9faaf7fd3cbd1e5a07c2611f0e2eaffe369f75d95
 DIST pytest-asyncio-0.20.2.gh.tar.gz 25876 BLAKE2B 75f948b804cb8945ec6153a5386ec4e2c5e95757c012acb04f9dcc877b109f0af1f9093a242c6d38196014c8da01fe459687d37fd4cb2fbeed2705936a9fba15 SHA512 5d8b4965cea14dec2a2c7f21f6bb1bad6693b93f07b9dab5c880107a944942bd2c3ef38adc0e17b309222a53afa7504f827baf42201c2a0282a266118e3f7eb7
+DIST pytest-asyncio-0.20.3.gh.tar.gz 27695 BLAKE2B 6e6f0d58d0f985cee9dc0b27f886d0b1b4b54ecbf4980c4ac59b420d6e6e5c01d1c6f3c9ed803391910124f19ee3a882c963f10e5f6bab6de6115bfa222c8be2 SHA512 78a6e251db80696d6f62a54c8d6836e2a820f27efdaa848eb1be512a1592d3bd3fb7c7eee46bb2039a317a8d431565614c888f8436fbe0d4eb60534ce4780e90
diff --git a/dev-python/pytest-asyncio/pytest-asyncio-0.20.3.ebuild b/dev-python/pytest-asyncio/pytest-asyncio-0.20.3.ebuild
new file mode 100644
index 000000000000..1ac6b9aa6ccc
--- /dev/null
+++ b/dev-python/pytest-asyncio/pytest-asyncio-0.20.3.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Library for testing asyncio code with pytest"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-asyncio/
+	https://pypi.org/project/pytest-asyncio/
+"
+SRC_URI="
+	https://github.com/pytest-dev/pytest-asyncio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/pytest-5.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-3.64[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+EPYTEST_DESELECT=(
+	# rely on precise warning counts
+	tests/test_pytest_min_version_warning.py
+	tests/modes/test_legacy_mode.py
+	tests/trio/test_fixtures.py::test_strict_mode_ignores_trio_fixtures
+)
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_asyncio.plugin,_hypothesis_pytestplugin,flaky.flaky_pytest_plugin
+	epytest
+}
diff --git a/dev-python/rapidfuzz/Manifest b/dev-python/rapidfuzz/Manifest
index 1191f9c3ca68..c3bb6c54b2e0 100644
--- a/dev-python/rapidfuzz/Manifest
+++ b/dev-python/rapidfuzz/Manifest
@@ -1,2 +1,3 @@
 DIST rapidfuzz-2.13.2.tar.gz 842042 BLAKE2B 35f3554a3a3cf3d02fc9e96b68e4e54bfd17d4df14befc9c17a3e3c3e078f41106bae2bdf5844ac8658af57dfcf6de90c9ccbadb45cb086a297b75d8c0de50fc SHA512 9cbc436f9259008dd911aac0884c222e444145554a6d8eab4761cff701397d62de26e1ac47393c3273fe99b0ee0a92b80cbc5d6683fe3aedd8582e8afc5d7828
 DIST rapidfuzz-2.13.3.tar.gz 840669 BLAKE2B 8589b8ccb6584a38a2580a8063de04bc8eaddec40fd07a6ad483bc794ee643c6223bca9225020090cb9e3bae0766f48b395c1fdd92a45f97b62a43082e1a20e6 SHA512 c390d33d9f44c7a9a2211dee1bda4abfd14959797d4b299905ed41ed1bc7991f9122e0f6d74cef42ad9d747bb5a32752516b58387c3fd8b66fcb05bdd245f8d9
+DIST rapidfuzz-2.13.4.tar.gz 843410 BLAKE2B 91a072f5697bf2e01db71725e94c4fa5c81877d2be5a2b39a57040c5412480e0c568818445f4f4ca13c02a57d8e20483041d177b18d78884a6084c0d2eb4772e SHA512 3ecf50403625a7a07a27631aea4dd3800dc936327e129414dd6cf3d7559aaf08222640ccf19ab5e02c667109e59c829b7b1ccbaa9d3cf5802203ea6d8bc2a738
diff --git a/dev-python/rapidfuzz/rapidfuzz-2.13.4.ebuild b/dev-python/rapidfuzz/rapidfuzz-2.13.4.ebuild
new file mode 100644
index 000000000000..ad742d8fbb94
--- /dev/null
+++ b/dev-python/rapidfuzz/rapidfuzz-2.13.4.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Rapid fuzzy string matching in Python using various string metrics"
+HOMEPAGE="
+	https://github.com/maxbachmann/RapidFuzz/
+	https://pypi.org/project/rapidfuzz/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# all these are header-only libraries
+DEPEND="
+	>=dev-cpp/taskflow-3.0.0
+	>=dev-cpp/rapidfuzz-cpp-1.10.0
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/rapidfuzz_capi[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.16.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+
+	distutils-r1_src_prepare
+
+	export RAPIDFUZZ_BUILD_EXTENSION=1
+}
diff --git a/dev-python/reedsolomon/Manifest b/dev-python/reedsolomon/Manifest
index c2cbce4dc1f5..3c352a15bda8 100644
--- a/dev-python/reedsolomon/Manifest
+++ b/dev-python/reedsolomon/Manifest
@@ -1 +1,2 @@
 DIST reedsolomon-1.5.4.tar.gz 283778 BLAKE2B 5354b8d320db1533469ae1fd706c0412a81bb408675041af5dbf42b42014e4b779b937fa8e3b3d0a5e67e62d9fd7ce9ac519022dd98dbc82a156ee0cda7914ce SHA512 c738f817c8f536ee86e5bcd3de73a4cf6a3e606ba196a359b6c09e7372dba31316ddb8b134d7c335100e4c2ff0158ff07caa35fee9bc20768bde23cd803e274a
+DIST reedsolomon-1.6.0.gh.tar.gz 62527 BLAKE2B 100e0152ca8d05605f961dbddcc41552941356a72b488375cb1237cf45938382abf6bfd439b572a9aed11a12068258027fae0bc867e7577280829779d21f53a3 SHA512 ddf73b0bdc78856d9aa76e7bf3fcb9715b9b7f922c2d72dc4bd13a4d5a233844757e2946ef96c545ab7979bc6b62a1f33286711f927871a6689a269d20a81b44
diff --git a/dev-python/reedsolomon/reedsolomon-1.6.0.ebuild b/dev-python/reedsolomon/reedsolomon-1.6.0.ebuild
new file mode 100644
index 000000000000..94e32fd919cf
--- /dev/null
+++ b/dev-python/reedsolomon/reedsolomon-1.6.0.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Reed Solomon encoder/decoder"
+HOMEPAGE="
+	https://github.com/tomerfiliba/reedsolomon/
+	https://pypi.org/project/reedsolo/
+"
+SRC_URI="
+	https://github.com/tomerfiliba/reedsolomon/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	"${EPYTHON}" tests/test_creedsolo.py || die "creedsolo test failed with ${EPYTHON}"
+	"${EPYTHON}" tests/test_reedsolo.py || die "reedsolo test failed with ${EPYTHON}"
+}
diff --git a/dev-python/sphinx_ansible_theme/Manifest b/dev-python/sphinx_ansible_theme/Manifest
index b49a27c3d206..6ba68e338042 100644
--- a/dev-python/sphinx_ansible_theme/Manifest
+++ b/dev-python/sphinx_ansible_theme/Manifest
@@ -1,2 +1,3 @@
 DIST sphinx-ansible-theme-0.10.0.tar.gz 49377 BLAKE2B 79d373387c2f6c75e2a352bfd169a8224b38cc5e9c75082cf3808e5318cf5be3bafce81d09e88adc8eafd5b1d98d8a20b081c3d076f2e91822a43c21959b0e82 SHA512 c7dab9040983fd946607e8ef2e3193be668fc4ba3d1ab747571297f896618e2300e4e102bacf277b3172da7292a15072c4522295b1d01d697293fb57edffc1ea
+DIST sphinx-ansible-theme-0.10.1.tar.gz 49575 BLAKE2B 605e153739605e85da19022ececaee8884df8d200ee5ce65a0e695e4bd4a305b5997624e18b593a3566b17c2cd9336b961280c7da6758d370a42555321a2de69 SHA512 8e5eada24f536320e3d7bb83138ebc38c1353db6b4cc0c7eaca95078ccb4d645c5e62ce83fe1ba88aa25c13999914d7d93b817eb893d47802eee9cd40cba483d
 DIST sphinx-ansible-theme-0.9.1.tar.gz 34505 BLAKE2B 533e665b30f5aa450e4a2240c55c4992340b9f6ee03d27758bf119dfe2eef987fbd4b98136349af376557d8e9a78e5391a648b9886136995d05410b0c26561f2 SHA512 f78602af8affe7be59988f466cf6a2aa67e174086f338cad855369a7bbee5a76d07bcffa8406dea5a819127b26d69e29b0d90dab38b82524b3e317f9082d0379
diff --git a/dev-python/sphinx_ansible_theme/sphinx_ansible_theme-0.10.1.ebuild b/dev-python/sphinx_ansible_theme/sphinx_ansible_theme-0.10.1.ebuild
new file mode 100644
index 000000000000..40896349a939
--- /dev/null
+++ b/dev-python/sphinx_ansible_theme/sphinx_ansible_theme-0.10.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+MY_PN="${PN//_/-}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A reusable Ansible Sphinx theme"
+HOMEPAGE="
+	https://github.com/ansible-community/sphinx_ansible_theme/
+	https://pypi.org/project/sphinx-ansible-theme/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-7.0.5[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	'dev-python/ansible-pygments' \
+	'dev-python/sphinx-notfound-page'
diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index f7e7c1905807..d4ff9bc79543 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-32.0.0.tar.gz 1121245 BLAKE2B 00cd2bf7f0869f9040134076e93ebb9d7aa56504788484ed0597d024afb74726df64aa2899dc021ba977cc01814e5e2213b46428d969a73d561e0056b5777d84 SHA512 8770a7067439977720916a8221554836c29afcb18f29716dc513c2eb9f5e09d9b7e123bf98dcb70dafb889594c431efb0367187622e5f0561b24e296a3613734
+DIST tempest-33.0.0.tar.gz 1126464 BLAKE2B 14bce9e0baf1878fc30cc5026c7849cda5abc0291706c7cd051827ffb1e15670e653a20ba6c0c898e86a7e1bee498d14139f82887606f5587b7775d18f96595f SHA512 1a34bc81a18121e3be05ab1a2b637aa8bfc41a0a8e11824294c78468762fb5f303ebf9607f5e72aed1cc5b130b26e22bf72c0574472a0de4eca083e899ff6eb0
diff --git a/dev-python/tempest/tempest-33.0.0.ebuild b/dev-python/tempest/tempest-33.0.0.ebuild
new file mode 100644
index 000000000000..9d0858789c72
--- /dev/null
+++ b/dev-python/tempest/tempest-33.0.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="
+	https://pypi.org/project/tempest/
+	https://docs.openstack.org/tempest/latest/
+	https://launchpad.net/tempest/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/defusedxml-0.7.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1
+	local -x OS_TEST_TIMEOUT=300
+	eunittest -b -s tempest/tests -t .
+}
diff --git a/dev-python/tox/tox-4.0.0_rc4.ebuild b/dev-python/tox/tox-4.0.0_rc4.ebuild
index fdfd50d4230b..880f31053fd9 100644
--- a/dev-python/tox/tox-4.0.0_rc4.ebuild
+++ b/dev-python/tox/tox-4.0.0_rc4.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
 
 inherit distutils-r1
 
@@ -49,7 +49,9 @@ BDEPEND="
 		dev-python/pytest-mock[${PYTHON_USEDEP}]
 		>=dev-python/pytest-xdist-3.1[${PYTHON_USEDEP}]
 		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
-		>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.8.2[${PYTHON_USEDEP}]
+		' 'python*')
 	)
 "
 
@@ -72,6 +74,11 @@ python_test() {
 		# requires devpi*
 		tests/test_provision.py
 	)
+	if ! has_version "dev-python/time_machine[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/util/test_spinner.py
+		)
+	fi
 
 	epytest
 }
diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index e65e208b0852..50e009d07ee6 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1,2 +1,3 @@
 DIST translate-3.7.3.gh.tar.gz 1153916 BLAKE2B 476b8ca3fd277f56cc73d8fc8f5adbf9ddb442b404c586627cc91af228ae08bbb87310219c910701de4938cb9977b386d0ed7b503901369a1ac5069664ebbd25 SHA512 ee339300e798fc043b1ac5455366e96bd5dab08306855a84cdcfd6d5176560366c3538810e94b7477704a5d1ed218e5c85f735979f48cd33242791ce1ad39c3b
 DIST translate-3.7.4.gh.tar.gz 1153973 BLAKE2B 55fd5d8f8d9c53d3aabaaece54272650fc412c778cbbc86d83b391946aebb627c7ad3dd8e10d5bc0bd6380f8396fd5c373a47d9323365886a50299f392238b4c SHA512 0eb93712de9fd7324e0e99cd31996694356452df51ac9f081f27f7bf15391e9630d4b042e2af4ca5b06d43d92f35cfd8806f18ad936c293bd08bdd465b09789e
+DIST translate-3.8.0.gh.tar.gz 1155430 BLAKE2B 53b9964373c49d2eaaa11f13c0a80aefef8572077561fbc2666b5c4f2f7b7731cda9ef665b0f077a84237bb7ccc6251b23308c18672d6397b08a6a64e91426bb SHA512 9ebacfa76e16e179cb000e9f60b1f91ddacf70644764d215df43c55876bc684c6e4c2c1d52e2c1aa00c6e757f87167f04ee7dac7ce996c5b9d3d39aff4bb7484
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.8.0.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.8.0.ebuild
new file mode 100644
index 000000000000..5f06cc0d6c6e
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-3.8.0.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/Levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+		# Apparently a change in line wrapping x_x
+		translate/storage/test_cpo.py::TestCPOFile::test_wrap_gettext
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		translate/storage/test_fluent.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index 6c1fbb52b1df..29a97563ae14 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1,2 +1,3 @@
 DIST trimesh-3.15.8.gh.tar.gz 11972365 BLAKE2B 2dd76c5f3c6949b79992dc23a4a80f3fc80c63c08ac7f8c6c11d6b1209b7b23f4843fe0da74528fbec0738bf83d2791260183cca710d2fe046c1bb8ef747c82b SHA512 806a8a10ff86a5198f7dc134f07fa3fd3f84d8e1b10f2d1f8dbc4a5783d2d24474d7c32f0427fd740f2af63d544fc4f3e710f1904cca0412390e6913092b1741
 DIST trimesh-3.16.0.gh.tar.gz 11970053 BLAKE2B 3898dd2fd12fd070bc9a3a10e21bd255b75f7758deb38e0d36314524b4e24b7ada6514865c06677a1db39b1723b918e5ec6dcf491bf0c946c3e22495cf7dcd01 SHA512 7b56a5007614eae8a7cef1a69334ef3b21499572b5bfaa414bd29097a431266e1ec4d7dda540dbf502a57f5b0ce9d3fb3763675821714ac25d924e0d15e22c71
+DIST trimesh-3.17.1.gh.tar.gz 12653345 BLAKE2B df286132ca01e1a7e8c226b7c98ffa0682b9bf2e225c4114c88395611d1a65a02be4395940ad04b67ae3b6909664b46e18e9fd018d892c86f8f5a4fcfe532210 SHA512 8cbf0bedd21c0867c5aa307e9bb8b4e4caff2aabee89cfadfa11513293304caa4b6a5ecce21064b7fa157a2453b58d401eb6010d0ea32bbd5a99c3075f38b826
diff --git a/dev-python/trimesh/trimesh-3.17.1.ebuild b/dev-python/trimesh/trimesh-3.17.1.ebuild
new file mode 100644
index 000000000000..603115d67a75
--- /dev/null
+++ b/dev-python/trimesh/trimesh-3.17.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimsh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	<dev-python/pyglet-2[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	sci-libs/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/mapbox_earcut[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# remove pyinstrument from tests, as only used for profiling
+	sed -e '/pyinstrument/d' -i tests/{regression,corpus,generic}.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# does profiling with pyinstrument
+		tests/test_scenegraph.py::GraphTests::test_shortest_path
+	)
+	epytest -n "$(makeopts_jobs)"
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" sci-libs/scikit-image
+}