Adding metadata

23 files changed, 528 insertions, 3 deletions

diff --git a/dev-python/ansible-compat/Manifest b/dev-python/ansible-compat/Manifest
index b17ac388a8c1..c63286ee0e16 100644
--- a/dev-python/ansible-compat/Manifest
+++ b/dev-python/ansible-compat/Manifest
@@ -1,2 +1,3 @@
 DIST ansible-compat-2.1.0.tar.gz 37840 BLAKE2B 5ac74cdaef1c932094996f331ed94418836b3351cbd376ae35ef22046b68dad0a8ab68fd293015db9954e0a5e1df4b5c529b3845cee5778daed2bb207733ca4f SHA512 a85681aff3d34ef4a4cdad8f419017a174bf315034495bc032a7e33d586cbcf72de74d163b6faf3cd21988704e5dbb922872b83a23981891311dbb18e53797a3
 DIST ansible-compat-2.2.0.tar.gz 38772 BLAKE2B dbe74d23d2f2e4275bd9df2303417ea83517e780e65c6a34bd6ae1022be265ac816b50b309fc45f88e0c7fac7d7a22c83a826cc15be050698a6f35b267a36ac3 SHA512 3bd199431659ecba52743c6c985d2cdc6ee55396444241ba2456bc5430bbc87e26087dffbfff62ac341fa854e19baa0d7052cf79f20511222fd9e001dd020136
+DIST ansible-compat-2.2.1.tar.gz 39126 BLAKE2B c4d0512606c99ba8f07e0287620c94af6b46d7bf0077f12dcbfd9689fc7106f164a87db25de1625249ac2930858bfa655bd93d83aba0d85ed4f8bdd42cd345dc SHA512 3e941eb2c5303f83b7e7c057d08801f192889b636d9c6e56a2ac21cf75144a52ba2916eaedeba7bf848dd268387bf4d3261541d75145b213cc3f6baca6a06e5e
diff --git a/dev-python/ansible-compat/ansible-compat-2.2.1.ebuild b/dev-python/ansible-compat/ansible-compat-2.2.1.ebuild
new file mode 100644
index 000000000000..13a3292ff4a5
--- /dev/null
+++ b/dev-python/ansible-compat/ansible-compat-2.2.1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Contains functions that facilitate working with various versions of Ansible"
+HOMEPAGE="
+	https://pypi.org/project/ansible-compat/
+	https://github.com/ansible/ansible-compat/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	>=app-admin/ansible-core-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.6.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/subprocess-tee-0.3.5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-6.3.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm_git_archive-1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-markdown[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-plus[${PYTHON_USEDEP}]
+	)
+"
+
+# All these tests attempt to connect to galaxy.ansible.com
+EPYTEST_DESELECT=(
+	test/test_runtime.py::test_install_collection
+	test/test_runtime.py::test_install_collection_dest
+	test/test_runtime.py::test_prepare_environment_with_collections
+	test/test_runtime.py::test_prerun_reqs_v1
+	test/test_runtime.py::test_prerun_reqs_v2
+	test/test_runtime.py::test_require_collection_no_cache_dir
+	test/test_runtime.py::test_require_collection_wrong_version
+	test/test_runtime.py::test_require_collection
+	test/test_runtime.py::test_upgrade_collection
+	test/test_runtime_example.py::test_runtime
+)
+
+distutils_enable_sphinx docs \
+	dev-python/ansible-pygments \
+	dev-python/myst_parser \
+	dev-python/sphinx_ansible_theme
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -p pytest_markdown.plugin
+}
diff --git a/dev-python/cairocffi/Manifest b/dev-python/cairocffi/Manifest
index b9dae2d62c3c..867c329fbacf 100644
--- a/dev-python/cairocffi/Manifest
+++ b/dev-python/cairocffi/Manifest
@@ -1 +1,2 @@
 DIST cairocffi-1.3.0.tar.gz 88784 BLAKE2B 022634825febd3d70a0115f0632e9b146719a2ab802583e0f57ebbd36c65c9e73f4547dbc5ea3651b8b38a043d519f000e908c34b77f3bf49e2ed5ded1a0ca02 SHA512 be459a5f4c1986cf339b7b15fdb7d3ac52476c8c31ff663b4708917ce8abd6fc66860d1966744b69aebf7aebca4415b32166df79505ad42f315ffd76d7163d7e
