Adding metadata

42 files changed, 656 insertions, 33 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 2aecc8b78be2..842837fc0c1e 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -7,4 +7,5 @@ DIST boto3-1.18.27.tar.gz 405813 BLAKE2B d3da4db8133c9ad7b979a6a765f0f6d7d72e558
 DIST boto3-1.18.28.tar.gz 406268 BLAKE2B 1379f65f46f287a541b098b3ae183bc7d0a6c40a58f6241d97ce39ffdde4f0655e755fe56890fda767b57c6cf7bd565d95745dbbeb80f42f729f561f6e8d9a82 SHA512 98c0d94dd4971f833677947dbfbdcd495a26fda60592130842cf2f22b8929c6f72f971294d9ddc4923372706bf7f37d3d4cb0ede32afc6955d8253c19ddab63f
 DIST boto3-1.18.29.tar.gz 406872 BLAKE2B c1535f65d03766cd1ffc0ff3b34e3c2df2ed912d3d4e6fc81ac682f006a2610844b5bfe182ab976668e8febd4ea0e5a71e67194bd5766ef8400942fa1d1077cc SHA512 ab2176be91a4cb84e2481b79e9567b67b276ac5acdb6ca0087e6684c16ab764de57805d4bc311352968e54d79c348b793ed5c75b18a18815b8f9cdf25a82b34e
 DIST boto3-1.18.30.tar.gz 407362 BLAKE2B 14cbd75f3a4441d0b0aa3cb9cd1001053be59086cd0d09ce0231b9e6d00ef1c15e138b1ddb2099d6e167782e9693160e377b71d6eaf83101ec6b490424832661 SHA512 582d677c481e0a2f7586d0735a9f4101a5abfc7c03891f67b034a5a6ac9b41703fdfb62e66c0509882b3b54791ec16e09988a99421c75b3d66cf068bccb4eb3f
+DIST boto3-1.18.31.tar.gz 407465 BLAKE2B 816833b83f8a9da0ce97ebd5a2636f8d7a9f9170c690c2be57be53f959f191976d2e661057a64b233705dfeb740c599520bf99cc74d385c867192e442cbb1076 SHA512 4dbe54b0beda32f3decbfe378cffc6c20899d4800196c4bf1390365ea0c84836b526f4a23cd2779a3cc365cc863612ade972c96284be7bbfbe8f652b1312c9c4
 DIST boto3-1.18.7.tar.gz 395640 BLAKE2B 6a9fa1dd55644806fe93271805f35fbe0c4cb65d1de08dded2d2f57fcefa96e32c4ebe7b60743c52c0898222bc06d33dbd03d304bbef327b88022450a7943e2c SHA512 20e7fedab7d061ab02f391e9baf36cb554e7f194f38d24d5a75f76715b2acf1b51b6adce5d8cf5a2a0d29df73566db00b8813a219d45a194d9a8eb93d0dab570
diff --git a/dev-python/boto3/boto3-1.18.31.ebuild b/dev-python/boto3/boto3-1.18.31.ebuild
new file mode 100644
index 000000000000..bee358e1c595
--- /dev/null
+++ b/dev-python/boto3/boto3-1.18.31.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ ||
+		die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 92e76a3c7021..6dfde8d7fb34 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -7,4 +7,5 @@ DIST botocore-1.21.27.tar.gz 8076120 BLAKE2B e7928438ec4b100ef00d202899fae47c7bb
 DIST botocore-1.21.28.tar.gz 8079306 BLAKE2B 26dce445746a9da1b0cf62b622597396f9b4e735701f9260fd9863410b28b884e70e41b446b8349df39c81696b64632450f4ebb3e3f7865175e538f1b465898c SHA512 29534e51465bc7ac7b6f2e2c48472768c26caa5089f4c7f4a23cc2411fd55fde473388ad181a0b5a36650a6c1252ecb3e2b65e30510adc40f6edd6ce0c89f484
 DIST botocore-1.21.29.tar.gz 8079625 BLAKE2B c396b453893782f94e503cb581efe5beb2a5766beb46b5c0840db3cea3d14b637a49c0cbf8971dc3fc4aa6899cdbaffac882cf3f889e78c25f0b5195de947925 SHA512 0b791b14e81158dbaaac0f39c0f1eba3f67b4a75ef97bbeff2a9eecf9b5c436268ae4a2ff0834bb00628497e06539148c22621a61ba6df9d44b988e17a67b329
 DIST botocore-1.21.30.tar.gz 8081027 BLAKE2B 6566d74873c08ce84f6bd0e6a802e62c6cf21956136f2e3991e1b498c3ac4f6a11b17a3d8b44595f4d4b5ef5e9b2a6bd71802e5f0270b8cc1473e8fc94e0db5c SHA512 fdc4991ac8fccb71c82542b05c25edba1607381289e384786079bd3b9efda527e0aecccd29fc372ff5b8d265a204fc570bbf7191683a36d9cb9e43a2153fe685
+DIST botocore-1.21.31.tar.gz 8081621 BLAKE2B 78bd0ad2d1371582e97c8ddddb9a0b9f41fd75d701ba2ad49fab0e6f3d4602eb6a06bb51f23f674ef71d8c0bcec39ab545071ec8ef252df1c9d9133d8223a746 SHA512 bdaa85ad59936334e8d0e57a0e6631bb1c4408a0b9a50eb883b9b9dc5df4845da2df0fc64af755c5bb2ce5ee667c449a751263e25c9912bcb335eaa41cbba95e
 DIST botocore-1.21.7.tar.gz 7977343 BLAKE2B 19c5bf5de40ab131585e30bb85486fcffc3428808811b312b33578174ce31a691f4f4d955462120f05d2aad2cd5e5772789704eee641760fb67099aa3cddc9b5 SHA512 db1bb36faa6857a1cc717e5d591954415bb948178ee2be90ab9c32c11b1fb45c5b5aff87dfacd907c2f11bc7cdd2cd4de2ee9c847fa8cda4e5f0814a828b1019
diff --git a/dev-python/botocore/botocore-1.21.31.ebuild b/dev-python/botocore/botocore-1.21.31.ebuild
new file mode 100644
index 000000000000..5684261bd4b3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.21.31.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/cli_helpers/Manifest b/dev-python/cli_helpers/Manifest
index c9182e19c8c0..c760fe582011 100644
--- a/dev-python/cli_helpers/Manifest
+++ b/dev-python/cli_helpers/Manifest
@@ -1 +1,2 @@
 DIST cli_helpers-2.1.0.tar.gz 32967 BLAKE2B c2ee2a92dce4185f656415d6079196953c5e9dccf9de4e29d9de61bf72b041a6225ffe4afa866b0f78abcd5d0809ec739db489aee21e440575b7e2a6e09b916a SHA512 75c6b24ae1ed05cbdfddfc30c5e43aeb7129f5fa319d485e19be098691762ad681c4874449b2f339f833424a970965b5a28a3b66814cb556ea8ad6293740fdbe
+DIST cli_helpers-2.2.0.tar.gz 34018 BLAKE2B c7dfe8b87db6312557b4ac87aa4eda77b94f12789fcd4a9e686cada47bd41601f5c357a77de4a1c6d550b2ea110b682da0a04edb312d26ecf281e6d323369462 SHA512 26d78227999e8bb37f58529ce29bbed1bc8d51c80f81127552fb1d1f880c476abdd43ca628c591ba50c0316b35d1df0541906bf902a7549f459da0e1200c8479
diff --git a/dev-python/cli_helpers/cli_helpers-2.2.0.ebuild b/dev-python/cli_helpers/cli_helpers-2.2.0.ebuild
new file mode 100644
index 000000000000..b2f197ec3ca0
--- /dev/null
+++ b/dev-python/cli_helpers/cli_helpers-2.2.0.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Python helpers for common CLI tasks"
+HOMEPAGE="https://cli-helpers.rtfd.io/"
+SRC_URI="https://github.com/dbcli/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/configobj-5.0.5[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/tabulate-0.8.0[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/cli_helpers/cli_helpers-9999.ebuild b/dev-python/cli_helpers/cli_helpers-9999.ebuild
index ce86f5dda8e7..c223d7d2f2f8 100644
--- a/dev-python/cli_helpers/cli_helpers-9999.ebuild
+++ b/dev-python/cli_helpers/cli_helpers-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 EGIT_REPO_URI="https://github.com/dbcli/${PN}.git"
@@ -19,7 +19,6 @@ RDEPEND="
 	>=dev-python/configobj-5.0.5[${PYTHON_USEDEP}]
 	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
 	>=dev-python/tabulate-0.8.0[${PYTHON_USEDEP}]
-	>=dev-python/terminaltables-3.0.0[${PYTHON_USEDEP}]
 	dev-python/wcwidth[${PYTHON_USEDEP}]
 "
 
diff --git a/dev-python/click/click-8.0.1.ebuild b/dev-python/click/click-8.0.1.ebuild
index 9c0cf6efd134..d13178ac949c 100644
--- a/dev-python/click/click-8.0.1.ebuild
+++ b/dev-python/click/click-8.0.1.ebuild
@@ -24,7 +24,8 @@ RDEPEND="
 distutils_enable_sphinx docs \
 	'>=dev-python/docutils-0.14' \
 	dev-python/pallets-sphinx-themes \
-	dev-python/sphinxcontrib-log_cabinet
+	dev-python/sphinxcontrib-log_cabinet \
+	dev-python/sphinx-issues
 distutils_enable_tests pytest
 
 python_install_all() {
diff --git a/dev-python/django-mptt/Manifest b/dev-python/django-mptt/Manifest
index bef1b93a80f0..bc876c5b7ec0 100644
--- a/dev-python/django-mptt/Manifest
+++ b/dev-python/django-mptt/Manifest
@@ -1,3 +1,4 @@
 DIST django-mptt-0.11.0.tar.gz 98300 BLAKE2B cbae24143007dfe8913aacf4cbe22bbccdf929617adc31640c2d429d6ea8be727a937be0aa8353e82862b9fe8c571397db4dd3877015eb17c2c5a56172cc66a5 SHA512 21af30007661db1474628b6f8af86a3f6de52494efe1aaf9235f8b1660ba153f0de3ad91ff979588e4b681b00b44652a05146df7d3951d6ee62da38a1900fd89
 DIST django-mptt-0.13.1.gh.tar.gz 302287 BLAKE2B 915e3066862be4d0883ba540cf584d917994ecbf83182726f5d39a40b61850e4ef1fade2c12325237f2c345de14ca6e54362712eb7bdbdf553eb6ebbf321075f SHA512 bc64d24f8d889109a054f270802f8ce6308c12bf3b9ebe1ba818d42e6c1f9d8904b8cad996e71e03c7f77ed80d912a7d8bb920cccc0e2fff170e754816367f40
+DIST django-mptt-0.13.2.gh.tar.gz 303658 BLAKE2B 8b9e968091be35d1b20816874f8a27cef065c11a25d5ac08192d01909be5a748ab96f0377a09b8a86ded5881d8ce075530bdd3a46c92065dd2f66d734853c27a SHA512 52e8631af11006a0ef1739d1f9c22d34fe39fd790dd45edb6bcde5f4ad875d6f2f0087aa4928d5e5b391b69728e67c2d8b6d10976714735eafe7b3b48e20d123
 DIST django-mptt-0.13.gh.tar.gz 302525 BLAKE2B 21b2fde5c81d83321bf7569d2064db87aec3c184f27cf3fc3bd34421be04212188e15f79a575b08aabb3a7b95d116bf3e5f0fb57c56cadf9ad2ac166e8e77845 SHA512 63dbb61dab59d42b5e747f35370a0840d40ed465979d1f93e66561cf4c0726635cae774f87e39cc1ac480847f3ccf0eb65dc8593759a0860d586e334fdd37256
diff --git a/dev-python/django-mptt/django-mptt-0.13.2.ebuild b/dev-python/django-mptt/django-mptt-0.13.2.ebuild
new file mode 100644
index 000000000000..e861ed8dfcd1
--- /dev/null
+++ b/dev-python/django-mptt/django-mptt-0.13.2.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="utilities for modified preorder tree traversal and trees of model instances"
+HOMEPAGE="https://github.com/django-mptt/django-mptt"
+SRC_URI="
+	https://github.com/django-mptt/django-mptt/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/django-1.11[${PYTHON_USEDEP}]
+	dev-python/django-js-asset[${PYTHON_USEDEP}]
+"
+
+python_test() {
+	"${EPYTHON}" tests/manage.py test -v2 myapp ||
+		die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/flexmock/Manifest b/dev-python/flexmock/Manifest
index 187d09bbe454..c21840a904b4 100644
--- a/dev-python/flexmock/Manifest
+++ b/dev-python/flexmock/Manifest
@@ -1,2 +1,3 @@
 DIST flexmock-0.10.4.tar.gz 45362 BLAKE2B 4ff79cff3b0d8fb0c97bd60b0d5aa5555a7b939d3d6275a17c9bd1002b1d7acb53d4f63f5f834faf0d349d8b8d429eb063f121c4d7b6d12aa1bb3e7bdbadb861 SHA512 d190fcb66f0c2c4e3be2384d68b95a22c695ffa0fe8f8a218f2baa68c91683641396197cac69ddab21e4b0990b9930f56423bb7cd85770ceade9c22ece72cedc
 DIST flexmock-0.10.6.tar.gz 46740 BLAKE2B b5c8083694e8787e85ff0f41265ad9f716a4c82d274ca5c793b6d93bf8bf28f3e57afd33f7ba59149e75f7bffbebd3843901dfa75caaefc6f76f3eef0c603314 SHA512 2ebaed78926f01bd4d886a509d978d0de04629f7d96c48f846b8ccf7906bb2303e7cbeab8226c6eb98d058f940434144cc2d6300d6aa2533f1f217788211490e
+DIST flexmock-0.10.8.tar.gz 46905 BLAKE2B d5f28e012edf9678fd5f72ec1d99e4e98b00dbb36536877cb393c16563097e0e3f18ab24243f7090bfa306f8be194243d201d9aaf5d64491bb594cff82b60e1e SHA512 cac327b3e3c4c6ccbcd6c7f71863b67fdd5454c13bbd5403b3ba521e3ae945ba453152df623eef08b2b60210ba626447a9e6bad76c2215281d43ae0f42ebf1a9
diff --git a/dev-python/flexmock/flexmock-0.10.8.ebuild b/dev-python/flexmock/flexmock-0.10.8.ebuild
new file mode 100644
index 000000000000..cdb4c5e31de5
--- /dev/null
+++ b/dev-python/flexmock/flexmock-0.10.8.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Testing library to create mocks, stubs and fakes"
+HOMEPAGE="https://flexmock.readthedocs.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -p no:flaky
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc -r docs
+}
diff --git a/dev-python/fuzzywuzzy/fuzzywuzzy-0.18.0.ebuild b/dev-python/fuzzywuzzy/fuzzywuzzy-0.18.0.ebuild
index 339700230b9c..64eb381cdb6e 100644
--- a/dev-python/fuzzywuzzy/fuzzywuzzy-0.18.0.ebuild
+++ b/dev-python/fuzzywuzzy/fuzzywuzzy-0.18.0.ebuild
@@ -14,14 +14,8 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="test"
 
-RESTRICT="!test? ( test )"
+RDEPEND="dev-python/python-levenshtein[${PYTHON_USEDEP}]"
+BDEPEND="test? ( dev-python/pycodestyle[${PYTHON_USEDEP}] )"
 
-DEPEND="test? ( dev-python/pycodestyle[${PYTHON_USEDEP}] )"
-RDEPEND="${PYTHON_DEPS}
-	dev-python/python-levenshtein[${PYTHON_USEDEP}]"
-
-python_test() {
-	"${PYTHON}" test_fuzzywuzzy.py || die "tests failed under ${EPYTHON}"
-}
+distutils_enable_tests pytest
diff --git a/dev-python/guzzle_sphinx_theme/guzzle_sphinx_theme-0.7.11-r1.ebuild b/dev-python/guzzle_sphinx_theme/guzzle_sphinx_theme-0.7.11-r1.ebuild
index 98d0be0f7e38..65ec841e36bf 100644
--- a/dev-python/guzzle_sphinx_theme/guzzle_sphinx_theme-0.7.11-r1.ebuild
+++ b/dev-python/guzzle_sphinx_theme/guzzle_sphinx_theme-0.7.11-r1.ebuild
@@ -15,4 +15,4 @@ LICENSE="MIT"
 SLOT="0"
 KEYWORDS="amd64 arm arm64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
 
-RDEPEND=">=dev-python/sphinx-1.2[${PYTHON_USEDEP}]"
+RDEPEND="dev-python/sphinx[${PYTHON_USEDEP}]"
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 26f61c728093..e57486d1af12 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -4,3 +4,4 @@ DIST hypothesis-python-6.14.8.tar.gz 9137594 BLAKE2B 421c3fdb13e172bdb93cd15f625
 DIST hypothesis-python-6.14.9.tar.gz 9138640 BLAKE2B 3cda0edace7b3a1c373bdd61267013874fe78ae18aa7fda02759ac451f7e576614a61c3ce1d588e24afe4333f61680d89eb30f6f055e41fee91312c791b1af5d SHA512 a32d4f09ae6a44354d136164a517ea53c653fccb3e21a39ac63df78ebdf695c887f13749d2f310ac67863b6645a85dca73ef0bfab077aefe0486e445f6a85dce
 DIST hypothesis-python-6.15.0.tar.gz 9138803 BLAKE2B 537d40d2f86b16730391e4f4f7fc692d882793b47854f1645eb587dddf41e37e27f74588c8fb8829e0b0ceb2b563f8f88006f8be6dd28c954be59ba76b81e8e6 SHA512 19b8b5d71156c08d77c11b6d675cca3df1a66beec493e2a52600e14c2d1444f42f58b55ed769f9d99c16dc6844da1843539b995bb972daa6bbd35480edc444ed
 DIST hypothesis-python-6.16.0.tar.gz 9140064 BLAKE2B 74d2963f71b357c1fcf5410271ef80a3f4f3540130c8e7ae5ec4408c07577962e30096d702a9feab25fa222cf23d85d865e816d661b8d5828570800b04453ef1 SHA512 92d98cb0a042d4abca9191ac46af6693ae2223433772622d33cd0838d2805fa72491421920af853ce258ec169037829ea1f924f35264d98319e2e0e3e7135f71
+DIST hypothesis-python-6.17.0.tar.gz 9142908 BLAKE2B e366f5355e13471c211e91a54fc70e46e3c575d06352968ce4ec3f5cbae0c5442d07c5fefb0907664f262f3ddd1fc50f202d4e93deedea380221e9cba796f0b5 SHA512 320dddaa88a697e6b2fdd942fc08bce0cb1c49f4eeb0de39a7d404d98971d60b0edb332d9d2dd5f3a63b37301d458e361ebd995ccca6554e784e772a7cb3ed6f
diff --git a/dev-python/hypothesis/hypothesis-6.17.0.ebuild b/dev-python/hypothesis/hypothesis-6.17.0.ebuild
new file mode 100644
index 000000000000..8b48444a4699
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.17.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' python3_{7..9})
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/typing-3.7.4.1
+	)
+"
+
+distutils_enable_tests --install pytest
+
+python_prepare() {
+	if ! use cli || ! has "${EPYTHON}" python3.{7..9}; then
+		sed -i -e '/console_scripts/d' setup.py || die
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	epytest tests/cover tests/pytest tests/quality \
+		-p no:pytest-describe \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/kiwisolver/Manifest b/dev-python/kiwisolver/Manifest
index 64dabc32e1cf..ce56ec80fc60 100644
--- a/dev-python/kiwisolver/Manifest
+++ b/dev-python/kiwisolver/Manifest
@@ -1 +1,2 @@
 DIST kiwisolver-1.3.1.tar.gz 86948 BLAKE2B 4e03547842e831424aef5be880021aea8d0fef372900bcb9b55f2367fc89f728250b936702fd737807579be34e4ff7489d5669f5113e95612352a293d9f883ea SHA512 0f5c1e516c334d358b8679313035dd45386381965853005271c73e3f4421fb27e3ca5a43b4f2dc85d693f4151427dae9b34d372fe72fcc1a186abd85a54a225a
+DIST kiwisolver-1.3.2.tar.gz 89075 BLAKE2B 729880e3b18ac8c6c3e48d2fb32f00b4232118eb753f60837c7736c75a0f22e7a259aec46b76bc91286541847929eb4a92fcf9991650dea16d263f4d16beffc1 SHA512 e9ef20756df587b49f7b8e52ff388db6e2e551548ae7d60b6916586fb35249b10bda895a7be7635b300e6100ec1c7daf7d641de6d26d9b2c36055ac6c176302b
diff --git a/dev-python/kiwisolver/kiwisolver-1.3.2.ebuild b/dev-python/kiwisolver/kiwisolver-1.3.2.ebuild
new file mode 100644
index 000000000000..511a3ef55a8c
--- /dev/null
+++ b/dev-python/kiwisolver/kiwisolver-1.3.2.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+# tagging fail?
+MY_PV=${PV}.rc1
+DESCRIPTION="An efficient C++ implementation of the Cassowary constraint solving algorithm"
+HOMEPAGE="https://github.com/nucleic/kiwi"
+SRC_URI="https://github.com/nucleic/kiwi/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}"/kiwi-${MY_PV}
+
+LICENSE="Clear-BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/cppy-1.1.0[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3.1-darwin-build.patch"
+)
+
+distutils_enable_tests pytest
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 1b7f4cf37278..418a3384b0b7 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -4,3 +4,4 @@ DIST moto-2.2.0.tar.gz 1650655 BLAKE2B 9969de2fb323b2deb272eb47727884054a35827a5
 DIST moto-2.2.2.tar.gz 1684678 BLAKE2B ebe1eb08c67ccdb8c484fa8fc75d7ce58750d94620f46b53268d6b6b0732d90160bf7b6837efa492f621e1c001d933f5d59d39c266d65bbb1852f315b3bc03d0 SHA512 a8b192637b701eda0e4a7b11e84f5251386de98590f1d7c33732d8bf12642b39b61f1d360ad39c3e1b0a645268139d9e330d48fbe7029b943094ad317cb45ff6
 DIST moto-2.2.3.tar.gz 1700636 BLAKE2B 926fe245ce457dd79eef6780fc0b984d2ff1cbe95807a3463f0d0080583af2ba356ccfcce22e60927737e1531ec7bc167c5f649e784b191ec821aa56df65277d SHA512 0b46229ae06db7cb2634df3f1b3b1a6b6fc983978a763e8879db0d9e209ccc6b96b28e8e2ee40f6e1a8e39b74d7a2430788126220e3a7dab5e8df217c3c8c005
 DIST moto-2.2.4.tar.gz 1724663 BLAKE2B 3feb39bec246a8157aa542c711289ab0ca257ec510835cd48aa732c3f07903db857971e3d024c1aef35b5a0b55b7c4ecef2b319824c1d76f0076ab8d2d75329e SHA512 8acd8a3156db71af35ad0ac6a5105a6b7739d8ca9881a2cb091637830bc6fbb10d8bf6adfd1a1091556f9269fad737b345d2bdf50e09b54201fe7438674dd906
