Adding metadata

21 files changed, 559 insertions, 133 deletions

diff --git a/dev-python/autopep8/Manifest b/dev-python/autopep8/Manifest
index d083b5c0a704..efa2b05aa64a 100644
--- a/dev-python/autopep8/Manifest
+++ b/dev-python/autopep8/Manifest
@@ -1,3 +1,4 @@
 DIST autopep8-2.1.0.tar.gz 88891 BLAKE2B 60bd5e9a177d8bdb741b37884bb3ef170fb59664b740beb1b1f38df021dfb7916f2cecdb2e20b6363c2abcc110f9f36902dbccd7f06ddf56f090ccb36149fb19 SHA512 f694a506646b4bc4932fb07cf1c989897e7db3fc9b65dc90886fa657b163dfcbad4c16bb911a2e399a4623b167b313d32213762d3e21e20bff27b6fe2a5abc59
 DIST autopep8-2.1.1.tar.gz 91009 BLAKE2B fa324c2c2e827a4bd5c3f60e0fbb83419055a5b0ced7c737b590cdfba9c43f6517ac659bc77212d9694530d42d6ea4c9af642acf5074d514b32a11c62dcc3688 SHA512 cfa9927e44d40d778405fa1a49385c40b79dd425d945ec5053510c594e783f98aaaf083ad53a07b04cf929eac9b274c5a37c8a1256ebb83d897364d40fc9eba0
 DIST autopep8-2.1.2.tar.gz 91299 BLAKE2B a38ed72306d77a517b2f510e46941aa2fe572b4d51e9c8ee9c817798d5e1db964c0f2f436de9be22553557335a9291074870694ca4ac1e054b4cfd9de9db71a5 SHA512 296f3463f5a7088029e4a6cfefcf9b93a8be1798e6c81818d362d801b97d76bb107619c7724d9f1557006223e9514bc5044f2cec24d8c896c7e420431eb2252d
+DIST autopep8-2.2.0.tar.gz 91723 BLAKE2B 6d00f689752cb134e11e46bbb617d274afbacb30f4f337270cfd00aa9a4dc1cd6f3754a1b0c53986d0350821475b91126ae14bb2464f25fa5f24afb9f9c13c73 SHA512 2a2441e742b3172c011dc142d8d24c439c17fc9b3733c0fc161d30914e1cea50b45c85a66e20c435a828629f1cd1e3f699c1b1a102db0bf721efe8b1e7c91c43
diff --git a/dev-python/autopep8/autopep8-9999.ebuild b/dev-python/autopep8/autopep8-2.2.0.ebuild
index 4ccf6207369a..af2966e33e91 100644
--- a/dev-python/autopep8/autopep8-9999.ebuild
+++ b/dev-python/autopep8/autopep8-2.2.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -7,26 +7,20 @@ DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
 PYTHON_REQ_USE="threads(+)"
 
-inherit distutils-r1
+inherit distutils-r1 pypi
 
 DESCRIPTION="Automatically formats Python code to conform to the PEP 8 style guide"
 HOMEPAGE="
 	https://github.com/hhatto/autopep8/
 	https://pypi.org/project/autopep8/
 "
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="https://github.com/hhatto/${PN}.git"
-	inherit git-r3
-else
-	inherit pypi
-	KEYWORDS="~alpha ~amd64 ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
-fi
 
 LICENSE="MIT"
 SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
 
 RDEPEND="
