Adding metadata

15 files changed, 302 insertions, 32 deletions

diff --git a/dev-python/clang-python/Manifest b/dev-python/clang-python/Manifest
index a3b5849d2682..94b891bdfa16 100644
--- a/dev-python/clang-python/Manifest
+++ b/dev-python/clang-python/Manifest
@@ -3,4 +3,5 @@ DIST llvm-project-14.0.6.src.tar.xz.sig 566 BLAKE2B cb658ad43d8ab6c43a5773aedadf
 DIST llvm-project-14f996dca8a2b5b17d6917528bfd9ee71ba6192a.tar.gz 169054148 BLAKE2B a23af6658a6ea8a7cb4272faef151937da229e39383ec068d7ef81e72a25d2a46dc2a86255a7f1148b7385b339d1c17e62f627df834d8eccc39be8921575f88d SHA512 e719d296016e7af718d022424c337a5df8d7124fdb49b9f219ab2a5dc592e6a59f6c09064775ea9349bcf4eed9d72214abb648de649ab872174c35635c945c04
 DIST llvm-project-15.0.3.src.tar.xz 112069972 BLAKE2B 3d29bab890467ba87fedcc4e76522f444e63e3dfbe546793f8e67821bcd403bad460ea176254c9e0b72d60ea56b8480e498a7f610477c1108732d178804c26cd SHA512 d378d417f01c56534f301cfe6cb4958d811c04ae22acaacc917e7e5f0380859d40ce19dffb265d046b70fff95dbc2e759f492e4d5af0ade52f21ebaa8da65856
 DIST llvm-project-15.0.3.src.tar.xz.sig 438 BLAKE2B e7e0614e144eb878f694c12e97cf42ff8476e47cb55e8f259eb2ec52e303463ad753771271512e89baf0137c1382b11cfa028c85324174ebcd054a124000f537 SHA512 41229bebdb0c2df9a5e3a4d6f02d39fac7dc91f21895a659523beab4fa3ef99ff06eff5e4386221369b6e2b6f8fe974d67b7d8496d5911ce484d09ae0db8b916
+DIST llvm-project-b34ea582774c057d9bf5591174d683fd3d8aa02b.tar.gz 169735900 BLAKE2B d3a82a07f855b038071fc8eb3f41a88b4c220a577219985ecddeb9a535ea8b159dbad575699997d90a49db74c074b5f4354ad707e91d6934daaa7319e0d8ee9b SHA512 3f5525c7d893bdac701cff4cf82dafc31608920d788d9b7401654f320b2432528cf4ae8ef013182807b3dc0c5b758c71f1efeedb672dd47fdb8aa6f434dfb583
 DIST llvmorg-13.0.1.tar.gz 147290251 BLAKE2B 2a44b012a672501761d0c27c6b3a315b69bfef0cd13b078a7e7d2fccc4a9c8c0f2bee0f164c4271c9106b0a99cb06e8b64986f66253b613336719fb86b82541b SHA512 9a8cb5d11964ba88b7624f19ec861fb28701f23956ea3c92f6ac644332d5f41fde97bd8933dd3ee70ed378058c252fa3a3887c8d1af90d219970c2b27691166f
diff --git a/dev-python/clang-python/clang-python-16.0.0_pre20221023.ebuild b/dev-python/clang-python/clang-python-16.0.0_pre20221023.ebuild
new file mode 100644
index 000000000000..42952bf51e0f
--- /dev/null
+++ b/dev-python/clang-python/clang-python-16.0.0_pre20221023.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+DEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	test? (
+		sys-devel/clang:${LLVM_MAJOR}
+	)
+"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	# tests rely on results from a specific clang version, so override
+	# the search path
+	local -x CLANG_LIBRARY_PATH=${BROOT}/usr/lib/llvm/${LLVM_MAJOR}/$(get_libdir)
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/icalendar/Manifest b/dev-python/icalendar/Manifest
index 20341d78a44a..3873cfc5e1f3 100644
--- a/dev-python/icalendar/Manifest
+++ b/dev-python/icalendar/Manifest
@@ -1,2 +1,3 @@
 DIST icalendar-4.1.0.tar.gz 78706 BLAKE2B a676b938101e901c45cfeceba031c35f26dc361832ca24877acefcbe9158e111d883b757a133d72901579f73b32e34adbcb47db6d8ccbaa49f013106c282401e SHA512 15bdf4fd22394836d120d7d7ee029e218247d731c51bd99d4e6df7dd6046b91ea0874b8a81bd6090d366fff035329eac98cabdf0ba5aead43efc82c1e6566b23
 DIST icalendar-5.0.0.tar.gz 97342 BLAKE2B ce0eef07439f150488748b5dbaea45dead18f419304a33ff8a11eb2c00c432ceb3d25cf14b59f13c7aeb18fa3ef137e87306c98bcb5f5d20503c99fe52738151 SHA512 b6608d6aa23e0e3118ea90babe224dfb2fa0a83477b443fdd66d52f82681d5ca7ca86c4b774cf9161e1d1d08f3c1c2cd79f2b347f1bf5e8e54a50e615d8c4880
+DIST icalendar-5.0.1.tar.gz 98634 BLAKE2B 5cc2e17e583caa2f35d5b4723da1975d784bfcbd5620108428cc0d671002620bf0e2fbc72c83440866e3ef31c5e3136781d45dee69ea15be00c42abb6b4d5d22 SHA512 55e62419b90e80e6e675a8ca339e03ea927a620f365a8dcfdb679328103665e7ec80fc7736b425efc6273cf806889783fe499dc4593c77b179601afa1d993e02
diff --git a/dev-python/icalendar/icalendar-5.0.1.ebuild b/dev-python/icalendar/icalendar-5.0.1.ebuild
new file mode 100644
index 000000000000..d0c2687e186c
--- /dev/null
+++ b/dev-python/icalendar/icalendar-5.0.1.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Package used for parsing and generating iCalendar files (RFC 2445)"
+HOMEPAGE="
+	https://github.com/collective/icalendar/
+	https://pypi.org/project/icalendar/
+"
+SRC_URI="mirror://pypi/${P::1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/backports-zoneinfo[${PYTHON_USEDEP}]
+	' 3.8)
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# reset conf.py to not read version from an installed instance
+	sed -e "s:pkg_resources.get_distribution('icalendar').version:'${PV}':" \
+		-i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/jaraco-collections/Manifest b/dev-python/jaraco-collections/Manifest
index 7b637544f364..14507b975b67 100644
--- a/dev-python/jaraco-collections/Manifest
+++ b/dev-python/jaraco-collections/Manifest
@@ -1 +1,2 @@
 DIST jaraco.collections-3.5.2.tar.gz 16038 BLAKE2B 3f7f48f4c65e44aba621dd894a84711473ff42e37be8067e356cd6ca0f8740c667cb282bddad4315ddd7c8922c316c57b40984455f0af4bc8bbf4304a12a6779 SHA512 9567ee44fbc5010cc81ee24de792e53b5a225759b5f7d2e7dd932b0cae38e2035fddb5bd3dee5dc08fea9c61e2bf9087418cd192d81c72760f1e0d95a7b3788c
+DIST jaraco.collections-3.6.0.tar.gz 16720 BLAKE2B 283e9570729ded2b33b6fd1ab7a7b1414588a48455fc3a3103e4a3fe3e4eadae0d9e925a2f1e2de6ee8973121e1d01923c4c3ea72c618033f776c2e4b9add558 SHA512 a5cfa42e60d4a63463d159090086f9400f6faeeaedd9cba7d46bdfc9fc328b0056d6f2e428de93bfd59ea4f2bdc5d8b71158c5f1592a62e2ebd8e1ed7471e4ef
diff --git a/dev-python/jaraco-collections/jaraco-collections-3.6.0.ebuild b/dev-python/jaraco-collections/jaraco-collections-3.6.0.ebuild
new file mode 100644
index 000000000000..d9889747db9e
--- /dev/null
+++ b/dev-python/jaraco-collections/jaraco-collections-3.6.0.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/-/.}
+DESCRIPTION="Models and classes to supplement the stdlib collections module"
+HOMEPAGE="
+	https://github.com/jaraco/jaraco.collections/
+	https://pypi.org/project/jaraco.collections/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN/-/.}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	dev-python/jaraco-text[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/kombu/Manifest b/dev-python/kombu/Manifest
index 2c2b525bd74a..6cc502a83f5d 100644
--- a/dev-python/kombu/Manifest
+++ b/dev-python/kombu/Manifest
@@ -1 +1,2 @@
 DIST kombu-5.2.4.tar.gz 423450 BLAKE2B d0a180a4644876594eacea51706ca74fa4a95729ba965f69694da9694c2a91641ccf05aa1aec8a64f9d8c2260477d00bc2664d0a50143562b46524c98e4159b1 SHA512 695813bee71d627649e772b45b25494784a6a81bcad92331160705e34d8b2268fa90629983ebcfd04ec23208508d422f1834cc56895532911602d58ec0090a03
+DIST kombu-5.3.0b2.tar.gz 434341 BLAKE2B 6d5188f7682ccf2daa6ca4ed0fec7988cd4781954be0fdc847c18e47d5c425a657c3df0f5bda7999c764de293626e119a4645e92ff7bf23328f4fcb9d6f4cd4a SHA512 3000577cc3b2acfb378396640245f2bdf4c9e5e1d45252a27e4e168e22ff4070f480ad1fd70059b24cd710c452924bff1716f69bedcf020446f428f0967de832
diff --git a/dev-python/kombu/kombu-5.3.0_beta2.ebuild b/dev-python/kombu/kombu-5.3.0_beta2.ebuild
new file mode 100644
index 000000000000..b3ab600cf4df
--- /dev/null
+++ b/dev-python/kombu/kombu-5.3.0_beta2.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 optfeature
+
+MY_PV="${PV//_beta/b}"
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/py-amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/py-amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/Pyro4[${PYTHON_USEDEP}]
+		dev-python/pytest-freezegun[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-py-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx_celery
+
+EPYTEST_IGNORE=(
+	# Unpackaged azure-servicebus
+	t/unit/transport/test_azureservicebus.py
+	# Unpackaged librabbitmq
+	t/unit/transport/test_librabbitmq.py
+	# Unpackaged python-consul
+	t/unit/transport/test_consul.py
+	# AttributeError: test_Etcd instance has no attribute 'patch'
+	t/unit/transport/test_etcd.py
+)
+
+python_test() {
+	local EPYTEST_DESELECT
+
+	# AttributeError: 'str' object has no attribute 'load'
+	[[ ${EPYTHON} == python3.10 ]] && \
+		EPYTEST_DESELECT+=( t/unit/utils/test_compat.py::test_entrypoints )
+
+	epytest
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Pyro 4 backend" dev-python/Pyro4
+	optfeature "Redis backend" dev-python/redis-py
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}
diff --git a/dev-python/lit/Manifest b/dev-python/lit/Manifest
index a3b5849d2682..94b891bdfa16 100644
--- a/dev-python/lit/Manifest
+++ b/dev-python/lit/Manifest
@@ -3,4 +3,5 @@ DIST llvm-project-14.0.6.src.tar.xz.sig 566 BLAKE2B cb658ad43d8ab6c43a5773aedadf
 DIST llvm-project-14f996dca8a2b5b17d6917528bfd9ee71ba6192a.tar.gz 169054148 BLAKE2B a23af6658a6ea8a7cb4272faef151937da229e39383ec068d7ef81e72a25d2a46dc2a86255a7f1148b7385b339d1c17e62f627df834d8eccc39be8921575f88d SHA512 e719d296016e7af718d022424c337a5df8d7124fdb49b9f219ab2a5dc592e6a59f6c09064775ea9349bcf4eed9d72214abb648de649ab872174c35635c945c04
 DIST llvm-project-15.0.3.src.tar.xz 112069972 BLAKE2B 3d29bab890467ba87fedcc4e76522f444e63e3dfbe546793f8e67821bcd403bad460ea176254c9e0b72d60ea56b8480e498a7f610477c1108732d178804c26cd SHA512 d378d417f01c56534f301cfe6cb4958d811c04ae22acaacc917e7e5f0380859d40ce19dffb265d046b70fff95dbc2e759f492e4d5af0ade52f21ebaa8da65856
 DIST llvm-project-15.0.3.src.tar.xz.sig 438 BLAKE2B e7e0614e144eb878f694c12e97cf42ff8476e47cb55e8f259eb2ec52e303463ad753771271512e89baf0137c1382b11cfa028c85324174ebcd054a124000f537 SHA512 41229bebdb0c2df9a5e3a4d6f02d39fac7dc91f21895a659523beab4fa3ef99ff06eff5e4386221369b6e2b6f8fe974d67b7d8496d5911ce484d09ae0db8b916
+DIST llvm-project-b34ea582774c057d9bf5591174d683fd3d8aa02b.tar.gz 169735900 BLAKE2B d3a82a07f855b038071fc8eb3f41a88b4c220a577219985ecddeb9a535ea8b159dbad575699997d90a49db74c074b5f4354ad707e91d6934daaa7319e0d8ee9b SHA512 3f5525c7d893bdac701cff4cf82dafc31608920d788d9b7401654f320b2432528cf4ae8ef013182807b3dc0c5b758c71f1efeedb672dd47fdb8aa6f434dfb583
 DIST llvmorg-13.0.1.tar.gz 147290251 BLAKE2B 2a44b012a672501761d0c27c6b3a315b69bfef0cd13b078a7e7d2fccc4a9c8c0f2bee0f164c4271c9106b0a99cb06e8b64986f66253b613336719fb86b82541b SHA512 9a8cb5d11964ba88b7624f19ec861fb28701f23956ea3c92f6ac644332d5f41fde97bd8933dd3ee70ed378058c252fa3a3887c8d1af90d219970c2b27691166f
diff --git a/dev-python/lit/lit-16.0.0_pre20221023.ebuild b/dev-python/lit/lit-16.0.0_pre20221023.ebuild
new file mode 100644
index 000000000000..804d31b11189
--- /dev/null
+++ b/dev-python/lit/lit-16.0.0_pre20221023.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm
+	)
+"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}
diff --git a/dev-python/python-cstruct/Manifest b/dev-python/python-cstruct/Manifest
index 90375f68b95f..278b7ef5c8ea 100644
--- a/dev-python/python-cstruct/Manifest
+++ b/dev-python/python-cstruct/Manifest
@@ -1,4 +1,3 @@
-DIST python-cstruct-2.2.gh.tar.gz 18764 BLAKE2B 75aaffae27fef59799e52866f8169cc5d7362ef1553a56986f361ef7cfb7ca3e7d8c67fe0f112ec8e03ddacf45885e19fc1ce0d9d27c7581deafbf7e7fe1789b SHA512 5a1d62b596fef08a48020557e82fc81360430d94f18ce0667919815d57b944102067c2fe5723372616f73c995afd3a1f674e4a37e406d0dc7eeaf9fe3ef8f484
-DIST python-cstruct-2.3.gh.tar.gz 19043 BLAKE2B dd445da91d155dc576523d5c15dc963493dfb62e7e79fae6c436e69654432eadbc30b0001026f5613268800eb0a3a01392120b11e7b3995cff16477850818c9f SHA512 5700a3d8ef58130bc5b3b5d7c36102f6a878fd8d5b9104804f0c206e583e77d7a9c9ff8e8008d9bd1ee72d55167e48cd3f9ba776816eb25ceb8ceaf0c880b597
 DIST python-cstruct-3.0.gh.tar.gz 25950 BLAKE2B 7ea8c77ed87e4fb740c3f7a4ed53a7532ee5aca15ee46fbb40da7308ae62ceacd7ccc67a958e6355904604ae67c9594acc9cae5d18bfed0558b91f7e9c8ad0a9 SHA512 dd1c85363512edc4df0379dec40e7d7fe3ceff1cc4014eae8dab0e91c47ea9c3619211e1a637aeec134ce713d0681688630b7fde97f02c6bcd7103a32f258a73
 DIST python-cstruct-3.1.gh.tar.gz 26633 BLAKE2B 449510cc8cc6661270d2618cd347eea2044eacc8f665ed2f55bc6fcd95bcf79f29f8bce6498d372d8b5b78f854edb06afb89a3f3ef7f5de37582ebf68d178db1 SHA512 00e2165c14dcc4461600a8eeef5c71bcaa6e59955c23d08055aff2186b16f20d6c10fdb1a02f6e263e27070fda562c712df0c4ad2440a25dc5f23afaa9c88719
