Adding metadata

30 files changed, 838 insertions, 1 deletions

diff --git a/dev-python/QtPy/QtPy-2.1.0-r2.ebuild b/dev-python/QtPy/QtPy-2.1.0-r3.ebuild
index ba6f89aab8ee..4098d8fc7319 100644
--- a/dev-python/QtPy/QtPy-2.1.0-r2.ebuild
+++ b/dev-python/QtPy/QtPy-2.1.0-r3.ebuild
@@ -29,7 +29,6 @@ unset _IUSE_QT_MODULES
 
 REQUIRED_USE="
 	|| ( pyqt5 pyside2 )
-	python_targets_python3_11? ( pyqt5 !pyside2 )
 "
 
 # These flags are currently *not* common to both the PySide2 and PyQt5 ebuild
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 5e2e320e18e8..1d5e97d14395 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,3 +2,4 @@ DIST boto3-1.24.12.gh.tar.gz 509573 BLAKE2B 5c9978cac1cbce0521dee6f2164652c4fca8
 DIST boto3-1.24.17.gh.tar.gz 511281 BLAKE2B 577efc0ebfb39957e55bcaf7aa678cdf072eed885ab1055b15fc8ca2295fedd6d56fd2fb919913beedcdd335ff26e452bc5434283c9ca9d8f0135080e2aa1312 SHA512 a843146951eb2a5ad7dd31159d833806ae403014abf3e9a617f6457e3ecec1a0dc4c6ce6a87079c9112513cbd6a2ccd26542e5736eeea6c5723c7e39c660befa
 DIST boto3-1.24.20.gh.tar.gz 512415 BLAKE2B c2196a9a518b0e4c0fb6e2382390d7d8e275d834a363856c266f696d57b5d56bf7f6a07df10d44670189098b19e0fcfad2a4907af10cd0d6361a5b2164bd6269 SHA512 cb4e426654895e26867a165304d03a722465441e10bf4dfd76fd7c5b45289785ba83f4f66c45d256a5ef6beb3cf5dfa923ea7479e99361344288ad98350a68a6
 DIST boto3-1.24.21.gh.tar.gz 513083 BLAKE2B 1de0405823b6b33efcb11316a3c400180fa3f9064a63023e2f13d6ae18fb6e60ac229ba11c8eb93901d4a6ca65aa32e9ff576b421ffbb6e75476149e93df4d2e SHA512 4f278cbe0bffd2107354aaa76ef7e725a8ea3fcf1688614203204b495be596405fcb0add790922ab09858d94798bc06076c9160f42ff20b855b8a31859c57bc4
+DIST boto3-1.24.22.gh.tar.gz 513301 BLAKE2B 1b71d128cc8f8224fd1ef521988e6b5e941562c256c2769941340f6a9e3342394f9e2cf20d658bc4b0e9f5ddaebc832ae8fdc96e35e348b73631ca01f0be33a6 SHA512 eb64a050c1b63da823fad2b10db828fefbf75a95ae1f222576eabb8efa80cbbb3e54862dfd40813a8d58f9c329f4d95595bbebc172bcf0141c241499af7d4726
diff --git a/dev-python/boto3/boto3-1.24.22.ebuild b/dev-python/boto3/boto3-1.24.22.ebuild
new file mode 100644
index 000000000000..e4a98e2e28f5
--- /dev/null
+++ b/dev-python/boto3/boto3-1.24.22.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 7705241255ae..b4f42378baa2 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,3 +2,4 @@ DIST botocore-1.27.12.tar.gz 9132872 BLAKE2B 74b74b5a5745cfacac066d5e087974fb58b
 DIST botocore-1.27.17.tar.gz 9130505 BLAKE2B 04c6b37f3b42a0f9fb696b5213338b004418a68c754f5027ad447119fb20556dc49bd53f40fd9560ea3f5bdcf2afbe151dba68e901079baec770f9f223b1a894 SHA512 b1a145d3c97adfd4df40639da99e1c34087508be189d5818ee7176f20454f2897a6f518a14b4bfbf41cb169a17188bec467337c10d0ad511e223f0c1ff5b64ee
 DIST botocore-1.27.20.tar.gz 9146126 BLAKE2B 3ec9e6480fb5bc95f72ffa1f0972b7d9e807fce2e69a3118818a7eba5c1023316c9499bdcbc2f6b2616842eb8797ed0b2bef5ebceee5b74a12074b927b339994 SHA512 1ac0b189e14fb25f07c63e4933113ca64c2bdc53fe719270daccc55b2c7d8ba7421fa81aa60e6fc3a0c86cdb3f57980781388586ce154d87f17f860cc943467a
 DIST botocore-1.27.21.tar.gz 9149425 BLAKE2B fa7141f78128ebc4810bf51bcca93a23606ef611721fd1a32ca490a9e38aef86439385bd7a0465e82a853c5bb7596dffb0b17fc5d7015fb5039f4933ab1554f1 SHA512 59bdf83b237e3845f48685919a6330846d2a4d7ce12d15d99cdb8dd9f2d3e0dcc0d1641c52de8d6d9ef7b7202b80bc59070cb1786f1b38c20884e0fa32481432
