Adding metadata

10 files changed, 307 insertions, 4 deletions

diff --git a/dev-python/exceptiongroup/exceptiongroup-1.0.0_rc8.ebuild b/dev-python/exceptiongroup/exceptiongroup-1.0.0_rc8.ebuild
index e7ae40078052..1ba8b0348cdf 100644
--- a/dev-python/exceptiongroup/exceptiongroup-1.0.0_rc8.ebuild
+++ b/dev-python/exceptiongroup/exceptiongroup-1.0.0_rc8.ebuild
@@ -22,7 +22,7 @@ S=${WORKDIR}/${MY_P}
 
 LICENSE="MIT PSF-2.4"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 ~sparc x86"
 
 distutils_enable_tests pytest
 
diff --git a/dev-python/flit_scm/flit_scm-1.6.2.ebuild b/dev-python/flit_scm/flit_scm-1.6.2.ebuild
index f62745f16385..f98afbad001a 100644
--- a/dev-python/flit_scm/flit_scm-1.6.2.ebuild
+++ b/dev-python/flit_scm/flit_scm-1.6.2.ebuild
@@ -19,7 +19,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~m68k ppc ppc64 ~riscv ~s390 ~sparc x86"
 
 RDEPEND="
 	>=dev-python/flit_core-3.5.0[${PYTHON_USEDEP}]
diff --git a/dev-python/hypothesis/hypothesis-6.49.1.ebuild b/dev-python/hypothesis/hypothesis-6.49.1.ebuild
index 5b926953a2fd..ad3ad640e1e5 100644
--- a/dev-python/hypothesis/hypothesis-6.49.1.ebuild
+++ b/dev-python/hypothesis/hypothesis-6.49.1.ebuild
@@ -25,7 +25,7 @@ S="${WORKDIR}/${MY_P}/hypothesis-python"
 
 LICENSE="MPL-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 ~sparc x86"
 IUSE="cli"
 
 RDEPEND="
diff --git a/dev-python/ldap3/ldap3-2.9.1.ebuild b/dev-python/ldap3/ldap3-2.9.1.ebuild
index 631738a46c96..fc7349da58e0 100644
--- a/dev-python/ldap3/ldap3-2.9.1.ebuild
+++ b/dev-python/ldap3/ldap3-2.9.1.ebuild
@@ -15,7 +15,7 @@ SRC_URI="https://github.com/cannatag/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="LGPL-3"
 SLOT="0"
-KEYWORDS="amd64 ~arm64 ~riscv x86"
+KEYWORDS="amd64 ~arm64 ~ppc64 ~riscv x86"
 
 # tests require a ldap server and extra configuration
 RESTRICT="test"
diff --git a/dev-python/mkdocs/Manifest b/dev-python/mkdocs/Manifest
index 63b4b1754e16..51b01bb3aea6 100644
--- a/dev-python/mkdocs/Manifest
+++ b/dev-python/mkdocs/Manifest
@@ -1 +1,2 @@
 DIST mkdocs-1.3.0.tar.gz 4085674 BLAKE2B e34605c2d1122ff86ed5cfb6134cdda67450e8f32d7628626ff4ac8c36c45b127312ad693efe35237b714adb9efd244f12f90cf8ecacf6009b75786db30ebb1b SHA512 d33d728eaff4e39106c1187cf04f579706ce28af364852c67706ab85f6b9ccdcd26ae84cd4d5ea7572e52fde1d1137eb3e424679dd4c8ef043c9637aac062270
