Adding metadata

32 files changed, 778 insertions, 9 deletions

diff --git a/dev-python/ansi2html/ansi2html-1.7.0.ebuild b/dev-python/ansi2html/ansi2html-1.7.0.ebuild
index ea9060bced14..f432ef433dbd 100644
--- a/dev-python/ansi2html/ansi2html-1.7.0.ebuild
+++ b/dev-python/ansi2html/ansi2html-1.7.0.ebuild
@@ -14,7 +14,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="LGPL-3+"
 SLOT="0"
-KEYWORDS="amd64 arm x86"
+KEYWORDS="amd64 arm ~riscv x86"
 IUSE="doc"
 
 RDEPEND=">=dev-python/six-1.7.3[${PYTHON_USEDEP}]"
diff --git a/dev-python/binaryornot/binaryornot-0.4.4-r2.ebuild b/dev-python/binaryornot/binaryornot-0.4.4-r2.ebuild
index ec52e44ff0df..1dd62ad16f32 100644
--- a/dev-python/binaryornot/binaryornot-0.4.4-r2.ebuild
+++ b/dev-python/binaryornot/binaryornot-0.4.4-r2.ebuild
@@ -13,7 +13,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz -> ${P}.r1.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~ppc64 x86"
+KEYWORDS="amd64 ~ppc64 ~riscv x86"
 
 RDEPEND=">=dev-python/chardet-3.0.2[${PYTHON_USEDEP}]"
 BDEPEND="test? ( dev-python/hypothesis[${PYTHON_USEDEP}] )"
diff --git a/dev-python/chardet/Manifest b/dev-python/chardet/Manifest
index ed73b3a9c79e..c5b951920846 100644
--- a/dev-python/chardet/Manifest
+++ b/dev-python/chardet/Manifest
@@ -1 +1,2 @@
 DIST chardet-4.0.0.tar.gz 1923933 BLAKE2B 10dce34cbe6f01536a526931510ed625bc5062335e9419e24c9e48d5697ebbe70dcc54ffaa976ec153340cc74c3086627a3b1dd9e34be32c89a9a81e83fd70d0 SHA512 cb0e052fdd9fec251ebc6eb3f31ca95ece017f2bfa99122997f989286988058ed9688e49d00631c63d8e4e52da1050e23f02b28d0e739aee7302b24c8808370e
+DIST chardet-5.0.0.gh.tar.gz 2016879 BLAKE2B 006992a4945840b3720e93f932618cf81debc094a3ae353bfdd4e56ecdc5a01e4a250bed15473d8d59108978fdbfb769081a9b87f672d35f4892d5ba04c2deb5 SHA512 d19413a4f1f571f3627ec3f55dcc6a69497f6a1d72fe972051713f4d7a473cd539cfbce2eb2c7a070295aa640c6ac2aec6fc0064751e465311935c0e4d88061a
diff --git a/dev-python/chardet/chardet-5.0.0.ebuild b/dev-python/chardet/chardet-5.0.0.ebuild
new file mode 100644
index 000000000000..242b6c45364b
--- /dev/null
+++ b/dev-python/chardet/chardet-5.0.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Universal encoding detector"
+HOMEPAGE="
+	https://github.com/chardet/chardet/
+	https://pypi.org/project/chardet/
+"
+SRC_URI="
+	https://github.com/chardet/chardet/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# super flaky test
+	# https://github.com/chardet/chardet/issues/256
+	test.py::test_detect_all_and_detect_one_should_agree
+)
diff --git a/dev-python/clang-python/Manifest b/dev-python/clang-python/Manifest
index 2f34b5a97122..fed0786bf224 100644
--- a/dev-python/clang-python/Manifest
+++ b/dev-python/clang-python/Manifest
@@ -1,5 +1,7 @@
 DIST llvm-project-14.0.5.src.tar.xz 105617748 BLAKE2B a68a6eb58302702f560d1204eb97d34b695eb5df417ccefb50117dbd641ba3c3dda9e64c04506e646dd40c1151eb60b12843e206996ef74b35b2841b8dabafda SHA512 db5a7ea1149988c2aab4ed634f14e00bb9a8042089350b811f875e295ced7b5add80a11b91cad80ba0ba9801261502644a720021506483c14dfb1bc24a7f54d5
 DIST llvm-project-14.0.5.src.tar.xz.sig 566 BLAKE2B ecf66df5d0acb382c9d441aee053404254fa4087d57130b04bb496af9cbb71c59e82f0938f44953d7fd777524781d13d1327b6c64065cf45b177bc3ea0e5c3f2 SHA512 a785e38f11863a46de8766ff4495a73173479cdbd95dc539804b0381a7a834a409713dbaf441272a9cc2963a3c7015c95dc6f0dcfa745e8d6047b1ad5feacff7
