Adding metadata

10 files changed, 332 insertions, 0 deletions

diff --git a/dev-python/clang-python/clang-python-16.0.0.9999.ebuild b/dev-python/clang-python/clang-python-16.0.0.9999.ebuild
new file mode 100644
index 000000000000..04eb349df22e
--- /dev/null
+++ b/dev-python/clang-python/clang-python-16.0.0.9999.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+DEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/libtmux/Manifest b/dev-python/libtmux/Manifest
index 49cf8df41bce..ace337d60498 100644
--- a/dev-python/libtmux/Manifest
+++ b/dev-python/libtmux/Manifest
@@ -1,3 +1,4 @@
 DIST libtmux-0.12.0.gh.tar.gz 214161 BLAKE2B 7040da2ee782b2e6bc73c70de0f5d5713c989a0959b0e731ac060f442e82e99829689f924cc2aeef6e79339b4f419df4143e2d5a9e356ad27cccb9cb3802e2f2 SHA512 f6f80daa3aaa99dd81ec0eb6a119ab1ad5fcd6c656d280b06a40c2b3bdc8d3ca7ae06089ea74482bfff005997f07e346338330d9ecf1c6745a6f3b7719b9cd0a
+DIST libtmux-0.13.0.gh.tar.gz 240339 BLAKE2B 5b975bef4835ed8b74f05fd56bd824028fa64b56c700396d0387661cdf41a4a43d81dce10462c89a90ce352b00ca0fea0334fa02e7259464a62369637b2435ce SHA512 bc5fce8c201f7c69fcbc15605808544baf19896e51c44daeebc4c133ee1db70dbffa8eea2641862cf27ca9fe341f4721cde432682e5aea84b2573f83ad25555f
 DIST libtmux-v0.10.3.tar.gz 225258 BLAKE2B 40d591ee1f8a6068947b61416d6247b2475cc99031a67c167dc527631e50075f18c46fe6fc16193867d83a1a735b0a23fbfbc77f4539f788f05375f1f68b77d2 SHA512 2c8f28ce8c313404caffa42e5fd4a1dfa5d48bdc48203f8db595cb97b44886d63608771f23d62d76a56513b7e4578e48a31cacd224eca92425f110efd0a5db69
 DIST libtmux-v0.11.0.tar.gz 234278 BLAKE2B 4939d38894fd6a1492ff282c98243b2d5b3b6f787691031c74337629aed710d3caebeb3bfce571e8f38fe07ecc341b6b3f8aa0bc42979fa362f5f0679aabf21e SHA512 e09749ce4cf7cf7756e4e40e50c6eb0a00435f2b00c8436667b6b77a94078e9c380a811107f8129ea0d347355f3ce8bb213b8fb36de2becf3cf1a2dbebd97867
diff --git a/dev-python/libtmux/libtmux-0.13.0.ebuild b/dev-python/libtmux/libtmux-0.13.0.ebuild
new file mode 100644
index 000000000000..99c909bf64af
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.13.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="python api for tmux"
+HOMEPAGE="https://libtmux.git-pull.com/"
+SRC_URI="
+	https://github.com/tmux-python/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=app-misc/tmux-3.0a
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/twine[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+	rm requirements/doc.txt || die
+
+	# increase timeouts for tests
+	sed -e 's/0.01/0.1/' -i tests/test_test.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/lit/lit-16.0.0.9999.ebuild b/dev-python/lit/lit-16.0.0.9999.ebuild
new file mode 100644
index 000000000000..804d31b11189
--- /dev/null
+++ b/dev-python/lit/lit-16.0.0.9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm
+	)
+"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}
diff --git a/dev-python/pylibmc/Manifest b/dev-python/pylibmc/Manifest
index 132d9d866ba2..f144b9eb5b6c 100644
--- a/dev-python/pylibmc/Manifest
+++ b/dev-python/pylibmc/Manifest
@@ -1,2 +1,3 @@
 DIST pylibmc-1.6.1-no-nose.patch 26090 BLAKE2B 160e5b58107dcea0354462370eeeb12739c7fd1549e1c64ddf1fe2451654e50c1408505985eb6a7150ce60185bc7acebba7a20c6444615bef8c6991debfba4cc SHA512 84fb37505def84caaacb1343032d18bd644f5072e6ce7a2d6e88bc33bd2dedc8b303f4cf2a9b57b32c3c4b8e01bef1bebcc09ecb525568c928aed326bee2cace
 DIST pylibmc-1.6.1.tar.gz 72061 BLAKE2B ebaa6f9dfc341d862a8b46bbbf0db1420ff400cb40390f7bee6bf198ff941ad7967b578040ffe1209721ea84a163a39649108a2a23f3dadc2d579db740b2ccf3 SHA512 a3874435389486b29bab5f1d29e5c179d67655d90995bb27fcb7cd46ce7eb3b60117b94f901602f8a65dc0e587d5f8edfcf15e259effd439411adb58ddb7065e
+DIST pylibmc-1.6.2.gh.tar.gz 71581 BLAKE2B 4fc9216150e122b6d80537184422b52c0a518f5b9fbcf5b54f794fde33d5ac6fcd474e08f71b8d71f0443351e91ea5d8ac2c24e94bd568605cf1183259394091 SHA512 1a1575fd5c3644d53e0ed49818bd958e0e28fe0354f41578c944b260f402f1b51a74baca8f98b32adfd0024e61ec8df1795c6ca7363509e35e4f34a907de063e
diff --git a/dev-python/pylibmc/pylibmc-1.6.2.ebuild b/dev-python/pylibmc/pylibmc-1.6.2.ebuild
new file mode 100644
index 000000000000..a0ef187027b2
--- /dev/null
+++ b/dev-python/pylibmc/pylibmc-1.6.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Libmemcached wrapper written as a Python extension"
+HOMEPAGE="
+	https://sendapatch.se/projects/pylibmc/
+	https://pypi.org/project/pylibmc/
+	https://github.com/lericson/pylibmc/
+"
+SRC_URI="
+	https://github.com/lericson/pylibmc/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86"
+
+DEPEND="
+	>=dev-libs/libmemcached-0.32
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	test? (
+		net-misc/memcached
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/pylibmc-1.6.1-fix-test-failures-r1.patch"
+)
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+# needed for docs
+export PYLIBMC_DIR=.
+
+src_test() {
+	local -x MEMCACHED_PORT=11219
+	memcached -d -p "${MEMCACHED_PORT}" -u nobody -l localhost \
+		-P "${T}/m.pid" || die
+	distutils-r1_src_test
+	kill "$(<"${T}/m.pid")" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# these require "AmazonElastiCache" running
+		tests/test_autoconf.py
+	)
+
+	epytest --doctest-modules --doctest-glob='doctests.txt' src/pylibmc tests
+}
diff --git a/dev-python/sentry-sdk/Manifest b/dev-python/sentry-sdk/Manifest
index c92c15368e65..53e8fa1bc7a0 100644
--- a/dev-python/sentry-sdk/Manifest
+++ b/dev-python/sentry-sdk/Manifest
@@ -2,3 +2,4 @@ DIST sentry-sdk-1.6.0.gh.tar.gz 249637 BLAKE2B c4d6788c80184ce9127ed85dfb5305363
 DIST sentry-sdk-1.7.2.gh.tar.gz 254370 BLAKE2B e65b2236bfec9279a4aa05b77c9492547f657e461a7c96c4158acb6bc0887571186bfa71893dce34251ef8d783fb5d583b25aa12539c5db7993cec65fdf05229 SHA512 9fe2c283a326b78c8be95500e4916bb633dc7369960a4e0ef69c0f29de74c38db81f43b3931c47d50431ee7f1a66a2b18e8c4fc02ce71c404a5e9700644cb76c
 DIST sentry-sdk-1.8.0.gh.tar.gz 286488 BLAKE2B d47f33a1c83cfffa6e4a801a6fdfde132d4cfe1b734e464c4db60e97abf53ebe503c53c3edd89d1a84e655a348a4463a75c3475d4824d03cd9b95733b13b5532 SHA512 aa3be96dbc55265f17371d8f20f8b3116b4310cbc1d078b62beeb1fd90bdbb840db85c25309e16f793a188d373c6dbcfd11a104db21b60221a5fb06d8deacc2d
 DIST sentry-sdk-1.9.0.gh.tar.gz 290271 BLAKE2B fcb4c45c129faf23a1177167e2bdd567a7ff228abbaa782676abb16c29e9c4cccef89f67ae5cd28c4f2b25e6687152fdc5eab0c7d981021a8df16374dc4e1fec SHA512 4f287bad8e9dd8eaad8f8a31d7335ccf6bfe72cc0ba8c0b26abcbd7e326bad886709d001976966a7b917f39e1ca249fa881abf29778cfd4bd65c63f05a6f6ef2