+DIST python-cstruct-3.2.gh.tar.gz 26876 BLAKE2B 084c4e3e1e5a48ee15c40e25a846b09dc1af1fe0ef9734bddad14ebac91e2bbdf78cffc39dd861f35d7ed307f1dfb14cb7b15dd47b900d3c943bf3245adb9ff3 SHA512 8b912bba7a31a8cacd77e07008ea1a0603c59c49e2cbb4a8fee158948b05166f2223c983f58c104d73c0fd868bfaebc9f38669277f27282486cfb064d9026ab5
diff --git a/dev-python/python-cstruct/python-cstruct-2.3.ebuild b/dev-python/python-cstruct/python-cstruct-2.3.ebuild
deleted file mode 100644
index 870df7088705..000000000000
--- a/dev-python/python-cstruct/python-cstruct-2.3.ebuild
+++ /dev/null
@@ -1,30 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{7,8,9,10} )
-inherit distutils-r1
-
-DESCRIPTION="C-style structs for Python"
-HOMEPAGE="https://github.com/andreax79/python-cstruct
-	https://pypi.org/project/cstruct/"
-SRC_URI="
-	https://github.com/andreax79/${PN}/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-DOCS=( README.md )
-
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	sed -e "/find_packages(/s@exclude=\[@&'tests', @" -i setup.py || die
-}
diff --git a/dev-python/python-cstruct/python-cstruct-2.2.ebuild b/dev-python/python-cstruct/python-cstruct-3.2.ebuild
index 870df7088705..870df7088705 100644
--- a/dev-python/python-cstruct/python-cstruct-2.2.ebuild
+++ b/dev-python/python-cstruct/python-cstruct-3.2.ebuild
diff --git a/dev-python/tavern/Manifest b/dev-python/tavern/Manifest
index 81fe25ec877d..3ef6915497b7 100644
--- a/dev-python/tavern/Manifest
+++ b/dev-python/tavern/Manifest
@@ -1 +1,2 @@
 DIST tavern-1.23.3.gh.tar.gz 162529 BLAKE2B cf4cb24b4e298b86917fc522a2b7b7da3fccb6d4efddeb53d45ee949273e66a0135a0dabb887a1cf1eec9a6429b3ac1eaaa01ef955e08eea452fb7eff2f9d994 SHA512 0a4e9bfde9b31e1b488ef022e73614c6f93c71837f813b76f98e02c69a71b05c3aad92b78d887764d4c9f6fbfc929b3cafc6b2e26a47618a81fcd00d5a6ad0d9
+DIST tavern-1.23.4.gh.tar.gz 163777 BLAKE2B 57fa5979c0d343b61ca047d4737d63ea02e036e8777a1f35d472ef72bf5630833a1e349741d23d7666a543e6e80964120b792f73e41b3251d11c838f5936494a SHA512 b6fe70a572b5d193893fe6d58456045d90079ec6738b47918011334d180ba8743487cad2967762b855869f7b6b773982924abf949a4209c5a8e6703e3e0bc80d
diff --git a/dev-python/tavern/tavern-1.23.4.ebuild b/dev-python/tavern/tavern-1.23.4.ebuild
new file mode 100644
index 000000000000..db25f21c13d0
--- /dev/null
+++ b/dev-python/tavern/tavern-1.23.4.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="A tool, library, and Pytest plugin for testing RESTful APIs"
+HOMEPAGE="https://github.com/taverntesting/tavern"
+SRC_URI="https://github.com/taverntesting/tavern/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/paho-mqtt[${PYTHON_USEDEP}]
+	dev-python/pyjwt[${PYTHON_USEDEP}]
+	dev-python/pykwalify[${PYTHON_USEDEP}]
+	dev-python/pytest[${PYTHON_USEDEP}]
+	dev-python/python-box[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/stevedore[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/colorlog[${PYTHON_USEDEP}]
+		dev-python/Faker[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest