Adding metadata

18 files changed, 500 insertions, 4 deletions

diff --git a/dev-python/aiohttp-socks/Manifest b/dev-python/aiohttp-socks/Manifest
index 403af00aaba7..982493d89282 100644
--- a/dev-python/aiohttp-socks/Manifest
+++ b/dev-python/aiohttp-socks/Manifest
@@ -1,3 +1,4 @@
 DIST aiohttp-socks-0.8.0.gh.tar.gz 13190 BLAKE2B 049655c526b5d7b64af79ef5f885d0f949edf1eeb4f3fb6e8a3cfc97738ebeb4663d68017761808279e938f477f9509123d8d6c6f4133287d1743dc2a8a021ed SHA512 e533be7059ee6914f919f5113596708732f70f4f1093adaccc6a829699c2aea157897c5398d9134acb0b2a11c8118f9d4f453792d8d8d14b10b207ca19ada2e7
 DIST aiohttp-socks-0.8.1.gh.tar.gz 13336 BLAKE2B 39ad70fe9f1eb8d4f743c4d65dafb82c0878808b0861f899b12ba437ef80a9e4f077485c37fb8267588ac307446ea0c2d26c02de05cd3f44a76896610cc85cc4 SHA512 f8d30d6c6aa32968bbcf075d016ecc542835f6bdc2f0bbe1ffa06e580ab851a4f5abdac8d008e639d0cff49829a299afa42a80e159d7fece67439e5384817d85
 DIST aiohttp-socks-0.8.2.gh.tar.gz 13563 BLAKE2B 4e16abf9ed3f31fbbb8604587f2249a5387dbb1acc8a29d1999b52e84a5be3a0795073867a18c97c5c397f0742d75d4246a71484066bb8970a3d2356b482c8da SHA512 7fd7863bb7aa315a678516f02c2b4c2ba9dfb9e38ac7f1dd7ea78f474f005ee82334262c1bc31ba289554aa1a9e657a2f16dcf1950f16a2b959563b4016c3e88
+DIST aiohttp-socks-0.8.3.gh.tar.gz 13291 BLAKE2B e7e757d966bff9943bb162e0aa4dce597afeb044da84db80b39a80b0431fa442850a4b3c09aad06fb8c78f90d508be5190dab1ef1d543e42a4a161ab056e0935 SHA512 53e164be4f8459c7a4df015f60a8d70971473a0ba7a39b32cdbd0499e7316d0d211ddead7e3c065516b1082804fbbedca8e75bb7b59f1abd893b395840b147dc
diff --git a/dev-python/aiohttp-socks/aiohttp-socks-0.8.3.ebuild b/dev-python/aiohttp-socks/aiohttp-socks-0.8.3.ebuild
new file mode 100644
index 000000000000..7080a32c617d
--- /dev/null
+++ b/dev-python/aiohttp-socks/aiohttp-socks-0.8.3.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="SOCKS proxy connector for aiohttp"
+HOMEPAGE="
+	https://pypi.org/project/aiohttp-socks/
+	https://github.com/romis2012/aiohttp-socks/
+"
+SRC_URI="
+	https://github.com/romis2012/aiohttp-socks/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aiohttp-2.3.2[${PYTHON_USEDEP}]
+	>=dev-python/python-socks-2.0.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/attrs[${PYTHON_USEDEP}]
+		dev-python/yarl[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/tiny-proxy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/ansible-compat/Manifest b/dev-python/ansible-compat/Manifest
index 783f6953834c..9fe7a0a0787a 100644
--- a/dev-python/ansible-compat/Manifest
+++ b/dev-python/ansible-compat/Manifest
@@ -1,3 +1,4 @@
+DIST ansible-compat-4.1.10.tar.gz 72127 BLAKE2B 1a3c172d30a68f14a163d2ad04180856d365424b99c593933c02c83afde7008f937a86f068fd4d09741eda731a0ae9801274764e349f56fd4a64ccdf1ff831b7 SHA512 f50d07d753fa2f3985efca4aa326d3608d55b3f8d00c42c3bd9ba95c6e40c7a717160220dd602374124ebbfc94c495819b4b738cb385875033876aee458d14b4
 DIST ansible-compat-4.1.5.tar.gz 68562 BLAKE2B b28b6e5185b29a55d452e9c72636b31a1a35c68f207cc07376fafd0a70335966d06f927a803582b715b29c090a80aa5aa2663cba54221cb4d2dbcd9a11ec5a7a SHA512 6da0bab56237a6447462ed9ef528711eb4c998de2732ec021e8257d2baf6cbb1e1435707440b4c0d122fb4f938c855693bcd555e147613f230105e3af74c00a6
 DIST ansible-compat-4.1.7.tar.gz 69900 BLAKE2B c8549573d4a4325579b6026b6b5fad5fe0abb0fdcf07a4c8e0699c040a97409632202f0a38703a113f9a86f68328642d8d5c4b897e3601a13737bc2a4deb4d88 SHA512 b3175573113a3df37923e582c191dd5f4522c3a2171cc93b186e49d5ca6baa2fd8b2e7af2e9457bb21b5bd6df6c9f82fccc10b5e2bfeda84c890c4cbc37fafb4
 DIST ansible-compat-4.1.8.tar.gz 71895 BLAKE2B 19a3cdc953e678a82f6b187ca224c9f10eccf36f57aba2305bf00bc7b3606dfc2caddef7331cd920ae67731b904bc21b1af19fb0945625b050162e0edc8ab652 SHA512 0b9157fd60e1ae9b26c103118fad3e8e28f872c7093d0c6238b047072ac3232e7f9a4c50001125850f4bdd0ba06a1efd8df44a994b1dfaaf7d3f3cb2cb888524
diff --git a/dev-python/ansible-compat/ansible-compat-4.1.10.ebuild b/dev-python/ansible-compat/ansible-compat-4.1.10.ebuild
new file mode 100644
index 000000000000..942ca69ac011
--- /dev/null
+++ b/dev-python/ansible-compat/ansible-compat-4.1.10.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Contains functions that facilitate working with various versions of Ansible"
+HOMEPAGE="
+	https://pypi.org/project/ansible-compat/
+	https://github.com/ansible/ansible-compat/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="
+	>=app-admin/ansible-core-2.12[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.6.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/subprocess-tee-0.4.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-plus[${PYTHON_USEDEP}]
+	)
+"
+
+# All these tests attempt to connect to galaxy.ansible.com
+EPYTEST_DESELECT=(
+	test/test_runtime.py::test_install_collection
+	test/test_runtime.py::test_install_collection_dest
+	test/test_runtime.py::test_prepare_environment_with_collections
+	test/test_runtime.py::test_prerun_reqs_v1
+	test/test_runtime.py::test_prerun_reqs_v2
+	test/test_runtime.py::test_require_collection_no_cache_dir
+	test/test_runtime.py::test_require_collection_wrong_version
+	test/test_runtime.py::test_require_collection
+	test/test_runtime.py::test_upgrade_collection
+	test/test_runtime_example.py::test_runtime
+	# pip, failing due to internets
+	test/test_runtime_scan_path.py::test_scan_sys_path
+)
+
+distutils_enable_tests pytest
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 857b3b1df9df..14eeb16656b0 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.28.35.gh.tar.gz 692481 BLAKE2B fe5c5906598be2aaef8524a0333751bc2368
 DIST boto3-1.28.38.gh.tar.gz 694902 BLAKE2B 2f33b0e1015c3fa15d16c990f709a782ddc0c9903fca8fd6d489e45fd7e2c3a939082f22f8c8c090a1ec6acdf96a6a71e5689bd3317c8f984e83bb36534df814 SHA512 a734d1a5a7532d09dcec1f36d9fcc9e1e03d388cfb5a86a97318c88bdeb2fb3fec6d1770e0e6b9ac7e801ec862d5e42ae48a315f4b01b398712be1f64c651273
 DIST boto3-1.28.39.gh.tar.gz 696213 BLAKE2B 2a71b9ca5416d6eb1fbd2b21c67c2eca95409acced1c67b8345355d61eece063f589c2cb81ee4c81fd2dda54e66268d8269a8bb2f251a6d95c51a18366b5d861 SHA512 cd62663568aabc87de3d0c669b7cf131072aa596d9a341a19a357d8a289458ebb1e18b6618ab454753d0d385b53d450aaf836b5fb1bf04d30b40b6b314308908
 DIST boto3-1.28.40.gh.tar.gz 696495 BLAKE2B 297a32f989dc0c1bc8f0a5cd797c5f2d52ea9b83fc202b0889fdf89e7233693fe3a61972d30bf58f05e528f62c8ffaf24ea255c4ef1972b70b546c8c13b692b5 SHA512 2493d647a5a8c399fb3e3a4a9bbf64d242ba78263d33ac8e019036035522574ecc39a5fd0bcbddf2492aa3bd1401ac3c24f0ec92c6ac62cb2898a8fbeedd8651
+DIST boto3-1.28.41.gh.tar.gz 697348 BLAKE2B 83ec56d2e2a4f9ebad061f1b7650425a074d53427f4c691c23d5d9746c14bf6c4326bdca17b13a13d70723dd8e62d2e9977452ab9664556cfa63a93043c9b832 SHA512 bdd62739f532919803cab3303d11cf5362fbca8f1b6045e53b584705b8dcce7eb0d17fd1fdac02ccd49386937f1d6edaadfca5b1b3ac02d42dfe629123e31ceb
diff --git a/dev-python/boto3/boto3-1.28.41.ebuild b/dev-python/boto3/boto3-1.28.41.ebuild
new file mode 100644
index 000000000000..e654679ffe12
--- /dev/null
+++ b/dev-python/boto3/boto3-1.28.41.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit} \
+		-p xdist -n "$(makeopts_jobs)" --dist=worksteal
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index afa471912dd3..2f9331af0044 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.31.35.gh.tar.gz 11877715 BLAKE2B 64c90cb764ab47fdf9f644b4819c9fc
 DIST botocore-1.31.38.gh.tar.gz 11926426 BLAKE2B 1f668a23e52f3033f3b12e6dfeb086d21eb6fd3e163ab12e5c07ccbf4a4a11df9504bac99d6b68a3001f7f1c5849a4d5340ddf5b838b349fc3aed580f6733a03 SHA512 800301dfca0a284d53e252bfbeff9e705120e087c45167bfee8ad343e7873a1eb69d2be725ef8a81bbd7c31fa2016908bfb3729d560d44b36f2ca160aac4663e
 DIST botocore-1.31.39.gh.tar.gz 11927900 BLAKE2B 28b1fe5beea5b586b3bf6434ad3ab32b8f781ae79ddc39a142a53f5e87d136bcad4e1d1baaeee2afc4b09c3e4b02f583817d6471d09dd145b881fafdf71c73e1 SHA512 2dc271ace551ff4c9a25d6ed4c3a31dbdd90cb0f1c4088e1c71b220e20f4b7008fd41b2682c838c5e3fe911c35758a99502fe874c45c51092a83150a14d25edc
 DIST botocore-1.31.40.gh.tar.gz 11933400 BLAKE2B c01958831fd477db79c7b723f799abfb2f02c85bf1ea67adc6ecb2bfba13b0f945e30e11a5d3103a3bd54f913c9386327127c5eaba792b6a42e8a4bfcc21d4f4 SHA512 7bbbb9bf9821bf6d24425de4694d1d0c871350b3fbb59488ff543c1569b41e669abfdc815840e1c912c3ade20e78a7fa8600f0d88ad220cee5bfc31b3138ed66
