Adding metadata

28 files changed, 567 insertions, 19 deletions

diff --git a/dev-python/greenstalk/Manifest b/dev-python/greenstalk/Manifest
index bca64cf3ea7a..c425b0b7a77b 100644
--- a/dev-python/greenstalk/Manifest
+++ b/dev-python/greenstalk/Manifest
@@ -1 +1,2 @@
 DIST greenstalk-1.0.1.tar.gz 12898 BLAKE2B fc0b90ba95b09e1490025175339c3f9eb7afed16db40ec34031305a3d487582fc7305b1990424f53a06887a34c30ab4f957db01a640576aa1c5db30511161c0f SHA512 8b57ec0c7fd3a60c24e8ddd7d51f31c0986317cbceb0f7045bbd720ca58e8f3c896f2f9924de7b1e8693844c814ecdebc020972d895468d1b0e7d055bf628b16
+DIST greenstalk-2.0.0.tar.gz 13280 BLAKE2B 510b84d7dd48e0f5c9fb46ec0158473623a9e4c570e1c72db45802fce7a61b99c8f15f87d6711fa7540e6e2b6d4a846194adc28e2696400c45dc6692747f41fb SHA512 4d338bccb09b7c17c0216ce9cc4c1c9c896d15327053adc248404140ded27df6969fc8f0807120ec9417676ead57395185fb9fc5d826f49a1a1ee473aabbb048
diff --git a/dev-python/greenstalk/greenstalk-2.0.0.ebuild b/dev-python/greenstalk/greenstalk-2.0.0.ebuild
new file mode 100644
index 000000000000..d87be8bb2c29
--- /dev/null
+++ b/dev-python/greenstalk/greenstalk-2.0.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 2021 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A Python 3 client for the beanstalkd work queue"
+HOMEPAGE="https://greenstalk.readthedocs.io/ https://github.com/justinmayhew/greenstalk"
+SRC_URI="https://github.com/justinmayhew/greenstalk/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		app-misc/beanstalkd
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	pytest -vv tests.py || die
+}
diff --git a/dev-python/greenstalk/metadata.xml b/dev-python/greenstalk/metadata.xml
index 659844d0fa26..dd31e4eea44b 100644
--- a/dev-python/greenstalk/metadata.xml
+++ b/dev-python/greenstalk/metadata.xml
@@ -1,9 +1,13 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
+ <maintainer type="project">
+  <email>dev@liguros.net</email>
+  <name>Development</name>
+ </maintainer>
  <upstream>
   <remote-id type="pypi">greenstalk</remote-id>
   <remote-id type="github">justinmayhew/greenstalk</remote-id>
  </upstream>
- <origin>gentoo-staging</origin>
+ <origin>ports</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/lxml/Manifest b/dev-python/lxml/Manifest
index 09a9b9b6e037..cfd6f208adff 100644
--- a/dev-python/lxml/Manifest
+++ b/dev-python/lxml/Manifest
@@ -1 +1,2 @@
 DIST lxml-4.6.2.tar.gz 948652 BLAKE2B df6ec7e183df48c0edc6cce0fbdd6ab78eb8d1b7e8fb81a76bd9f4a24f05923c757d5b21f508be9be50c7bb187927c4e3a66146d480f2d40efc05388d26d3bf5 SHA512 81dcf5cade7b05c0e831beae7cdfbdb21e876fa55b23da98b89cbfa7960a4737efc13346ea3ade22a2448f20e036173cf5e32d43df6656c3231bfba07981f9ed
+DIST lxml-4.6.3.tar.gz 948931 BLAKE2B 373248827cb6bc0698b632ef60978adb2b8f7c37444fa1804567f08eb669018dc38fadf52422262fd96280e88c59578d244e4c5a1ed55609af55c010b3bf2b09 SHA512 50e42d6269dc45b4c0ab3285c49307f8bee87fcc4b9e0f531e1ee37bcf83c5938b7e361f906a3158fac8df89a79b932dd64a8839455e45f45f3a5f0ba73ff6a5
diff --git a/dev-python/lxml/lxml-4.6.3.ebuild b/dev-python/lxml/lxml-4.6.3.ebuild
new file mode 100644
index 000000000000..c5ac7df9ce32
--- /dev/null
+++ b/dev-python/lxml/lxml-4.6.3.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature toolchain-funcs
+
+DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
+HOMEPAGE="https://lxml.de/ https://pypi.org/project/lxml/ https://github.com/lxml/lxml"
+SRC_URI="https://github.com/lxml/lxml/archive/${P}.tar.gz"
+S=${WORKDIR}/lxml-${P}
+
+LICENSE="BSD ElementTree GPL-2 PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples +threads test"
+RESTRICT="!test? ( test )"
+
+# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
+RDEPEND="
+	>=dev-libs/libxml2-2.9.5
+	>=dev-libs/libxslt-1.1.28"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/docutils[${PYTHON_USEDEP}]
+			dev-python/pygments[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+		')
+	)
+	test? ( dev-python/cssselect[${PYTHON_USEDEP}] )
+	"
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.6.0-tests-pypy.patch
+)
+
+python_check_deps() {
+	use doc || return 0
+	has_version "dev-python/docutils[${PYTHON_USEDEP}]" &&
+	has_version "dev-python/pygments[${PYTHON_USEDEP}]" &&
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+	has_version "dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+	# avoid replacing PYTHONPATH in tests.
+	sed -i -e '/sys\.path/d' test.py || die
+
+	# don't use some random SDK on Darwin
+	sed -i -e '/_ldflags =/s/=.*isysroot.*darwin.*None/= None/' \
+		setupinfo.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	if ! python_is_python3; then
+		local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	fi
+	tc-export PKG_CONFIG
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake html
+}
+
+python_test() {
+	cp -r -l src/lxml/tests "${BUILD_DIR}"/lib/lxml/ || die
+	cp -r -l src/lxml/html/tests "${BUILD_DIR}"/lib/lxml/html/ || die
+	ln -s "${S}"/doc "${BUILD_DIR}"/ || die
+
+	"${EPYTHON}" test.py -vv --all-levels -p || die "Test ${test} fails with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		local DOCS=( README.rst *.txt doc/*.txt )
+		local HTML_DOCS=( doc/html/. )
+	fi
+	if use examples; then
+		dodoc -r samples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Support for BeautifulSoup as a parser backend" dev-python/beautifulsoup
+	optfeature "Translates CSS selectors to XPath 1.0 expressions" dev-python/cssselect
+}
diff --git a/dev-python/mkdocs-material/Manifest b/dev-python/mkdocs-material/Manifest
index f0d0d91bca2d..3d6b906d5edb 100644
--- a/dev-python/mkdocs-material/Manifest
+++ b/dev-python/mkdocs-material/Manifest
@@ -1,2 +1,2 @@
-DIST mkdocs-material-6.1.7.tar.gz 4580050 BLAKE2B 9919a94b008be298dcff569a33c6dacfa783b338cbf1a09afde6f14c85636b9f971f65863d82f9616c527c3521490c945c0d3ad3647adf69ff8e2795a1b43166 SHA512 ddca360760db8a29055bbf41b58d568943965ffe3bcce5b77fbd4af17caaaebba94f41a9dec6d1042c537054ab92eb6da41cc267ef4421d91ed69373417cde99
 DIST mkdocs-material-6.2.5.tar.gz 5373656 BLAKE2B 7e04a4a284c0749264be819a0b42bc93f924c84b40df9f718392912f97b4cc2288dac7d7a721047c0ad24ed4bb73e4a2d00aaedfbcdd9198c59180fcb2eb286a SHA512 3925c03e2f7e71cf25cf386a6f7c6e768c059a61201860dce186f095c84cb311645628fd8732f10e9106bd818e348115c1f22457bba7c128f6bc89e980983bab
+DIST mkdocs-material-7.0.6.tar.gz 6224144 BLAKE2B 87945b12c8f922fac925cae603ab2cf3a30ee6f707c4960826116d0e24e59f24cccb0319f19b245785f7f764326cc54db880aa7517491e9df6f70a4fd38a3f66 SHA512 8c88f57e2daca9e7d1d466b6bf78c67936c98dc1a871156ae9c29266cd6bf31c73b908b220e2a99f4c1cd77edb5a7fd6f5460885e997189bf02bb75d048273ac
diff --git a/dev-python/mkdocs-material/metadata.xml b/dev-python/mkdocs-material/metadata.xml
index 13a779bd058f..eb4db1b190c7 100644
--- a/dev-python/mkdocs-material/metadata.xml
+++ b/dev-python/mkdocs-material/metadata.xml
@@ -10,7 +10,7 @@
   <name>Proxy Maintainers</name>
  </maintainer>
  <longdescription lang="en">
-What to expect
+    What to expect
 
     Responsive design and fluid layout for all kinds of screens and devices, designed to serve your project documentation in a user-friendly way in 41 languages with optimal readability.
 
@@ -23,4 +23,5 @@ What to expect
   <remote-id type="pypi">mkdocs-material</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/mkdocs-material/mkdocs-material-6.1.7.ebuild b/dev-python/mkdocs-material/mkdocs-material-7.0.6.ebuild
index be425c2f3932..67616a73b383 100644
--- a/dev-python/mkdocs-material/mkdocs-material-6.1.7.ebuild
+++ b/dev-python/mkdocs-material/mkdocs-material-7.0.6.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
diff --git a/dev-python/mkdocs_pymdownx_material_extras/Manifest b/dev-python/mkdocs_pymdownx_material_extras/Manifest
index e4d3e5437408..d62d02cc5e4a 100644
--- a/dev-python/mkdocs_pymdownx_material_extras/Manifest
+++ b/dev-python/mkdocs_pymdownx_material_extras/Manifest
@@ -1,2 +1,3 @@
 DIST mkdocs_pymdownx_material_extras-1.0.7.tar.gz 17995 BLAKE2B a7a8715ec07b9ef5551eadb37e618f45ca2f8f3c707aa5269eb7d2587db70ba29cfaa8027bb606c4264bbf93d7b3950d7a5dc03640b71afc677658b044d064fa SHA512 33fe8fddd0ee5856fdfb02068e2698f26a8db139458d7736715b776fbc2d8ae8ccb3170dbb786c52338e4e7a1612006046eb429f2268469f6f2bb5ba7f8e256d
 DIST mkdocs_pymdownx_material_extras-1.1.3.tar.gz 40029 BLAKE2B faa17e6e4d27a5d5e34a98a6830e34b934f8623fafb87a73051eb424cf95d29c5dd185bbfbbe49dd3e93eeee00a8310ac0543d480ab70e5abee4047b1cecc774 SHA512 340818ebcd8f9cf175e5049028d0932a0d6208de3d8f86cf5ea47747680079c6b9b3bf27e0c32ee10ee6a1bc7ab8ffc6cc3aa48470be43ed32adfde74f44d5dd
+DIST mkdocs_pymdownx_material_extras-1.2.2.tar.gz 40542 BLAKE2B 583b06830fc230e28b0a8ed465c5c2c69700aa0707dfefea33bedbf87c00265ae5ce4bf9e3789a34b4ec195aef85e370b1f01470ba80c384669abf225486a312 SHA512 3db8aa9b22d24d0e374e5ef298685bb35c0a6b6b1916be12c756d540daac6e482d60c0dc7ce9662a8a05a71c1c75be9b8e0c0b8e7a25f495e2d652d91556ee7c
diff --git a/dev-python/mkdocs_pymdownx_material_extras/metadata.xml b/dev-python/mkdocs_pymdownx_material_extras/metadata.xml
index d109b4b4eb84..26394e4a8e97 100644
--- a/dev-python/mkdocs_pymdownx_material_extras/metadata.xml
+++ b/dev-python/mkdocs_pymdownx_material_extras/metadata.xml
@@ -24,4 +24,5 @@ Files are copied from the pymdown-extensions project.
   <remote-id type="pypi">mkdocs-pymdownx-material-extras</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/mkdocs_pymdownx_material_extras/mkdocs_pymdownx_material_extras-1.2.2.ebuild b/dev-python/mkdocs_pymdownx_material_extras/mkdocs_pymdownx_material_extras-1.2.2.ebuild
new file mode 100644
index 000000000000..b0e80951e470
--- /dev/null
+++ b/dev-python/mkdocs_pymdownx_material_extras/mkdocs_pymdownx_material_extras-1.2.2.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Custom alterations based on Mkdocs-Material"
+HOMEPAGE="
+	https://github.com/facelessuser/mkdocs_pymdownx_material_extras
+	https://pypi.org/project/mkdocs-pymdownx-material-extras"
+SRC_URI="https://github.com/facelessuser/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/mkdocs-material-5.0.2[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/pydot/pydot-1.4.2.ebuild b/dev-python/pydot/pydot-1.4.2.ebuild
index 519a860246b3..7b870edc0645 100644
--- a/dev-python/pydot/pydot-1.4.2.ebuild
+++ b/dev-python/pydot/pydot-1.4.2.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/pydot/pydot/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos ~sparc-solaris"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc ~x86 ~amd64-linux ~ppc-macos ~x64-macos ~sparc-solaris"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/pyspelling/Manifest b/dev-python/pyspelling/Manifest
index bef7a333b22f..403b1c618517 100644
--- a/dev-python/pyspelling/Manifest
+++ b/dev-python/pyspelling/Manifest
@@ -1,2 +1,2 @@
-DIST pyspelling-2.7.0.tar.gz 149425 BLAKE2B f8e600a41ebd4ec290562307306e7fd5c67d384b9186de037b98d50d58016ded19c426caa892497ca44e309fb3db04292b890612afbe25a34f9f6b06985d3740 SHA512 2fcd225a66cb02fff10d5ca652e523a01bd0488a005dafa32ba1151fba9afe73809781501c957d6df00927baa9fb6779872973b32e2d3fe8a09306fdc4191995
 DIST pyspelling-2.7.1.tar.gz 149449 BLAKE2B a5faefac163850d327d64b75776b5f360ad1e1337cb3784c8d0a167e1240e92a202f4ecbe86d768341a7512b36c83981b5fbf4058a2142a5b627f40c0e60c09f SHA512 be0cc9be343e2d5d2c16b2dc9cb6f83fd5f60eba81c709711fef37b880363db8b76e86ec048b57ab270be59803b101696709bd474d4f0267c99f55c906ec7857
+DIST pyspelling-2.7.2.tar.gz 150911 BLAKE2B 813eca2c4bdf377fd7babec376dd2991713db59c66b509c656cb24a314776c2cc360ec9ff884baec6607f27cae3169672746580d3c58abad35dbfe9f605fc51e SHA512 2937c1985ec6f27713275d9f31d3529e35f219df211be0ac9f1ae89d5c92a1e52c51b982291be7bd25375eb6404f52ac0ad893afbe73aada1fb03923dc09f721
diff --git a/dev-python/pyspelling/metadata.xml b/dev-python/pyspelling/metadata.xml
index d40a562111c2..f32dcba62459 100644
--- a/dev-python/pyspelling/metadata.xml
+++ b/dev-python/pyspelling/metadata.xml
@@ -26,4 +26,5 @@ Aspell and Hunspell are very good spell checking tools. Aspell particularly come
   <remote-id type="pypi">pyspelling</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pyspelling/pyspelling-2.7.0.ebuild b/dev-python/pyspelling/pyspelling-2.7.2.ebuild
index 31fca876c8ea..fb7a626fc953 100644
--- a/dev-python/pyspelling/pyspelling-2.7.0.ebuild
+++ b/dev-python/pyspelling/pyspelling-2.7.2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -28,8 +28,8 @@ RDEPEND="
 	|| ( app-text/aspell app-text/hunspell )
 
 	dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
-	dev-python/lxml[${PYTHON_USEDEP}]
 	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
 	dev-python/markdown[${PYTHON_USEDEP}]
 	dev-python/pyyaml[${PYTHON_USEDEP}]
 	>=dev-python/soupsieve-1.8[${PYTHON_USEDEP}]
diff --git a/dev-python/snakeoil/snakeoil-0.9.3.ebuild b/dev-python/snakeoil/snakeoil-0.9.3.ebuild
index 69aff416f2d5..40873b95e954 100644
--- a/dev-python/snakeoil/snakeoil-0.9.3.ebuild
+++ b/dev-python/snakeoil/snakeoil-0.9.3.ebuild
@@ -10,7 +10,7 @@ if [[ ${PV} == *9999 ]] ; then
 	EGIT_REPO_URI="https://github.com/pkgcore/snakeoil.git"
 	inherit git-r3
 else
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ~ia64 ppc ppc64 ~s390 sparc ~x86 ~x64-macos"
 	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 fi
 
diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 698714fe150c..0a027208a958 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,4 +1,6 @@
 DIST spyder-4.2.0.tar.gz 11840358 BLAKE2B 26e4cd9865196fb39fa5b49a17f172b3000fe27c5ab6fb1b31ed56d41f118e4016b6ed97ce8cb1b39c65031fc11413f8e426876d3dc8d5af25f12428d0e0c481 SHA512 c1460e2fe9a37c0e6107657de71205682018d87737b3eac16ec92c32d979bf727a6c8955bd2700872b6e91159d1a1efc57cdea52ffc44604fe34b78094de6e7f
 DIST spyder-4.2.3.tar.gz 11539371 BLAKE2B aecd2e9772c52e644e9c0503195e380fffecdfaa5aea3f00a64e98a969faf3de4e0d8eb0515cc59893f28deb7733403826e90e36006ad7f8f4d67e8ef5e64543 SHA512 9e56efab8862c21e7496d45e813d28c4e9be583275352b0a6e0a58e99f6c0234fa9862da66705839beacb971dde9b6edc253405d9d62853a3c4c9c9991844846
+DIST spyder-4.2.4.tar.gz 11538634 BLAKE2B 7d235c716dd39c250616264048d5f70b13b682024e1493f24f69ada3c0cee03f4da99dc5b58cecae8e98ca27313024c98184be1e398e5a4e5c231339100bac03 SHA512 723e8b9a030d620e19a17c16a9f52a1863f5f063985d3b805c9deaa836875d11a72a39ee690301a6ae65d634273ba25a897ec2f338e9cc082861c6c0f8413b98
 DIST spyder-docs-5c9c8a3317045c2d301e05b751943be9b521d129.tar.gz 66692311 BLAKE2B ec741a9cd830bc8a5776be1d52dcac9649c8abf33faec0ac8741d95625d8aeda2b8c0d2bdbef02c068a22ec62a4d5281a48e996530e1bd2e6de43b86e0a14ffe SHA512 73bd05ef31f69ebd80bb488017998536c4ed0e63a331efe743d9d858b936df287253f333d09beac6d2b249a96e8f82538d321850a64b0941db3d0141122995eb
+DIST spyder-docs-78b25754c69a20643258821146e398ad5535c920.tar.gz 69167467 BLAKE2B d2815d552002f329b5fac59329fba3b3b0cd592bcbdacc0878966919e44dbab29548533661e60a1b9b8fd763d57d1e4c2f761782ace1b0a814a5f0cec1f66af9 SHA512 10764367fd5f830d7a3620b9d9e7ec4ab74539c1f48326c0c40f7caff74a50401addc7609fe1558c57dac4649d0a214c0d2d77cecd100bd8574151134e49634d
 DIST spyder-docs-7fbdabcbc37fe696e4ad5604cdbf4023dfbe8b6c.tar.gz 58822544 BLAKE2B 9ddd662eb0e3b2845a15bc38a0ab994fcf43824a560cf635a29e16b5eb66407706a412ea50a2f8e5c0212675df3422ece649bd1e50e3ecd1c34ee5727f8a2df9 SHA512 ab30f287733681da0b1d15656a44cd320401330309efbff8f0a89f59a15d5c57532a2eab3e8353d8c3856eac0a393385a852663d6698d0a0d309def21d13933d
diff --git a/dev-python/spyder/metadata.xml b/dev-python/spyder/metadata.xml
index 9b3619c3b22b..562304c50347 100644
--- a/dev-python/spyder/metadata.xml
+++ b/dev-python/spyder/metadata.xml
@@ -30,4 +30,5 @@
   <remote-id type="github">spyder-ide/spyder</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/spyder/spyder-4.2.4.ebuild b/dev-python/spyder/spyder-4.2.4.ebuild
new file mode 100644
index 000000000000..af3abcf3acb0
--- /dev/null
+++ b/dev-python/spyder/spyder-4.2.4.ebuild
@@ -0,0 +1,253 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+# The warning that this is wrong is a false positive
+# Spyder has setuptools in install_requires
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit optfeature xdg distutils-r1
+
+# Commit of documentation to fetch
+DOCS_PV="78b25754c69a20643258821146e398ad5535c920"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# The test suite often hangs or does not work.
+# Technically spyder requires pyqt5<13, which
+# we do not have in ::gentoo any more. Likely
+# this is the reason many of the tests fail
+# or hang. RESTRICTing because IMO it is
+# not worth the several hours I spend every
+# single version bump checking which tests
+# do and do not work. Spyder itself works
+# fine with pyqt5>13.
+RESTRICT="test"
+
+# White space separated deps are expansion of python-language-server[all] dep
+# As the pyls ebuild does not add flags for optional runtime dependencies
+# we have to manually specify these desp instead of just depending on the [all]
+# flag. The indentation allows us to distinguish them from spyders direct deps.
+RDEPEND="
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/cloudpickle-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.6.0[${PYTHON_USEDEP}]
+	~dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	~dev-python/parso-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-1.0[${PYTHON_USEDEP}]
+	>=dev-python/python-language-server-0.36.2[${PYTHON_USEDEP}]
+
+	dev-python/autopep8[${PYTHON_USEDEP}]
+	>=dev-python/flake8-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.6.0[${PYTHON_USEDEP}]
+	<dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyflakes-2.2.0[${PYTHON_USEDEP}]
+	<dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
+	dev-python/pylint[${PYTHON_USEDEP}]
+	>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
+	dev-python/yapf[${PYTHON_USEDEP}]
+
+	<dev-python/python-language-server-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-black-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.3.2[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/qdarkstyle-2.8[${PYTHON_USEDEP}]
+	<dev-python/qdarkstyle-3.0[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-0.5.7[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.0.3[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-1.5.0[${PYTHON_USEDEP},svg,webengine]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-1.10.2[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-1.11.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+	<dev-python/watchdog-2.0.0[${PYTHON_USEDEP}]
+
+	dev-python/PyQt5[${PYTHON_USEDEP}]
+	dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
+"
+
+BDEPEND="test? (
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/flaky[${PYTHON_USEDEP}]
+	dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]
+	dev-python/pandas[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	<dev-python/pytest-6.0[${PYTHON_USEDEP}]
+	dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+	dev-python/pytest-mock[${PYTHON_USEDEP}]
+	dev-python/pytest-ordering[${PYTHON_USEDEP}]
+	dev-python/pytest-qt[${PYTHON_USEDEP}]
+	dev-python/pytest-xvfb[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-4.2.1-build.patch"
+	"${FILESDIR}/${PN}-4.1.5-doc-theme-renamed.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/doc dev-python/sphinx-panels dev-python/pydata-sphinx-theme dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these deps are packaged separately: dev-python/spyder-kernels, dev-python/python-language-server
+	rm external-deps/* -r || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# do not depend on pyqt5<13
+	sed -i -e '/pyqt5/d' \
+		-e '/pyqtwebengine/d' \
+			setup.py || die
+
+	# do not check deps, fails because we removed pyqt5 dependency above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# can't check for update, need network
+	rm spyder/workers/tests/test_update.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	# KeyError: 'conda: base', need conda??
+	sed -i -e 's:test_status_bar_conda_interpreter_status:_&:' \
+		spyder/widgets/tests/test_status.py || die
+
+	# assert 2 == 1
+	sed -i -e 's:test_pylint_max_history_conf:_&:' \
+		spyder/plugins/pylint/tests/test_pylint.py || die
+
+	# https://bugs.gentoo.org/747211
+	sed -i -e 's:test_loaded_and_closed_signals:_&:' \
+		spyder/plugins/projects/tests/test_plugin.py || die
+
+	# AssertionError: assert '' == 'This is some test text!'
+	sed -i -e 's:test_tab_copies_find_to_replace:_&:' \
+		spyder/plugins/editor/widgets/tests/test_editor.py || die
+
+	# hangs till forever
+	sed -i -e 's:test_help_opens_when_show_tutorial_full:_&:' \
+		spyder/app/tests/test_mainwindow.py || die
+
+	# Assertion error, can't connect/remember inside ebuild environment
+	rm spyder/plugins/ipythonconsole/widgets/tests/test_kernelconnect.py || die
+
+	# AssertionError: waitUntil timed out in 20000 miliseconds
+	sed -i -e 's:test_pdb_multiline:_&:' \
+		spyder/plugins/ipythonconsole/tests/test_ipythonconsole.py || die
+
+	# AssertionError: assert 'if True:\n    0\n    ' == 'if True:\n    0'
+	sed -i -e 's:test_undo_return:_&:' \
+		spyder/plugins/editor/widgets/tests/test_codeeditor.py || die
+
+	# assert False is True
+	sed -i -e 's:test_range_indicator_visible_on_hover_only:_&:' \
+		spyder/plugins/editor/panels/tests/test_scrollflag.py || die
+
+	# AssertionError: waitUntil timed out in 10000 miliseconds
+	sed -i -e 's:test_get_hints:_&:' \
+		spyder/plugins/editor/widgets/tests/test_hints_and_calltips.py || die
+
+	# Fatal Python error: Aborted
+	sed -i -e 's:test_module_completion:_&:' \
+		spyder/utils/introspection/tests/test_modulecompletion.py || die
+
+	# assert 0 > 0
+	sed -i -e 's:test_maininterpreter_page:_&:' \
+		spyder/preferences/tests/test_config_dialog.py || die
+
+	# This hangs forever
+	sed -i -e 's:test_load_kernel_file:_&:' \
+		-e 's:test_load_kernel_file_from_location:_&:' \
+		-e 's:test_load_kernel_file_from_id:_&:' \
+		spyder/plugins/ipythonconsole/tests/test_ipythonconsole.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly makes the tests freeze after completing even if successful
+# Exit code is nonzero even upon success, so can't add || die here
+# test results should be checked for success manually
+python_test() {
+	${EPYTHON} runtests.py
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "To get additional features, optional runtime dependencies may be installed:"
+		optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+		optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+		optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+		optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+		optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+		optfeature "Run Cython files in the IPython console" dev-python/cython
+		optfeature "The hdf5/h5py plugin" dev-python/h5py
+		optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+		optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+		# spyder-autopep8 does not have a release (yet)
+		# and are not compatible with >=spyder-4.0.0 at the moment
+		# optfeature "The autopep8 plugin" dev-python/spyder-autopep8
+		optfeature "Vim key bindings" dev-python/spyder-vim
+		optfeature "Unittest support" dev-python/spyder-unittest
+		optfeature "Jupyter notebook support" dev-python/spyder-notebook
+		optfeature "System terminal inside spyder" dev-python/spyder-terminal
+		# spyder-reports not yet updated to >=spyder-4.0.0
+		# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+
+	elog ""
+	elog "Spyder currently only works with PyQt5 as QtPy backend, PySide2 is not supported."
+	elog "Please ensure that 'eselect qtpy' is set to PyQt5."
+	elog ""
+}
diff --git a/dev-python/textdistance/Manifest b/dev-python/textdistance/Manifest
index ee6361a1a911..4a3aedf10276 100644
--- a/dev-python/textdistance/Manifest
+++ b/dev-python/textdistance/Manifest
@@ -1 +1 @@
-DIST textdistance-4.2.0.tar.gz 34519 BLAKE2B 0432705c57cecd66fe8c9cd4c12293220f1aa72e26c17f7a99d0a312d6ac7c2bb769a01dce9fc950a578f50a490616cb76dbafec541cbe1d61dd8f645dd51281 SHA512 8b58d02824d0c94ece9d0322180dd25af7dd0cef708e3f981efa16e262373532de3d68aed7dffd2008cfb04f30495a1792f2f22e9f1d8a802426d464c20d7b07
+DIST textdistance-4.2.1.tar.gz 45095 BLAKE2B c0b7fec8adb3a90fc2f3c939a39492887a4989e16d6bd9c548fceb1d5020323d2782dabdb69ae17dc4c3cd795425b3fbdf9bb6041b1ef7df840c2b3a9e2a7e05 SHA512 daff22077800e42ae266edd8614a1300f3f2d080868dbd38e14d035f19853e555485d27ab0392401318e0c4ddc81fbf1b537dd3aa1ba25d7a89e5f0edde8ce46
diff --git a/dev-python/textdistance/metadata.xml b/dev-python/textdistance/metadata.xml
index ead788949904..376ef7524a65 100644
--- a/dev-python/textdistance/metadata.xml
+++ b/dev-python/textdistance/metadata.xml
@@ -14,4 +14,5 @@
   <remote-id type="github">life4/textdistance</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/textdistance/textdistance-4.2.0.ebuild b/dev-python/textdistance/textdistance-4.2.1.ebuild
index a3b35e6301c4..2259757c7395 100644
--- a/dev-python/textdistance/textdistance-4.2.0.ebuild
+++ b/dev-python/textdistance/textdistance-4.2.1.ebuild
@@ -9,15 +9,12 @@ inherit distutils-r1
 
 DESCRIPTION="Compute distance between the two texts"
 HOMEPAGE="https://github.com/life4/textdistance"
-SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+SRC_URI="https://github.com/life4/textdistance/archive/v.${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 
-# Too many strange failures
-RESTRICT="test"
-
 BDEPEND="test? (
 	dev-python/abydos[${PYTHON_USEDEP}]
 	dev-python/hypothesis[${PYTHON_USEDEP}]
@@ -28,4 +25,17 @@ BDEPEND="test? (
 	dev-python/pyxDamerauLevenshtein[${PYTHON_USEDEP}]
 )"
 
+S="${WORKDIR}/${PN}-v.${PV}"
+
 distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# RuntimeError: cannot import distance.hamming
+	# these optional things are missing at the moment
+	sed -i -e 's:test_compare:_&:' \
+		-e 's:test_qval:_&:' \
+		-e 's:test_list_of_numbers:_&:' \
+		tests/test_external.py || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/tree-sitter/tree-sitter-0.19.0.ebuild b/dev-python/tree-sitter/tree-sitter-0.19.0.ebuild
index 7a62ef7cda63..8ed598d65b0a 100644
--- a/dev-python/tree-sitter/tree-sitter-0.19.0.ebuild
+++ b/dev-python/tree-sitter/tree-sitter-0.19.0.ebuild
@@ -15,6 +15,6 @@ SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_P}.tar.gz -> py-${P}.tar.gz"
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ppc ~ppc64 ~s390 ~sparc ~x86 ~x64-macos"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ~ia64 ppc ppc64 ~s390 sparc ~x86 ~x64-macos"
 
 S="${WORKDIR}/${MY_P}"
diff --git a/dev-python/twisted/files/twisted-21.2.0-incremental-21.patch b/dev-python/twisted/files/twisted-21.2.0-incremental-21.patch
new file mode 100644
index 000000000000..c726d32cb89d
--- /dev/null
+++ b/dev-python/twisted/files/twisted-21.2.0-incremental-21.patch
@@ -0,0 +1,65 @@
+From ab934c065177422a7121e44c792c56c32962c4e4 Mon Sep 17 00:00:00 2001
+From: Thomas Grainger <tagrain@gmail.com>
+Date: Tue, 2 Mar 2021 11:27:56 +0000
+Subject: [PATCH] update tests for incremental >= 21.3.0
+
+---
+ pyproject.toml                           | 2 +-
+ setup.cfg                                | 2 +-
+ src/twisted/python/test/test_versions.py | 6 +++---
+ 3 files changed, 5 insertions(+), 5 deletions(-)
+
+diff --git a/pyproject.toml b/pyproject.toml
+index a7d531b003d..ca12b3ef7e0 100644
+--- a/pyproject.toml
++++ b/pyproject.toml
+@@ -2,7 +2,7 @@
+ requires = [
+     "setuptools >= 35.0.2",
+     "wheel >= 0.29.0",
+-    "incremental >= 16.10.1",
++    "incremental >= 21.3.0",
+ ]
+ build-backend = "setuptools.build_meta"
+ 
+diff --git a/setup.cfg b/setup.cfg
+index 17501b91ecf..07094f7ea6b 100644
+--- a/setup.cfg
++++ b/setup.cfg
+@@ -28,7 +28,7 @@ python_requires = >=3.6.7
+ install_requires =
+     zope.interface >= 4.4.2
+     constantly >= 15.1
+-    incremental >= 16.10.1
++    incremental >= 21.3.0
+     Automat >= 0.8.0
+     hyperlink >= 17.1.1
+     attrs >= 19.2.0
+diff --git a/src/twisted/python/test/test_versions.py b/src/twisted/python/test/test_versions.py
+index 022010a6eec..6707169b1f8 100644
+--- a/src/twisted/python/test/test_versions.py
++++ b/src/twisted/python/test/test_versions.py
+@@ -126,7 +126,7 @@ def test_strWithPrerelease(self):
+         Calling C{str} on a version with a prerelease includes the prerelease.
+         """
+         self.assertEqual(
+-            str(Version("dummy", 1, 0, 0, prerelease=1)), "[dummy, version 1.0.0rc1]"
++            str(Version("dummy", 1, 0, 0, prerelease=1)), "[dummy, version 1.0.0.rc1]"
+         )
+ 
+     def testShort(self):
+@@ -145,7 +145,7 @@ def test_getVersionStringWithPrerelease(self):
+         """
+         self.assertEqual(
+             getVersionString(Version("whatever", 8, 0, 0, prerelease=1)),
+-            "whatever 8.0.0rc1",
++            "whatever 8.0.0.rc1",
+         )
+ 
+     def test_base(self):
+@@ -158,4 +158,4 @@ def test_baseWithPrerelease(self):
+         """
+         The base version includes 'preX' for versions with prereleases.
+         """
+-        self.assertEqual(Version("foo", 1, 0, 0, prerelease=8).base(), "1.0.0rc8")
++        self.assertEqual(Version("foo", 1, 0, 0, prerelease=8).base(), "1.0.0.rc8")
diff --git a/dev-python/twisted/twisted-21.2.0.ebuild b/dev-python/twisted/twisted-21.2.0.ebuild
index 27101cc65a7c..fd8225b6d547 100644
--- a/dev-python/twisted/twisted-21.2.0.ebuild
+++ b/dev-python/twisted/twisted-21.2.0.ebuild
@@ -14,6 +14,7 @@ HOMEPAGE="https://www.twistedmatrix.com/trac/"
 SRC_URI="
 	https://github.com/twisted/twisted/archive/${P}.tar.gz
 	https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz"
+S=${WORKDIR}/${PN}-${P}
 
 LICENSE="MIT"
 SLOT="0"
@@ -59,9 +60,10 @@ RDEPEND="
 	!dev-python/twisted-web
 "
 BDEPEND="
-	>=dev-python/incremental-16.10.1[${PYTHON_USEDEP}]
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
 	test? (
 		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
 		>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
 		>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
 		dev-python/cython-test-exception-raiser[${PYTHON_USEDEP}]
@@ -75,9 +77,9 @@ BDEPEND="
 	)
 "
 
-S=${WORKDIR}/${PN}-${P}
-
 python_prepare_all() {
+	eapply "${FILESDIR}"/${P}-incremental-21.patch
+
 	# upstream test for making releases; not very useful and requires
 	# sphinx (including on py2)
 	rm src/twisted/python/test/test_release.py || die
diff --git a/dev-python/unittest-or-fail/unittest-or-fail-1.ebuild b/dev-python/unittest-or-fail/unittest-or-fail-1.ebuild
index 74d9351193cd..0e6a26176824 100644
--- a/dev-python/unittest-or-fail/unittest-or-fail-1.ebuild
+++ b/dev-python/unittest-or-fail/unittest-or-fail-1.ebuild
@@ -15,7 +15,7 @@ SRC_URI="
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+KEYWORDS="~amd64 ~arm arm64 ~hppa ~ia64 ppc ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 
 # Warning: do not use distutils_enable_tests to avoid a circular
 # dependency on itself!
diff --git a/dev-python/zope-interface/Manifest b/dev-python/zope-interface/Manifest
index 53878e77b869..3771804b5106 100644
--- a/dev-python/zope-interface/Manifest
+++ b/dev-python/zope-interface/Manifest
@@ -1 +1,2 @@
 DIST zope.interface-5.2.0.tar.gz 227058 BLAKE2B d5afcaf56d77431436bc6f2ccf566e835c0908f7037ecd2a93e2b2681c0588b2baeacb0ec50207e59e67f7c4ac3cc76bca657330b48991f22835637985b85ccd SHA512 64688b8a823d63fc78720ee15d59cc54c07a700dc45e46336cb23cd1a0a3eb998284a4d954d3fa08c7f26b35583c0284fb2fcd18f84f3133ce93f7c3ade0a988
+DIST zope.interface-5.3.0.tar.gz 241964 BLAKE2B 4b1ea32f3f08e2d49afa402358760dd575057bc4487ad52686a2aaceee782501c3c1891dda00cbd306abe35e7bfea4cf41a4a340644258cf478a637abd62c103 SHA512 3544c64d64f32e4635031325b38500b8ed5888b03821c5ff2e07c2d88bb50ccb0b6fe24c6a55813bbe05caf2b847be832182e04dcd8e9ff29f1e68c1fda7c680
diff --git a/dev-python/zope-interface/zope-interface-5.3.0.ebuild b/dev-python/zope-interface/zope-interface-5.3.0.ebuild
new file mode 100644
index 000000000000..3de37efdae2b
--- /dev/null
+++ b/dev-python/zope-interface/zope-interface-5.3.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# pkg_resources namespace
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1 flag-o-matic
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Interfaces for Python"
+HOMEPAGE="https://pypi.org/project/zope.interface/ https://github.com/zopefoundation/zope.interface"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	dev-python/namespace-zope[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/zope-event[${PYTHON_USEDEP}]
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/5.1.0-drop-coverage.patch
+)
+
+distutils_enable_tests setup.py
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}"
+		append-flags -fno-strict-aliasing
+	fi
+
+	distutils-r1_python_compile
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# remove .pth files since dev-python/namespace-zope handles the ns
+	find "${D}" -name '*.pth' -delete || die
+}