Adding metadata

46 files changed, 700 insertions, 261 deletions

diff --git a/dev-python/bitstring/Manifest b/dev-python/bitstring/Manifest
index b39bf8442961..78d86a001307 100644
--- a/dev-python/bitstring/Manifest
+++ b/dev-python/bitstring/Manifest
@@ -1 +1,2 @@
 DIST bitstring-4.1.4.tar.gz 232014 BLAKE2B fad74a1a2931504b44c7d95c4e88b058c17ee189ab7b4ec6987d1284c273329b7850cd1aff8e93eb6badf7d52284db006f1f1118ee5f871694f2bd5b4b10e449 SHA512 e05d983ac340565b193c4b4d5f7f5fceea3ba68f04c348ab42cd1d783ac64e1b1adb0ce9bcaac20335137f103d51df198421c7cfee1e5c1ad9f3c9b89b77b679
+DIST bitstring-4.2.0.tar.gz 248168 BLAKE2B 72167fd3c18f80a46f5d1a0567644db8dfb1110c7c3884660b442903fa82fb625d7474cdde53dc1a58fd3560c0fc5664a53b1fccef13111dac78f715cc3477c3 SHA512 b3df84fc4e38faee704a8880533d436d33faae2b4786098cb755554100188528715d17f2dfdb3f09ea91cf4b45424b87cdf5d10952f1748addbc2492521ab7e9
diff --git a/dev-python/bitstring/bitstring-4.2.0.ebuild b/dev-python/bitstring/bitstring-4.2.0.ebuild
new file mode 100644
index 000000000000..6142fca92987
--- /dev/null
+++ b/dev-python/bitstring/bitstring-4.2.0.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A pure Python module for creation and analysis of binary data"
+HOMEPAGE="
+	https://github.com/scott-griffiths/bitstring/
+	https://pypi.org/project/bitstring/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/bitarray-3[${PYTHON_USEDEP}]
+	>=dev-python/bitarray-2.9.0[${PYTHON_USEDEP}]
+	dev-python/gfloat[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/dataclasses-json/Manifest b/dev-python/dataclasses-json/Manifest
new file mode 100644
index 000000000000..c011b221ef4d
--- /dev/null
+++ b/dev-python/dataclasses-json/Manifest
@@ -0,0 +1 @@
+DIST dataclasses-json-0.5.14.gh.tar.gz 72513 BLAKE2B f45ca18030388efcc21ca9c939bf2298f891de66d62dc0f8042a3d0e26cc0bae63c7c5a02c839b07282c3110d6e5752979e3abea361b215b86b354984901c77c SHA512 5ec21843ef29a8e6e9511922698f42c115c7e641ca9ae5e47a58c6f0697a51928fd462f6342190263469baa70b76a302ad1d27954f50b9457b97149586f35703
diff --git a/dev-python/dataclasses-json/dataclasses-json-0.5.14.ebuild b/dev-python/dataclasses-json/dataclasses-json-0.5.14.ebuild
new file mode 100644
index 000000000000..d5c2a8c3ea31
--- /dev/null
+++ b/dev-python/dataclasses-json/dataclasses-json-0.5.14.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Easily serialize Data Classes to and from JSON"
+HOMEPAGE="https://github.com/lidatong/dataclasses-json"
+SRC_URI="https://github.com/lidatong/dataclasses-json/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${P/_/-}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/marshmallow-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/marshmallow_enum-1.5.1[${PYTHON_USEDEP}]
+	>=dev-python/typing-inspect-0.4.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/mypy-0.710[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/dataclasses-json/metadata.xml b/dev-python/dataclasses-json/metadata.xml
new file mode 100644
index 000000000000..736a1167c898
--- /dev/null
+++ b/dev-python/dataclasses-json/metadata.xml
@@ -0,0 +1,6 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ 
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/gfloat/Manifest b/dev-python/gfloat/Manifest
new file mode 100644
index 000000000000..e5873b0692c7
--- /dev/null
+++ b/dev-python/gfloat/Manifest
@@ -0,0 +1 @@
+DIST gfloat-0.0.5.tar.gz 17493 BLAKE2B d2eb75b6ecdf58b0875481fb2428ee2bed998988ded0e0bf212dc5834c428a8a2af0796e6badf2ff2c400432db266a82312743bc338cb6444bbb3133526dcf7b SHA512 b08d4f8cb3c8e2e629d32c96ecf3efb81280363bba9ac90a489ffcd2418a9a4a0c9248ce3f524d9873a295b5e5e520c70ebd098e7cfdfe9a3dc92d8ee58920ca
diff --git a/dev-python/gfloat/gfloat-0.0.5.ebuild b/dev-python/gfloat/gfloat-0.0.5.ebuild
new file mode 100644
index 000000000000..ec8297ffa986
--- /dev/null
+++ b/dev-python/gfloat/gfloat-0.0.5.ebuild
@@ -0,0 +1,30 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Generic floating-point types in Python"
+HOMEPAGE="
+	https://github.com/graphcore-research/gfloat/
+	https://pypi.org/project/gfloat/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ml-dtypes[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/sphinxcontrib-asyncio/metadata.xml b/dev-python/gfloat/metadata.xml
index a0d4c5913ba0..7ad11570cc7d 100644
--- a/dev-python/sphinxcontrib-asyncio/metadata.xml
+++ b/dev-python/gfloat/metadata.xml
@@ -6,5 +6,4 @@
  </maintainer>
  
  <origin>gentoo-staging</origin>
- <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/gst-python/gst-python-1.22.11.ebuild b/dev-python/gst-python/gst-python-1.22.11.ebuild
index 58c75e462f41..489400efe99c 100644
--- a/dev-python/gst-python/gst-python-1.22.11.ebuild
+++ b/dev-python/gst-python/gst-python-1.22.11.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://gstreamer.freedesktop.org/src/${PN}/${P}.tar.xz"
 
 LICENSE="LGPL-2+"
 SLOT="1.0"
-KEYWORDS="~alpha ~amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
 RDEPEND="${PYTHON_DEPS}
diff --git a/dev-python/imageio/Manifest b/dev-python/imageio/Manifest
index 2412a00ebe94..e7244638142e 100644
--- a/dev-python/imageio/Manifest
+++ b/dev-python/imageio/Manifest
@@ -1,3 +1,4 @@
 DIST imageio-2.34.0.gh.tar.gz 413125 BLAKE2B c6f9650265924f370634f5ab87bed94bdb501d078a154b93400d8c89847da3fef7196f18db0682bbfc99ac5c9f4156a113bb2d74f572c010842b9b9593d7c13e SHA512 d28b5b849a8d7fc90c4c4a82b2056431e5351ecce709cd48ccb9aaf58a50964a1b77faf4663d3fdeb4757951fb8a03b5bf632e57f78ddd59d5a9acdb62b78f48
+DIST imageio-2.34.1.gh.tar.gz 413414 BLAKE2B 59371d0aeace317b9006a0b3b182b97259a53ca0d2288d8ee497234e4f2e7e253c1c27b40b2c5c1f531555a71c7f426ae6d4555043525aa88ca2818d26adfd7d SHA512 d7d1f99f735447e559c0b1fdc2dbe19f2991fb3c640cb9f1396d149c3c44f05e1c357ca8753fff8130625f8fb40a72f277ef09e7cec2b060d1a4f3a675e086a0
 DIST imageio-chelsea.png 221294 BLAKE2B 58537d7a1678fa5be4cc899e5bacd925bfc180eb4ae691330a53749a49ff544e979609b529ed27e5c1fc9efe4bc050ca1ce49b777f4016fb1d66affd926ef9d3 SHA512 48470cdb843eed4dfa6673811c09c5aac9869ee23dd36be0c6b653d9f108d61d21b148c2a4435aaa6604887ba030e5bbc5e35d378da876366445dfc2d0ba4e27
 DIST imageio-cockatoo.mp4 728751 BLAKE2B 45b22cd517c1cb7c0cd12f8865facaca6a847047aea716e49633cf2b1dc13826f94787c8a8f9dd5f48c6a896f5d37794c0058da1bde9e1469f196916476dbfa2 SHA512 e9cb7c25de8019c59ba4090cf10ab29f2b5d62ada37a877081ca07d2ecfe010036222ae843b41bbcc843130d97fa5e14421de252639e9481df1d1c27b19add49
diff --git a/dev-python/imageio/imageio-2.34.1.ebuild b/dev-python/imageio/imageio-2.34.1.ebuild
new file mode 100644
index 000000000000..d04d7e644fa7
--- /dev/null
+++ b/dev-python/imageio/imageio-2.34.1.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+BIN_COMMIT=224074bca448815e421a59266864c23041531a42
+DESCRIPTION="Python library for reading and writing image data"
+HOMEPAGE="
+	https://imageio.readthedocs.io/en/stable/
+	https://github.com/imageio/imageio/
+	https://pypi.org/project/imageio/
+"
+SRC_URI="
+	https://github.com/imageio/imageio/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://github.com/imageio/imageio-binaries/raw/${BIN_COMMIT}/images/chelsea.png
+			-> ${PN}-chelsea.png
+		https://github.com/imageio/imageio-binaries/raw/${BIN_COMMIT}/images/cockatoo.mp4
+			-> ${PN}-cockatoo.mp4
+	)
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+# over 50% of tests rely on Internet
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	<dev-python/numpy-2[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.20.0[${PYTHON_USEDEP}]
+	>=dev-python/pillow-8.3.2[${PYTHON_USEDEP}]
+	media-libs/freeimage
+"
+# requests for fsspec[github]
+BDEPEND="
+	test? (
+		dev-python/fsspec[${PYTHON_USEDEP}]
+		>=dev-python/imageio-ffmpeg-0.4.9-r1[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/tifffile[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	local PATCHES=(
+		# block silently downloading vulnerable libraries from the Internet
+		"${FILESDIR}"/imageio-2.22.0-block-download.patch
+	)
+
+	if use test; then
+		mkdir -p "${HOME}"/.imageio/images || die
+		local i
+		for i in chelsea.png cockatoo.mp4; do
+			cp "${DISTDIR}/${PN}-${i}" "${HOME}/.imageio/images/${i}" || die
+		done
+	fi
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails because of system installed freeimage
+		tests/test_core.py::test_findlib2
+		# Tries to download ffmpeg binary ?!
+		tests/test_ffmpeg.py::test_get_exe_installed
+		# blocked by our patch
+		tests/test_core.py::test_fetching
+		tests/test_core.py::test_request
+		# known broken
+		# https://github.com/imageio/imageio/issues/890
+		tests/test_freeimage.py::test_exr_write
+		# requires pillow-heif, also possibly Internet
+		tests/test_pillow.py::test_avif_remote
+		tests/test_pillow.py::test_heif_remote
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/jupyterlab-server/Manifest b/dev-python/jupyterlab-server/Manifest
index 3865e8c202e7..d236d641b392 100644
--- a/dev-python/jupyterlab-server/Manifest
+++ b/dev-python/jupyterlab-server/Manifest
@@ -1,2 +1,3 @@
 DIST jupyterlab_server-2.25.4.tar.gz 74772 BLAKE2B 8647840e2bb93244360db07524374f30e6831fddf6c2b89101b2a01f505470649fcc6aa31b40dc18a480628eeb791b4f7488cd91bb921796c3daad36102e535b SHA512 de04d1c5de3507a2465c316686be10ff6398be2f05d9d84ff6e79c376978503bc6ff836bfca67735d85f8ef23a15d6f30ad69268a25855dc4ebc1bd5f7c2fdaf
 DIST jupyterlab_server-2.26.0.tar.gz 75100 BLAKE2B 10f507cf8b6640ee4178d2850561a5d186f9b9004b2d74de7382b4c9a03494d3553e7a2397cafb45b3be60062baf0d3df3026b1f8613e5dd2a597faad0cfc9d5 SHA512 cb9c78ae8afed53637b441767c630666d391a7ce6a19cc5cf8bcc9c3149ef570c5aeaba204878bd4d52806a6e2b9e25f9724536f1addf084bfb15855f7700125
+DIST jupyterlab_server-2.27.0.tar.gz 75375 BLAKE2B c4b8c26d93a2af79ab4d82492172a8cdfb2049d7885c6cefda96f472d9edafc749c8d06ae194b5e4b66052a8514d0cbdbba1bcbc4b03fdf9e4cec65ab27cca8e SHA512 7336434b3b9378d345f7d657f8f21c3217d4605fae93a74382bb4a71135fabb3dfc7229e388737297568f13281ba9e8f710b010a6fa9b6bc0bbc5db2dd3f3293
diff --git a/dev-python/jupyterlab-server/jupyterlab-server-2.27.0.ebuild b/dev-python/jupyterlab-server/jupyterlab-server-2.27.0.ebuild
new file mode 100644
index 000000000000..579c6102b263
--- /dev/null
+++ b/dev-python/jupyterlab-server/jupyterlab-server-2.27.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Server components for JupyterLab and JupyterLab like applications"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyterlab/jupyterlab_server/
+	https://pypi.org/project/jupyterlab-server/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/Babel-2.10[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.3[${PYTHON_USEDEP}]
+	>=dev-python/json5-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.18.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.31[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-server-1.21[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/jupyter-server[${PYTHON_USEDEP}]
+		<dev-python/openapi-core-0.19[${PYTHON_USEDEP}]
+		>=dev-python/openapi-core-0.18[${PYTHON_USEDEP}]
+		<dev-python/openapi-spec-validator-0.8[${PYTHON_USEDEP}]
+		>=dev-python/openapi-spec-validator-0.6[${PYTHON_USEDEP}]
+		dev-python/pytest-jupyter[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+		dev-python/strict-rfc3339[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+# TODO: package autodoc_traits
+#distutils_enable_sphinx docs/source dev-python/pydata-sphinx-theme dev-python/myst-parser
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		tests/test_translation_api.py
+	)
+
+	EPYTEST_DESELECT=(
+		# Fails if terminal not available
+		tests/test_labapp.py::test_page_config
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_tornasync.plugin -p timeout
+}
diff --git a/dev-python/libcst/libcst-0.4.3_p20220607.ebuild b/dev-python/libcst/libcst-0.4.3_p20220607.ebuild
index 4e1b183b5d9a..7e69a7c7a1c9 100644
--- a/dev-python/libcst/libcst-0.4.3_p20220607.ebuild
+++ b/dev-python/libcst/libcst-0.4.3_p20220607.ebuild
@@ -132,7 +132,7 @@ RDEPEND="
 	>=dev-python/pyyaml-5.2[${PYTHON_USEDEP}]
 	>=dev-python/setuptools-rust-0.12.1[${PYTHON_USEDEP}]
 	>=dev-python/typing-extensions-3.7.4.2[${PYTHON_USEDEP}]
-	>=dev-python/typing_inspect-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-inspect-0.4.0[${PYTHON_USEDEP}]
 "
 DEPEND="${RDEPEND}"
 # 	test? (
diff --git a/dev-python/mkdocs-get-deps/Manifest b/dev-python/mkdocs-get-deps/Manifest
new file mode 100644
index 000000000000..8c70f83de18a
--- /dev/null
+++ b/dev-python/mkdocs-get-deps/Manifest
@@ -0,0 +1 @@
+DIST mkdocs_get_deps-0.2.0.tar.gz 10239 BLAKE2B 2fceb113b499f5c7433ef5ffbde60c8c1f2ae0817285ee41d4889c01283783959673609721766e70dc5888285d497e2b94c5462140d3119922b16c0071b13624 SHA512 3fdf445923b82544fc9feaddd6a99638901f9c88a34f404c38ce510934245bd836d1491a9c5561f7b49ae0aa006c58a83ac946449713b0504c0da788d8233d5e
diff --git a/dev-python/mkdocs-get-deps/metadata.xml b/dev-python/mkdocs-get-deps/metadata.xml
new file mode 100644
index 000000000000..f4c4fc90a218
--- /dev/null
+++ b/dev-python/mkdocs-get-deps/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>andrewammerlaan@gentoo.org</email>
+  <name>Andrew Ammerlaan</name>
+ </maintainer>
+ 
+ <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/mkdocs-get-deps/mkdocs-get-deps-0.2.0.ebuild b/dev-python/mkdocs-get-deps/mkdocs-get-deps-0.2.0.ebuild
new file mode 100644
index 000000000000..aa4b7ed4a603
--- /dev/null
+++ b/dev-python/mkdocs-get-deps/mkdocs-get-deps-0.2.0.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="extension that lists all dependencies according to a mkdocs.yml file"
+HOMEPAGE="
+	https://github.com/mkdocs/get-deps/
+	https://pypi.org/project/mkdocs-get-deps/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+
+RDEPEND="
+	>=dev-python/mergedeep-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/mkdocs/Manifest b/dev-python/mkdocs/Manifest
index 8b6da2ece664..8e5fd03923d0 100644
--- a/dev-python/mkdocs/Manifest
+++ b/dev-python/mkdocs/Manifest
@@ -1 +1,2 @@
 DIST mkdocs-1.5.3.gh.tar.gz 4057780 BLAKE2B d1e7ac739ea3a78f2a2d294a28c721f95cb8be6c114a5131893e346254ed1937218cc0d247e75092876d7f42dc04c8060fdc8d7535326f26a8f68ec11bc7045b SHA512 3f7d0af4b071ac6998e82cefb18df27f1cc98d91c7902d2943acdaa08c56f90e36c1c5d1df1c1f61a1c50d8fecc2fb0014497f2436be89d52b17959808c31abc
+DIST mkdocs-1.6.0.gh.tar.gz 4494411 BLAKE2B 2a0d55c54509827fcff39c04812be6cff6b1ccbf823cc05a48fa154745a49aed08d811147fc5f64db138ede952dc89241b156f8e0e01e42a468f73309eece0fb SHA512 330dfb7cd390b320ca9c2bfd2dc248d877b95713ec3c1d2c9d5b28be52a42276c58412bc77527a492e4b1b31608e3093dbad2a983bfe6396577ec7464e274609
diff --git a/dev-python/mkdocs/mkdocs-1.6.0.ebuild b/dev-python/mkdocs/mkdocs-1.6.0.ebuild
new file mode 100644
index 000000000000..cb899f5b7ba6
--- /dev/null
+++ b/dev-python/mkdocs/mkdocs-1.6.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Project documentation with Markdown"
+HOMEPAGE="
+	https://www.mkdocs.org/
+	https://github.com/mkdocs/mkdocs/
+	https://pypi.org/project/mkdocs/
+"
+SRC_URI="
+	https://github.com/mkdocs/mkdocs/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+
+# https://bugs.gentoo.org/873349
+# Building documentation requires packaging: callouts and mkdocs-autorefs
+#
+# IUSE="doc"
+#
+# BDEPEND="
+# 	doc? (
+# 		$(python_gen_any_dep '
+# 			dev-python/mdx-gh-links[${PYTHON_USEDEP}]
+# 			dev-python/mkdocs-redirects[${PYTHON_USEDEP}]
+# 		')
+# 	)
+# "
+RDEPEND="
+	>=dev-python/Babel-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.11.1[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.3.6[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-2.0[${PYTHON_USEDEP}]
+	>=dev-python/ghp-import-1.0[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.11.1[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml_env_tag-0.1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.5[${PYTHON_USEDEP}]
+	>=dev-python/mergedeep-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-get-deps-0.2.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Tests fails if additional themes are installed
+	mkdocs/tests/utils/utils_tests.py::UtilsTests::test_get_themes
+	mkdocs/tests/utils/utils_tests.py::UtilsTests::test_get_themes_error
+	mkdocs/tests/utils/utils_tests.py::UtilsTests::test_get_themes_warning
+
+	# Does not work in emerge env
+	mkdocs/tests/config/config_options_tests.py::ListOfPathsTest::test_paths_localized_to_config
+
+	# TODO
+	mkdocs/tests/build_tests.py::testing_server
+	mkdocs/tests/livereload_tests.py::testing_server
+)
+
+python_compile_all() {
+	default
+# 	if use doc; then
+# 		# cannot just do mkdocs build, because that fails if
+# 		# the package isn't already installed
+# 		python -m mkdocs build || die "Failed to make docs"
+# 		# Colliding files found by ecompress:
+# 		rm site/sitemap.xml.gz || die
+# 		HTML_DOCS=( "site/." )
+# 	fi
+}
+
+python_test() {
+	epytest '-opython_files=*tests.py' mkdocs/tests
+}
diff --git a/dev-python/ml-dtypes/Manifest b/dev-python/ml-dtypes/Manifest
index b9f867304fa1..2d151239c361 100644
--- a/dev-python/ml-dtypes/Manifest
+++ b/dev-python/ml-dtypes/Manifest
@@ -1,2 +1,3 @@
 DIST eigen-7bf2968fed5f246c0589e1111004cb420fcd7c71.tar.bz2 2239233 BLAKE2B 3a7e81c302cb11ae1d6ef9433a9ec41506c1f37d04cfb8744ac3fcf7dbe9430c1b48d7197ca3b8e1f9354398bac3d0dbc3e0599c0b649acd6175e906befe2973 SHA512 29ee89770726e6e0f5135b7fab24649f3e69223caed90d2daa6f0014783e69fe98f0551de49bd4e393d7b7938f2943caf1ed00f3933fa771ac14fae3c63fd5dd
 DIST ml_dtypes-0.3.2.gh.tar.gz 71606 BLAKE2B cbf5414d09160a2e4e878261c5842efd664a424064aae727d9d1188304a5e888ca955b3bf199956c2beed53c78c0f8afeb8860245d57553b10ca7262ba1e8bce SHA512 d42f6734edc5c159f15b9c020deb2595f32bbcdf53ecfaea840afb38314a855d09315693129393f755fdc3295b5965073b404822aacf1a149c7f9bab89c48fd5
+DIST ml_dtypes-0.4.0.gh.tar.gz 72894 BLAKE2B a2d70369f8fc72b8234d198ee4517dd3666b6e5a82ea8bca28973966e141426ef5517d441cfdd4cc00146d534194378c191b29f695f1d8c6b9d2785c84d2548c SHA512 a4674c352a641ceab212ff1da25168823d43016dbe00ae06885ef787f1bc0814ae61e595d5f9d43710da29c12e70e3c616e1c634560b911bdb25f4c40b6ba324
diff --git a/dev-python/ml-dtypes/metadata.xml b/dev-python/ml-dtypes/metadata.xml
index 72e10dd03722..e5e20236c85e 100644
--- a/dev-python/ml-dtypes/metadata.xml
+++ b/dev-python/ml-dtypes/metadata.xml
@@ -5,6 +5,10 @@
   <email>perfinion@gentoo.org</email>
   <name>Jason Zaman</name>
  </maintainer>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
  
  <origin>gentoo-staging</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/ml-dtypes/ml-dtypes-0.3.2.ebuild b/dev-python/ml-dtypes/ml-dtypes-0.3.2-r1.ebuild
index 6e67491f497d..95bbda75925b 100644
--- a/dev-python/ml-dtypes/ml-dtypes-0.3.2.ebuild
+++ b/dev-python/ml-dtypes/ml-dtypes-0.3.2-r1.ebuild
@@ -24,7 +24,7 @@ KEYWORDS="~amd64"
 S="${WORKDIR}/${PNGH}-${PV}"
 
 DEPEND="
-	dev-python/numpy[${PYTHON_USEDEP}]
+	<dev-python/numpy-2:=[${PYTHON_USEDEP}]
 "
 BDEPEND="
 	dev-python/pybind11[${PYTHON_USEDEP}]
diff --git a/dev-python/ml-dtypes/ml-dtypes-0.4.0.ebuild b/dev-python/ml-dtypes/ml-dtypes-0.4.0.ebuild
new file mode 100644
index 000000000000..13d3aebc57f9
--- /dev/null
+++ b/dev-python/ml-dtypes/ml-dtypes-0.4.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P=${PN/-/_}-${PV}
+EIGEN_CommitId="7bf2968fed5f246c0589e1111004cb420fcd7c71"
+
+DESCRIPTION="A stand-alone implementation of several NumPy dtype extensions"
+HOMEPAGE="
+	https://github.com/jax-ml/ml_dtypes/
+	https://pypi.org/project/ml-dtypes/
+"
+SRC_URI="
+	https://github.com/jax-ml/ml_dtypes/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	https://gitlab.com/libeigen/eigen/-/archive/${EIGEN_CommitId}/eigen-${EIGEN_CommitId}.tar.bz2
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-python/numpy:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/pybind11[${PYTHON_USEDEP}]
+	test? (
+		dev-python/absl-py[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	rmdir third_party/eigen || die
+	mv "${WORKDIR}/eigen-${EIGEN_CommitId}" third_party/eigen || die
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	mv ml_dtypes/tests . || die
+	rm -r ml_dtypes || die
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	epytest
+}
diff --git a/dev-python/pipenv/pipenv-2023.12.1.ebuild b/dev-python/pipenv/pipenv-2023.12.1-r1.ebuild
index 10380d8aef72..0384a566a12b 100644
--- a/dev-python/pipenv/pipenv-2023.12.1.ebuild
+++ b/dev-python/pipenv/pipenv-2023.12.1-r1.ebuild
@@ -30,7 +30,7 @@ RDEPEND="
 	dev-python/dparse[${PYTHON_USEDEP}]
 	>=dev-python/markupsafe-2.0.1[${PYTHON_USEDEP}]
 	>=dev-python/pexpect-4.8.0[${PYTHON_USEDEP}]
-	dev-python/pipdeptree[${PYTHON_USEDEP}]
+	~dev-python/pipdeptree-2.16.2[${PYTHON_USEDEP}]
 	~dev-python/plette-0.4.4[${PYTHON_USEDEP}]
 	>=dev-python/ptyprocess-0.7.0[${PYTHON_USEDEP}]
 	dev-python/pyparsing[${PYTHON_USEDEP}]
diff --git a/dev-python/prov/Manifest b/dev-python/prov/Manifest
deleted file mode 100644
index afbcb160818c..000000000000
--- a/dev-python/prov/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST prov-2.0.0.tar.gz 131878 BLAKE2B 65f14ad3a7dc6e10d03b0d778be02d3a3a7e4cae7b8aedf54117446eefe51546fb30e9ca602b2d5780fab8abde4ed1d56ed7385815db64a7879623a481b050be SHA512 6d05c88855f23d5dc22b0eccce0af935c0ad3d227b7a257ff205ad8566ed9607f614c13427ac8dd922e79bd477ca125b9d3f9492f5f65ae55ab8e8f3b9b97307
diff --git a/dev-python/prov/metadata.xml b/dev-python/prov/metadata.xml
deleted file mode 100644
index 4aa7a12c2c3e..000000000000
--- a/dev-python/prov/metadata.xml
+++ /dev/null
@@ -1,11 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
-<pkgmetadata>
- <longdescription lang="en">
-		A library for W3C Provenance Data Model supporting PROV-O
-		(RDF), PROV-XML, PROV-JSON import/export Interface to
-		Graphviz’s Dot language.
-	</longdescription>
- 
- <origin>gentoo-staging</origin>
-</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/prov/prov-2.0.0.ebuild b/dev-python/prov/prov-2.0.0.ebuild
deleted file mode 100644
index 241ad2263804..000000000000
--- a/dev-python/prov/prov-2.0.0.ebuild
+++ /dev/null
@@ -1,29 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
-inherit distutils-r1 pypi
-
-DESCRIPTION="W3C provenance data dodel library"
-HOMEPAGE="https://pypi.org/project/prov/"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/pydot[${PYTHON_USEDEP}]
-	dev-python/python-dateutil[${PYTHON_USEDEP}]
-	dev-python/lxml[${PYTHON_USEDEP}]
-	>=dev-python/networkx-1.10[${PYTHON_USEDEP}]
-	dev-python/rdflib[${PYTHON_USEDEP}]
-"
-
-distutils_enable_tests setup.py
-
-src_prepare() {
-	sed -e 's/test_json_to_ttl_match/_&/' -i src/prov/tests/test_rdf.py || die
-	distutils-r1_src_prepare
-}
diff --git a/dev-python/pyarrow/pyarrow-16.0.0.ebuild b/dev-python/pyarrow/pyarrow-16.0.0.ebuild
index a980e74a3f09..ac8ab31469f9 100644
--- a/dev-python/pyarrow/pyarrow-16.0.0.ebuild
+++ b/dev-python/pyarrow/pyarrow-16.0.0.ebuild
@@ -80,6 +80,7 @@ python_test() {
 		tests/interchange/test_interchange_spec.py::test_dtypes
 		tests/test_convert_builtin.py::test_array_to_pylist_roundtrip
 		tests/test_feather.py::test_roundtrip
+		tests/test_pandas.py::test_array_to_pandas_roundtrip
 	)
 
 	if has_version ">=dev-python/numpy-2"; then
diff --git a/dev-python/python-skywater-pdk/python-skywater-pdk-0.0.0_p20220424.ebuild b/dev-python/python-skywater-pdk/python-skywater-pdk-0.0.0_p20220424.ebuild
index eb6a28687fca..3434a54c3a63 100644
--- a/dev-python/python-skywater-pdk/python-skywater-pdk-0.0.0_p20220424.ebuild
+++ b/dev-python/python-skywater-pdk/python-skywater-pdk-0.0.0_p20220424.ebuild
@@ -4,7 +4,7 @@
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_COMPAT=( python3_{8,9,10,11,12} ) # python3_11 depends on dev-python/dataclasses_json
 
 MY_PN="skywater-pdk"
 MY_REV=5a57f505cd4cd65d10e9f37dd2d259a526bc9bf7
diff --git a/dev-python/rst-linker/Manifest b/dev-python/rst-linker/Manifest
index 0aec84dfc54e..3dbe53e3f09f 100644
--- a/dev-python/rst-linker/Manifest
+++ b/dev-python/rst-linker/Manifest
@@ -1 +1,2 @@
 DIST rst.linker-2.4.0.tar.gz 11340 BLAKE2B a1ae9c811b7d6fa2821bfbf5787dce75fd3d7e5d933ec15fbac9cd3bde08cfad59fdc81b3b58dc39d1209a27ca9dd8d2ecd68034b434b3f6d15469bfb98efa3d SHA512 31e3427ecf35b433cc9650138ee36090e99003b72c69b60b530835eb624d7eb13aae4cf81cc0044b36750798a4b8aa676e53e3b9eb335430076593640a243940
+DIST rst_linker-2.5.0.tar.gz 11548 BLAKE2B eafa6a0076dd51d05779710cb3b41f4b6e5109b25ea71537bc4f4e75d8c0fe4c9329321833e5a9253bb4a51fab706488a78ece4679a4c52cd7fc0295cc29e76f SHA512 7aaa55ccbe34767f8c0e085703872f4112c5db142e81f7024fd0653fa74fcf0b9d15fec06998268e8161dc70dac6935ba7b380992a132ecaa2548ed0db3b5a13
diff --git a/dev-python/rst-linker/rst-linker-2.5.0.ebuild b/dev-python/rst-linker/rst-linker-2.5.0.ebuild
new file mode 100644
index 000000000000..d4776acaee6a
--- /dev/null
+++ b/dev-python/rst-linker/rst-linker-2.5.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Sphinx plugin to add links and timestamps to the changelog"
+HOMEPAGE="
+	https://github.com/jaraco/rst.linker/
+	https://pypi.org/project/rst.linker/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-3.4.1[${PYTHON_USEDEP}]
+	test? (
+		dev-python/path[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/scikit-build-core/Manifest b/dev-python/scikit-build-core/Manifest
index 3ab5faa12cf4..e21f78d1c36a 100644
--- a/dev-python/scikit-build-core/Manifest
+++ b/dev-python/scikit-build-core/Manifest
@@ -1,4 +1 @@
-DIST scikit_build_core-0.8.2.tar.gz 203630 BLAKE2B 7093fd02891fe225ffee1b6da7800e49eb71c6468947fff1a80015eda8c9940f117196dfd067d0ea274d9958f8f13681ccd859f95ce9bf6a7d72eedc367489f3 SHA512 4b33936912806b5f607492d253d5cc6b2523d4892043caad82fed76140e53a0e9dec8178811a618cdc9b64f247e37145d474eb1979d181dd595b4905def1da8f
-DIST scikit_build_core-0.9.0.tar.gz 224820 BLAKE2B 1221745656016ac90f1ac8bf9fb0d43c9f6f2dbd366b70522e2c8bcc15da87d64fc0ae84a583b811faa4cae638b9ab9d3987b21bccb29698fffb3d83cb26d881 SHA512 6d8dbb902a37c7d75f4e0c6d237f0aff6e6bcf08d0757bcef5d854b62b1ba3c562065aff7e87f0860803d4e768d0f6b2c4e866ae992b4fa510f0bee8d516431e
-DIST scikit_build_core-0.9.1.tar.gz 224992 BLAKE2B aaa02572c278138ba2463e42e4514647f9617cb257cdcb6f86a9a97e332967a867a2da97c2407388eae566a998496f6e712781d6e8af960a9fde4e8771baf41f SHA512 8e4632694f862db1fcc05d3c5844fee601ea975f2f3fd548d214d12bfb19e8f200aed199ed04142c37b3454e0ba077e658d85d976ceba875f2642f2d13a3f8c2
 DIST scikit_build_core-0.9.2.tar.gz 225078 BLAKE2B 8d50e82754013f23a2216d269757fce5b56c5fa99e2f3b93e3bb65e50730799f2874d0eaa71681e248eeb30c443cde03a5bd447732b764852f2069ed18ea98d3 SHA512 c94cb9b109c994bedaba0e82de15caaf4fc4ae5c08375324aeb60f8d05911cc958a70c0430d35b23ad9792d39ab0312ff607b0587cd55eb4fe68ae4f28eed1d9
diff --git a/dev-python/scikit-build-core/scikit-build-core-0.8.2.ebuild b/dev-python/scikit-build-core/scikit-build-core-0.8.2.ebuild
deleted file mode 100644
index 1ad34e4cca6c..000000000000
--- a/dev-python/scikit-build-core/scikit-build-core-0.8.2.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Build backend for CMake based projects"
-HOMEPAGE="
-	https://github.com/scikit-build/scikit-build-core/
-	https://pypi.org/project/scikit-build-core/
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-
-# we always want [pyproject] extra
-RDEPEND="
-	>=dev-python/packaging-20.9[${PYTHON_USEDEP}]
-	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
-	>=dev-python/pyproject-metadata-0.5[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/exceptiongroup[${PYTHON_USEDEP}]
-		>=dev-python/tomli-1.1[${PYTHON_USEDEP}]
-	' 3.9 3.10)
-"
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/build[${PYTHON_USEDEP}]
-		>=dev-python/cattrs-22.2.0[${PYTHON_USEDEP}]
-		dev-python/pybind11[${PYTHON_USEDEP}]
-		>=dev-python/pytest-subprocess-1.5[${PYTHON_USEDEP}]
-		dev-python/setuptools[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-		dev-python/wheel[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# TODO / we don't package validate_pyproject anyway
-		tests/test_schema.py::test_compare_schemas
-		# setuptools now respects PEP 625
-		tests/test_setuptools_pep517.py::test_pep517_sdist
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p subprocess -m "not isolated and not network"
-}
diff --git a/dev-python/scikit-build-core/scikit-build-core-0.9.0.ebuild b/dev-python/scikit-build-core/scikit-build-core-0.9.0.ebuild
deleted file mode 100644
index d28037667b7b..000000000000
--- a/dev-python/scikit-build-core/scikit-build-core-0.9.0.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Build backend for CMake based projects"
-HOMEPAGE="
-	https://github.com/scikit-build/scikit-build-core/
-	https://pypi.org/project/scikit-build-core/
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-
-# we always want [pyproject] extra
-RDEPEND="
-	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
-	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
-	>=dev-python/pyproject-metadata-0.5[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/exceptiongroup[${PYTHON_USEDEP}]
-		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
-	' 3.10)
-"
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/build[${PYTHON_USEDEP}]
-		>=dev-python/cattrs-22.2.0[${PYTHON_USEDEP}]
-		dev-python/fastjsonschema[${PYTHON_USEDEP}]
-		dev-python/pybind11[${PYTHON_USEDEP}]
-		>=dev-python/pytest-subprocess-1.5[${PYTHON_USEDEP}]
-		dev-python/setuptools[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-		dev-python/wheel[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local _EPYTEST_DESELECT=(
-		# TODO / we don't package validate_pyproject anyway
-		tests/test_schema.py::test_compare_schemas
-		# setuptools now respects PEP 625
-		tests/test_setuptools_pep517.py::test_pep517_sdist
-	)
-	local EPYTEST_IGNORE=(
-		# needs unpackaged validate_pyproject
-		tests/test_schema.py
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p subprocess -m "not isolated and not network"
-}
diff --git a/dev-python/scikit-build-core/scikit-build-core-0.9.1.ebuild b/dev-python/scikit-build-core/scikit-build-core-0.9.1.ebuild
deleted file mode 100644
index d28037667b7b..000000000000
--- a/dev-python/scikit-build-core/scikit-build-core-0.9.1.ebuild
+++ /dev/null
@@ -1,61 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Build backend for CMake based projects"
-HOMEPAGE="
-	https://github.com/scikit-build/scikit-build-core/
-	https://pypi.org/project/scikit-build-core/
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-
-# we always want [pyproject] extra
-RDEPEND="
-	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
-	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
-	>=dev-python/pyproject-metadata-0.5[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		dev-python/exceptiongroup[${PYTHON_USEDEP}]
-		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
-	' 3.10)
-"
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/build[${PYTHON_USEDEP}]
-		>=dev-python/cattrs-22.2.0[${PYTHON_USEDEP}]
-		dev-python/fastjsonschema[${PYTHON_USEDEP}]
-		dev-python/pybind11[${PYTHON_USEDEP}]
-		>=dev-python/pytest-subprocess-1.5[${PYTHON_USEDEP}]
-		dev-python/setuptools[${PYTHON_USEDEP}]
-		dev-python/virtualenv[${PYTHON_USEDEP}]
-		dev-python/wheel[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-python_test() {
-	local _EPYTEST_DESELECT=(
-		# TODO / we don't package validate_pyproject anyway
-		tests/test_schema.py::test_compare_schemas
-		# setuptools now respects PEP 625
-		tests/test_setuptools_pep517.py::test_pep517_sdist
-	)
-	local EPYTEST_IGNORE=(
-		# needs unpackaged validate_pyproject
-		tests/test_schema.py
-	)
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest -p subprocess -m "not isolated and not network"
-}
diff --git a/dev-python/scikit-build-core/scikit-build-core-0.9.2.ebuild b/dev-python/scikit-build-core/scikit-build-core-0.9.2-r1.ebuild
index d28037667b7b..bc7ccf1f1709 100644
--- a/dev-python/scikit-build-core/scikit-build-core-0.9.2.ebuild
+++ b/dev-python/scikit-build-core/scikit-build-core-0.9.2-r1.ebuild
@@ -20,6 +20,8 @@ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc
 
 # we always want [pyproject] extra
 RDEPEND="
+	app-alternatives/ninja
+	dev-build/cmake
 	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
 	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
 	>=dev-python/pyproject-metadata-0.5[${PYTHON_USEDEP}]
diff --git a/dev-python/sphinxcontrib-asyncio/Manifest b/dev-python/sphinxcontrib-asyncio/Manifest
deleted file mode 100644
index 57f179b3d9ef..000000000000
--- a/dev-python/sphinxcontrib-asyncio/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST sphinxcontrib-asyncio-0.3.0.tar.gz 11622 BLAKE2B 8c3358ad191e12e79767be6e6f3800e5de423d9a5ad005bdb416aa7a601cddc5f115db3e9b27213c06dbc341b671cbacd00217b65496baada40bfe257069abfa SHA512 fa66a2a9b5f89327686481f46d8e5be0b674f6355c8c0eeb862bf0ca0b5bb848121c5ed153780f653242faf1b82debc6917c3f6046244cce0f1423303a324f29
diff --git a/dev-python/sphinxcontrib-asyncio/sphinxcontrib-asyncio-0.3.0-r1.ebuild b/dev-python/sphinxcontrib-asyncio/sphinxcontrib-asyncio-0.3.0-r1.ebuild
deleted file mode 100644
index 2e57b2249961..000000000000
--- a/dev-python/sphinxcontrib-asyncio/sphinxcontrib-asyncio-0.3.0-r1.ebuild
+++ /dev/null
@@ -1,31 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYPI_NO_NORMALIZE=1
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="sphinx extension to support coroutines in markup"
-HOMEPAGE="
-	https://github.com/aio-libs/sphinxcontrib-asyncio/
-	https://pypi.org/project/sphinxcontrib-asyncio/
-"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
-
-RDEPEND="
-	dev-python/sphinx[${PYTHON_USEDEP}]
-"
-
-distutils_enable_sphinx docs
-
-src_prepare() {
-	rm sphinxcontrib/__init__.py || die
-	distutils-r1_src_prepare
-}
diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index d3ddeb988efd..aec6cb2e5c6e 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1 +1,2 @@
 DIST translate-3.12.2.gh.tar.gz 1202828 BLAKE2B fdfc6ea91d0e0fe9f36e1352247463fe04ff3f4cdd13dd969077ccf0dde984250303872f6bb605dcd1628a1089d81dd98b36dfd68e92c3030c740d65899a70ba SHA512 7488f45521f1744d8d457ce5f74a4955a0e4468af8b3f5be06410667f2c1e52a3dacd3b959330e6c2eb5b3a443c1e2c761538896352576f5090ce27dbfc8edab
+DIST translate-3.13.0.gh.tar.gz 1171837 BLAKE2B 9c6212d26749eac652369e94d2b653f67b364afc9f9125c5125d19e3cabc1bb36bd27bc172ad93d28cb6cdf57ed2b245336664b6b4954db9bbbfb4a8ad92b3f9 SHA512 7c6f87ec32c81a14d1775dc24d43e49b79fdf8473a4380c93a2af1532bed32a9733ee755641ce26852b1bd63acffa2110598c5fc3010bbf9de40e8a0f32af308
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.13.0.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.13.0.ebuild
new file mode 100644
index 000000000000..ece6e611bccc
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-3.13.0.ebuild
@@ -0,0 +1,118 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/Levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+# Technically, the test suite also has undeclared dependency
+# on dev-python/snapshottest but all the tests using it are broken
+# anyway, so we skip them.
+BDEPEND="
+	test? (
+		dev-python/phply[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
+	# correctly, so we need to reassemble all data files in a single directory
+	local -x XDG_DATA_HOME=${T}/share
+	cp -r translate/share "${T}/" || die
+	cp -r "${ESYSROOT}/usr/share"/gaupol "${XDG_DATA_HOME}"/ || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+		# all tests based on snapshottest are broken and I'm too tired
+		# to figure this out
+		tests/translate/tools/test_pocount.py::test_{cases,output}
+		tests/translate/tools/test_junitmsgfmt.py::test_output
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		tests/translate/storage/test_fluent.py
+		# changes directory and does not change it back, sigh
+		tests/odf_xliff/test_odf_xliff.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /usr
+	doins -r translate/share
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+}
diff --git a/dev-python/typing-inspect/Manifest b/dev-python/typing-inspect/Manifest
new file mode 100644
index 000000000000..013f920d56be
--- /dev/null
+++ b/dev-python/typing-inspect/Manifest
@@ -0,0 +1 @@
+DIST typing_inspect-0.9.0.tar.gz 13825 BLAKE2B 599ec6a99fd040ac5ee83ef20deee86a8255dd116c8d8defe67d99291088984efc3b639986a9d350b26200028a309cfe6590a3f75dc4b9e0306bdc13bb65641e SHA512 5d46e6632895fa0a59007779f49a5812beff09f59e359a81af93bfee7bb5f4c2025566efbd27422299a614baa4d9c22da2317377090b0ad1cdd89fca73e9ee5a
diff --git a/dev-python/typing-inspect/metadata.xml b/dev-python/typing-inspect/metadata.xml
new file mode 100644
index 000000000000..736a1167c898
--- /dev/null
+++ b/dev-python/typing-inspect/metadata.xml
@@ -0,0 +1,6 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ 
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/typing-inspect/typing-inspect-0.9.0.ebuild b/dev-python/typing-inspect/typing-inspect-0.9.0.ebuild
new file mode 100644
index 000000000000..39d5d46959f3
--- /dev/null
+++ b/dev-python/typing-inspect/typing-inspect-0.9.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Runtime inspection utilities for Python typing module"
+HOMEPAGE="https://github.com/ilevkivskyi/typing_inspect"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/mypy_extensions-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.7.4.2[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# https://github.com/ilevkivskyi/typing_inspect/issues/84
+	local EPYTEST_DESELECT=( 'test_typing_inspect.py::GetUtilityTestCase::test_typed_dict_typing_extension' )
+	epytest
+}
diff --git a/dev-python/urwid/Manifest b/dev-python/urwid/Manifest
index 654ae687c06e..bf129027e33d 100644
--- a/dev-python/urwid/Manifest
+++ b/dev-python/urwid/Manifest
@@ -1,3 +1,4 @@
 DIST urwid-2.6.10.tar.gz 857094 BLAKE2B 7a3a9afb9fc7930ef47dde125e7378448c04ca50ad4eee140b6044f018ce6693972d92f4094d98a5a05223b26772bfcf0aa9de1f4c784396d2e0c235c937cc49 SHA512 1c7cdd6417359b01ced49c42f7f6122e0bec4535211290bf01d59a2d922b29b0674ab3c034e5065d15863e1c089179518b5be91932b4121aca5f0cf78bc7ab54
+DIST urwid-2.6.11.tar.gz 847254 BLAKE2B af0f23f404bc926c378b14a124b5c9504ea282048acd943221ca85f69b86cc8435df7cffc0ed632b3a2067504aca528e560454855acf129518cf69535242a6a6 SHA512 351185673a4ed506a55e2142c0a65150987ac4b6c1176e10c497df6f69c9f4acdabb15ec45564554b9a720387eaa725854fbe4adc4d288ef519b754b17b2fb33
 DIST urwid-2.6.8.tar.gz 854980 BLAKE2B 4168bcd59710ee46e2af408e5e6331585ee2a260ca94990ff947d259d9aad7153750e6c2fc2e227ad00ce42aeeba063b5b11dd89e83f6c30548a6df5ed992e8f SHA512 34617104804f9eb710d5ed51c95c4d2f6354861f07a2d652b99109c59941561985d9717f928ba77990b3e0406723da02b1eb67d9f2236f31888a21b9de109e2e
 DIST urwid-2.6.9.tar.gz 855865 BLAKE2B 468c3188e110fb3e91dc2aa371aef8c1f66c0614ce116a2185050c39404987d354dba3f0d9e230b3308ecee6c6f7c90c12b91007db43c5e7f0cc9dc1d34d5d82 SHA512 23e692b76f4229ecdb51b00c5d88f38bd1de721f7a8815d91f277979935b7f58654422b11421dd93a901add390c65facb513c166b26b00195fc7826492405ed8
diff --git a/dev-python/urwid/urwid-2.6.11.ebuild b/dev-python/urwid/urwid-2.6.11.ebuild
new file mode 100644
index 000000000000..d33150d89fcb
--- /dev/null
+++ b/dev-python/urwid/urwid-2.6.11.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Curses-based user interface library for Python"
+HOMEPAGE="
+	https://urwid.org/
+	https://pypi.org/project/urwid/
+	https://github.com/urwid/urwid/
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	rm -rf urwid || die
+	eunittest
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Trio event loop" "dev-python/trio"
+}
diff --git a/dev-python/urwidtrees/urwidtrees-1.0.3-r1.ebuild b/dev-python/urwidtrees/urwidtrees-1.0.3-r2.ebuild
index 265def4fdfee..1f5a38693184 100644
--- a/dev-python/urwidtrees/urwidtrees-1.0.3-r1.ebuild
+++ b/dev-python/urwidtrees/urwidtrees-1.0.3-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8