Updating liguros repo

10 files changed, 327 insertions, 48 deletions

diff --git a/dev-python/aws-sam-translator/Manifest b/dev-python/aws-sam-translator/Manifest
index 944cdec687a4..59a4ed1a44c8 100644
--- a/dev-python/aws-sam-translator/Manifest
+++ b/dev-python/aws-sam-translator/Manifest
@@ -1 +1,2 @@
 DIST aws-sam-translator-1.25.0.tar.gz 5144283 BLAKE2B f04f2715f140b2ea0df71bb830e033442d212db88ae1f08a8027d0875e6c4d2a3404f2855d54109b1623e3c290aa7ee8f2d7d205ce2163ebdfbddcbb46215fc8 SHA512 4dd428750c7e0c73987dea89b8a257fad33a59680c282136f6adaff16e3695123d0d3d42b45cd85da5311e1b38f2a2879d54170db7d5303e6e8d9086becf66b1
+DIST aws-sam-translator-1.26.0.tar.gz 793347 BLAKE2B 701cefdf0f2c220b96104f6a0df4d2c5d2b9ccd9076a216601414407c4fe5fabfef4fd3d6cbd305a6ce94587e8d4fe937ae730c30bbb785f65a6cf53564f41d8 SHA512 2ffc3953d8591e9e4bcc9d593cb34fdc57580f043ee19e6db49068bf0c5d870c5d5902ef3887400256c36774d0b3ce0dfaa962e6be3f6066fbe1caf31bd14498
diff --git a/dev-python/aws-sam-translator/aws-sam-translator-1.26.0.ebuild b/dev-python/aws-sam-translator/aws-sam-translator-1.26.0.ebuild
new file mode 100644
index 000000000000..a14c82857479
--- /dev/null
+++ b/dev-python/aws-sam-translator/aws-sam-translator-1.26.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="A library that transform SAM templates into AWS CloudFormation templates"
+HOMEPAGE="https://github.com/awslabs/serverless-application-model https://pypi.org/project/aws-sam-translator/"
+SRC_URI="https://github.com/awslabs/serverless-application-model/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/serverless-application-model-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/boto3-1.5[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.6[${PYTHON_USEDEP}]
+	>=dev-python/six-1.11[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# remove pytest-cov dependency
+	sed -r -e 's:--cov(-[[:graph:]]+|)[[:space:]]+[[:graph:]]+::g' \
+		-i pytest.ini || die
+
+	# don't install tests
+	sed -e 's:"tests",:"tests", "tests.*",:' -i setup.py || die
+
+	# deps are installed by ebuild, don't try to reinstall them via pip
+	truncate --size=0 requirements/*.txt || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/partd/partd-1.1.0.ebuild b/dev-python/partd/partd-1.1.0.ebuild
index 556d2aef4c19..d7fb0ea113a6 100644
--- a/dev-python/partd/partd-1.1.0.ebuild
+++ b/dev-python/partd/partd-1.1.0.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
 
 RDEPEND="dev-python/locket[${PYTHON_USEDEP}]"
 DEPEND="${RDEPEND}
diff --git a/dev-python/pip/Manifest b/dev-python/pip/Manifest
index 2b4569e4dd8b..8af744a70025 100644
--- a/dev-python/pip/Manifest
+++ b/dev-python/pip/Manifest
@@ -1,6 +1,7 @@
 DIST pip-20.0.2.tar.gz 6445047 BLAKE2B 8f6e0a8908cf594c8d51818942b0839f59a495697a95dcc0347235e90cbe6d7f035f155761e7da9cfca1ba08b2c5a2c5def52c60c381f5428ef48efd1b6b5131 SHA512 f9965944ca0f319d01db1638ce97cf64772afff1778b3b1271155de73208cfcb3954d89a469c1143c0bf3288a53d4446165a49df994374b16ac6f7ffdae85857
 DIST pip-20.1.1.tar.gz 6503229 BLAKE2B 5b0409042c970ec47fa6f947b21a53aca43563a6bb442fd5f91788fa97caf7167a84b4f581de87453eb0e55657d2ccd11dca2d1815c3bfe9ef5923994306a6db SHA512 ee7b0345c08fbe0215811d07b4c57c1ceece826871842f6d1c174d82e8eee0ad810aa5413d6763ecd5a513e151792a53c36623ab99d2049555ef2542d32d1658
 DIST pip-20.2.1.tar.gz 8717384 BLAKE2B a547b85296da67662080309fc8630c8ad3b0a6898319bd523719b411f0919cb15819e4b8e794aad9e7c13d6af2159c102ead0bd8d8f89e0e618017a8552cf985 SHA512 52abcc336a3c06b0e2b790a7fd4283483b46c1cc6be8e89d8640072ae4517d79afa074683622f8374ebf76a7c3516a05f261e35363327d5d68fb15ec6e6718cd
+DIST pip-20.2.2.tar.gz 8719081 BLAKE2B 642a8e9b2f7c3dc08b7e8f7874b7d1d988622f50b9430939060c3b9c086ae7bdaf4a58e9709376e0d36411fb2b492d4e44ddb6282f1fe12d7c8b9ecfdb1c0482 SHA512 0b000977f169900eebd4afeabfc7bd59b104246bbb048ce5b4db7f701e20ef1caef22c7ca2311843eafc4a37abbb81a74beddddf655eeaf2e33e3949d5a811e6
 DIST pip-20.2.tar.gz 8715960 BLAKE2B dbcec865314ba0b65112e42477a2c48dc9a60592a07a834d3886025489fcd8de4c83733044d1ad84dd87af084677b2f406d5d8faa301853ab844b3770be168de SHA512 77db7c618b492cbdef54ef98d4e9a94735a809148fb08ef7d065fbeaf047ced26ddc20d0395a0b2db079c66175a267fc15717a24def70392182326b2c659e6f1
 DIST setuptools-44.0.0-py2.py3-none-any.whl 583230 BLAKE2B 823e6792471660f247e30a938aa869d345a63db7294e5f9b4bd88f15a7694779011d29740fe317149620985f705fc6e18cbb07a18e5680cc11d7c229ffbc74f6 SHA512 7006fd303181afbeeec0e30cafb9fd1e4d3c6f55cfdd6343fedbc32b17dbb96b3d96ae37f4db27bfb168738727474cf425904ec280ff1d2b789fc48077a8fa84
 DIST wheel-0.34.2-py2.py3-none-any.whl 26502 BLAKE2B 3a1bd4571c582245b60ff33c9bf74ff8a2ebafb26e56fc7b9bd215058d059b6bd13bbe21ce46002af257813a54126f27e19253f211e21c4548c7cf84cd15caf7 SHA512 4f1a44f4691ed8baad777d7874f7f4da96a5019eb485fd3a9eed9259aa2a9d5acccc6dc63a72128664347c64ee039a6076c6ca9c3b75a1f94457967864e522ed
diff --git a/dev-python/pip/pip-20.2.2.ebuild b/dev-python/pip/pip-20.2.2.ebuild
new file mode 100644
index 000000000000..6452415611d1
--- /dev/null
+++ b/dev-python/pip/pip-20.2.2.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python2_7 python3_{5,6,7,8,9} )
+PYTHON_REQ_USE="ssl(+),threads(+)"
+
+inherit bash-completion-r1 distutils-r1 multiprocessing
+
+SETUPTOOLS_PV="44.0.0"
+WHEEL_PV="0.34.2"
+
+DESCRIPTION="Installs python packages -- replacement for easy_install"
+HOMEPAGE="https://pip.pypa.io/ https://pypi.org/project/pip/ https://github.com/pypa/pip/"
+SRC_URI="
+	https://github.com/pypa/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+	test? (
+		https://files.pythonhosted.org/packages/py2.py3/s/setuptools/setuptools-${SETUPTOOLS_PV}-py2.py3-none-any.whl
+		https://files.pythonhosted.org/packages/py2.py3/w/wheel/wheel-${WHEEL_PV}-py2.py3-none-any.whl
+	)
+"
+# PyPI archive does not have tests, so we need to download from GitHub.
+# setuptools & wheel .whl files are required for testing, exact version is not very important.
+
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+SLOT="0"
+IUSE="test -vanilla"
+
+# disable-system-install patch breaks tests
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/setuptools-39.2.0[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/csv23[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/scripttest[${PYTHON_USEDEP}]
+		<dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' -2)
+	)
+"
+
+python_prepare_all() {
+	local PATCHES=(
+		"${FILESDIR}/${PN}-19.3-disable-version-check.patch"
+		"${FILESDIR}/${PN}-20.2-no-coverage.patch"
+	)
+	if ! use vanilla; then
+		PATCHES+=( "${FILESDIR}/pip-20.0.2-disable-system-install.patch" )
+	fi
+
+	# TODO
+	rm tests/functional/test_new_resolver_user.py || die
+
+	distutils-r1_python_prepare_all
+
+	if use test; then
+		mkdir tests/data/common_wheels/ || die
+		cp "${DISTDIR}"/setuptools-${SETUPTOOLS_PV}-py2.py3-none-any.whl \
+			tests/data/common_wheels/ || die
+
+		cp "${DISTDIR}"/wheel-${WHEEL_PV}-py2.py3-none-any.whl \
+			tests/data/common_wheels/ || die
+	fi
+}
+
+python_test() {
+	if [[ ${EPYTHON} == pypy* ]]; then
+		ewarn "Skipping tests on ${EPYTHON} since they are very broken"
+		return 0
+	fi
+
+	local -a exclude_tests
+
+	# these will be built in to an expression passed to pytest to exclude
+	exclude_tests=(
+		git
+		svn
+		bazaar
+		mercurial
+		version_check
+		uninstall_non_local_distutils
+		pep518_uses_build_env
+		install_package_with_root
+		install_editable_with_prefix
+		install_user_wheel
+		install_from_current_directory_into_usersite
+		uninstall_editable_from_usersite
+		uninstall_from_usersite_with_dist_in_global_site
+		build_env_isolation
+		user_config_accepted
+	)
+
+	distutils_install_for_testing
+
+	# generate the expression to exclude failing tests
+	local exclude_expr
+	printf -v exclude_expr "or %s " "${exclude_tests[@]}" || die
+	exclude_expr="not (${exclude_expr#or })" || die
+
+	local -x GENTOO_PIP_TESTING=1 \
+		PATH="${TEST_DIR}/scripts:${PATH}" \
+		PYTHONPATH="${TEST_DIR}/lib:${BUILD_DIR}/lib"
+
+	pytest -vv \
+		-k "${exclude_expr}" \
+		-m "not network" \
+		|| die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	# Prevent dbus auto-launch
+	# https://bugs.gentoo.org/692178
+	export DBUS_SESSION_BUS_ADDRESS="disabled:"
+
+	local DOCS=( AUTHORS.txt docs/html/**/*.rst )
+	distutils-r1_python_install_all
+
+	COMPLETION="${T}"/completion.tmp
+
+	# 'pip completion' command embeds full $0 into completion script, which confuses
+	# 'complete' and causes QA warning when running as "${PYTHON} -m pip".
+	# This trick sets correct $0 while still calling just installed pip.
+	local pipcmd='import sys; sys.argv[0] = "pip"; import pip.__main__; sys.exit(pip.__main__._main())'
+
+	${PYTHON} -c "${pipcmd}" completion --bash > "${COMPLETION}" || die
+	newbashcomp "${COMPLETION}" ${PN}
+
+	${PYTHON} -c "${pipcmd}" completion --zsh > "${COMPLETION}" || die
+	insinto /usr/share/zsh/site-functions
+	newins "${COMPLETION}" _pip
+}
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 6fc6e58fea54..d5b0088f3fa5 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -3,3 +3,4 @@ DIST Sphinx-2.0.1.tar.gz 6017030 BLAKE2B a446aab8c7f5a4adc93477f4f60ca975690cb4c
 DIST Sphinx-2.4.4.tar.gz 5966973 BLAKE2B 727a75eb4ec33beadf80b22cdd8dda02a53f4da4aea10ee18ecae658a69a9bb797f83b0d11b41b8405bf18b2472ea7fd501bea85382c20c5f2a9d5b14a032428 SHA512 cd35b7ebdf4eb41fb3a58706333ca4328fbf9b37999ad1bcc751f9769f0a294464e4def019a403fcd2204ca963ef641c35c957a4145eb50af07573d21df8c74d
 DIST Sphinx-3.0.4.tar.gz 5909229 BLAKE2B 892b435642be2a6334f93d9f230ec1aeeff8cf7b374570aae66eb341614d4318125920ef0c5593e7eee64e0b8781f035635af71aac34e9c2c6eb20a07ed68d48 SHA512 ec0c2487f098f774452b58d4fb67be7850b4a54b80f2b01dcee990298f59bfede3ca43b28fa992181cdceb07f261abce186862afd75c889c6682338049db6288
 DIST Sphinx-3.1.2.tar.gz 5934433 BLAKE2B 4ed04dcff4db412ea1f749c0b90d0c38197bbc95607bcc719522f0690d6fd58aa59b87a053c036e9b3c982e9c0f6fa9b6b67f903cb7d9e6fea3a13d99b7be297 SHA512 d1b55a603ea4a76d2315e170b8ba7858caf1658660e9983034918bd265c505f0e5157ab9d9cebc970261646ae0959e1cf75562b01b73bf3a380e712393a735b9
