Adding metadata

37 files changed, 825 insertions, 4 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 2662a0a73ec3..dd0050c01b97 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,3 +1,4 @@
 DIST boto3-1.26.142.gh.tar.gz 655602 BLAKE2B e9d5671308e71bb43a97953407f4aba5b78594ed39b26c3c992af9db8864e3c363ab874a66b5b015083c4a18fe7415bb1761137367783a70ff22564ada8a8842 SHA512 c2eabdb47898aa26fc8ba8a8ebfa43a86153188af1f1600bfa741bd3af1ce68a8692e461aecb5a29df94885e1c977b06c3cd009f1cec52a2e7a9dc853a2c3942
 DIST boto3-1.26.146.gh.tar.gz 658035 BLAKE2B 29104a4ebd16ca8b2a0631bb747ed8b5af9fd6a5c86927937e6fc3ded14857c5244dc3ae4db1aec880f845b32d505edb1ef652a29f9f4d48f8a935a3ff239dbd SHA512 910c49bfdca0f39e089eab50ca24f9cfa3c75cae8c33d53155f0df2dd4c6ae1729dc235bfb3f5880cd50bdeeb60327490bf2372ca2cc14600d24dc90b51d6120
 DIST boto3-1.26.151.gh.tar.gz 661732 BLAKE2B 8adc42757d828414dd4bde9f460bc9fd6781131de5c8a5648fd1b6888ad4ff656db4075aeb2855493823290c5239ea6364aedd531197206c540b126bd466c379 SHA512 51359a351ed023de6b7c84e6d3e2bd5fc28f1ddc39e71af61bc6880002ed9478150e87e4237032d0ff9110792fcfbc09a62ee23f89d7d417730a88abccda0517
+DIST boto3-1.26.152.gh.tar.gz 662874 BLAKE2B 31866c0c3244cdb868fadaf985410e5577d8d75f37387ee44f6ce879ae06c282a4e85e262da4bab3e588918b126110c10b5a64bf7764f076baf495a4382cd225 SHA512 3d496da055172bbc840a3a6f8bd7df6f24bbb1f2f5dbacbbc0e337d4bd15d1355b9fd2e5dbb9e611aa1e415d11dc32bd0b61428a0d0ce7e2d55bb143a0cf1491
diff --git a/dev-python/boto3/boto3-1.26.152.ebuild b/dev-python/boto3/boto3-1.26.152.ebuild
new file mode 100644
index 000000000000..03c610b184f7
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.152.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index c260b8c31c39..405f805924ea 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,3 +1,4 @@
 DIST botocore-1.29.142.gh.tar.gz 11528069 BLAKE2B 860a5ab68d26424702006b221e62e29cfe21ba93593be61e4ef7e89ab50c6afb4b305f2ef3b2d80fd428cf7791933e43b20e1d4934d330653290a7b2aa16f6c4 SHA512 f408175054095bdd3094dd789de333e4e669cee72fdbc5b03551fc006cbcda5cf69eaa6daa2eb3bf09b30524f50d4b7b334d7b18051e55eca12caa16529b41bf
 DIST botocore-1.29.146.gh.tar.gz 11553866 BLAKE2B 7b5b060480de459af9045be8724272fb876c8663b39b1a1ea3575cee83d233dc4e04735682f7eac9299ae0219a5995ddd3379d75c6d2e1bece565e2294b3cc23 SHA512 e786137deaac49fa9db7c8c4df1ff8be195dd400432fbb2e6a23608181161234fa5c3a81a293b4ae1133d1a40e0341b3a081f0d845672e8d0c604fdffc2bc1b5
 DIST botocore-1.29.151.gh.tar.gz 11618833 BLAKE2B cac8007e6177c029b97e288c244668657da6b20d3ea1b4e5b1b93e65bf7dec1206c5bccdc70094e14b02a3937a10f12868a3ea9b85cf6fbcb6e7a6c71155170a SHA512 960a5a62e467a3057e89f1f7d2700b67a1aff442b85a7b89b7da6a403deb2d706e9d6297392ef74a5569d90cd3123fa0474d40f378f0756012d88665c0214aa4
+DIST botocore-1.29.152.gh.tar.gz 11624895 BLAKE2B f6b8596548ab8ff5cbf401d98ebf90cd0425f0363f9be1b71f58649a98dd6c69a859deb80467621bcdc5c15ebe151df7960880ebc013d5834d5310e80a89e948 SHA512 f51f8e00e61ed51d39ec9e51a08cf0f57d29f5e1d4e77460cf28ed296f062cf9df2b5761a30d8a78b6bc4ca8a971032150929cb84147d099e45f8e0112a717e5
diff --git a/dev-python/botocore/botocore-1.29.152.ebuild b/dev-python/botocore/botocore-1.29.152.ebuild
new file mode 100644
index 000000000000..509d06dedf97
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.152.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+		# urllib3-2 compatibility, mock relies on implementation details
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_no_response_from_server
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_returned
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_sends_307
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_sends_connection_header
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_handles_expect_100_with_different_reason_phrase
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_state_reset_on_connection_close
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/dropbox/Manifest b/dev-python/dropbox/Manifest
index 4ebd3603123d..312d1388e70d 100644
--- a/dev-python/dropbox/Manifest
+++ b/dev-python/dropbox/Manifest
@@ -1 +1 @@
-DIST dropbox-sdk-python-11.36.1.gh.tar.gz 1166660 BLAKE2B ed2586c27e020cae38dafdee7367ea38ad191a6275ab677adef13cf3b3c2eec1fab204d6845a7108b33a925a41459053eb5d33bd5a5c0be771613e9f89f775d7 SHA512 29db18efa9059744d6e18f3f15eaee9161df0e26af947fac3fdf3d7e906380f499c1ecc4b2c14a5207c879cd282b73dea44a1dc664f27be99fbe2cd309b86f09
+DIST dropbox-sdk-python-11.36.2.gh.tar.gz 1166700 BLAKE2B afd0592bd1e18416f91d1fd673f2b7b7f605eaab80c02a9d8535fefa7fb23c8bc6a08c191492e1ced5d4b2d17fa72e8e5b6a58ba797f170c0efb75e755a451c9 SHA512 ec27685b4e5344e706bffb68b110ef2d7b307a5865bed3e042d6835f3666d2eefca646627a07bae1a3142e5f0346865fe285b037b00f3da081eb5797f9a768f5
diff --git a/dev-python/dropbox/dropbox-11.36.1.ebuild b/dev-python/dropbox/dropbox-11.36.2.ebuild
index 0a1dd189c752..0a1dd189c752 100644
--- a/dev-python/dropbox/dropbox-11.36.1.ebuild
+++ b/dev-python/dropbox/dropbox-11.36.2.ebuild
diff --git a/dev-python/filelock/Manifest b/dev-python/filelock/Manifest
index 4d5dba791631..02f9ec031a5e 100644
--- a/dev-python/filelock/Manifest
+++ b/dev-python/filelock/Manifest
@@ -1,2 +1,3 @@
 DIST filelock-3.12.0.tar.gz 11839 BLAKE2B 3c363e7e7ca39ddf21a6c86ed4e98eff170c3be6d4c8429a641403dd7d90058a6f15330457f01217b994959514ad297aa5ae8807b0f1d6359455cf5776be8b90 SHA512 4bd5d9df76499e2a4f9dd9274fcc8bd507813446fa8e5852cef6c674d34d3db2313e4b79ac98eae07d6a9fe953de4ee6390baa4c9d5ab6a005c96324dd5904e8
 DIST filelock-3.12.1.tar.gz 12445 BLAKE2B 7f4a115e6b50976935fee917ca7ebcba13129ad1494f8f536502c4f34335aee1f83a18393b01707195b362f83246d6ba86bd26859846540fb6de12c416f6a43c SHA512 c08768d230cad4407f21b23578a009da61858f347d3ca189756b1da32b61b70c187029786f00e286f76f026b561beb270e87b19fc1caf3fdeaea5eb96c208ae8
+DIST filelock-3.12.2.tar.gz 12441 BLAKE2B a54eb7841bd037caf537144829818ab25acf7b5a916c6fc2a296a937f36a36b7846cce3b35e751041ccc1dfc5c5c4be1b6031a261927c152657f968bb465915b SHA512 0753743338c4937f57176ef2291f44a919d949c7b3aa73e3210572d670949a60a9ad3efaaaeff198704e1308c169807655bb90d399c1158e4f5c9aae4adcd486
diff --git a/dev-python/filelock/filelock-3.12.2.ebuild b/dev-python/filelock/filelock-3.12.2.ebuild
new file mode 100644
index 000000000000..b3a0af7951e1
--- /dev/null
+++ b/dev-python/filelock/filelock-3.12.2.ebuild
@@ -0,0 +1,29 @@
+# Copyright 2018-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A platform independent file lock for Python"
+HOMEPAGE="
+	https://github.com/tox-dev/py-filelock/
+	https://pypi.org/project/filelock/
+"
+
+LICENSE="Unlicense"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index 4c83320404bd..ba6eddb89607 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1 +1,2 @@
 DIST fonttools-4.39.4.gh.tar.gz 3710610 BLAKE2B f4d75ae71c7b8ec752eee3820129719583072c8e1e68d54b3443c192e7c6732e7db7adfaec32145b87eccd23b1720a748e70682d58a1628d93f89890d3ddc274 SHA512 4be7c19022ccfbb182edb7d80ec50ff2aa91eae3dd4328c1023e65a293e079edd4c1ae0a8b2260e35fa940417e7b03dc96bd7a6d6ec4234bc4c4257187b24758
+DIST fonttools-4.40.0.gh.tar.gz 3726926 BLAKE2B c14cf10baeca50f6a70dc210de40f46b24effa66efdaded0a2706539af659b7fea276064b352fbe2f412028912658dc3f215409c3975bd773a7bd789986a65a1 SHA512 03daecfb2c48e13f22255872dd9dca47aaca9fc71139f2d5876cdb74fa8560d697344845d870742da00d3734043e36f143efe5d2048b884a5f7ed924435aa2f0
diff --git a/dev-python/fonttools/fonttools-4.40.0.ebuild b/dev-python/fonttools/fonttools-4.40.0.ebuild
new file mode 100644
index 000000000000..8ebccb763a7a
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.40.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="
+	https://github.com/fonttools/fonttools/
+	https://pypi.org/project/fonttools/
+"
+SRC_URI="
+	https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	export FONTTOOLS_WITH_CYTHON=1
+}
+
+src_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	epytest Tests fontTools || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/google-i18n-address/Manifest b/dev-python/google-i18n-address/Manifest
index 279277d6a879..4491eb8b6c0b 100644
--- a/dev-python/google-i18n-address/Manifest
+++ b/dev-python/google-i18n-address/Manifest
@@ -1 +1,2 @@
 DIST google-i18n-address-2.5.2.gh.tar.gz 724067 BLAKE2B 1ec13e99216e263985d04ceb3efd6708041a91be2cc6d4531c099d1599bfa55e21ebbc785d94bda245304bc904778e906c036b2bf0235c9e7c26c8439a69ad07 SHA512 3e9a583cee35af2c045c41fbdafea8dab2897354422a4d2df96834d56443499442a62fb19be42d06cd8974fac677936cb34713730b1c3c18c9a041a7ae46c5cb