+DIST botocore-1.27.22.tar.gz 9151155 BLAKE2B e3aa6e9814e07bca2bd67d16f6548303af71654021b28f13c43b4005ba24a32cfccffa9a145babb781a6cbff9df3eab7de4c18973c00b3861ba83264eb144537 SHA512 57e43577840c62556760ff40d820898b0ee1efeb5da39fbdfe8c7ef53e86c8184bdfed5a52eeb9d0652fa053900462bdad9820b4a34bd4b5231f361b89c710d6
diff --git a/dev-python/botocore/botocore-1.27.22.ebuild b/dev-python/botocore/botocore-1.27.22.ebuild
new file mode 100644
index 000000000000..1f52e2694e84
--- /dev/null
+++ b/dev-python/botocore/botocore-1.27.22.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/fixtures/Manifest b/dev-python/fixtures/Manifest
index 717b04dcbdca..57c4aa1aec1b 100644
--- a/dev-python/fixtures/Manifest
+++ b/dev-python/fixtures/Manifest
@@ -1 +1,2 @@
 DIST fixtures-4.0.0.tar.gz 56786 BLAKE2B 7fa8916d3e384a47c967b51ffeebb81c50c4be7432601aa94f220b6ae32ed189f16750cb126c2925995c2e945684c48041014a97902145343527e8856125b61a SHA512 dcd67c3df9efc16f2a21b6d2917a5b7e45ecc09d1ddbd1de98a5b4b717ea7da0fc82e1054f494255b419a792e841145110c77a1772444f4019fc02e9917c5b80
+DIST fixtures-4.0.1.tar.gz 56752 BLAKE2B bddda3976ec453129fa05e53da066344ed8f4db9626ec21dd0159e6720993da0c17e3b51ba37de2ef05cd7649809d674cc6409b16c8e1d242dc424d573010975 SHA512 722436f146768e4db1e3312a0db1edab2a7daa86107825fb2436654eaf74e00f569357531316df506ef3f80cef89ac7185aee1adf0b00a6ee85cbc9811ca8100
diff --git a/dev-python/fixtures/fixtures-4.0.1.ebuild b/dev-python/fixtures/fixtures-4.0.1.ebuild
new file mode 100644
index 000000000000..53c813193e67
--- /dev/null
+++ b/dev-python/fixtures/fixtures-4.0.1.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pbr
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Fixtures, reusable state for writing clean tests and more"
+HOMEPAGE="
+	https://github.com/testing-cabal/fixtures/
+	https://pypi.org/project/fixtures/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( Apache-2.0 BSD )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/pbr-5.7.0[${PYTHON_USEDEP}]
+	>=dev-python/testtools-2.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/imagesize/Manifest b/dev-python/imagesize/Manifest
index 71e78e0de0a7..5fd0680db284 100644
--- a/dev-python/imagesize/Manifest
+++ b/dev-python/imagesize/Manifest
@@ -1 +1,2 @@
 DIST imagesize-1.3.0.tar.gz 1279535 BLAKE2B 926b90ad493b790db41941467dd2dd0385f86064fc1ce9547670a52f925965effc9b8b7f61057158a4452cac2223b65dbfaecc34a19ddaf52067a9057560b56a SHA512 3686e513f03cc16f5237ca206cd1bf131eea968015ee4906f620ab1c8932ed24d19881807225a02fa319d0465da4b01851ec0bd0a47146ef914053185bc0c755
+DIST imagesize-1.4.1.tar.gz 1280026 BLAKE2B 9293f56277e40a1ad74a96b2857e46535fd5bd320ab7dee48432762206f29b4f78e64d8713e19ea26c3f405ab6905ded3b04273d04e781f512e981bfe83e3f8c SHA512 f191d7fe34a01ab21b0f4f6519df8ab2a53c1ca54956f4d825d9cec5bd5f4c569491bdc26cb36fcaad2c453c35e51f69379f091362e206453aaefbda4802daa4
diff --git a/dev-python/imagesize/imagesize-1.4.1.ebuild b/dev-python/imagesize/imagesize-1.4.1.ebuild
new file mode 100644
index 000000000000..53886780a6cd
--- /dev/null
+++ b/dev-python/imagesize/imagesize-1.4.1.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure Python module for getting image size from png/jpeg/jpeg2000/gif files"
+HOMEPAGE="
+	https://github.com/shibukawa/imagesize_py/
+	https://pypi.org/project/imagesize/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-solaris"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires Internet
+	test/test_get_filelike.py::test_get_filelike
+)
diff --git a/dev-python/iminuit/Manifest b/dev-python/iminuit/Manifest
index 58d9c3acf719..0db0c8a7018f 100644
--- a/dev-python/iminuit/Manifest
+++ b/dev-python/iminuit/Manifest
@@ -1,2 +1,3 @@
 DIST iminuit-2.11.2.tar.gz 411984 BLAKE2B 8fa47b24890f26718ebb8f053c2f908d982a7b6cc7f71f6523f387128ab0bd894bb851f18e2f8611ff5ab1c113651f526893445f465fbbfa10d487dc15effcbd SHA512 b60755f21ae38bd19860e0d711bab9c6e37dd361cc8cf43bdd1a583e8c06abca38e42ae0a6c4631be05c5082c9ab169bddb51e4d84397ce8f81833fd4c46cdd7
 DIST iminuit-2.12.0.tar.gz 420687 BLAKE2B 9d3761bd756f58a7c36a61f161e4667f8efbb6edef9bb1882fcd324efe46aaec126dbfb4b692a5b7f56a1f162cb292c9e58a0d3337ae04a019756455bc0df1e9 SHA512 1697c04722323506bbe43682befe1b6020656348c98fec0a877ea8403390e741ea106d61d95e31595d894b020025606b413b2f185fd747b2b7d733b729919fe1
+DIST iminuit-2.12.1.tar.gz 420488 BLAKE2B 8910017f27d683b5129a506c7536def9b70b3dac27153985023f81bc94fb767c33f0a9fb4c8ac6911634839fd3870ac3bb63ddbf0cd8925b68778983c341354b SHA512 2b54ebb3c66eb508e848fbedae32aac32a82d794da899d10848d683b7a97b7882014e77b1e98be3563b0e96957208072f048e8df23a8c14f5e3b472eae5b5f23
diff --git a/dev-python/iminuit/iminuit-2.12.1.ebuild b/dev-python/iminuit/iminuit-2.12.1.ebuild
new file mode 100644
index 000000000000..aeaeffc6c6f4
--- /dev/null
+++ b/dev-python/iminuit/iminuit-2.12.1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+# forced implicitly
+CMAKE_MAKEFILE_GENERATOR=emake
+inherit cmake distutils-r1 virtualx
+
+DESCRIPTION="Minuit numerical function minimization in Python"
+HOMEPAGE="https://github.com/scikit-hep/iminuit/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="MIT LGPL-2.1"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	epytest -p no:pytest-describe || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/lxml/Manifest b/dev-python/lxml/Manifest
index 074412d4bb7e..c3b7f271d87b 100644
--- a/dev-python/lxml/Manifest
+++ b/dev-python/lxml/Manifest
@@ -1,2 +1,3 @@
 DIST lxml-4.8.0.tar.gz 959376 BLAKE2B a40be5e058153e1dc3f8501b645b0211f4498928ed71b161df54a67501356e9968064401b6d17e17dc8d62223b29e794eaa2bee7ff78ffee203d9f9a22f3e1c2 SHA512 bbcd8ea001cfa2820dcac4e00de6ded81700b2f0bd4a58bcdd4da05a19a107f57cd56280c4838fe19ee7ecd6be105878bf8c2f1c0e5111899c4ad1a2ba03537f
 DIST lxml-4.9.0.gh.tar.gz 960537 BLAKE2B c1ffa82f74ae1876c39d94fe248ab0278d30b805081fef92b9cc9ccf28dc10d239a3ee1861a5603deda1f1ae2c4eb288a66019281010459f6320b1000bea1955 SHA512 fb88b2e9d92972de69c1f8b54529ea00364b8b72475a2a88c9c509e4fb8cfbf0ced1bc093f96ae60c1d275ee9a8e5a5d2f51472ecce3d706a1cb1299789f9495
+DIST lxml-4.9.1.gh.tar.gz 960663 BLAKE2B bb464757f9188a76661732d237f3b0f9010f51dd9c5426b578ca8fdb486d28fcfec81d4dd817b2fa0601ed9d7890e01ce71e4ea4c842b92e59dd5437200bad22 SHA512 f52d54908f92997f610638a9a3054cb73723ae81a5ad9e77918b0603ec7441b0e7d2143f8a8ac66c05cd6a0b3b298d348397b7e2df19f83c21e336514c47d910
diff --git a/dev-python/lxml/lxml-4.9.1.ebuild b/dev-python/lxml/lxml-4.9.1.ebuild
new file mode 100644
index 000000000000..b7cd9122c7a9
--- /dev/null
+++ b/dev-python/lxml/lxml-4.9.1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature toolchain-funcs
+
+DESCRIPTION="A Pythonic binding for the libxml2 and libxslt libraries"
+HOMEPAGE="
+	https://lxml.de/
+	https://pypi.org/project/lxml/
+	https://github.com/lxml/lxml
+"
+SRC_URI="https://github.com/lxml/lxml/archive/${P}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/lxml-${P}
+
+LICENSE="BSD ElementTree GPL-2 PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples +threads test"
+RESTRICT="!test? ( test )"
+
+# Note: lib{xml2,xslt} are used as C libraries, not Python modules.
+DEPEND="
+	>=dev-libs/libxml2-2.9.12-r2
+	>=dev-libs/libxslt-1.1.28"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+	>=dev-python/cython-0.29.29[${PYTHON_USEDEP}]
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/docutils[${PYTHON_USEDEP}]
+			dev-python/pygments[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+		')
+	)
+	test? (
+		dev-python/cssselect[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.6.0-tests-pypy.patch
+)
+
+python_check_deps() {
+	use doc || return 0
+	has_version -b "dev-python/docutils[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/pygments[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+	has_version -b "dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]"
+}
+
+python_prepare_all() {
+	# avoid replacing PYTHONPATH in tests.
+	sed -i -e '/sys\.path/d' test.py || die
+
+	# don't use some random SDK on Darwin
+	sed -i -e '/_ldflags =/s/=.*isysroot.*darwin.*None/= None/' \
+		setupinfo.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	tc-export PKG_CONFIG
+	distutils-r1_python_compile
+}
+
+python_compile_all() {
+	use doc && emake html
+}
+
+python_test() {
+	local dir=${BUILD_DIR}/test$(python_get_sitedir)/lxml
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	cp -al "${BUILD_DIR}"/{install,test} || die
+	cp -al src/lxml/tests "${dir}/" || die
+	cp -al src/lxml/html/tests "${dir}/html/" || die
+	ln -rs "${S}"/doc "${dir}"/../../ || die
+
+	"${EPYTHON}" test.py -vv --all-levels -p || die "Test ${test} fails with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		local DOCS=( README.rst *.txt doc/*.txt )
+		local HTML_DOCS=( doc/html/. )
+	fi
+	if use examples; then
+		dodoc -r samples
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Support for BeautifulSoup as a parser backend" dev-python/beautifulsoup4
+	optfeature "Translates CSS selectors to XPath 1.0 expressions" dev-python/cssselect
+}
diff --git a/dev-python/nbclient/Manifest b/dev-python/nbclient/Manifest
index 0c5646226a51..de17a04694c4 100644
--- a/dev-python/nbclient/Manifest
+++ b/dev-python/nbclient/Manifest
@@ -1,3 +1,4 @@
 DIST nbclient-0.6.3.tar.gz 77571 BLAKE2B 41b96f8c174506a97b257b352e2614f023785137bf79d57d9bd4fd38942b54cc9db97bdf63c65579e67f88afd57ff81cbc798880080842e981797ee07be9f441 SHA512 bf267f3f49289cadcce412dc772f01dab5cd4d5a4ceb3fa12b076357d04191a15573d540773d47d58a14570fe219a9591ab539b917b52f3f7a902aac0493ba82
 DIST nbclient-0.6.4.gh.tar.gz 78101 BLAKE2B 91a653eb1735fe1a43044f18da773bcb0c4afd485fe7bfd3630c8c6a80776c9ff7e4cb08130c4e3953f03832933c429e68d7383677d8e56c54b485d55b8c5469 SHA512 a953b40b314ce104b28dfb9178a004ca4726d8a5912c84c168bf71527ee224082d3910f11040b172b6e62683493978b9b10161b69cadbca48a5652a4f98b5009
 DIST nbclient-0.6.5.gh.tar.gz 78170 BLAKE2B 690eb6c9b70d43210da013b7f0a2cd7e0ae76bd737dd9860df555c95f91e167c17dc6bbf54a73f98c2cff37d8f69d7246d3a3a6c45a33ce4187c498e6fcb81b1 SHA512 1dabd799c3b0f51c5158c58ebdad6f13662a2970b863a9414731fb7a9c4268ebd83c86fdc11d5de25f2998b6b847bd62d0d227b2bb38440618f583b4fa2d4e87
+DIST nbclient-0.6.6.gh.tar.gz 78247 BLAKE2B 06793fe792dcb8606d74e85a7a5c4d8f3ba850f81191bf205706e404e67bfe3d6914dff5790c5d6dca62d7797482518b5d87b06da34f06a5cb44a8a0ff6855e4 SHA512 8ca0333a47920994d8afe7c8943b366d4669e7ad91daab1a36c57480b70e51dfd05c7cd44acd2a2005b8c0a6b41c4fe6be0fc22b75a3efe291e9c35dd334643c
diff --git a/dev-python/nbclient/nbclient-0.6.6.ebuild b/dev-python/nbclient/nbclient-0.6.6.ebuild
new file mode 100644
index 000000000000..d813ead69722
--- /dev/null
+++ b/dev-python/nbclient/nbclient-0.6.6.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A client library for executing Jupyter notebooks"
+HOMEPAGE="
+	https://nbclient.readthedocs.io/en/latest/
+	https://github.com/jupyter/nbclient/
+	https://pypi.org/project/nbclient/
+"
+SRC_URI="
+	https://github.com/jupyter/nbclient/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/jupyter_client-6.1.5[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.0[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.2.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+		dev-python/xmltodict[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	'nbclient/tests/test_client.py::test_run_all_notebooks[Interrupt.ipynb-opts6]'
+)
diff --git a/dev-python/phonenumbers/Manifest b/dev-python/phonenumbers/Manifest
index 8e87b1c7e1e7..7f6bacefa2b2 100644
--- a/dev-python/phonenumbers/Manifest
+++ b/dev-python/phonenumbers/Manifest
@@ -1,2 +1,3 @@
 DIST python-phonenumbers-8.12.49.gh.tar.gz 4904202 BLAKE2B 20974162d5a8668c1d15021de71795983c4eda1f3afc931822b3593c80249481bcb4ea9f8b80066a71f7f2821284534991d3307eddea0e8f0270e75eced0573e SHA512 0504a84b3a6047c7ca4bc1667a0418d60c7f43052911751572820e7f4e40b430b8847e4c8f6e4d88dd7a2684b5ad8de2dfda8891d81fd8e1af1c595be152f9fc
 DIST python-phonenumbers-8.12.50.gh.tar.gz 4904755 BLAKE2B 60353aa081e4d4d0909302a97a45a89c1f94aac323a6a68fd93cd67146090189d0901b947c40e80e54e1718ce4a45c4a83d2799701ff1323666e82570174d358 SHA512 7a4406626d04a85e010036ceca20430a2562939ad8e7e2651afd65f0d5eb26feb1fbbe0c11f081ab58a9ab8bd81da2ccc153ad22f12eb8135b4f604077b5b29d
+DIST python-phonenumbers-8.12.51.gh.tar.gz 4903034 BLAKE2B 6d97e25c3601f817ad51eb8dac550fec4a13799dd9321235c9105386ca2a1ab3a7fa6403f31643197a5a2f162be50edf6b3705c8947098f2d9ff744f6af1dab6 SHA512 80f5ad4356e31bc505c929a8bb9b577ed1571b9173e7f8faebe972f62c16f5a5d764eab5e3bd8aa939faae2c4ebbe2b0fa11a5f2e6fe334be98148a68881c912
diff --git a/dev-python/phonenumbers/phonenumbers-8.12.51.ebuild b/dev-python/phonenumbers/phonenumbers-8.12.51.ebuild
new file mode 100644
index 000000000000..ec95c5a695a3
--- /dev/null
+++ b/dev-python/phonenumbers/phonenumbers-8.12.51.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+MY_P=python-${P}
+DESCRIPTION="Python port of Google's libphonenumber"
+HOMEPAGE="
+	https://github.com/daviddrysdale/python-phonenumbers/
+	https://pypi.org/project/phonenumbers/
+"
+SRC_URI="
+	https://github.com/daviddrysdale/python-phonenumbers/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}/python
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		dev-python/protobuf-python[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( ../README.md )
+
+python_test() {
+	"${EPYTHON}" testwrapper.py -v || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index 672af6b4061d..e73a55dc8b3e 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1 +1,2 @@
 DIST pillow-9.1.1.tar.gz 49753799 BLAKE2B 969a338f768951c340177d0590c50ba1213f48810870ac3fdbc2556c57344e356e0cf1ef080bde29bf89291adbf9f64b2dd1f950260d2ce5c0eb28d197f2dfe2 SHA512 8c05c0af6be992667d764046c6d7c189e1486d6ab987474c15e3bc8a64b9955d4c91d94b94ea46ef6d1c6f343ba424240dfa7d758c666bec40fa580728206a5f
+DIST pillow-9.2.0.gh.tar.gz 50018953 BLAKE2B 72dc1175c08276531c5949f0eb19bdce37afb25303614d489375c57aba19c5f708db7d149a033490f95848bdd6b4249dd36993205069e7f471a2efd602cb3ac4 SHA512 02926d6c88aa8bc0df05b0ecd04b9852821a6400a24c6e70b66d4092eb3174139dee116adfa94ba8b7f3df8f6725cc68b32705f308f4347153e0112d987fc5f2
diff --git a/dev-python/pillow/pillow-9.2.0.ebuild b/dev-python/pillow/pillow-9.2.0.ebuild
new file mode 100644
index 000000000000..ba7893b52ee4
--- /dev/null
+++ b/dev-python/pillow/pillow-9.2.0.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 toolchain-funcs virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="
+	https://python-pillow.org/
+	https://github.com/python-pillow/
+	https://pypi.org/project/Pillow/
+"
+SRC_URI="
+	https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples imagequant +jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
+REQUIRED_USE="test? ( jpeg jpeg2k tiff truetype )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	imagequant? ( media-gfx/libimagequant:0 )
+	jpeg? ( media-libs/libjpeg-turbo )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2= )
+	tiff? ( media-libs/tiff:0=[jpeg,zlib] )
+	truetype? ( media-libs/freetype:2= )
+	webp? ( media-libs/libwebp:0= )
+	xcb? ( x11-libs/libxcb )
+	zlib? ( sys-libs/zlib:0= )
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/olefile[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		${RDEPEND}
+		dev-python/defusedxml[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		|| (
+			media-gfx/imagemagick[png]
+			media-gfx/graphicsmagick[png]
+		)
+	)
+"
+
+EPYTEST_DESELECT=(
+	# TODO; incompatible Qt version?
+	Tests/test_qt_image_qapplication.py::test_sanity
+)
+
+usepil() {
+	usex "${1}" enable disable
+}
+
+python_configure_all() {
+	# It's important that these flags are also passed during the install phase
+	# as well. Make sure of that if you change the lines below. See bug 661308.
+	cat >> setup.cfg <<-EOF || die
+		[build_ext]
+		disable_platform_guessing = True
+		$(usepil truetype)_freetype = True
+		$(usepil jpeg)_jpeg = True
+		$(usepil jpeg2k)_jpeg2000 = True
+		$(usepil lcms)_lcms = True
+		$(usepil tiff)_tiff = True
+		$(usepil imagequant)_imagequant = True
+		$(usepil webp)_webp = True
+		$(usepil webp)_webpmux = True
+		$(usepil xcb)_xcb = True
+		$(usepil zlib)_zlib = True
+	EOF
+
+	# setup.py won't let us add the right toolchain paths but it does
+	# accept additional ones from INCLUDE and LIB so set these. You
+	# wouldn't normally need these at all as the toolchain should look
+	# here anyway but it doesn't for this setup.py.
+	export \
+		INCLUDE="${ESYSROOT}"/usr/include \
+		LIB="${ESYSROOT}"/usr/$(get_libdir)
+
+	# We have patched in this env var.
+	tc-export PKG_CONFIG
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	"${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+	# no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
+	epytest -p no:relaxed || die "Tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	python_doheader src/libImaging/*.h
+	distutils-r1_python_install
+}
+
+python_install_all() {
+	if use examples ; then
+		docinto example
+		dodoc docs/example/*
+		docompress -x /usr/share/doc/${PF}/example
+	fi
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/setuptools_scm/Manifest b/dev-python/setuptools_scm/Manifest
index 9b100fb5d944..fb543185697f 100644
--- a/dev-python/setuptools_scm/Manifest
+++ b/dev-python/setuptools_scm/Manifest
@@ -2,3 +2,4 @@ DIST setuptools_scm-6.4.2.tar.gz 61305 BLAKE2B e1b5191425cf5db8334761a6857b0bc39
 DIST setuptools_scm-7.0.1.tar.gz 67921 BLAKE2B 15a4a8953bb9cf8754fe465b53e11483ade33b09c5b407f096ecbdaed80081fa554e0c6da1accdbc629163019bf91968f4edae40166dc4598b25e0a51c5881d1 SHA512 49d296ca4af3175c47a385d9d935fe32371d39c31ff4e6d704ea6fc8dd512e7ed6b0136677e7768836c0ec2ae558c47f156adc5975ace30a396fa81644e61acb
 DIST setuptools_scm-7.0.2.tar.gz 68142 BLAKE2B 11bc3db134c3ee90b9262cf663036a6119a559e134b479a42e10c4b54005029c0e192d92e32d14f8d2dee2d09258b9cbebe9b45f07b553507b80ac7f2ecee110 SHA512 c9782a1b5bbfaaab2bbfc223477e92e8ee2fb0b2a393ff912f0c54fb99494d1c014a4e6c103a3f852d335733b02bcaa3b15eed8ec3a5c1ef54c4691fba7cb0de
 DIST setuptools_scm-7.0.3.tar.gz 70341 BLAKE2B dea8fcdb3cafb040dd2bcdc5efeb8bcba1906d35fee83b17646e1df10a4fee642a01df7d115d66e93c1c177c2ddfa0f4260fb9fe9bf54d24955c3c7014611d35 SHA512 511cff1d00601e535ef4abb14189b7a965003b77b630578c6306758946d45e9140f9a0cdf9a02b915d829f92fcc3460a49091ad2971dec783016f952cff1d326
+DIST setuptools_scm-7.0.4.tar.gz 70512 BLAKE2B 07acfccdbeb0c7f6a6773ff93fa10c35aa8cc2451ede42cce269e2278606fed4acd17e8fda8294ac84b596e776a5ba02ae5ef1203dff42738291798e624cd991 SHA512 cdd1f36fab5b0fa9c1f3dc42c57ee732fbc7b39e761b2db3047c9e953ddc28dd6bbc29b44451e77f602c4ea39469af86a7b08d2d6ab1513b938193e000c3c04e
diff --git a/dev-python/setuptools_scm/setuptools_scm-7.0.4.ebuild b/dev-python/setuptools_scm/setuptools_scm-7.0.4.ebuild
new file mode 100644
index 000000000000..38403f15478a
--- /dev/null
+++ b/dev-python/setuptools_scm/setuptools_scm-7.0.4.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Manage versions by scm tags via setuptools"
+HOMEPAGE="
+	https://github.com/pypa/setuptools_scm/
+	https://pypi.org/project/setuptools-scm/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/tomli[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-vcs/git
+		!sparc? (
+			dev-vcs/mercurial
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fetching from the Internet
+	testing/test_regressions.py::test_pip_download
+
+	# the usual nondescript gpg-agent failure
+	testing/test_git.py::test_git_getdate_signed_commit
+
+	# broken by... pbr?
+	testing/test_integration.py::test_pyproject_support
+)
diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index cb87e9176b21..73f725a10533 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1,2 +1,3 @@
 DIST translate-3.6.2.gh.tar.gz 1152569 BLAKE2B 44c9a5878a177b53d34e48d8b642f293ed475c90de8a530f53462384420b8afaaf107cb62c0cdd45e6d0633f53cd8eedb73dd0dcd81d6f876dc5389ba4230c94 SHA512 fb1fc2f6abb766814269d7051f571cbfb25ecd6b7267e2080e5ab0bb41338ace430a8bb01084abe176e2fd0a934cdf6492bf79f5e27c1f8ce99b021175efcec9
 DIST translate-3.7.0.gh.tar.gz 1152162 BLAKE2B 75d3b0a7f2a840766f983d6e1484aab16de2aa2bab74d0753910be9ad0d1c76ebfa553188318920a7d5a6f1ce6b72e755147eb45c501cdeb79246472c0329449 SHA512 18159f85d94768c32fe5a44f3d3e586038b281a0f3e386621bd57a5be64a9ae21a4272c05de8a2ea2a2467c98935205a8ef49a714dc9aabf9ed21de4f533fb93
+DIST translate-3.7.1.gh.tar.gz 1152674 BLAKE2B c4a7d8cb1eec656a261a1af145a1171e9d686348294a0849f29ae23dcd867d831c6f95f0927101325f62ef9b21e0891a7a574f08111bbc3e9c0ce2b996faa70c SHA512 5ed9d156f071f4ce567a0ff3f0ef5c0b42b312edaae82e96eee040ae9547f0cb3334f2973d8050b9181b752f7e81021cc183613bb5c6309aeb110bcacab212fb
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.7.1.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.7.1.ebuild
new file mode 100644
index 000000000000..6a5bb58373a4
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-3.7.1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+MY_P=translate-${PV}
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="
+	https://github.com/translate/translate/
+	https://pypi.org/project/translate-toolkit/
+"
+SRC_URI="
+	https://github.com/translate/translate/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+
+RDEPEND="
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-bootstrap-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+	)
+	local EPYTEST_IGNORE=(
+		# unpackaged fluent.*
+		translate/storage/test_fluent.py
+	)
+
+	if ! use ini; then
+		EPYTEST_IGNORE+=(
+			translate/convert/test_ini2po.py
+			translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		EPYTEST_IGNORE+=(
+			translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index 2ed7be8fe675..f468126de127 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1,2 +1,3 @@
 DIST trimesh-3.12.5.gh.tar.gz 10755276 BLAKE2B ced596c4182b085df8c59bc007977aebb94702edd364ed67ee0114376b235fe020bbeee130853e1e0fbabd1f1d0f6523faaf268ffba1b4c7c30f3f794b64e51b SHA512 d467bd6ceb5b567182ac80ea38374f28b85b9ab983edf98428e09c8f799c206d23e282c03c808227c92e2dcb37f3faabea8d5db74b8ac419265751bcbaa396e1
 DIST trimesh-3.12.6.gh.tar.gz 10755102 BLAKE2B 69336781530f0195c71e65d67ba3362314ad39c3dd349e9b88174136d85b3f72c5e64c93a0ca64572c1595292e2b241bea6552c1e33671fea48bc0aa42f21d13 SHA512 2c6d64ba3307cb50148f345db0f6fbf8f94838ba2171698fad31b2d26205860afa98cc803ccf7264422ca3cad65cb8cddb0f55dfac45f430d012a4579d5c08de
+DIST trimesh-3.12.7.gh.tar.gz 10756892 BLAKE2B af1f40b5de1eb60ec3241d342b3ed99fc7dc5e906c71a7669578e539d7c45ab4b037038423efb324cc462dc34a8ac1d1a8134f6b775f1965f2512acd76a8af14 SHA512 35f8039e46f55a3b2e713249d66a658ef48eb8c4a0a6e196f34933fc28052ad0a73953cc4736377bb7b79606ea08b78b132bb9d709fc50da11b2e96aa0e231e6
diff --git a/dev-python/trimesh/trimesh-3.12.7.ebuild b/dev-python/trimesh/trimesh-3.12.7.ebuild
new file mode 100644
index 000000000000..faf7151e2296
--- /dev/null
+++ b/dev-python/trimesh/trimesh-3.12.7.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 multiprocessing optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimsh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/msgpack[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	sci-libs/rtree[${PYTHON_USEDEP}]
+	>=sci-libs/shapely-1.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -n "$(makeopts_jobs)"
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" sci-libs/scikit-image
+}
diff --git a/dev-python/typing-extensions/Manifest b/dev-python/typing-extensions/Manifest
index 3e8a84d01ada..cf73a3a08e83 100644
--- a/dev-python/typing-extensions/Manifest
+++ b/dev-python/typing-extensions/Manifest
@@ -1 +1,2 @@
 DIST typing-extensions-4.2.0.gh.tar.gz 77169 BLAKE2B 3b7e91d0b410daf749d61213e8dc2bce069c05db7626a6c3a380fe1955ad97871f3c90782a8ba5114b11c42e0775558fd6fb1fd28a7cc0fbf2ec97480ef72298 SHA512 52e67eaeb3159e5effdcf180fc43d9881453c7efc00546335a8f31d5f7ab9859c2f89b29612861015ba490cdfd596720aa577630b424323256930b036b119776
+DIST typing_extensions-4.3.0.gh.tar.gz 47842 BLAKE2B 23a600dcded95a1109da46537bab49a6a478c77334d7c9effe65564bf236371c413a07220df3fa1de1bd0451e90961df908e097e7c7cb6d2534102369ce2590e SHA512 3c4a9073dc89e71b8027d535853d35725163961f7feeaba817e28f93b236bcae805d9b1f6e2be8e9fc3651c283b662935ba0352e5de25ff74df4dc18373e8f7a
diff --git a/dev-python/typing-extensions/typing-extensions-4.3.0.ebuild b/dev-python/typing-extensions/typing-extensions-4.3.0.ebuild
new file mode 100644
index 000000000000..bf10c744f869
--- /dev/null
+++ b/dev-python/typing-extensions/typing-extensions-4.3.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/-/_}
+DESCRIPTION="Backported and Experimental Type Hints for Python 3.7+"
+HOMEPAGE="
+	https://pypi.org/project/typing-extensions/
+	https://github.com/python/typing_extensions/
+"
+SRC_URI="
+	https://github.com/python/typing_extensions/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
+
+python_test() {
+	cd "${S}"/src || die
+	"${EPYTHON}" test_typing_extensions.py -v || die "tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/untangle/Manifest b/dev-python/untangle/Manifest
index 6dfdf4d8abdf..5c81cda5ecc1 100644
--- a/dev-python/untangle/Manifest
+++ b/dev-python/untangle/Manifest
@@ -1 +1,2 @@
 DIST untangle-1.1.1.tar.gz 3089 BLAKE2B d8b8ffe1adb2acbcdcde8e6f67231315b9f318c9e8e1496dfa23b0ac6dd68651e75e2d2e67f6d7d521002ad6b0e9c4cc30c155685b9df60b6b223d137add0632 SHA512 252c3d0ed8d004660adad8f37a179a4d1b2b46e9d7127aee59b596eac3f65684a7a8b5b881bec97ddaf5470aa678df407b903209eaa069a40f53dc2dde9a94b2
+DIST untangle-1.2.0.gh.tar.gz 23772 BLAKE2B b93edbd704d2e2664628de2496cd4bf9057501585155bb21dcabe0e56506e697afa11999d2f607119eb3b2a274721a1e29de16ca914391a4e6720b92b964b12c SHA512 83e34702385e69ee172042644fc2d50196e2cbeb403b7a06385e3e3fa701bb132807742453994f724df4bf85fd0915d73ec618c57f4c47995039fa15bb578007
diff --git a/dev-python/untangle/metadata.xml b/dev-python/untangle/metadata.xml
index edbf614f1086..f779b78a9efd 100644
--- a/dev-python/untangle/metadata.xml
+++ b/dev-python/untangle/metadata.xml
@@ -5,6 +5,10 @@
   <email>sci@gentoo.org</email>
   <name>Gentoo Science Project</name>
  </maintainer>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
  
  <origin>gentoo-staging</origin>
  <stabilize-allarches/>
diff --git a/dev-python/untangle/untangle-1.2.0.ebuild b/dev-python/untangle/untangle-1.2.0.ebuild
new file mode 100644
index 000000000000..5092c7f70c18
--- /dev/null
+++ b/dev-python/untangle/untangle-1.2.0.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Convert XML documents into Python objects"
+HOMEPAGE="
+	https://github.com/stchris/untangle/
+	https://pypi.org/project/untangle/
+"
+SRC_URI="
+	https://github.com/stchris/untangle/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_tests pytest