Adding metadata

22 files changed, 595 insertions, 0 deletions

diff --git a/dev-python/aiohttp/Manifest b/dev-python/aiohttp/Manifest
index f1566c460eb4..f952f78c491e 100644
--- a/dev-python/aiohttp/Manifest
+++ b/dev-python/aiohttp/Manifest
@@ -1,2 +1,3 @@
 DIST aiohttp-3.8.6.tar.gz 7352172 BLAKE2B 4dc602abb4f9bd7c65bda7d11cde3e703bbc7786fb3f8ef36922caef42912b2c10a198ebdcecd3fcd022c3a9a729766a2023636f756a8fa10663bf988554f967 SHA512 43f1dd6670d90aefee7f0f30411b13c643ea684815b493cc4437e5f1981f4fdf4b718a40543d7c3c8c70d8b27470b8f3bf1609e46146362e0490ce0990a057f5
 DIST aiohttp-3.9.0.tar.gz 7475063 BLAKE2B 0447b9b095b3004b16eef37bd4d815f864dbfad7efb3021cb97676487cdf6d3007de47cb80daa773cc645ca60b21c79768fdc7a15163bb60578b4d05e17db924 SHA512 3001ea211985c26aa4f8a20210d80d6e72a904c1ea93a5aed5d08eb191dd253155ec5a44ae14d961c6ebbc747cbc8e602866ee7eb0b8963cf783a68dcf8b3ba6
+DIST aiohttp-3.9.1.tar.gz 7482118 BLAKE2B 2150ae98f799f9c6e1f48987bfd8b1847439d8b87cd21417676c2fa5c971fcdc13c3f933dfdd5eceb92b47ad604d16c2a71d884118d8bde1816f2d944d2930a2 SHA512 3288085d5fbcfb7e3664f906345aeab6f989f2318babae6bf5cc3955de48707e9de56ce3b9553d6ee35c72b8f884dc1fd01861a638ee738573e78a203e6a9dec
diff --git a/dev-python/aiohttp/aiohttp-3.9.1.ebuild b/dev-python/aiohttp/aiohttp-3.9.1.ebuild
new file mode 100644
index 000000000000..7da95098a16a
--- /dev/null
+++ b/dev-python/aiohttp/aiohttp-3.9.1.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="HTTP client/server for asyncio"
+HOMEPAGE="
+	https://github.com/aio-libs/aiohttp/
+	https://pypi.org/project/aiohttp/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/aiosignal-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
+	dev-python/brotlicffi[${PYTHON_USEDEP}]
+	>=dev-python/frozenlist-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		<dev-python/async-timeout-5[${PYTHON_USEDEP}]
+		>=dev-python/async-timeout-4.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python3*')
+		test-rust? (
+			dev-python/trustme[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+DOCS=( CHANGES.rst CONTRIBUTORS.txt README.rst )
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# increase the timeout a little
+	sed -e '/abs=/s/0.001/0.01/' -i tests/test_helpers.py || die
+	# xfail_strict fails on py3.10
+	sed -i -e '/--cov/d' -e '/xfail_strict/d' setup.cfg || die
+	sed -i -e 's:-Werror::' Makefile || die
+
+	distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	# workaround missing files
+	mkdir tools || die
+	> requirements/cython.txt || die
+	> tools/gen.py || die
+	chmod +x tools/gen.py || die
+	# force rehashing first
+	emake requirements/.hash/cython.txt.hash
+	> .update-pip || die
+	> .install-cython || die
+	emake cythonize
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# proxy is not packaged
+		tests/test_proxy_functional.py
+		# python_on_whales is not packaged
+		tests/autobahn/test_autobahn.py
+	)
+
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/test_client_session.py::test_client_session_timeout_zero
+		# broken by irrelevant deprecation warnings
+		tests/test_circular_imports.py::test_no_warnings
+		# TODO
+		tests/test_client_session.py::test_request_tracing_url_params
+		# fragile timing test
+		tests/test_imports.py::test_import_time
+		# crash in time-machine
+		# https://github.com/aio-libs/aiohttp/issues/7851
+		# https://github.com/adamchainz/time-machine/issues/403
+		tests/test_cookiejar.py::TestCookieJarSafe::test_max_age
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			# upstream unconditionally blocks building C extensions
+			# on PyPy3 but the test suite needs an explicit switch,
+			# sigh
+			local -x AIOHTTP_NO_EXTENSIONS=1
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_mock,xdist.plugin,pytest_forked
+	rm -rf aiohttp || die
+	epytest --forked
+}
diff --git a/dev-python/cython/Manifest b/dev-python/cython/Manifest
index 63c67f8fddd8..7bd49ccadde4 100644
--- a/dev-python/cython/Manifest
+++ b/dev-python/cython/Manifest
@@ -3,3 +3,4 @@ DIST cython-3.0.2.gh.tar.gz 2744583 BLAKE2B f631891870a6ce24acf2bcde75ebcb9775cf
 DIST cython-3.0.3.gh.tar.gz 2753188 BLAKE2B 0e6d40533f1cebf3c4217dc19aeebc2f873a8bacb94e68810e81d1c6d4cd75176de88516f2d82f43b36107656b6cd5e6990547e93bd8436b1aa93c73ccda6eaf SHA512 c27c16abaf0122ad61e0eeb92aa80a33fc491332b8ebec209cd1810d2b0e3bf14fe1e81838803b86f407520a6d6f7ab8b84d97e495e7d91fd6f7702a46980caa
 DIST cython-3.0.4.gh.tar.gz 2754689 BLAKE2B 5418b8c374565894deb07e7a3f2fe242e1ef43eed5d716cbd9c6b9fd3d62088d9982eb156c981fa9f6edcf42592f2249f9eb450d16ef908be464e357ee9bbea7 SHA512 bc87e38f9c188a5311f75f49ba4b9ec1ee0af00ff9ed655ca69972891f8b0801025265f8cad4521670088275c7da3d6136aeda7ebb6a33554f64cc7aef362c73
 DIST cython-3.0.5.gh.tar.gz 2756583 BLAKE2B d9b5af97933030fc1ac49677a5f3fd8194ba6e685dccd257f4ef4af206565ae2fa6f72c1268d8d0604b6fd6f2d8147c542501e8e319588bfdc4a7f40622976ff SHA512 585d3fe810ace55278fcc6ea4508b3b5259320f92998cd688da787cd5f88ac5fc2467025f20da6d968969eb3296ae9c517136d24a4dbb475441271227968f6be
