Adding metadata

37 files changed, 1072 insertions, 131 deletions

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 71a041cf46b4..01dc612d89fe 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,8 +1,14 @@
 DIST Django-2.2.27.checksum.txt 2556 BLAKE2B 770dc5670d0d4aebcfd1956d644b9d7e4e5bf0b511649ae072de1b8ec8d2ea12dbc48563f5372979dead9e729abd9b5174c99323a14170876b1f1b5e61de96f6 SHA512 fb76f2bef6e6d0a3002298e4eeec5b335bfdc365ae55f0c26dcb050d369864c504dd32d40ac3b49897d56bc0dadc10136b588361ddf3598ffdc03830a97e1d63
 DIST Django-2.2.27.tar.gz 9185716 BLAKE2B 26d509c722c62b5bf784331466a97ad1b961715572da9e6add4be1bdc7cf999c0ec7c763d9bc8ab2fc1ca35a48783feaf748c3c9388ae9f5f3e393972deea734 SHA512 0db670651a820b49d855e38a336c0c6990ce4701bb686c5e8a292ccb03342e995c61c2c628b1d625d2715404e969fc31c256e5bf0fd6c1ff714d1c1c1ee30bff
+DIST Django-2.2.28.checksum.txt 2554 BLAKE2B 23421008f45040be56c417fb4d31ab8cb72d6d6fb59f12e53de1a7947ffed3a290908a49e7ce08bbb155380472daed93b33c2e90580d3bd0aa3d0d9190478bca SHA512 a7e4b2abf3f3ff79e6a0a55047afc6dcb97a2a27bdd6b25770ad60df3eaa4d260d332ef0b94e63971c500a313c2033127575510e871c5ec648bd045c04353aa1
+DIST Django-2.2.28.tar.gz 9187543 BLAKE2B da6ae04b84a858a678b9740694cf1b638128b783da1aa8443c0e85ea3d7f71104e433de043ff7264575e2df36b6fea7275874ff04391b41eb70ba6c7c78306dc SHA512 228aec6ee8619ff3d0397ff867bd59352900fb95557bd02cfea594b3bc3f813b5bcd13f488b451b0ee79a4d52deab19c5e97aa40f1075ba06db72542d119228e
 DIST Django-3.2.12.checksum.txt 2556 BLAKE2B 7ae6e41305b5b07969ddad3474a0819359dff888fc3bdc1c5000ded1b9b726a7c55aa7aaffc85184558edcc6c12b617c8270cc569fa8e645622206631979a9c2 SHA512 5098dde440a15ad066fa7927943f4ec66bb925798afcb42101c5cf50b8148301866c39ad37ebb5db9d7f9e195953337c03dc6fa2c49758716f969ee2ce414d24
 DIST Django-3.2.12.tar.gz 9812448 BLAKE2B 39b6e7e8f50b79d7be62be171eb358ab815c9dd630b8b2ad2cf085c42c79a6a8c92914fae3c471f41578e65fa09f011f959dd0794c804e7b30cfbc9411cf4f4b SHA512 fc8ad3af019b268d514cc5240cac9c6b2fbf3a169c7933e8ab2da92e9cfed72df7a2784a8d92eaec8105bc9c245763acd307178bdf662e5d51407e72ae9d8683
+DIST Django-3.2.13.checksum.txt 2554 BLAKE2B 301d816685f6d97c4a18b4f9d015b063521a7e90a870f1c95ec37ebbc1d4e7311abfee7f7c4aafaa40932334d0eab68fc768dcf21acfffe1d098cabd71ea161a SHA512 ef4a5d0fb8e885cbc2854a4b9b2380dec1cec0e8f6d9bc54179354eb6170755bd6f02268ad5bdc81fdea9d30022422462b0b14894ccc0f37d2e7288aeda83abb
+DIST Django-3.2.13.tar.gz 9813985 BLAKE2B eb8319cc225491fc71f719d2eef6daa05114a97b1302093a0cf0f77bb2a51f398e7a034df7aa52c6a64e9796b9cc66b127fccee810cb38508506ba4cd121cfbf SHA512 08f056b18bc04b95d6705cf70c2ecc5be0c1324e0b38582991b907ed5977c4e3d35417ccf4ec06c2436a718e3aae007b015f0d40dd94ce5cfb129a54cceb6578
 DIST Django-4.0.2.checksum.txt 2547 BLAKE2B 532139126846e1758bbe7b4dc4ad4aad6c6b3607e298f4373366239637ceca7d01a26472b2a87917e64db7140d28a76c1f5fbb396e7022b1a42b723551770d1f SHA512 eddd8ac31fc60f803f1e6f975c079e84e5ef997e8ac93b7dcf3573bd0c5d057adeb6f092acaecb200529044d81aa2db9849c1c13525678c8c2bd27bd14d6b280
 DIST Django-4.0.2.tar.gz 9996300 BLAKE2B 422b0bb000e7f62a854dc8fa686001acc3f629ded462d2520fad9486a9c8eb5d501d29c6a9f30f63ff8da128ded6f40281439371eb688fb9bc95f2377c5ca0f7 SHA512 c64b25aa69b826805cc7a3efcd63ae41bbc31a61e68cdbda90e6bcec6bd8e2c5fc47b82176d0c1708f55d2c7b082c71939b89cb0621fcf1929d1475e3d393a97
 DIST Django-4.0.3.checksum.txt 2550 BLAKE2B 19471819fb593611217ae13a7dcb6bc67a0323daa94f4a4aeee508305aa09edbbd88ea759968ac989a1971bd72df766c7651e969aa86d3cbddd65b2bb3bf7efa SHA512 573cd0b9291698bf3218d6a77c146b5cda814e99c01cc2c455bf1b5ab2c4cbf4f2f569ea14a108e658237e933a69ec1a5288c293174916f4393ecb119231b9dc
 DIST Django-4.0.3.tar.gz 10061007 BLAKE2B 1cab7d16608acc64b2bd80aeb7d25e740442411080811a2704bbb8ddbc91d86d2aeb761cbb0522a9f095d29468060959ba7f4efd902f6c3afe0f6eb06399dd11 SHA512 4de4445e8b095ad5b858a741adc21939654838ab88b368d532f87490c1c2b3b9c927410f4370e02d2883d51d6a9508f5db3be13c2358221ae687cefea034b294
+DIST Django-4.0.4.checksum.txt 2545 BLAKE2B d82f7b01f49f2b37de3cfd9eb8738e4af69c8eda0c3ed2b6d80a5f876989f36a9335640c5cd5916dcc682fcbf5453c299cb8b3f52e05f2d29413a4c75d274cbc SHA512 9889e086f35192432084fd2ae1104c316e63fa2ab0d34f6954d5eb98b810b5f2e10861a4136c480b54178d2a5453a36f3b893c7720a92f35b44cd578902a8bf9
+DIST Django-4.0.4.tar.gz 10388499 BLAKE2B f839b343bf5c2f83810f2bb22e93a91b18ccc30754589fef2931ebdf29d4600a3bf5493f9e977a3b647097c3a379ea1ef4e0e25366efb54082bc0f43ed00485f SHA512 75ecf5991763237297b458f546d245a25f62272f7013364783aea19469586fa54ce94a16323ac9a6d6b81097f8e962ea7a20f26c7afd8acda842812409215bb1
diff --git a/dev-python/django/django-2.2.28.ebuild b/dev-python/django/django-2.2.28.ebuild
new file mode 100644
index 000000000000..cc0ee416d6fd
--- /dev/null
+++ b/dev-python/django/django-2.2.28.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( sec-keys/openpgp-keys-django )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.0.7-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_prepare_all() {
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}
diff --git a/dev-python/django/django-3.2.13.ebuild b/dev-python/django/django-3.2.13.ebuild
new file mode 100644
index 000000000000..867ab2a893a8
--- /dev/null
+++ b/dev-python/django/django-3.2.13.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.3.4[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_prepare_all() {
+	# Fails because of warnings
+	sed -i 's/test_dumpdata_proxy_with_concrete/_&/' tests/fixtures/tests.py || die
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}
diff --git a/dev-python/django/django-4.0.4.ebuild b/dev-python/django/django-4.0.4.ebuild
new file mode 100644
index 000000000000..6f0e550b5fd5
--- /dev/null
+++ b/dev-python/django/django-4.0.4.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="
+	https://www.djangoproject.com/
+	https://pypi.org/project/Django/
+"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+		!!<dev-python/ipython-7.21.0-r1
+		!!=dev-python/ipython-7.22.0-r0
+	)
+	verify-sig? ( >=sec-keys/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.0-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	# TODO: this suddenly started failing
+	sed -i -e 's:test_custom_fields:_&:' tests/inspectdb/tests.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature_header "Additional Backend support can be enabled via:"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	optfeature_header
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}
diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 3401fe495722..11be5be2ebe5 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,4 +1,5 @@
 DIST ipykernel-6.10.0.tar.gz 129057 BLAKE2B e50fd0b5d041236002d29360eb670e5bcf97ad6e0eff091e62a4189567d14832b6fa95915bbd29818b897430fa3f37b930c54155a407cc46d7a9607aa19caf2b SHA512 9f2c9e24244e5c3aafbfd2da6a131cbf19abfeb8164e6a64c69aa4b65dad92101137482c71f53eb5d8395944d6714938a73556e5dbfc8a6c92303c716d6244b5
 DIST ipykernel-6.11.0.tar.gz 129429 BLAKE2B 746cff0b32a1282f8abe02bd339d35061ceb04d3f4d7fc325bc97b744185958ed91beaff83c19d269e0d8ec7b35c5c88412c135c1aa2dcbf770846986eddc82f SHA512 69b88e3c8b552f5277f392a004a33a5c64c2edc93aeea0d2c2d03b0d8ee649f41fc1378068c1dd8322807cce188f5579c0d92730760baeca8170a98f585f500b
 DIST ipykernel-6.12.1.tar.gz 129979 BLAKE2B 96ee301974c9353374b6869003995238068f4abcdaa0cf4c2b6294c1ef8c4e6358e93a41feaa49fcba587fb94ca719f3180eac2b47fbbf6c54fa9fb315d784ad SHA512 309701a287e8b87d0f8b07eac402e2fc163515f471f3b5b3187bc210c47714d4cfb496f40e34ebad47be5e7eca8157ef0eea7da141fb16a6fd943f4a2095f360
+DIST ipykernel-6.13.0.tar.gz 131331 BLAKE2B 95a662b5ff6062fd8f6712a214b2bdcb227064acec145ebbb2ff7dfc0647ee9c486bbb560502e8ab6c5f74bb44c7715a1ee16f4b8cd2661b7a6e77206be7ab67 SHA512 6025a540d7ae08f637d2cc9a022805df54c11844c93d989be73a3a800fb0985ec56f2ce5d8ee940a5ce51d41b4d1f632131b25c1f5847cb51623c285c4944f39
 DIST ipykernel-6.9.2.tar.gz 128759 BLAKE2B 74740bdbe420d14cbb75e5a1dee9bfb0894c3e10ebf029bd7ceb29eb5112489ef83bc9a2075f6dd1cf16745f893d3782ee22144edfec66d650246eaa0d97215c SHA512 a452d7a44c4e33cb2d79262916045fe3044803f20db7d525bca3277dd49e9d216d07a832312b29a5a61293ecf7863641a45e0f188136059799287c5983beb0d4
diff --git a/dev-python/ipykernel/ipykernel-6.13.0.ebuild b/dev-python/ipykernel/ipykernel-6.13.0.ebuild
new file mode 100644
index 000000000000..bb04b0b94aa8
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.13.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="https://github.com/ipython/ipykernel"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/debugpy-1.0[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
+	>=www-servers/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	ipykernel/inprocess/tests/test_kernel.py::InProcessKernelTestCase::test_pylab
+	ipykernel/tests/test_debugger.py::test_attach_debug
+	ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+	ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_set_breakpoints
+	ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+)
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
diff --git a/dev-python/jupyter/jupyter-1.0.0-r4.ebuild b/dev-python/jupyter/jupyter-1.0.0-r4.ebuild
index 9516c0b853cf..07bf807cf476 100644
--- a/dev-python/jupyter/jupyter-1.0.0-r4.ebuild
+++ b/dev-python/jupyter/jupyter-1.0.0-r4.ebuild
@@ -17,7 +17,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 x86"
 
 RDEPEND="
 	dev-python/notebook[${PYTHON_USEDEP}]
diff --git a/dev-python/lazr-config/lazr-config-2.2.3-r1.ebuild b/dev-python/lazr-config/lazr-config-2.2.3-r1.ebuild
new file mode 100644
index 000000000000..d7985e764d9f
--- /dev/null
+++ b/dev-python/lazr-config/lazr-config-2.2.3-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Create configuration schemas, and process and validate configurations"
+HOMEPAGE="https://code.launchpad.net/lazr.config"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/lazr-delegates[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace lazr
+	epytest
+}
diff --git a/dev-python/lazr-delegates/lazr-delegates-2.0.4-r1.ebuild b/dev-python/lazr-delegates/lazr-delegates-2.0.4-r1.ebuild
new file mode 100644
index 000000000000..ca0f8f4bd115
--- /dev/null
+++ b/dev-python/lazr-delegates/lazr-delegates-2.0.4-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+
+DESCRIPTION="Easily write objects that delegate behavior"
+HOMEPAGE="https://code.launchpad.net/lazr.delegates"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# strip unused rdeps
+	sed -i -e "/'setuptools'/d" -e "/'nose'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/manuel/manuel-1.10.1-r1.ebuild b/dev-python/manuel/manuel-1.10.1-r1.ebuild
new file mode 100644
index 000000000000..88d0de48d093
--- /dev/null
+++ b/dev-python/manuel/manuel-1.10.1-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Lets you mix and match traditional doctests with custom test syntax"
+HOMEPAGE="
+	https://github.com/benji-york/manuel/
+	https://pypi.org/project/manuel/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/zope-testing[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests setup.py
+
+src_prepare() {
+	# unused rdep
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/nbconvert/Manifest b/dev-python/nbconvert/Manifest
index f8cb1542fffe..cc76311e5288 100644
--- a/dev-python/nbconvert/Manifest
+++ b/dev-python/nbconvert/Manifest
@@ -1,3 +1,4 @@
 DIST nbconvert-6.4.2.tar.gz 902691 BLAKE2B ee61836ac423db0803d90b92f5cfce7e53e311637dfff7e31e5506fc1588a41515e984860bc56f617b0e0add033c41e6d2099f2abfdda7f31015f6e751110639 SHA512 325637844044ff4a118ca7803e9803fd6909667e017dae04859f58a02e1aadc8b8c699f9b9612bd47991a4c06a23acd526abdcbf1a219e29d985001ae01237bb
 DIST nbconvert-6.4.4.tar.gz 906988 BLAKE2B 84ea6726804ccb738995df1e2e961a9816d3bf9c77034d464afbfa2ba0cf3ce19c1f6af1775fa027795ba3faeaacac765decce2d309f8a60a27e76934cdb356a SHA512 2b319fcc13c6b2addc7e1ca319f36e8a37e8390eb0d8d8df9f9456e7ae816b93ec30ab00a1003894c92091030658920729f0e31fdb5031dccb3f36b38b5d8f99
 DIST nbconvert-6.4.5.tar.gz 906309 BLAKE2B 5aee22eb9ce6bb36e04cc3b3db5460041b0a2dfb4afeb1e4787e941d6815f22b7621104ca6d14cb0977c5d09f9a0fade8a5787416b5f55ca1b09149730560bf7 SHA512 9a32eceaff065016baea9fc79478aeb8981f55a2cd47889e640815f2bf924df201d9ce72a4b615d533bcadbd681900678d30de61f777ae4f12bd9fce62d73622
+DIST nbconvert-6.5.0.tar.gz 908377 BLAKE2B a91c6c93e9e33f90c5c7f19743e20aa6cf88e5dd29be4ee777744d96037dddd15294858776c8391d79f5436e929fb1b623a3f11f6c4cbcf60728dba2204b6e2e SHA512 4e0d26d581435525f819c05207890cc7cbeaff786a16c354f0356c9bc50111a724a92b7e15445a0cf0ebf1e1c2f0ff064a2c8722267f66dd8677ad82b5e61714
diff --git a/dev-python/nbconvert/nbconvert-6.5.0.ebuild b/dev-python/nbconvert/nbconvert-6.5.0.ebuild
new file mode 100644
index 000000000000..1b0fb39ed095
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-6.5.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="https://nbconvert.readthedocs.io/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-2.0[${PYTHON_USEDEP}]
+	>=dev-python/mistune-0.8.1[${PYTHON_USEDEP}]
+	<dev-python/mistune-2[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.1[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		nbconvert/exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		'nbconvert/tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	epytest --pyargs nbconvert
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}
diff --git a/dev-python/paste/paste-3.5.0-r1.ebuild b/dev-python/paste/paste-3.5.0-r1.ebuild
new file mode 100644
index 000000000000..3529b5d4c51a
--- /dev/null
+++ b/dev-python/paste/paste-3.5.0-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_P="Paste-${PV}"
+DESCRIPTION="Tools for using a Web Server Gateway Interface stack"
+HOMEPAGE="https://pypi.org/project/Paste/"
+SRC_URI="mirror://pypi/${MY_P::1}/${PN^}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris"
+
+RDEPEND="
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs
+
+EPYTEST_DESELECT=(
+	# Internet
+	tests/test_proxy.py
+)
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/pastedeploy/pastedeploy-2.1.1-r2.ebuild b/dev-python/pastedeploy/pastedeploy-2.1.1-r2.ebuild
new file mode 100644
index 000000000000..119d0f9a549d
--- /dev/null
+++ b/dev-python/pastedeploy/pastedeploy-2.1.1-r2.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="PasteDeploy"
+MY_P="${MY_PN}-${PV}"
+DESCRIPTION="Load, configure, and compose WSGI applications and servers"
+HOMEPAGE="https://pypi.org/project/PasteDeploy/"
+# pypi tarball does not include tests
+SRC_URI="https://github.com/Pylons/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-solaris"
+
+PATCHES=(
+	"${FILESDIR}/${P}-change-sphinx-theme.patch"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/pdm-pep517/Manifest b/dev-python/pdm-pep517/Manifest
index 299d0166e621..3d4a51949a46 100644
--- a/dev-python/pdm-pep517/Manifest
+++ b/dev-python/pdm-pep517/Manifest
@@ -1,2 +1 @@
-DIST pdm-pep517-0.12.1.gh.tar.gz 303954 BLAKE2B 65344c2571264b9fadcffcf5ae05f42246912dce3e7029a1ea5e91df72f1c9425d603024099146cb7d9ed95d8e3ab0fcf5058ab35346893e28d3595d430548f6 SHA512 a7c27c685eec274798b5d9fa7fd3d7ec7ca77d204110c7c9962a53b1522c4c6dbc56d7413ce5ff6fe8e8f091b0d4e4914b9e3296dc226bcae9f5fbc2cb28444e
 DIST pdm-pep517-0.12.3.gh.tar.gz 304242 BLAKE2B ad4beb6ab35c219e1991b585bf9ce087be3e7e957f34b1dbc9de676f7b49c3084471e2b55c634eb6fd1cf6cb88dd4161b5060a17a5ca7e5e3ae57c9610303f6e SHA512 4c0f098d5237353fea73ef62149b8177987881239cb6b1b112bd6789931acd7484c56d413f780db4f23c60f4ff3a37c6956de3e1de472fed114487925b0e3553
diff --git a/dev-python/pdm-pep517/pdm-pep517-0.12.1.ebuild b/dev-python/pdm-pep517/pdm-pep517-0.12.1.ebuild
deleted file mode 100644
index 845cc21c1891..000000000000
--- a/dev-python/pdm-pep517/pdm-pep517-0.12.1.ebuild
+++ /dev/null
@@ -1,58 +0,0 @@
-# Copyright 2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=standalone
-PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
-HOMEPAGE="
-	https://pypi.org/project/pdm-pep517/
-	https://github.com/pdm-project/pdm-pep517/
-"
-SRC_URI="
-	https://github.com/pdm-project/pdm-pep517/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	>=dev-python/cerberus-1.3.4[${PYTHON_USEDEP}]
-	dev-python/license-expression[${PYTHON_USEDEP}]
-	>=dev-python/packaging-21.0[${PYTHON_USEDEP}]
-	>=dev-python/tomli-2[${PYTHON_USEDEP}]
-	dev-python/tomli-w[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	${RDEPEND}
-	test? (
-		dev-vcs/git
-	)
-"
-# setuptools are used to build C extensions
-RDEPEND+="
-	dev-python/setuptools[${PYTHON_USEDEP}]
-"
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	rm -r pdm/pep517/_vendor || die
-	find -name '*.py' -exec sed \
-		-e 's:from pdm\.pep517\._vendor\.:from :' \
-		-e 's:from pdm\.pep517\._vendor ::' \
-		-i {} + || die
-	distutils-r1_src_prepare
-}
-
-src_test() {
-	git config --global user.email "test@example.com" || die
-	git config --global user.name "Test User" || die
-	distutils-r1_src_test
-}
diff --git a/dev-python/python-lsp-black/python-lsp-black-1.2.0.ebuild b/dev-python/python-lsp-black/python-lsp-black-1.2.0.ebuild
index 101959c2dc5f..968a820b2008 100644
--- a/dev-python/python-lsp-black/python-lsp-black-1.2.0.ebuild
+++ b/dev-python/python-lsp-black/python-lsp-black-1.2.0.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 
 RDEPEND="
 	>=dev-python/python-lsp-server-1.4.0[${PYTHON_USEDEP}]
diff --git a/dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild b/dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild
index b5760231b763..9e83223de03d 100644
--- a/dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild
+++ b/dev-python/ruamel-std-pathlib/ruamel-std-pathlib-0.9.2-r1.ebuild
@@ -30,11 +30,6 @@ python_compile() {
 }
 
 python_test() {
-	# this is needed to keep the tests working while
-	# dev-python/namespace-ruamel is still installed
-	cat > "${BUILD_DIR}/install$(python_get_sitedir)"/ruamel/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace ruamel
 	epytest
-	rm "${BUILD_DIR}/install$(python_get_sitedir)"/ruamel/__init__.py || die
 }
diff --git a/dev-python/ruamel-yaml/ruamel-yaml-0.17.21-r1.ebuild b/dev-python/ruamel-yaml/ruamel-yaml-0.17.21-r1.ebuild
index 0a4289fb8bd1..274f8e8604f3 100644
--- a/dev-python/ruamel-yaml/ruamel-yaml-0.17.21-r1.ebuild
+++ b/dev-python/ruamel-yaml/ruamel-yaml-0.17.21-r1.ebuild
@@ -52,9 +52,6 @@ python_test() {
 
 	# this is needed to keep the tests working while
 	# dev-python/namespace-ruamel is still installed
-	cat > "${BUILD_DIR}/install$(python_get_sitedir)"/ruamel/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace ruamel
 	epytest
-	rm "${BUILD_DIR}/install$(python_get_sitedir)"/ruamel/__init__.py || die
 }
diff --git a/dev-python/sphinxcontrib-bibtex/sphinxcontrib-bibtex-2.4.2.ebuild b/dev-python/sphinxcontrib-bibtex/sphinxcontrib-bibtex-2.4.2.ebuild
index bc740e6d7c95..94c6b11bc598 100644
--- a/dev-python/sphinxcontrib-bibtex/sphinxcontrib-bibtex-2.4.2.ebuild
+++ b/dev-python/sphinxcontrib-bibtex/sphinxcontrib-bibtex-2.4.2.ebuild
@@ -37,11 +37,6 @@ python_compile() {
 }
 
 python_test() {
-	# this is needed to keep the tests working while
-	# dev-python/namespace-sphinxcontrib is still installed
-	cat > "${BUILD_DIR}/install$(python_get_sitedir)/sphinxcontrib/__init__.py" <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace sphinxcontrib
 	epytest
-	rm "${BUILD_DIR}/install$(python_get_sitedir)/sphinxcontrib/__init__.py" || die
 }
diff --git a/dev-python/tempest/Manifest b/dev-python/tempest/Manifest
index 1e820dd27853..06deed59195f 100644
--- a/dev-python/tempest/Manifest
+++ b/dev-python/tempest/Manifest
@@ -1 +1,2 @@
 DIST tempest-30.0.0.tar.gz 1110715 BLAKE2B b697ecbced21124719e6b1d7ebd2c4f8ba83528a84da0b8f8109c155b61124581b97c180bbdc6885ae53850fb28daed25772d12be5026c44ecc3fe4f0dad98a3 SHA512 fa9be713ccb130ad065628592f59bebda3dc1fa8222ab3c382ec5b299504dc0a730f2110ef80f98bbdd1288b5785ab745fe39b721b77f7343983c1bc0a036f19
+DIST tempest-30.1.0.tar.gz 1112219 BLAKE2B 864dbd01a843b9c480656788a3a673ea6c089af8bf67e66837fdb77ee46eef00f2caed3ee08722b113db45d1e39fee167dcb344676543ec82fe5f022ae8c713d SHA512 3c4469d5ab590fe2185dbe77cc1ca1179022b75b4da9f2fe0d43956b14598d56328dd4e62e8445197b25f93017c812edd75cb9fef2d81ae183aea478fd817b15
diff --git a/dev-python/tempest/tempest-30.1.0.ebuild b/dev-python/tempest/tempest-30.1.0.ebuild
new file mode 100644
index 000000000000..7e94279ebab9
--- /dev/null
+++ b/dev-python/tempest/tempest-30.1.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenStack Integration Testing"
+HOMEPAGE="https://pypi.org/project/tempest/ https://docs.openstack.org/tempest/latest/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>dev-python/cliff-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/paramiko-2.7.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/oslo-concurrency-3.26.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-config-5.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.12[${PYTHON_USEDEP}]
+	>=dev-python/subunit-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.21.1[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		dev-python/stestr[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Small subset of tests, which fail as result of not using specific
+	# testing environment. Others expect to run suite using stestr.
+	rm -r tempest/tests/lib/services/volume/v3/ || die
+	rm tempest/tests/test_list_tests.py || die
+	rm tempest/tests/lib/cmd/test_check_uuid.py || die
+
+	# remove dep on hacking
+	rm tempest/tests/test_hacking.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	mv "${BUILD_DIR}"/install/{usr/,}etc || die
+}
+
+python_test() {
+	local -x OS_LOG_CAPTURE=1 OS_STDOUT_CAPTURE=1 OS_STDERR_CAPTURE=1 OS_TEST_TIMEOUT=320
+	eunittest -b -s tempest/tests -t .
+}
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index bb4c9d3b1e8c..48fb4950b406 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-3.24.5.tar.gz 306305 BLAKE2B a6d3338d21068d9123505a29da3beec4fd5a15c263bcaf5ba62f65a253d04e11d453bef159d06e88b2cbac9a895d786d0d9444cc16cd3de7a868eac6919b82ea SHA512 4e1ef81c978977e905edbdc00ff971eb4132b9009ce21456fcebf95d8ee2c583e04e464f1db5ca6e5454f4f1ad0353ffc9df7898f6389fe8084dc5b9726ca59b
+DIST tox-3.25.0.tar.gz 307073 BLAKE2B 2dda34fc6d6518897bdc587ca6a31b92f2add463c3bcce9df3f4e511d2588dc75265b60809195c2d78a9c1b0d08d79c32811aab1e2c01934faf40019a1882042 SHA512 9c10524c5a67b32a01cb0dd4d25cc01d0641e46ca4e0c03a4c76eb8913f6038075aeb21e647a94d6b8d99c80edb7701b1c62893ebd6a20584121fdf33b9d9010
diff --git a/dev-python/tox/tox-3.25.0.ebuild b/dev-python/tox/tox-3.25.0.ebuild
new file mode 100644
index 000000000000..9f36d1750273
--- /dev/null
+++ b/dev-python/tox/tox-3.25.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="https://tox.readthedocs.io https://github.com/tox-dev/tox https://pypi.org/project/tox/"
+SRC_URI="https://github.com/tox-dev/tox/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+# doc disabled because of missing deps in tree
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-0.12[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/py[${PYTHON_USEDEP}]
+	>=dev-python/six-1.14[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-16.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=dev-python/flaky-3.4.0[${PYTHON_USEDEP}]
+		>=dev-python/freezegun-0.3.11[${PYTHON_USEDEP}]
+		>=dev-python/pytest-4.0.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken without Internet
+		tests/unit/session/test_provision.py::test_provision_non_canonical_dep
+		tests/integration/test_provision_int.py::test_provision_interrupt_child
+
+		# expects python2 to exist
+		tests/unit/interpreters/test_interpreters.py::test_tox_get_python_executable
+
+		# fragile and relies on checking stdout
+		tests/unit/util/test_spinner.py::test_spinner_progress
+
+		# TODO
+		tests/unit/test_z_cmdline.py::TestSession::test_summary_status
+		tests/unit/session/test_provision.py::test_provision_bad_requires
+	)
+
+	[[ ${EPYTHON} != pypy3 ]] && EPYTEST_DESELECT+=(
+		# TODO?
+		tests/unit/interpreters/test_interpreters.py::test_find_alias_on_path
+
+		# broken without tox installed first
+		# TODO: why it can't import itself?
+		tests/integration/test_parallel_interrupt.py::test_parallel_interrupt
+	)
+
+	epytest --no-network
+}
diff --git a/dev-python/twisted/Manifest b/dev-python/twisted/Manifest
index 0cf381dc2d64..1f2f17157a06 100644
--- a/dev-python/twisted/Manifest
+++ b/dev-python/twisted/Manifest
@@ -1,3 +1,4 @@
 DIST twisted-22.1.0.tar.gz 3883519 BLAKE2B 0b438481af94fbfe08c7470a71421e176ca4994efaf7144b2bd3bc7e69c774295e04831d5356af104d087d970856c1c153b30331cb1598226f83e761b624a53c SHA512 1db52865d00e07044bc755b25bef2fa260cf269a8b51512bec97a015fa484d0b331b41154b52f97b5e8c477d3e5ad1d003f5ac15c7361988d073d097c6e7355d
 DIST twisted-22.2.0.tar.gz 3887750 BLAKE2B 43b50aa33f9a70f2123930ebfc0e9fec08a6faa791dc8fb73c1252fc1de3e00844e421f653d920e5f651aff89557750c6dc6c4557689e01bc9a0793c15de8eea SHA512 a2f66055f0ea6658a04888316b9eb90bd0f389c72db8315fe1722a70f16bb290805d98acc8cfd8a5d22b4817683603aaea50bb04a204927898bd74fc58a1db6d
+DIST twisted-22.4.0.tar.gz 3896724 BLAKE2B 830a724156473a28394e6c731f6cec184c491410dc880bc2e37a99cb460c7fe040219463f224941532b12478abe953aa0228c70676e5baecda4a3b2bdd6a0a32 SHA512 776d36040bcefb9ca65e471d9058fe1067ffc8171a501cb451e9d4824a88dd83f79dc9b27a127ca898451587454ee661000acbce6c4c39b069aeadd64710f103
 DIST twisted-regen-cache.gz 911 BLAKE2B ffd3fcda6c67ffe6fd3ef581c8d507548396b66ed0708e9a5c790095e579c0d5f0f71596acf05712989da2ddef2b8d437eca973bc4d80ef8a9fa852915f38305 SHA512 95a9b931c73017d16d1b5e6b41345dddffe62b6af1a8e93b5e40d06d3d15be17b0dd0181c767ffeeb791534d463764ef9e066fa6c2ee2ac4b53c86d1da8fce03
diff --git a/dev-python/twisted/twisted-22.4.0.ebuild b/dev-python/twisted/twisted-22.4.0.ebuild
new file mode 100644
index 000000000000..7a9ec0f28aa4
--- /dev/null
+++ b/dev-python/twisted/twisted-22.4.0.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="An asynchronous networking framework written in Python"
+HOMEPAGE="https://www.twistedmatrix.com/trac/"
+SRC_URI="
+	https://github.com/twisted/twisted/archive/${P}.tar.gz
+	https://dev.gentoo.org/~mgorny/dist/twisted-regen-cache.gz
+"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="conch crypt http2 serial test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/automat-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+	>=dev-python/hyperlink-17.1.1[${PYTHON_USEDEP}]
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pyhamcrest-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.6.5[${PYTHON_USEDEP}]
+	>=dev-python/zope-interface-4.4.2[${PYTHON_USEDEP}]
+	conch? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.5.0[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+	)
+	crypt? (
+		>=dev-python/pyopenssl-16.0.0[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+		>=dev-python/idna-0.6[${PYTHON_USEDEP}]
+	)
+	serial? ( >=dev-python/pyserial-3.0[${PYTHON_USEDEP}] )
+	http2? (
+		>=dev-python/h2-3.0.0[${PYTHON_USEDEP}]
+		<dev-python/h2-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/priority-1.1.0[${PYTHON_USEDEP}]
+		<dev-python/priority-2.0[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/incremental-21.3.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/appdirs-1.4.0[${PYTHON_USEDEP}]
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		>=dev-python/constantly-15.1.0[${PYTHON_USEDEP}]
+		dev-python/cython-test-exception-raiser[${PYTHON_USEDEP}]
+		dev-python/idna[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pyserial[${PYTHON_USEDEP}]
+		net-misc/openssh
+		$(python_gen_cond_dep '
+			dev-python/gmpy[${PYTHON_USEDEP}]
+		' 'python*')
+		!alpha? ( !hppa? ( !ia64? (
+			>=dev-python/cryptography-0.9.1[${PYTHON_USEDEP}]
+			>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+			dev-python/service_identity[${PYTHON_USEDEP}]
+		) ) )
+	)
+"
+
+PATCHES=(
+	# https://twistedmatrix.com/trac/ticket/10200
+	"${FILESDIR}/${PN}-22.1.0-force-gtk3.patch"
+)
+
+python_prepare_all() {
+	# upstream test for making releases; not very useful and requires
+	# sphinx (including on py2)
+	rm src/twisted/python/test/test_release.py || die
+
+	# puts system in EMFILE state, then the exception handler may fail
+	# trying to open more files due to some gi magic
+	sed -e '/SKIP_EMFILE/s:False:True:' \
+		-i src/twisted/internet/test/test_tcp.py || die
+
+	# multicast tests fail within network-sandbox
+	sed -e 's:test_joinLeave:_&:' \
+		-e 's:test_loopback:_&:' \
+		-e 's:test_multiListen:_&:' \
+		-e 's:test_multicast:_&:' \
+		-i src/twisted/test/test_udp.py || die
+
+	# These tests rely on warnings which seems work unreliably between python versions
+	sed -e 's:test_currentEUID:_&:' \
+		-e 's:test_currentUID:_&:' -i src/twisted/python/test/test_util.py || die
+
+	# broken by new expat
+	sed -e 's:test_namespaceWithWhitespace:_&:' \
+		-i src/twisted/words/test/test_domish.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	# the test suite handles missing file & failing ioctl()s gracefully
+	# but not permission errors from sandbox
+	addwrite /dev/net/tun
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" -m twisted.trial twisted ||
+		die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# own the dropin.cache so we don't leave orphans
+	> "${D}$(python_get_sitedir)"/twisted/plugins/dropin.cache || die
+
+	python_doscript "${WORKDIR}"/twisted-regen-cache
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	newconfd "${FILESDIR}/twistd.conf" twistd
+	newinitd "${FILESDIR}/twistd.init" twistd
+}
+
+python_postinst() {
+	twisted-regen-cache || die
+}
+
+pkg_postinst() {
+	if [[ -z ${ROOT} ]]; then
+		python_foreach_impl python_postinst
+	fi
+}
+
+python_postrm() {
+	rm -f "${ROOT}$(python_get_sitedir)/twisted/plugins/dropin.cache" || die
+}
+
+pkg_postrm() {
+	# if we're removing the last version, remove the cache file
+	if [[ ! ${REPLACING_VERSIONS} ]]; then
+		python_foreach_impl python_postrm
+	fi
+}
diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index 6085d7c7ebf6..16f61fec3287 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,3 +1,4 @@
 DIST virtualenv-20.13.3.tar.gz 12152717 BLAKE2B 791eff66e02d0e7b563d68136cf9652ca0e7422cde94ddf558053778e7677937f7f3ddd9e2d6d0a5fd56c79d9061474685b39aa8519471cea230f4dc5ea71c83 SHA512 e9e05e6e6aba10bb6c0813484f508aede9fe2a78401272bb12ea68b80e8f4059f4292de51e37c2487efb92d27f6eeda6e108dd12f45623984966d8fe821352c0
 DIST virtualenv-20.13.4.tar.gz 12153741 BLAKE2B 050553253f2576917b71eccb94b9a4f370d8c131c61fd84e1d4e6445181c793435ca7ce988ff62cffedb406d357c52337ba5ad921f1837ac29d81896958b58e0 SHA512 d2800ce3830ac154e9c0f03fe96535286a4322b89ef94c01638065ec353ee1dc439f7dbdbd9647836e514e828781c5a48fce3723f80c32bfa9ce96243610a396
 DIST virtualenv-20.14.0.tar.gz 12209889 BLAKE2B d6b89f71009109ec688045b92fa2907baa2a174a8736b66e3635b125d05f9cedf2b0cf26497e47193d3c99d44b94b899205e8b94d20beeeacab0b22b47e3eb41 SHA512 c4f1b40187d847602cb2ccef1be9ecce6acd234d08abf5967219d8cf900e641337ce027018c2cca566409a5ab3dda1f363d7381a0d2f676000c04e10677bfada
+DIST virtualenv-20.14.1.tar.gz 12216889 BLAKE2B 7d06b47629dcf4a60299b9b0a192478b20ef820b8a7516569e50b57b2df383781e7e14fd4beda14a3425164997e69c8ed922edb593f86eb3bd85e4ee3a9f2ac1 SHA512 149e78787db23eabd4238baa172bf023ddcf87d59284fdd090269acfa15991aab182f9e168851f88ef810d5c50dd7cdce69d132c46ebedb10080d65a308e63a1
diff --git a/dev-python/virtualenv/virtualenv-20.14.1.ebuild b/dev-python/virtualenv/virtualenv-20.14.1.ebuild
new file mode 100644
index 000000000000..7e24a17889ab
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.14.1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/backports-entry_points_selectable-1.0.4[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.1[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-freezegun-0.4.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	)
+"
+
+# (unpackaged deps)
+#distutils_enable_sphinx docs \
+#	dev-python/sphinx-argparse \
+#	dev-python/sphinx_rtd_theme \
+#	dev-python/towncrier
+distutils_enable_tests pytest
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/unit/activation/test_xonsh.py
+		tests/unit/seed/embed/test_bootstrap_link_via_app_data.py::test_seed_link_via_app_data
+		tests/unit/create/test_creator.py::test_cross_major
+	)
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-pypy3-posix-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[root-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-isolated]'
+		'tests/unit/create/test_creator.py::test_create_no_seed[venv-venv-copies-global]'
+		'tests/unit/create/test_creator.py::test_zip_importer_can_import_setuptools'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[PyPy-3--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.9--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7.10--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3.7--bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3-64-bin-]'
+		'tests/unit/discovery/py_info/test_py_info_exe_based_of.py::test_discover_ok[python-3--bin-]'
+	)
+
+	epytest
+}
+
+pkg_postinst() {
+	elog "Please note that while virtualenv package no longer supports"
+	elog "Python 2.7, you can still create py2.7 virtualenvs via:"
+	elog "  $ virtualenv -p 2.7 ..."
+}
diff --git a/dev-python/zope-component/zope-component-4.4.1-r1.ebuild b/dev-python/zope-component/zope-component-4.4.1-r1.ebuild
index c2976b085a87..c5e4e4006691 100644
--- a/dev-python/zope-component/zope-component-4.4.1-r1.ebuild
+++ b/dev-python/zope-component/zope-component-4.4.1-r1.ebuild
@@ -49,11 +49,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-configuration/zope-configuration-4.4.1-r1.ebuild b/dev-python/zope-configuration/zope-configuration-4.4.1-r1.ebuild
index 4cc62bb787f1..92156d337e39 100644
--- a/dev-python/zope-configuration/zope-configuration-4.4.1-r1.ebuild
+++ b/dev-python/zope-configuration/zope-configuration-4.4.1-r1.ebuild
@@ -51,11 +51,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-deprecation/zope-deprecation-4.4.0-r1.ebuild b/dev-python/zope-deprecation/zope-deprecation-4.4.0-r1.ebuild
index 4388c9eeb50f..90b38194f029 100644
--- a/dev-python/zope-deprecation/zope-deprecation-4.4.0-r1.ebuild
+++ b/dev-python/zope-deprecation/zope-deprecation-4.4.0-r1.ebuild
@@ -37,11 +37,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-event/zope-event-4.5.0-r2.ebuild b/dev-python/zope-event/zope-event-4.5.0-r2.ebuild
index a48e889f3f0f..8d20fe7586a3 100644
--- a/dev-python/zope-event/zope-event-4.5.0-r2.ebuild
+++ b/dev-python/zope-event/zope-event-4.5.0-r2.ebuild
@@ -37,11 +37,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-exceptions/zope-exceptions-4.5.ebuild b/dev-python/zope-exceptions/zope-exceptions-4.5.ebuild
index 26ffee12c0a9..b846fc939ebe 100644
--- a/dev-python/zope-exceptions/zope-exceptions-4.5.ebuild
+++ b/dev-python/zope-exceptions/zope-exceptions-4.5.ebuild
@@ -40,11 +40,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.0.1-r1.ebuild b/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.0.1-r1.ebuild
index 5a71bfded8d7..c7462d240d43 100644
--- a/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.0.1-r1.ebuild
+++ b/dev-python/zope-i18nmessageid/zope-i18nmessageid-5.0.1-r1.ebuild
@@ -41,11 +41,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-interface/zope-interface-5.4.0-r1.ebuild b/dev-python/zope-interface/zope-interface-5.4.0-r1.ebuild
index f8f341f52ca8..aaf67755c7ee 100644
--- a/dev-python/zope-interface/zope-interface-5.4.0-r1.ebuild
+++ b/dev-python/zope-interface/zope-interface-5.4.0-r1.ebuild
@@ -46,11 +46,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild b/dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild
index aebe64da5975..59dc7d8f4504 100644
--- a/dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild
+++ b/dev-python/zope-schema/zope-schema-6.2.0-r1.ebuild
@@ -48,11 +48,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }
diff --git a/dev-python/zope-testing/zope-testing-4.10-r1.ebuild b/dev-python/zope-testing/zope-testing-4.10-r1.ebuild
index ac80fe188f3a..43613ec9d9a2 100644
--- a/dev-python/zope-testing/zope-testing-4.10-r1.ebuild
+++ b/dev-python/zope-testing/zope-testing-4.10-r1.ebuild
@@ -38,11 +38,6 @@ python_compile() {
 
 python_test() {
 	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
-	# this is needed to keep the tests working while
-	# dev-python/namespace-zope is still installed
-	cat > zope/__init__.py <<-EOF || die
-		__path__ = __import__('pkgutil').extend_path(__path__, __name__)
-	EOF
+	distutils_write_namespace zope
 	eunittest
-	rm zope/__init__.py || die
 }