+DIST llvm-project-14.0.6.src.tar.xz 105618228 BLAKE2B ee67c5407df8cef493b9c0004f15e428f22a536a17e5f4e3eb29a003b8a8ec0abe0fa3e072591161d5f30ef7d8867c1ce34d1b341ad858e93c00263499941a99 SHA512 6fc6eeb60fac698702d1aac495fc0161eb7216a1f8db2020af8fccec5837831f7cc20dc2a169bf4f0b5f520748280b4a86621f3697d622aa58faaa45dbfaad13
+DIST llvm-project-14.0.6.src.tar.xz.sig 566 BLAKE2B cb658ad43d8ab6c43a5773aedadf0569c97b5ee4b1bd58eceb10e1879a30880c741c3d66bedd462c892309b688fb7b2673115a62d1f74d71ee375a578de9547f SHA512 b4a7b368532a7a4a24376cfa7db8f6d3478f6d4446474342fc00b474ecf466330cd0f16783209263c4c72d5fc7ddedfb11b95578842e700cfb7ee0bb34cc95d6
 DIST llvmorg-12.0.1.tar.gz 134259748 BLAKE2B f41de787bc73ff2edfda1b22cc8602be6f65f37dd9e4c8888533cfa8c3ccdcf4f108aaab9de23ab0ab987966eb160f2a553a0bdff99461e71ddd5bfcd086090d SHA512 6eb0dc18e2c25935fabfdfc48b0114be0939158dfdef7b85b395fe2e71042672446af0e68750aae003c9847d10d1f63316fe95d3df738d18f249174292b1b9e1
 DIST llvmorg-13.0.1.tar.gz 147290251 BLAKE2B 2a44b012a672501761d0c27c6b3a315b69bfef0cd13b078a7e7d2fccc4a9c8c0f2bee0f164c4271c9106b0a99cb06e8b64986f66253b613336719fb86b82541b SHA512 9a8cb5d11964ba88b7624f19ec861fb28701f23956ea3c92f6ac644332d5f41fde97bd8933dd3ee70ed378058c252fa3a3887c8d1af90d219970c2b27691166f
 DIST llvmorg-14.0.1.tar.gz 158074615 BLAKE2B bf80366461580058494eb101646efcd1a8b55a66818a710c2eb8c649bf88c02fe4552cecf4c1c8637a64e7cee8d644bca31aafc804765ed18f2b5e2975dd6c92 SHA512 0a15aa9cfc978a7b03a1659a2affad65ede66d280f5c12bf0beaaf194cd7bdd57ff438b5f40e64c1e1b88f368de99be349e9d30b544d2bbe4a50f0ebed3307f2
diff --git a/dev-python/clang-python/clang-python-14.0.6.ebuild b/dev-python/clang-python/clang-python-14.0.6.ebuild
new file mode 100644
index 000000000000..e347899e1291
--- /dev/null
+++ b/dev-python/clang-python/clang-python-14.0.6.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+DEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/click-help-colors/click-help-colors-0.9.1.ebuild b/dev-python/click-help-colors/click-help-colors-0.9.1.ebuild
index a55a1147baa5..f4bd619dfc5c 100644
--- a/dev-python/click-help-colors/click-help-colors-0.9.1.ebuild
+++ b/dev-python/click-help-colors/click-help-colors-0.9.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -14,7 +14,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~riscv"
 IUSE="examples"
 
 RDEPEND="dev-python/click[${PYTHON_USEDEP}]"
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index adc57809455b..3eb0205eabd6 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -3,4 +3,5 @@ DIST hypothesis-hypothesis-python-6.47.1.gh.tar.gz 9314265 BLAKE2B c2ad0120ab2cb
 DIST hypothesis-hypothesis-python-6.47.2.gh.tar.gz 9314053 BLAKE2B df607e7d81a280d916cc3946c71f6b2a6c7004263069e83d2647222730d11276b6c246fedbb07c5a4f3c526df38d6ea5c7999bdb416f0c86b0877d0231418c73 SHA512 b58835fac221353ea9beff227dda81f7776e2b50f6a765e536c83bea129d5c5a862551423d9df5abbc0cf294b358c6c537c62add69b3d5a1f38b22e179d2f83c
 DIST hypothesis-hypothesis-python-6.47.3.gh.tar.gz 9314739 BLAKE2B 282b012e020fc6494b628ba629c576f604db831c219878ab92539fbd1d980f3363e490ef35f888b68902661dd82e682393641d13a882c1177d8570ec232b217a SHA512 c7231ff06ae5846f718e76c48ed4bb8a1fc0f9aff80c7ddd1ff0ead219eb93dcc7f9d5c5e591390661e81a33bcac79773ea620cfe3f246210114635f0c089144
 DIST hypothesis-hypothesis-python-6.47.4.gh.tar.gz 9314838 BLAKE2B 183048d7d784f8e64bcac1f5bb53b6b9f945b38d555aebd84d0966bcf64178e952f767dcf63122d9b3e8d41d79034b4b11074335e5dbb7575b5f78e152d05c25 SHA512 17a7388ac03ea9029bc5a90f24aa85c3f825bd04ceee963ff7f144ff675b0465afdd22edc5608931f1fd60e83c59d10be24dd74ed64015f942c3f09956b652d7
