Adding metadata

28 files changed, 707 insertions, 31 deletions

diff --git a/dev-python/Faker/Faker-13.6.0.ebuild b/dev-python/Faker/Faker-13.6.0.ebuild
new file mode 100644
index 000000000000..016041bf7170
--- /dev/null
+++ b/dev-python/Faker/Faker-13.6.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="
+	https://github.com/joke2k/faker/
+	https://pypi.org/project/Faker/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	!dev-ruby/faker
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/random2[${PYTHON_USEDEP}]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index c9d6ce8514ba..50166cb66ee7 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -1,3 +1,4 @@
 DIST Faker-13.3.3.tar.gz 1483842 BLAKE2B bf74f1e4d38b7ec5bd81610a462d88a86fec92886e42ad42a6827524d259697fd263a4e357f28abeee3ffe73ebc17fc4ea12082837773cc326ad0a89e117b32e SHA512 ac2dddf662fd8053bacd81fa52560bdf90f7055741648ea25d2cab92066be6efa1ddc29646ece416a408038fda695ff6602c5a655de3734c208864812f9d67cf
 DIST Faker-13.3.5.tar.gz 1484180 BLAKE2B 137c3faad4ccee4a673a45a8f1245a9e0681b64bfa43c5f7caa91ea1e1d797be0b0973aef8b32a4c44a790218509c77cdf9a8ead5dcf87c19a5165b2b2e9b599 SHA512 8cce3b1488ae34a292bbf9cc0373ffd9c47fe29b484bddb51396a1fe63eef0953022d638ea9b4a49148a48a72d56a9d38d342ebd228265ccb34320406ab45453
 DIST Faker-13.4.0.tar.gz 1484289 BLAKE2B 6d3ab8f958a1d51550bec29c28799753db91330cf98a47ba556b41d61459c42e34bb7dda24c71efab4820fc8843b1f0b4e2b41fa59f185a0acb0989b5f8c947c SHA512 29a0da1cd8275b90e3c65bf74874661e9ac1f2029aee1d317ae139e758aff946d0fccc48ace9043d78ba9a9242c431dd79d025f4203816ce3d8c56b394355672
+DIST Faker-13.6.0.tar.gz 1488090 BLAKE2B 9b4485fc97b0c22f9cce298a55e9dd91c05ea9a56514618c1355c420f3ce6beaa599caa51d909803e968ab918c4c841f459da3d06dd78fbfe984d22b323e2cbe SHA512 bcfb49777640f9b605e164b91380aee77206614f055a321b905ead1649219c081254e57ea80045dd692d061e53e69201ad356daaf6727655c87d65b16752c4cc
diff --git a/dev-python/backoff/Manifest b/dev-python/backoff/Manifest
index 07b2a0bf598e..9baef88f5072 100644
--- a/dev-python/backoff/Manifest
+++ b/dev-python/backoff/Manifest
@@ -1,3 +1,4 @@
 DIST backoff-1.11.0.gh.tar.gz 17566 BLAKE2B 4afed5284eb3cbedf54e06fcd89861701613357c672ebabe2611a4bc28c3a6e4539e206cee24bb6a646f7c16c033f16ef56be3b21867aad760b71410749383b7 SHA512 0f5e176bf9d093a72068cf6e55ada8da3e8ec67b85b4fba2d697117dcb3c563a429ff53c5fe17b4a20a8b5ee0420930b789478bd89de5949b628158263413a60
 DIST backoff-1.11.1.gh.tar.gz 17581 BLAKE2B ca940270859ad78cd29d33cfd3c17605f5b42c2c745b7e7a41d53b2d6ef4bee78dd9e8f15c80387da31679aac6d30404c0988013a890ff34bd55e91716c0eff8 SHA512 7ba0e579d2a4a4bb5046ddc0d1f4b5b58ae2969a10a10a3c657e7dd9b8fd0cd6bc56fec18c28c8fb49101521b3840fe31c65e103977ea5f52f3671a07def97d4
 DIST backoff-2.0.0.gh.tar.gz 19327 BLAKE2B a53d97c8f27b05a2cf0fac9d7ffd5c964f7f58c8c1d6957bb495502c4dd2742fb3dc7c9a6e31f9aabc8982d548926a93e23aa1a60bada4cb3ac9f0968647face SHA512 34e37b3ff45e92311e7d040b05783e094cafc5d1d32c7e2cb8ef89cb9c0ca1a7ca2b16ba596c3b1c4a308d1780d790c9b077411eb8d48d6c5c86f2d6ea82f475