+DIST sentry-sdk-1.9.1.gh.tar.gz 270398 BLAKE2B 66ee16816d312b38df737c5ecb0ecc4a2189c932c162bbedf165f2a153029e95c389372a4638d5f71f669ac780710769e4708c3e7673573d1b1e79a29cbf93c9 SHA512 5997252aeee900125e42d7275627359ca5382707162b93e45b238c11a181ac724fea327fa1b29deed63dbf800463d10c9d2a8e8943c32b907e4eac055e399297
diff --git a/dev-python/sentry-sdk/sentry-sdk-1.9.1.ebuild b/dev-python/sentry-sdk/sentry-sdk-1.9.1.ebuild
new file mode 100644
index 000000000000..aa4b4106f18f
--- /dev/null
+++ b/dev-python/sentry-sdk/sentry-sdk-1.9.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="
+	https://sentry.io/
+	https://github.com/getsentry/sentry-python/
+	https://pypi.org/project/sentry-sdk/
+"
+SRC_URI="
+	https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/sentry-python-${PV}"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		dev-python/zope-event[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/eventlet[${PYTHON_USEDEP}]
+		' python3_{8..9})
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# tests require Internet access
+	tests/integrations/httpx/test_httpx.py
+	tests/integrations/requests/test_requests.py
+	tests/integrations/stdlib/test_httplib.py
+	tests/integrations/flask/test_flask.py
+	tests/integrations/django/test_basic.py
+	# wtf is it supposed to do?!
+	tests/integrations/gcp/test_gcp.py
+	# broken by rq-1.10.1 (optional dep)
+	tests/integrations/rq/test_rq.py
+	# fastapi is not packaged
+	tests/integrations/asgi/test_fastapi.py
+	# TODO
+	tests/integrations/bottle
+	# requires python-multipart (TODO: package it)
+	tests/integrations/starlette
+)
+
+EPYTEST_DESELECT=(
+	# hangs
+	'tests/test_transport.py::test_transport_works'
+	# TODO
+	'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+	tests/test_client.py::test_databag_depth_stripping
+	tests/test_client.py::test_databag_string_stripping
+	tests/test_client.py::test_databag_breadth_stripping
+	tests/integrations/asgi/test_asgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/asgi/test_asgi.py::test_websocket
+	tests/integrations/aiohttp/test_aiohttp.py::test_transaction_style
+	tests/integrations/aiohttp/test_aiohttp.py::test_traces_sampler_gets_request_object_in_sampling_context
+	# incompatible version?
+	tests/integrations/falcon/test_falcon.py
+	tests/integrations/sqlalchemy/test_sqlalchemy.py::test_too_large_event_truncated
+	# test_circular_references: apparently fragile
+	'tests/integrations/threading/test_threading.py::test_circular_references'
+	# test for new feature, fails with IndexError
+	tests/integrations/wsgi/test_wsgi.py::test_session_mode_defaults_to_request_mode_in_wsgi_handler
+	# TODO
+	tests/integrations/wsgi/test_wsgi.py::test_auto_session_tracking_with_aggregates
+	tests/integrations/wsgi/test_wsgi.py::test_profile_sent_when_profiling_enabled
+)
diff --git a/dev-python/svglib/Manifest b/dev-python/svglib/Manifest
index b24b0f69ad50..10fbfa2d0358 100644
--- a/dev-python/svglib/Manifest
+++ b/dev-python/svglib/Manifest
@@ -1 +1,2 @@
 DIST svglib-1.3.0.gh.tar.gz 1264820 BLAKE2B f53bda781479ddc5d4b04fd122b5141620db81756308973cb283957615711e62623baa74b69af954936be24970a4e4a6f026667c4069d62bf1705a839ecc52f3 SHA512 457fb69ba1c298079888f200502c7099cf5ee674857ff8682948011bf8e1544715e6196544212f5c0ddef1202d04f3f05d01edb4351e673ceae16a85ca0d66e5
+DIST svglib-1.4.1.gh.tar.gz 1265260 BLAKE2B ad4d6a402cd56e2e6f1fb534a8cc9c2bdc038fbdd01aad228d0b6471fd9781bcec88064dd6b93ef324201f141202404d25e31834c0f32a40c0a8037be7196edc SHA512 058aae53224cc590d56585a0f5e45506bd6586f70ddb3d9429052c8b2c18a3906925cd17a19c0f6b46695159eee1914f5e658293e7c40c1a7506f2414f8c41f8
diff --git a/dev-python/svglib/svglib-1.4.1.ebuild b/dev-python/svglib/svglib-1.4.1.ebuild
new file mode 100644
index 000000000000..8dabff89ac82
--- /dev/null
+++ b/dev-python/svglib/svglib-1.4.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python library for reading and converting SVG"
+HOMEPAGE="
+	https://github.com/deeplook/svglib/
+	https://pypi.org/project/svglib/
+"
+SRC_URI="
+	https://github.com/deeplook/svglib/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/cssselect2[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/reportlab[${PYTHON_USEDEP}]
+	dev-python/tinycss2[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Needs network access
+	tests/test_samples.py::TestWikipediaFlags::test_convert_pdf
+	tests/test_samples.py::TestW3CSVG::test_convert_pdf_png
+)