Adding metadata

7 files changed, 206 insertions, 1 deletions

diff --git a/dev-python/deprecated/Manifest b/dev-python/deprecated/Manifest
index 48b3bc073c1b..8d507c297d13 100644
--- a/dev-python/deprecated/Manifest
+++ b/dev-python/deprecated/Manifest
@@ -1 +1,2 @@
 DIST deprecated-1.2.18.tar.gz 2928744 BLAKE2B e71acf4851015380abf13865096c2be935e0586c09d88d2ee34b27c98ca462619186a098c4f93cfadd65ff1321e65a76b63b820e642720e646aff10398783bbd SHA512 d19abf2ac19e92666cbcca8a20870ba3e69c6dd724c4e527b9b29cd34c4d91a4f703592f3e3d34dab2ae049d8295ad0cb0b2aa98945b1a81be0d557b4e177639
+DIST deprecated-1.3.1.tar.gz 2932523 BLAKE2B 68fcfd7d22cc5b02624b9ea175c02d7999806f6233e8fdcdfa2b266e396e9654530335636cfcd6eaab00728f1e985aaba5e8a3c5a3d2cd1b3a2f8baef98b0761 SHA512 1218a010ee83ec3ddcec279007af2aa7f5b9ec34a36a6b592cfdf3ef8d621dd6aba0a2e93f8ccacd190b111f1d47699a6484f546ea068a1b40103dcc114a2a36
diff --git a/dev-python/deprecated/deprecated-1.3.1.ebuild b/dev-python/deprecated/deprecated-1.3.1.ebuild
new file mode 100644
index 000000000000..5f417a10622e
--- /dev/null
+++ b/dev-python/deprecated/deprecated-1.3.1.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2019-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python @deprecated decorator to deprecate old API"
+HOMEPAGE="
+	https://github.com/laurent-laporte-pro//deprecated/
+	https://pypi.org/project/Deprecated/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/wrapt[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:< [0-9.]*,::' setup.py || die
+}
diff --git a/dev-python/gherkin-official/gherkin-official-36.0.0.ebuild b/dev-python/gherkin-official/gherkin-official-36.0.0.ebuild
index d9448a86aad4..f9881727bcde 100644
--- a/dev-python/gherkin-official/gherkin-official-36.0.0.ebuild
+++ b/dev-python/gherkin-official/gherkin-official-36.0.0.ebuild
@@ -21,7 +21,7 @@ S=${WORKDIR}/gherkin-${PV}/python
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 arm64"
+KEYWORDS="amd64 arm64"
 
 RDEPEND="
 	dev-python/typing-extensions[${PYTHON_USEDEP}]
diff --git a/dev-python/persist-queue/Manifest b/dev-python/persist-queue/Manifest
index e5a396bf27d3..609126eac195 100644
--- a/dev-python/persist-queue/Manifest
+++ b/dev-python/persist-queue/Manifest
@@ -1,2 +1,3 @@
 DIST persist-queue-0.8.1.tar.gz 29652 BLAKE2B b088a1d1784928e682151d0ccf984439df13b771aea4c5125b213a87fea05fbbc654fd80b787e141083a148b8b4b661b50fbe22f85cc582d0f411297089a88e2 SHA512 a5582deddd06108b4e748ee10fed5f64a328fe361b2db8f74400f7e43fc5800aafee67230e7edf481f926c8e20c73fb5d32109d15504a24caa67da848458ce6c
 DIST persist-queue-1.0.0.tar.gz 30262 BLAKE2B 266b731302ea4a805755df89ef62ad79f60d2b65a3b8f8acdb0daf9816e6a8f8a31f896f5757020f61403382612f00cbfee8d9ceea90782409c08bd8999162d9 SHA512 5fba323ca24dfe79688d2c89ac044729d4ef0b63d195d8fcac6da3ca5e6667d930c348626bce3cb808a560f06d0bfcad041be97b22811e7de0868324b3ef7c1b
+DIST persist_queue-1.1.0.tar.gz 39294 BLAKE2B 61aefe596fd6f1ed358899ba285f57da63f630cdf892ba303e61d4611188817276e97ce209e85066638cd12b4a0265e466d3bcb9837dae2cda0442fe38b7408e SHA512 9dc211d5ef872e3885ee2db0bd2c2d7e538db32b7e0f43aa03be2ef07a6ea9c34c44564229b727142fa07f9a9e45f004ed5c63e1f9e2cb613870298c22bc9d76
diff --git a/dev-python/persist-queue/persist-queue-1.1.0.ebuild b/dev-python/persist-queue/persist-queue-1.1.0.ebuild
new file mode 100644
index 000000000000..f1e2b9abb3e8
--- /dev/null
+++ b/dev-python/persist-queue/persist-queue-1.1.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A thread-safe disk based persistent queue in Python"
+HOMEPAGE="https://github.com/peter-wangxu/persist-queue"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# It tries to connect to a local MySQL server
+RESTRICT="test"
+
+DEPEND="
+	dev-python/dbutils[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/pymysql[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}"
diff --git a/dev-python/wxpython/Manifest b/dev-python/wxpython/Manifest
index bef61471da19..b2d248bc4136 100644
--- a/dev-python/wxpython/Manifest
+++ b/dev-python/wxpython/Manifest
@@ -1 +1,2 @@
 DIST wxPython-4.2.3.tar.gz 58861286 BLAKE2B 2c674227ff109564be1431f2a86a212250ffac809fed4ca8934f7473c93616603e252098511e443ffdf460ab546b5eb17b3f29ab275fb8b5433041a4d47e48cb SHA512 c7b9f0758b9d77dbeab436e8069c024796b6f252af5043615e14083b3f62fb44386c5f325a118f9e2d99c15eeb7687bb1cc1a13a00263114689b32e2126364a7
+DIST wxpython-4.2.4.tar.gz 58583054 BLAKE2B 03b236deb44a345beb989273af605228f5336eaa8b4a3a18b5654536007457b8a31b4a266e31ca8445a7b948c6d6af4040f9b005930ec5c653394e97af539a0f SHA512 4ae124bced8a0d357a34763c981ef370b7c0c978dfba0f941f37e83227816881fee2e65eb7eaa2a114bbaded14afd8e96ad17dba5a9886b38ac35bc75ec82737
diff --git a/dev-python/wxpython/wxpython-4.2.4.ebuild b/dev-python/wxpython/wxpython-4.2.4.ebuild
new file mode 100644
index 000000000000..6606c438c36a
--- /dev/null
+++ b/dev-python/wxpython/wxpython-4.2.4.ebuild
@@ -0,0 +1,142 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+PYPI_NO_NORMALIZE=1
+PYPI_PN="wxPython"
+WX_GTK_VER="3.2-gtk3"
+
+inherit distutils-r1 multilib multiprocessing virtualx wxwidgets pypi
+
+DESCRIPTION="A blending of the wxWindows C++ class library with Python"
+HOMEPAGE="
+	https://www.wxpython.org/
+	https://github.com/wxWidgets/Phoenix/
+	https://pypi.org/project/wxPython/
+"
+# >=4.2.4 has all lowercase sdist
+SRC_URI="$(pypi_sdist_url ${PN} ${PV})"
+
+LICENSE="wxWinLL-3"
+SLOT="4.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="test webkit"
+RESTRICT="!test? ( test )"
+
+# wxPython doesn't seem to be able to optionally disable features. webkit is
+# optionally patched out because it's so huge, but other elements are not,
+# which makes us have to require all features from wxGTK
+DEPEND="
+	>=x11-libs/wxGTK-3.2.7:${WX_GTK_VER}=[gstreamer,libnotify,opengl,sdl,tiff,webkit?,X]
+	media-libs/libpng:=
+	media-libs/tiff:=
+	media-libs/libjpeg-turbo:=
+"
+RDEPEND="
+	${DEPEND}
+"
+# sip-6.11.0-r0 blocked wrt bug #956566, can replace by just >=6.8.5
+# on bump or so as the version was short lived and never stable
+BDEPEND="
+	app-text/doxygen
+	dev-python/cython[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.11.1-r1[${PYTHON_USEDEP}]
+	test? (
+		${VIRTUALX_DEPEND}
+		dev-python/appdirs[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.2.0-flags.patch"
+	"${FILESDIR}/${PN}-4.2.1-x86-time.patch"
+	"${FILESDIR}/${PN}-4.2.2-setuppy.patch"
+)
+
+python_prepare_all() {
+	if ! use webkit; then
+		eapply "${FILESDIR}/${PN}-4.2.0-no-webkit.patch"
+	fi
+
+	local build_options="build_py --use_syswx --no_magic --jobs=$(makeopts_jobs) --verbose --release"
+
+	DISTUTILS_ARGS=(
+		--verbose
+		build
+		--buildpy-options="${build_options}"
+	)
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	setup-wxwidgets
+}
+
+python_compile() {
+	# Patch will fail if copy of refreshed sip file is not restored
+	# if using multiple Python implementations.
+	# TODO: Could we do this in python_compile_all() instead? It would
+	# save a lot of time.
+	DOXYGEN="$(type -P doxygen)" ${PYTHON} build.py dox touch etg sip --nodoc || die
+
+	cp "${S}/sip/cpp/sip_corewxAppTraits.cpp" "${S}" || die
+
+	eapply "${FILESDIR}/${PN}-4.2.2-no-stacktrace.patch"
+
+	distutils-r1_python_compile
+
+	# This package's built system relies on copying extensions back
+	# to source directory for setuptools to pick them up.  This is
+	# hopeless.
+	find -name "*$(get_modname)" -delete || die
+
+	cp "${S}/sip_corewxAppTraits.cpp" "${S}/sip/cpp/" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# virtx probably
+		unittests/test_display.py::display_Tests::test_display
+		unittests/test_frame.py::frame_Tests::test_frameRestore
+		unittests/test_mousemanager.py::mousemanager_Tests::test_mousemanager1
+		unittests/test_uiaction.py::uiaction_KeyboardTests::test_uiactionKeyboardChar
+		unittests/test_uiaction.py::uiaction_KeyboardTests::test_uiactionKeyboardKeyDownUp
+		unittests/test_uiaction.py::uiaction_KeyboardTests::test_uiactionKeyboardText
+		unittests/test_uiaction.py::uiaction_MouseTests
+
+		# assertion (TODO)
+		unittests/test_aboutdlg.py::aboutdlg_Tests::test_aboutdlgGeneric
+		unittests/test_lib_agw_piectrl.py::lib_agw_piectrl_Tests::test_lib_agw_piectrlCtor
+
+		# seems to rely on state from a previous test (sigh)
+		unittests/test_lib_agw_persist_persistencemanager.py::lib_agw_persist_persistencemanager_Tests::test_persistencemanagerRestore
+		unittests/test_lib_agw_persist_persistencemanager.py::lib_agw_persist_persistencemanager_Tests::test_persistencemanagerPersistValue
+
+		# requires Spanish localization
+		unittests/test_intl.py::intl_Tests::test_intlGetString
+
+		# TODO
+		unittests/test_tipwin.py::tipwin_Tests::test_tipwinCtor
+		unittests/test_lib_pubsub_provider.py::lib_pubsub_Except::test1
+		unittests/test_windowid.py::IdManagerTest::test_newIdRef03
+	)
+	local EPYTEST_IGNORE=()
+	if ! use webkit; then
+		EPYTEST_IGNORE+=( unittests/test_webview.py )
+	fi
+
+	rm -rf wx || die
+	# We use pytest-forked as opensuse does to avoid tests corrupting each
+	# other.
+	virtx epytest --forked unittests
+}