+DIST botocore-1.31.41.gh.tar.gz 11935773 BLAKE2B 6bf4c1f7c3b3d9115c53f5cc833688097d0282eaacc868156fc9d29721e9d9cbf75e31d34ebba5c65b543be7bdccd6848de7cac5f8fb43d1fac63896b6e3f39e SHA512 add75b55a3c6941cd96100ca9ce846f616d638ce18bad658776acfc8b9ab9526da48069393a2ea54d24e93a25141ef2496837b04395956f82319f9a3d8fe5ad4
diff --git a/dev-python/botocore/botocore-1.31.41.ebuild b/dev-python/botocore/botocore-1.31.41.ebuild
new file mode 100644
index 000000000000..10b7950a4ee2
--- /dev/null
+++ b/dev-python/botocore/botocore-1.31.41.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x EPYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit} -p xdist -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/coverage/Manifest b/dev-python/coverage/Manifest
index 1e538d99fc21..fc4503877a2b 100644
--- a/dev-python/coverage/Manifest
+++ b/dev-python/coverage/Manifest
@@ -1,2 +1,3 @@
 DIST coverage-7.2.7.tar.gz 762575 BLAKE2B 20a800c3cd62095aacdfa4853613a3fd579abacd9051878ee2b308360db181ad45b68a0866236666826efc510d4a0328273d63c78c42fa4a7419ac98f85cf3f4 SHA512 01ed5ef8ddb600b8a7443200b568eb5d8aa7d652f408617f78a2e1251a5f091ee05188a7d383acd530f29b688b67a4bf2dc2e1241efffe8b9d0f70f44c646f33
 DIST coverage-7.3.0.tar.gz 763902 BLAKE2B dbd49200ef5ca167b9ae11b76bae1d8dd682289d14c657029227d0f2f1cc149ddde7c571add7165e10a150d2bd591d9bc988a7d306d01dd3eb34e8a5098d66cd SHA512 3b394c3c96ca8484641585ce26c27100153892a77369e14e3596fe604a98ac0f9b33189d679fffd9fa80a41ac4bfa6a64dfe97e586833b39707ecc7f5aa43c35