+DIST mkdocs-1.3.1.gh.tar.gz 4088396 BLAKE2B b54d0090318fef205d84c4e914f916f91309bdfe6857cd2592fea24e6fb68baaa2eede6dc768681c85ae37adf794546a6ac82dd34d300f421969991f9a796cae SHA512 6eb041f9d0a628eb3a2e6585fde0959f5ef35501edf2c69db640059d98523e2cfa723bc49aedfac1dea4804dcf3c51791e4a052b77ef97bd85a0f4ace2a4d9ad
diff --git a/dev-python/mkdocs/mkdocs-1.3.1.ebuild b/dev-python/mkdocs/mkdocs-1.3.1.ebuild
new file mode 100644
index 000000000000..f8f1e01f1639
--- /dev/null
+++ b/dev-python/mkdocs/mkdocs-1.3.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="Project documentation with Markdown"
+HOMEPAGE="https://www.mkdocs.org https://github.com/mkdocs/mkdocs"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+IUSE="doc"
+
+BDEPEND="
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/mdx_gh_links[${PYTHON_USEDEP}]
+			dev-python/mkdocs-redirects[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+RDEPEND="
+	>=dev-python/Babel-2.9.0[${PYTHON_USEDEP}]
+	>=dev-python/click-3.3[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.2[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2.1[${PYTHON_USEDEP}]
+	<dev-python/markdown-3.4[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-2.0[${PYTHON_USEDEP}]
+	>=dev-python/ghp-import-1.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml_env_tag-0.1[${PYTHON_USEDEP}]
+	>=dev-python/importlib_metadata-4.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.5[${PYTHON_USEDEP}]
+	>=dev-python/mergedeep-1.3.4[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Tests fails if additional themes are installed
+	sed -i -e 's:test_get_themes:_&:' \
+		mkdocs/tests/utils/utils_tests.py || die
+
+	# Skip this network test, "does not appear to be an IPv4 or IPv6 address"
+	sed -i -e 's/test_IP_normalization/_&/' \
+		mkdocs/tests/config/config_options_tests.py || die
+
+	# livereload has been dropped in this release, this test is a remnant
+	rm mkdocs/tests/livereload_tests.py || die
+
+	# fix apparent typo in test (importing wrong thing)
+	sed -i -e 's/from localization import/from mkdocs.localization import/g' \
+		mkdocs/tests/theme_tests.py || die
+
+	# Does not work in emerge env
+	sed -i -e 's/test_paths_localized_to_config/_&/' \
+		mkdocs/tests/config/config_options_tests.py
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	default
+	if use doc; then
+		# cannot just do mkdocs build, because that fails if
+		# the package isn't already installed
+		python -m mkdocs build || die "Failed to make docs"
+		# Colliding files found by ecompress:
+		rm site/sitemap.xml.gz || die
+		HTML_DOCS=( "site/." )
+	fi
+}
+
+python_test() {
+	epytest mkdocs/tests/*
+}
diff --git a/dev-python/mkdocs_pymdownx_material_extras/Manifest b/dev-python/mkdocs_pymdownx_material_extras/Manifest
index 6136f9359b49..eff82620c112 100644
--- a/dev-python/mkdocs_pymdownx_material_extras/Manifest
+++ b/dev-python/mkdocs_pymdownx_material_extras/Manifest
@@ -1,4 +1,5 @@
 DIST mkdocs_pymdownx_material_extras-1.0.7.tar.gz 17995 BLAKE2B a7a8715ec07b9ef5551eadb37e618f45ca2f8f3c707aa5269eb7d2587db70ba29cfaa8027bb606c4264bbf93d7b3950d7a5dc03640b71afc677658b044d064fa SHA512 33fe8fddd0ee5856fdfb02068e2698f26a8db139458d7736715b776fbc2d8ae8ccb3170dbb786c52338e4e7a1612006046eb429f2268469f6f2bb5ba7f8e256d
 DIST mkdocs_pymdownx_material_extras-1.1.3.tar.gz 40029 BLAKE2B faa17e6e4d27a5d5e34a98a6830e34b934f8623fafb87a73051eb424cf95d29c5dd185bbfbbe49dd3e93eeee00a8310ac0543d480ab70e5abee4047b1cecc774 SHA512 340818ebcd8f9cf175e5049028d0932a0d6208de3d8f86cf5ea47747680079c6b9b3bf27e0c32ee10ee6a1bc7ab8ffc6cc3aa48470be43ed32adfde74f44d5dd
 DIST mkdocs_pymdownx_material_extras-2.1.tar.gz 24220 BLAKE2B bc16a3f4b7f471a14b3f5189ce7749f49a72b33c0b4ac9d67f6c7324004532103136898a2cec49adabba37c93c2ac1189e637ed4f2c6f4611f1fcbb9628ac707 SHA512 e10545455adf58643147a802ab422a3b3e293a8853c5e20c0c91cb97f8ee1bd3cb1f2ce23bb73f30f0b92872ab549e8d8fbd41bd783b1d9af3e995e313ebfa4b
+DIST mkdocs_pymdownx_material_extras-2.2.1.tar.gz 24497 BLAKE2B af9c932a7f5686f3524d247cfee5e0d91681a0ae185f7f25405fd8355cd4c5a4de869f0f50de41a7cf7ab27275f532c0922bbfb84d7e7d74d25cfb292538fca1 SHA512 001f23d0b80fc082fc34e69903fb097fe67d4931cb2f02edd200f9c856f5e6393b2b6c6edd81e12ab609e7fefc27bceb494a6ad59bb7596b60200560dfb17465
 DIST mkdocs_pymdownx_material_extras-2.2.tar.gz 24492 BLAKE2B 13c9580f91d90641630dcf0c98fc40955ea01061b22592efd997d17d9bb6dee79bf9b8ad572ea33d2f1de2792eb63d358d8e334c5d49dd0eb7985bb681093132 SHA512 31a1c4b9e70ac4a604743a80665b733e5d72203aba2b62e4884c9005692f5e2e171f0b075a237458be6d52580afcae75f143bdde173ecf90ae05e62861099021
diff --git a/dev-python/mkdocs_pymdownx_material_extras/mkdocs_pymdownx_material_extras-2.2.1.ebuild b/dev-python/mkdocs_pymdownx_material_extras/mkdocs_pymdownx_material_extras-2.2.1.ebuild
new file mode 100644
index 000000000000..846f2497c0e3
--- /dev/null
+++ b/dev-python/mkdocs_pymdownx_material_extras/mkdocs_pymdownx_material_extras-2.2.1.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Custom alterations based on Mkdocs-Material"
+HOMEPAGE="
+	https://github.com/facelessuser/mkdocs_pymdownx_material_extras
+	https://pypi.org/project/mkdocs-pymdownx-material-extras"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/mkdocs-material-8.3.3[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index c3ae20e49789..3f0105fb53ec 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,2 +1,4 @@
 DIST spyder-5.3.1.tar.gz 24415110 BLAKE2B 368179c6ba6d355ca56fe3eb3ed8b24be3e986f1f2d0284f0f5739bdecb21225bce10802883b54dd888da54515bd8477adf6c0d3e38a3c549bb10407534254b0 SHA512 2501ddc45df11671b1a318eb33b50788b334ab10fbafb97a9491775a0efcc6a57814672068ab84314f9cb43961d6fabd9b906fb164cd58c77b6d6ecf0d6621e6
+DIST spyder-5.3.2.gh.tar.gz 24441566 BLAKE2B dae46baf1a2673ee7449d1060302a726963424c946c9a0188ab85401c9a457fe818039ce3217ccd94ee3976b3e1a4dbb4379945862dee039ebd01ca41077846f SHA512 d1e9a83ddad6e637bef9cacc8261e9097684996661f730ff2813c2bdd72b1d58e9ae75f8a54730088761750eee6ae3d622f25fb9d0e6bca70325906cf4fc9348
+DIST spyder-docs-d43d6cd46b6eb7675ec690b0dff573ca03f2e301.gh.tar.gz 90037375 BLAKE2B 2faf8d2d07b10aec750534c73ebcfc9146533db4223908ecabafb214d7e0a85416aaaf4359f95768572bbd8806f13bd707124f9585299527af5bd5bc735293d4 SHA512 00f12af5298f5b90eaf9a4ea8706b5bb29445ca344b5117801dbac54508eefa29c807e0d4f36524fb5d8b6208204533dc657da63849cadaf13f4aa3652612cb1
 DIST spyder-docs-d43d6cd46b6eb7675ec690b0dff573ca03f2e301.tar.gz 90037375 BLAKE2B 2faf8d2d07b10aec750534c73ebcfc9146533db4223908ecabafb214d7e0a85416aaaf4359f95768572bbd8806f13bd707124f9585299527af5bd5bc735293d4 SHA512 00f12af5298f5b90eaf9a4ea8706b5bb29445ca344b5117801dbac54508eefa29c807e0d4f36524fb5d8b6208204533dc657da63849cadaf13f4aa3652612cb1
diff --git a/dev-python/spyder/spyder-5.3.2.ebuild b/dev-python/spyder/spyder-5.3.2.ebuild
new file mode 100644
index 000000000000..259d6e93d23b
--- /dev/null
+++ b/dev-python/spyder/spyder-5.3.2.ebuild
@@ -0,0 +1,193 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit optfeature xdg distutils-r1
+
+# Commit of documentation to fetch
+DOCS_PV="d43d6cd46b6eb7675ec690b0dff573ca03f2e301"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="
+	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# The test suite often hangs or does not work. RESTRICTing because IMO it is
+# not worth the several hours I would have to spend every single version bump
+# checking which tests do and do not work.
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-black-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-22.1.0[${PYTHON_USEDEP}]
+	>=dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
+	<dev-python/qdarkstyle-3.1[${PYTHON_USEDEP}]
+	>=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.3.0[${PYTHON_USEDEP}]
+	<dev-python/qtconsole-5.4.0[${PYTHON_USEDEP}]
+	>=dev-python/QtPy-2.1.0[${PYTHON_USEDEP},svg,webengine]
+	>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-2.3.2[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-2.4.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-ordering[${PYTHON_USEDEP}]
+		dev-python/pytest-qt[${PYTHON_USEDEP}]
+		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/sympy[${PYTHON_USEDEP}]
+	)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.0-build.patch"
+	"${FILESDIR}/${PN}-5.2.0-doc-theme-renamed.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/doc \
+	dev-python/sphinx-panels \
+	dev-python/pydata-sphinx-theme \
+	dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these dependencies are packaged separately:
+	#    dev-python/spyder-kernels,
+	#    dev-python/python-lsp-server,
+	#    dev-python/qdarkstyle
+	rm -r external-deps/* || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
+	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
+	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
+	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
+	# Do not depend on ipython, this dependency is carried in spyder-kernels
+	# The explicit version requirements only make things more complicated, if e.g.
+	# pyls-spyder gains compatibility with a newer version of python-lsp-server
+	# in a new release it will take time for this information to propagate into
+	# the next spyder release. So just remove the dependency and let the other
+	# ebuilds handle the version requirements to speed things up and prevent
+	# issues such as Bug 803269.
+	sed -i \
+		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
+		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
+		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
+		-e "/'parso[ 0-9<=>.,]*',/d" \
+		-e "/'jedi[ 0-9<=>.,]*',/d" \
+		-e "/'pylint[ 0-9<=>.,]*',/d" \
+		-e "/'ipython[ 0-9<=>.,]*',/d" \
+			setup.py || die
+	sed -i \
+		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
+		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
+		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
+		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
+		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
+		-e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
+			spyder/dependencies.py || die
+
+	# do not check deps, fails because we removed dependencies above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# can't check for update, need network
+	rm spyder/workers/tests/test_update.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly makes the tests freeze after completing even if successful
+# Exit code is nonzero even upon success, so can't add || die here test results
+# should be checked for success manually
+python_test() {
+	"${EPYTHON}" runtests.py
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+	optfeature "Run Cython files in the IPython console" dev-python/cython
+	optfeature "The hdf5/h5py plugin" dev-python/h5py
+	# optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+	# spyder-autopep8 does not have a release (yet)
+	# and are not compatible with >=spyder-4.0.0 at the moment
+	# optfeature "The autopep8 plugin" dev-python/spyder-autopep8
+	# optfeature "Vim key bindings" dev-python/spyder-vim
+	optfeature "Unittest support" dev-python/spyder-unittest
+	# optfeature "Jupyter notebook support" dev-python/spyder-notebook
+	optfeature "System terminal inside spyder" dev-python/spyder-terminal
+	# spyder-reports not yet updated to >=spyder-4.0.0
+	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+}