+DIST cython-3.0.6.gh.tar.gz 2759853 BLAKE2B fdcbb870418eebfb2e55e28f7223699fee4fb06d52f9f41db55b30fbe6ba6ee3de42af9bbdd8930d418ec790dec195546486ea45c370e2df122d6fada08d38cf SHA512 f1d33775166d0b6541ea98bee5d4186fc6128aad788323224397c1f3ba0a058141ac84a8b3baa4885204dcbf0979141bc4b5316342003e96208952f040f31753
diff --git a/dev-python/cython/cython-3.0.6.ebuild b/dev-python/cython/cython-3.0.6.ebuild
new file mode 100644
index 000000000000..c644f619be87
--- /dev/null
+++ b/dev-python/cython/cython-3.0.6.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{8,9,10,11,12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 multiprocessing toolchain-funcs
+
+MY_P=${P/_rc/rc}
+DESCRIPTION="A Python to C compiler"
+HOMEPAGE="
+	https://cython.org/
+	https://github.com/cython/cython/
+	https://pypi.org/project/Cython/
+"
+SRC_URI="
+	https://github.com/cython/cython/archive/${PV/_rc/rc}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/numpy[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.29.22-spawn-multiprocessing.patch"
+	"${FILESDIR}/${PN}-0.29.23-test_exceptions-py310.patch"
+	"${FILESDIR}/${PN}-0.29.23-pythran-parallel-install.patch"
+)
+
+distutils_enable_sphinx docs \
+	dev-python/jinja \
+	dev-python/sphinx-issues \
+	dev-python/sphinx-tabs
+
+python_compile() {
+	# Python gets confused when it is in sys.path before build.
+	local -x PYTHONPATH=
+
+	distutils-r1_python_compile
+}
+
+python_test() {
+	if ! has "${EPYTHON/./_}" "${PYTHON_TESTED[@]}"; then
+		einfo "Skipping tests on ${EPYTHON} (xfail)"
+		return
+	fi
+
+	# Needed to avoid confusing cache tests
+	unset CYTHON_FORCE_REGEN
+
+	tc-export CC
+	# https://github.com/cython/cython/issues/1911
+	local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
+	"${PYTHON}" runtests.py \
+		-vv \
+		-j "$(makeopts_jobs)" \
+		--work-dir "${BUILD_DIR}"/tests \
+		--no-examples \
+		--no-code-style \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/ensurepip-wheel/Manifest b/dev-python/ensurepip-wheel/Manifest
index 81c2e36fbdf3..13d3d5ed3f7d 100644
--- a/dev-python/ensurepip-wheel/Manifest
+++ b/dev-python/ensurepip-wheel/Manifest
@@ -1,2 +1,3 @@
 DIST wheel-0.41.2-py3-none-any.whl 64848 BLAKE2B 761efd3a97a9bbfbbd7683f12638aa5b0ed83679f3313cb8dce2632d2d2ba33fb9f0801a57e21077e8a232464aa929338983d334d57b4ccdf5f2c78a26202ca5 SHA512 9ecad670c61e4e2e598058cbd405e29401068a93d758c63481df72cff5e0a9f22b3c5ee1ae705140cffa1ea98149a6a8a9b3c80a356b520ea10bee586e615473
 DIST wheel-0.41.3-py3-none-any.whl 65801 BLAKE2B 93582f1ee65ccae9d1915d51ad8bca5fa8b0700f3ccbe1d572299eef2676c6d41162c6a2d6ac79c3c8ab02242235283e86b97a2d24137d0e116e7decd1738e8b SHA512 5be2eabac26432a03d6a81954e80f004617e372bdce1a8d4f562af227964cace6883ee41d9300e7ccc2bd39b5330c4578c33777e8420868bc7a416352aea0623
+DIST wheel-0.42.0-py3-none-any.whl 65375 BLAKE2B 36887c4203b1ebd6a675f3977f78cab89bcb1fe99c939648e81e6bef02d99a2559e6a2b4d1cf76957c30d2da9aa937335cf12e19d8b55fd4a04ceb32307c2e27 SHA512 59cbcab7516e698ec3bd9eeadc550920df9406b07c53eb9bc2023db0121ec3ad6ad2556ac3e13c7c7bda55e8131b1e13fb5e51a74906abec3914e11230428fb2
diff --git a/dev-python/ensurepip-wheel/ensurepip-wheel-0.42.0.ebuild b/dev-python/ensurepip-wheel/ensurepip-wheel-0.42.0.ebuild
new file mode 100644
index 000000000000..e3e7fe90c1fa
--- /dev/null
+++ b/dev-python/ensurepip-wheel/ensurepip-wheel-0.42.0.ebuild
@@ -0,0 +1,20 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit pypi
+
+DESCRIPTION="Shared wheel wheel for use in pip tests"
+HOMEPAGE="https://pypi.org/project/wheel/"
+SRC_URI="$(pypi_wheel_url "${PN#ensurepip-}")"
+S=${DISTDIR}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+src_install() {
+	insinto /usr/lib/python/ensurepip
+	doins "${A}"
+}
diff --git a/dev-python/jupyter-lsp/Manifest b/dev-python/jupyter-lsp/Manifest
index 1ebfeb85b91d..04a061ed5252 100644
--- a/dev-python/jupyter-lsp/Manifest
+++ b/dev-python/jupyter-lsp/Manifest
@@ -1 +1,2 @@
 DIST jupyter-lsp-2.2.0.tar.gz 45769 BLAKE2B 7004a1bc6b8ece280df1bb54a80ca8b7d93a4995a92c909dcc7f6193500b1881ca5beb6fc3b0c1a4e7659465216b05b4ee7b83b1d2973fce5b74a304e87e3fd4 SHA512 0f6d844be172054eed7599eb5f2c2be4c1ebb749176af3f08aa3327849fa045de2b8f9003c67188ed0f1b7ba2e28f1223d0dcca008eaa528caacf38a95c3f59b
+DIST jupyter-lsp-2.2.1.tar.gz 45839 BLAKE2B 5f7af7a335f97f8f35ebcd2cabb9b6377ec3bbc9b756bcd9c02e3b2ab8798855c2de9df7b9c3f1b832672030de660e1b6a475de70708911c1deca128d1cbfe44 SHA512 2f8d5a7a19daedd649810baa43bed5ae994dec7245a793298f5de4c32fd22190ffa3c4a356b3bfda3422fcdce5a34ea081c7f49030db8fcb633f761719ecfe4b
diff --git a/dev-python/jupyter-lsp/jupyter-lsp-2.2.1.ebuild b/dev-python/jupyter-lsp/jupyter-lsp-2.2.1.ebuild
new file mode 100644
index 000000000000..f6fcf7143f52
--- /dev/null
+++ b/dev-python/jupyter-lsp/jupyter-lsp-2.2.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYPI_NO_NORMALIZE=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Multi-Language Server WebSocket proxy for Jupyter Notebook/Lab"
+HOMEPAGE="
+	https://github.com/jupyter-lsp/jupyterlab-lsp
+	https://pypi.org/project/jupyter-lsp/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/entrypoints[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-server-1.1.2[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not depend on pytest-cov or flake8
+	sed -i -e '/--cov/d' -e '/--flake8/d' setup.cfg || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Not packaged
+		jupyter_lsp/tests/test_detect.py::test_r_package_detection
+		"jupyter_lsp/tests/test_listener.py::test_listeners[bash-language-server]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[dockerfile-language-server-nodejs]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[pylsp]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[sql-language-server]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[typescript-language-server]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[unified-language-server]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[vscode-css-languageserver-bin]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[vscode-html-languageserver-bin]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[vscode-json-languageserver-bin]"
+		"jupyter_lsp/tests/test_listener.py::test_listeners[yaml-language-server]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[bash-language-server]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[dockerfile-language-server-nodejs]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[pylsp]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[sql-language-server]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[typescript-language-server]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[unified-language-server]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[vscode-css-languageserver-bin]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[vscode-html-languageserver-bin]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[vscode-json-languageserver-bin]"
+		"jupyter_lsp/tests/test_session.py::test_start_known[yaml-language-server]"
+	)
+
+	case ${EPYTHON} in
+		python3.12)
+			EPYTEST_DESELECT+=(
+				jupyter_lsp/tests/test_session.py::test_start_unknown
+			)
+			;;
+	esac
+
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	optfeature "Language server for Python" dev-python/python-lsp-server
+}
diff --git a/dev-python/jupyterlab-lsp/Manifest b/dev-python/jupyterlab-lsp/Manifest
index 1184776e05fe..ec7ed5ec374d 100644
--- a/dev-python/jupyterlab-lsp/Manifest
+++ b/dev-python/jupyterlab-lsp/Manifest
@@ -1 +1,2 @@
 DIST jupyterlab-lsp-5.0.0.tar.gz 753429 BLAKE2B bd9fac94edea990943ce839c773270f14a5afd646b312c3c6888a0230c2846968388862c01c4954830d85c3eebcd6699aed79cc7861e4fb8d19d576cf0ba938b SHA512 a6e586cf19707a6aec91f495fbb437ce2aaa6b827964c06d4479d056b0a8eca525c46a3e3e8c7891e0f486cde9b63416a80188c623f71948e4b1658a751d98b1