+DIST hypothesis-hypothesis-python-6.47.5.gh.tar.gz 9315253 BLAKE2B f1b9829c2b0ba7f82dd49289feaf22100901674e0f394520c3c8d43d2eaab77669cc9d8f355455c1ea23210a17786c8ee6e982d7ca49067c51571491e3c7f43b SHA512 f08d1ac0237292fb3232e0ba11e81520a16f03d2c266f4d05495ffc3d1e801de7fbceee1973c73311f2b18e0cdc88988a2635968e1dd5c493f6887e5d63812fe
 DIST hypothesis-python-6.46.9.tar.gz 9311955 BLAKE2B f8cf7e216650401ea8a9b427311d10bc65a21b79eb231864c4ff429baea4600f8d84b05e4b94120551ebe17f1b4b99a65e76157efe9d0a133ad68c22b1c46452 SHA512 e4fed5210ba11977958d4d14f9fb32427b812ea7903f391bbf977ade7ae268770e846b0cd2193585f519a02681e4fabfead23eea5bcededaccc0e7a9857e98cf
diff --git a/dev-python/hypothesis/hypothesis-6.47.5.ebuild b/dev-python/hypothesis/hypothesis-6.47.5.ebuild
new file mode 100644
index 000000000000..76ae0a30c4d1
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.47.5.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{8..10} )
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+	epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/importlib_metadata/Manifest b/dev-python/importlib_metadata/Manifest
index 3622acd060d3..1e34e1e16693 100644
--- a/dev-python/importlib_metadata/Manifest
+++ b/dev-python/importlib_metadata/Manifest
@@ -1 +1,2 @@
 DIST importlib_metadata-4.11.4.tar.gz 44160 BLAKE2B 83b39ac858c5d3b63becc19be1a62ce253ce873afba16e5dad085fed531c5dcefa173e1644de10bef6318965aa132331b5d037dd7c0c8a0908880d97764b645e SHA512 2b5a6b0788103f7f0245f172832576852f56316e1c05b32f194a56b5fbaccd987c0315971f7d32d1b225ab74c12dc9f1aa96eb2a9ed2ebfd7613a9b816398560
+DIST importlib_metadata-4.12.0.tar.gz 48153 BLAKE2B b12b61a02be6428f80de418b3932b917066f6e9396d85158f8f31fa1b800c9cbd3f7dfd7cec48b51cc6c4ad5e5532136cc6ad7ea688c70466621976b232d9ccb SHA512 a7e3b8876665880a42bab885014199eed90efafcb386b89fddf62f3a6dbf51b192a0b9d208a40fd1f8b6db9d1bf80cf6d6753c1073196daa54dffa22a627443f
diff --git a/dev-python/importlib_metadata/importlib_metadata-4.12.0.ebuild b/dev-python/importlib_metadata/importlib_metadata-4.12.0.ebuild
new file mode 100644
index 000000000000..9f2607c4bb0d
--- /dev/null
+++ b/dev-python/importlib_metadata/importlib_metadata-4.12.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=flit
+# NB: this package extends beyond built-in importlib stuff in py3.8+
+# new entry_point API not yet included in cpython release
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Read metadata from Python packages"
+HOMEPAGE="https://github.com/python/importlib_metadata"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/importlib_resources[${PYTHON_USEDEP}]
+		' 3.8)
+	)
+"
+
+distutils_enable_tests unittest
+
+src_configure() {
+	grep -q 'build-backend = "setuptools' pyproject.toml ||
+		die "Upstream changed build-backend, recheck"
+	# write a custom pyproject.toml to ease setuptools bootstrap
+	cat > pyproject.toml <<-EOF || die
+		[build-system]
+		requires = ["flit_core >=3.2,<4"]
+		build-backend = "flit_core.buildapi"
+
+		[project]
+		name = "importlib_metadata"
+		version = "${PV}"
+		description = "Read metadata from Python packages"
+	EOF
+}
diff --git a/dev-python/jinja2-time/jinja2-time-0.2.0-r1.ebuild b/dev-python/jinja2-time/jinja2-time-0.2.0-r1.ebuild
index 17737a6499f8..5dc1d7350fa5 100644
--- a/dev-python/jinja2-time/jinja2-time-0.2.0-r1.ebuild
+++ b/dev-python/jinja2-time/jinja2-time-0.2.0-r1.ebuild
@@ -17,7 +17,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~ppc64 x86"
+KEYWORDS="amd64 ~ppc64 ~riscv x86"
 
 RDEPEND="
 	dev-python/arrow[${PYTHON_USEDEP}]
diff --git a/dev-python/lit/Manifest b/dev-python/lit/Manifest
index 2f34b5a97122..fed0786bf224 100644
--- a/dev-python/lit/Manifest
+++ b/dev-python/lit/Manifest
@@ -1,5 +1,7 @@
 DIST llvm-project-14.0.5.src.tar.xz 105617748 BLAKE2B a68a6eb58302702f560d1204eb97d34b695eb5df417ccefb50117dbd641ba3c3dda9e64c04506e646dd40c1151eb60b12843e206996ef74b35b2841b8dabafda SHA512 db5a7ea1149988c2aab4ed634f14e00bb9a8042089350b811f875e295ced7b5add80a11b91cad80ba0ba9801261502644a720021506483c14dfb1bc24a7f54d5
 DIST llvm-project-14.0.5.src.tar.xz.sig 566 BLAKE2B ecf66df5d0acb382c9d441aee053404254fa4087d57130b04bb496af9cbb71c59e82f0938f44953d7fd777524781d13d1327b6c64065cf45b177bc3ea0e5c3f2 SHA512 a785e38f11863a46de8766ff4495a73173479cdbd95dc539804b0381a7a834a409713dbaf441272a9cc2963a3c7015c95dc6f0dcfa745e8d6047b1ad5feacff7
