Adding metadata

14 files changed, 317 insertions, 0 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 2e10d6a69527..14fe92b58b05 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -11,3 +11,4 @@ DIST boto3-1.17.86.tar.gz 378144 BLAKE2B 35d6bfec515c985ead488811e7f2ad021f671e8
 DIST boto3-1.17.87.tar.gz 378759 BLAKE2B 21ad4c735f34edbd82767043653ed0cee9604f0b36328f40cb22c4f9cd57758e0bc89ae93fd798babc1dded019e2b1531bbffa0574edd7ce3e07515374cd97cf SHA512 da3f2cb772d3f9708f5cbb102907ef58622435d4acdec8fe0abde80511f0734e6cc9739f0652150edc9e4f12039c0c7ee62bcc0059b42d86d5af0e809d779fab
 DIST boto3-1.17.88.tar.gz 379248 BLAKE2B 1aa238efaf5a22594b90903e1090f4f66a04effe93c3506ad36e0a96aa607eef9506f6fc579981a919b0f55ab1ba7a5d7e02a22a3d2692a9442f143a63f1b282 SHA512 989f8f879bdcded758f7b0be93e9355f91be859de7f2eabc7760cb8ad6e3317fa999cc5c092aac53bb2645ea0a86d0a6ceb03237b5164b89850b8c34d3eebdb5
 DIST boto3-1.17.89.tar.gz 379572 BLAKE2B 8a067aa757974cc3399de29173a6fcf99d35196c64978bd0cdb4e85f6e50558c9584722fab3402f3b3a2f951b3cd801aada17ce70bceab4f215f1b91dffd6372 SHA512 6bae209eda16ee07b142fe56740a5e177378b88e66b0e5c6aac99748c59b34f28f0c78d863d5a76b9efeda6413c4e6aab94d3c9ee87fbc5ae7d9c8bf02b5fb3f
+DIST boto3-1.17.90.tar.gz 379938 BLAKE2B 72392968678576505a4c80f62ca0b3f7cf086a7c739a918b6d39d7c8b05a2a1b9648d7028126bb6c2893da44bc9bd5367089beb12a187d48c09712f2b6d7a95a SHA512 75f2d02c1256a2a60a4f87d774d5a339e556180482419c21774ec41a5980fd0149e7d66f52cb408035b394550bbbdcb2710de1fd6f948cccd91064e5d94f20ca
diff --git a/dev-python/boto3/boto3-1.17.90.ebuild b/dev-python/boto3/boto3-1.17.90.ebuild
new file mode 100644
index 000000000000..76a508785b03
--- /dev/null
+++ b/dev-python/boto3/boto3-1.17.90.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index da79f9654c25..65ba9e3110e0 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -11,3 +11,4 @@ DIST botocore-1.20.86.tar.gz 7798788 BLAKE2B 93450262bf1e34a627a64f8972e4d8b02dc
 DIST botocore-1.20.87.tar.gz 7800088 BLAKE2B ba98b0f910216a340f48adb5ddf14aa9239ca44202641c97ca91da69f34a67716c50d9bc6a330021fd630f7c309062fc0326543e46ee1207c294870baefd0aeb SHA512 b922e40030a1708ce2e5a2fa60012e21e28b955c6d30fbced5d1a93dafe189e83430b5cee162e2ab73e80c7dfa18657c2ca42057c17e943c0d421c6cd9969b53
 DIST botocore-1.20.88.tar.gz 7806185 BLAKE2B 21c3e3420fc9810712a462cfab4f43509ebd25a4cbaee4a51f2d82cc90a530c4a170b66cb6551121148d284404427eca7d9dd979ead5a9f4132ded47b4adf180 SHA512 aa36c39147d870758b9561e569f6b8a616e69437d775b1f68d522574a24f0e8252e5332d6e20b92448bc3189ec50232d89134bf86d12a3b72d63962de0d9cda6
 DIST botocore-1.20.89.tar.gz 7808318 BLAKE2B cc160b85d7e85267aa4bd7140c8f90b33dc07e5b8c0cf2cd4761ea456dfa955bd95b500e8da89bd9cca70237edcbd7df45c8f1d543e4e67646a8e597a5516fb5 SHA512 41fd7cf61b8eddb3e467d6d6b115c53e75413bdd3bb181723dd48c6efdd7133eee45ac597bf207482b2aa5872bf79d7801176194e474c61614599119df67db5a
+DIST botocore-1.20.90.tar.gz 7810567 BLAKE2B f34ce1e4ed16254585a90e3ba1674a35909169a0a73a216e0b5d60609567133ce1257fc3b48a21e3c707b42db546612f40263e20fb68eba1e01cc3560ed5ef15 SHA512 4765abfe9913bb214d1c4aeacc00f5b5745322121bbb1e652705fbd63a9801476e513596078f833306834047f42b39edc9de31939f02860476fdb825f4b654b1
diff --git a/dev-python/botocore/botocore-1.20.90.ebuild b/dev-python/botocore/botocore-1.20.90.ebuild
new file mode 100644
index 000000000000..ca62b7dad65f
--- /dev/null
+++ b/dev-python/botocore/botocore-1.20.90.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/google-api-core/Manifest b/dev-python/google-api-core/Manifest
index 575a88003575..9d97412fe442 100644
--- a/dev-python/google-api-core/Manifest
+++ b/dev-python/google-api-core/Manifest
@@ -2,3 +2,4 @@ DIST google-api-core-1.26.3.tar.gz 133409 BLAKE2B ca3c63769f87cc79483d5ac52646cb
 DIST google-api-core-1.27.0.tar.gz 134035 BLAKE2B be074208ac51b6e33466a2304e5780894d6a420ccf7ea36e5b98b6d9f920cd6f0cc9f94dababb154731ebe4a36d8b863897f5c654e00068a0f12753ceecb6e8c SHA512 5e8ca58c7f1dc9aa3e612ea635feb84a115c0f21bde2a3152cd54be5b041841ab1c0d2c725660794e15d42e63a4b6955a5318d3dec20bbbb3e7d683c630a5f5e
 DIST google-api-core-1.28.0.tar.gz 133640 BLAKE2B 8134e39cc3ff2fbb850d5e774d08589e3e64b83ca5d5209279f5d1b7fc2eb350a523bbe2890fba6d907689149df3872a7e0a11991b1ecc62fc64a4753dce38e4 SHA512 3702d27613e621394209047451729c1308beb88c917033b4340e3fa96bf4a5ec36ad2594c98ed14439c578f69a202d95a96d30472438a30417484cff6e06fe7d
 DIST google-api-core-1.29.0.tar.gz 134251 BLAKE2B 46455f34ad18bd57b21afe70b237466a51d5dbaca8f46f31491d00fcc7e6339fcf48e150418ef71100a628245cc5333984e6377e27eec00b9b55e0c1a3de86e2 SHA512 b8a7b19ba737172e04c0a322af7c60299b72002b17a099fbaa9445c4965b94fd6f3087380fa4262f4440113af4304d5235cd062f22c27cd997e62b276ea67471
+DIST google-api-core-1.30.0.tar.gz 134595 BLAKE2B 104f52bafb68fd91904c02cbd6d3dd2e32c160a528f58e9af3612fc4f7a9934c522f79895b50982b46ee77947af7eb52557bf304b6f2624b97b5082905511829 SHA512 cc14f9c67bac99290665e2b85a97eacf43cdd2a0e4668ecbc7dd8e7131a7e4e908aca2be6d65797d0838081a02768354703762a1a80fa0b666efb81448b27899
diff --git a/dev-python/google-api-core/google-api-core-1.30.0.ebuild b/dev-python/google-api-core/google-api-core-1.30.0.ebuild
new file mode 100644
index 000000000000..b40ab82c7645
--- /dev/null
+++ b/dev-python/google-api-core/google-api-core-1.30.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Core Library for Google Client Libraries"
+HOMEPAGE="https://github.com/googleapis/python-api-core
+	https://googleapis.dev/python/google-api-core/latest"
+SRC_URI="https://github.com/googleapis/${PN//google/python}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P//google/python}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/googleapis-common-protos[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.25.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/rsa[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${D}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index f012f658b6b5..53efc753e3d8 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1,2 +1,3 @@
 DIST google-api-python-client-2.4.0.tar.gz 24853833 BLAKE2B 4ed2083a9bb8b4f8fe31ab5dbd7875c0c36c972cdb0f71a59565fe4eb23ff1ef0a40794acd7af9646c1ee3904fbab3caaeb2700a3660b66d3069d2bc4f811e76 SHA512 db545850b9d2746e3bcf7b4a2f12b0d4827bd68f44d5627fd80d39bff2ca3303c8d520f72ee17637fe700bc935548706ce885ff0d7fe737ae157668e0314fbc6
 DIST google-api-python-client-2.7.0.tar.gz 25488451 BLAKE2B a8a761944fed3970ae0cf53b2cb926a6670ac37323c39085a5f7fb4f354451292fca4bbb2c34a72d086dfa961b74a72f66319f6bbc2505ef70f5c94aff3f7a0e SHA512 531e919cc9d0cffc49b31d881a6ee3adb2d9cc166813b5884c300e9a3b63b28c9c269a0d1efe47961fa61f79ec5adb8a12e2208b644fd62ed4baa66c56d219ba
+DIST google-api-python-client-2.8.0.tar.gz 25286774 BLAKE2B b21aebda062984b9eb8f2f5c563016f0f8f663883dc8ddb913053ff3df32c652c6a83f924f3e19136e5edec085e12c43cc584bc9898630122c77a219810033bc SHA512 cc3c55438b2f5835b52d17d04a749919c4865991ff78cf95920d0941a55e1493eae502a13f6565cfe1db799ce9950659e8baaa690bada058d711309861c8d07e
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.8.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.8.0.ebuild
new file mode 100644
index 000000000000..65426126077e
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.8.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.16.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.13.0[${PYTHON_USEDEP}]
+	<dev-python/six-2[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests --install pytest
+
+python_test() {
+	local deselect=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	distutils_install_for_testing
+	epytest ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/google-auth/Manifest b/dev-python/google-auth/Manifest
index 768c1902f01c..97f2bab4a104 100644
--- a/dev-python/google-auth/Manifest
+++ b/dev-python/google-auth/Manifest
@@ -1,2 +1,3 @@
 DIST google-auth-1.30.0.tar.gz 169598 BLAKE2B 4b0a0e66255abc11c697ca2c3d77ea0b7cf72cc13f6b1630307018e6ea52bda57a1f856787394455d71c61b58103d4e5e24da62f6ffd95022042b48842efcbbe SHA512 d07d6946635071e601c684a60e99ecec532ec51425aa934ece48b124419cb4c69c7651505018471431a7cf14470f4f8d894a2121999d3a482d603d41e5a8e66c
 DIST google-auth-1.30.1.tar.gz 169244 BLAKE2B e496239807ab9ca64e1b5dc39726fa22b56d55f14883c983673064b8ea33f80dee013654d4808fead0d06e8b6ddc53554d094f42aede6e06224dc3a3c04e88d1 SHA512 7e35f5be9be160ddef4b579c2e5bc966f1d64f8f0bb75220e22fd3edb9c6f6140bdcf68055fdb13dd370e3d543206900cc9403237eb328d69418a384a4d0fe26
+DIST google-auth-1.30.2.tar.gz 169368 BLAKE2B c01191313b4bd7ffdc62fbca20aeadcb01fcb1f26e4c11504f88c2582b9a3dca10046edd5d2fe88c98980fb09e4d68da99bf0b8b5692abcf5271994515f91765 SHA512 f133ef403f8a3c92437055f2fd0e5f607199a0bfd9a76a44075a9be8ec16c4d4822d58d85fa52ade4c448e11cb6822f7e8da03ab72f3dddfb811c8d7a846f841
diff --git a/dev-python/google-auth/google-auth-1.30.2.ebuild b/dev-python/google-auth/google-auth-1.30.2.ebuild
new file mode 100644
index 000000000000..490439987838
--- /dev/null
+++ b/dev-python/google-auth/google-auth-1.30.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://github.com/googleapis/google-auth-library-python/
+	https://pypi.org/project/google-auth/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/cachetools-2.0.0[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pyu2f[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/radon/Manifest b/dev-python/radon/Manifest
index 94cf26f77954..8d8216d5d352 100644
--- a/dev-python/radon/Manifest
+++ b/dev-python/radon/Manifest
@@ -1 +1,2 @@
 DIST radon-4.5.2.tar.gz 1873164 BLAKE2B 64a6def2be3505e247625b11deaaf75520781f98748cd8fec07c0d525905605deaf7f17c0103c6d41361ac0c6f62f489aeb418b5bd592dbd5b12755ec73e0116 SHA512 247fcd715ed3dfb889a73889fb5be8dc159673beb3abe1e1ba5170b8caadb85ad405ebd05f6a9080a6097f1c731b83b9dbe8b7f564f2a39b1b7cb0239f445813
+DIST radon-5.0.1.tar.gz 1873494 BLAKE2B 5a4e1db727b0ce5c7f368ca7fa710deb2034febd7fde4bccedcad6c935c57e3c73191173395f637000ebeeae6146a6eae19e0759d430dab2b7245f67eaf08ca8 SHA512 022a2209b5ac37c30a2a9e7a6ec567d4ab6edcf627cfe0e38547ec502bfa348f0131e27f41ccfe8a924c30cda879dfdc6a13011cdf6e0d19803bfd9d8949fcdf
diff --git a/dev-python/radon/radon-5.0.1.ebuild b/dev-python/radon/radon-5.0.1.ebuild
new file mode 100644
index 000000000000..e43d99ef743a
--- /dev/null
+++ b/dev-python/radon/radon-5.0.1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Code Metrics in Python"
+HOMEPAGE="https://radon.readthedocs.io/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/flake8[${PYTHON_USEDEP}]
+	dev-python/mando[${PYTHON_USEDEP}]
+	dev-python/pytest-mock[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
diff --git a/dev-python/trustme/Manifest b/dev-python/trustme/Manifest
index 508813567c33..40a418e85f8b 100644
--- a/dev-python/trustme/Manifest
+++ b/dev-python/trustme/Manifest
@@ -1 +1,2 @@
 DIST trustme-0.7.0.tar.gz 27853 BLAKE2B 97313cfe10260c67e29b470b9b65d4bb190b6e3be9b6944599a3c318d87b984f44abfe581420cd0ef29afc8165029c67129104cfb7ccf9d68e3c686424de34ec SHA512 3b2aa69dc617c04af3a83ca424ef19b5eaf37495ba4bc5cc55004016a9ea63c8df3585bb7fe52709b1b18a2a55e51d6a1a2b21ebc12c57ac18133b20c958b1a8
+DIST trustme-0.8.0.tar.gz 29046 BLAKE2B 5f2dd542974466dd8e61fa0ba5cd78e824afd243dd3b27ca21aec4ba4905daaa0c46db8f4edb30dcb483acf44758d7ad8de4db9c3e07a05d4d3d084565722def SHA512 93b1007319f7d625410eddf92910607c8190533f9bb02a71ecc4c424e44ecea70749f6bceb917297241e179b0d50ce1ed330c208cf3de77d4d3a619f5436af9d
diff --git a/dev-python/trustme/trustme-0.8.0.ebuild b/dev-python/trustme/trustme-0.8.0.ebuild
new file mode 100644
index 000000000000..b8861ec5b0e7
--- /dev/null
+++ b/dev-python/trustme/trustme-0.8.0.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="#1 quality TLS certs while you wait, for the discerning tester"
+HOMEPAGE="https://github.com/python-trio/trustme"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/service_identity[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest