Adding metadata

27 files changed, 639 insertions, 146 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index b55e7767be68..a9a3daf555c3 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,3 +1,4 @@
 DIST boto3-1.39.14.gh.tar.gz 974493 BLAKE2B 14c6295f20cab6390c81d399585c9bd8291163a206e212400f44a23d871f43f02c76c0fae5201855cdd77cf45b598b5ceb86320b584fb48a5acb142133aa9d22 SHA512 332cc223c87f0823fded9c885c47892e0dd0abdd4346968425cbdec8e9eacd1d3d22720cb3a615876c47ba031b8b1f4a592d325c812e37f86690b0554438e9a4
+DIST boto3-1.39.15.gh.tar.gz 975021 BLAKE2B 951591198b4d7b524f06165bd998d17fbdcdf54e3f47bac29b3e05966631fd4deb99dd038ff573bb072b95db5cf1f97697723bfe4ea52417031b21a5ed2e4a9e SHA512 00e22e88d75faede7925e8a57a91e2282874bf60f42406da9004874badd688d076916c46f2758fb56d54c9b383fd8092e83ab7876353affff459102694f4dd76
 DIST boto3-1.39.4.gh.tar.gz 967954 BLAKE2B 5e63cfb5c2381605475c928c4aec6cf303b99ca13eb67377e5a283e07d0de35eb6846352976a854632e72c34477f964b32ffc8f0fc178d10d7e95df8d4a145cc SHA512 dbe389b4eb1e8ac1f425f34bb96c5baecc42acdc608bef7ddc31e1fbaa3baa6850504cb9513494a6ca782755ce9264fd0d794960eeb495678ef1cb3d2c85fe90
 DIST boto3-1.39.9.gh.tar.gz 971951 BLAKE2B d77a87e3035a2797ff67d49c3df329836c51b305c72f8ce01445b668802aa1a529424e744ddd18e142cd35a0680be51383b56512dca115506a1a0f4860657b47 SHA512 c6df821d3558ca1d234a4a1dea231467c0935dff7c34e6eb01b067d4d2396024308f70218a621064b111359bc5197b191bc8f4a099bcfcc5f4d5bf174ba859b0
diff --git a/dev-python/boto3/boto3-1.39.15.ebuild b/dev-python/boto3/boto3-1.39.15.ebuild
new file mode 100644
index 000000000000..bd6e26787db4
--- /dev/null
+++ b/dev-python/boto3/boto3-1.39.15.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.13.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index b7dbbbba73ff..86dba3a10797 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,3 +1,4 @@
 DIST botocore-1.39.14.gh.tar.gz 15002421 BLAKE2B a054f85ee0076f1445e122e497683b31387323f52036f914ab1474eb14b32f923459079c539d0a1109c7f622e93e614b8550f9d5ce6e34a0e0a581561e12c9d5 SHA512 716c68404b06b24442da1b1018cfe06256a2b2855f846bd061ef44332db8a624cfd8f16a06169b2337d1c8e54c034aa46f3f3063f6e8d6c4020d1e50d30b6910
+DIST botocore-1.39.15.gh.tar.gz 15007399 BLAKE2B 4d155561f4fab9d6b6d5afd1c3506ade56d2764d21226983f2f6d84ee637a8dad1f6d71d0790b4edcbeea3d3fbe183f0fe005f650021d8dc1c6a6a87e621ed5b SHA512 094374ddc592d8d2652be0e49ec213f6897ec855a2d842cd3e363dcac6dd8137d521ca17946a68508018a9aec2bbc86af0acfe0130fa0d378cff473ce0c7c49d
 DIST botocore-1.39.4.gh.tar.gz 14901512 BLAKE2B 08fc52957828be9ccee26f61c4c006679c4f47754d4ecdf15eecfbb991808035215d1aac24f5ddf76a64673b23132b555fcb24adf57aacda8679abd7b0a16040 SHA512 3a68c96000a4e393abb68a9ca843ad62b74decd12ba551fa642efd21095fb3de50f0eeb8ee71f8934e9efa47486a138ee7bad6f3f4408fd5eff0a0fbf5053e6e
 DIST botocore-1.39.9.gh.tar.gz 14983953 BLAKE2B 929c2456d8efc4256326c255888ebca82edd837df2dc0beeb37119af5f397b74c8e1d1349c66adc79361fe0cbdcb74d268b04ca563fa0047b27cd8f70f755290 SHA512 421421a9ac2845e18ccc6904b443d2d53883c5f85df1b34245541546ef5369cd29fc7af8751507e7513d06c818ff195bc59d6ea4e773b8975d4de874ba79116d
diff --git a/dev-python/botocore/botocore-1.39.15.ebuild b/dev-python/botocore/botocore-1.39.15.ebuild
new file mode 100644
index 000000000000..a931fcaefec4
--- /dev/null
+++ b/dev-python/botocore/botocore-1.39.15.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/cffi/Manifest b/dev-python/cffi/Manifest
index 39184736f5e0..39fa548c09d0 100644
--- a/dev-python/cffi/Manifest
+++ b/dev-python/cffi/Manifest
@@ -1 +1,2 @@
 DIST cffi-1.17.1.tar.gz 516621 BLAKE2B 902844a14c0765ada6adf5054a9462a195b49b2ea4d7441deeff97dd6d9209accd29257697002ee1bad7e143ebf983a2d98077b17e08b060dd1ee75dc682e3d8 SHA512 907129891d56351ca5cb885aae62334ad432321826d6eddfaa32195b4c7b7689a80333e6d14d0aab479a646aba148b9852c0815b80344dfffa4f183a5e74372c
+DIST cffi-2.0.0b1.tar.gz 521625 BLAKE2B a62b15652e02ed62ce33cc92f6bfd4454a81a6a7c3fb84cc048fbf8cc39325af09c19f5c2a2f1e6c80063e9fc8ae6537d1b917a01f15e8e56c2bb847bd79bfac SHA512 974f724a4c819f0a32da38a7209c6f54e63810817794bab286e8721bab6c59ce50c2c0992c828af54088ff8f1dec40480ffe37155d979cadc26c79cdc6b78f54
diff --git a/dev-python/cffi/cffi-2.0.0_beta1.ebuild b/dev-python/cffi/cffi-2.0.0_beta1.ebuild
new file mode 100644
index 000000000000..1f850d13ea69
--- /dev/null
+++ b/dev-python/cffi/cffi-2.0.0_beta1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+# DO NOT ADD pypy to PYTHON_COMPAT
+# pypy bundles a modified version of cffi. Use python_gen_cond_dep instead.
+PYTHON_COMPAT=( python3_{11..14} python3_14t )
+
+inherit distutils-r1 toolchain-funcs pypi
+
+DESCRIPTION="Foreign Function Interface for Python calling C code"
+HOMEPAGE="
+	https://cffi.readthedocs.io/
+	https://pypi.org/project/cffi/
+"
+
+LICENSE="MIT"
+SLOT="0/${PV}"
+
+# Needs recent libffi for HPPA fixes
+DEPEND="
+	>=dev-libs/libffi-3.4.4-r1:=
+"
+# setuptools as a modern distutils provider
+RDEPEND="
+	${DEPEND}
+	dev-python/pycparser[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+	test? (
+		dev-python/py[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx doc/source
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/cffi-1.14.0-darwin-no-brew.patch
+)
+
+src_prepare() {
+	if [[ ${CHOST} == *darwin* ]] ; then
+		# Don't obsessively try to find libffi
+		sed -i -e "s/.*\-iwithsysroot\/usr\/include\/ffi.*/\tpass/" setup.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	tc-export PKG_CONFIG
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# these tests call pip
+		testing/cffi0/test_zintegration.py
+	)
+
+	"${EPYTHON}" -c "import _cffi_backend as backend" || die
+	epytest src/c testing
+}
diff --git a/dev-python/griffe/Manifest b/dev-python/griffe/Manifest
index ce5626114a9a..661ed6842627 100644
--- a/dev-python/griffe/Manifest
+++ b/dev-python/griffe/Manifest
@@ -1,2 +1,2 @@
-DIST griffe-1.7.3.gh.tar.gz 398342 BLAKE2B 628f48b594ec30135cf1e8b0aee32452d75c33f41f16f5e549be4789b8c91cdea65816addc4fc8eee4c6c56cf70ff4c5682c739b0c2483758764e3b8b3dc95af SHA512 b39c4e279bd0f0ba3be144b6d8c3f762f2246f070a0af040aeb0315baecc5a2e519b7fb0bca263ed37b9002791d8efd3b340d43a3cd4e9e1c9253af8d758b52b
 DIST griffe-1.8.0.gh.tar.gz 404336 BLAKE2B f3b83974b979823e74bf705eed180ace7aede4085258059389e6ff94bc243984e25f93d621fcdfd34f9af6720e0d99e1a0f4ad0f2dce1e467a00871d9dfc2da9 SHA512 cdb2176aeceab63d1ed704c9ee7cbdcd028ed768755a69879942c99ecb22081fed03ec3ad8ba9b51e104f9017e5150e7749e0ab23bd2b148c87fe5ee26a98ca9
+DIST griffe-1.9.0.gh.tar.gz 412784 BLAKE2B 87b6797a28f1aca869374357ab36d551a3f6470f702ec678170966181354b2af259c59054ab6d46cb19ba59e77558eae36654e40abba6d89bbcc9e6a38b0ab4f SHA512 1267caae4824de07e36fb900d962af8b72b79571f88a9acc80622a063de8ed4a01e8a6aed178bda27d929108ff2f7335c2c05007288c4e006b21fd30829e6a34
diff --git a/dev-python/griffe/griffe-1.7.3.ebuild b/dev-python/griffe/griffe-1.9.0.ebuild
index 6f7090dd3f3d..29b77fdf3a18 100644
--- a/dev-python/griffe/griffe-1.7.3.ebuild
+++ b/dev-python/griffe/griffe-1.9.0.ebuild
@@ -26,45 +26,21 @@ KEYWORDS="~amd64 ~arm64 ~riscv"
 
 RDEPEND="
 	>=dev-python/colorama-0.4[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		>=dev-python/backports-strenum-1.3[${PYTHON_USEDEP}]
-	' 3.10)
 "
 BDEPEND="
 	test? (
 		>=dev-python/jsonschema-4.17[${PYTHON_USEDEP}]
 		>=dev-python/mkdocstrings-0.28.0[${PYTHON_USEDEP}]
-		>=dev-python/pytest-xdist-2.4[${PYTHON_USEDEP}]
 	)
 "
 
+EPYTEST_PLUGINS=( pytest-xdist )
 distutils_enable_tests pytest
 
-export PDM_BUILD_SCM_VERSION=${PV}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# fragile to installed packages
-		# (failed on PySide2 for me)
-		tests/test_stdlib.py::test_fuzzing_on_stdlib
-	)
+EPYTEST_DESELECT=(
+	# fragile to installed packages
+	# (failed on PySide2 for me)
+	tests/test_stdlib.py::test_fuzzing_on_stdlib
+)
 
-	case ${EPYTHON} in
-		pypy3.11)
-			EPYTEST_DESELECT+=(
-				# https://github.com/pypy/pypy/issues/5226
-				tests/test_inspector.py::test_inspecting_objects_from_private_builtin_stdlib_moduless
-			)
-			;&
-		pypy3*)
-			EPYTEST_DESELECT+=(
-				# tries importing CPython-specific modules
-				# https://github.com/mkdocstrings/griffe/issues/362
-				tests/test_loader.py::test_load_builtin_modules
-			)
-			;;
-	esac
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest
-}
+export PDM_BUILD_SCM_VERSION=${PV}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index da8094c63832..9c92b32d08e3 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -5,3 +5,4 @@ DIST hypothesis-6.136.2.gh.tar.gz 9597138 BLAKE2B 06b6d4ea1e46a65af75380e08e1de3
 DIST hypothesis-6.136.3.gh.tar.gz 9598370 BLAKE2B 8f8c06d53fa240151bcc155ffdce6992565e1ca69b334dc90ffa549e3d0fe627126eb7918342ceb542fde22510eeec58d329e7f1ef27d8bd76d5579c5c13f35e SHA512 9f29abd284eae68e888dcba65f7ead624bef56bd47401a08281ce7dbd34975d7f845d69b5f005c85dd7718538db535104b2ab7dbd9293e73b479d0ffcfdfd60c
 DIST hypothesis-6.136.4.gh.tar.gz 9598539 BLAKE2B f22f644ad9d9b308de9b1357a5977dceb2ced24987b252f291d5f7a9ea66722277b45eb4313e7ac4771d21f5aa3cd43f92a2ee0a988e0c8b994384853ba30c08 SHA512 9de1e0acfc9242ce97728adb415ee8d56afdeb194e5550fdce4140c13b29cab09f1ef7ebded14ede12e66520a86c55548f1e743315ada6dc0e5a48ba87014ac3
 DIST hypothesis-6.136.5.gh.tar.gz 9599010 BLAKE2B f97d7fbacc4ee7c9642841032e2cf76a3da9e35fe0064721d77ee8bbd29adc2a9b7c0406a55e6aa3383dc793c5679082035ed0d3d6d1e59cf6ad2f9ef0bbb7fe SHA512 0a6fea6080a9bec4123758fd145ca4e85399ab60b7ca6f7f1dd97c467af420bb353ee1159cc868c6e7ed48f667ecacb9ddb4b412c5329e90373b5f2859b02f1e