+DIST jupyterlab-lsp-5.0.1.tar.gz 755832 BLAKE2B d8082aaf9c1219fedeebd6a717b81f08a7bba2a8618dc99b2ecf9a6d28c4e6cbf34b711c4fae4a847675ea05d2dc7acd0c812a772e9d51f37f563d088398c088 SHA512 7fef1ab7309978aa9185afdc895a7adefc72210842228d055150b231b70980e772abf166762820971f653cf0f5abd65e9bdfe3a206c4aed99b4586fec684399e
diff --git a/dev-python/jupyterlab-lsp/jupyterlab-lsp-5.0.1.ebuild b/dev-python/jupyterlab-lsp/jupyterlab-lsp-5.0.1.ebuild
new file mode 100644
index 000000000000..1ad2de9795ef
--- /dev/null
+++ b/dev-python/jupyterlab-lsp/jupyterlab-lsp-5.0.1.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Coding assistance for JupyterLab with Language Server Protocol"
+HOMEPAGE="
+	https://github.com/jupyter-lsp/jupyterlab-lsp/
+	https://pypi.org/project/jupyterlab-lsp/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/jupyterlab-4.0.0[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-5.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-lsp-2.0.0[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/mkdocs-material/Manifest b/dev-python/mkdocs-material/Manifest
index 7410eedff1d3..60c565d2ef80 100644
--- a/dev-python/mkdocs-material/Manifest
+++ b/dev-python/mkdocs-material/Manifest
@@ -1,6 +1,7 @@
 DIST mkdocs-material-9.4.10.gh.tar.gz 14552628 BLAKE2B 167cc7388d18c4db4c763b50356932a5e1fe03c19232fb79a6cfdecefb6295c67fabfc089ccd83660bebba6098ad1ba24ecb9afcf58d91e46401821466fce502 SHA512 62905520b8ad9ede2357f4b4208a9409aa7134d77b51efdcd87de2a69ba6b4200da297a8b654ff9c96a9147b322c753b66e6106f5d0b872a9b993494801b7e22
 DIST mkdocs-material-9.4.11.gh.tar.gz 14560073 BLAKE2B 83079e3a7fa1fc4125954e49953666c52619148157174f8d1f9abea95b10715122f4d053219eef9253db2d7137d8abc053ea096c52006e5ff05d2f4026ca4220 SHA512 38d7de0e21125a71fab33d2469d1b6775cb45f85d9775eef9e4a1feefd01a18ea658e6ca9dcb16ccf0f580089be12d52812f5f34d5500502b11f72f30c66d080
 DIST mkdocs-material-9.4.12.gh.tar.gz 14560964 BLAKE2B 546e02f89c79e56c67265869c4bb0e9e91462b3c24024e59a2fc538537a52abed4431d3975e84105cc237786dc2baa4b0023af4748bb9425a83b175fd19c90fd SHA512 ad0486b68ec3802ed637464f8e45d56ad507f42e9b28119ed71f49583181d56bed3e6b70b438c8151ac2b6019eae391b4572de4c80dec5d16442b06d07d0c020