+DIST Sphinx-3.2.0.tar.gz 5970521 BLAKE2B d099e3e4fda68d52060f03196dc4d9ac3f960ed516c37a99e6f4f7efc9c81913e3e161dd70a16591d07200a0a4eb2a72536aeb63ccf3ce2dca9e1f1985931751 SHA512 7b4108acdd241240a91171ade30c800aa0ef0ccb00080eb80d205abc95c56f2accca179e4d95d7e34ed48137c0845b4175a285b8204d1e8de1a22c707e6d06b0
diff --git a/dev-python/sphinx/sphinx-3.2.0.ebuild b/dev-python/sphinx/sphinx-3.2.0.ebuild
new file mode 100644
index 000000000000..ed0d88421631
--- /dev/null
+++ b/dev-python/sphinx/sphinx-3.2.0.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx"
+SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
+IUSE="doc latex test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/imagesize[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/snowballstemmer[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-htmlhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typed-ast[${PYTHON_USEDEP}]
+	' python3_{6,7})
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		${RDEPEND}
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		virtual/imagemagick-tools[jpeg,png,svg]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+
+S="${WORKDIR}/${P^}"
+
+python_prepare_all() {
+	# remove tests that fail due to network-sandbox
+	rm tests/test_build_linkcheck.py || die "Failed to remove web tests"
+	sed -i -e 's:test_latex_images:_&:' tests/test_build_latex.py || die
+
+	# fail under pypy3 (some because of missing typed-ast)
+	# revisit when pypy3 becomes pypy3.8
+	sed -i -e '/def test_partialfunction/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		-e '/def test_autodoc_typed_instance_variables/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		-e '/def test_autodoc_inherited_members_None/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		-e '/def test_cython/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		-e '/def test_automethod_for_builtin/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_ext_autodoc.py || die
+	sed -i -e '/import pytest/aimport sys' \
+		-e '/def test_builtin_function/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		-e '/def test_methoddescriptor/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		-e '/def test_wrapped_function/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_ext_autodoc_autofunction.py || die
+	sed -i -e '/import pytest/aimport sys' \
+		-e '/def test_autodoc_typehints_signature/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_ext_autodoc_configs.py || die
+	sed -i -e '/import pytest/aimport sys' \
+		-e '/def test_autosummary_generate_content_for_module/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_ext_autosummary.py || die
+	sed -i -e '/def test_annotated_assignment_py36/i\
+@pytest.mark.skipif(hasattr(sys, "pypy_version_info"), reason="broken on pypy3")' \
+		tests/test_pycode_parser.py || die
+
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# Generate the grammar. It will be caught by install somehow.
+	# Note that the tests usually do it for us. However, I don't want
+	# to trust USE=test really running all the tests, especially
+	# with FEATURES=test-fail-continue.
+	pushd "${BUILD_DIR}"/lib >/dev/null || die
+	"${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
+	popd >/dev/null || die
+}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	fi
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/transitions/Manifest b/dev-python/transitions/Manifest
index 925644a12b76..b7533d5d980c 100644
--- a/dev-python/transitions/Manifest
+++ b/dev-python/transitions/Manifest
@@ -1,2 +1 @@
-DIST transitions-0.7.1.tar.gz 1283833 BLAKE2B 5f2f2813ba158cf5ccac4e2d55700149b986bdd24f9e864cec8d03390724cf79d9d379afa06b1a7b56c6a91376410252fdda169024f6ebbba2ed976fe7a18e7b SHA512 3fe5989faf9dbfdc15d50beaf2656240317f00278727271e5bd64ad465be1640b67e760fb73f4b06a61920343215815a8be03d41dc4d32086222446463ef71d7
 DIST transitions-0.8.2.tar.gz 1084797 BLAKE2B 9ff6284e7c42365c5a169388057acffd53dd31c3ca6d9dee240b253ca34118a67d3f070fd8b6a86cb6a01a2e15023e0bad02ccc07813ee0855a54008ac3d7597 SHA512 d10e513806801d0c874be3eb59e92ad61584b5f7992ba26db8828848df1225fb806621abc118a8d43f2efaa353d988b5becbe4296bc054754e551c86495a540f
diff --git a/dev-python/transitions/transitions-0.7.1-r1.ebuild b/dev-python/transitions/transitions-0.7.1-r1.ebuild
deleted file mode 100644
index c22d1ea5dc1a..000000000000
--- a/dev-python/transitions/transitions-0.7.1-r1.ebuild
+++ /dev/null
@@ -1,45 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{5,6,7,8,9} )
-
-inherit distutils-r1
-
-DESCRIPTION="A lightweight, object-oriented state machine implementation in Python"
-HOMEPAGE="https://github.com/pytransitions/transitions"
-SRC_URI="https://github.com/pytransitions/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="examples test"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-python/graphviz[${PYTHON_USEDEP}]
-	dev-python/six[${PYTHON_USEDEP}]
-"
-
-DEPEND="
-	${RDEPEND}
-	test? (
-		dev-python/dill[${PYTHON_USEDEP}]
-		dev-python/mock[${PYTHON_USEDEP}]
-		dev-python/nose[${PYTHON_USEDEP}]
-		dev-python/pycodestyle[${PYTHON_USEDEP}]
-		dev-python/pytest[${PYTHON_USEDEP}]
-	)
-"
-
-BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
-
-distutils_enable_tests pytest
-
-src_install() {
-	distutils-r1_src_install
-
-	use examples && dodoc examples/*.ipynb
-}
diff --git a/dev-python/transitions/transitions-0.8.2.ebuild b/dev-python/transitions/transitions-0.8.2.ebuild
index 0910eb417eae..c22d1ea5dc1a 100644
--- a/dev-python/transitions/transitions-0.8.2.ebuild
+++ b/dev-python/transitions/transitions-0.8.2.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/pytransitions/${PN}/archive/${PV}.tar.gz -> ${P}.tar
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="examples test"
 
 RESTRICT="!test? ( test )"