+DIST hypothesis-6.136.6.gh.tar.gz 9599136 BLAKE2B 731ecc6cce2d037ae9d0bf1e3d6b606392950e7a4d70719ce8c553e3b25a65d2c5afe8113fe8f7619504b2d5df3fa25a25e37d73fda56046250d4a6b007867ce SHA512 cb29bc9d5cf31d5d90f7c7475a1fce51e2a0d058b7ed9b3af241410a91201920286362f3620f879784c819c8b4bd2e668ab60fa1b820784ee94f0a3615bb3b73
diff --git a/dev-python/hypothesis/hypothesis-6.136.6.ebuild b/dev-python/hypothesis/hypothesis-6.136.6.ebuild
new file mode 100644
index 000000000000..7a7443937da6
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.136.6.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{11..13} )
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	dev-python/hypothesis-gentoo[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGIN_LOAD_VIA_ENV=1
+EPYTEST_PLUGINS=( "${PN}" pytest-xdist )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		python3.13t)
+			EPYTEST_DESELECT+=(
+				# TODO: missing warning
+				'hypothesis-python/tests/cover/test_random_module.py::test_passing_referenced_instance_within_function_scope_warns'
+			)
+			;;
+		python3.14*)
+			EPYTEST_DESELECT+=(
+				'hypothesis-python/tests/cover/test_compat.py::test_resolve_fwd_refs[Foo-Union]'
+				'hypothesis-python/tests/cover/test_lookup.py::test_builds_suggests_from_type[Union]'
+				hypothesis-python/tests/cover/test_attrs_inference.py::test_attrs_inference_builds
+				hypothesis-python/tests/cover/test_lookup.py::test_bytestring_not_treated_as_generic_sequence
+				hypothesis-python/tests/cover/test_lookup.py::test_issue_4194_regression
+				hypothesis-python/tests/cover/test_lookup.py::test_resolves_forwardrefs_to_builtin_types
+				hypothesis-python/tests/cover/test_lookup.py::test_specialised_collection_types
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_collection_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_container_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_contextmanager_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_iterable_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_reversible_as_generic
+				hypothesis-python/tests/cover/test_lookup_py37.py::test_resolving_standard_sequence_as_generic
+				hypothesis-python/tests/cover/test_random_module.py::test_evil_prng_registration_nonsense
+				hypothesis-python/tests/cover/test_random_module.py::test_passing_referenced_instance_within_function_scope_warns
+				hypothesis-python/tests/cover/test_random_module.py::test_register_random_within_nested_function_scope
+				hypothesis-python/tests/cover/test_random_module.py::test_registering_a_Random_is_idempotent
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_missing_dot_access_forward_ref
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_missing_forward_ref
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_type_checking_only_forward_ref_wrong_type
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py::test_bound_type_cheking_only_forward_ref
+			)
+			;;
+	esac
+
+	local -x HYPOTHESIS_NO_PLUGINS=1
+	epytest -o filterwarnings= tests/{cover,pytest,quality}
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/knowit/Manifest b/dev-python/knowit/Manifest
index bc0df0f72e21..9f78ceb63c68 100644
--- a/dev-python/knowit/Manifest
+++ b/dev-python/knowit/Manifest
@@ -1,3 +1,4 @@
+DIST knowit-0.5.10.tar.gz 59356 BLAKE2B f62baee74fb743d4032abe5ce0f4eb85ec8d803be6fde601bba2ef345bbd86c32d8416cecb25839910731ea1e30a46770c42fba432ef763efebfb7b5e425b2b9 SHA512 6ad5f8d6ea866cde285ebac5955704c888530b7ad4a3b0707b9ac2eb4a581cd7028035fa87b7e67b20b2b8d785619036463826484a0886cb8dedee585c2154f1
 DIST knowit-0.5.6.gh.tar.gz 79683 BLAKE2B da132883e7b4d15a2a21b22b05cb627859947f293a4611a853b2bd31341e4b317a5de42bb7ab48b64a340d96327cb579bb7722f1e875dfc58d1e26652844064c SHA512 c064c2428300f0b2ee08e514e8deea2299f0aa9a552a7ac9ea914035e4e40666a21aa8d2256605d2c86c61592955f1e6b432d2cf43b7a34a3d1235d4b9971aaf
 DIST knowit-0.5.8.tar.gz 59362 BLAKE2B 724b1f00bced9097059fbc798e75a872e347e2b00b5a9079172f7275f451d25f013afb9fd993775013a7a5181f29cdb4d7eb81eea22ff8d50a004c5f4ecd4ef0 SHA512 b6140e64f6a8295ac9fa811db1523c3a1c8aef686e3251f99bbc17e71ab9ddc9041bd4f8b8ed335691fb8fc4949da210f0bc95fbfcf7168045130f4357040b16
 DIST matroska_test_w1_1.zip 184550509 BLAKE2B f111725aa08267661942072c2d4ac019d3d322c4e933aad10afb3aa6f69bb3469114c4400d161e53d8a7618b818b22465177460003804a7ac3e69fa4f4db000d SHA512 f170a8e83dab15228f992b3692330163da2402b8e436c7fa195ac1ecc06cf1eaf1a48d8c99a85c031122c158c2d4006023aae75d5b7805385ba25a6d601cb78f
diff --git a/dev-python/knowit/knowit-0.5.10.ebuild b/dev-python/knowit/knowit-0.5.10.ebuild
new file mode 100644
index 000000000000..0fea987d108e
--- /dev/null
+++ b/dev-python/knowit/knowit-0.5.10.ebuild
@@ -0,0 +1,71 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Know better your media files"
+HOMEPAGE="
+	https://github.com/ratoaq2/knowit/
+	https://pypi.org/project/knowit/
+"
+SRC_URI+="
+	test? (
+		https://downloads.sourceforge.net/matroska/test_files/matroska_test_w1_1.zip
+	)
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+# https://github.com/ratoaq2/knowit/blob/d7135a4797440838bca94e76326fc9d4019d8f9a/README.md?plain=1#L224
+RDEPEND="
+	>=dev-python/babelfish-0.6.1[${PYTHON_USEDEP}]
+	>=dev-python/enzyme-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/trakit-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/pymediainfo-7.0.1[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0[${PYTHON_USEDEP}]
+	|| (
+		media-video/ffmpeg
+		media-video/mediainfo
+		media-video/mkvtoolnix
+	)
+"
+BDEPEND="
+	test? (
+		app-arch/unzip
+		>=dev-python/requests-2.32.4[${PYTHON_USEDEP}]
+		media-video/ffmpeg
+		media-video/mediainfo
+		media-video/mkvtoolnix
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_unpack() {
+	# Needed to unpack the test data
+	default
+
+	if [[ ${PV} == 9999 ]] ; then
+		git-r3_src_unpack
+	fi
+}
+
+src_prepare() {
+	if use test ; then
+		mkdir -p tests/data/videos || die
+		ln -s "${WORKDIR}"/test*.mkv tests/data/videos/ || die
+	fi
+
+	distutils-r1_src_prepare
+
+	# poetry, sigh
+	sed -i -e 's:\^:>=:' pyproject.toml || die
+}
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 318958e71e0d..24a44c4652fd 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -1,2 +1,3 @@
 DIST moto-4.2.14.tar.gz 4933741 BLAKE2B 4c50a808dc8f27cfbcd0ba234d268084ee9a32f36cb5d6af61aacc4ee79f7bf5cf1045147c4642472129eee37bef8bc2c1953d140260d39d7f333ae0f5e5cf95 SHA512 d4079118ed1d2eef9134575e33dc0ed749bff0293d753baa63a630dbb987914b9933445027abdc344bb93fa1d6e483baf8a337a444c9dd055dda50b095ff9937
 DIST moto-5.1.8.tar.gz 7039961 BLAKE2B be2231a13036e2a5c925c7435ebce3adeea6ac03d9806d010d1c067b4e2d008f642a234fb80e082e5053332c6580d130f232ebe0b83d59c55977ea3a38364914 SHA512 fb8ad9ba2ac94a86261e2862d87d9ea632d2275c6cccf7d248ac95db96f615109add8803bf118625c828c7a2615fc6f20bcf682de1e4398f69add5eeb9fe8114
+DIST moto-5.1.9.tar.gz 7041662 BLAKE2B 8121c2022e5af70e71b6d4855ca7f964234ef06f14f8b08e80bd3676c26f6e9a06e8f469e610bcf2882b5468d613a17c3108aff3c344c12dc8331a9f9582b87b SHA512 986d41cc9fa875b5ee51723fdd7669b528dacb6136b6ebb3fa72d4efb3bb89f1fbc44aaa06aa154b80d44c87bca2d93cce30ee32c1ab7c3e8d622b53e011167d
diff --git a/dev-python/moto/moto-5.1.9.ebuild b/dev-python/moto/moto-5.1.9.ebuild
new file mode 100644
index 000000000000..51cda88e2043
--- /dev/null
+++ b/dev-python/moto/moto-5.1.9.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi toolchain-funcs
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/getmoto/moto/
+	https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.35.47[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-35.0.0[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-2.10.1[${PYTHON_USEDEP}]
+	dev-python/jsonpath-ng[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.25.6[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/sshpubkeys[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/antlr4-python3-runtime[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_RERUNS=5
+: "${EPYTEST_TIMEOUT:=180}"
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_dynamodb/test_dynamodb_import_table.py
+		# require joserfc
+		tests/test_apigateway/test_apigateway.py::test_create_authorizer
+		tests/test_apigateway/test_apigateway.py::test_delete_authorizer
+		tests/test_apigateway/test_apigateway.py::test_update_authorizer_configuration
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserDeleter::test_authenticate_with_signed_out_user
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_email_is_
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_username_
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_different_seed
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_same_seed
+		tests/test_cognitoidp/test_server.py::test_admin_create_user_without_authentication
+		tests/test_cognitoidp/test_server.py::test_associate_software_token
+		tests/test_cognitoidp/test_server.py::test_sign_up_user_without_authentication
+		# require py_partiql_parser
+		tests/test_dynamodb/test_dynamodb_statements.py
+		tests/test_s3/test_s3_select.py
+		# require graphql
+		tests/test_appsync/test_appsync_schema.py
+		# Internet
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_entire_service
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_specific_url
+		tests/test_core/test_request_passthrough.py::test_passthrough_calls_for_wildcard_urls
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+	)
+	local EPYTEST_IGNORE=(
+		# require joserfc
+		tests/test_cognitoidp/test_cognitoidp.py
+	)
+
+	if ! tc-has-64bit-time_t; then
+		einfo "time_t is smaller than 64 bits, will skip broken tests"
+		EPYTEST_DESELECT+=(
+			tests/test_acm/test_acm.py::test_request_certificate_with_optional_arguments
+			tests/test_s3/test_multiple_accounts_server.py::TestAccountIdResolution::test_with_custom_request_header
+			tests/test_s3/test_server.py::test_s3_server_post_cors_multiple_origins
+		)
+		EPYTEST_IGNORE+=(
+			tests/test_route53domains/test_route53domains_domain.py
+		)
+	fi
+
+	local -x TZ=UTC
+	local -x AWS_DEFAULT_REGION=us-east-1
+
+	rm -rf moto || die
+	epytest -m 'not network and not requires_docker'
+}
diff --git a/dev-python/narwhals/Manifest b/dev-python/narwhals/Manifest
index df63f34d258f..cc792ea42083 100644
--- a/dev-python/narwhals/Manifest
+++ b/dev-python/narwhals/Manifest
@@ -1,3 +1 @@
-DIST narwhals-1.47.1.tar.gz 516244 BLAKE2B 432b08ab90e596be515d46cba4fa7911ee6703aa80d71ea56fbb1af390ee30cb3c0d021a840c73cd6b533f3de7f4d430da28bab31530c7e4578deaca16148166 SHA512 f00a128007f32b765283b806f80063a538c402ca1082d626e48c8a536b193eb056fcd4b9ab828ccf44360cce5f72c64f1c77aeb39d7be9f8412f78eebb7db8c3
-DIST narwhals-1.48.0.tar.gz 515112 BLAKE2B 554c6d5e91762390a641e90d02f2e6a23e54fcff535a0a4757063ca2cd2b33046bfc3020d04dd983d0e7babd29a0585a026cf4b81a2cc265f1715019daf0864d SHA512 f2793a5ee0a99d0c339c24b707a2eb68b0445cef99c774058481c6b98e25c7bc2cf644f2c1ca19d74bfaddd750d5697fb843ec4eff0c61d42e6068ef20ecdbef
 DIST narwhals-1.48.1.tar.gz 515882 BLAKE2B 89e829161aeb3e7a986d26f11f0108c506c028d2f1685544913c47166865283b1ce62099562df1f85ebe5d4352e6f6d3eecd78da8d62a8a19fc9f8772995ebba SHA512 8096099844fe8042e53f5c8da39de5a843d94c892ef199d11f9ffe3b4ec58acea59d0160a11a51d9d347ddf7229ba997be093fa7e4bd9313e778ebc957da1d83
diff --git a/dev-python/narwhals/narwhals-1.47.1.ebuild b/dev-python/narwhals/narwhals-1.47.1.ebuild
deleted file mode 100644
index d2a95b1951d3..000000000000
--- a/dev-python/narwhals/narwhals-1.47.1.ebuild
+++ /dev/null
@@ -1,36 +0,0 @@
-# Copyright 2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Extremely lightweight compatibility layer between dataframe libraries"
-HOMEPAGE="
-	https://github.com/narwhals-dev/narwhals/
-	https://pypi.org/project/narwhals/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-
-BDEPEND="
-	test? (
-		>=dev-python/pandas-1.1.3[${PYTHON_USEDEP}]
-		>=dev-python/pyarrow-13.0.0[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=( hypothesis pytest-env )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-python_test() {
-	# make hypothesis more forgiving
-	local -x CI=1
-	epytest --runslow --constructors="pandas,pandas[nullable],pandas[pyarrow],pyarrow"
-}
diff --git a/dev-python/narwhals/narwhals-1.48.0.ebuild b/dev-python/narwhals/narwhals-1.48.0.ebuild
deleted file mode 100644
index d2a95b1951d3..000000000000
--- a/dev-python/narwhals/narwhals-1.48.0.ebuild
+++ /dev/null
@@ -1,36 +0,0 @@
-# Copyright 2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Extremely lightweight compatibility layer between dataframe libraries"
-HOMEPAGE="
-	https://github.com/narwhals-dev/narwhals/
-	https://pypi.org/project/narwhals/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-
-BDEPEND="
-	test? (
-		>=dev-python/pandas-1.1.3[${PYTHON_USEDEP}]
-		>=dev-python/pyarrow-13.0.0[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_PLUGINS=( hypothesis pytest-env )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-python_test() {
-	# make hypothesis more forgiving
-	local -x CI=1
-	epytest --runslow --constructors="pandas,pandas[nullable],pandas[pyarrow],pyarrow"
-}
diff --git a/dev-python/pymdown-extensions/Manifest b/dev-python/pymdown-extensions/Manifest
index e988cd308765..44f1a4188b1a 100644
--- a/dev-python/pymdown-extensions/Manifest
+++ b/dev-python/pymdown-extensions/Manifest
@@ -1 +1,2 @@
+DIST pymdown_extensions-10.16.1.tar.gz 853277 BLAKE2B 3cfe1511ead6abec9e5098fc7a1e9ccedadedda3d6cad67f5a4f835f12e009e5dc33fe19460bd79ed0beffc460c4c5139102f6fdbd1fc58db76c861122b16e0e SHA512 7fdb30f7e3df2f049fc4d88d0d588696a5fa588a1b67d2e4060797d555a2732efbaa661513e8323ff386604b5632a0d72cce29f1a61c9b418b8f460c3aa1b9ae
 DIST pymdown_extensions-10.16.tar.gz 853197 BLAKE2B 10379f3c41d72c8bb39bdc3d972e4dd1348d3fa2beacee9bf3a25dcd996139676b41b2cc65ffd6b6374d6921f9c841d27c1d5152fa7a1367359346a641b0bdf1 SHA512 042033b39190c156d6da7b30f07e6539c49c26e776ec75d79700b26f7204382bffff7d362b45a1d7110cf3c1a027031e9763dcd0de8978328aee2d0461014916
diff --git a/dev-python/pymdown-extensions/pymdown-extensions-10.16.1.ebuild b/dev-python/pymdown-extensions/pymdown-extensions-10.16.1.ebuild
new file mode 100644
index 000000000000..cc52511d518f
--- /dev/null
+++ b/dev-python/pymdown-extensions/pymdown-extensions-10.16.1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Extensions for Python Markdown"
+HOMEPAGE="
+	https://github.com/facelessuser/pymdown-extensions/
+	https://pypi.org/project/pymdown-extensions/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/markdown-3.6[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		>=dev-python/pygments-2.19.1[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
diff --git a/dev-python/pympress/Manifest b/dev-python/pympress/Manifest
new file mode 100644
index 000000000000..51ee2aa6454b
--- /dev/null
+++ b/dev-python/pympress/Manifest
@@ -0,0 +1 @@
+DIST pympress-1.8.6.tar.gz 237373 BLAKE2B 9de1c88c5338970859c1a81ee5a9b8ace9f1f7bdb47f6c214f993e911f0912e4ed2aee3577e6de72ed126e51bebf16612debf5fae45580f1f5ebb250d92bda70 SHA512 d6cd646132670139e0a8831c4e3806a194377d56f284a95f2bbe422d5c50f96f5c54022271b1abbc92d1ed23a1ba179b528ca343ebe8f9afdddce928e621978b
diff --git a/dev-python/pympress/metadata.xml b/dev-python/pympress/metadata.xml
new file mode 100644
index 000000000000..630b167a0b69
--- /dev/null
+++ b/dev-python/pympress/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>apn-pucky@gentoo.org</email>
+  <name>Alexander Puck Neuwirth</name>
+ </maintainer>
+ <longdescription lang="en">
+	Pympress is a PDF presentation tool designed for dual-screen setups such as presentations and public talks. Highly configurable, fully-featured, and portable.
+	</longdescription>
+ 
+ <use>
+  <flag name="vlc">Build with python-vlc bindings</flag>
+ </use>
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pympress/pympress-1.8.6.ebuild b/dev-python/pympress/pympress-1.8.6.ebuild
new file mode 100644
index 000000000000..5a0683f25ce8
--- /dev/null
+++ b/dev-python/pympress/pympress-1.8.6.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature pypi xdg-utils
+
+DESCRIPTION="A simple and powerful dual-screen PDF reader designed for presentations"
+HOMEPAGE="
+	https://github.com/Cimbali/pympress
+	https://pypi.org/project/pympress/
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="vlc"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	dev-python/watchdog[${PYTHON_USEDEP}]
+	app-text/poppler
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3
+	x11-libs/cairo
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	x11-libs/gdk-pixbuf
+	vlc? ( dev-python/python-vlc[${PYTHON_USEDEP}] )
+"
+BDEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	# >=python3_13 only works with >dev-python/pygobject-3.51
+	# https://github.com/Cimbali/pympress/issues/330
+	sed -i 's/ a_widget.props/ list(a_widget.props)/' pympress/builder.py || die
+}
+
+pkg_postinst() {
+	optfeature "gstreamer support" media-libs/gstreamer
+
+	# QA: update desktop database MIME=
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	# QA: update desktop database MIME=
+	xdg_desktop_database_update
+}
diff --git a/dev-python/pytest-mypy-plugins/Manifest b/dev-python/pytest-mypy-plugins/Manifest
index a09bb2ad314c..73a5d8660e22 100644
--- a/dev-python/pytest-mypy-plugins/Manifest
+++ b/dev-python/pytest-mypy-plugins/Manifest
@@ -1 +1 @@
-DIST pytest-mypy-plugins-3.1.0.gh.tar.gz 24331 BLAKE2B b4cae94e254f8da0ef8cd081479cbee4522150843ef3bbbd16ae6efe6722e44e84aa49e761e99699b75c94f8b44963e8f9eeefb5c5b3352411df4801a1bbc5b4 SHA512 4892b653b9cd2bbe5cd253c5f0472d48a6eaf5e1261d53ef0f1c53470c2589baf21d428a0873c64acca71eec38ef9653ec501e0746ffc564d30830ba68148f91
+DIST pytest-mypy-plugins-3.2.0.gh.tar.gz 25568 BLAKE2B 60143ea5316cb3efd1aa356123cd40b52e7883dc201c22f108e0f4fb3aa3e9aae296920a1422cb1f8084c7657c29c955f07892b09a643a88f9024f726209ab6f SHA512 3d5a6490b626f5dbb3f3c946f2ffbbb56cd0128b8234e9d98020d147e9f8f0841c76ca72f3cadb5ad568a5663e403417028fc07f85ec7f0e3a50b592bde734a7
diff --git a/dev-python/pytest-mypy-plugins/pytest-mypy-plugins-3.1.0.ebuild b/dev-python/pytest-mypy-plugins/pytest-mypy-plugins-3.2.0.ebuild
index 77a54073502a..8970c5133942 100644
--- a/dev-python/pytest-mypy-plugins/pytest-mypy-plugins-3.1.0.ebuild
+++ b/dev-python/pytest-mypy-plugins/pytest-mypy-plugins-3.2.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2023-2024 Gentoo Authors
+# Copyright 2023-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -22,31 +22,33 @@ KEYWORDS="~amd64"
 DOCS="README* CHANGELOG*"
 
 RDEPEND="
-	>=dev-python/mypy-1.3.0[${PYTHON_USEDEP}]
-	>=dev-python/pytest-7.0.0[${PYTHON_USEDEP}]
-	>=dev-python/tomlkit-0.11[${PYTHON_USEDEP}]
 	dev-python/decorator[${PYTHON_USEDEP}]
 	dev-python/jinja2[${PYTHON_USEDEP}]
 	dev-python/jsonschema[${PYTHON_USEDEP}]
+	>=dev-python/mypy-1.3.0[${PYTHON_USEDEP}]
 	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pytest-7.0.0[${PYTHON_USEDEP}]
 	dev-python/pyyaml[${PYTHON_USEDEP}]
 	dev-python/regex[${PYTHON_USEDEP}]
+	>=dev-python/tomlkit-0.11[${PYTHON_USEDEP}]
 "
 
+EPYTEST_PLUGINS=( ${PN} )
 distutils_enable_tests pytest
 
-python_prepare_all() {
-	# tests need pytest_mypy_plugins.tests on the modules search path and
-	# python -m pytest preprends sys.path with ${S}
-	sed "s/\"pytest\"/\"MY_EPYTHON\", \"-m\", \"pytest\"/" \
-		-i pytest_mypy_plugins/tests/test_explicit_configs.py || die
-	distutils-r1_python_prepare_all
-}
-
 python_test() {
-	# substitute the correct interpreter
-	sed "s/MY_EPYTHON/${EPYTHON}/" -i pytest_mypy_plugins/tests/test_explicit_configs.py || die
+	local EPYTEST_DESELECT=(
+		# circumvents our test setup by calling "pytest"; do the test manually
+		pytest_mypy_plugins/tests/test_explicit_configs.py
+	)
 	distutils-r1_python_test
-	# reset for next interpreter run
-	sed "s/${EPYTHON}/MY_EPYTHON/" -i pytest_mypy_plugins/tests/test_explicit_configs.py || die
+
+	local config= testfile="${S}"/pytest_mypy_plugins/tests/test-mypy-config.yml
+
+	for config in pytest_mypy_plugins/tests/test_configs/*{1,2}.toml; do
+		epytest --mypy-pyproject-toml-file "${config}" "${testfile}"
+	done
+	for config in pytest_mypy_plugins/tests/test_configs/*.{ini,cfg}; do
+		epytest --mypy-ini-file "${config}" "${testfile}"
+	done
 }
diff --git a/dev-python/types-protobuf/Manifest b/dev-python/types-protobuf/Manifest
index 164657a40098..f5b7a3ecd54b 100644
--- a/dev-python/types-protobuf/Manifest
+++ b/dev-python/types-protobuf/Manifest
@@ -1,2 +1 @@
-DIST types-protobuf-4.24.0.20240408.tar.gz 52102 BLAKE2B 3312ddd8e28ee490f6ae94978d5ebfca353cbd9051862629cdde08474ae657130bf87cda8cb06f33ea2d38ccb5bfe9097ef3d8f4bb77fba94707b9914ff33466 SHA512 adb4d69ef5d8bab15e6e311c7d1013725419f2b681e64befea2cc435fec69cf0d0e70431ae65b9f617e8b4c86957fdaae88abd57cc306fa55ad51d3c09d5f222
-DIST types-protobuf-5.27.0.20240626.tar.gz 54215 BLAKE2B 49f791cf6cc8cdc0b16172c2afc2f22eb15c8ecb73b89fa323779227e12105dd82fe316e58a2fa9b0421a3e91f0b8206e7b073cf0193a705be3cc339c53df525 SHA512 f7e572985639ef19b4a257e0bc2a931f4c745eb3c8f10d98ccd6c95133b0df3486b40b86418045b94854c46a26da510be1f63c524005580cf1446364aca4eade
+DIST types_protobuf-6.30.2.20250703.tar.gz 62300 BLAKE2B 7069a81619a04807cd1816171691d757f5e87c509a88502581e85f10250e7fee37976aad91e295d3b4e398e0d991874bbbebac138fbb3b2cbf0c45ca248c2c3b SHA512 45df568cecf47b1a30a29d0c49299c82112c67420248d336704e9c700b9510f2fabae843eb7c67e42d690a9686a106bc889d1f4e2bbb28e2f6a04a03270f86e8
diff --git a/dev-python/types-protobuf/types-protobuf-5.27.0.20240626.ebuild b/dev-python/types-protobuf/types-protobuf-5.27.0.20240626.ebuild
deleted file mode 100644
index 6bb64159befd..000000000000
--- a/dev-python/types-protobuf/types-protobuf-5.27.0.20240626.ebuild
+++ /dev/null
@@ -1,18 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYPI_NO_NORMALIZE=1
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-inherit distutils-r1 pypi
-
-DESCRIPTION="Typing stubs for protobuf"
-HOMEPAGE="
-	https://pypi.org/project/types-protobuf/
-	https://github.com/python/typeshed/tree/master/stubs/protobuf/
-"
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64"
diff --git a/dev-python/types-protobuf/types-protobuf-4.24.0.20240408.ebuild b/dev-python/types-protobuf/types-protobuf-6.30.2.20250703.ebuild
index 6bb64159befd..169420605f29 100644
--- a/dev-python/types-protobuf/types-protobuf-4.24.0.20240408.ebuild
+++ b/dev-python/types-protobuf/types-protobuf-6.30.2.20250703.ebuild
@@ -1,11 +1,10 @@
-# Copyright 2023-2024 Gentoo Authors
+# Copyright 2023-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
-PYPI_NO_NORMALIZE=1
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+PYTHON_COMPAT=( python3_{11..14} )
 inherit distutils-r1 pypi
 
 DESCRIPTION="Typing stubs for protobuf"