Adding metadata

26 files changed, 735 insertions, 18 deletions

diff --git a/dev-python/Faker/Faker-19.7.0.ebuild b/dev-python/Faker/Faker-19.7.0.ebuild
new file mode 100644
index 000000000000..133de870b2fd
--- /dev/null
+++ b/dev-python/Faker/Faker-19.7.0.ebuild
@@ -0,0 +1,40 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A Python package that generates fake data for you"
+HOMEPAGE="
+	https://github.com/joke2k/faker/
+	https://pypi.org/project/Faker/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.4.2[${PYTHON_USEDEP}]
+	!dev-ruby/faker
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},tiff]
+		dev-python/validators[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=faker.contrib.pytest.plugin
+	epytest
+}
diff --git a/dev-python/Faker/Manifest b/dev-python/Faker/Manifest
index 60c98b2dd32c..a35e10516616 100644
--- a/dev-python/Faker/Manifest
+++ b/dev-python/Faker/Manifest
@@ -1,2 +1,3 @@
 DIST Faker-19.6.1.tar.gz 1668966 BLAKE2B 48e1d0c658e7cd482660b797e5ac8e107c84e7d2be9ab86e55cb5f0da662ed742565c1f5a3176d1f2588b8ffafcc37e7dbd072c78e5b1ab94bea8678ea9f1d48 SHA512 1511f03cb41f70a22784a8dc1cdb5b58fdc19fc6f67d4a414a9b15619d019ec6b6564b7fa50db03535aaa3650ae93e4c948c732ae65e61652d7469d9ad83db36
 DIST Faker-19.6.2.tar.gz 1680331 BLAKE2B 3453c531a1860c3e1782e24ad2d892d8291e1fafc698483639f43e7bdd281cee6e5c8bf7e60181db72011c1434ca3bc1c7f2a877ce136bf6e4f00286249033b9 SHA512 8a7929135ad562fafc2c95408ed644e7b965215d3e9ea2f2682e2aa2a5bab9759ab42d67380c7f8c89cf099cb65ad0dd13f6575c028f20550ef157f7db90102b
+DIST Faker-19.7.0.tar.gz 1680303 BLAKE2B 80169d818749003b6961adb85969eb025c38b81d8d333466b304815396aaf646b1a9e1fb9457e68292600576fa6a91ae1851af85e2bc3403dfa383f223fe49ab SHA512 f9b47d0bf52f5ba3a300222d45ad087eedbdf9ed7b1cae11cb600834f8919247e9000211157811dc016be7040925ec7930a407e8ea497ca87cae382d1edd2a56
diff --git a/dev-python/Levenshtein/Levenshtein-0.23.0.ebuild b/dev-python/Levenshtein/Levenshtein-0.23.0.ebuild
new file mode 100644
index 000000000000..f78f96425ea8
--- /dev/null
+++ b/dev-python/Levenshtein/Levenshtein-0.23.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+# custom wrapper over setuptools
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Functions for fast computation of Levenshtein distance, and edit operations"
+HOMEPAGE="
+	https://pypi.org/project/Levenshtein/
+	https://github.com/maxbachmann/Levenshtein/
+"
+SRC_URI="
+	https://github.com/maxbachmann/Levenshtein/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+DEPEND="
+	>=dev-cpp/rapidfuzz-cpp-2.0.0
+"
+RDEPEND="
+	<dev-python/rapidfuzz-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/rapidfuzz-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/cython-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/scikit-build-0.13.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# sterilize build flags
+	sed -i -e '/CMAKE_INTERPROCEDURAL_OPTIMIZATION/d' CMakeLists.txt || die
+
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/Levenshtein/Manifest b/dev-python/Levenshtein/Manifest
index 396670d389da..cb461a320b1e 100644
--- a/dev-python/Levenshtein/Manifest
+++ b/dev-python/Levenshtein/Manifest
@@ -1,2 +1,3 @@
 DIST Levenshtein-0.21.1.gh.tar.gz 36656 BLAKE2B b2e5325cd836b646d876fb59d1062c7bb415d707076d9692fff2b98e00dce29d813fb68c139283d66f8800fd836ec93b709ac7ebfaa6d9cca563b65c428019ef SHA512 5fd823e7871c53f521198275b7ebb3189f7208347d41f306686e11446397c4ed5b2672230cbfa76a0c2f1afcc08fd24c6c7468d808be2a09bb9c31c2d9f61f16
 DIST Levenshtein-0.22.0.gh.tar.gz 36726 BLAKE2B dec59ca80d0c40295a97adeb59f7946be3e38b3b29e7ec7345e07c0853e5817df6d98213e6d60bf4300a7998ee9754da5d266567aed0c543f8c82955b7821a39 SHA512 f762d6702dc3acbde1c545ec4ca3bb5c96ce256319c4cd045737fa9c7309f5fab7dca621a09b1fb6f89a925f505737cbde9c1f480d3c2f4a2b948b1b8083bbee