+DIST backoff-2.0.1.gh.tar.gz 19356 BLAKE2B 0d4867372763d59cf3d20e15ef5a9d01d314f9862170f55bcbbb5c29eb571dd672d4e0393f6b5b6d84b695264915d6c9a2649637b84a79062d4fe6a37b742cfb SHA512 bcec57466470ab419b04e5bdcad7dd6717fda1e27678a9c0e2cab9ce974d55c2057a73dc488105e71ec9a893acb32a907809a839490ff6442f20d9d3f41436d9
diff --git a/dev-python/backoff/backoff-2.0.1.ebuild b/dev-python/backoff/backoff-2.0.1.ebuild
new file mode 100644
index 000000000000..f275ea10057f
--- /dev/null
+++ b/dev-python/backoff/backoff-2.0.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Function decoration for backoff and retry"
+HOMEPAGE="
+	https://github.com/litl/backoff/
+	https://pypi.org/project/backoff/
+"
+SRC_URI="
+	https://github.com/litl/backoff/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DOCS=( README.rst )
+
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 274d64dd6936..5f916b481a5c 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,3 +2,4 @@ DIST boto3-1.21.42.tar.gz 488786 BLAKE2B eba75a62e2460aeb2ea66641fadb52448314e63
 DIST boto3-1.21.46.tar.gz 491253 BLAKE2B f55d30087e4f29e3d8ba577d798cd4e4c5fe1f710ac172d6684f005047a422855a6fad91aaaac76e3f33260cbac35be81c8177a80bea913283bcbe7bacb3750f SHA512 0d219b1af786583318a078413a3b30999b2aaad985db72eafe2b63f0068996f0d13b7a48464909cc753d5f9098ea583336ef4887839db5375ebdfcedad3dbffa
 DIST boto3-1.22.0.tar.gz 492175 BLAKE2B cce4b21c0f4de7e70b1c9e402d9e19ccda26e7fc6eab07686c378ae8a9a72a7cf3bb3e2927282e21cd167ca395d63e1fbdfb31d385e5e7a2591c48367c80517c SHA512 b4c51a26e95344ec6e4b876d88148c9603ae7807105ffd0564d928f611c278729f00efd38baff4b31154b358b17ae72c6b90698aef9c013b601bc70d543e2ffb
 DIST boto3-1.22.1.tar.gz 493753 BLAKE2B bd58778f89b792b3203b4b8f86edaca2149ebc24399af9ffa090d9c8ccfa812a078e2d6742bafd08197e39e5020da16948fabb685a448b7acf7ce520321c94cd SHA512 0a8d02325331bb2e069fd1f7280a3c57dae8f6a25f6593db8a1c7998f765d2957765a71645a748da891e66d5ccee859d34171fabea08de62e13ee7793c0d7cb5
+DIST boto3-1.22.2.tar.gz 494671 BLAKE2B c9b72c6a4b667772147235c5791ac4d08adb9e4bd690ea9e369ce712fd705dcc89b2fea4f5b2c580702cc4eb5064b3e46f1237de15e5dd812e2b88c54144d665 SHA512 ecf5d77fb5128a79001a0ccf2e141197d23c0a24d61517e191058de24498d63b13e351fb8e0bfe28f1c58c676d44b2e7f98bd80c41a2510c61d737e086c1010b
diff --git a/dev-python/boto3/boto3-1.22.2.ebuild b/dev-python/boto3/boto3-1.22.2.ebuild
new file mode 100644
index 000000000000..a60384bf1f0d
--- /dev/null
+++ b/dev-python/boto3/boto3-1.22.2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 2c3cd9394268..d88a90c6f505 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,3 +2,4 @@ DIST botocore-1.24.42.tar.gz 8907476 BLAKE2B 11cdce9d9c69835b1e57757d67d561f2493
 DIST botocore-1.24.46.tar.gz 8922345 BLAKE2B f9caf235e902be9e4e15e9a570e67cac328eb7e53668e7e12ba8e6caa4c9ed53e22115231d58fdf8d782ff3ab618e5485438dce7c454918a5d53341e5e5967ac SHA512 ccdbd6e6617a68f810c5491f37a6e94ffe015b30dfea8b01c2543b58c81573358b69af702df2fcf3efb7dd2c4b715e86957c4d60b8f0a0a51279e921dfe02993
 DIST botocore-1.25.0.tar.gz 8925642 BLAKE2B 7f7b89e59801564284cd5e22958bb590aeb821c38682c7dd6163fd31b1c181ae67412b3d8cde351a48a63c2e762923d6bb2bb051e9a367468eb77db228e1c3ad SHA512 43f3edcd6868b37933b24486091097dd6dfc51f51773bea3e3cff1fce5eef5f8b3df6d09b8815c858f5c8d7e87e8ed14cf13f236e72c851e4f98d52ad85e4afc
 DIST botocore-1.25.1.tar.gz 8931771 BLAKE2B 6d2ba3c564104e8463ce588a0f9de47d4ecb7397ae03ddd4698b38f18617ab225676925d142ae0805467f860410addfbefbf6eed521d5142b994274c3bde7a06 SHA512 52dff81c0f7064aa1edc15aebf3e326c0b4ba1dc87667c8da6f487b1caa03a5ba3247253994139dab7d40873197d88f94e8545ffc3e2d51f26c14de27b5d6460