+DIST llvm-project-14.0.6.src.tar.xz 105618228 BLAKE2B ee67c5407df8cef493b9c0004f15e428f22a536a17e5f4e3eb29a003b8a8ec0abe0fa3e072591161d5f30ef7d8867c1ce34d1b341ad858e93c00263499941a99 SHA512 6fc6eeb60fac698702d1aac495fc0161eb7216a1f8db2020af8fccec5837831f7cc20dc2a169bf4f0b5f520748280b4a86621f3697d622aa58faaa45dbfaad13
+DIST llvm-project-14.0.6.src.tar.xz.sig 566 BLAKE2B cb658ad43d8ab6c43a5773aedadf0569c97b5ee4b1bd58eceb10e1879a30880c741c3d66bedd462c892309b688fb7b2673115a62d1f74d71ee375a578de9547f SHA512 b4a7b368532a7a4a24376cfa7db8f6d3478f6d4446474342fc00b474ecf466330cd0f16783209263c4c72d5fc7ddedfb11b95578842e700cfb7ee0bb34cc95d6
 DIST llvmorg-12.0.1.tar.gz 134259748 BLAKE2B f41de787bc73ff2edfda1b22cc8602be6f65f37dd9e4c8888533cfa8c3ccdcf4f108aaab9de23ab0ab987966eb160f2a553a0bdff99461e71ddd5bfcd086090d SHA512 6eb0dc18e2c25935fabfdfc48b0114be0939158dfdef7b85b395fe2e71042672446af0e68750aae003c9847d10d1f63316fe95d3df738d18f249174292b1b9e1
 DIST llvmorg-13.0.1.tar.gz 147290251 BLAKE2B 2a44b012a672501761d0c27c6b3a315b69bfef0cd13b078a7e7d2fccc4a9c8c0f2bee0f164c4271c9106b0a99cb06e8b64986f66253b613336719fb86b82541b SHA512 9a8cb5d11964ba88b7624f19ec861fb28701f23956ea3c92f6ac644332d5f41fde97bd8933dd3ee70ed378058c252fa3a3887c8d1af90d219970c2b27691166f
 DIST llvmorg-14.0.1.tar.gz 158074615 BLAKE2B bf80366461580058494eb101646efcd1a8b55a66818a710c2eb8c649bf88c02fe4552cecf4c1c8637a64e7cee8d644bca31aafc804765ed18f2b5e2975dd6c92 SHA512 0a15aa9cfc978a7b03a1659a2affad65ede66d280f5c12bf0beaaf194cd7bdd57ff438b5f40e64c1e1b88f368de99be349e9d30b544d2bbe4a50f0ebed3307f2
diff --git a/dev-python/lit/lit-14.0.6.ebuild b/dev-python/lit/lit-14.0.6.ebuild
new file mode 100644
index 000000000000..b944deb27c4c
--- /dev/null
+++ b/dev-python/lit/lit-14.0.6.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm
+	)
+"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 8ee0c46b1053..b57aa609dccd 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,3 +1,4 @@
 DIST moto-3.1.12.tar.gz 2323555 BLAKE2B f2ecefc5dbbc3f4ce66a799ec255cad40ce466f62fe3bfb0885866c7d0125884a0fef299b58fdcf1cb5da7ef58ac513d844b2fbae6d6545dcb38f2a3bbb2cda4 SHA512 29b8d0d71f3227784eddd05959434451ad88c9c0346b3684360e57bd3df8b9734f781d263bf992ac946749c88b433f6c86c1fc71d71a2dc565633c812579c297
 DIST moto-3.1.13.tar.gz 2330638 BLAKE2B ded004bcd783f623edd5b198c39b0245bc847233be46e101b8556adf71c8a7495a175957b3c5c475ca66c392df0999f53c8cedbb439cbb39cd5566e610887cc2 SHA512 95708e6638ab9a8d68b1acaf3af14fc381584e2d978d7f03ee500c50cd2b3409d99633f0e211bfb86c40335e67581f9e6ff3dc7934f8e91fc9f8be8311de8b5b
 DIST moto-3.1.14.tar.gz 2340613 BLAKE2B 8bdd9131449c2f3aeb1e4b4fcf40fe2d7ffac86777a73bcdff1d04a3450ec71030e5611c1d3d7429fd57e7ebc0791aecca4c57b8fb12456d18f2256693387fa0 SHA512 3a07e4f15a70ec422f81ba8cf5e2f38624981ff809e7ec51a3e23e26f3dff1755aa11d236daac097da0961948a46cc93e549e36102fbd8d5036f419d5fc96312
+DIST moto-3.1.15.tar.gz 2352817 BLAKE2B 29c756ac5a6bdca2bea4bd74c746756b1621342ce8db7064ca822f78cf9a49cb298c27f74b5ef388c5262217c3fb22b5ae8988de9b3d37422834c6eef85c1b4e SHA512 9d2268e71ef68136e2d43285cb96901e0b6176f59a03183ec6628df8055a636cf80ace1c31446daffb49b7b7a10c1ed6680f0e984654352c67cd0f2cc8ea1a25
diff --git a/dev-python/moto/moto-3.1.15.ebuild b/dev-python/moto/moto-3.1.15.ebuild
new file mode 100644
index 000000000000..60f4306b0f98
--- /dev/null
+++ b/dev-python/moto/moto-3.1.15.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	dev-python/boto[${PYTHON_USEDEP}]
+	dev-python/cfn-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	dev-python/botocore[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.2.8[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+		tests/test_swf/responses/test_decision_tasks.py::test_respond_decision_task_completed_with_schedule_activity_task_boto3
+		tests/test_swf/responses/test_timeouts.py::test_activity_task_heartbeat_timeout_boto3
+		tests/test_swf/responses/test_timeouts.py::test_decision_task_start_to_close_timeout_boto3
+		tests/test_swf/responses/test_timeouts.py::test_workflow_execution_start_to_close_timeout_boto3
+		# broken code (local variable used referenced before definition)
+		tests/test_appsync/test_appsync_schema.py
+		# Needs network (or docker?) but not marked as such, bug #807031
+		# TODO: report upstream
+		tests/test_batch/test_batch_jobs.py::test_terminate_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_pending_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_running_job
+		tests/test_batch/test_batch_jobs.py::test_dependencies
+		tests/test_batch/test_batch_jobs.py::test_container_overrides
+		tests/test_cloudformation/test_cloudformation_custom_resources.py::test_create_custom_lambda_resource__verify_cfnresponse_failed
+		tests/test_cloudformation/test_cloudformation_stack_integration.py::test_lambda_function
+		tests/test_events/test_events_lambdatriggers_integration.py::test_creating_bucket__invokes_lambda
+		tests/test_sqs/test_integration.py::test_invoke_function_from_sqs_exception
+		tests/test_sqs/test_sqs_integration.py::test_invoke_function_from_sqs_exception
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events0-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events1-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events3-ObjectCreated:Put]"
+	)
+
+	# pytest-django causes freezegun try to mangle stuff inside django
+	# which fails when django is not really used
+	epytest -p no:django -m 'not network'
+}
diff --git a/dev-python/nodeenv/Manifest b/dev-python/nodeenv/Manifest
index 4d4279586978..63d22456e84f 100644
--- a/dev-python/nodeenv/Manifest
+++ b/dev-python/nodeenv/Manifest
@@ -1 +1,2 @@
 DIST nodeenv-1.6.0.tar.gz 35407 BLAKE2B b952fa95787b02353ff01c27a3e4b692c0cb27954e99af4c4aec682c00692bf3e509947ffd378639dcfdcb2d8077e1b2679f56cef7818997a13a31f882251a2a SHA512 abf4fe55ba478570a32ff3bb24fc3c60ba2d100822f8295c4c55c301ccdff2dc2d20ef76990ea3ac203e30db8a1e85f3ef2df671f87c0cf7305cf1aeb788efdd
+DIST nodeenv-1.7.0.gh.tar.gz 36209 BLAKE2B ff5853c04f9c442ffee883f7c981e574704c4ccbb37a8627257c4c7af3c86d70034a2e62b4bc6f4e7c6da32e0edb4f5b9216bf288f47991d9b42f21be454634f SHA512 1e3e4068591d51d8915de73ab0f82f04620ca628152ec5a454e7ad18001ff20b698f9818353c44b80200ab529d95fa3196a3dbc85f0c497ea49f60eaa5dc9ea7
diff --git a/dev-python/nodeenv/nodeenv-1.7.0.ebuild b/dev-python/nodeenv/nodeenv-1.7.0.ebuild
new file mode 100644
index 000000000000..0131ebfed7ba
--- /dev/null
+++ b/dev-python/nodeenv/nodeenv-1.7.0.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Node.js virtual environment builder"
+HOMEPAGE="https://github.com/ekalinin/nodeenv"
+SRC_URI="
+	https://github.com/ekalinin/nodeenv/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+
+# requires network access
+RESTRICT="test"
+PROPERTIES="test_network"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pdm-pep517/Manifest b/dev-python/pdm-pep517/Manifest
index 1afd248261f0..d21727cd3ee0 100644
--- a/dev-python/pdm-pep517/Manifest
+++ b/dev-python/pdm-pep517/Manifest
@@ -1 +1,2 @@
 DIST pdm-pep517-0.12.7.gh.tar.gz 304959 BLAKE2B 0571a77803b999f88f38da843c5fcf126eeb538c6812c3e245be2fc14d6cd19929559985efba2d245bbf0efb00e412b2133fca6bbe9e63317e6b7311867e0072 SHA512 45da8ab31071a57062fac5b89abe7d912d787d647eda1b45fe3941c43687fe0fe5c8d11e539290035375e17eef808489000513e3128708fcefd851e792757b8f
+DIST pdm-pep517-1.0.0.gh.tar.gz 307117 BLAKE2B 6af1cbeb10bfcf040aaaaf60535d660c00ad84f0a186b508112e224df7eed417ce97ec1bdbf2764549172ecbededf4e9b17b6ae915b71599f04d09f2103c0a7c SHA512 cb8c02af8c4f00cf68e6379c2e93aa0ab7d30f4405debb62f7c46afc10596ab440128f1a7444fe6989d5eafb462bbbe0cfc83325bc1aba92268498a3d96332e8
diff --git a/dev-python/pdm-pep517/pdm-pep517-1.0.0.ebuild b/dev-python/pdm-pep517/pdm-pep517-1.0.0.ebuild
new file mode 100644
index 000000000000..773c078ae24f
--- /dev/null
+++ b/dev-python/pdm-pep517/pdm-pep517-1.0.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-pep517/
+	https://github.com/pdm-project/pdm-pep517/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-pep517/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
+	dev-python/license-expression[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r pdm/pep517/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.pep517\._vendor\.:from :' \
+		-e 's:from pdm\.pep517\._vendor ::' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/pytest-html/pytest-html-3.1.1.ebuild b/dev-python/pytest-html/pytest-html-3.1.1.ebuild
index 871aa99c045c..5fb2c941458f 100644
--- a/dev-python/pytest-html/pytest-html-3.1.1.ebuild
+++ b/dev-python/pytest-html/pytest-html-3.1.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~riscv ~x86"
 
 # Lots of test failures...
 RESTRICT="test"
diff --git a/dev-python/pytest-metadata/pytest-metadata-2.0.1.ebuild b/dev-python/pytest-metadata/pytest-metadata-2.0.1.ebuild
index df05aebc6d6f..294d923ca56e 100644
--- a/dev-python/pytest-metadata/pytest-metadata-2.0.1.ebuild
+++ b/dev-python/pytest-metadata/pytest-metadata-2.0.1.ebuild
@@ -17,7 +17,7 @@ SRC_URI="
 
 LICENSE="MPL-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 ~riscv ~x86"
 
 RDEPEND="
 	<dev-python/pytest-8[${PYTHON_USEDEP}]
diff --git a/dev-python/requests/files/requests-2.28.0-drop-dependency-warnings.patch b/dev-python/requests/files/requests-2.28.0-drop-dependency-warnings.patch
new file mode 100644
index 000000000000..ec3634966a07
--- /dev/null
+++ b/dev-python/requests/files/requests-2.28.0-drop-dependency-warnings.patch
@@ -0,0 +1,21 @@
+Minimal patch to avoid often rebasing.
+
+We already have tools to try check for these (`pip check` obviously, but also
+app-portage/gpyutils provides gpy-verify-deps).
+--- a/requests/__init__.py
++++ b/requests/__init__.py
+@@ -106,13 +106,7 @@ try:
+         urllib3.__version__, chardet_version, charset_normalizer_version
+     )
+ except (AssertionError, ValueError):
+-    warnings.warn(
+-        "urllib3 ({}) or chardet ({})/charset_normalizer ({}) doesn't match a supported "
+-        "version!".format(
+-            urllib3.__version__, chardet_version, charset_normalizer_version
+-        ),
+-        RequestsDependencyWarning,
+-    )
++    pass
+ 
+ # Attempt to enable urllib3's fallback for SNI support
+ # if the standard library doesn't support SNI or the
diff --git a/dev-python/requests/files/requests-2.28.0-unpin-chardet.patch b/dev-python/requests/files/requests-2.28.0-unpin-chardet.patch
new file mode 100644
index 000000000000..bd0451daaf13
--- /dev/null
+++ b/dev-python/requests/files/requests-2.28.0-unpin-chardet.patch
@@ -0,0 +1,37 @@
+https://github.com/psf/requests/pull/6179
+
+From 09483bae4f56e4f4c227e2d25ee920c538271feb Mon Sep 17 00:00:00 2001
+From: Wong Hoi Sing Edison <hswong3i@pantarei-design.com>
+Date: Sun, 26 Jun 2022 12:18:42 +0800
+Subject: [PATCH] Update Dependency with `chardet>=3.0.2,<6`
+
+https://github.com/chardet/chardet/releases/tag/5.0.0 was released on
+2022-06-25 with remove of Python 3.6 support, which also align with our
+Python > 3.6 requirement.
+
+Signed-off-by: Wong Hoi Sing Edison <hswong3i@pantarei-design.com>
+--- a/requests/__init__.py
++++ b/requests/__init__.py
+@@ -75,8 +75,8 @@ def check_compatibility(urllib3_version, chardet_version, charset_normalizer_ver
+     if chardet_version:
+         major, minor, patch = chardet_version.split(".")[:3]
+         major, minor, patch = int(major), int(minor), int(patch)
+-        # chardet_version >= 3.0.2, < 5.0.0
+-        assert (3, 0, 2) <= (major, minor, patch) < (5, 0, 0)
++        # chardet_version >= 3.0.2, < 6.0.0
++        assert (3, 0, 2) <= (major, minor, patch) < (6, 0, 0)
+     elif charset_normalizer_version:
+         major, minor, patch = charset_normalizer_version.split(".")[:3]
+         major, minor, patch = int(major), int(minor), int(patch)
+--- a/setup.py
++++ b/setup.py
+@@ -123,7 +123,7 @@ def run_tests(self):
+     extras_require={
+         "security": [],
+         "socks": ["PySocks>=1.5.6, !=1.5.7"],
+-        "use_chardet_on_py3": ["chardet>=3.0.2,<5"],
++        "use_chardet_on_py3": ["chardet>=3.0.2,<6"],
+     },
+     project_urls={
+         "Documentation": "https://requests.readthedocs.io",
+
diff --git a/dev-python/requests/requests-2.28.0-r2.ebuild b/dev-python/requests/requests-2.28.0-r2.ebuild
new file mode 100644
index 000000000000..a95d838918db
--- /dev/null
+++ b/dev-python/requests/requests-2.28.0-r2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP library for human beings"
+HOMEPAGE="
+	https://requests.readthedocs.io/
+	https://github.com/psf/requests/
+	https://pypi.org/project/requests/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="socks5"
+
+RDEPEND="
+	>=dev-python/certifi-2017.4.17[${PYTHON_USEDEP}]
+	dev-python/charset_normalizer[${PYTHON_USEDEP}]
+	<dev-python/idna-4[${PYTHON_USEDEP}]
+	<dev-python/urllib3-1.27[${PYTHON_USEDEP}]
+	socks5? ( >=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}] )
+"
+
+BDEPEND="
+	test? (
+		dev-python/pytest-httpbin[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
+		!alpha? ( !hppa? ( !ia64? (
+			dev-python/trustme[${PYTHON_USEDEP}]
+		) ) )
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.28.0-unpin-charset-normalizer.patch
+	"${FILESDIR}"/${PN}-2.28.0-unpin-chardet.patch
+	"${FILESDIR}"/${PN}-2.28.0-drop-dependency-warnings.patch
+)
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet (doctests)
+		requests/__init__.py::requests
+		requests/api.py::requests.api.request
+		requests/models.py::requests.models.PreparedRequest
+		requests/sessions.py::requests.sessions.Session
+		# require IPv4 interface in 10.* range
+		tests/test_requests.py::TestTimeout::test_connect_timeout
+		tests/test_requests.py::TestTimeout::test_total_timeout_connect
+		# TODO: openssl?
+		tests/test_requests.py::TestRequests::test_pyopenssl_redirect
+	)
+
+	if ! has_version "dev-python/trustme[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			tests/test_requests.py::TestRequests::test_https_warnings
+		)
+	fi
+
+	epytest
+}
diff --git a/dev-python/setuptools-rust/setuptools-rust-1.3.0.ebuild b/dev-python/setuptools-rust/setuptools-rust-1.3.0.ebuild
index 171c88faf30f..f021f10da3e7 100644
--- a/dev-python/setuptools-rust/setuptools-rust-1.3.0.ebuild
+++ b/dev-python/setuptools-rust/setuptools-rust-1.3.0.ebuild
@@ -96,7 +96,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv ~s390 x86"
+KEYWORDS="amd64 arm arm64 ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/sphinx-tabs/Manifest b/dev-python/sphinx-tabs/Manifest
index 15aa9ccb183e..713f4d5bca94 100644
--- a/dev-python/sphinx-tabs/Manifest
+++ b/dev-python/sphinx-tabs/Manifest
@@ -1 +1,2 @@
 DIST sphinx-tabs-3.3.1.tar.gz 523932 BLAKE2B 8b941eb549ea8a10fcd329e880b8fa15742ba7903f4f9d6422335cf889c344a1fec8f16798c286b0c0f7561c128ea297153c31d0445b867e5e23f7960698d31a SHA512 d93ba1149a20711b52f8a76f22d212fdbb97349561f3e13b53873cdb4dba8f18f645e2d73ef378c2dde3d1c0c585c1402d73f4102da0e973be0c90a5912e7036