+DIST moto-2.2.5.tar.gz 1737336 BLAKE2B 450861edc607b9175cd72f29923e3259b81ce3a6e02302eb74486946cd8f6ebe8c15c61f6fd6da66d821b148924a0de1bcaf4e46ce6a5a751f7817d42450ea96 SHA512 27c04690d55647c7b43b342647f9a37f47ec3656c96aad8b6572c57752d555a77ecce3670e3cc5397318423ed179632fd79562a8b3a209049d74bf6e2a4bd51d
diff --git a/dev-python/moto/moto-2.2.5.ebuild b/dev-python/moto/moto-2.2.5.ebuild
new file mode 100644
index 000000000000..b76e77a4b433
--- /dev/null
+++ b/dev-python/moto/moto-2.2.5.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/boto[${PYTHON_USEDEP}]
+	dev-python/cfn-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.9.201[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.12.201[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# unpin indirect dep on ecdsa that's supposed to workaround pip bugs
+	sed -i -e '/ecdsa/s:<0.15::' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local ignore=(
+		# incompatible versions?
+		tests/test_core/test_decorator_calls.py
+		tests/test_s3/test_s3_classdecorator.py
+	)
+
+	# pytest-django causes freezegun try to mangle stuff inside django
+	# which fails when django is not really used
+	epytest -p no:django -m 'not network' ${ignore[@]/#/--ignore }
+}
diff --git a/dev-python/olefile/metadata.xml b/dev-python/olefile/metadata.xml
index 647666d35fe5..6d4fa2073851 100644
--- a/dev-python/olefile/metadata.xml
+++ b/dev-python/olefile/metadata.xml
@@ -9,4 +9,5 @@
   <remote-id type="pypi">olefile</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/olefile/olefile-0.46-r1.ebuild b/dev-python/olefile/olefile-0.46-r1.ebuild
index c1539227e4bc..bc17d8c1c102 100644
--- a/dev-python/olefile/olefile-0.46-r1.ebuild
+++ b/dev-python/olefile/olefile-0.46-r1.ebuild
@@ -15,5 +15,6 @@ LICENSE="BSD-2"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
 
-distutils_enable_sphinx doc
+distutils_enable_sphinx doc \
+	dev-python/sphinx_rtd_theme
 distutils_enable_tests unittest
diff --git a/dev-python/openstacksdk/Manifest b/dev-python/openstacksdk/Manifest
index 88d01c75eaa4..62645140a6f3 100644
--- a/dev-python/openstacksdk/Manifest
+++ b/dev-python/openstacksdk/Manifest
@@ -1 +1,2 @@
 DIST openstacksdk-0.58.0.tar.gz 1021818 BLAKE2B 530ec940b958d5c9b1a1caba71716201172e1141ebac208b26ea512732be152ccc6e928d20e38964eb455ff47fd6f42756d3f9af19800a45104b631d45d312c9 SHA512 94bb317e9f79ab419e5a0e7def4510d6686e3b8585721c15bd1f03eced5e8f45509cf925ed2b3e51a19ecd2d3e28469343cdae5a3df549f35bb61c448add5caa
+DIST openstacksdk-0.59.0.tar.gz 1021995 BLAKE2B be57afcdc707547e2cd69774de1b7d0dc4b84ffe58bdaa4f063b85996e8ee08ded60004d3211f827d7b4a5239d1420485ce2fae92b550722c959274a18ed2753 SHA512 02f8f8f174896417f0cf4ce1c65c87ea705664fa7a1c6383ad1791f5d94cb818b5b0bfee331bd0d07d724df59859ccef91c507b0c39522115f9549d6258a3eb7
diff --git a/dev-python/openstacksdk/openstacksdk-0.59.0.ebuild b/dev-python/openstacksdk/openstacksdk-0.59.0.ebuild
new file mode 100644
index 000000000000..c1c29c9361d0
--- /dev/null
+++ b/dev-python/openstacksdk/openstacksdk-0.59.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A collection of libraries for building applications to work with OpenStack."
+HOMEPAGE="https://github.com/openstack/python-openstacksdk"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE=""
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0"
+RDEPEND="${CDEPEND}
+	>=dev-python/pyyaml-3.13[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requestsexceptions-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonpatch-1.16[${PYTHON_USEDEP}]
+	!~dev-python/jsonpatch-1.20[${PYTHON_USEDEP}]
+	>=dev-python/os-service-types-1.7.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth-3.18.0[${PYTHON_USEDEP}]
+	>=dev-python/munch-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/decorator-4.4.1[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-2.7.0[${PYTHON_USEDEP}]
+	dev-python/importlib_metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="${CDEPEND}
+	test? (
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+		dev-python/hacking[${PYTHON_USEDEP}]
+		>=dev-python/prometheus_client-0.4.2[${PYTHON_USEDEP}]
+		>=dev-python/oslo-config-6.1.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/requests-mock-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/statsd-3.3.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests unittest
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+
+	# Internet?
+	sed -e 's:test_create_dynamic_large_object:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# TODO
+	sed -e 's:test_generate_form:_&:' \
+		-e 's:test_create_static_large_object:_&:' \
+		-e 's:test_object_segment_retries:_&:' \
+		-e 's:test_object_segment_retry_failure:_&:' \
+		-e 's:test_slo_manifest_retry:_&:' \
+		-i openstack/tests/unit/cloud/test_object.py || die
+
+	# unhappy about paths due to test runner
+	sed -e 's:test_method_not_supported:_&:' \
+		-i openstack/tests/unit/test_exceptions.py || die
+	sed -e 's:test_repr:_&:' \
+		-i openstack/tests/unit/test_resource.py || die
+
+	# functional tests require cloud instance access
+	eunittest -b openstack/tests/unit
+}
diff --git a/dev-python/pallets-sphinx-themes/pallets-sphinx-themes-2.0.1.ebuild b/dev-python/pallets-sphinx-themes/pallets-sphinx-themes-2.0.1.ebuild
index ba163882361b..5253545e19c7 100644
--- a/dev-python/pallets-sphinx-themes/pallets-sphinx-themes-2.0.1.ebuild
+++ b/dev-python/pallets-sphinx-themes/pallets-sphinx-themes-2.0.1.ebuild
@@ -19,4 +19,4 @@ RDEPEND="dev-python/jinja[${PYTHON_USEDEP}]
 	dev-python/sphinx[${PYTHON_USEDEP}]
 	$(python_gen_cond_dep '
 		dev-python/importlib_metadata[${PYTHON_USEDEP}]
-	' python3_7 pypy3)"
+	' pypy3)"
diff --git a/dev-python/prettytable/Manifest b/dev-python/prettytable/Manifest
index 0a8128470d4c..b15e3132566a 100644
--- a/dev-python/prettytable/Manifest
+++ b/dev-python/prettytable/Manifest
@@ -1,2 +1,3 @@
 DIST prettytable-0.7.2.tar.bz2 21755 BLAKE2B 385d5bd6d4ab75a8c7ae96abc9d9e98a66a196265853113e7fb59073876e9f5e9c6c4fba9a30d80cc726a5184e78fb6451ff9a553909704fcc5022b6a08413f4 SHA512 f3a3fe6fa29f4ef090ff6cac06549ebd9db8b387e7b25fc64c4e37c8444586f50355c5573f38caabc72360aa68054aa189a67aa37f0bd13b872862ecd9151e71
 DIST prettytable-2.1.0.tar.gz 43306 BLAKE2B e2085003f2720d573e19fb2b03c8aa98262ec9e7a3f7d0a20474cad2fab374a91664bb513d8158cd612e58a47917c3ebe8b43798272f38c182f6cc2472918f55 SHA512 8eaad22c66299ca3f66cc167e1a94aa41e3b2699da4ff48a0e81927ee8cc623d3147ae29a0bef92370d07d6a7fb6b1eac535fca7090562419aed219b9483edd5
+DIST prettytable-2.2.0.tar.gz 44939 BLAKE2B eff6eeb98b6accdb5089cfd1ceb09db2e4a0897e9675a07b744a12ab15fb1cb43bd4a411788d8e22662089f68a31c346d79cfaaca44c7f14f452870a7039bdb6 SHA512 df8ae2a1103a4965a351ba16a95ef9659107075bb023090bd9bffd69805ce647dcb26f49164f07f5af0c0b03503373c0353935b32a0fb18edf969dc984aecda7
diff --git a/dev-python/prettytable/prettytable-2.2.0.ebuild b/dev-python/prettytable/prettytable-2.2.0.ebuild
new file mode 100644
index 000000000000..a202b300abee
--- /dev/null
+++ b/dev-python/prettytable/prettytable-2.2.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Easily displaying tabular data in a visually appealing ASCII table format"
+HOMEPAGE="
+	https://github.com/jazzband/prettytable/
+	https://pypi.org/project/prettytable/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/importlib_metadata[${PYTHON_USEDEP}]
+	' pypy3)
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_impl_dep sqlite)
+	)"
+
+distutils_enable_tests --install pytest
diff --git a/dev-python/pycryptodome/pycryptodome-3.10.1.ebuild b/dev-python/pycryptodome/pycryptodome-3.10.1.ebuild
index 8914a37b67e4..18956fef1c20 100644
--- a/dev-python/pycryptodome/pycryptodome-3.10.1.ebuild
+++ b/dev-python/pycryptodome/pycryptodome-3.10.1.ebuild
@@ -18,7 +18,7 @@ SRC_URI="
 
 LICENSE="BSD-2 Unlicense"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 IUSE=""
 
 DEPEND="
diff --git a/dev-python/regex/Manifest b/dev-python/regex/Manifest
index b402a3a5535c..f7e2cb273773 100644
--- a/dev-python/regex/Manifest
+++ b/dev-python/regex/Manifest
@@ -3,4 +3,5 @@ DIST regex-2021.7.1.tar.gz 693459 BLAKE2B 484259e14af99d911a20835be73686fea621e5
 DIST regex-2021.7.6.tar.gz 693843 BLAKE2B 9acbca300632ff45744d509e47de56625b003b2046c068f3bf5cae3987bc9bbd51e5cdc442c3e72c6c9c0daeeacd658c56b56754c0f9e83c03816237cc311000 SHA512 0849caaafc669b6dc322dcd4d48962cefbe955c19f9ee3d657b7b8389f77ab2b2e27ec341745dff01a60dd3930904d69015a334ff748de10be2d0b7c421b0967
 DIST regex-2021.8.21.tar.gz 693951 BLAKE2B 4d10d6da6480b9e3e82546ad73e8c03e7625a515d1619943447f2aaf26f05df3b7397028f428e20ccd1bdfd6166a9b3d3335ede84605d2b4751a01306ebd807c SHA512 10bacc761a878ad1359c0ba8dbc7396dbaf7a2c1658dba228b8d993f41583399b097c665a3ce5887257fabb54e6be2ef7010a03a5af26d11af51075f3b8f0584
 DIST regex-2021.8.27.tar.gz 693958 BLAKE2B ff0c184aff50794fc85de33c8d13daf6331db8ad50989ead1eb58d2fc065e279ba30bb36d998338399fe8e7ee4793b8bac1e13ba6b3eaf012f7fea7a210f56a2 SHA512 fbaf2a05c4753027668ae4c27b6d3353965458d74e403da37fab62067c20b5a76d82b723a271f89337a9192cd6237dd8b788b44c8b0a223f67642d7a537eff10
+DIST regex-2021.8.28.tar.gz 694689 BLAKE2B 1aeceeb77df3c67e3ac14811000dc0f0cccf2a4994fd349f01f3a4e793f265dc9a73ea685202c6a7af8f507f0db94d6b74b1ae448ce58dd985ca4122c3454cba SHA512 da95f8ce03200f45b6be8730b65d01170847d074202e9b5f311688e22e3d59c32a8ff93768e2ac0105bac02936cbcde49eb114b762e89e6ebf895d8b799b4bf9
 DIST regex-2021.8.3.tar.gz 693937 BLAKE2B 886dfe1a312bb34d83a3fe9442231215be7e263cbd123da24c454cdceac1055cb4dacfe4a3104699b6b97f86b14e2b723ea1267a13c2395ce2baad4ca367d77e SHA512 3ac33421ca15e47a1d8beeb3841b6e698d492e96965955afe69529dc71cc7d522e5e8236e4f577c934a3fd27036340a8084c84055bcfff0a9572e8fb56ba272b
diff --git a/dev-python/regex/regex-2021.8.28.ebuild b/dev-python/regex/regex-2021.8.28.ebuild
new file mode 100644
index 000000000000..adc8b42f3f8b
--- /dev/null
+++ b/dev-python/regex/regex-2021.8.28.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1 flag-o-matic
+
+DESCRIPTION="Alternative regular expression module to replace re"
+HOMEPAGE="https://bitbucket.org/mrabarnett/mrab-regex"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="doc"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_empty_array.patch"
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_issue_18468.patch"
+)
+
+distutils_enable_tests unittest
+
+python_test() {
+	eunittest -s "${BUILD_DIR}"/lib
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/Features.html )
+	local DOCS=( README.rst docs/*.rst )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/setuptools/setuptools-57.4.0-r2.ebuild b/dev-python/setuptools/setuptools-57.4.0-r2.ebuild
index 5c307d8fa68c..64fc2e08b1e4 100644
--- a/dev-python/setuptools/setuptools-57.4.0-r2.ebuild
+++ b/dev-python/setuptools/setuptools-57.4.0-r2.ebuild
@@ -19,7 +19,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
diff --git a/dev-python/setuptools_scm/Manifest b/dev-python/setuptools_scm/Manifest
index d9a284c2a533..28cf9eebb539 100644
--- a/dev-python/setuptools_scm/Manifest
+++ b/dev-python/setuptools_scm/Manifest
@@ -1,2 +1,3 @@
 DIST setuptools_scm-6.0.1.tar.gz 51433 BLAKE2B 7045eec0c1a43d6c93c94e0b2799f0d000cda509fa0df9ee9a638b95383f07fe430b07c3bf72fdc4809563ac289521976956f728a4b2984921fa31532bb7ed8b SHA512 db27653c57f674ec62689247680adace3779216249f1b09a35e8a0233a1ec1acb9ae89b52acd439f7062da2ba1a45b8c0d6d81333ddda0764447c30698ddb314
 DIST setuptools_scm-6.1.0.tar.gz 55618 BLAKE2B b1bdf0c2faa34eb77b378908fcd73670b2f1918552b62b0bd6a0359af00508485ddc91704966e4e862255b3c4e93492210741a60da41a8f09f9cd6c660e1aa8a SHA512 d9359936e22f8c0bc207def147283d79321ff0f26ba75661afd593edb3c41a06d057317f09bb5b8ef013e95b1aa5911372d4aeb3c7a05bd012ff24bdbf479073
+DIST setuptools_scm-6.2.0.tar.gz 54691 BLAKE2B 2564e4b3e888b0b24ed053bc85311062d8bafc07b12cdfd5ade2b5c276537bfa473377905282b4eb4901f13873e6319dc05fb12a07ae4525d89814b4edd84d57 SHA512 33c0a7c4be0df296dd859989f94db6eddf553e37e5580abe1dda63c33054e709a672a5eb9dc6f262f482f4d2a5507511aa0332022d46943251b5c522dff7c840
diff --git a/dev-python/setuptools_scm/setuptools_scm-6.2.0.ebuild b/dev-python/setuptools_scm/setuptools_scm-6.2.0.ebuild
new file mode 100644
index 000000000000..84147be61a34
--- /dev/null
+++ b/dev-python/setuptools_scm/setuptools_scm-6.2.0.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Manage versions by scm tags via setuptools"
+HOMEPAGE="
+	https://github.com/pypa/setuptools_scm/
+	https://pypi.org/project/setuptools-scm/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="dev-python/tomli[${PYTHON_USEDEP}]"
+BDEPEND="
+	!!<dev-python/setuptools_scm-2
+	test? (
+		dev-vcs/git
+		!sparc? ( dev-vcs/mercurial ) )"
+
+distutils_enable_tests --install pytest
+
+EPYTEST_DESELECT=(
+	# fetching from the Internet
+	testing/test_regressions.py::test_pip_download
+	testing/test_setuptools_support.py
+)
diff --git a/dev-python/sphinx-py3doc-enhanced-theme/sphinx-py3doc-enhanced-theme-2.3.2-r1.ebuild b/dev-python/sphinx-py3doc-enhanced-theme/sphinx-py3doc-enhanced-theme-2.3.2-r1.ebuild
index be1e25bcc5b5..40a9394ad852 100644
--- a/dev-python/sphinx-py3doc-enhanced-theme/sphinx-py3doc-enhanced-theme-2.3.2-r1.ebuild
+++ b/dev-python/sphinx-py3doc-enhanced-theme/sphinx-py3doc-enhanced-theme-2.3.2-r1.ebuild
@@ -14,4 +14,3 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 LICENSE="BSD"
 SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-IUSE=""
diff --git a/dev-python/sphinx_selective_exclude/metadata.xml b/dev-python/sphinx_selective_exclude/metadata.xml
index 7e0e439f138b..3cfb48fe1033 100644
--- a/dev-python/sphinx_selective_exclude/metadata.xml
+++ b/dev-python/sphinx_selective_exclude/metadata.xml
@@ -10,7 +10,8 @@
   <name>Python</name>
  </maintainer>
  <upstream>
-  <remote-id type="pypi">sphinx_selective_exclude</remote-id>
+  <remote-id type="pypi">sphinx-selective-exclude</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/sphinx_selective_exclude/sphinx_selective_exclude-1.0.3.ebuild b/dev-python/sphinx_selective_exclude/sphinx_selective_exclude-1.0.3.ebuild
index 6e7165fafde8..7556a73609b7 100644
--- a/dev-python/sphinx_selective_exclude/sphinx_selective_exclude-1.0.3.ebuild
+++ b/dev-python/sphinx_selective_exclude/sphinx_selective_exclude-1.0.3.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 
@@ -14,6 +14,5 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 LICENSE="BSD-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
-IUSE=""
 
 PDEPEND="dev-python/sphinx[${PYTHON_USEDEP}]"
diff --git a/dev-python/sphinxcontrib-doxylink/sphinxcontrib-doxylink-1.8.ebuild b/dev-python/sphinxcontrib-doxylink/sphinxcontrib-doxylink-1.8.ebuild
index 4f4c4f6bbd98..60611c8a790f 100644
--- a/dev-python/sphinxcontrib-doxylink/sphinxcontrib-doxylink-1.8.ebuild
+++ b/dev-python/sphinxcontrib-doxylink/sphinxcontrib-doxylink-1.8.ebuild
@@ -22,7 +22,12 @@ RDEPEND="
 	dev-python/pyparsing[${PYTHON_USEDEP}]
 "
 
-BDEPEND="test? ( app-doc/doxygen )"
+BDEPEND="
+	test? (
+		app-doc/doxygen
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+"
 
 distutils_enable_tests pytest
 distutils_enable_sphinx doc
diff --git a/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.2.1.ebuild b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.2.1.ebuild
index 29f93044fb1d..848004c1137c 100644
--- a/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.2.1.ebuild
+++ b/dev-python/sphinxcontrib-spelling/sphinxcontrib-spelling-7.2.1.ebuild
@@ -16,9 +16,6 @@ SLOT="0"
 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux"
 
 RDEPEND="
-	$(python_gen_cond_dep '
-		>=dev-python/importlib_metadata-1.7.0[${PYTHON_USEDEP}]
-	' python3_{6,7})
 	dev-python/pyenchant[${PYTHON_USEDEP}]
 	dev-python/sphinx[${PYTHON_USEDEP}]
 "
@@ -32,6 +29,10 @@ BDEPEND="
 # The doc can only be built from a git repository
 distutils_enable_tests pytest
 
+EPYTEST_DESELECT=(
+	tests/test_filter.py::test_contributors
+)
+
 # We don't want distutils_enable_tests to add the namespace
 # package to BDEPEND under "test?". Therefore we add it to RDEPEND
 # after running distutils_enable_tests.
@@ -39,14 +40,6 @@ RDEPEND+="
 	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]
 "
 
-python_test() {
-	local deselect=(
-		tests/test_filter.py::test_contributors
-	)
-
-	epytest ${deselect[@]/#/--deselect }
-}
-
 python_install_all() {
 	distutils-r1_python_install_all
 	find "${ED}" -name '*.pth' -delete || die
diff --git a/dev-python/tldextract/Manifest b/dev-python/tldextract/Manifest
index ee6ef4a2807f..b0c71b93dbe2 100644
--- a/dev-python/tldextract/Manifest
+++ b/dev-python/tldextract/Manifest
@@ -1,2 +1,3 @@
 DIST tldextract-2.2.1.tar.gz 54538 BLAKE2B 0abfb1982d0b9e9cd767bc64db289da8bf2f58b599eaea7e703adf36934dae0d052170fa9a8205b8ac0b441d8f1ac75648ccc108515586b0bcacf2ecb43fef52 SHA512 db4f14e514c0e68f85f28226343d7ec91ceea2843ee01c9a2950f0972f365bf343640e07cfb118aff52bab975719be71d179fc6b3bd4da7eb62a47b62747cc0b
 DIST tldextract-3.1.0.tar.gz 101874 BLAKE2B 105f34699de2118126dc0f9d68f25999f99211aa8529c2640dd21d303cfb18cd5388819986881e235b8111a21b74d99c6424ad469a66a0ac45c25a0e7c31a21f SHA512 c6c67598b7dd2c8e85008c5061693182eb075e16390b001eb696fd12a0f5666d0a327667a0fd61e4f270003a8cfc97a8fbf7b53a246bab6f9e9ad95943dac9d8
+DIST tldextract-3.1.1.tar.gz 103195 BLAKE2B e0cdf85e22d58bf68705e9c37cfffaa8a9508316e734adf682b14daa50f02b408cbeda9f4554674f0f582b3246e750bbc46c70d7528c1a4af30b55f05e4bf595 SHA512 caec65beca0b2ba8f294043cf2f64839aef9fe472d1a76619bef1ec6b33ac99ccd08c24601c7fd97fef215621c9ec71a34911d3832febdb36d3f8ac9561b1175
diff --git a/dev-python/tldextract/tldextract-3.1.1.ebuild b/dev-python/tldextract/tldextract-3.1.1.ebuild
new file mode 100644
index 000000000000..de4807fe93d1
--- /dev/null
+++ b/dev-python/tldextract/tldextract-3.1.1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Accurately separate the TLD from the registered domain and subdomains of a URL."
+HOMEPAGE="https://pypi.org/project/tldextract/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/idna[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/requests-file[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--pylint::' pytest.ini || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/weasyprint/Manifest b/dev-python/weasyprint/Manifest
index 104a0e47050d..c8d1fc8c4f4a 100644
--- a/dev-python/weasyprint/Manifest
+++ b/dev-python/weasyprint/Manifest
@@ -1 +1,2 @@
 DIST weasyprint-53.0.tar.gz 386339 BLAKE2B 6d8e30a02d54061557e549a685944de7cbc61f4c1b46b23dbaef66e87232325f630fd5a34cf5c846599612914f9306b5235fad65a008e19a7c200af2f4c7d9da SHA512 de34ee5654ee90aec82b67c1bc7d9496fe3a4247b2a649ab110d1613c4780fd9ae611c9da177de07e5287749978af9a4a7d5c102d0940e5fd970e5aa8586c47e
+DIST weasyprint-53.2.tar.gz 387220 BLAKE2B 820c3ef386c86ab927a02153e68ba085817d18c9658539233c283b2ee2e58a190420a88d3d1b4282d7e46eefbd89d9c5fbd94ccefaa6ef7c304d893579739482 SHA512 c4e1a831a9ac5b3adf1241b8c53c90330e3960cf7a5ab8307bbeb89e8e17a7e5a5d50fd676961ce45deda606b82eaa2b05d37f7dd5a1506bd0d78f8e4276328a
diff --git a/dev-python/weasyprint/weasyprint-53.2.ebuild b/dev-python/weasyprint/weasyprint-53.2.ebuild
new file mode 100644
index 000000000000..abdc28ba79f6
--- /dev/null
+++ b/dev-python/weasyprint/weasyprint-53.2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Visual rendering engine for HTML and CSS that can export to PDF"
+HOMEPAGE="https://weasyprint.org https://github.com/Kozea/WeasyPrint"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/cffi-0.6:=[${PYTHON_USEDEP}]
+	>=dev-python/cssselect2-0.1[${PYTHON_USEDEP}]
+	>=dev-python/fonttools-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pillow-4.0.0[jpeg,jpeg2k,${PYTHON_USEDEP}]
+	>=dev-python/pydyf-0.0.3[${PYTHON_USEDEP}]
+	>=dev-python/pyphen-0.9.1[${PYTHON_USEDEP}]
+	>=dev-python/tinycss2-1.0.0[${PYTHON_USEDEP}]
+	x11-libs/pango
+"
+
+BDEPEND="
+	test? (
+		app-text/ghostscript-gpl
+		media-fonts/ahem
+		media-fonts/dejavu
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/addopts/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}