+DIST botocore-1.25.2.tar.gz 8947291 BLAKE2B fedf6c61ac2bc43ae6a60f7afb717d319ffd3baf4d6c5849a11279e96901e4968141b916c8d3c46ff007942ffe25fc85e7c8ef5176331e6537446cf349edc52f SHA512 5660e1fc96575dfa7d8c177192783f6edf5689176f6e3ac8c9ec5c85debe7a124297e1e61af5e1a35785346e40deba1ef7a2d8eac52902cda2cffb0327dcb701
diff --git a/dev-python/botocore/botocore-1.25.2.ebuild b/dev-python/botocore/botocore-1.25.2.ebuild
new file mode 100644
index 000000000000..a45a0b69b8f6
--- /dev/null
+++ b/dev-python/botocore/botocore-1.25.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit} \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index cbdd38ddb3fb..cc15e0744a40 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1 +1,2 @@
 DIST hatch-hatchling-v0.22.0.tar.gz 201590 BLAKE2B c75e48a19e10f04d9bb1d09beea0ec6598bded5dc9e595f363a076731b7708bae55169ee780931b548478c16db093053c65e30a5510f7b0136c1d339caf29d39 SHA512 cc532b66752d0494b62fb4ed88c8b7870d5618c991b301f46b644aa90b656cfe842efd2fa96797a6b96015deb3468ff8ff69058bd146133360de340d367a5489
+DIST hatch-hatchling-v0.23.0.tar.gz 212046 BLAKE2B 8cc73c68bc476cd282686dc69314fd401f5aac4d5d5df083a338aaf59125988aabc9d33f97ad556013d46886d43facef92e7951e7b0a7bc3fc1ab608a16fca11 SHA512 0666b95e68fcd6fbcdeda5fdce577a1178ca8a965226c58495cfc2699bac2aabe3f3bc162e8bb5b03c9c70ff7aa678be6aba5c343dd787600d2f5ee883685444
diff --git a/dev-python/hatchling/hatchling-0.23.0.ebuild b/dev-python/hatchling/hatchling-0.23.0.ebuild
new file mode 100644
index 000000000000..be90cb841b42
--- /dev/null
+++ b/dev-python/hatchling/hatchling-0.23.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/ofek/hatch/
+"
+SRC_URI="
+	https://github.com/ofek/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~hppa ~ia64 ~m68k ~ppc ~riscv ~s390 ~sparc"
+
+RDEPEND="
+	>=dev-python/editables-0.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/atomicwrites[${PYTHON_USEDEP}]
+		dev-python/click[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/platformdirs[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+		dev-python/tomli-w[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	# TODO: remove this when gpep517 is the norm
+	local -x PYTHONPATH=src
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	epytest tests/backend
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 94e19d570f31..e180fae18390 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -2,3 +2,4 @@ DIST hypothesis-python-6.42.3.tar.gz 9187948 BLAKE2B 3303cea4e8f2776f14defd88dcc
 DIST hypothesis-python-6.43.3.tar.gz 9189636 BLAKE2B d47e4b5f3016e32c8ba547eca7f3b6513609d6a84cf1f1b8db5e14282e75cf4ee1778fba1dcf801fac135a1ebfef2ce5f9306bd9be4c33f02b5f05d1690abba2 SHA512 1988efc630b63a2373f25813bd066a1da8576416a167d487f1b262825c49864ab622e84a6189d5016f8ca28b37819d5f035bc11779f906a447baf2f957fedfcc
 DIST hypothesis-python-6.44.0.tar.gz 9189825 BLAKE2B f6688f55a920b0dc65beab54d715c98869bf70d29ed4044f4ad15c88cb9b60cc5dee834f9d218e15d6cc9e02a8b25114660af2578ab07c9a353124cb95611e22 SHA512 8642d078f2e7e232baa100075dac530e4e7c358f8ea7bdb5fd1f3d29ceb291a1a00abfdd25596669010c230893c7d6fc29cc54be42340aabc2481a612e616684
 DIST hypothesis-python-6.45.0.tar.gz 9191348 BLAKE2B e607b21f0e24daec57b19be5e8c1b77c9d78abb724cd5b89dc7dff1351a066387f990d0d92bded39ccb4da4368c3b827a6f3117a24c251d8955be98d8338ba3a SHA512 01e4aea5ce71c476fbee52182ff07529126744eb8bb603175370d33d2e1ce49a367ef2c0ec7abf879ed2bfa25a31e1b2136e2b79bc68d4a4c200cc3159583c6c
+DIST hypothesis-python-6.45.1.tar.gz 9190980 BLAKE2B 61365d27603383cb76d62a0f0f4ca01ac09c779d90b8f028709fedb20dccabb8bb3d452d7bf87926a8bc30c334387378e1cc8e2b42c9bfa8834577e01b34d635 SHA512 a68eaf4b5012735027aba70eae8c244747a676e345b5ab6c6f7e08cab58ce3330410eba5eaa1ded89d1e15386bf644d3df9012b382d675e967781cd7b762fb21
diff --git a/dev-python/hypothesis/hypothesis-6.45.1.ebuild b/dev-python/hypothesis/hypothesis-6.45.1.ebuild
new file mode 100644
index 000000000000..d09b69112221
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.45.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' python3_{8..10})
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+	epytest tests/cover tests/pytest tests/quality \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" python3.{8..10}; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/jc/Manifest b/dev-python/jc/Manifest
index d9396f17105e..8b48e44911db 100644
--- a/dev-python/jc/Manifest
+++ b/dev-python/jc/Manifest
@@ -1,3 +1,2 @@
-DIST jc-1.18.5.tar.gz 3981643 BLAKE2B 9eebaef4e2ee0a014df5fa73f0fecf9d91c62483594d529d6ae9b1d538ee4c62ec1ab6f673f0f3fbb32220920c843e8fd6a487ecaaa9662b63128ff9df786dcc SHA512 f105aa3aa6e5059d06976d089f52eb9c8a1005e2b2c0b9ee2b4229e2f82028277a45979d34a6f81679c22472d7a99903711ac6946accdb86c796e790d121112e
-DIST jc-1.18.6.tar.gz 4007477 BLAKE2B 9380e8a254df921983f486d8d9d0e8479e477e391075ace3fcaa40029f72b733abd6d55ed62f4cd436bb280fa37d9bdec6398418e24c714caa833fcef2991d35 SHA512 ae291ea271e12cebd1e0287cdc8e3f52c72959711d9da752880a1a90257b3add23c6a4b97d34ee0ebfa2332e355b90f8388cd425d18f03aa37c4979765101086
 DIST jc-1.18.7.tar.gz 8106032 BLAKE2B 05c069d0c00c1c789d253419dfc1e2caee656a848618b761664e7d46f87705f945955164c4fc213f7e8f19840b529d02ab52bc439384db122f3d464226c2b4b4 SHA512 c5ce538d4565f29a0d5fb1e39eda80a84481ad74c7ea4ce9339ec7881f2888a105af5c77c8adaf0b6174830e2f7cd1bf9628e5b9bb87d9c7b17e567251645ca9
+DIST jc-1.18.8.tar.gz 8103065 BLAKE2B 77713dda97a4228ed4715f123f2b8c1609496767aabcd38b0e80981959af5308b4296b0e1a76afed42f57517d2dadc773b00e8877324f2e1473f9f4457ea7dfd SHA512 2ed8d6946bc2230f4caaf3ef4fcf80ebb64d1fb5e3d42fddbd306bd84b6f4d4e3e84213ae479267293adb4defb443cb94828f55c74c82782eab8b4b192f792c7
diff --git a/dev-python/jc/jc-1.18.6.ebuild b/dev-python/jc/jc-1.18.6.ebuild
deleted file mode 100644
index 6c748171405c..000000000000
--- a/dev-python/jc/jc-1.18.6.ebuild
+++ /dev/null
@@ -1,26 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-
-inherit distutils-r1
-
-DESCRIPTION="Converts the output of popular command-line tools and file-types to JSON"
-HOMEPAGE="https://github.com/kellyjonbrazil/jc"
-SRC_URI="
-	https://github.com/kellyjonbrazil/jc/archive/v${PV}.tar.gz
-		-> ${P}.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc64"
-
-RDEPEND="dev-python/pygments[${PYTHON_USEDEP}]
-	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
-	dev-python/xmltodict[${PYTHON_USEDEP}]"
-
-distutils_enable_tests unittest
diff --git a/dev-python/jc/jc-1.18.5.ebuild b/dev-python/jc/jc-1.18.8.ebuild
index 6c748171405c..920b1626be60 100644
--- a/dev-python/jc/jc-1.18.5.ebuild
+++ b/dev-python/jc/jc-1.18.8.ebuild
@@ -9,7 +9,10 @@ PYTHON_COMPAT=( python3_{7,8,9,10} )
 inherit distutils-r1
 
 DESCRIPTION="Converts the output of popular command-line tools and file-types to JSON"
-HOMEPAGE="https://github.com/kellyjonbrazil/jc"
+HOMEPAGE="
+	https://github.com/kellyjonbrazil/jc/
+	https://pypi.org/project/jc/
+"
 SRC_URI="
 	https://github.com/kellyjonbrazil/jc/archive/v${PV}.tar.gz
 		-> ${P}.tar.gz
@@ -19,8 +22,10 @@ LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~amd64 ~ppc64"
 
-RDEPEND="dev-python/pygments[${PYTHON_USEDEP}]
+RDEPEND="
+	dev-python/pygments[${PYTHON_USEDEP}]
 	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
-	dev-python/xmltodict[${PYTHON_USEDEP}]"
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+"
 
 distutils_enable_tests unittest
diff --git a/dev-python/jupyter_server/Manifest b/dev-python/jupyter_server/Manifest
index 29195d5de682..a8eecff20a45 100644
--- a/dev-python/jupyter_server/Manifest
+++ b/dev-python/jupyter_server/Manifest
@@ -1 +1,2 @@
 DIST jupyter_server-1.15.6.tar.gz 440539 BLAKE2B 11a090495fa9cf8fd59bc7c1b1149bb16e1e2e0b78a54e0ba827e5012fcc5910d90498c572c1f96cd4c73b5232f0e91c23f4296bddc7e63b006df034ad8fde3d SHA512 b967165c5509e724cb75dfbad0647e7c69fb4fa981bffd3475d480264c52de3d58e2504b01d7096091579dc065646eda11554c2b1ba9d5b6bc840cbcfb484f53
+DIST jupyter_server-1.17.0.tar.gz 445648 BLAKE2B d7e19804b6b4cccb72c0a24febe8702829c2a32768e916a9da09ee9f55a08e360cf2a81c3c4bc535ff342c916155bc0b7933a9b5b49645db2b5f9a58ec02ab3a SHA512 d99d4036698d6f8d5e1258de214e3cbc6239b978314af4af7e722789c950edb1f261b98e666cffb46efdfe97a23c001784cfd29d7bf75c02dae53c2c07476b7f
diff --git a/dev-python/jupyter_server/jupyter_server-1.17.0.ebuild b/dev-python/jupyter_server/jupyter_server-1.17.0.ebuild
new file mode 100644
index 000000000000..bf45a2b4a1cf
--- /dev/null
+++ b/dev-python/jupyter_server/jupyter_server-1.17.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=jupyter
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+	<dev-python/anyio-4[${PYTHON_USEDEP}]
+	dev-python/argon2-cffi[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_core-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-6.4.4[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.2.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/prometheus_client[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1[${PYTHON_USEDEP}]
+	dev-python/websocket-client[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	dev-python/pydata-sphinx-theme \
+	dev-python/myst_parser \
+	dev-python/ipython \
+	dev-python/sphinxemoji \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/sphinxcontrib-openapi
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# This fails if your terminal is zsh (and maybe other non-bash as well?)
+	tests/test_terminal.py::test_culling
+	tests/test_terminal.py::test_terminal_create_with_cwd
+	tests/test_terminal.py::test_terminal_create_with_relative_cwd
+)
+
+src_prepare() {
+	# disable npm use
+	sed -i -e '/\[tool\.jupyter-packaging\.builder\]/,+1d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest \
+		-p pytest_tornasync.plugin \
+		-p jupyter_server.pytest_plugin \
+		-p pytest_console_scripts \
+		-p pytest_timeout
+}
diff --git a/dev-python/markdown2/Manifest b/dev-python/markdown2/Manifest
index 7d15892592d3..d395bec808b3 100644
--- a/dev-python/markdown2/Manifest
+++ b/dev-python/markdown2/Manifest
@@ -1 +1,2 @@
 DIST markdown2-2.4.2.tar.gz 96270 BLAKE2B 63808f2b6e8af25eca047e7b24a7ab7ce7afc35fa10aff57b93952cefae765ae8746300f6e93033be87aa73607249198cdfd4fa6e3b3aed711e80d9dc7a006ab SHA512 8c41617213ae8a2d02a986489756d511ee7e1ae970eef348f68808439feaef099ef935ea0a2c31cb9e9abe39899a24fd981a29b7c90d1f8096ba999506121e60
+DIST markdown2-2.4.3.tar.gz 102973 BLAKE2B 7a856a9d0bd539e3de1e358aa7d4968aca62b67a30dc64a905633040a6a525b2ac1ec0d4cd7d8d4ed9b38e68e5df3f187cf0f56e1816a4ec10efe4e849356580 SHA512 b5eb5cb6ac52878a224aa6b4642ade86593de5340594271940b3ef25809a9e37b9b3cbb04f4fa9880a50a4fee8ed85c1c6d76b19065b0fd703363faf4d812679
diff --git a/dev-python/markdown2/markdown2-2.4.3.ebuild b/dev-python/markdown2/markdown2-2.4.3.ebuild
new file mode 100644
index 000000000000..df3369a7a31b
--- /dev/null
+++ b/dev-python/markdown2/markdown2-2.4.3.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python Markdown language reimplementation"
+HOMEPAGE="
+	https://github.com/trentm/python-markdown2/
+	https://pypi.org/project/markdown2/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	cd test || die
+	"${EPYTHON}" -m unittest test_markdown2.py -v ||
+		die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/mypy/Manifest b/dev-python/mypy/Manifest
index 4437c142098e..c43416443d74 100644
--- a/dev-python/mypy/Manifest
+++ b/dev-python/mypy/Manifest
@@ -5,3 +5,4 @@ DIST mypy-0.931.tar.gz 2779826 BLAKE2B 11986102c6bc498a23bae52002e6ac515fa03724e
 DIST mypy-0.940.tar.gz 2700469 BLAKE2B 4ac13002c3752566ade30a720c4de56d600552221c42f930af54a68573e6b5eb10de90ce66e2cd42f9eb419d5d09e354e4bf2d09cbcf0d6b841ab0e6710d7058 SHA512 5131ea3fe8d96f12442c68dddf04261582a063dcdd031804276263949af9f9af967be3dd775868d289709987773e1911f33e1f43951389f93cabf91c771e271f
 DIST mypy-0.941.tar.gz 2700297 BLAKE2B 1d0369336b82c167dc25da8bcc21817b351a65a2543727f08c2e14aa15a75fec21b0937eb09b8060b405c09703b8052d4ed2df65d6e27f5dd429998b110a9e35 SHA512 39ef6e0d9215f0f530ca572d3b701a877f9b968034c2ca5a04549bf6a337a8d3609c23bc45bf45b16209128d26ab2b74bca27ecbdc5de53581429b47fb348aa8
 DIST mypy-0.942.tar.gz 2701940 BLAKE2B 5501466e57b4afb8825e6c804cbdc270c79ff457c39f2e5834f4b68df70263c05b2b9abb08fe58202ee65f5e22d2291f39fcb1fc47168416134538c5f6e12ab3 SHA512 79b83587eefad10d7d20d3bfd8484a9e8b2d363e68c1e5ffaa3a82ca8b8f8d9183036ea46695a634f9156911d6f918af684ac636105b37b3a5d0e958f5d661f4
+DIST mypy-0.950.tar.gz 2746164 BLAKE2B 8466012fd3622f5e730acef774115ac84ff8c6f5488213a450de63d5acc790f937b7c69a1b05b46deef6fe8f81a13ed8e85f83c6c22cce9abdbb73b2ecf4179c SHA512 949d1dade3f225bbef0934fff040f7d5aec47039f554a669ca491d6cb46d56de3fcae0186864cdcaf5dec1347bc3af453218520536a0afa77e89a5c0e4640500
diff --git a/dev-python/mypy/mypy-0.950.ebuild b/dev-python/mypy/mypy-0.950.ebuild
new file mode 100644
index 000000000000..37f645d84b9b
--- /dev/null
+++ b/dev-python/mypy/mypy-0.950.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Optional static typing for Python"
+HOMEPAGE="http://www.mypy-lang.org/"
+SRC_URI="https://github.com/python/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# stubgen collides with this package: https://bugs.gentoo.org/585594
+RDEPEND="
+	!dev-util/stubgen
+	>=dev-python/psutil-4[${PYTHON_USEDEP}]
+	>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/typed-ast-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.7.4[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	<dev-python/mypy_extensions-0.5.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-python/attrs-18.0[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-1.18[${PYTHON_USEDEP}]
+		>=dev-python/py-1.5.2[${PYTHON_USEDEP}]
+		>=dev-python/typed-ast-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+# this requires packaging a lot of type stubs
+export MYPY_USE_MYPYC=0
+
+python_test() {
+	# Some mypy/test/testcmdline.py::PythonCmdlineSuite tests
+	# fail with high COLUMNS values
+	local -x COLUMNS=80
+	epytest -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index db024b0c6c4a..02910c6154d0 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo.utils-4.12.2.tar.gz 101505 BLAKE2B fb2d56c767e8ed100ba789560e6b50dfecf8528de2a2717a9660e3dc8ceb93838137d59f1c2e3f05ccb99b95ea1ec86870e22160fb670a8cfb2dd9d6783f1d0f SHA512 fa56225f1991b031e2122cf08cd0992d8a9bfacd9a83d590f87ff86c495d51763ac06f65076c746a59563a60f886601d00ea9536dfcc927fca94c5a1431bcf67
+DIST oslo.utils-4.13.0.tar.gz 101834 BLAKE2B 9d3457ee9ce1746869120bf66d83495b4e1f2b4ca005285fa121ff4c176e85148662cd1de52bdaf93dc18d85478f2cbfde9b310e748b895f01c77ef82019dc0e SHA512 1d97fdaab79cc6c4cc34efdafca7263a2679e60d446aadc46fe31d7fdda2051b37f9df79d149644d914c7274e7fa2d9ef6a1c1aeafad8a1333221dcbe65f4723
diff --git a/dev-python/oslo-utils/oslo-utils-4.13.0.ebuild b/dev-python/oslo-utils/oslo-utils-4.13.0.ebuild
new file mode 100644
index 000000000000..83b8932b6701
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-4.13.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${PN::1}/${PN/-/.}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.2.0[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/eventlet-0.23.0[${PYTHON_USEDEP}]
+		' python3_{8..9})
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# spurious rdep
+	sed -i -e '/pbr/d' requirements.txt || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	if ! has "${EPYTHON}" python3.{8..9}; then
+		find "${BUILD_DIR}"/install -name '*eventletutils*.py' -delete || die
+	fi
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	eunittest
+}
diff --git a/dev-python/pbr/pbr-5.8.0.ebuild b/dev-python/pbr/pbr-5.8.0-r1.ebuild
index 059fd5c5a968..f657d79f2afd 100644
--- a/dev-python/pbr/pbr-5.8.0.ebuild
+++ b/dev-python/pbr/pbr-5.8.0-r1.ebuild
@@ -15,6 +15,9 @@ LICENSE="Apache-2.0"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux"
 
+RDEPEND="
+	>=dev-python/setuptools-60.5.0[${PYTHON_USEDEP}]
+"
 # git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and https://bugs.gentoo.org/show_bug.cgi?id=561038
 # docutils is needed for sphinx exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848
 # stestr is run as external tool
diff --git a/dev-python/pydispatcher/pydispatcher-2.1.2-r1.ebuild b/dev-python/pydispatcher/pydispatcher-2.1.2-r1.ebuild
new file mode 100644
index 000000000000..392810a2469d
--- /dev/null
+++ b/dev-python/pydispatcher/pydispatcher-2.1.2-r1.ebuild
@@ -0,0 +1,20 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit distutils-r1
+
+MY_P="PyPyDispatcher-${PV}"
+DESCRIPTION="Multi-producer-multi-consumer signal dispatching mechanism"
+HOMEPAGE="https://github.com/scrapy/pypydispatcher https://pypi.org/project/PyPyDispatcher/"
+SRC_URI="mirror://pypi/${MY_P::1}/${MY_P%-*}/${MY_P}.tar.gz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~x86"
+
+distutils_enable_tests unittest
diff --git a/dev-python/python-engineio/python-engineio-4.3.2-r1.ebuild b/dev-python/python-engineio/python-engineio-4.3.2-r1.ebuild
new file mode 100644
index 000000000000..bb7f108a9ccb
--- /dev/null
+++ b/dev-python/python-engineio/python-engineio-4.3.2-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Python implementation of the Engine.IO realtime server"
+HOMEPAGE="
+	https://python-engineio.readthedocs.io/
+	https://github.com/miguelgrinberg/python-engineio/
+	https://pypi.org/project/python-engineio/"
+SRC_URI="
+	https://github.com/miguelgrinberg/python-engineio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+# Can use eventlet, werkzeug, or gevent, but no tests for werkzeug
+# eventlet doesn't yet support Python 3.10, so let's work around it
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/eventlet[${PYTHON_USEDEP}]
+		' python3_{8,9} )
+
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/websockets[${PYTHON_USEDEP}]
+		www-servers/tornado[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Both want websocket (server) which isn't strictly required and fails
+	# because it can't find it. Think it needs right provider depending on
+	# whether it chose gevent/eventlet/werkzeug. Not worth the effort.
+	tests/common/test_server.py::TestServer::test_connect
+	tests/common/test_server.py::TestServer::test_upgrades
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+python_test() {
+	if [[ ${EPYTHON} != python3.8 && ${EPYTHON} != python3.9 ]] ; then
+		EPYTEST_IGNORE+=(
+			tests/common/test_async_eventlet.py
+		)
+
+		EPYTEST_DESELECT+=(
+			tests/common/test_server.py::TestServer::test_async_mode_eventlet
+		)
+	fi
+
+	epytest
+}
diff --git a/dev-python/python-slugify/Manifest b/dev-python/python-slugify/Manifest
index f8d03acf9caf..1d39ebf8161d 100644
--- a/dev-python/python-slugify/Manifest
+++ b/dev-python/python-slugify/Manifest
@@ -1 +1,2 @@
 DIST python-slugify-6.1.1.tar.gz 13259 BLAKE2B 2f85061775d9e921bf5679ab47d9a5b4fed2d2e1703aa2717e21c1d43fd1b93ef5d7060151bb4b473cd901aef16d3d905d2ca5004ae7bc61e906464bb52494a2 SHA512 2ffe8420b2f0504c57f42bf20aa0145ae521dab8d1bbefcaff1a815aa04377c7eb48eab929890915a9c9632a5c1cac4d3e7e093dcdfdda59f8ecee1ab787cbb7
+DIST python-slugify-6.1.2.tar.gz 13302 BLAKE2B 600ac1cc37cd0001ca3c08cdccb4655dd3754f7673596eada2dfb6adcb6c190f0e5644bd1cba4debf0fae42ae183b3d81acdcc09270e3ade94076d69ba25895a SHA512 3748c18d469032fc002318fbd5730b96a6f8430ff7b0b1a9afb4c19d4dd8e7528400682fa6b2fcc11ec4230917d7e7f61de290f5b199935d77d5335006af0ffb
diff --git a/dev-python/python-slugify/python-slugify-6.1.2.ebuild b/dev-python/python-slugify/python-slugify-6.1.2.ebuild
new file mode 100644
index 000000000000..c9a5bb68fbb8
--- /dev/null
+++ b/dev-python/python-slugify/python-slugify-6.1.2.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python Slugify application that handles Unicode"
+HOMEPAGE="
+	https://github.com/un33k/python-slugify/
+	https://pypi.org/project/python-slugify/
+"
+SRC_URI="
+	https://github.com/un33k/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/text-unidecode[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest