Adding metadata

12 files changed, 258 insertions, 6 deletions

diff --git a/dev-python/aiohttp/aiohttp-3.8.1-r1.ebuild b/dev-python/aiohttp/aiohttp-3.8.1-r1.ebuild
new file mode 100644
index 000000000000..db44e48134d3
--- /dev/null
+++ b/dev-python/aiohttp/aiohttp-3.8.1-r1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 multiprocessing
+
+LLHTTP_COMMIT=69d6db2008508489d19267a0dcab30602b16fc5b
+
+DESCRIPTION="http client/server for asyncio"
+HOMEPAGE="
+	https://github.com/aio-libs/aiohttp/
+	https://pypi.org/project/aiohttp/
+"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	app-arch/brotli[python,${PYTHON_USEDEP}]
+	>=dev-python/aiosignal-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/async_timeout-4.0.0_alpha3[${PYTHON_USEDEP}]
+	>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
+	>=dev-python/charset_normalizer-2.0[${PYTHON_USEDEP}]
+	>=dev-python/frozenlist-1.1.1[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/async_generator[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		!hppa? ( !ia64? (
+			dev-python/trustme[${PYTHON_USEDEP}]
+		) )
+	)
+"
+
+DOCS=( CHANGES.rst CONTRIBUTORS.txt README.rst )
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	'>=dev-python/alabaster-0.6.2' \
+	'dev-python/sphinxcontrib-asyncio' \
+	'dev-python/sphinxcontrib-blockdiag' \
+	'dev-python/sphinxcontrib-newsfeed' \
+	'dev-python/sphinxcontrib-spelling' \
+	'dev-python/sphinx' \
+	'dev-python/sphinx-aiohttp-theme'
+
+src_prepare() {
+	# increase the timeout a little
+	sed -e '/abs_tol=/s/0.001/0.01/' -i tests/test_helpers.py || die
+
+	# xfail_strict fails on py3.10
+	sed -i -e '/--cov/d' -e '/xfail_strict/d' setup.cfg || die
+
+	distutils-r1_src_prepare
+}
+
+python_configure_all() {
+	# workaround missing files
+	mkdir requirements tools || die
+	> requirements/cython.txt || die
+	> tools/gen.py || die
+	chmod +x tools/gen.py || die
+	# force rehashing first
+	emake requirements/.hash/cython.txt.hash
+	> .update-pip || die
+	> .install-cython || die
+	emake cythonize
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# proxy is not packaged
+		tests/test_proxy_functional.py
+	)
+
+	local EPYTEST_DESELECT=(
+		# runtime warnings
+		'tests/test_client_functional.py::test_aiohttp_request_coroutine[pyloop]'
+		# Internet
+		tests/test_client_session.py::test_client_session_timeout_zero
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		# C extensions are not used on PyPy3
+		tests/test_http_parser.py::test_c_parser_loaded
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_mock,xdist.plugin,pytest_forked
+	rm -rf aiohttp || die
+	epytest -n "$(makeopts_jobs)" --forked
+}
diff --git a/dev-python/async_timeout/async_timeout-4.0.2-r1.ebuild b/dev-python/async_timeout/async_timeout-4.0.2-r1.ebuild
new file mode 100644
index 000000000000..e4fae1f84854
--- /dev/null
+++ b/dev-python/async_timeout/async_timeout-4.0.2-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${PN/_/-}-${PV}
+DESCRIPTION="Timeout context manager for asyncio programs"
+HOMEPAGE="
+	https://github.com/aio-libs/async-timeout/
+	https://pypi.org/project/async-timeout/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pointless dep on pytest-cov
+	sed -i -e '/addopts/d' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest -p no:aiohttp
+}
diff --git a/dev-python/editables/editables-0.3.ebuild b/dev-python/editables/editables-0.3.ebuild
index dc8ac56e5b1f..51aacc7ea55f 100644
--- a/dev-python/editables/editables-0.3.ebuild
+++ b/dev-python/editables/editables-0.3.ebuild
@@ -20,6 +20,6 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
+KEYWORDS="amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
 distutils_enable_tests pytest
diff --git a/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.5.1.ebuild b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.5.1.ebuild
index 7953fb93b5eb..5e12b989ce65 100644
--- a/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.5.1.ebuild
+++ b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.5.1.ebuild
@@ -23,6 +23,10 @@ RDEPEND="
 	>=dev-python/sqlalchemy-0.8.0[${PYTHON_USEDEP}]
 "
 
+BDEPEND="test? (
+	dev-python/mock[${PYTHON_USEDEP}]
+)"
+
 distutils_enable_tests pytest
 distutils_enable_sphinx docs dev-python/pallets-sphinx-themes \
 	dev-python/sphinx-issues
diff --git a/dev-python/fonttools/fonttools-4.33.3.ebuild b/dev-python/fonttools/fonttools-4.33.3.ebuild
index 866763d284c1..8f83736a47bb 100644
--- a/dev-python/fonttools/fonttools-4.33.3.ebuild
+++ b/dev-python/fonttools/fonttools-4.33.3.ebuild
@@ -15,7 +15,7 @@ SRC_URI="https://github.com/fonttools/fonttools/archive/${PV}.tar.gz -> ${P}.tar
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86 ~x64-macos"
 
 RDEPEND=">=dev-python/fs-2.4.9[${PYTHON_USEDEP}]"
 BDEPEND="${RDEPEND}
diff --git a/dev-python/hatchling/hatchling-0.24.0.ebuild b/dev-python/hatchling/hatchling-0.24.0.ebuild
index 68a01b40bde9..e2a90d789f50 100644
--- a/dev-python/hatchling/hatchling-0.24.0.ebuild
+++ b/dev-python/hatchling/hatchling-0.24.0.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}/backend
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
+KEYWORDS="amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
 	>=dev-python/editables-0.2[${PYTHON_USEDEP}]
diff --git a/dev-python/immutables/immutables-0.17.ebuild b/dev-python/immutables/immutables-0.17.ebuild
index 1d694aefd04b..8da94f6c6a75 100644
--- a/dev-python/immutables/immutables-0.17.ebuild
+++ b/dev-python/immutables/immutables-0.17.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
 
 distutils_enable_tests pytest
 
diff --git a/dev-python/passlib/passlib-1.7.4-r2.ebuild b/dev-python/passlib/passlib-1.7.4-r2.ebuild
new file mode 100644
index 000000000000..32703c2e5258
--- /dev/null
+++ b/dev-python/passlib/passlib-1.7.4-r2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Password hashing framework supporting over 20 schemes"
+HOMEPAGE="
+	https://foss.heptapod.net/python-libs/passlib/-/wikis/home
+	https://pypi.org/project/passlib/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+SLOT="0"
+IUSE="doc"
+
+BDEPEND="
+	test? (
+		dev-python/bcrypt[${PYTHON_USEDEP}]
+		dev-python/scrypt[${PYTHON_USEDEP}]
+		!alpha? ( !hppa? ( !ia64? (
+			dev-python/cryptography[${PYTHON_USEDEP}]
+		) ) )
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken all the time by new django releases
+		passlib/tests/test_ext_django.py
+	)
+
+	# skip fuzzing tests, they are very slow
+	epytest -k "not fuzz_input"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use doc && dodoc docs/{*.rst,requirements.txt,lib/*.rst}
+}
+
+pkg_postinst() {
+	optfeature "Argon2 support" dev-python/argon2-cffi
+	optfeature "bcrypt support" dev-python/bcrypt
+	optfeature "scrypt support" dev-python/scrypt
+	optfeature "Time-based One-Time Password (TOTP) support" dev-python/cryptography
+}
diff --git a/dev-python/python-docs/python-docs-3.9.12.ebuild b/dev-python/python-docs/python-docs-3.9.12.ebuild
index faae3196acc3..0d66370bcd05 100644
--- a/dev-python/python-docs/python-docs-3.9.12.ebuild
+++ b/dev-python/python-docs/python-docs-3.9.12.ebuild
@@ -10,7 +10,7 @@ S="${WORKDIR}/python-${PV}-docs-html"
 
 LICENSE="PSF-2"
 SLOT="$(ver_cut 1-2)"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~s390 sparc x86"
 
 src_install() {
 	rm -r _sources || die
diff --git a/dev-python/python-gammu/Manifest b/dev-python/python-gammu/Manifest
index fede82ec0d79..45683f07729a 100644
--- a/dev-python/python-gammu/Manifest
+++ b/dev-python/python-gammu/Manifest
@@ -1 +1,2 @@
 DIST python-gammu-2.11.tar.gz 135567 BLAKE2B 133172cfd0715ff6b5bd47b93e5d93d52af3e608459ba1158bf008da9b5f24f6d155c04334dea7ff2cacdea678f00d986838a139290d5f8ac874bb9702fcd5e6 SHA512 cdf3a54fc538fecdbe3dae63f0534094ce94a289998f9b670a0b3e12a3c571eb46ee86eae67a7a8d2428698850046d5c75569753bf77551cd395d315e6f9b70d
+DIST python-gammu-3.2.4.tar.gz 144136 BLAKE2B ef06b78568e9b88da95d09029191a2de0c4e26cb6b222326bffd0134a9c7eb743bab20201347d3be8a81db43f6005ec2a0550e1976a59de9ee9202c733ae41e0 SHA512 9d76b402c50018cc52476376952edebb6b0934aa374ea2a2177f5497d0949fcc77644aa2a35c7402b3f2179962d903409b7b1949c5e85a0e5130058d34f89664
diff --git a/dev-python/python-gammu/python-gammu-3.2.4.ebuild b/dev-python/python-gammu/python-gammu-3.2.4.ebuild
new file mode 100644
index 000000000000..0ca4fe86bcbd
--- /dev/null
+++ b/dev-python/python-gammu/python-gammu-3.2.4.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings for Gammu"
+HOMEPAGE="https://wammu.eu/python-gammu/"
+SRC_URI="https://github.com/gammu/python-gammu/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+RESTRICT="!test? ( test )"
+
+RDEPEND=">=app-mobilephone/gammu-1.34.0"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		$(python_gen_impl_dep sqlite)
+		app-mobilephone/gammu[dbi]
+	)"
+
+DOCS=( AUTHORS NEWS.rst README.rst )
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		docompress -x /usr/share/doc/${P}/examples
+		dodoc -r examples
+	fi
+}
diff --git a/dev-python/setproctitle/setproctitle-1.2.3.ebuild b/dev-python/setproctitle/setproctitle-1.2.3.ebuild
index 9570c7d5f629..7821486621be 100644
--- a/dev-python/setproctitle/setproctitle-1.2.3.ebuild
+++ b/dev-python/setproctitle/setproctitle-1.2.3.ebuild
@@ -5,10 +5,14 @@ EAPI=8
 
 DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10} pypy3 )
+
 inherit distutils-r1
 
 DESCRIPTION="Allow customization of the process title"
-HOMEPAGE="https://github.com/dvarrazzo/py-setproctitle"
+HOMEPAGE="
+	https://github.com/dvarrazzo/py-setproctitle/
+	https://pypi.org/project/setproctitle/
+"
 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"