+DIST cairocffi-1.4.0.tar.gz 69851 BLAKE2B 8037d9bc619d2e96e655dc4682bb95a1e920d0b2188963088c1be21f2e157f7e791f3994f0ae7ecd338547baf2a65d03b175398bc1b3c92145ae6ea148420b5a SHA512 7ffdaf365c1251b202e2680a2f689ec6ea04c19eb75df38137624ffeb429ab61c6f54af450aec019b2570a4e91d2d701328109e4e0f5662a3b3b655ab53705ff
diff --git a/dev-python/cairocffi/cairocffi-1.4.0.ebuild b/dev-python/cairocffi/cairocffi-1.4.0.ebuild
new file mode 100644
index 000000000000..0cdc28c3025b
--- /dev/null
+++ b/dev-python/cairocffi/cairocffi-1.4.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="CFFI-based drop-in replacement for Pycairo"
+HOMEPAGE="
+	https://github.com/Kozea/cairocffi/
+	https://pypi.org/project/cairocffi/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/cffi-1.1.0:=[${PYTHON_USEDEP}]
+	' 'python*')
+	>=dev-python/xcffib-0.3.2[${PYTHON_USEDEP}]
+	x11-libs/cairo:0=[X,xcb(+)]
+	x11-libs/gdk-pixbuf[jpeg]
+"
+BDEPEND="
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.8.0-tests.patch
+)
+
+src_test() {
+	rm -r cairocffi || die
+	virtx distutils-r1_src_test
+}
diff --git a/dev-python/configshell-fb/configshell-fb-1.1.29.ebuild b/dev-python/configshell-fb/configshell-fb-1.1.29.ebuild
index c60f8f11db7a..f046ea5f86a6 100644
--- a/dev-python/configshell-fb/configshell-fb-1.1.29.ebuild
+++ b/dev-python/configshell-fb/configshell-fb-1.1.29.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc x86"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc x86"
 
 RDEPEND="dev-python/pyparsing[${PYTHON_USEDEP}]
 	dev-python/six[${PYTHON_USEDEP}]
diff --git a/dev-python/contourpy/contourpy-1.0.5.ebuild b/dev-python/contourpy/contourpy-1.0.5.ebuild
index ad6637d8fef3..b152ce186509 100644
--- a/dev-python/contourpy/contourpy-1.0.5.ebuild
+++ b/dev-python/contourpy/contourpy-1.0.5.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~riscv"
 
 RDEPEND="
 	>=dev-python/numpy-1.16[${PYTHON_USEDEP}]
diff --git a/dev-python/dj-email-url/Manifest b/dev-python/dj-email-url/Manifest
index 905f35806393..94260b551e11 100644
--- a/dev-python/dj-email-url/Manifest
+++ b/dev-python/dj-email-url/Manifest
@@ -1 +1,2 @@
 DIST dj-email-url-1.0.5.gh.tar.gz 7950 BLAKE2B 1d159023f9b49f3a13fba39c29c51bb06bb6dd9d3c5303a4d246ad9f72daec9a273c15d214ad94a219883c9c210955d84bacc5861f5411845e152fedc7ee6880 SHA512 7de79a4f1f7416634c5877bc45d290d20d841e5ec470bc40ea900f04531037e2337c81788792b8f70a11318633a42f86700a5b27e611fac466b373d2d3b7f355
+DIST dj-email-url-1.0.6.gh.tar.gz 15944 BLAKE2B d10a428cca05e93129be9acb4947c534cd897a39995f8224b17017405942defc977c19457b69b07be9518b203fbe50c6302da5ef089cd54301fe3ee46c091f90 SHA512 f41f4c7cb6c2ce9ff99d9dd4d5676fcd3d82814a929fe4c64c52409ec1b12fc87e657fcb39d40d7ec24fef8fed633418ef7d7537563f753532e1348290672faa
diff --git a/dev-python/dj-email-url/dj-email-url-1.0.6.ebuild b/dev-python/dj-email-url/dj-email-url-1.0.6.ebuild
new file mode 100644
index 000000000000..3d3a06006ea9
--- /dev/null
+++ b/dev-python/dj-email-url/dj-email-url-1.0.6.ebuild
@@ -0,0 +1,27 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Use an URL to configure email backend settings in your Django Application"
+HOMEPAGE="
+	https://github.com/migonzalvar/dj-email-url/
+	https://pypi.org/project/dj-email-url/
+"
+SRC_URI="
+	https://github.com/migonzalvar/dj-email-url/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+DOCS=( CHANGELOG.rst README.rst )
+
+distutils_enable_tests unittest
diff --git a/dev-python/libtmux/Manifest b/dev-python/libtmux/Manifest
index 97fa5b5b0937..7dc40b6caab4 100644
--- a/dev-python/libtmux/Manifest
+++ b/dev-python/libtmux/Manifest
@@ -1,2 +1,3 @@
 DIST libtmux-0.14.2.gh.tar.gz 234682 BLAKE2B e93b0a280c3cfdfab4c9a313d251d15665c530813f00aa78151efe62a6a566f2d8986afed015de4a8be80b48f31ac197e98d3efa592eb8895e8d9626ff34ef72 SHA512 1565529ecf555dac8f896146e2d802c0e5460458ea1da6ba5496d5d2c394f56cc8c5f7650c5d4aebd1750659bbdc529e439e60dff6a0ccef8806bb65305d2421
 DIST libtmux-0.15.4.gh.tar.gz 237928 BLAKE2B b12643336717fbba079df884aa7b8a3029c393afd0dbcfe7be07d7c08f15a8252ec73479f5423fbe86efe63fb990529f68ed5690b40e2c7938df7edd2c6e51e5 SHA512 41adc83fde64a00385bb6885243b50c73e4cedd4d0860b1eb5c9a533b73d2f7fedef1e23f1b994c809abb834b666931c3fbdccd417969865172777e34a1cc5fe
+DIST libtmux-0.15.7.gh.tar.gz 237820 BLAKE2B b398fb9c44ebf916e99d442094bee9925e129e67a32becdfdda9d5ec4c8e30bebe937ebde58e2fb5654807251cd00076117646974430a0c608b1b89637fdfe94 SHA512 ac33aeecc579b018af2e09d0aaf86f97dafa7782893bee065798247ebd5e2a5a4a8d14b1b3314e0050e39bceefeadef6600d3881fbb30a8e3e9b4831b4df339b
diff --git a/dev-python/libtmux/libtmux-0.15.7.ebuild b/dev-python/libtmux/libtmux-0.15.7.ebuild
new file mode 100644
index 000000000000..0d94f96d3b32
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.15.7.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="python api for tmux"
+HOMEPAGE="https://libtmux.git-pull.com/"
+SRC_URI="
+	https://github.com/tmux-python/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twine[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/libtmux-0.15.4-no-doctest.patch"
+)
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	libtmux/pane.py::libtmux.pane.Pane.send_keys
+)
+
+python_prepare_all() {
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+	rm requirements/doc.txt || die
+
+	# increase timeouts for tests
+	sed -e 's/0.01/0.1/' -i tests/test_test.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/nbconvert/nbconvert-6.5.2.ebuild b/dev-python/nbconvert/nbconvert-6.5.2.ebuild
index c3871c1e3348..8e1601668ec9 100644
--- a/dev-python/nbconvert/nbconvert-6.5.2.ebuild
+++ b/dev-python/nbconvert/nbconvert-6.5.2.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~ia64 ppc ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="amd64 arm arm64 ~ia64 ppc ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
 	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
diff --git a/dev-python/nuitka/Manifest b/dev-python/nuitka/Manifest
index 3f6b14425bdc..ac1908adfd3b 100644
--- a/dev-python/nuitka/Manifest
+++ b/dev-python/nuitka/Manifest
@@ -1,2 +1,3 @@
 DIST Nuitka-1.0.6.tar.gz 3890331 BLAKE2B 4a8240123b61ff7c8ec274e6c318ade2b5057f56b0b766f1a555451f501a194c137696bd51dff23bdd125e1ffa3679f790e3ad50b9c15e85ba5358f56d47b34f SHA512 f431c976b28b80ad10cdbc27c8f0d3321aadace08a104d18089c38d00b80ee96fd3aa051dd50eb668ed57f6aca25e4f918f07d065df00627c139bc34afdcb52c
 DIST Nuitka-1.0.7.tar.gz 3891250 BLAKE2B 6f401de98bae91688d0ceab210d178fdb8d2cb32beeb7dd6925eee7985d0e344e41edcaddbdff8313402625d40dc7236433f52ca71f1100a1168775b9bc3da8b SHA512 29cb7377c976f59d8ea49aedd74798ee11b38b98b597611bd41bd5bef5c2473cd76bb260f764afd277edc4b5bfb8359b995a532ba4814f1d2310fa9c90d1467d
+DIST Nuitka-1.0.8.tar.gz 3890590 BLAKE2B 04257834d79f0988800a06d9b4725e9fa694bf7f9aafebbfb9ddbb09a2a5f666c02f13bf8ee56fd3360216faa31cd7b14a30d9a2daf23eef719ed568bfd3501c SHA512 824830121ca87b33aebcee074e0af52e456942190168186248a9ed62937bb044c6741ff721bd4bcd7d657cae96d573c1a6b9cb1fde6374073c12c1e1f6a6df26
diff --git a/dev-python/nuitka/nuitka-1.0.8.ebuild b/dev-python/nuitka/nuitka-1.0.8.ebuild
new file mode 100644
index 000000000000..3574a8ce15f5
--- /dev/null
+++ b/dev-python/nuitka/nuitka-1.0.8.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 flag-o-matic optfeature
+
+DESCRIPTION="Python to native compiler"
+HOMEPAGE="https://www.nuitka.net"
+SRC_URI="https://nuitka.net/releases/${P^}.tar.gz"
+S="${WORKDIR}/${P^}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~loong ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="dev-util/scons[${PYTHON_USEDEP}]"
+BDEPEND="
+	${RDEPEND}
+	test? ( dev-util/ccache )
+"
+
+DOCS=( Changelog.pdf Developer_Manual.pdf README.pdf )
+
+distutils-r1_src_prepare() {
+	# remove vendored version of SCons that is Python2 only
+	# this should be removed when upstream removes support for Python2
+	rm -vR "${PN}/build/inline_copy/lib/scons-2.3.2/SCons" || die
+	eapply_user
+}
+
+python_install() {
+	distutils-r1_python_install
+	doman doc/nuitka3.1 doc/nuitka3-run.1
+}
+
+python_test() {
+	append-ldflags -Wl,--no-warn-search-mismatch
+	./tests/basics/run_all.py search || die
+}
+
+pkg_postinst() {
+	optfeature "support for stand-alone executables" app-admin/chrpath
+}
diff --git a/dev-python/phonenumbers/Manifest b/dev-python/phonenumbers/Manifest
index 5fb05833b4a4..05f6f609843d 100644
--- a/dev-python/phonenumbers/Manifest
+++ b/dev-python/phonenumbers/Manifest
@@ -1,2 +1,3 @@
 DIST python-phonenumbers-8.12.54.gh.tar.gz 4905001 BLAKE2B 5fc206b3dd5f5cc96ecfc91b33369fb12d8a11245f846039478bf77f9dbc8e1bfe0e169eb6f1c360ac2a730f79b512178b115f82434790baeb3b2d26d5eaa370 SHA512 0da4f3ffa57f0c2ddaf843eea1440b33844be7ee45122a21d00b5630b720eac059777dca2051e00baf39158737478d5077f97ec6b9293528b11a9844294a621c
 DIST python-phonenumbers-8.12.55.gh.tar.gz 4905987 BLAKE2B 3c05fbe261f9c347bdccb9e664f0005f3f67120df5a494b105780ac5f00a407289bd6be6bbaefbf843937193b760b772e1d8c298a6676770f97d7e6a3d16f25a SHA512 f1aaecd70d761aaa2b6b53d5dc03624f1a64cfb8733b2ac3260bb295be527238755659b55b5d79b6a49a06c56616517afb2cd56b3f39f5eba8dcc27b61e4a6b5
+DIST python-phonenumbers-8.12.56.gh.tar.gz 4906531 BLAKE2B d55d828a26bc3a86660b6341c9577de6f489d3511971c5a843f10c14c05f0c82340109f13cc86c261119d6598ade95c2c3c9afdea485b09f3f73be891ee2a16e SHA512 675cf8d15536efd156a230cff9e027cdba718a32ca2facb493b235f39dc1a0c86f6a376d3d501690b25a5e52d6d411309626b8ecce9a065456e42774da04ea49
diff --git a/dev-python/phonenumbers/phonenumbers-8.12.56.ebuild b/dev-python/phonenumbers/phonenumbers-8.12.56.ebuild
new file mode 100644
index 000000000000..9767e4c2d82d
--- /dev/null
+++ b/dev-python/phonenumbers/phonenumbers-8.12.56.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=python-${P}
+DESCRIPTION="Python port of Google's libphonenumber"
+HOMEPAGE="
+	https://github.com/daviddrysdale/python-phonenumbers/
+	https://pypi.org/project/phonenumbers/
+"
+SRC_URI="
+	https://github.com/daviddrysdale/python-phonenumbers/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/python
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( ../README.md )
+
+python_test() {
+	"${EPYTHON}" testwrapper.py -v || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/pyupgrade/Manifest b/dev-python/pyupgrade/Manifest
index a204959f7420..219934dcd06e 100644
--- a/dev-python/pyupgrade/Manifest
+++ b/dev-python/pyupgrade/Manifest
@@ -1 +1,2 @@
 DIST pyupgrade-2.38.0.gh.tar.gz 63620 BLAKE2B 73f551e92a6d68e0e1e2b1f21a3afd0f26ece7889450135fe7c68ad3ce094799cba669547965ff3c5589f1e667568e8dcf60709e8d1b3699fd36680494b79f96 SHA512 c65534c59f1810730cd039375678c648565023e1fbb03df4bd14846be95757b33d712c51197f54009e907da647a04700dd8d8ff1094188ef7ba0dbf2352084cf
+DIST pyupgrade-2.38.1.gh.tar.gz 63637 BLAKE2B 348346d82f85c8df4edfaf2b09e8e519b5ee1d895920a896ae4c0a23f0af0da338ec2c1c2d2c175977da725313b4b5ace6ced65a3a54f5722146f35986485a9c SHA512 056e9886a8bacaf58d74461a7cbce8b7e67392b6758a7e42363404b4822df837067a7a2ec5da6a97411ce8297955ff260901f95b17d1a9e84835bce755071fca
diff --git a/dev-python/pyupgrade/pyupgrade-2.38.1.ebuild b/dev-python/pyupgrade/pyupgrade-2.38.1.ebuild
new file mode 100644
index 000000000000..ce7f409b8cc7
--- /dev/null
+++ b/dev-python/pyupgrade/pyupgrade-2.38.1.ebuild
@@ -0,0 +1,23 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Tool + pre-commit hook to automatically upgrade syntax for newer Pythons"
+HOMEPAGE="https://github.com/asottile/pyupgrade"
+SRC_URI="
+	https://github.com/asottile/pyupgrade/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="dev-python/tokenize-rt[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
diff --git a/dev-python/readme_renderer/Manifest b/dev-python/readme_renderer/Manifest
index ae8432eed99c..2f779aa55f9c 100644
--- a/dev-python/readme_renderer/Manifest
+++ b/dev-python/readme_renderer/Manifest
@@ -1,2 +1,3 @@
 DIST readme_renderer-36.0.tar.gz 28680 BLAKE2B e356690bc791d5f4a27ef59c61e356b3932595623434feae8d0fc9cf99d1bd4a724d5c202e47f989017821ce2bd69604338912c37b879699677496b789453c56 SHA512 1e208e830060d2a94e608dbbef36376c7720b8b4e2c8619665e82c64b7111153f4b764c1c7a77b36d3c0d652adb1f49a14bc7306b7bb5c65598db7acec6e984e
 DIST readme_renderer-37.1.tar.gz 29234 BLAKE2B 42a78cb5d19ee1d5cddd1d35c82801468bb2911c49037c4d4a07bc06cb1652046da99e306ed6b2864c2d26569092f824f1b7eeca53c147e6dcf6d60701679de9 SHA512 065dc1ee9baf88cea15d278dc130189b282c4bc04ccdb3d25cba423d4e32d41c8614b978ea96956913b925e1a2bdab0c2c162a369708ec253e8fae275b1c795b
+DIST readme_renderer-37.2.tar.gz 29493 BLAKE2B c517a25b2f48646a38f12cba313fec8e9292c773704f4a7a4790e14d1d403c73ca64883894d1193de582ac80573f331df9f9779d329c67d8e675a777b38e5d46 SHA512 d8bc03ba77eec8ee493705ed9b19d4695630b2f07e342f0e27a3d23c1e9c74e1d33e8a091ef5a82f42de154e7c11da33850c2e158057000c9bc097299f8c4fab
diff --git a/dev-python/readme_renderer/readme_renderer-37.2.ebuild b/dev-python/readme_renderer/readme_renderer-37.2.ebuild
new file mode 100644
index 000000000000..89ce02bbe3ea
--- /dev/null
+++ b/dev-python/readme_renderer/readme_renderer-37.2.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="a library for rendering \"readme\" descriptions for Warehouse"
+HOMEPAGE="
+	https://github.com/pypa/readme_renderer/
+	https://pypi.org/project/readme-renderer/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/bleach-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.13.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.5.2[${PYTHON_USEDEP}]
+"
+
+DOCS=( README.rst )
+
+distutils_enable_tests pytest
diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index f55c1e98a83b..13fedf898a0f 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
+DIST rq-1.11.1.gh.tar.gz 604043 BLAKE2B 57169a50fe9c2724c4e61a23e4d73d23af6aae241276dac414d2a065675e64bdd1fd35500903e7c276345a0a713a87dc7642894cdb887f019e82606fa668eba3 SHA512 ce5a2bf1fb2757d248704461ef9b631443610a11fa1c832e8aad62e68812d478c51e7bbd0d1ed4a9af678d3a9c85067e1cf16547653851ffb8c19e36b97ba945
 DIST rq-1.11.gh.tar.gz 603425 BLAKE2B f6295e1d7ddbe229001076b8ca04f0f8c323eed988a7963449c2240cbc6168d48539297c16e1ce95f7ec2b8824e6f65fc1e026e76a6093e73c06dd1b847d1c5b SHA512 6e208f4c1c8c55f5847843d7933f17d2fae58e2b24cf1461fddba08894a860f8bcb55aac5c6840f2d9223b88538070c414e2e540e9bc846cef05a26b0ef38ffb
diff --git a/dev-python/rq/rq-1.11.1.ebuild b/dev-python/rq/rq-1.11.1.ebuild
new file mode 100644
index 000000000000..e44b14291cee
--- /dev/null
+++ b/dev-python/rq/rq-1.11.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="
+	https://python-rq.org/
+	https://github.com/rq/rq/
+	https://pypi.org/project/rq/
+"
+SRC_URI="
+	https://github.com/rq/rq/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	>=dev-python/redis-py-3.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/sentry-sdk[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
diff --git a/dev-python/setuptools/Manifest b/dev-python/setuptools/Manifest
index 3c8069623511..b123c4712fc8 100644
--- a/dev-python/setuptools/Manifest
+++ b/dev-python/setuptools/Manifest
@@ -5,3 +5,4 @@ DIST setuptools-65.1.0.tar.gz 2614949 BLAKE2B 89f4556b292afa7b46e558ff059647798a
 DIST setuptools-65.1.1.tar.gz 2615020 BLAKE2B 1c45d7106e5845b95e6eec52b72749f80f799f1c5695b39e79ae7b49f52c0eab39fba305a7d2cb54a852679479db3c512e562b52a931e6a325d640479e5d4399 SHA512 29ec01558d6f6432c82797313cf12f1b3125c2000d9582e89fff415f59362c44fbfa00340cfbc4f7f4f9898161b3b585058115d1bc5b4bbcdfc0991812f858a8
 DIST setuptools-65.2.0.tar.gz 2614890 BLAKE2B a2da0870eaa0d36200dcfcab3fc63ea641d7b8451467ada32e834e94a9d33f84428e517a402d5e64ee999b5b8c2a0fff20044781fa5227ce3e2cc2fcb8f0796a SHA512 84e6e23780e6ef2e0010d4574bebf373f25f6c1e833b4e914f510e2fb3eabdbe1155c8b7d2cfeb93fd59c73fd3ad5b47c7b54e00ffaffa9ea84cf33fa5a6ee69
 DIST setuptools-65.3.0.tar.gz 2615722 BLAKE2B 1344fe17c1c2a4ec60dbf37b3e1cbad56bb5299bed9f8e30a21015f2457e1e90d6782369dfc2d804973e7348d22a356ec0ef75d1aeabba7d77e20e5ddf36e576 SHA512 3c173b1e1a8dbbed0bf3bf600df1256aeabf1b9dec34d5f5d0b1429b0fe16f2aa61fa6c4f400a5b6da24b9d679954866b76e019130bcf2246b138fe017025de9
+DIST setuptools-65.4.0.tar.gz 2615629 BLAKE2B 778b0acf1a447fbc72043113da757d73ca5dc0df8e6be8dceff7e35d64a920793dca6098d8747bd66bfe1159236570bffb6f2545a0f89a2a7916f94f849b89a7 SHA512 4c8c6348fc5e9e2cc2d7b143b050103e7ed4252dd58ca5aae8d50ee9ec522789ecfbe61dd87513d47bfd1d4afc290a7abc07fd0a6e8d27155c6732111702032d
diff --git a/dev-python/setuptools/setuptools-65.4.0.ebuild b/dev-python/setuptools/setuptools-65.4.0.ebuild
new file mode 100644
index 000000000000..7460575c4f20
--- /dev/null
+++ b/dev-python/setuptools/setuptools-65.4.0.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{7,8,9,10} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+SRC_URI="
+	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.4-r2[${PYTHON_USEDEP}]
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/nspektr-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3-r2[${PYTHON_USEDEP}]
+	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-4.11.1[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-5.4.0-r3[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	${RDEPEND}
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+"
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+	)
+
+	# remove bundled dependencies, setuptools will switch to system deps
+	# automatically
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		setuptools/tests/test_editable_install.py::test_editable_with_pyproject
+	)
+
+	epytest -n "$(makeopts_jobs)" setuptools
+}