+DIST Levenshtein-0.23.0.gh.tar.gz 36891 BLAKE2B 847772ee88a76881c0974a1a9c1ef252320308f17b30b227f8251b0a8b8454c2289e02a24b2a9cb225d34183c5b6e4dbf574b22a5d37a1b453596ff0cb6e0aa0 SHA512 137116f337f576534bf2c12dc49d35f81a3b267eb613e5e6cca6cb80e5701dd0adbfd97c1cec4ea8f1bb4dee2bc67deeb19553474348ea78af4e05b79ce01fdf
diff --git a/dev-python/astroid/astroid-2.15.8-r1.ebuild b/dev-python/astroid/astroid-2.15.8-r1.ebuild
new file mode 100644
index 000000000000..2ca1d7f67c9a
--- /dev/null
+++ b/dev-python/astroid/astroid-2.15.8-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+SRC_URI="
+	https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in pyproject.toml
+RDEPEND="
+	>=dev-python/lazy-object-proxy-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/wrapt-2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0.0[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+		tests/brain/test_regex.py::TestRegexBrain::test_regex_pattern_and_match_subscriptable
+		# some problem with warnings (our options?)
+		tests/test_decorators.py::TestDeprecationDecorators::test_deprecated_default_argument_values_one_arg
+		tests/test_decorators.py::TestDeprecationDecorators::test_deprecated_default_argument_values_two_args
+		tests/test_scoped_nodes.py::test_deprecation_of_doc_attribute
+		# requires six bundled in urllib3, sigh
+		tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
+		# requires pip, and looks suspicious anyway
+		tests/test_manager.py::IsolatedAstroidManagerTest::test_no_user_warning
+		# pydantic-2?
+		tests/brain/test_dataclasses.py::test_pydantic_field
+		# TODO
+		tests/test_manager.py::ClearCacheTest::test_clear_cache_clears_other_lru_caches
+	)
+
+	# Faker causes sys.path_importer_cache keys to be overwritten
+	# with PosixPaths
+	epytest -p no:faker
+}
diff --git a/dev-python/astroid/astroid-3.0.0-r1.ebuild b/dev-python/astroid/astroid-3.0.0-r1.ebuild
new file mode 100644
index 000000000000..87f69d12d690
--- /dev/null
+++ b/dev-python/astroid/astroid-3.0.0-r1.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/pylint-dev/astroid/
+	https://pypi.org/project/astroid/
+"
+SRC_URI="
+	https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+# Version specified in pyproject.toml
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/attrs[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/regex[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# no clue why they're broken
+		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
+#		tests/brain/test_regex.py::TestRegexBrain::test_regex_pattern_and_match_subscriptable
+#		# some problem with warnings (our options?)
+#		tests/test_decorators.py::TestDeprecationDecorators::test_deprecated_default_argument_values_one_arg
+#		tests/test_decorators.py::TestDeprecationDecorators::test_deprecated_default_argument_values_two_args
+#		tests/test_scoped_nodes.py::test_deprecation_of_doc_attribute
+#		# requires six bundled in urllib3, sigh
+#		tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
+#		# requires pip, and looks suspicious anyway
+#		tests/test_manager.py::IsolatedAstroidManagerTest::test_no_user_warning
+		# pydantic-2?
+		tests/brain/test_dataclasses.py::test_pydantic_field
+#		# TODO
+#		tests/test_manager.py::ClearCacheTest::test_clear_cache_clears_other_lru_caches
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/google-auth/Manifest b/dev-python/google-auth/Manifest
index c7f0ebd8953d..1df08a322058 100644
--- a/dev-python/google-auth/Manifest
+++ b/dev-python/google-auth/Manifest
@@ -1 +1,2 @@
 DIST google-auth-2.23.2.tar.gz 232207 BLAKE2B 0de53f79bd908d7194253525de07075779ffc0ed33ef71e50004773ba85aee8e7392cd5cc87ad88b5f9ce90bc3eb19c0c094d0e76311d2cd93fb0bdb62ab2450 SHA512 d443b769e6ee7de6da14e31f8beb938aaf63edecafcbedda46b253bf0380dbd78a4508a0214f7a708a09c39d1d262cc93a290ec44e89fa05da7796828f33c1fd
+DIST google-auth-2.23.3.tar.gz 232472 BLAKE2B aab7c55e6037751f578c9b9ec83c2efac10bd0e9d755b56ff21cba68ce71baaff73f4947b00da54b02e41742f718b854d1c2efb88bf8ba8cb582c2425afcb29f SHA512 a561c1359e520e82de6faf3e0d60f8c072b96231ee2db54bea59ad9fa5caa505f91ab5b1008f7a3ebecdfcd70fbddbcfb5c19dfad8b0fe1424558284757aeb4b
diff --git a/dev-python/google-auth/google-auth-2.23.3.ebuild b/dev-python/google-auth/google-auth-2.23.3.ebuild
new file mode 100644
index 000000000000..25589b3173ca
--- /dev/null
+++ b/dev-python/google-auth/google-auth-2.23.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://github.com/googleapis/google-auth-library-python/
+	https://pypi.org/project/google-auth/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/cachetools-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pyu2f[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# these are compatibility tests with oauth2client
+		# disable them to unblock removal of that package
+		tests/test__oauth2client.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/h5py/Manifest b/dev-python/h5py/Manifest
index 438d98fcb61c..bf1fb5fb0e74 100644
--- a/dev-python/h5py/Manifest
+++ b/dev-python/h5py/Manifest
@@ -1 +1,2 @@
+DIST h5py-3.10.0.tar.gz 403716 BLAKE2B a8e4351a15aee5fe9d23f9c5f9b6ff44e688a391ba17e27338675bde60415c73e3cd97a4a0c05490df849f649d626450d3dbecc9ae6ea3d24d784a0a4aaa1850 SHA512 840d7f2b9b9d5e22e8edae21c84884abec64acdd6c36437a4921ce9dc1b343c55f66f72b699146d71fe55688f6f948787b62335a24906288e9565b2b19b24b01
 DIST h5py-3.9.0.tar.gz 402856 BLAKE2B e2c617c492c2fba751fa546292232b78e1cec4bc75fb50a7c59cdb4a34bc927134d4604d3d9b24f880235cfb356636e66907b8026107547905a77ed9732ccc26 SHA512 f87cb36ba874e86b179776031c3345ad83bc7b5eff2f3ee54acb6b0997cc7925c17dc478957103ab6bb07d8aaa8593af1d51c3547021a205e9d01c0e36d833a9
diff --git a/dev-python/h5py/h5py-3.10.0.ebuild b/dev-python/h5py/h5py-3.10.0.ebuild
new file mode 100644
index 000000000000..67fa4af14a49
--- /dev/null
+++ b/dev-python/h5py/h5py-3.10.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple Python interface to HDF5 files"
+HOMEPAGE="
+	https://www.h5py.org/
+	https://github.com/h5py/h5py/
+	https://pypi.org/project/h5py/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~x64-macos"
+# disable mpi until mpi4py gets python3_8
+#IUSE="examples mpi"
+IUSE="examples"
+
+#RDEPEND="sci-libs/hdf5:=[mpi=,hl(+)]
+DEPEND="
+	>=sci-libs/hdf5-1.10.4:=[hl(+)]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/numpy-1.17.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	<dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.14.5[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	test? (
+		dev-python/QtPy[testlib,${PYTHON_USEDEP}]
+	)
+"
+#	mpi? ( virtual/mpi )
+#	mpi? ( dev-python/mpi4py[${PYTHON_USEDEP}] )
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/alabaster
+
+#pkg_setup() {
+#	use mpi && export CC=mpicc
+#}
+
+python_prepare_all() {
+	# avoid pytest-mpi dep, we do not use mpi anyway
+	sed -i -e 's:pytest-mpi::' pytest.ini || die
+	distutils-r1_python_prepare_all
+
+	export H5PY_SETUP_REQUIRES=0
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	epytest -m "not mpi"
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..e9da2ac43cac 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 736a1167c898..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,6 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- 
- <origin>gentoo-guru-overlay</origin>
+ <maintainer type="person">
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/openapi-spec-validator/Manifest b/dev-python/openapi-spec-validator/Manifest
index 736101d3684b..89d0fcd177f8 100644
--- a/dev-python/openapi-spec-validator/Manifest
+++ b/dev-python/openapi-spec-validator/Manifest
@@ -1,2 +1,3 @@
 DIST openapi_spec_validator-0.5.7.tar.gz 33722 BLAKE2B 71096a996d335b60d6646d96390e580952a1e27829aa807c4b333ee11a7925bc1bc10f4440c79fc6d4a8321dfd3bab9ec86bf79bef6c7139835b7f8035cbc061 SHA512 63dafc0bc459d8ad097d0a98a3d23e67ae37c0004ce6d53ad999b037f2a6743c95e13ae22920403368c37f8877665c104ac20e1f58532cffd8df54c800a6cf7d
 DIST openapi_spec_validator-0.6.0.tar.gz 33646 BLAKE2B cf8d397602b147872e86c0f236731ec477e20775aa63a61162e66deb7d4b81ef91bd86b67d2dfddf5d6b160c37b7eab4ddb1d10975ada8dc13aebdc088e4483a SHA512 71434f131f34902210237940d75f07f250b296c3e1814e03f0eaae436321ca11ac63d0014c85ad571852e66b2e11545c9d0cf21d771c0c67210a60c1f9094cc2
+DIST openapi_spec_validator-0.7.0.tar.gz 36700 BLAKE2B aadaa34259900af7e2eb120ac7ccd6ea50d29ddd2c49edbd11c1c95f611dfc68edd580f4c5044a1c91ede2c421f2ef0b8e35dca89c5b997b6fc6211c68126b09 SHA512 a9e2b254d6855cfb4127eac44a0589e674748b2be6c68dd30e24144271096e82b336913b06e00407a88e6f3d3fdd0079a0c9489755dc68110d92d2b686f695ac
diff --git a/dev-python/openapi-spec-validator/openapi-spec-validator-0.7.0.ebuild b/dev-python/openapi-spec-validator/openapi-spec-validator-0.7.0.ebuild
new file mode 100644
index 000000000000..7762f60a672b
--- /dev/null
+++ b/dev-python/openapi-spec-validator/openapi-spec-validator-0.7.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="OpenAPI 2.0 (aka Swagger) and OpenAPI 3.0 spec validator"
+HOMEPAGE="
+	https://github.com/python-openapi/openapi-spec-validator/
+	https://pypi.org/project/openapi-spec-validator/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/jsonschema-4.18.0[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-spec-0.2.3[${PYTHON_USEDEP}]
+	>=dev-python/lazy-object-proxy-1.7.1[${PYTHON_USEDEP}]
+	>=dev-python/openapi-schema-validator-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# Internet
+	tests/integration/test_shortcuts.py::TestPetstoreV2Example
+	tests/integration/test_shortcuts.py::TestApiV2WithExampe
+	tests/integration/test_shortcuts.py::TestPetstoreV2ExpandedExample
+	tests/integration/test_shortcuts.py::TestPetstoreExample
+	tests/integration/test_shortcuts.py::TestRemoteValidatev2SpecUrl
+	tests/integration/test_shortcuts.py::TestRemoteValidatev30SpecUrl
+	tests/integration/test_shortcuts.py::TestApiWithExample
+	tests/integration/test_shortcuts.py::TestPetstoreExpandedExample
+	tests/integration/test_validate.py::TestPetstoreExample
+	tests/integration/test_validate.py::TestApiWithExample
+	tests/integration/test_validate.py::TestPetstoreExpandedExample
+	tests/integration/validation/test_validators.py
+)
+
+src_prepare() {
+	sed -i -e '/--cov/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/pytest-cov/pytest-cov-4.1.0.ebuild b/dev-python/pytest-cov/pytest-cov-4.1.0.ebuild
index 0a5189935ca2..574445f9435e 100644
--- a/dev-python/pytest-cov/pytest-cov-4.1.0.ebuild
+++ b/dev-python/pytest-cov/pytest-cov-4.1.0.ebuild
@@ -7,7 +7,7 @@ DISTUTILS_USE_PEP517=setuptools
 PYPI_NO_NORMALIZE=1
 PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
 
-inherit distutils-r1 pypi
+inherit distutils-r1 multiprocessing pypi
 
 DESCRIPTION="pytest plugin for coverage reporting"
 HOMEPAGE="
@@ -49,6 +49,15 @@ python_test() {
 	local EPYTEST_DESELECT=(
 		# attempts to install packages via pip (network)
 		tests/test_pytest_cov.py::test_dist_missing_data
+		# TODO: pytest-cov.pth breaks importing coverage
+		# https://bugs.gentoo.org/889886
+		tests/test_pytest_cov.py::test_append_coverage_subprocess
+		tests/test_pytest_cov.py::test_central_subprocess_change_cwd
+		tests/test_pytest_cov.py::test_central_subprocess_change_cwd_with_pythonpath
+		tests/test_pytest_cov.py::test_central_subprocess
+		tests/test_pytest_cov.py::test_dist_subprocess_collocated
+		tests/test_pytest_cov.py::test_dist_subprocess_not_collocated
+		tests/test_pytest_cov.py::test_subprocess_with_path_aliasing
 		# TODO
 		tests/test_pytest_cov.py::test_contexts
 		tests/test_pytest_cov.py::test_cleanup_on_sigterm
@@ -57,18 +66,5 @@ python_test() {
 		tests/test_pytest_cov.py::test_cleanup_on_sigterm_sig_ign
 	)
 
-	local src=$(
-		"${EPYTHON}" -c "import coverage as m; print(*m.__path__)" || die
-	)
-	# TODO: why do we need to do that?!
-	# https://github.com/pytest-dev/pytest-cov/issues/517
-	ln -s "${src}/coverage" \
-		"${BUILD_DIR}/install$(python_get_sitedir)/coverage" || die
-
-	nonfatal epytest
-	local ret=${?}
-
-	rm "${BUILD_DIR}/install$(python_get_sitedir)/coverage" || die
-
-	[[ ${ret} -ne 0 ]] && die "epytest failed on ${EPYTHON}"
+	epytest -n "$(makeopts_jobs)" --dist=worksteal
 }
diff --git a/dev-python/python-lsp-server/Manifest b/dev-python/python-lsp-server/Manifest
index 79bd52477678..32c491a730b8 100644
--- a/dev-python/python-lsp-server/Manifest
+++ b/dev-python/python-lsp-server/Manifest
@@ -1,3 +1,4 @@
 DIST python-lsp-server-1.7.4.tar.gz 97864 BLAKE2B 9832298391d72bf2f035f388694a7879d66546ead5a36837220cb3af5d8181eba198c04dd82747cba75f0478d256b001476c24b02bc679fc07cb41c7aedb0e66 SHA512 7aa96de6e51548e2854b55690698fe6c7bda60103c11ad5982df611c65569cec1ab13691727c92ec47d9ac44c34f233f872211a41041ea0969223e10e87d7e08
 DIST python-lsp-server-1.8.0.tar.gz 105548 BLAKE2B aa7f714bbc7e88d68224f9a51c3c811168ade36afce02fcdf95d3ffef55f7efc964aea6fb3c26bc88c3439744928f70914c136987c89a8bd146a2f54df579ead SHA512 b8050037e313261b653f0df170762126886ceef780d7ca35651c79967270d78d9930e464ccecc71a40ceee10b0265fd262d200e1e38c50ce04490ab364bc8389
 DIST python-lsp-server-1.8.1.tar.gz 106979 BLAKE2B 3d71de40b4fff5a0e50d1e16fb1aab330c90ddc68d255f212c8ec9a1c2cc5afcbafaa9d288f938d22b824852f6ca231d48f031df3dcc7e9d97699767b3548788 SHA512 f26e836013df9ddee05f17e7629bf7abfab96aae6fc4eba9d565203b324f6e3ac3e02cbcc1bd1b9ad8a4e0628d58476797bd55564e0307a53946df7a934df11b
+DIST python-lsp-server-1.8.2.tar.gz 107104 BLAKE2B 8a525e25f94c97cef23e6e9fad4ef9d7e5e0afaf1efdac9f5b98c84bc634ffaed2c19ebed80113a771a30b777285db166996ae25a3d34963e75909e183e082dc SHA512 4cfed043c69a6a390b27299d1e8e53c9ad0184e72b98503e4b3314b7104841a4f3667988e62dcaa88c54b166a1f8549e5b56a70fa69a33068bda5dc49299d642
diff --git a/dev-python/python-lsp-server/python-lsp-server-1.8.2.ebuild b/dev-python/python-lsp-server/python-lsp-server-1.8.2.ebuild
new file mode 100644
index 000000000000..e09678cdac54
--- /dev/null
+++ b/dev-python/python-lsp-server/python-lsp-server-1.8.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python Language Server for the Language Server Protocol"
+HOMEPAGE="
+	https://github.com/python-lsp/python-lsp-server/
+	https://pypi.org/project/python-lsp-server/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="all-plugins"
+
+RDEPEND="
+	dev-python/docstring-to-markdown[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.17.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-jsonrpc-1.1.0[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	all-plugins? (
+		>=dev-python/autopep8-2.0.4[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-6.3.0[${PYTHON_USEDEP}]
+		<dev-python/pydocstyle-6.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		>=dev-python/autopep8-1.6.0[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		>=dev-python/flake8-5.0.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		>=dev-python/pycodestyle-2.9.0[${PYTHON_USEDEP}]
+		>=dev-python/pydocstyle-6.3.0[${PYTHON_USEDEP}]
+		<dev-python/pydocstyle-6.4.0[${PYTHON_USEDEP}]
+		>=dev-python/pyflakes-2.5.0[${PYTHON_USEDEP}]
+		>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
+		dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
+		>=dev-python/rope-1.2.0[${PYTHON_USEDEP}]
+		>=dev-python/yapf-0.33.0[${PYTHON_USEDEP}]
+		>=dev-python/whatthepatch-1.0.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dep
+	sed -i -e '/addopts =/d' pyproject.toml || die
+	# unpin all the deps
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# broken by presence of pathlib2
+		'test/plugins/test_autoimport.py'
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "Automatically format Python code to conform to the PEP 8 style guide" dev-python/autopep8
+	optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
+	optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
+	optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
+	optfeature "Python docstring style checker" dev-python/pydocstyle
+	optfeature "Passive checker for Python programs" dev-python/pyflakes
+	optfeature "Python code static checker" dev-python/pylint
+	optfeature "Python refactoring library" dev-python/rope
+	optfeature "A formatter for Python files" dev-python/yapf
+}
diff --git a/dev-python/selenium/Manifest b/dev-python/selenium/Manifest
index bd6b87c70753..f7c2ef45fec1 100644
--- a/dev-python/selenium/Manifest
+++ b/dev-python/selenium/Manifest
@@ -1,2 +1,4 @@
 DIST selenium-4.13.0.tar.gz 9266949 BLAKE2B fbf6bf204b47648d67f3205729db232097a92bc3fbb491bb98308e1171d4a7b090f57f5153f07a642a5e6f476c12758496021fc2a7fc02ea7d525d9e4bef5fb7 SHA512 9f1531a5693d1f67a7fcafd0623bfaf85876fa0bf6292679a04d5b3976b1e8a46ea2718ae61b8f2da68005d7b6e11cda6eb9390b0094756a26fadec839e3efe8
+DIST selenium-4.14.0.tar.gz 9710348 BLAKE2B 038660990ce32c725b7c166031a7e78be5df2f9b1d0abe133e73566a9b9060c189310269fcf5db1330c2a2b1ed2901d8453b7134094528c73ca9dff899258914 SHA512 b41d81eeecdce428bfadfa3dc8c190512eb4243f710730519a3868987fa5f21db4a0fd7666b0dc9f40e56fbcf046f79a799ed32a31b7ab7e3c440d7f990a00bd
 DIST selenium-selenium-4.13.0.gh.tar.gz 78263115 BLAKE2B 8f06ee9e6a8ac8a63c3f016d3e310ba22ac0bd5566f06f6d6f71f269084bafa00f0627aaf1103f2f28a8785e81ace1652b64a271a23fdc74a56c0bf118ccd2ca SHA512 7156b28326492efa189ec4d5e53e131f4e8fb3aea97ce6632b0a9a81e04e238645b4994e348fa6e3f689e5472f569dfe95fdb11a6bd8456381b85d41fb0ede61
+DIST selenium-selenium-4.14.0.gh.tar.gz 78721372 BLAKE2B f57f5ed30f4439a83308909f5233187f924476de455d9b6504255e56a3217844d206968a96963c0f824c1a7dc5e69a196dde50a0cfb291820e6690be67a87c5e SHA512 b3b3f375ef0589cdc2afb454b50678ebe881d08cea841c697c9a5a4d745fc8ac84f941d2f5bbea9082c6e0c7052b7c5f08207947bb4389b0322c257dc81dcc89
diff --git a/dev-python/selenium/selenium-4.14.0.ebuild b/dev-python/selenium/selenium-4.14.0.ebuild
new file mode 100644
index 000000000000..2206ae325187
--- /dev/null
+++ b/dev-python/selenium/selenium-4.14.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+# upstream sometimes tags it as ${P}, sometimes as ${P}-python, sigh
+TEST_TAG=${P}
+TEST_P=selenium-${TEST_TAG}
+
+DESCRIPTION="Python language binding for Selenium Remote Control"
+HOMEPAGE="
+	https://www.seleniumhq.org/
+	https://github.com/SeleniumHQ/selenium/tree/trunk/py/
+	https://pypi.org/project/selenium/
+"
+SRC_URI+="
+	test? (
+		https://github.com/SeleniumHQ/selenium/archive/${TEST_TAG}.tar.gz
+			-> ${TEST_P}.gh.tar.gz
+	)
+"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/certifi-2021.10.8[${PYTHON_USEDEP}]
+	<dev-python/trio-1[${PYTHON_USEDEP}]
+	>=dev-python/trio-0.17[${PYTHON_USEDEP}]
+	<dev-python/trio-websocket-1[${PYTHON_USEDEP}]
+	>=dev-python/trio-websocket-0.9[${PYTHON_USEDEP}]
+	<dev-python/urllib3-3[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.26[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: we may need extra setup or deps
+		test/selenium
+
+		# expects vanilla certifi
+		test/unit/selenium/webdriver/remote/remote_connection_tests.py::test_get_connection_manager_for_certs_and_timeout
+	)
+
+	cd "${WORKDIR}/${TEST_P}/py" || die
+	rm -rf selenium || die
+	# https://github.com/SeleniumHQ/selenium/blob/selenium-4.8.2-python/py/test/runner/run_pytest.py#L20-L24
+	# seriously?
+	epytest -o "python_files=*_tests.py test_*.py"
+}
diff --git a/dev-python/shapely/files/shapely-2.0.1-cython3.patch b/dev-python/shapely/files/shapely-2.0.1-cython3.patch
new file mode 100644
index 000000000000..23fb0384e3f4
--- /dev/null
+++ b/dev-python/shapely/files/shapely-2.0.1-cython3.patch
@@ -0,0 +1,30 @@
+https://bugs.gentoo.org/898708
+https://github.com/shapely/shapely/pull/1872
+https://github.com/shapely/shapely/commit/fea6d0351a4422b1f9fefb508db7924981c18e43
+
+From fea6d0351a4422b1f9fefb508db7924981c18e43 Mon Sep 17 00:00:00 2001
+From: Joris Van den Bossche <jorisvandenbossche@gmail.com>
+Date: Sun, 8 Oct 2023 11:12:28 +0200
+Subject: [PATCH] Fix for cython 3 compatibility (#1872)
+
+--- a/pyproject.toml
++++ b/pyproject.toml
+@@ -1,6 +1,6 @@
+ [build-system]
+ requires = [
+-    "Cython~=0.29",
++    "Cython",
+     "oldest-supported-numpy",
+     "setuptools>=61.0.0",
+ ]
+--- a/shapely/_geos.pyx
++++ b/shapely/_geos.pyx
+@@ -8,7 +8,7 @@ import warnings
+ from shapely import GEOSException
+ 
+ 
+-cdef void geos_message_handler(const char* message, void* userdata):
++cdef void geos_message_handler(const char* message, void* userdata) noexcept:
+     snprintf(<char *>userdata, 1024, "%s", message)
+ 
+ 
diff --git a/dev-python/shapely/shapely-2.0.1-r1.ebuild b/dev-python/shapely/shapely-2.0.1-r1.ebuild
new file mode 100644
index 000000000000..7c35e5c247df
--- /dev/null
+++ b/dev-python/shapely/shapely-2.0.1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Geometric objects, predicates, and operations"
+HOMEPAGE="
+	https://pypi.org/project/shapely/
+	https://github.com/shapely/shapely/
+"
+SRC_URI="
+	https://github.com/shapely/shapely/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="
+	>=sci-libs/geos-3.9
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${DEPEND}
+	>=dev-python/cython-0.29.32[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.0.1-cython3.patch
+)
+
+EPYTEST_DESELECT=(
+	# Should be able to drop these in next release (>2.0.1)
+	# https://github.com/shapely/shapely/issues/1670
+	# https://github.com/shapely/shapely/issues/1855
+	tests/test_parallel_offset.py::OperationsTestCase::test_parallel_offset_linestring
+)
+
+distutils_enable_tests pytest
+
+python_compile_all() {
+	rm -r shapely || die
+}
diff --git a/dev-python/sip/sip-6.7.11.ebuild b/dev-python/sip/sip-6.7.11.ebuild
index 2fa65be6ae34..5794e6536a7e 100644
--- a/dev-python/sip/sip-6.7.11.ebuild
+++ b/dev-python/sip/sip-6.7.11.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 
 LICENSE="|| ( GPL-2 GPL-3 SIP )"
 SLOT="5"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~ppc ppc64 ~riscv ~sparc x86"
 
 RDEPEND="
 	dev-python/packaging[${PYTHON_USEDEP}]
diff --git a/dev-python/structlog/Manifest b/dev-python/structlog/Manifest
index 1cf56c903ebc..60c4fb662edf 100644
--- a/dev-python/structlog/Manifest
+++ b/dev-python/structlog/Manifest
@@ -1 +1,2 @@
 DIST structlog-23.1.0.tar.gz 746300 BLAKE2B 94e6099729803fff717c24922f90be0484f045e4fe231398242a890e6e18359f9a5c231985818d655141e978fe06546f36540a96ebe332f5bbf6d5500fc111c0 SHA512 24e28791e12a4a106062368771385ac06e80bd50fb051d2a71205cf9e6ebf92ca8a4e6c0efefd8d862699ac8dee9b4d1ccf4ee33f8d76233acf5256d69f9593c
+DIST structlog-23.2.0.tar.gz 749288 BLAKE2B c5a619ddacc04e6f2377c66aa343ecfddb8001d5d87c3f10859c2644ce427150771abe4942d57a9ea6db1029af5bde825a0a99218921beea08c4fd147fc5c1cb SHA512 01ddaf3b819da66beefef1810e6d460a2e5ce37f6be3dee144411a3a5db7c81bdfd83a0843172a921406596a2b9f1f87de08caf881c7d701496825203d13bdad
diff --git a/dev-python/structlog/structlog-23.2.0.ebuild b/dev-python/structlog/structlog-23.2.0.ebuild
new file mode 100644
index 000000000000..a11438290230
--- /dev/null
+++ b/dev-python/structlog/structlog-23.2.0.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Structured Logging for Python"
+HOMEPAGE="
+	https://github.com/hynek/structlog/
+	https://pypi.org/project/structlog/
+"
+
+LICENSE="|| ( Apache-2.0 MIT )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~riscv ~x86"
+
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/xlsxwriter/Manifest b/dev-python/xlsxwriter/Manifest
index eb9a0db40990..0eb74f6179e2 100644
--- a/dev-python/xlsxwriter/Manifest
+++ b/dev-python/xlsxwriter/Manifest
@@ -3,3 +3,4 @@ DIST XlsxWriter-RELEASE_3.1.3.gh.tar.gz 37317330 BLAKE2B 08dd76cfb7bcb336d0fa642
 DIST XlsxWriter-RELEASE_3.1.4.gh.tar.gz 37324495 BLAKE2B ebedb84e46eb73e750b9442969c397bb9c77af807c1bd78fe956bf304ae942cb8575f8f410631c7ae542f9e16c1d5c76385ba232fec109bc5ccf59fd1843b2c3 SHA512 2faa7a9fc03a620c3a1f9230685b2bd09c5b282fb783d36a28de225b1d5e64663db32cd5da1a16ffe3cb4bc886f77b79eb7f13ce460c18f6e88667b9979e504e
 DIST XlsxWriter-RELEASE_3.1.5.gh.tar.gz 37348174 BLAKE2B ae86c45f63dabe7678a476fcc7aae60de36a0b4b1a422b83ecfb6143ab0b1563ee274ea715aca7147e1fa184a3311c9f7c92c3b7d3c01bf934d5772c635862e3 SHA512 c2da3a2dc52e7f9b887e71828452484edabd99e882a3cbeed9969e04fef538cac2b48042900e9ac4bf8e41ed21178aa498b3ebecd018d2bdd31cad29b81c040b
 DIST XlsxWriter-RELEASE_3.1.6.gh.tar.gz 37354453 BLAKE2B a2b54fb38d7c7a60b5814968431b781f533dc0803ed23aed38df4e78ea0d5f9315cddb00ec6d59db340e5cf19142cac2179ace53d42e903d8b0f2cfe64b0385b SHA512 4a7996163ff25881210b729d025998343bf9f142693a40e6f73039a3b4582e668699bbd27e1a77c0bbfba61f2160ecd8cf1179206d011217b46cf11d17b56bc4
+DIST XlsxWriter-RELEASE_3.1.7.gh.tar.gz 37369556 BLAKE2B e7eefd4fac6a791f917e19fd5559ac1fef436a0b304a1db9d436e21a2fc412b73de94a2a05a81acec5e297a07a11bdc953774947ec196fe666beb2ce85a2a21a SHA512 fd144eebbcb04e914aff1c2980353f0ddb88ef7841c70d1681561c86d925a201000931dba18bc15965fdb195bf3b2ea959b7c1ba21be8d1c7c6ed678c90c0fc7
diff --git a/dev-python/xlsxwriter/xlsxwriter-3.1.7.ebuild b/dev-python/xlsxwriter/xlsxwriter-3.1.7.ebuild
new file mode 100644
index 000000000000..ebaeb3e4f89f
--- /dev/null
+++ b/dev-python/xlsxwriter/xlsxwriter-3.1.7.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+TAG=RELEASE_${PV}
+MY_P=XlsxWriter-${TAG}
+DESCRIPTION="Python module for creating Excel XLSX files"
+HOMEPAGE="
+	https://github.com/jmcnamara/XlsxWriter/
+	https://pypi.org/project/XlsxWriter/
+"
+SRC_URI="
+	https://github.com/jmcnamara/XlsxWriter/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+distutils_enable_tests pytest