+DIST sphinx-tabs-3.4.0.gh.tar.gz 524212 BLAKE2B 18688d10d37e5794340ccfc5d798a31bf80374ed74e64dcb54ae53dc557d7538de39b4e29002d16735cab5ed4618189af54da2682dce195c503af442f554fef7 SHA512 2833586c7040e454cac65963a3dfb22ac7e09b0a4cd5cba9ea449d798a5d7120ce3d19ac0a9d638a9389d52773bd98ab4bde33d06924170757036ff3218f6d55
diff --git a/dev-python/sphinx-tabs/sphinx-tabs-3.4.0.ebuild b/dev-python/sphinx-tabs/sphinx-tabs-3.4.0.ebuild
new file mode 100644
index 000000000000..af11fcaf04e7
--- /dev/null
+++ b/dev-python/sphinx-tabs/sphinx-tabs-3.4.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Tabbed views for Sphinx"
+HOMEPAGE="
+	https://github.com/executablebooks/sphinx-tabs/
+	https://pypi.org/project/sphinx-tabs/
+"
+SRC_URI="
+	https://github.com/executablebooks/sphinx-tabs/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+		dev-python/pytest-regressions[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/sphinx-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/sphinx_rtd_theme
+
+EPYTEST_DESELECT=(
+	# Unpackaged rinohtype
+	tests/test_build.py::test_rinohtype_pdf
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+	# annoying, incorrect version limitations
+	sed -i -e '/install_requires/d' setup.py || die
+}
diff --git a/dev-python/sphinxcontrib-spelling/Manifest b/dev-python/sphinxcontrib-spelling/Manifest
index a867f30e2efd..d43c67bfb3e7 100644
--- a/dev-python/sphinxcontrib-spelling/Manifest
+++ b/dev-python/sphinxcontrib-spelling/Manifest
@@ -1,3 +1,4 @@
 DIST sphinxcontrib-spelling-7.3.3.tar.gz 51912 BLAKE2B 6a9bd90db2298beb78686252d555dd5e77d0c9042eb0986dd2eeab9e413a921c5f5f594c539c2cfe6315002c2f2892241b789b10976e634158f3ca1d8be1b627 SHA512 7406bd846c5eac507f8e4481ada4d0d725d0a3ad8cf2f8fd3328389128cf54091bb0e304dfe23fdf771a26d9103d2c028d2f7f29e1949ca59fcf43de5bac9cb1
 DIST sphinxcontrib-spelling-7.5.0.tar.gz 54978 BLAKE2B ed56e27434a43d688a63ff6ca8aa7889a80a0a750abdebc5e9307c68fae8a14ae7ba065b127c583fff11499e75750aee6f017b4d442204b1a2308a5c8692e73c SHA512 d306d19664990cfb6ceff947f3a34243a8ead95b0e6076f9da924cd0ef43e2621178bd374400f805970592f803d6a129c74a32a6c6837d41e4f72118da667138
 DIST sphinxcontrib-spelling-7.5.1.tar.gz 55547 BLAKE2B 61415fb62b0d47672901048276897d7578f891732278d9ea0b4fe0ca5f42654114f76d600ffcf0f602afe1c0d46f4bf466c326337accf910090f768c1cee1c69 SHA512 d38114421e519ed127eae712637677a8ae75cc640087d2e7740d8c106a0d7058e633f65fb1ac9ee2fa75d295b218aa98d3a3279b077f2a89ea947a3b4c0fd05a