+DIST google-i18n-address-3.1.0.gh.tar.gz 726728 BLAKE2B ef41b285aecea0b3e11b08c0815d57a2c3816c59fe01fab64fd75913b0f870e42fbcd0ed76b201c6cd47e4b249c03689b54c648468c3a2cf3d3cb67e2be7ab03 SHA512 b47b5eeaf214a04614ed0976055d25fbce2d298c45db4bfe31b369cd27dc1e097b14d4fae62b5f8dd95be5693d2fda12d0b618029dc1f3ed2784e28b60c43ef9
diff --git a/dev-python/google-i18n-address/google-i18n-address-3.1.0.ebuild b/dev-python/google-i18n-address/google-i18n-address-3.1.0.ebuild
new file mode 100644
index 000000000000..5be9e0250f61
--- /dev/null
+++ b/dev-python/google-i18n-address/google-i18n-address-3.1.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google's i18n address metadata repository"
+HOMEPAGE="
+	https://github.com/mirumee/google-i18n-address/
+	https://pypi.org/project/google-i18n-address/
+"
+# Using the github release, as it contains the tests (unlike the pypi artifact).
+SRC_URI="
+	https://github.com/mirumee/google-i18n-address/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+distutils_enable_tests pytest
diff --git a/dev-python/googleapis-common-protos/Manifest b/dev-python/googleapis-common-protos/Manifest
index d69e8c8e0973..db6f22741de3 100644
--- a/dev-python/googleapis-common-protos/Manifest
+++ b/dev-python/googleapis-common-protos/Manifest
@@ -1 +1,2 @@
 DIST googleapis-common-protos-1.59.0.tar.gz 117558 BLAKE2B cd566fd57f9a3e783389aa31ee9c148efa267b727c134ef870c3a3da8d43caf7a55b0623f26810b7fa24ec3f828d8e517ffe76eedf6c80eac677b4b982e74a07 SHA512 7699f818f30f2938a6c701b41e84cd0cefd652c6004169532461b5c435270ea42806271032ff5b3cc8cae04b9a8568795aa0786dc362f190fe3e1eeee0a0cda7
+DIST googleapis-common-protos-1.59.1.tar.gz 118520 BLAKE2B e9f1b9f0b02465552aca8df83d12eb4ff2db9cdab27c0359b6b8c402c19afe77fed9c715179669e1029bee864edaa6fd744f307f9b3275170677e282c955faca SHA512 e977382da5880ef9097af7ff653768902a2c6c00927847cb2b9e601072f226509539226a82c98a9e4f38354b05e246f0f9c9c87ed008cb9c0a5976eae1863bd3
diff --git a/dev-python/googleapis-common-protos/googleapis-common-protos-1.59.1.ebuild b/dev-python/googleapis-common-protos/googleapis-common-protos-1.59.1.ebuild
new file mode 100644
index 000000000000..2bb77565f0d4
--- /dev/null
+++ b/dev-python/googleapis-common-protos/googleapis-common-protos-1.59.1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python classes generated from the common protos in the googleapis repository"
+HOMEPAGE="
+	https://github.com/googleapis/python-api-common-protos/
+	https://pypi.org/project/googleapis-common-protos/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/protobuf-python-5[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.15.0[${PYTHON_USEDEP}]
+	!dev-python/namespace-google
+"
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+# no tests as this is all generated code
diff --git a/dev-python/hatchling/Manifest b/dev-python/hatchling/Manifest
index d622c78b317f..ef860b5489ef 100644
--- a/dev-python/hatchling/Manifest
+++ b/dev-python/hatchling/Manifest
@@ -1,2 +1,3 @@
 DIST hatch-hatchling-v1.17.0.gh.tar.gz 383013 BLAKE2B 469d0d3e017d2dadcfdf9e2b4975f9e484739737a5c2d8fca9c55a4e519cf2e12b1ee44b3e26160476b3b990b15219a7075e692b58dcc4104b76b57395d8b0d1 SHA512 3649f2932c9963184deda5aac91726dad30ed88db2230377dc303714e0cdfd148b2fefc174ddeffff5cd95033bd984a35e3d297da02c29e4bfb7a6fb42f12dbd
 DIST hatch-hatchling-v1.17.1.gh.tar.gz 383218 BLAKE2B be31190492af5904aa9d8d10fa7f204d664599fc9543a6c3b5a3781bdc68a3f5f3fd2eabbd21e34e21ed8367c8253ed280b6aa5c6387268534799de4b75efa35 SHA512 2a9b163d10834b021f6ebd35484ebff01f22a7addbb2c472ec21dcc7a389e617d955935820bd7247d33fe79c4009e0e368a898b29fa0a3c7fff232f3bd7c424e
+DIST hatch-hatchling-v1.18.0.gh.tar.gz 386992 BLAKE2B 9597d139ca0d59b82862a4b89208bf61ceb0859ed37e2f62c14f7f26550638716cd375082cae6ce0e233f92297b97015af5587144c2d801ecacdb15a07f32cf2 SHA512 e71e51fdace9b9aa276c2efba3a81a030ed934c21283057f83a6ce4a09f8feed8cd4386088280c9fe1381dd92e574daeda8c845a6a2cf6a015708126ca9788d7
diff --git a/dev-python/hatchling/hatchling-1.18.0.ebuild b/dev-python/hatchling/hatchling-1.18.0.ebuild
new file mode 100644
index 000000000000..d492fe929cc2
--- /dev/null
+++ b/dev-python/hatchling/hatchling-1.18.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{7,8,9,10,11} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1
+
+TAG=${P/-/-v}
+MY_P=hatch-${TAG}
+DESCRIPTION="Modern, extensible Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/hatchling/
+	https://github.com/pypa/hatch/
+"
+SRC_URI="
+	https://github.com/pypa/hatch/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/backend
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+
+# deps are listed in backend/src/hatchling/ouroboros.py
+RDEPEND="
+	>=dev-python/editables-0.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+	dev-python/trove-classifiers[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/atomicwrites[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+			dev-python/httpx[${PYTHON_USEDEP}]
+			dev-python/platformdirs[${PYTHON_USEDEP}]
+			dev-python/pytest-mock[${PYTHON_USEDEP}]
+			dev-python/rich[${PYTHON_USEDEP}]
+			dev-python/tomli-w[${PYTHON_USEDEP}]
+			dev-python/virtualenv[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x EPYTEST_DESELECT=(
+		# these run pip to install stuff
+		tests/backend/dep/test_core.py::test_dependency_found
+		tests/backend/dep/test_core.py::test_extra_met
+		tests/backend/dep/test_core.py::test_extra_no_dependencies
+		tests/backend/dep/test_core.py::test_extra_unmet
+		tests/backend/dep/test_core.py::test_unknown_extra
+		tests/backend/dep/test_core.py::test_version_unmet
+		# broken if CARGO is set
+		tests/backend/builders/test_app.py::TestBuildBootstrap::test_no_cargo
+	)
+
+	# top-level "tests" directory contains tests both for hatch
+	# and hatchling
+	cd "${WORKDIR}/${MY_P}" || die
+	local -x PYTHONPATH="src:${PYTHONPATH}"
+	# sigh; standalone test suites are overrated, right?
+	echo "__version__ = '${PV}'" > src/hatch/_version.py || die
+	# tests mock cargo subprocess call but the backend raises if CARGO
+	# is not set and shutil.which() can't find it
+	local -x CARGO=cargo
+	epytest tests/backend
+}
diff --git a/dev-python/ijson/Manifest b/dev-python/ijson/Manifest
index c4d39d05da09..2b546a9b7eaa 100644
--- a/dev-python/ijson/Manifest
+++ b/dev-python/ijson/Manifest
@@ -1 +1,2 @@
 DIST ijson-3.2.0.post0.gh.tar.gz 127558 BLAKE2B 38e06039bb177c43e4744f145fed2159e317a0b8da628b85a62215cdfe6693b271c39629811513d2e563b532244950616b9105134916bc577446a0b5e5ce25f7 SHA512 b926253a3d6a070e2ac27c61542d340e4a1498de7642957dbe59e9fd3c53d700ed4e8ee71c83efcb90b2c302d15b0d268c38054c10728bbb436521aa5b42050b
+DIST ijson-3.2.1.gh.tar.gz 127577 BLAKE2B 1b3c8ce6d8b01d0cf4af4d8995bcc33d879321ed5b89c4b6baa84ef10cd311a1e66254113a17229c228c26e2b996a52c4b0629b42dbd830f296fd4903b603468 SHA512 2bd3a978016fbbd3f5aca6644778d19478a561f40729206eaa4f14e30fde4ff3b92c8aa33c928cb9e81c678a5a84fa59ab68e747421d725e77c79a9c987e4536
diff --git a/dev-python/ijson/ijson-3.2.1.ebuild b/dev-python/ijson/ijson-3.2.1.ebuild
new file mode 100644
index 000000000000..39fb7cf5694a
--- /dev/null
+++ b/dev-python/ijson/ijson-3.2.1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+# _yajl2 extension is known to be broken
+# https://github.com/ICRAR/ijson/issues/98
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+MY_P="${P//_p/.post}"
+DESCRIPTION="Iterative JSON parser with a Pythonic interface"
+HOMEPAGE="
+	https://github.com/ICRAR/ijson/
+	https://pypi.org/project/ijson/
+"
+SRC_URI="
+	https://github.com/ICRAR/${PN}/archive/v${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+DEPEND="
+	dev-libs/yajl
+"
+RDEPEND="
+	${DEPEND}
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index cfc9dff155da..c751bc664edf 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -1,2 +1,3 @@
 DIST ipykernel-6.23.0.tar.gz 151969 BLAKE2B c41aac053b27a2e3618831f8d6458b21877b4510062019576fe98f921b9485fe180f2bced09c0a8ddd930af5a386a09d4d13a2ffbb78e58d71bb7a7cea1c91c1 SHA512 d852742bd858639d150864d343da23ee915c2034b8fbad7875755ea580be80b5faf553c16af65c50001f214979cd4a80c89fe08e4db7198754b554de0101a1d1
 DIST ipykernel-6.23.1.tar.gz 153370 BLAKE2B 654998d46851bcc55d3c0c9c6134f3fcf8c81c2552d5af6dcdbd791e1ac98ed223a59aafc9b7b4260345f8730d243d3c82d4e19e03935a368a0a0154de547cb0 SHA512 8f3921789c837f7c046eed4ffdaade2273b6491cfd97b9a192a256966a66d58c1ad93cbfa69a5e933e052fa35c2c7a4671a652ee9f2bb2cca5a156c79df0f14f
+DIST ipykernel-6.23.2.tar.gz 154126 BLAKE2B 75289aed8e3eff98519fc309a802e440b4486a89f8f62717facb85c04fa03405bb0b1200f5c61e07dc6c96e4efda67473a50cc677fc438b7ec8f72157f084859 SHA512 f3c05d145aea0ada4a11486357895b9938d64cbebc4a7265a6bd1246dfbe0a3cba1ad4ef1de900115ce24d6a0bdfda71eb6d7a06980366f41c410e22f73ebdec
diff --git a/dev-python/ipykernel/ipykernel-6.23.2.ebuild b/dev-python/ipykernel/ipykernel-6.23.2.ebuild
new file mode 100644
index 000000000000..1fd114899109
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.23.2.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi virtualx
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-20[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		ipykernel/tests/test_debugger.py::test_attach_debug
+		ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+		ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+		ipykernel/tests/test_debugger.py::test_set_breakpoints
+		ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+		ipykernel/tests/test_debugger.py::test_copy_to_globals
+		# hangs?
+		ipykernel/tests/test_eventloop.py::test_tk_loop
+	)
+
+	virtx distutils-r1_src_test
+}
diff --git a/dev-python/jsonschema-spec/Manifest b/dev-python/jsonschema-spec/Manifest
index e5802f3db993..8e1b82cadff4 100644
--- a/dev-python/jsonschema-spec/Manifest
+++ b/dev-python/jsonschema-spec/Manifest
@@ -2,3 +2,4 @@ DIST jsonschema-spec-0.1.4.gh.tar.gz 30903 BLAKE2B eae7ba8b811dfd14d9b2e33d3355b
 DIST jsonschema-spec-0.1.5.gh.tar.gz 36035 BLAKE2B 4e6019fb1c7f5e85a03488e00ef080798bc6e3e06999d9c9c931072c640fd74b5125882e43dca26bad1acc3bdacb06a26f2c95dff25339e3f8b785d759085a49 SHA512 c76b15a3ead9498696c80cf7a378a675194837f04cd88d81be5213a38cde8177d5e8f7866d007648b7013db74d1057b700b027a79bcd893b0d493269abcd621d
 DIST jsonschema-spec-0.1.6.gh.tar.gz 36043 BLAKE2B e85cad336d6b5ed11d6a51c8fab2c28826f6a9836ad50d2423b23bef047c338307d3e9430f1d151dbaf7a92574c9899dbfd016c570456996250e8d7634373313 SHA512 78ea06a78fd25006d270e2c5033645133ee79b0f45cbfc54e250d4225a36beac59cf9aa92f15fd51bd101fac20fee990d693ab91d8343cd6a298d71735c80884
 DIST jsonschema-spec-0.2.0.gh.tar.gz 37210 BLAKE2B 44892638371f8ed9074c997e0590594a55a4a00bb0f88bbe535021726f1de6b961825a710c7f1ed63081c5ee7d252bc4f5bcc2cb462ded71ecb492625876c811 SHA512 6bc9f50f9132a72243df1a20d16d049ca1413904fba5403fb780663c0819ae3be8dfd51efada84118e34e157e95475e375df9c6ce1e1930c72c6d45dc71d4d04
+DIST jsonschema-spec-0.2.1.gh.tar.gz 37242 BLAKE2B 8e1b2c4e44052fba0e78cefdf0a60a1e14adbe9f0027464d87e635bac7bb2ce1aefe65c92a1224877128ee23505402f199aca119cd48769d9149d57b5f9ec7ea SHA512 1d1769e301f60c2b2a1e7b413e5d1081f3e069bf29ad12d5e3c4b0c91094c8e78f44b01642a9a58f229e5efe69db14276cf067d9dad37d53c8a35368bd62d6d6
diff --git a/dev-python/jsonschema-spec/jsonschema-spec-0.2.0.ebuild b/dev-python/jsonschema-spec/jsonschema-spec-0.2.0.ebuild
index 405d92e19734..df1eab88d8cc 100644
--- a/dev-python/jsonschema-spec/jsonschema-spec-0.2.0.ebuild
+++ b/dev-python/jsonschema-spec/jsonschema-spec-0.2.0.ebuild
@@ -29,6 +29,12 @@ RDEPEND="
 	>=dev-python/jsonschema-specifications-2023.3.4[${PYTHON_USEDEP}]
 "
 
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
 distutils_enable_tests pytest
 
 src_prepare() {
diff --git a/dev-python/jsonschema-spec/jsonschema-spec-0.2.1.ebuild b/dev-python/jsonschema-spec/jsonschema-spec-0.2.1.ebuild
new file mode 100644
index 000000000000..fb788747b9e9
--- /dev/null
+++ b/dev-python/jsonschema-spec/jsonschema-spec-0.2.1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="JSONSchema Spec with object-oriented paths"
+HOMEPAGE="
+	https://pypi.org/project/jsonschema-spec/
+	https://github.com/p1c2u/jsonschema-spec/
+"
+SRC_URI="
+	https://github.com/p1c2u/jsonschema-spec/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	>=dev-python/pathable-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/referencing-0.28.1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-specifications-2023.3.4[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/--cov/d' pyproject.toml || die
+	# remove random pins due to caret operator
+	sed -i -e 's:\^:>=:' -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/jsonschema-specifications/jsonschema-specifications-2023.5.2.ebuild b/dev-python/jsonschema-specifications/jsonschema-specifications-2023.5.2.ebuild
index f11443c5c025..eb46508f16c9 100644
--- a/dev-python/jsonschema-specifications/jsonschema-specifications-2023.5.2.ebuild
+++ b/dev-python/jsonschema-specifications/jsonschema-specifications-2023.5.2.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~riscv"
 
 RDEPEND="
 	>=dev-python/referencing-0.28.0[${PYTHON_USEDEP}]
diff --git a/dev-python/openapi-schema-validator/Manifest b/dev-python/openapi-schema-validator/Manifest
index 5136401c04b4..6c856b3ba479 100644
--- a/dev-python/openapi-schema-validator/Manifest
+++ b/dev-python/openapi-schema-validator/Manifest
@@ -1 +1,2 @@
 DIST openapi_schema_validator-0.4.4.tar.gz 11626 BLAKE2B e4247f07476d472761f46c98d9259383e960641b910334d967e61f55c63b855c752176e7217f8870016ec3767b0c1c45e8863ca600e354eb5aaa62bcacbe8d51 SHA512 273e3d7080c794ff277170e55e67e32d65211469642652437e59f985a002b20bd2cc8643d2b0214dc232980dd69c2f87ea748537552c66999a110b2e4be2125c
+DIST openapi_schema_validator-0.5.0.tar.gz 11996 BLAKE2B 91f4c51c1d44e363b5f4ca8c69c7836a6df3927d2db5f255b1cc81b97b2056b409becc6f5fb44c0fb82a11fb6a6de398ae49930fdcf77cdb1d88c998b75bf00f SHA512 4db13d63641f375d809501ca7f6efecbbdcc46e74fff1d06657e0c509e6e182c9b97a83031b7a9251e9897f5dd5620a29ddf932f7b8e191c3f78fd2adba5bc68
diff --git a/dev-python/openapi-schema-validator/openapi-schema-validator-0.5.0.ebuild b/dev-python/openapi-schema-validator/openapi-schema-validator-0.5.0.ebuild
new file mode 100644
index 000000000000..77aa0aaa1eb2
--- /dev/null
+++ b/dev-python/openapi-schema-validator/openapi-schema-validator-0.5.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenAPI schema validation for Python"
+HOMEPAGE="
+	https://github.com/python-openapi/openapi-schema-validator/
+	https://pypi.org/project/openapi-schema-validator/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	<dev-python/jsonschema-4.18[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.0.0[${PYTHON_USEDEP}]
+	dev-python/rfc3339-validator[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -e '/--cov/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/pylint-venv/Manifest b/dev-python/pylint-venv/Manifest
index 4bb8c9e48d01..414eab787300 100644
--- a/dev-python/pylint-venv/Manifest
+++ b/dev-python/pylint-venv/Manifest
@@ -1 +1,2 @@
 DIST pylint-venv-3.0.1.gh.tar.gz 14901 BLAKE2B e41a0782fe1bdf83b0019c035cb80416838b71924a1574189aa8936a22fce689523984a277305beba49559d0bcdbde9c8b4ac6a9cb12e1a3853a9a3f287a7a57 SHA512 7b6e7be85dd5552c99d620550e602eb908fccb1ef0982e1734276e14f882261ad7c13309ac796e657865544484a275016981e9b75ef31d17d4c01454b7e091a8
+DIST pylint-venv-3.0.2.gh.tar.gz 15046 BLAKE2B 3c07e00739541c4b9b7c28c9b6cf91e8dee27885adcac8ec88b347f6c580ee0a0c905271eb5b5256ccf0ea975604bf98560ce271a27cbfd2d5790d1143ba6af4 SHA512 716491ffbb5e6642cd61cee62c720a594d85b4cf44feb2d53d3e120dbdea813234776a95341ac10acbdd64354cc3875659f1d3bbc5f45a87ac5232e1e7f89473
diff --git a/dev-python/pylint-venv/pylint-venv-3.0.2.ebuild b/dev-python/pylint-venv/pylint-venv-3.0.2.ebuild
new file mode 100644
index 000000000000..b436554d033c
--- /dev/null
+++ b/dev-python/pylint-venv/pylint-venv-3.0.2.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Init-hook to use the same Pylint with different virtual environments"
+HOMEPAGE="
+	https://pypi.org/project/pylint-venv/
+	https://github.com/jgosmann/pylint-venv/
+"
+SRC_URI="
+	https://github.com/jgosmann/pylint-venv/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/pylint-2.14.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pylint-2.14.0[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	# we need to set PYTHONPATH explicitly since the test runs installed
+	# pylint (i.e. starts outside the test venv)
+	local -x PYTHONPATH=${S}:${PYTHONPATH}
+	bash test/test.sh || die "Test failed with ${EPYTHON}"
+}
diff --git a/dev-python/pyproj/Manifest b/dev-python/pyproj/Manifest
index 04defc4ab185..d4ba278e26b1 100644
--- a/dev-python/pyproj/Manifest
+++ b/dev-python/pyproj/Manifest
@@ -1 +1,2 @@
 DIST pyproj-3.5.0.gh.tar.gz 237380 BLAKE2B e401998418efb79be496bf11be904191fa43e004331867415524508c8766ca9f4ae390ade1341ab6508e6d7d92c8875357bad2b1af159b642345065f8c28ebf8 SHA512 64d1eab54fc5e39d6403fcb0ae3e0b5283303471431894fa6fa94c118374c4ca1a9a418a7d0d1d8bbd2a6a96a5a2dbaf3d067417d6335174c8911db796fbd0a9
+DIST pyproj-3.6.0.gh.tar.gz 238966 BLAKE2B 441904a343b7abab19e9d17a1bcb053d4f5606886b1325cfadcdd8456b61871bee4d13c49802008aea5c5864c40ef15a4a7681969890368a1991ba696b76ab78 SHA512 e713de94331022112049e76f7f56d24439a0dee339e8419acf8b023b3234a7c2ba468bed880749036fca2a93b289575ebb74854ba178f3b6debae8aa53befcf7
diff --git a/dev-python/pyproj/pyproj-3.6.0.ebuild b/dev-python/pyproj/pyproj-3.6.0.ebuild
new file mode 100644
index 000000000000..babe636bc227
--- /dev/null
+++ b/dev-python/pyproj/pyproj-3.6.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface to the PROJ library"
+HOMEPAGE="
+	https://github.com/pyproj4/pyproj/
+	https://pypi.org/project/pyproj/
+"
+SRC_URI="
+	https://github.com/pyproj4/pyproj/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+
+DEPEND="
+	>=sci-libs/proj-9.0.0:=
+"
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	# Avoid greedily trying -L/usr/lib, etc
+	# https://github.com/pyproj4/pyproj/blob/main/setup.py#L76
+	export PROJ_LIBDIR="${ESYSROOT}/usr/$(get_libdir)"
+	export PROJ_INCDIR="${ESYSROOT}/usr/include"
+}
+
+python_test() {
+	rm -rf pyproj || die
+	epytest -m "not network" test
+}
diff --git a/dev-python/referencing/referencing-0.29.0.ebuild b/dev-python/referencing/referencing-0.29.0.ebuild
index db6d33e1ecd4..4eac407f9987 100644
--- a/dev-python/referencing/referencing-0.29.0.ebuild
+++ b/dev-python/referencing/referencing-0.29.0.ebuild
@@ -25,7 +25,7 @@ SRC_URI+="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~riscv"
 
 RDEPEND="
 	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
diff --git a/dev-python/rich/Manifest b/dev-python/rich/Manifest
index 2e40119deefb..f0ad48ab5475 100644
--- a/dev-python/rich/Manifest
+++ b/dev-python/rich/Manifest
@@ -1,2 +1,3 @@
 DIST rich-13.3.4.gh.tar.gz 15059899 BLAKE2B f0ca78bf4cdec19136f9372e541ea90713e55acf4dc6f709b8edba9c8dc56da9ac534c6f32b05b634a970e4c02b1f08bfcb5ff949889d6f7bfaa104a1ca6b1cd SHA512 ab3b2ef30ede12f0959671baeff299621303e09750c245b3b3d7b8f1dbd3b7465410400b39668791de57d6027fe24a0a17d5b7284eea162d819c4cb6b9535f81
 DIST rich-13.4.1.gh.tar.gz 15062357 BLAKE2B b5e0067f378910b6a93f0ec40ff47a4ce26298055fba694441962ec2443f9bb76a8ba34ffe43a05abdc077ea8b1d26bbf6294c9d2370baf724045be043c29544 SHA512 655252e9f34da17df6bc7ce74560667f4472da4df6ed699d4302a02301857543ba8756153f48ea8d5a2df5e627ed3c4c8ab732b2b2b27baf66a10c798795a885
+DIST rich-13.4.2.gh.tar.gz 15063000 BLAKE2B f65079440bc7d89a3ff03be01fa71e076493ae50f22ae8781be2448a7ff2769c174d6654db3a835d34720c34cd8cbecfdd6b13e3064cf7fdcade71806563309d SHA512 17052a9fb0e1d89b31a00d8a719214719891d048fd805185b2d4258c8766130f44bf2280c9567bc162f3b34d9bf2eb7d747d6a37d910c81cd53d3003b51f70bd
diff --git a/dev-python/rich/rich-13.4.2.ebuild b/dev-python/rich/rich-13.4.2.ebuild
new file mode 100644
index 000000000000..353debe9fe77
--- /dev/null
+++ b/dev-python/rich/rich-13.4.2.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for rendering rich text, tables, etc. to the terminal"
+HOMEPAGE="
+	https://github.com/Textualize/rich/
+	https://pypi.org/project/rich/
+"
+SRC_URI="
+	https://github.com/Textualize/rich/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	>=dev-python/markdown-it-py-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.13.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x COLUMNS=80
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_console.py::test_size_can_fall_back_to_std_descriptors
+		tests/test_inspect.py::test_inspect_integer_with_methods_python38_and_python39
+		# pygments?
+		tests/test_syntax.py::test_python_render_simple_indent_guides
+		tests/test_syntax.py::test_python_render_line_range_indent_guides
+	)
+	# version-specific output -- the usual deal
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# pypy3.10, to be more precise
+				tests/test_inspect.py::test_inspect_integer_with_methods_python310only
+			)
+			;;
+		python3.12)
+			EPYTEST_DESELECT+=(
+				tests/test_inspect.py::test_inspect_builtin_function_except_python311
+				tests/test_inspect.py::test_inspect_integer_with_methods_python310only
+				tests/test_inspect.py::test_inspect_integer_with_methods_python311_and_above
+				tests/test_pretty.py::test_attrs_broken
+			)
+			;;
+	esac
+	epytest -p no:pytest-qt
+}
+
+pkg_postinst() {
+	optfeature "integration with HTML widgets for Jupyter" dev-python/ipywidgets
+}
diff --git a/dev-python/rpds-py/rpds-py-0.7.1.ebuild b/dev-python/rpds-py/rpds-py-0.7.1.ebuild
index d3fa8e0c998a..159a2cfbd93b 100644
--- a/dev-python/rpds-py/rpds-py-0.7.1.ebuild
+++ b/dev-python/rpds-py/rpds-py-0.7.1.ebuild
@@ -64,7 +64,7 @@ LICENSE+="
 	Unicode-DFS-2016
 "
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~riscv"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/zeroconf/Manifest b/dev-python/zeroconf/Manifest
index 8f68b4de80d9..f7887f3e7dae 100644
--- a/dev-python/zeroconf/Manifest
+++ b/dev-python/zeroconf/Manifest
@@ -2,3 +2,4 @@ DIST zeroconf-0.62.0.tar.gz 141269 BLAKE2B 17efd98394155e415cc9b9b6ff7b2ec6d7026
 DIST zeroconf-0.63.0.tar.gz 141580 BLAKE2B 22267e2be9118c91b5d7638843e89de0a2838eb1ebca2c233038fc202b8648256193fd8d61523960e1fce110ef7e3c3c06190f5369f700c02cbd047a036a362e SHA512 b899838ddae288b0f0483ca6950871d88ee387769507fe803a68df1cd5657bf9eee2aeecfc2e7685ded5327e70e04cfe445b564f16e3e9191112ddaae7deda18
 DIST zeroconf-0.64.0.tar.gz 142520 BLAKE2B b26c728519b7962c9620f857654e9bd347b1dcd98642a2305f4102ce8fe76cf2f24a934a7a65c355e1dbeaf2152c31f43b529f922b2c3fceec09dbc3f106c6ff SHA512 b85fab86150e88ab4aec8c5f5d338c962ad071140f5ee472b7f3ba8f196a96976e4dc9c1c99b2bd8040d486d0f79c966d45ee2ba58f7724cdbc3345811b9ebc9
 DIST zeroconf-0.64.1.tar.gz 142617 BLAKE2B 100243491aa85b9be8a7664ad9de6f1b202d02fbc2fd3be6116cf1c00c8885ad9fa00c784a036b27338ddb09f6a29b59a056fc610bcf9283cb9fce79110fa07b SHA512 9fa217811bea4b8597bfa4cdca40afd9fdd6920a6499d5b7f61fe78ff09106662f3cbc2381dfbfb541a330ecfa21a751e4bf455f19ba7433b0ebf43da1f21cce
+DIST zeroconf-0.66.0.tar.gz 142962 BLAKE2B 7cc625ea71e00a4e1f47589de1e8168c6299396f1f50d5ba6b530040a0d97ce40b1e858bb76eaaa3e8796c5cc793d819f0b31d693340f2ba5f26cf17d8db3f28 SHA512 544bccaf1acf2a3861c3e0131836f4ccd5d5aadc7222cf34f02ccae61abf32cf7430925698f13d14cf16a62ea9875df6e37fc5e93abfb02dbed79cb1e2e47fe3
diff --git a/dev-python/zeroconf/zeroconf-0.64.1.ebuild b/dev-python/zeroconf/zeroconf-0.64.1.ebuild
index 5a01c685cb9e..1eb1043b709f 100644
--- a/dev-python/zeroconf/zeroconf-0.64.1.ebuild
+++ b/dev-python/zeroconf/zeroconf-0.64.1.ebuild
@@ -27,7 +27,9 @@ RDEPEND="
 "
 # the build system uses custom build script that uses distutils to build
 # C extensions, sigh
+# Cython-3: https://github.com/python-zeroconf/python-zeroconf/issues/1183
 BDEPEND="
+	<dev-python/cython-3[${PYTHON_USEDEP}]
 	>=dev-python/cython-0.29.32[${PYTHON_USEDEP}]
 	>=dev-python/setuptools-65.6.3[${PYTHON_USEDEP}]
 	test? (
@@ -37,6 +39,8 @@ BDEPEND="
 
 distutils_enable_tests pytest
 
+export REQUIRE_CYTHON=1
+
 python_test() {
 	local -x SKIP_IPV6=1
 	local EPYTEST_DESELECT=(
diff --git a/dev-python/zeroconf/zeroconf-0.66.0.ebuild b/dev-python/zeroconf/zeroconf-0.66.0.ebuild
new file mode 100644
index 000000000000..1eb1043b709f
--- /dev/null
+++ b/dev-python/zeroconf/zeroconf-0.66.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
+HOMEPAGE="
+	https://github.com/python-zeroconf/python-zeroconf/
+	https://pypi.org/project/zeroconf/
+"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-3.0.0[${PYTHON_USEDEP}]
+	' 3.{9..10})
+"
+# the build system uses custom build script that uses distutils to build
+# C extensions, sigh
+# Cython-3: https://github.com/python-zeroconf/python-zeroconf/issues/1183
+BDEPEND="
+	<dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/cython-0.29.32[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.6.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+python_test() {
+	local -x SKIP_IPV6=1
+	local EPYTEST_DESELECT=(
+		# network
+		tests/test_core.py::Framework::test_close_multiple_times
+		tests/test_core.py::Framework::test_launch_and_close
+		tests/test_core.py::Framework::test_launch_and_close_context_manager
+
+		# fragile to timeouts (?)
+		tests/services/test_browser.py::test_service_browser_expire_callbacks
+		tests/utils/test_asyncio.py::test_run_coro_with_timeout
+	)
+
+	epytest -o addopts=
+}