+DIST mkdocs-material-9.4.14.gh.tar.gz 14563700 BLAKE2B 313698c16f79cc11fc9aa2905313871605f683fad32073e956402728e0b51cbd2788947c11711eb1fc9a0addb8cdc1d7382703cc5a6684a72541f40a1afb699f SHA512 1102c1003562af2fc7126d85d8e5b0556cd240d6c56273f811947bbfc650fd7554b8b979ab9e14a43ed3dc44688c7ce277e28fdd4cbb6787b83b9f76d80a3bbf
 DIST mkdocs-material-9.4.7.gh.tar.gz 14556029 BLAKE2B a3f0289afcd38dc9af2bb18205e19e78565fbe4230ed5a730736945d6b12edbcf598b337ad0715b96184059d434b6589d133bc93cec7624a72bc89ce4c30c352 SHA512 31feb4bdb5ad54fdfbe0cc054fce76e2af3b2c87424c1f3ffbda7500852074994a09de94c51b87fa40145afce6e82911b3e7399691a6c736e8c0858cc094107b
 DIST mkdocs-material-9.4.8.gh.tar.gz 14556346 BLAKE2B 21cdf8e9c4d0e236db1d3bc34510be57ea273ec8b8761d896b82f32e1001313f4e00716a9b90c956ef81b522370e622bc6ad83c342a5c29cdd83e3006aae0bdf SHA512 d6f89071b60f1259f34e96e5ff3562c80096a1b3ac2b5ff44f1bf20818bdff32067d125c24d15c3b8e794e3649c42f6681417dbf1b72f0c0bd10e345e20b5be9
 DIST mkdocs-material-9.4.9.gh.tar.gz 14552215 BLAKE2B 69411102e874017f9a74991cda8552d9ea2422ba5717bfe31e89f99f1e042711ea2c12cf4eb1bcd1b897d260c262869c9c230c5c4ec8c9a110be5583546dd882 SHA512 cb7535b2989f752a4cbd4bf783358dcc388e4cff03273898273b1c65332471dcd7a21571e9bf1c55666339e0462bf356d1d6c17f59f75a54ab388bb357e1c6a3
diff --git a/dev-python/mkdocs-material/mkdocs-material-9.4.14.ebuild b/dev-python/mkdocs-material/mkdocs-material-9.4.14.ebuild
new file mode 100644
index 000000000000..31c55fa06872
--- /dev/null
+++ b/dev-python/mkdocs-material/mkdocs-material-9.4.14.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-material-extensions
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-redirects
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="A Material Design theme for MkDocs"
+HOMEPAGE="
+	https://github.com/squidfunk/mkdocs-material/
+	https://pypi.org/project/mkdocs-material/
+"
+SRC_URI="
+	https://github.com/squidfunk/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="social"
+
+RDEPEND="
+	>=dev-python/Babel-2.10.3[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.6[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.5.3[${PYTHON_USEDEP}]
+	>=dev-python/paginate-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.16[${PYTHON_USEDEP}]
+	>=dev-python/pymdown-extensions-10.2[${PYTHON_USEDEP}]
+	>=dev-python/readtime-2.0[${PYTHON_USEDEP}]
+	>=dev-python/regex-2022.4.24[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26[${PYTHON_USEDEP}]
+	social? (
+		>=dev-python/pillow-9.0[${PYTHON_USEDEP}]
+		>=media-gfx/cairosvg-2.5[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/trove-classifiers-2023.10.18[${PYTHON_USEDEP}]
+"
+# mkdocs-material-extensions depends on mkdocs-material creating a circular dep
+PDEPEND="
+	>=dev-python/mkdocs-material-extensions-1.2[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	# simplify pyproject to remove extra deps for metadata
+	"${FILESDIR}/${PN}-8.5.7-simplify-build.patch"
+)
+
+src_prepare() {
+	echo "__version__ = '${PV}'" > gentoo_version.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/multitasking/Manifest b/dev-python/multitasking/Manifest
new file mode 100644
index 000000000000..26302d02df89
--- /dev/null
+++ b/dev-python/multitasking/Manifest
@@ -0,0 +1 @@
+DIST multitasking-0.0.11.tar.gz 9843 BLAKE2B 7c6c5e7270c3edb9535406399d9c8a2fbc45d3a57854c77b27af6375ec4c3cea32fe9c57252916da453b2c47ae23f4f9faf186f54fa651dece130eb31abbb7f3 SHA512 ebfdaae828f00aee4bd3e5527a6dd7a466c6497538db4f0223278dd9504020b08cba6a5c39e871e7927b1cdef4487248ff513bbdbaf9a3c11631d9d105c46052
diff --git a/dev-python/multitasking/metadata.xml b/dev-python/multitasking/metadata.xml
new file mode 100644
index 000000000000..36acccda7221
--- /dev/null
+++ b/dev-python/multitasking/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>dev@liguros.net</email>
+  <name>Development</name>
+ </maintainer>
+ 
+ <origin>ports</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/multitasking/multitasking-0.0.11.ebuild b/dev-python/multitasking/multitasking-0.0.11.ebuild
new file mode 100644
index 000000000000..3d0047e071e0
--- /dev/null
+++ b/dev-python/multitasking/multitasking-0.0.11.ebuild
@@ -0,0 +1,16 @@
+# Copyright 2023 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Non-blocking Python methods using decorators"
+HOMEPAGE="https://github.com/ranaroussi/multitasking"
+SRC_URI="https://github.com/ranaroussi/multitasking/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
diff --git a/dev-python/pytest-salt-factories/Manifest b/dev-python/pytest-salt-factories/Manifest
index 90adc5396b18..556d3f94fcc7 100644
--- a/dev-python/pytest-salt-factories/Manifest
+++ b/dev-python/pytest-salt-factories/Manifest
@@ -1,3 +1,4 @@
 DIST pytest-salt-factories-1.0.0_rc20.gh.tar.gz 160140 BLAKE2B 7ecd9af695626c465e5776ed218bd92f30a556394cf4af0c2b6fb87c182f8aaf2d8f998358a7eef95fae53c85a6be2d4ed5a6ff191496fcac62a97e25cf19063 SHA512 5677c6638b5dc7f90c01f2c2204e1910c2bf6ea2c10b714173d3443d4c682b5f515ad7881e2ceee66f6eaf619e399d6fa10052604fdc9c5157c58348b63c8f2b
 DIST pytest-salt-factories-1.0.0_rc23.gh.tar.gz 162711 BLAKE2B 28610679d7717d7a6f97a2f14a1ac838aec5101171ae65f2328d9b902d04b272c5e37f08d8ff3414af52ff7af954da24c083dfdc4afd1a9342b09cce0bf5aec3 SHA512 22d8f4a1c48a144437b9ff7d064760b59bb2a1003838e07f446a6150a77c162bffa7f21c570f796d8214d870d5b029e92abf7b0410ce19726085b607628364f0
 DIST pytest-salt-factories-1.0.0_rc25.gh.tar.gz 166148 BLAKE2B 11935c0164727968b9f2bd6f77498ea9ed4dbafd48bd6bb2730716fbcb1bb69b1ab09ef9ea2e2519368f4b6408bbb03f41fb0e52fc3cf75695f2b9c2b8d37294 SHA512 dd18688731b6bd2384abff9d739154b1ca7786bc3843d9fa8c293d1950925fff6c5820680a8095d4d5f3b75bcaeb07d8b3c7703ecab64a5f3a28bad11da18397
+DIST pytest-salt-factories-1.0.0_rc28.gh.tar.gz 168150 BLAKE2B c286c2a3933f8a987f1073ba97097cec29bf494cac9c4ba21ec4c261e22570ac3445900cacf629cce6253fb1a5fb95eb3d637b4d26e8835648dd11c569a7255e SHA512 ea362daa83007d9054b023ca9c11864ba304d802fa359c8cb883aa929f339c5347d50560a2d4a9cbc151a7b05bc46d1dc2f7693dd32d26383766cb5f249f3484
diff --git a/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc28.ebuild b/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc28.ebuild
new file mode 100644
index 000000000000..3eb94603ead5
--- /dev/null
+++ b/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc28.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="The new generation of the pytest-salt Plugin"
+HOMEPAGE="
+	https://github.com/saltstack/pytest-salt-factories/
+	https://pypi.org/project/pytest-salt-factories/
+"
+SRC_URI="
+	https://github.com/saltstack/pytest-salt-factories/archive/${PV//_/}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${P//_/}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/docker[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7.0.0[${PYTHON_USEDEP}]
+	dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+	dev-python/pytest-skip-markers[${PYTHON_USEDEP}]
+	dev-python/pytest-system-statistics[${PYTHON_USEDEP}]
+	>=dev-python/pytest-shell-utilities-1.4.0[${PYTHON_USEDEP}]
+	dev-python/pyzmq[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	>=app-admin/salt-3005.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/importlib-metadata[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	sed -i -e 's:helpers_namespace:pytest_&.plugin:' tests/conftest.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/integration/factories/daemons/ssh/test_salt_ssh.py::test_salt_ssh
+		tests/integration/factories/daemons/sshd/test_sshd.py::test_connect
+		tests/scenarios/examples/test_echoext.py::test_echoext
+	)
+
+	local ret tempdir x
+	# ${T} is too long a path for the tests to work
+	tempdir="$(mktemp -du --tmpdir=/tmp salt-XXX)" || die
+	addwrite "${tempdir}"
+
+	local -x SHELL="/bin/bash" TMPDIR="${tempdir}"
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=saltfactories.plugins
+	PYTEST_PLUGINS+=,pytest_helpers_namespace.plugin
+	PYTEST_PLUGINS+=,pytestsysstats.plugin
+	PYTEST_PLUGINS+=,pytest_subtests
+	for x in factories markers sysinfo event_listener log_server loader
+	do
+		PYTEST_PLUGINS+=,saltfactories.plugins.${x}
+	done
+ 
+	nonfatal epytest --no-sys-stats
+	ret=${?}
+
+	rm -rf "${tempdir}" || die
+	[[ ${ret} -ne 0 ]] && die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/wheel/Manifest b/dev-python/wheel/Manifest
index 07095c15add6..36df7d89251a 100644
--- a/dev-python/wheel/Manifest
+++ b/dev-python/wheel/Manifest
@@ -1,2 +1,3 @@
 DIST wheel-0.41.2.tar.gz 98050 BLAKE2B 211c3021179e2f80036f57d59583ac449e91558e64fb10cc5b925d93f7288c6db444ca2ac35a20b13a2646641885c094faa458b591554f3bd926c53a3d099ec2 SHA512 46632c2e61f286d33609bc7f954da86c537e4c70b30cb57e79ae8fd5e4422f4fb46dcf2434361d3c6b45b9e5adc6cbf33daa1cd2fc40f31a393162c97ed38356
 DIST wheel-0.41.3.tar.gz 98880 BLAKE2B 3d07d03fabb3c339aecca772fa2229d92893c0fcdffaba726e2be2255f24e728d7d77dc33a03755f01f03e66e8ce098ec6e6d354776c1ee7fe58fa8a02a1e593 SHA512 53fde824b563167825d8f8b5f802bf419f5b1ae823665d27ac8cfe05eee372ea339f8203d1565044c2cae901fe539a2353559351a6a5dafd26c65dde4e2e5eda
+DIST wheel-0.42.0.tar.gz 98667 BLAKE2B 201f8246dc55c62bb700e706d7734e76689b13a3036aeeca7531f483c7f354ccc5ca7452106038425ba300e74f1041f7408f6749d03e39aca289398598833014 SHA512 4816261c0f6d8971a80665f66868ec9cb082f2189b6e31e083a0d3a6080e159f06a4152f44eda1147a2b907b5aead0f63bbac725aacb56bb8be13fc77da2b79c
diff --git a/dev-python/wheel/wheel-0.42.0.ebuild b/dev-python/wheel/wheel-0.42.0.ebuild
new file mode 100644
index 000000000000..8a9e778a4edc
--- /dev/null
+++ b/dev-python/wheel/wheel-0.42.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A built-package format for Python"
+HOMEPAGE="
+	https://github.com/pypa/wheel/
+	https://pypi.org/project/wheel/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos ~x64-solaris"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unbundle packaging
+	rm -r src/wheel/vendored || die
+	sed -i -e 's:\.vendored\.::' src/wheel/*.py || die
+	sed -i -e 's:wheel\.vendored\.::' tests/*.py || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/yfinance/Manifest b/dev-python/yfinance/Manifest
new file mode 100644
index 000000000000..ee9342f5d565
--- /dev/null
+++ b/dev-python/yfinance/Manifest
@@ -0,0 +1 @@
+DIST yfinance-0.2.32.tar.gz 98969 BLAKE2B 3264b2093a2b13c43be76bce54c557b9be00cae426400e7394f3d67e17d221351400d72de12cf7625c7eba4d4f36f04d1ab8e4cf5b188274056ca2e19fa594fc SHA512 1e62eed6b4cdad549f02129e7f42d42f53397d7cb9e322aebf22187c5c138d37807eb2ef8d35d929ca34f1d1e5b2aad508676e158d30b71302b5f031741ef2a9
diff --git a/dev-python/yfinance/metadata.xml b/dev-python/yfinance/metadata.xml
new file mode 100644
index 000000000000..36acccda7221
--- /dev/null
+++ b/dev-python/yfinance/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>dev@liguros.net</email>
+  <name>Development</name>
+ </maintainer>
+ 
+ <origin>ports</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/yfinance/yfinance-0.2.32.ebuild b/dev-python/yfinance/yfinance-0.2.32.ebuild
new file mode 100644
index 000000000000..1a8dc2fbb65a
--- /dev/null
+++ b/dev-python/yfinance/yfinance-0.2.32.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2023 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Download market data from Yahoo! Finance's API"
+HOMEPAGE="https://aroussi.com/post/python-yahoo-finance"
+SRC_URI="https://github.com/ranaroussi/yfinance/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pandas-1.3.0
+	>=dev-python/numpy-1.16.5
+	>=dev-python/requests-2.31
+	>=dev-python/lxml-4.9.1
+	>=dev-python/appdirs-1.4.4
+	>=dev-python/pytz-2022.5
+	>=dev-python/frozendict-2.3.4
+	>=dev-python/beautifulsoup4-4.11.1
+	>=dev-python/html5lib-1.1
+	>=dev-python/peewee-3.16.2
+"