+DIST sphinxcontrib-spelling-7.6.0.tar.gz 56329 BLAKE2B e26a3fcb39edf622b20bce0d79d1ce2d2a13e4dd8bdef0bb5cc31108a8ee42afd728975fd65e840c91bc6c6510a57904ebc478b458a52a96031bf44f1cbfa8b6 SHA512 102202eb73767ffface2aa5555c8ee2658bcd3c1eb7f3a925e8713e2f233d1bcf0eb307fed6c264c4e4e6503c30d83a3025b0c39ef608451d2fe86664aeb48c5
diff --git a/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.6.0.ebuild b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.6.0.ebuild
new file mode 100644
index 000000000000..b8d27861b9f0
--- /dev/null
+++ b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.6.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Sphinx spelling extension"
+HOMEPAGE="
+	https://github.com/sphinx-contrib/spelling/
+	https://pypi.org/project/sphinxcontrib-spelling/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/pyenchant[${PYTHON_USEDEP}]
+	dev-python/sphinx[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/pbr[${PYTHON_USEDEP}]
+	test? (
+		app-dicts/myspell-en
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires the git repo
+	tests/test_filter.py::test_contributors
+)
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	distutils_write_namespace sphinxcontrib
+	rm -rf sphinxcontrib || die
+	epytest tests
+}
diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index 3abc3d0a1a17..90cf8bb31612 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1 +1,2 @@
 DIST virtualenv-20.14.1.tar.gz 12216889 BLAKE2B 7d06b47629dcf4a60299b9b0a192478b20ef820b8a7516569e50b57b2df383781e7e14fd4beda14a3425164997e69c8ed922edb593f86eb3bd85e4ee3a9f2ac1 SHA512 149e78787db23eabd4238baa172bf023ddcf87d59284fdd090269acfa15991aab182f9e168851f88ef810d5c50dd7cdce69d132c46ebedb10080d65a308e63a1
+DIST virtualenv-20.15.0.tar.gz 13523195 BLAKE2B c5d4b1fd78998ccdc7a041d11e0fcb569bfd00151975170260e245726eee03b4ef1cf758d43175312e69e4b482f9ec17b4e93e6854c3bfeafa2304eef2688a20 SHA512 2e3cddae926f89ef986a85ddf592b38d53401212e974b65243b9f47290b653798ab2405920c28d3a7961aeb726f25ed6401e19661f1e9ce7afd195e87a0524ab
diff --git a/dev-python/virtualenv/virtualenv-20.15.0.ebuild b/dev-python/virtualenv/virtualenv-20.15.0.ebuild
new file mode 100644
index 000000000000..59946a3286d1
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.15.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	)
+"
+
+# (unpackaged deps)
+#distutils_enable_sphinx docs \
+#	dev-python/sphinx-argparse \
+#	dev-python/sphinx_rtd_theme \
+#	dev-python/towncrier
+distutils_enable_tests pytest
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/unit/activation/test_xonsh.py
+		tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
+		tests/unit/create/test_creator.py::test_cross_major
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
+	)
+	[[ ${EPYTHON} == python3.11 ]] && EPYTEST_DESELECT+=(
+		# TODO
+		tests/unit/discovery/py_info/test_py_info.py::test_py_info_setuptools
+		tests/unit/discovery/py_info/test_py_info.py::test_custom_venv_install_scheme_is_prefered
+	)
+
+	epytest
+}
+
+pkg_postinst() {
+	elog "Please note that while virtualenv package no longer supports"
+	elog "Python 2.7, you can still create py2.7 virtualenvs via:"
+	elog "  $ virtualenv -p 2.7 ..."
+}