+DIST coverage-7.3.1.tar.gz 764806 BLAKE2B 7399c7df63d0a546e20797c52780376bb8f65578753ffae3bb15901bd4fb7b4c0d8360b2dbc445e038d226af9ddf0b39c38c16fa70d9690b62477e5e75dfb51d SHA512 deeeab41ca53cdda83fe233f63bcf14909b96dfa0710d882dcaa9f81f4884ef7b39aaf177f832ce0f66f1fb88ad4b97d37ef2adfa2540d551352ed48af1926b2
diff --git a/dev-python/coverage/coverage-7.3.1.ebuild b/dev-python/coverage/coverage-7.3.1.ebuild
new file mode 100644
index 000000000000..5340f5b50ba4
--- /dev/null
+++ b/dev-python/coverage/coverage-7.3.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Code coverage measurement for Python"
+HOMEPAGE="
+	https://coverage.readthedocs.io/en/latest/
+	https://github.com/nedbat/coveragepy/
+	https://pypi.org/project/coverage/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		>=dev-python/unittest-mixins-1.4[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/addopts/s:-q -n auto::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+test_tracer() {
+	local -x COVERAGE_TEST_TRACER=${1}
+	einfo "  Testing with the ${COVERAGE_TEST_TRACER} tracer ..."
+	epytest tests
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: fails because of additional "Terminated" print on SIGTERM
+		tests/test_concurrency.py::SigtermTest::test_sigterm_threading_saves_data
+	)
+	local EPYTEST_IGNORE=(
+		# pip these days insists on fetching build deps from Internet
+		tests/test_venv.py
+	)
+
+	"${EPYTHON}" igor.py zip_mods || die
+
+	local -x COVERAGE_TESTING=True
+	# TODO: figure out why they can't be imported inside test env
+	local -x COVERAGE_NO_CONTRACTS=1
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=_hypothesis_pytestplugin,flaky.flaky_pytest_plugin,xdist.plugin
+
+	local prev_opt=$(shopt -p nullglob)
+	shopt -s nullglob
+	local c_ext=( "${BUILD_DIR}/install$(python_get_sitedir)"/coverage/*.so )
+	${prev_opt}
+
+	if [[ -n ${c_ext} ]]; then
+		cp "${c_ext}" \
+			coverage/ || die
+		test_tracer c
+		rm coverage/*.so || die
+	else
+		test_tracer py
+	fi
+}
diff --git a/dev-python/hvac/Manifest b/dev-python/hvac/Manifest
index b6df5c4736f5..f8387afbe6dc 100644
--- a/dev-python/hvac/Manifest
+++ b/dev-python/hvac/Manifest
@@ -1 +1,2 @@
 DIST hvac-1.1.1.gh.tar.gz 317494 BLAKE2B 3a6849a1f41a8e45f436baae3f5e2ba400c4b7cc49b253eca1741d8685d0499a9cfd42d3eaaac330ac949f64b6e9dc66d209df0efe2e9248b5750eedecca924e SHA512 f5de49b33c257ccfcdc662ed269e843d3f76912bc2e773663e72c8425d1ccc317cdc137dc7bb978e0e966bc6248f34953306fc919fba2cc8f97f0a695b5daf2b
+DIST hvac-1.2.0.tar.gz 310344 BLAKE2B be81cfb9b2632da9146ef9153017e478e121a908bfb7a4838169f0a1984b91fe29d9efeb887352e02244136ba96c1ae98618de88ecc238f2f1a6cf2d46b45401 SHA512 61fee19dae22661c8c9aac56656b3038083ff6487773ea7fd62cb9655b55f8aaf60d40760125179c790a02323ea8711829261969695459c67834c4bdd315312d
diff --git a/dev-python/hvac/hvac-1.2.0.ebuild b/dev-python/hvac/hvac-1.2.0.ebuild
new file mode 100644
index 000000000000..15ba8d5374f5
--- /dev/null
+++ b/dev-python/hvac/hvac-1.2.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="HashiCorp Vault API client"
+HOMEPAGE="
+	https://github.com/hvac/hvac/
+	https://pypi.org/project/hvac/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/pyhcl-0.4.4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.24.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/jwcrypto[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/semantic-version[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# ldap_test is not packaged.
+	tests/integration_tests/api/auth_methods/test_ldap.py
+	# https://github.com/lepture/authlib is not packaged.
+	tests/integration_tests/api/auth_methods/test_oidc.py
+)
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index eabccb4101c7..44e4b87ea7c4 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -8,3 +8,4 @@ DIST hypothesis-6.83.0.gh.tar.gz 9380147 BLAKE2B ec878cbd6def0cfd8b8c638775c00e4
 DIST hypothesis-6.83.1.gh.tar.gz 9380569 BLAKE2B a1af77a089ade4a957fd66036095436861ff96dca3c9670ae87f28ba4223531168175329a43574c744ce0d91786bed2ed911837642c9506341f94875080e5a5b SHA512 4649061550b0d1ac96217c5cfd5e6eb44352eee6b81861fd93138fffaac3d85a87644c3faff221f6bb389f2bebdc47436f5ea70fc746aada2d25c78a74a21fec
 DIST hypothesis-6.84.0.gh.tar.gz 9383310 BLAKE2B 3b269214d341dbdf88b529e3c04dc613eb0d79db4748462b0637f118daceb721fcb4779ea030fc872ebab272e9b92419c7ac0b33ee7648ff73a425bc272cd095 SHA512 956db7837d6cf12e425d088593b227d777c56fc51f49e62e6767141d307c9df10a3273e30532eea6288689ed58e03ab9bd975c66fec940d0a72f8079e359d918
 DIST hypothesis-6.84.1.gh.tar.gz 9385220 BLAKE2B 44fd42635f5abd87fbead97f334650da7c3ff2d69522f6e22edca9f5eccea9f82315099f6c9bbac2bba5af0a8fab477bbfbe65a7beb68a3821208e0e03602ede SHA512 fab9e337e0d445c2994892268ec9a660032c87cc0bd261138abd174c0e103c2952557ec28516e719a6264d3c7fcab621995c46886d358240c086dc9669085dbe
+DIST hypothesis-6.84.2.gh.tar.gz 9385845 BLAKE2B 91b8dc464f4545ae800e44d2775715d7db46d727db301cdfd6c269a00cac2e32e59bdedbb1bc631d699a6548c77e9ddf16344a4fd759901db420af2975d9bf03 SHA512 618440a6bd9836f7929ab5eaefba0be84292ca12f134bed6562791aae298df85cfc7990a1e54e7488474331245d9bbb436d25764cb7c1baf1417584b0408ba83
diff --git a/dev-python/hypothesis/hypothesis-6.84.2.ebuild b/dev-python/hypothesis/hypothesis-6.84.2.ebuild
new file mode 100644
index 000000000000..4c56e9453286
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.84.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" --dist=worksteal \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..e9da2ac43cac 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index ddb5b0f1787e..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -2,9 +2,11 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
-  <email>cyber+gentoo@sysrq.in</email>
-  <name>Anna</name>
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
  </maintainer>
- 
- <origin>gentoo-guru-overlay</origin>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pytest-aiohttp/Manifest b/dev-python/pytest-aiohttp/Manifest
index 006695422700..271862f283b7 100644
--- a/dev-python/pytest-aiohttp/Manifest
+++ b/dev-python/pytest-aiohttp/Manifest
@@ -1 +1,2 @@
 DIST pytest-aiohttp-1.0.4.tar.gz 11868 BLAKE2B d964fe29ebe10e80391ebcbe4fc73bf37e2d8568c4d7679493ce68392b5722d75735798a78f388134d60b9c922bac116b0d453cabae5a95fc06c4288cc5d4c8e SHA512 baf87e3aa229e8a4ab6746d277a923436ad2e0625825581c94a2fb0a9bbcd309bfc55186f8866589b65a75ccfd7d5b494d71554359724c0b2c9541ea94a177d8
+DIST pytest-aiohttp-1.0.5.tar.gz 12209 BLAKE2B b02154239a6073bafac3d8be70a7ae8ff13fefdd09941db558c0b1ad31d14c5e29131209f157ab418202852a2d97f151d765cfffe0de06aac57f0c983ea99518 SHA512 b8421c63e4d5caa9742a013a6d1fd3c010b5e4a48e4f5c1a07ddfb7b05853ce6a7a0d65ce78493fd607f59c669d31c75d97a9022048e6a60cbc90a19a48dd02c
diff --git a/dev-python/pytest-aiohttp/pytest-aiohttp-1.0.5.ebuild b/dev-python/pytest-aiohttp/pytest-aiohttp-1.0.5.ebuild
new file mode 100644
index 000000000000..34c0bba5b39b
--- /dev/null
+++ b/dev-python/pytest-aiohttp/pytest-aiohttp-1.0.5.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="pytest plugin for aiohttp support"
+HOMEPAGE="
+	https://github.com/aio-libs/pytest-aiohttp/
+	https://pypi.org/project/pytest-aiohttp/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/aiohttp-3.8.1[${PYTHON_USEDEP}]
+	>=dev-python/pytest-6.1.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-asyncio-0.17.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-6.2[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# warning doesn't seem to be emitted for some reason
+	# doesn't look very important
+	tests/test_obsolete_fixtures.py::test_loop_fixture
+)