-	>=dev-python/pycodestyle-2.10[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.11.0[${PYTHON_USEDEP}]
 	$(python_gen_cond_dep '
 		dev-python/tomli[${PYTHON_USEDEP}]
 	' 3.10)
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 92ad5c1f2ac3..6642de6afe95 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.34.108.gh.tar.gz 809808 BLAKE2B 56d21fdc35917426ea94f27ee4c7a59bc9e
 DIST boto3-1.34.113.gh.tar.gz 812031 BLAKE2B ffb4cc54a83d9d783eb69694393a6cc8c4d07325496802de80e8ac1999a1b5f45166571ae52eb8b38cb7d3e58d0cc8114088f7cd698f090b6ab1244565c0af63 SHA512 eebde25a83b2a7169b6892fa61475f26f9bf6baf7eff242d8bde0a5cd1920a7a39107071b093e59aca2a742662e16825b7fcf2850f59840da63a9cf78a19615d
 DIST boto3-1.34.114.gh.tar.gz 812014 BLAKE2B fd11639c03d8b5a106af0781d71bc10f185aadeeb27aa5cd62fb6c005e4fa57eb1cbfa544c4940817e4ac28a085ff6c6aaa77d4a9ef19928f605e21b93ff7984 SHA512 3f4ace4460d467a490e885bd1e523799495e83dcc51815ddd7ca77a7ba054057763fa9f13f5c6c89e2603be880d7d85b5ac0ae523c05a016285bf8dd9b3e1f29
 DIST boto3-1.34.115.gh.tar.gz 812507 BLAKE2B d53ec48e920333c02d637d9f2fa9276ec52dc5384c3b2b85a1e6395b331528f3b71232ba45cf9b2b66512fb7e8caedbddd1d6bfcb4a420994477fb992f9d4872 SHA512 63859d9f7a0d07a479286c12fb5873cf1d0de6e27e5e6cf6d1450d0d238b5520606bda3dc5dbd559432a2c68350e6f12cf85dd094c505d27d4ddbe4e7ebe6fce
+DIST boto3-1.34.116.gh.tar.gz 813371 BLAKE2B e49855120e6d7e5b9888429d135299975c69769f139ba33f522427af06a2370026cfda3f60c61860b86828230081fbef057609d1d2d33d66b7371105f44dfa1f SHA512 d5e59325d95ce1fdb5492fc14ac949fbd98ba33eafc078bd990420afff80cec6dffeef15239558b2a8bfdac385a35393101fb1f796cfd5aaa14fc936eec8dfa7
diff --git a/dev-python/boto3/boto3-1.34.116.ebuild b/dev-python/boto3/boto3-1.34.116.ebuild
new file mode 100644
index 000000000000..509842b2699d
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.116.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 78da13ad4828..7702ff236950 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.34.108.gh.tar.gz 13029228 BLAKE2B 947c11bb991e9e7622412bb7e90579
 DIST botocore-1.34.113.gh.tar.gz 13060395 BLAKE2B 8f9329d613f489f2305d068566940a94199a16e9d538597a86cd916a331245a70c6ad771f0d7d71a05a77a49c86aa8ff6be2ac6cd97c04828cc9f54cb6c5e2ac SHA512 218656c921b7ae6a605d6cca4cb90b76aee2a18541e78189828f2adfbb821fbebac406ba19887c0a07aece72dd4936f41b057fb25611e1b03db4bd11fda66bd6
 DIST botocore-1.34.114.gh.tar.gz 13062423 BLAKE2B 3d72a66466da0f2979bb8a6a47b7a732df048755eee3f2de4e44753aac1a2155502ed106ba5378e04b12d77fff1ee1c0f2baf317487a33a18645eca81e07f89a SHA512 183c91714f50a68e20663dde9cdd101d919c368fa8e0e95d4b71d89d0a560b2b0cac591d884b894de0b310cef5fa65784b288f21bb044c5e4ec196d81d645a6c
 DIST botocore-1.34.115.gh.tar.gz 13066625 BLAKE2B d894c358515f6c3b65cc4f562ac0afbf95efb7829bc8987d27be927b447f84e118d861f06df84b4f49e9b66ddd5f74ae94550419017cb9c8346d36498279c92e SHA512 82720ce84bc9ffafffc73bde5ae0033a5696c63f92d1c48538b2c257500e3f3597d0d44ab1d9e378917f59c1be085c9649b946512bf87175a1e8edb997b195f6
+DIST botocore-1.34.116.gh.tar.gz 13074946 BLAKE2B a6d660beabfee65becff832f32c4a6a0908b5acbb7b9cc66f1fac987e2a33840f467907cf65d07a9dabc54a1ccc32d3437cf997e3c3d10a46441906d515c9157 SHA512 82e89462b15e5e46c97289ae7c99a7254b98357fe5cc65072c5c25652dba5ff90097a96385b4bc869d80f94c5cdf7f93402383e4e4371b445140ecfde52d56e6
diff --git a/dev-python/botocore/botocore-1.34.116.ebuild b/dev-python/botocore/botocore-1.34.116.ebuild
new file mode 100644
index 000000000000..857224b496b7
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.116.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/findimports/Manifest b/dev-python/findimports/Manifest
index dfe7f92f1b1e..89d5625bb736 100644
--- a/dev-python/findimports/Manifest
+++ b/dev-python/findimports/Manifest
@@ -1 +1,2 @@
 DIST findimports-2.4.0.gh.tar.gz 26597 BLAKE2B 8dc176a551a07f38996ddbcf0df865ad7c7c1c7f86036be0939578a932155f30bdff17d2880063edd49ae1d169ebfb5bbade771a626859ad8306d54df743ee79 SHA512 90dfc39a5f73ea86a9d5c3ebec0f220f2f428f5768edc9688c47079f555b44abb80b4945b38550032289a3bff659f3857019a50882b1b2f2e83570f3e36530be
+DIST findimports-2.5.0.gh.tar.gz 26899 BLAKE2B 0050f0f711c3deb449993f8a50f484076005d5956275ba62ea55150c40b04540c3a2d656188da3d02775de71fc2d29f24b0855e91f160d491e384880b0b39043 SHA512 f75c9312c888fb456fe73983a2790f6e6841fd76692f7bce6e6d2e7c85e7055ee9d982af1b7cc8490de47dd2957ba1f74234698a519c36982dcb92bea6894301
diff --git a/dev-python/findimports/findimports-2.5.0.ebuild b/dev-python/findimports/findimports-2.5.0.ebuild
new file mode 100644
index 000000000000..07088c98d5a9
--- /dev/null
+++ b/dev-python/findimports/findimports-2.5.0.ebuild
@@ -0,0 +1,27 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python module import analysis tool"
+HOMEPAGE="
+	https://github.com/mgedmin/findimports/
+	https://pypi.org/project/findimports/
+"
+SRC_URI="
+	https://github.com/mgedmin/findimports/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+python_test() {
+	"${EPYTHON}" testsuite.py -v || die
+}
diff --git a/dev-python/jupyter-server/Manifest b/dev-python/jupyter-server/Manifest
index 1dc07fc31ac6..88d1041b7c03 100644
--- a/dev-python/jupyter-server/Manifest
+++ b/dev-python/jupyter-server/Manifest
@@ -1 +1,2 @@
 DIST jupyter_server-2.14.0.tar.gz 719491 BLAKE2B 6a742c2b4a269a23af7c54e72d551045cc17b017efe88e0cb5848aff9d9a9d0855c74ed066b316bb87d15f49984cc5787250b6191f036c8ae8bd0af7a6b53695 SHA512 57258afae5e64af6b499795795c469fd08fb2562da770ba06b78716dccee12f6662b0d6465739857aa5f3fea084eb2d8553c7205edc7b6813e4f5d61815917b3
+DIST jupyter_server-2.14.1.tar.gz 719107 BLAKE2B 2b38fbc709346bdb8c2734dd5f22cf958f0555660af0df23b08b6af8b3dee9130daa0538b7e78c5a0c63d66511a973babbb544c638d1aed267368ebba7d10c36 SHA512 1770fe0fc34c164952a74b75bf765fc737ab59cc52c04f61c0a28d5f6c747587ddee4c6cd3dcb90e2ccb72029d0f52de321569ed7a55bddbad50326e728b53fd
diff --git a/dev-python/jupyter-server/jupyter-server-2.14.1.ebuild b/dev-python/jupyter-server/jupyter-server-2.14.1.ebuild
new file mode 100644
index 000000000000..70043430f00a
--- /dev/null
+++ b/dev-python/jupyter-server/jupyter-server-2.14.1.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Core services, APIs, and REST endpoints to Jupyter web applications"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter-server/jupyter_server/
+	https://pypi.org/project/jupyter-server/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/argon2-cffi-21.1[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.3[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7.4.4[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-core-5.1.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-server-terminals-0.4.4[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-events-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-6.4.4[${PYTHON_USEDEP}]
+	>=dev-python/nbformat-5.3.0[${PYTHON_USEDEP}]
+	>=dev-python/overrides-5.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+	>=dev-python/prometheus-client-0.9[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24[${PYTHON_USEDEP}]
+	>=dev-python/send2trash-1.8.2[${PYTHON_USEDEP}]
+	>=dev-python/terminado-0.8.3[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.2[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.6.0[${PYTHON_USEDEP}]
+	>=dev-python/websocket-client-1.7[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		>=dev-python/pytest-jupyter-0.7[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# This fails if your terminal is zsh (and maybe other non-bash as well?)
+		tests/test_terminal.py
+		# Fails because above is ignored
+		tests/auth/test_authorizer.py
+		# Fails with additional extensions installed
+		tests/extension/test_app.py::test_stop_extension
+	)
+
+	# FIXME: tests seem to be affected by previously installed version
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest \
+		-p pytest_tornasync.plugin \
+		-p jupyter_server.pytest_plugin \
+		-p pytest_console_scripts \
+		-p pytest_timeout \
+		-o tmp_path_retention_policy=all
+}
diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 4be010b50edb..fefb01aa44c0 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -3,3 +3,4 @@ DIST moto-5.0.5.tar.gz 5188450 BLAKE2B 052cb9cbc5752ce46283f4d3fd43e92ba3a492437
 DIST moto-5.0.6.tar.gz 5212834 BLAKE2B 8bd5734c0c7615e2ca42f715e8865989ce8a07a2733dbc8f9bce3d3c8e4718543cbbc37cc342620ecf51df64f23c21f237f32a56f165f751472bd2b793140606 SHA512 41a29faf5a206690197315693a91d0e9a71ccb24dbbd790f568502d91a0b40cad0fbea60f6af75412f4e6cb11da00677db24dfc9c3d0a884533b39e4904e2ec3
 DIST moto-5.0.7.tar.gz 5239975 BLAKE2B 8227b2d002308ffc402f949d1c858c3d42098897332ee8973ba47ea0e5d447446a1521a66640bcea5159724362c3e377b50bad3954927832d1deacbc32c1b957 SHA512 167e2388453af29f3f6be92354c33c09f20fd3c6743a790d396759237fcc463a6b9030b0d523e6cec8d04ac83630a0a2a259290473a87daeb1f4d7d2ef3cae62
 DIST moto-5.0.8.tar.gz 5255012 BLAKE2B f9b6d619d69fac0c451c9b224626d69df188f4c8238809ef5e2af0eb5f7b14a13906e2e0998e5e88516d864e6201bde6dfd46f3657c0fa5550dabe661f3c4c51 SHA512 5e6f26cc1850623244c45115a0cd7aeab70218967b249da165afe7cd40ea7bde57a6284a89f5ebc1c41f565dbf674a517017233fc90056f581206318b12a4b95
+DIST moto-5.0.9.tar.gz 5256902 BLAKE2B a817d42f05d8b2fa65585ac5f0404f995bb4b6ca7d70305db0d12cc526745c4af1c36ac2067af33d2b688a7076dff7eb6bdad117c38ac54c873e7149a3e8a1bf SHA512 44ac3a91a759105db5bd48950a7b19d3df9612b41b4062eb7df08bb864e99f982731ae973b24a7c5547c0fd47e07a703c21be7260730983abad46d154c9f7742
diff --git a/dev-python/moto/moto-5.0.9.ebuild b/dev-python/moto/moto-5.0.9.ebuild
new file mode 100644
index 000000000000..20ce1f880740
--- /dev/null
+++ b/dev-python/moto/moto-5.0.9.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="
+	https://github.com/getmoto/moto/
+	https://pypi.org/project/moto/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-0.93[${PYTHON_USEDEP}]
+	dev-python/boto3[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cfn-lint-0.40.0[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	>=dev-python/docker-3.0.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/openapi-spec-validator-0.5.0[${PYTHON_USEDEP}]
+	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.15.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/sshpubkeys[${PYTHON_USEDEP}]
+	dev-python/typing-extensions[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_firehose/test_firehose_put.py::test_put_record_http_destination
+		tests/test_firehose/test_firehose_put.py::test_put_record_batch_http_destination
+		# broken code (local variable used referenced before definition)
+		tests/test_appsync/test_appsync_schema.py
+		# Needs network (or docker?) but not marked as such, bug #807031
+		# TODO: report upstream
+		tests/test_awslambda/test_lambda_layers_invoked.py::test_invoke_local_lambda_layers
+		tests/test_batch/test_batch_jobs.py::test_cancel_pending_job
+		tests/test_batch/test_batch_jobs.py::test_cancel_running_job
+		tests/test_batch/test_batch_jobs.py::test_container_overrides
+		tests/test_batch/test_batch_jobs.py::test_dependencies
+		tests/test_batch/test_batch_jobs.py::test_failed_dependencies
+		tests/test_batch/test_batch_jobs.py::test_failed_job
+		tests/test_batch/test_batch_jobs.py::test_submit_job_array_size
+		tests/test_batch/test_batch_jobs.py::test_terminate_job
+		tests/test_batch/test_batch_jobs.py::test_terminate_nonexisting_job
+		tests/test_cloudformation/test_cloudformation_custom_resources.py::test_create_custom_lambda_resource__verify_cfnresponse_failed
+
+		tests/test_cloudformation/test_cloudformation_stack_integration.py::test_lambda_function
+		tests/test_core/test_docker.py::test_docker_is_running_and_available
+		tests/test_core/test_request_passthrough.py
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_aws_and_http_requests
+		tests/test_core/test_responses_module.py::TestResponsesMockWithPassThru::test_http_requests
+		tests/test_events/test_events_lambdatriggers_integration.py::test_creating_bucket__invokes_lambda
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events0-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events1-ObjectCreated:Put]"
+		"tests/test_s3/test_s3_lambda_integration.py::test_objectcreated_put__invokes_lambda[match_events3-ObjectCreated:Put]"
+		# TODO
+		tests/test_sqs/test_sqs_integration.py::test_invoke_function_from_sqs_queue
+		tests/test_sqs/test_sqs_integration.py::test_invoke_function_from_sqs_fifo_queue
+		# require py_partiql_parser
+		tests/test_s3/test_s3_select.py
+		tests/test_dynamodb/test_dynamodb_statements.py
+		# require joserfc
+		tests/test_apigateway/test_apigateway.py::test_update_authorizer_configuration
+		tests/test_apigateway/test_apigateway.py::test_create_authorizer
+		tests/test_apigateway/test_apigateway.py::test_delete_authorizer
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserDeleter::test_authenticate_with_signed_out_user
+		No
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_email_is_
+		-
+		tests/test_cognitoidp/test_cognitoidp_exceptions.py::TestCognitoUserPoolDuplidateEmails::test_use_existing_email__when_username_
+		-
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_different_seed
+		No
+		tests/test_cognitoidp/test_cognitoidp_replay.py::TestCreateUserPoolWithPredeterminedID::test_same_seed
+		tests/test_cognitoidp/test_server.py::test_sign_up_user_without_authentication
+		tests/test_cognitoidp/test_server.py::test_admin_create_user_without_authentication
+		# TODO
+		tests/test_dynamodb/test_dynamodb_import_table.py
+		# hangs
+		tests/test_core/test_account_id_resolution.py::TestAccountIdResolution::test_environment_variable_takes_precedence
+	)
+	local EPYTEST_IGNORE=(
+		# require joserfc
+		tests/test_cognitoidp/test_cognitoidp.py
+		# require antlr4 (which doesn't support py3.12)
+		tests/test_stepfunctions/parser
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x TZ=UTC
+
+	local serial_tests=(
+		# these tests set up credentials that are needed by the tests below
+		tests/test_core/test_importorder.py
+		# these tests apparently rely on some other test setting credentials
+		# up for them, so they need to be run separately, after the above
+		tests/test_awslambda_simple/test_lambda_simple.py::test_run_function{,_no_log}
+		tests/test_dynamodb/exceptions/test_dynamodb_exceptions.py
+		tests/test_dynamodb/exceptions/test_dynamodb_transactions.py::test_transaction_with_empty_key
+		tests/test_dynamodb/test_dynamodb.py::test_transact_write_items_failure__return_item
+		tests/test_dynamodb/test_dynamodb.py::test_transact_write_items_put_conditional_expressions
+		tests/test_dynamodb/test_dynamodb_update_expressions.py::test_update_different_map_elements_in_single_request
+		tests/test_events/test_events.py::test_start_replay_send_to_log_group
+		tests/test_lakeformation/test_resource_tags_integration.py
+		tests/test_redshiftdata
+		tests/test_resourcegroupstaggingapi/test_server.py::test_resourcegroupstaggingapi_list
+		tests/test_s3/test_s3.py::test_delete_bucket_cors
+		tests/test_s3/test_s3.py::test_delete_objects_percent_encoded
+		tests/test_s3/test_s3.py::test_delete_versioned_bucket_returns_metadata
+		tests/test_s3/test_s3_copyobject.py::test_copy_key_boto3_with_args
+		tests/test_s3/test_s3_copyobject.py::test_copy_key_boto3_with_args__using_multipart
+		tests/test_s3/test_s3_file_handles.py::TestS3FileHandleClosuresUsingMocks
+		tests/test_s3/test_s3_list_object_versions.py
+		tests/test_s3/test_s3_tagging.py
+		tests/test_s3control/test_s3control_access_points.py::test_delete_access_point
+		tests/test_utilities/test_threaded_server.py::TestThreadedMotoServer::test_server_can_handle_multiple_services
+		tests/test_utilities/test_threaded_server.py::TestThreadedMotoServer::test_server_is_reachable
+	)
+
+	EPYTEST_XDIST= epytest "${serial_tests[@]}"
+
+	EPYTEST_DESELECT+=( "${serial_tests[@]}" )
+	epytest -m 'not network'
+}
diff --git a/dev-python/nose2/Manifest b/dev-python/nose2/Manifest
index c34908cab7f9..cafff1507ec3 100644
--- a/dev-python/nose2/Manifest
+++ b/dev-python/nose2/Manifest
@@ -1 +1,2 @@
 DIST nose2-0.14.2.tar.gz 167874 BLAKE2B b2d1d1d026de10e9d73a312205b0562c377775016b8adea0b64213cb32930e9a58823021fa970f23e8acd79d2ea2a3df1f294732fcb2f96c454a2345f65091db SHA512 728d6c3f1c037630b6b3a4fc3012a488d91dfdcef5fe1d1f6473b317f71ac6ba16a33d33721de7422caec019eac00137e95190eb2c98edd67c4c5f7f8ee09440
+DIST nose2-0.15.0.tar.gz 168825 BLAKE2B fc61b1be549cc725a05825cc801b23fa3055b13f745f63c5a1929b87724691001cf743248cb9606b6ae11b32090b99de0e583dac175141a6a6c9e5efb5a16099 SHA512 e0c1287aec4092fba55814bca8f5ac867d2ac0f9c9da15d6eb955007050b7e4beb2f211d049acc4dce9fa9990bc42468d01f2945cc358127295b60f9a5f998a6
diff --git a/dev-python/nose2/nose2-0.15.0.ebuild b/dev-python/nose2/nose2-0.15.0.ebuild
new file mode 100644
index 000000000000..4d2b9fef90a0
--- /dev/null
+++ b/dev-python/nose2/nose2-0.15.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Unittest with plugins"
+HOMEPAGE="
+	https://github.com/nose-devs/nose2/
+	https://pypi.org/project/nose2/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/coverage-4.4.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme \
+	dev-python/sphinx-issues
+
+python_test() {
+	"${EPYTHON}" -m nose2.__main__ -vv || die "tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/spotipy/Manifest b/dev-python/spotipy/Manifest
index 9f7c8f6e6543..5160ee4ef54c 100644
--- a/dev-python/spotipy/Manifest
+++ b/dev-python/spotipy/Manifest
@@ -1 +1,2 @@
 DIST spotipy-2.23.0.gh.tar.gz 112399 BLAKE2B 5510ce35624c561df61fffee78f211dfa91ff8d5b3dc15d37c96a51bf830e67aac9c6a0787c71715bee17a3ba91b84766c1ecec37d5775f2182617f2b74a2cb3 SHA512 52955fa3365d5153f19f60874ce8e96910ac8db783499e0e2ef2ab31127277844e24a045115dc522dd7b7535f7907de56da87e02a63b94ee7506b75c1e108e9b
+DIST spotipy-2.24.0.gh.tar.gz 114822 BLAKE2B 0db73d723c1cb3818d68cfa90fd8077c6d6eb82b16f24e087907091d74644b86431aa93ea5ed9a842ec674c16f67cddc5be17a3b6cfcb92d0c01aa8bd3d1529f SHA512 9860119f078ff894a9b27bb4d51cd7b469c2cea4981757338d8c3f1c6c8a1c0bbb3b79622820486c07f0b86ce4e26f9329635b51fc976c4cee43122b9a0209ff
diff --git a/dev-python/spotipy/spotipy-2.24.0.ebuild b/dev-python/spotipy/spotipy-2.24.0.ebuild
new file mode 100644
index 000000000000..a2b3ea036a90
--- /dev/null
+++ b/dev-python/spotipy/spotipy-2.24.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="A lightweight Python library for the Spotify Web API"
+HOMEPAGE="
+	https://spotipy.readthedocs.io/
+	https://github.com/spotipy-dev/spotipy/
+	https://pypi.org/project/spotipy/
+"
+SRC_URI="
+	https://github.com/spotipy-dev/spotipy/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/redis[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	dev-python/redis \
+	dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Internet
+	tests/unit/test_oauth.py::TestSpotifyClientCredentials::test_spotify_client_credentials_get_access_token
+)
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	use examples && dodoc -r examples
+}
diff --git a/dev-python/sqlglot/Manifest b/dev-python/sqlglot/Manifest
index 0f419359b342..4b95b3666366 100644
--- a/dev-python/sqlglot/Manifest
+++ b/dev-python/sqlglot/Manifest
@@ -19,9 +19,8 @@ DIST quote-1.0.33.crate 28090 BLAKE2B 77c4b166f1200e1ee2ab94a5014acd334c1fe4b7d7
 DIST redox_syscall-0.4.1.crate 24858 BLAKE2B c3301137a0b84e03b09d28dfa377ab3bea74d574a08cee21d35713b278d8b5b30ca2a1d73a0981baeb4644cbb88c86c8eb15ab3bb2692e38b93e6b35fab4e0da SHA512 073ed9d96090cf46eab9877742277a013c62d8da86d9caf2310b4fa868af306511936553579e01309f27067d344226cc8dc5e3aef01d9b900da2febd33848f8d
 DIST scopeguard-1.2.0.crate 11619 BLAKE2B 8b7e9ed6cefef9ee55407fb9690d57a2a98bb93e5105aeebdb475a52485e9e185255249e1dce8f83cd80534e7402d485aac3efa7e8493b13135de27550cd4bc4 SHA512 6247719a15fe1e4e2d179127b9a934bd2f99367724f41175ed9522f58824b6bc69b35002eae66b35880375ff61d77ac43ddaa78cbde7160a35183a1da32d3fbb
 DIST smallvec-1.11.2.crate 34801 BLAKE2B 58645e99db8f02db64d02c75860c7ea41836c427c03ee3b0b23365e73a406e4fd6ac312bf13fc5faef8bb6111c10fcfd5f839d5b3686e9b34d1626f8469fc327 SHA512 5cfb427c3b99b0dbd71f6154ed899abcde9d7d2992977ac7b2ef3a4c3ff51e4efafd133071a69609b4ed6cb269bdc26b79eb72e1988f10dfcaef8185d950cd1d
-DIST sqlglot-24.0.1.tar.gz 18650459 BLAKE2B 96069393d5e9f05644d7352b701f74c9da157656d4cf9504557a004c0a288fa23b477bf1c50038b0dc14911e05d4da0b93da101d161eedcdc274c7f02daea17a SHA512 d1fcf7839fa8fdcb8cba311c6aad6b588619d75275b80483d2adc6fa8162e288abc7f3f410570c81bd50c3ac6d9429e85d93e1b4e5a01700c5249c8e85339817
-DIST sqlglot-24.0.2.tar.gz 18685998 BLAKE2B 82b08e1de59ff4d2f8ad8760693a9223c8a9431e943640d2a97453eb66d0af0dc7a3979ac61a26d8d3ca834614c1469716bea059176aace45f2a3e3c0824f522 SHA512 01fa975b0d2d09bac87f3bcf7e39dbc733979d098adffd42c65f83ad7a8d81c48b5b327a8a244a4efbcca3924cf3fe7d3addc99a544d7f4ac446e3f85f52010b
 DIST sqlglot-24.0.3.tar.gz 18699657 BLAKE2B 263092d5646f3f29c8f1251102623c37257a678f5837ca374576ce96ab49ec6db030bdfacd34bf729119faea995a5698e7952c381880f5e0616c60260f525aba SHA512 765449ead2e3561970c4e77d80dab9449ae283a6d214b8eb7386f82c0eee2a60869ecd1a0e9453640786fbda3bea5550a3856bef1dc73a7fcf0500b318c79dae
+DIST sqlglot-24.1.0.tar.gz 18704713 BLAKE2B 2ea8b2bec6c3e4237cfa0e1310da744555ef18f46cb5a0ead83e50a53fea1857094acb6422be638c18fc935650bf522d987f97eb71883a41b2cb3e6279d5ac59 SHA512 f0379cba95cf2e17cde6a010f651285bdace7619a51e4bc4260388966682d41cc65215405dbe5e33cc34aab8c3c088de5bb9c44baf4c9290aa3725ca89cb5dc2
 DIST syn-2.0.41.crate 246016 BLAKE2B 9d389f2e2a0acb4c84c309456e8ffcc88c5d4d541535ed136832d7a6054dde45a598bb68e8a6f3062ca2a96e1ceae947d54b3aec9bad65b0c51d6733aa6c80db SHA512 6bbaf69ca783025dfb81ac3612ac60bfbed31b2d87792909b35c12892dadebdaff2ddf9463105e536b671dce5870610ab90fe29471284bbd3014dca8d6993f1a
 DIST target-lexicon-0.12.12.crate 25156 BLAKE2B f3803596c75f6c89438592a1176c3748fc2c0524d7d50a20056de1cd26d40c572b05bafcdf6dd702752864bea37c8b4f28f96dadc12a5b3bb1d279b25e489f85 SHA512 6147295c43ba1b7b087a3c5ab51534b2985e4e77e5e15687978cfb9d07e21c4fd9bc7191576d6cabd268d08a44dc733c4a957e59dba8b948c2055d8bb433aeca
 DIST unicode-ident-1.0.12.crate 42168 BLAKE2B 4cede03c08758ccd6bf53a0d0057d7542dfdd0c93d342e89f3b90460be85518a9fd24958d8b1da2b5a09b5ddbee8a4263982194158e171c2bba3e394d88d6dac SHA512 bc1824e1e4452a40732fc69874d7e1a66f7803717a314790dcf48867eba34bc9441331ef031e386912e52c385645c25b6ed39d4f149973b5b97371b1b96b1920
diff --git a/dev-python/sqlglot/sqlglot-24.0.2.ebuild b/dev-python/sqlglot/sqlglot-24.0.2.ebuild
deleted file mode 100644
index c040bab3734b..000000000000
--- a/dev-python/sqlglot/sqlglot-24.0.2.ebuild
+++ /dev/null
@@ -1,121 +0,0 @@
-# Copyright 2023-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_EXT=1
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
-
-CARGO_OPTIONAL=1
-CRATES="
-	autocfg@1.1.0
-	bitflags@1.3.2
-	cfg-if@1.0.0
-	heck@0.4.1
-	indoc@2.0.4
-	libc@0.2.150
-	lock_api@0.4.11
-	memoffset@0.9.0
-	once_cell@1.19.0
-	parking_lot@0.12.1
-	parking_lot_core@0.9.9
-	proc-macro2@1.0.70
-	pyo3-build-config@0.20.0
-	pyo3-ffi@0.20.0
-	pyo3-macros-backend@0.20.0
-	pyo3-macros@0.20.0
-	pyo3@0.20.0
-	quote@1.0.33
-	redox_syscall@0.4.1
-	scopeguard@1.2.0
-	smallvec@1.11.2
-	syn@2.0.41
-	target-lexicon@0.12.12
-	unicode-ident@1.0.12
-	unindent@0.2.3
-	windows-targets@0.48.5
-	windows_aarch64_gnullvm@0.48.5
-	windows_aarch64_msvc@0.48.5
-	windows_i686_gnu@0.48.5
-	windows_i686_msvc@0.48.5
-	windows_x86_64_gnu@0.48.5
-	windows_x86_64_gnullvm@0.48.5
-	windows_x86_64_msvc@0.48.5
-"
-
-inherit cargo distutils-r1 pypi optfeature
-
-DESCRIPTION="An easily customizable SQL parser and transpiler"
-HOMEPAGE="
-	https://sqlglot.com/
-	https://github.com/tobymao/sqlglot/
-	https://pypi.org/project/sqlglot/
-"
-SRC_URI+="
-	native-extensions? (
-		${CARGO_CRATE_URIS}
-	)
-"
-
-LICENSE="MIT"
-LICENSE+=" native-extensions? ("
-# Dependent crate licenses
-LICENSE+=" Apache-2.0-with-LLVM-exceptions MIT Unicode-DFS-2016"
-LICENSE+=" )"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="+native-extensions"
-
-BDEPEND="
-	native-extensions? (
-		${RUST_DEPEND}
-		dev-util/maturin[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-
-QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/sqlglotrs/sqlglotrs.*.so"
-
-src_unpack() {
-	cargo_src_unpack
-}
-
-src_prepare() {
-	# remove fragile timing check
-	sed -i -e '/assertLessEqual(time\.time/d' tests/test_parser.py || die
-	distutils-r1_src_prepare
-}
-
-python_compile() {
-	distutils-r1_python_compile
-
-	if use native-extensions; then
-		local DISTUTILS_USE_PEP517=maturin
-		cd sqlglotrs || die
-		distutils-r1_python_compile
-		cd - >/dev/null || die
-	fi
-}
-
-python_test() {
-	local EPYTEST_IGNORE=(
-		# Tests require pyspark or duckdb which aren't in the tree.
-		# Pandas would be a requirement normally, but it gets ignored by proxy.
-		"tests/dataframe/integration/test_dataframe.py"
-		"tests/dataframe/integration/test_grouped_data.py"
-		"tests/dataframe/integration/test_session.py"
-		"tests/test_executor.py"
-		"tests/test_optimizer.py"
-	)
-
-	# make sure not to use an earlier installed version
-	local -x SQLGLOTRS_TOKENIZER=$(usex native-extensions 1 0)
-	rm -rf sqlglotrs || die
-	epytest
-}
-
-pkg_postinst() {
-	optfeature "simplifying timedelta expressions" dev-python/python-dateutil
-}
diff --git a/dev-python/sqlglot/sqlglot-24.0.1.ebuild b/dev-python/sqlglot/sqlglot-24.1.0.ebuild
index c040bab3734b..c040bab3734b 100644
--- a/dev-python/sqlglot/sqlglot-24.0.1.ebuild
+++ b/dev-python/sqlglot/sqlglot-24.1.0.ebuild
diff --git a/dev-python/stripe/Manifest b/dev-python/stripe/Manifest
index 3a6dcf01f910..a60f57e58e98 100644
--- a/dev-python/stripe/Manifest
+++ b/dev-python/stripe/Manifest
@@ -1,3 +1,4 @@
 DIST stripe-9.6.0.tar.gz 1265189 BLAKE2B d5b37cc8c7ee8597b80f9920e782e6eda5ff6905f8b303c4344b345c73c80a37eb1cd8dc9cc30d7321c58070cc5b0180144964d5f285edcff031cb0655b41409 SHA512 d93349c85791abec7d691c2aa726996e3110117dfda5608aa63e39463399200a4f8427dc609fc2a32c7eea005e4a79fd93cffa76762e0914efcd89b83baa58c2
 DIST stripe-9.7.0.tar.gz 1268225 BLAKE2B 2ae512fa7f24966166e2d64a8e4e9f23077d0d0318c6f85e4b922b59fbf66e7bf884567d86270c96911a82b51ecfd72312dfd42d335801e9dd40a1912150e8f0 SHA512 5c36ca6447f5d4947b0e069fe5d4fa30ce2cf11768efa8abb70fcc9a69bd104fe085707a463d566abb5417f9dd4b6cb1d3bab132d20616267931fd895544236e
 DIST stripe-9.8.0.tar.gz 1268721 BLAKE2B 12eeb333a51e71f39c366dda1a4bf82c15f7c3673fc4d27c0e25b978a19902b722d44d5b0f17c017638740cb95f353a024f5012ad70b13c0ac7f7b420df4b082 SHA512 3b19ba9709818af12ba2110b32232c9a33f3a43ce33dfeb8a1e0a7c8a2d643f96795ef474ccdef9e780c1ab58bfa3e687105311cc1d5d24c2984d442d539706b
+DIST stripe-9.9.0.tar.gz 1272880 BLAKE2B 222cc85453d6ed184c7b945d55ca2d35fb5327b3005c04b97d57ab14d44174394f4c7a03d8ed699297cd1b8a7d2e38a1265e66efe07a6c71abefcea7b36df2cc SHA512 49c783e4365e2cc04fbeef66e2678e5e596899cbc90b1edc2192cc7aac6590a138a7315bb2e0f5f504f6a81b7bc3dd8ee7dfb9777d7780d9944b129b0b8e0d2d
diff --git a/dev-python/stripe/stripe-9.9.0.ebuild b/dev-python/stripe/stripe-9.9.0.ebuild
new file mode 100644
index 000000000000..27387de014be
--- /dev/null
+++ b/dev-python/stripe/stripe-9.9.0.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Stripe python bindings"
+HOMEPAGE="
+	https://github.com/stripe/stripe-python/
+	https://pypi.org/project/stripe/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="telemetry"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+"
+# please bump dev-util/stripe-mock dep to the latest version on every bump
+BDEPEND="
+	test? (
+		>=dev-util/stripe-mock-0.186.0
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+		net-misc/curl
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( LONG_DESCRIPTION.rst CHANGELOG.md README.md )
+
+src_prepare() {
+	if ! use telemetry; then
+		sed -i -e '/enable_telemetry/s:True:False:' stripe/__init__.py || die
+	fi
+	# https://github.com/stripe/stripe-python/pull/1297
+	sed -e 's:from mock:from unittest.mock:' \
+		-i tests/test_http_client.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests -p anyio -p pytest_mock
+}
+
+src_test() {
+	local stripe_mock_port=12111
+	local stripe_mock_max_port=12121
+	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
+	# Try to start stripe-mock until we find a free port
+	while [[ ${stripe_mock_port} -le ${stripe_mock_max_port} ]]; do
+		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
+		stripe-mock --http-port "${stripe_mock_port}" &> "${stripe_mock_logfile}" &
+		local stripe_mock_pid=${!}
+		sleep 2
+		# Did stripe-mock start?
+		curl --fail -u "sk_test_123:" \
+			"http://127.0.0.1:${stripe_mock_port}/v1/customers" &> /dev/null
+		eend ${?} "Port ${stripe_mock_port} unavailable"
+		if [[ ${?} -eq 0 ]]; then
+			einfo "stripe-mock running on port ${stripe_mock_port}"
+			break
+		fi
+		(( stripe_mock_port++ ))
+	done
+	if [[ ${stripe_mock_port} -gt ${stripe_mock_max_port} ]]; then
+		eerror "Unable to start stripe-mock for tests"
+		die "Please see the logfile located at: ${stripe_mock_logfile}"
+	fi
+
+	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
+	distutils-r1_src_test
+
+	# Tear down stripe-mock
+	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
+}