Adding metadata

33 files changed, 1169 insertions, 114 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 1d51dfa1fe15..c627bb82f52b 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -5,3 +5,4 @@ DIST boto3-1.34.89.gh.tar.gz 799495 BLAKE2B 2d719b0c2e09f0387dbe317f76555b36fda7
 DIST boto3-1.34.90.gh.tar.gz 800389 BLAKE2B cd604cf39479af676c46b7fd1e5a8ee24e46ec384d97c50b15f80c2d96a5f46ad1c66a8a34a03ccffdf37cf386e7dcc455dc38543fc9c919f9c2b18be6e402bb SHA512 480824e36f9f118b0813b391818a4214bb1861e322099cfbc2e7f5e20a088799d2e3c1c4e745ead86dde634b2f2b46656dec872025c0d5b3b608859fc8c9d9c8
 DIST boto3-1.34.91.gh.tar.gz 800954 BLAKE2B 40bbc688a006666e85b07d8f40f291ced5d6ffa0a26980bb89e353f7e300960bbff74c46554d8d4805b0cfd6723f8fa8b75f54908a255c9bc0d341ae23000265 SHA512 e8db938b1af6753c65b42f764ec1f4783d33dc889cadc76715f7fd6053a29149163e328593315f2d900a9d5d46fe0ab451bbba597180dbabd654dbac83b75b2c
 DIST boto3-1.34.92.gh.tar.gz 801544 BLAKE2B ec5e6aabcbc51f7fd0ce235b124489e5bf3375d346c9922430114a8e79d56544c90e91eb861393c63b191a1bdaa8eb04d6d59a40095c785741c59acde411d523 SHA512 349fbdc017da180d5f5d53a8d22c49203bbe633e8d98db71c9ec2be7dc8a78deedae7d0e256d827e2b75608374283ec9946b9c43aa9dd80504fd88fc8f8b65a8
+DIST boto3-1.34.93.gh.tar.gz 802078 BLAKE2B 43f19efd6ae42bdb20e8dd79b1735df229ec2f231b5fe05006b26fcd5ddf4796a53fba6011c298fb919ee7b205b4ae3f4b563ad3b5325bdbbdebaeab7be59608 SHA512 4da1d9d7d8648e895f23763e5055a868d05bbfd8eb28d56e716975b3b8349bd1825d703f6fd11c316174004c39e1fca5ddcd8a4ad27a000e1a52f08a36eb4780
diff --git a/dev-python/boto3/boto3-1.34.93.ebuild b/dev-python/boto3/boto3-1.34.93.ebuild
new file mode 100644
index 000000000000..509842b2699d
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.93.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 1d0b5e0be626..2470c76828bb 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -5,3 +5,4 @@ DIST botocore-1.34.89.gh.tar.gz 12942425 BLAKE2B f2df9f8e1c90a55ec9c4a1695dd9d9e
 DIST botocore-1.34.90.gh.tar.gz 12959004 BLAKE2B e80aa5ec0727db538ccbdac357431a3015494aa10da2d4a0e9ff6fb5080eaab38494933c3d3678fbf9d1266007a5edfc742b5a65a6be8e26edb8e3e11de255b5 SHA512 a6eb45e36ff189edf7915667719112279a07133ce7ef9bfe94c18c8e5ab6df4b734a00d973986f9f74ed7e475fa72461457a7633464973e720f38cf828f2ecc8
 DIST botocore-1.34.91.gh.tar.gz 12975028 BLAKE2B 0a4d4ca5530411148e7df7be4f937741457e44b3cf7774ded834db58ce9d6fd05f0fed6aaac1283ee410b6914d4825387c36545b17b1e78cf89175d560445071 SHA512 aad3f747ca49f58eed1116c303202e29bb0cec0a9816c5436bf75881d46b4c363e9aebbc039b3f6c6faedaf81cbea03d635b744fffb9f740cdb4c1d3ff21724f
 DIST botocore-1.34.92.gh.tar.gz 12978936 BLAKE2B 64fda2f4b1cbaa31c3d9148039c0db44e54811245186abf014ce1f3a635cb52f5bcef1180f082fed27300314ebd3b79887f364698b4df131f6534dc3bd694444 SHA512 4923a04ac00d325f7d8b3dd69b11d82130abf642afd5a7abb22620062ff9f8859940d9dea1ff15bc3ace546e7b85ddb0e56a30e472ee8adf4406124c9587fe09
+DIST botocore-1.34.93.gh.tar.gz 12982900 BLAKE2B 3225279b85101e04da3be11f01ac3f4ca74cf77235fcb8878bc12d7aca61472155c8319329beb54ffe335f9da9023fb3ccce99256f3a31c6588389dfa1746de9 SHA512 505e8c9b3915b1c2da3863b62c85c392a58c12376c3e71493025445b7b672ba320474087b446fda876ffee5d6260909bc1d1442ff6dbfeb49fd6661d3d7840a1
diff --git a/dev-python/botocore/botocore-1.34.93.ebuild b/dev-python/botocore/botocore-1.34.93.ebuild
new file mode 100644
index 000000000000..857224b496b7
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.93.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/dask-expr/Manifest b/dev-python/dask-expr/Manifest
index bdb6cbbb5140..9d4ec9431499 100644
--- a/dev-python/dask-expr/Manifest
+++ b/dev-python/dask-expr/Manifest
@@ -1,3 +1,4 @@
 DIST dask-expr-1.0.11.gh.tar.gz 242347 BLAKE2B 38b35e4558fc589738d98b59bcaa378351dfa11110c3a7fd7919b709db1ef5b5b97fd431aa2fc07ba69ec41012c91667873615fea763efee2d8f07b99eee910e SHA512 ddd4cd3582dc843a3dd7702f5a457df44d97b7b3828629d702c209f4b84fc1410b059029f82dc167ebefbf3de148aed7f54ecc69241c179c86bf66f9bbd19f41
 DIST dask-expr-1.0.12.gh.tar.gz 253354 BLAKE2B 566075d45e3d3b0521cf686b231c0e17f8f445ac95f81f8f32a10c2627cba62e243c02b4ef8d8eed88771df6ce52f88923c5d6fad94a84f950c33ffc70ea550f SHA512 423797cb6142761bbaf56970f474ecf96b047675c8032f2e73427158320f3dd012e861cd9c86560c75c51b9e1350b1081ad5bd0943cde6522b3c21a799fee307
+DIST dask-expr-1.0.13.gh.tar.gz 253953 BLAKE2B a3261ef74ec46835b29223a81ac7a69ae36599af4a092ac87876ca64fc764c1b042b14d39bf624132b2d3623979263ed382f6938793d0d7e1ded7679d0971b32 SHA512 5d32b7cdcc9004ca761ab1c16cccab8bd9487f528d0b09a98b5557ff24bf0a4e432e86b1fcb4e4a1ca78b38848ca85a0b6760a904917141cb73d8d27d80a876c
 DIST dask-expr-1.0.5.gh.tar.gz 239409 BLAKE2B 0fae8540f40cbdead823f300a68df239bb838bb88d34c000b6d29ee451609a4cfc4422586cbf1fc3d2e10b50ffab6e8a2414c14c00635d929d92d7e40b1abff5 SHA512 3baf9e1aca78bc8158bce0e6beb323e511fa5717578bb10bfce27ec38a8f7b6e25b21edeffc669a1ac5f4a987dbbd948bba0f4375f3c5b329d13fab7093708ea
diff --git a/dev-python/dask-expr/dask-expr-1.0.13.ebuild b/dev-python/dask-expr/dask-expr-1.0.13.ebuild
new file mode 100644
index 000000000000..1c0c21cf70ab
--- /dev/null
+++ b/dev-python/dask-expr/dask-expr-1.0.13.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="High Level Expressions for Dask"
+HOMEPAGE="
+	https://github.com/dask/dask-expr/
+	https://pypi.org/project/dask-expr/
+"
+# pypi tarball removes tests, as of 1.0.1
+SRC_URI="
+	https://github.com/dask/dask-expr/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/dask-2024.4.2[${PYTHON_USEDEP}]
+	>=dev-python/pyarrow-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pandas-2[${PYTHON_USEDEP}]
+"
+# TODO: make pandas depend on pyarrow unconditionally?  we're having
+# transitive deps here.
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-libs/apache-arrow[parquet,snappy]
+		dev-python/pyarrow[parquet,${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin
+	sed -i -e '/dask/s:==:>=:' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires distributed
+		'dask_expr/tests/test_shuffle.py::test_respect_context_shuffle[shuffle]'
+		# TODO
+		dask_expr/tests/test_groupby.py::test_groupby_index_array
+	)
+	local EPYTEST_IGNORE=(
+		# requires distributed
+		dask_expr/io/tests/test_parquet.py
+		dask_expr/tests/test_diagnostics.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest
index fc48e57709ee..2fbe63fe5c60 100644
--- a/dev-python/ipython/Manifest
+++ b/dev-python/ipython/Manifest
@@ -1,2 +1,3 @@
 DIST ipython-8.22.2.tar.gz 5490399 BLAKE2B 61d7d30d77c0b422ba174ac3c3f17c753502d9469d1d2ba8e3f2583761ab1f26230172b7e2efa680bb8f7ef23ef47cfe56241344380591e3da0da5d15f385727 SHA512 ff9c56b0594e63dbb26aad466eb9449d41db4002da61837363aaff817b99a54f310152994e4d361dfd5b6c40452dedf3eb74825c6d0a7d8c5fff84c1ac20f7ff
 DIST ipython-8.23.0.tar.gz 5491405 BLAKE2B c4273d20bccdf07283abf9a69b8d64a27be3aa2e0672d14781cd9035ff39a5392518d7e22f45cdd20c8e110111a601d4bdbc36659efde153742de731d574e4be SHA512 4e6f061dba024f5e717f6497706a144c5568c9d650215d898fe8e5efc85b92445f64e2c8eb6ef3c9bfe1a305c9098cc49e79b6d1cc25c8be5add1497682fce28
+DIST ipython-8.24.0.tar.gz 5491819 BLAKE2B 49ca26f4ab6ceb7c787038db5b1073790d7a32cb96951bcc2ffa4ac05b3a689507e654344fda196560e2dc4b9e2225335e27bc3fb7472ba487adebb1ebba44e1 SHA512 adf032a93e94e1e8008a1cc106fb348d0bccb914a335e0ad04490531e7a7d16e7a2dc4a345f7faf1b3151d60a649413fa78130688cb59de088e5eb4291689310
diff --git a/dev-python/ipython/ipython-8.24.0.ebuild b/dev-python/ipython/ipython-8.24.0.ebuild
new file mode 100644
index 000000000000..551d2ccbec84
--- /dev/null
+++ b/dev-python/ipython/ipython-8.24.0.ebuild
@@ -0,0 +1,179 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE='readline(+),sqlite,threads(+)'
+
+inherit distutils-r1 optfeature pypi virtualx
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="
+	https://ipython.org/
+	https://github.com/ipython/ipython/
+	https://pypi.org/project/ipython/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="doc examples notebook nbconvert qt5 +smp test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/decorator[${PYTHON_USEDEP}]
+	>=dev-python/jedi-0.16[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.3[${PYTHON_USEDEP}]
+	>=dev-python/prompt-toolkit-3.0.41[${PYTHON_USEDEP}]
+	<dev-python/prompt-toolkit-3.1[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
+	dev-python/stack-data[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.13.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/exceptiongroup[${PYTHON_USEDEP}]
+	' 3.10)
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.10 3.11)
+"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		app-text/dvipng[truetype]
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/nbformat[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.23[${PYTHON_USEDEP}]
+		dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+		dev-python/pickleshare[${PYTHON_USEDEP}]
+		<dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-2[${PYTHON_USEDEP}]
+		dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+RDEPEND+="
+	nbconvert? (
+		dev-python/nbconvert[${PYTHON_USEDEP}]
+	)
+"
+PDEPEND="
+	$(python_gen_cond_dep '
+		notebook? (
+			dev-python/notebook[${PYTHON_USEDEP}]
+			dev-python/ipywidgets[${PYTHON_USEDEP}]
+			dev-python/widgetsnbextension[${PYTHON_USEDEP}]
+		)
+		qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] )
+	' 'python*')
+	smp? (
+		>=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}]
+		>=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/2.1.0-substitute-files.patch
+)
+
+python_prepare_all() {
+	# Remove out of date insource files
+	#rm IPython/extensions/cythonmagic.py || die
+	#rm IPython/extensions/rmagic.py || die
+
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	# Rename the test directory to reduce sys.path pollution
+	# https://github.com/ipython/ipython/issues/12892
+	mv IPython/extensions/{,ipython_}tests || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html_noapi
+		HTML_DOCS=( docs/build/html/. )
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local -x IPYTHON_TESTING_TIMEOUT_SCALE=20
+	local EPYTEST_DESELECT=(
+		# TODO: looks to be a regression due to a newer dep
+		IPython/core/tests/test_oinspect.py::test_class_signature
+		IPython/core/tests/test_oinspect.py::test_render_signature_long
+		IPython/terminal/tests/test_shortcuts.py::test_modify_shortcut_with_filters
+	)
+
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# https://github.com/numpy/numpy/issues/25164
+				IPython/lib/tests/test_display.py::TestAudioDataWithoutNumpy
+			)
+			;;
+	esac
+
+	# nonfatal implied by virtx
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest -p asyncio --asyncio-mode=auto ||
+		die "Tests failed on ${EPYTHON}"
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	# Create ipythonX.Y symlinks.
+	# TODO:
+	# 1. do we want them for pypy? No.  pypy has no numpy
+	# 2. handle it in the eclass instead (use _python_ln_rel).
+	# With pypy not an option the dosym becomes unconditional
+	dosym ../lib/python-exec/${EPYTHON}/ipython \
+		/usr/bin/ipython${EPYTHON#python}
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
+
+pkg_postinst() {
+	optfeature "code formatting" dev-python/black
+	optfeature "sympyprinting" dev-python/sympy
+	optfeature "cythonmagic" dev-python/cython
+	optfeature "%lprun magic command" dev-python/line-profiler
+	optfeature "%matplotlib magic command" dev-python/matplotlib-inline
+
+	if use nbconvert; then
+		if ! has_version virtual/pandoc ; then
+			einfo "Node.js will be used to convert notebooks to other formats"
+			einfo "like HTML. Support for that is still experimental. If you"
+			einfo "encounter any problems, please use app-text/pandoc instead."
+		fi
+	fi
+}
diff --git a/dev-python/jupyterlab/Manifest b/dev-python/jupyterlab/Manifest
index d01d17ae45a6..349666f1e7cf 100644
--- a/dev-python/jupyterlab/Manifest
+++ b/dev-python/jupyterlab/Manifest
@@ -1 +1,3 @@
 DIST jupyterlab-4.1.6.tar.gz 21773628 BLAKE2B b2855ecc4fa0cc892fab9bb79c19a3cec0ea577c9c490571ad4028e9fe35bca87fc61d0035cc889bee14313475825344e1cea69f34af4a908c5d2a304250d983 SHA512 b895aac68c6df3affb47eaebc243ecf7d778228a5adec8b8a047783e341008ab4beb0fe50b92138f765e7a72acfbe906f63f41aebe1a72544fe3030105d52716
+DIST jupyterlab-4.1.7.tar.gz 21773423 BLAKE2B 6456011cd841b0c61b09ecd647443cd68abc4a48151ddeab6b5834f22fd99616470a70fc68897a8b46cb32873a49c3f950006eff80facd6e109d337be5d95569 SHA512 01c8b1a496c621d387a8b03c8705c1807f9f18d09be30aa3327a9beac1fa97b23df02f518490d984ac022f1265a55104d7db69ca69a79941c526b50946c8d20b
+DIST jupyterlab-4.1.8.tar.gz 21774267 BLAKE2B d707257b2f7c53c023fa0e2741ff1ddbb83116c1b8cc8136b550c94120737161c519c4a2e67211fff275267ab31c58e58b17ea6041e9ba00d44baa1919876f1e SHA512 376b9a9b154b70716ca8450126b9623932b44c88b1a83e42fadc4b98f5a3dd3982d77ae9fc807f483fbd84615c184dd8c170297002c9f609b81755aec21e1ff4
diff --git a/dev-python/jupyterlab/jupyterlab-4.1.7.ebuild b/dev-python/jupyterlab/jupyterlab-4.1.7.ebuild
new file mode 100644
index 000000000000..1a24abe1d86c
--- /dev/null
+++ b/dev-python/jupyterlab/jupyterlab-4.1.7.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi xdg
+
+DESCRIPTION="JupyterLab computational environment"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyterlab/jupyterlab/
+	https://pypi.org/project/jupyterlab/
+"
+
+LICENSE="BSD MIT GPL-3 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/async-lru[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.25.0[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.5.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.3[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-lsp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-server-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-server-2.27.1[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-server-3[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+	>=dev-python/tornado-6.2.0[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	net-libs/nodejs
+"
+
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		>=dev-python/pytest-jupyter-0.5.3[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-cache[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# These tests call npm and want internet
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_uninstall_core_extension
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned_folder
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom_minimal_core_config
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_check
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_clear
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_build
+)
+
+EPYTEST_IGNORE=(
+	jupyterlab/tests/test_announcements.py
+)
+
+distutils_enable_tests pytest
+# TODO: package sphinx_copybutton
+#distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme dev-python/myst-parser
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/jupyterlab/jupyterlab-4.1.8.ebuild b/dev-python/jupyterlab/jupyterlab-4.1.8.ebuild
new file mode 100644
index 000000000000..1a24abe1d86c
--- /dev/null
+++ b/dev-python/jupyterlab/jupyterlab-4.1.8.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi xdg
+
+DESCRIPTION="JupyterLab computational environment"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyterlab/jupyterlab/
+	https://pypi.org/project/jupyterlab/
+"
+
+LICENSE="BSD MIT GPL-3 Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/async-lru[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.25.0[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.5.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.3[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-lsp-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-server-2.4.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-server-3[${PYTHON_USEDEP}]
+	>=dev-python/jupyterlab-server-2.27.1[${PYTHON_USEDEP}]
+	<dev-python/jupyterlab-server-3[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.2[${PYTHON_USEDEP}]
+	' 3.10)
+	>=dev-python/tornado-6.2.0[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	net-libs/nodejs
+"
+
+BDEPEND="
+	dev-python/hatch-jupyter-builder[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-console-scripts[${PYTHON_USEDEP}]
+		>=dev-python/pytest-jupyter-0.5.3[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-cache[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# These tests call npm and want internet
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_uninstall_core_extension
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned_folder
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_install_and_uninstall_pinned
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom_minimal_core_config
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_custom
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build_check
+	jupyterlab/tests/test_jupyterlab.py::TestExtension::test_build
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_clear
+	jupyterlab/tests/test_build_api.py::TestBuildAPI::test_build
+)
+
+EPYTEST_IGNORE=(
+	jupyterlab/tests/test_announcements.py
+)
+
+distutils_enable_tests pytest
+# TODO: package sphinx_copybutton
+#distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme dev-python/myst-parser
+
+python_install_all() {
+	distutils-r1_python_install_all
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
diff --git a/dev-python/keyring/Manifest b/dev-python/keyring/Manifest
index 7934751d5665..e1bc555df8da 100644
--- a/dev-python/keyring/Manifest
+++ b/dev-python/keyring/Manifest
@@ -1,2 +1,3 @@
 DIST keyring-24.3.1.tar.gz 60454 BLAKE2B cb0a9b82163febbbd737f2f25353bf96cbb7b8a87c7db00523960b3fce5595c6af65bc02b7d070b0fa5a466fc53530975de8f7a44ab9a9f783d2db34b1a67901 SHA512 53f26763175c7f1de041d8805062696ef3ef6c79792cdc75ae72621da8e729ac4cbb6e76937db2a0a5ce4bc41ab92c164d62e4627f92edab8c0d0fc02ca4980e
 DIST keyring-25.1.0.tar.gz 60191 BLAKE2B 90cf0088f7740f6bc6562173b98630f885eca4c011be513532630ecaf4ca327053e37444b88ef5110a224567a68ad14228f59cf859090761be08a17d007b18ba SHA512 991023f96c9ffa98b65ee48cb07908bfa0c2a56af13aba60f476a5c99eea9c627112a8eb777c2a8be1ae87cfc8fc79ba68c9ca08ed53002e9e240e64f937cff4
+DIST keyring-25.2.0.tar.gz 60808 BLAKE2B a9f97b80593cc1fc4716b0c97579408d4485dbd9dab415fa98e1827130cea425a03ff6188282ffb0125327feb6ed282260c15d21ce603f4d2561a94f83e6cbd0 SHA512 36ef4a78d5b9081f13ea7aabbfbe508e0ee275cbdf458fbcb36da5a360f91df79ce4c54bf0ce4000d91961d06f019d75a9ffc46328ef7d9e14e9a883508a1950
diff --git a/dev-python/keyring/keyring-25.2.0.ebuild b/dev-python/keyring/keyring-25.2.0.ebuild
new file mode 100644
index 000000000000..9198c50f5be3
--- /dev/null
+++ b/dev-python/keyring/keyring-25.2.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Provides access to the system keyring service"
+HOMEPAGE="
+	https://github.com/jaraco/keyring/
+	https://pypi.org/project/keyring/
+"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/secretstorage-3.2[${PYTHON_USEDEP}]
+	dev-python/jaraco-classes[${PYTHON_USEDEP}]
+	dev-python/jaraco-context[${PYTHON_USEDEP}]
+	dev-python/jaraco-functools[${PYTHON_USEDEP}]
+	>=dev-python/jeepney-0.4.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/importlib-metadata-4.11.4[${PYTHON_USEDEP}]
+	' 3.10 3.11)
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# this test fails if importlib-metadata returns more than one
+		# entry, i.e. when keyring is installed already
+		tests/test_packaging.py::test_entry_point
+	)
+	local EPYTEST_IGNORE=(
+		# apparently does not unlock the keyring properly
+		tests/backends/test_libsecret.py
+		# hangs
+		tests/backends/test_kwallet.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -o addopts=
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index e9da2ac43cac..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
new file mode 100644
index 000000000000..637368d2f237
--- /dev/null
+++ b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
@@ -0,0 +1,13 @@
+Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
+
+--- a/setup.py
++++ b/setup.py
+@@ -18,7 +18,7 @@ setup(
+     author_email='michal.danilak@gmail.com',
+     url='https://github.com/Mimino666/langdetect',
+     keywords='language detection library',
+-    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
++    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
+     include_package_data=True,
+     install_requires=['six'],
+     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index c09b7356f549..630fe63c6f53 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,4 +19,6 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
+PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
+
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..736a1167c898 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,12 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
- </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/lxml-html-clean/lxml-html-clean-0.1.1.ebuild b/dev-python/lxml-html-clean/lxml-html-clean-0.1.1.ebuild
index 60a7ecd8674d..d6ecef4846c1 100644
--- a/dev-python/lxml-html-clean/lxml-html-clean-0.1.1.ebuild
+++ b/dev-python/lxml-html-clean/lxml-html-clean-0.1.1.ebuild
@@ -15,7 +15,7 @@ HOMEPAGE="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="amd64 ~arm64"
 
 RDEPEND="
 	>=dev-python/lxml-5.2.0[${PYTHON_USEDEP}]
diff --git a/dev-python/mechanize/Manifest b/dev-python/mechanize/Manifest
index 0679fda04d7d..9762e1d2e5e7 100644
--- a/dev-python/mechanize/Manifest
+++ b/dev-python/mechanize/Manifest
@@ -1 +1,2 @@
+DIST mechanize-0.4.10.tar.gz 218291 BLAKE2B 7a6f293ac5622b4ac01d1b84327e4dd41132eb2fdfaf9826e6c7a8b088890ae8b4b5f4e90aca930761d532702138f0be6f9394e48ee2defc48dcb5f19ee22a79 SHA512 76d13ac8ac06e8e3836ba814259e1ec8495ebbfc259d4f8652f3ed23863b6a5f6fc5983409083ad9f5d0312db6581b0e7b32bfe6d46ecd190006188ac4cf3fc8
 DIST mechanize-0.4.9.tar.gz 218286 BLAKE2B 42ea97f843ec61b5ae05913e564f0cdb473976ea4e08a886c3bed15b27cea64def7fe5c73c1b809e48688d5ae41c269e85b633a24731c83409bf9855fc72b85f SHA512 a0c5d6e01ddabd35dded9908e4f7e24cb0a8c20a674af603cd2f5f146c75d38dc96c36af0898646691206ce41745dff9a736ce53efd03ff48e55e763814b893c
diff --git a/dev-python/mechanize/mechanize-0.4.10.ebuild b/dev-python/mechanize/mechanize-0.4.10.ebuild
new file mode 100644
index 000000000000..e29691fc8e32
--- /dev/null
+++ b/dev-python/mechanize/mechanize-0.4.10.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Stateful programmatic web browsing in Python"
+HOMEPAGE="
+	https://github.com/python-mechanize/mechanize/
+	https://pypi.org/project/mechanize/
+"
+
+LICENSE="|| ( BSD ZPL )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/html5lib-0.999999999[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+	)
+"
+
+python_test() {
+	"${EPYTHON}" run_tests.py -v || die
+}
diff --git a/dev-python/puremagic/Manifest b/dev-python/puremagic/Manifest
index e60787c0ae9c..0959516923b7 100644
--- a/dev-python/puremagic/Manifest
+++ b/dev-python/puremagic/Manifest
@@ -1 +1,2 @@
 DIST puremagic-1.21.gh.tar.gz 296990 BLAKE2B 78709c296ee8599009f07f8fadfaa60957895d1a45d3fd5f12605a54901e2f0ab878abdb4dc121a77d2c4da922b2f5a173d13ef660a2265298716a26da28f293 SHA512 cc2c76a2ddcfacdfce778e565b07692dcd247723aa85c562ba4d8c70992f79a8f13a7bc33f1468ee37298c266d35d76febe2e6164fdc145077d68b05cfa2e1c4
+DIST puremagic-1.22.gh.tar.gz 304145 BLAKE2B 8165ae8527462223255a04c84c3e9f15b76298a8e8ad1f38ae3f92c6e359d514efa543cb290d45d37c2d5aa44a6e082e626cf0ed570c40c905f570b8569f43bf SHA512 d447861e9f7a15f307fdf0ee1e34c5f03304dabb783ba4bfdbfa304fdfa0071b9f51ee9b0a3835417057b9fe4143cf5277a0be451024dc253a88bb94b05b9a99
diff --git a/dev-python/puremagic/puremagic-1.22.ebuild b/dev-python/puremagic/puremagic-1.22.ebuild
new file mode 100644
index 000000000000..51b9731459c1
--- /dev/null
+++ b/dev-python/puremagic/puremagic-1.22.ebuild
@@ -0,0 +1,32 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure python implementation of magic file detection"
+HOMEPAGE="
+	https://github.com/cdgriffith/puremagic/
+	https://pypi.org/project/puremagic/
+"
+SRC_URI="
+	https://github.com/cdgriffith/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DOCS=( CHANGELOG.md README.rst )
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/pytest/Manifest b/dev-python/pytest/Manifest
index 12dda2dc03ae..2b409ccd1829 100644
--- a/dev-python/pytest/Manifest
+++ b/dev-python/pytest/Manifest
@@ -1,3 +1,4 @@
 DIST pytest-7.4.4.tar.gz 1357116 BLAKE2B 0bf281b3d4b7b2eb7805423a75c8c2befa820cc230318511e5a2d5ea35321a78a2603d5dbc033414ed73171525371efa9d9f54083d5638fc752c1c218e6d53aa SHA512 28a259dac6739683c131993409d508e10fbfee461291b8fc7697dd83f30725a3c60e681ba00b5669a215af6a5e683f07a329485d780acc9ad0372a6552f783a1
 DIST pytest-8.0.2.tar.gz 1396924 BLAKE2B ad95d246f5592cfe54faea6c96e38cb60d3e2713070d1ff7cab6c42aea312883c5d97c99a930dbcbd8493e966c4b8351320f6494b4ab904afbf21d7e1dd004a7 SHA512 c495943baad05e09b467d23c7afadb3edff7ae93ee96290d6db9e64739236888148b63dff7e8e25b331b11bd48c55fb0ca8901cf823d69b1a922e94915bab2f1
 DIST pytest-8.1.1.tar.gz 1409703 BLAKE2B 8e382c87af1bbbc235f9b27f8bb892d08393e0a9821f32373ee2546112c24dc6f90e1990f10ef799a94a1426a83a2bc3de0be9e7efde90cbf4eac5a0c9ee375c SHA512 f1a9f69cd4eca3ab36c36bc666bf70b099125ed6e17b89d13554c3f13b100d05abfd0b35516660d00ca4fb9eca81164ab02bc8f7a9a8d90fd4302bf399cd88c0
+DIST pytest-8.1.2.tar.gz 1410060 BLAKE2B 1379047c5ba434e98a383756c53a9cf31dc3bd3abcc49820f872b9110ec70906ca14080ce17ed2770b71195fbd79627a0eb16ee00429e165368144b20153a02b SHA512 a6ffae29da98ee4c357ebb03f00c4bc1a33f093ef867ad118841695548468c7f229eaa2c029a2ce3b158bbb0a65be5014e91555a223d04c1c72e614cb1d00546
diff --git a/dev-python/pytest/pytest-8.1.2.ebuild b/dev-python/pytest/pytest-8.1.2.ebuild
new file mode 100644
index 000000000000..17405705eb0f
--- /dev/null
+++ b/dev-python/pytest/pytest-8.1.2.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple powerful testing with Python"
+HOMEPAGE="
+	https://pytest.org/
+	https://github.com/pytest-dev/pytest/
+	https://pypi.org/project/pytest/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/iniconfig[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	<dev-python/pluggy-2[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.4[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+		>=dev-python/tomli-1[${PYTHON_USEDEP}]
+	' 3.10)
+	!!<=dev-python/flaky-3.7.0-r5
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-6.2.3[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		$(python_gen_cond_dep '
+			dev-python/argcomplete[${PYTHON_USEDEP}]
+			>=dev-python/attrs-19.2[${PYTHON_USEDEP}]
+			>=dev-python/hypothesis-3.56[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			>=dev-python/pygments-2.7.2[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/requests[${PYTHON_USEDEP}]
+			dev-python/xmlschema[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+	)
+"
+
+src_test() {
+	# workaround new readline defaults
+	echo "set enable-bracketed-paste off" > "${T}"/inputrc || die
+	local -x INPUTRC="${T}"/inputrc
+	distutils-r1_src_test
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x COLUMNS=80
+
+	local EPYTEST_DESELECT=(
+		# broken by epytest args
+		testing/test_warnings.py::test_works_with_filterwarnings
+
+		# tend to be broken by random pytest plugins
+		# (these tests patch PYTEST_DISABLE_PLUGIN_AUTOLOAD out)
+		testing/test_helpconfig.py::test_version_less_verbose
+		testing/test_helpconfig.py::test_version_verbose
+		testing/test_junitxml.py::test_random_report_log_xdist
+		testing/test_junitxml.py::test_runs_twice_xdist
+		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal
+		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_normal_count
+		testing/test_terminal.py::TestProgressOutputStyle::test_xdist_verbose
+		testing/test_terminal.py::TestProgressWithTeardown::test_xdist_normal
+		testing/test_terminal.py::TestTerminalFunctional::test_header_trailer_info
+		testing/test_terminal.py::TestTerminalFunctional::test_no_header_trailer_info
+
+		# unstable with xdist
+		testing/test_terminal.py::TestTerminalFunctional::test_verbose_reporting_xdist
+
+		# TODO (XPASS)
+		testing/test_debugging.py::TestDebuggingBreakpoints::test_pdb_not_altered
+		testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_simple
+		testing/test_debugging.py::TestPDB::test_pdb_interaction_capturing_twice
+		testing/test_debugging.py::TestPDB::test_pdb_with_injected_do_debug
+		testing/test_debugging.py::test_pdb_suspends_fixture_capturing
+
+		# setuptools warnings
+		testing/acceptance_test.py::TestInvocationVariants::test_cmdline_python_namespace_package
+
+		# times out
+		testing/test_debugging.py::TestPDB::test_pdb_interaction_exception
+		testing/test_debugging.py::TestPDB::test_pdb_with_caplog_on_pdb_invocation
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		# regressions on pypy3.9
+		# https://github.com/pytest-dev/pytest/issues/9787
+		testing/test_skipping.py::test_errors_in_xfail_skip_expressions
+		testing/test_unraisableexception.py
+	)
+
+	local EPYTEST_XDIST=1
+	epytest
+}
diff --git a/dev-python/sentry-sdk/Manifest b/dev-python/sentry-sdk/Manifest
index beec52a5a2cd..25daeb35f51a 100644
--- a/dev-python/sentry-sdk/Manifest
+++ b/dev-python/sentry-sdk/Manifest
@@ -1,3 +1,4 @@
 DIST sentry-python-1.44.1.gh.tar.gz 472129 BLAKE2B ae98f7c6292ed3d95e4c33221154b065d6348c2e34efd4b4b10f083ff9082765594f39a1b0adf0df945ba7948e2b0d0d31cf2fb3987d1f65e1bd0e582be7a76b SHA512 c9de3538cdf2ccce2b6775ff57308f122d1e7f5db5036db78ec8b85a423edfbacb806080b4ededba42bc33e419b5fc71cc011bdbcf542e4aa9be1978a0129bc8
 DIST sentry-python-1.45.0.gh.tar.gz 475425 BLAKE2B 8dc46154dfc1c7c9104a706be032b5269d407dee6845da252f1c603ea4f9486d02d1d3c6bec314064b821dee31b503d07a9c17935ca1f4dd6cc4d7b9c3165094 SHA512 dad23a3f6a8e6ef5fe78e1d38a61977d8974edf306d5688537f331801d8fa0f60743d18cc3dadf6e9a9666c55a01c98b9ff8d8808ece7d8f95ee68a69b6cb9be
 DIST sentry-python-2.0.0.gh.tar.gz 484223 BLAKE2B 3630ed4585ce6088d648a28b3606e945de0e230ed4a611fc1b8954e7a05f8a3e3f80ae7110c64a54ae81569fb48a0ef3ed856f8dfeec441454238157016475d4 SHA512 a97ef336e54c2e28ae4e9ff4dc921fc892bb4567c2a926c6ec5d1c838417bb8c3293576ca450bc7f08721ebe9ce37bd45e4752b6223a76a3724f2b8912426fb4
+DIST sentry-python-2.0.1.gh.tar.gz 486632 BLAKE2B ace9891068050d988b3c16622f6937486f733caaf3de864ed973ea156e1e06e44f2d73764d01d5943a9347044c3c880bb9cf00229f2a36f2730aad9ef55660d0 SHA512 c62447a990ead1bebee89cd16d7a9d7a3798c48af53fba2cf5cece47c9bf5971fa1cd2b028b9fe8f7d9996cc48962ca50a61df9899b1c24a2dffced74f38e6ce
diff --git a/dev-python/sentry-sdk/sentry-sdk-2.0.1.ebuild b/dev-python/sentry-sdk/sentry-sdk-2.0.1.ebuild
new file mode 100644
index 000000000000..a0c6d4e1a10a
--- /dev/null
+++ b/dev-python/sentry-sdk/sentry-sdk-2.0.1.ebuild
@@ -0,0 +1,160 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P=sentry-python-${PV}
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="
+	https://sentry.io/
+	https://github.com/getsentry/sentry-python/
+	https://pypi.org/project/sentry-sdk/
+"
+SRC_URI="
+	https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		<dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/python-socks[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+		dev-python/zope-event[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}/sentry-sdk-1.21.0-ignore-warnings.patch"
+)
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# tests require Internet access
+		tests/integrations/httpx/test_httpx.py
+		tests/integrations/requests/test_requests.py
+		tests/integrations/stdlib/test_httplib.py
+		tests/integrations/flask/test_flask.py
+		tests/integrations/django/test_basic.py
+		tests/integrations/socket/test_socket.py
+		# wtf is it supposed to do?!
+		tests/integrations/gcp/test_gcp.py
+		# broken by rq-1.10.1 (optional dep)
+		tests/integrations/rq/test_rq.py
+		# fastapi is not packaged
+		tests/integrations/asgi/test_fastapi.py
+		# TODO
+		tests/integrations/bottle
+		# TODO: causes breakage in other tests
+		tests/integrations/starlette
+		# TODO
+		tests/integrations/tornado
+		# requires mockupdb
+		tests/integrations/pymongo
+		# requires AWS access
+		tests/integrations/aws_lambda
+		# requires quart_auth
+		tests/integrations/quart
+		# TODO: require opentelemetry (with py3.10)
+		tests/integrations/opentelemetry
+	)
+
+	local EPYTEST_DESELECT=(
+		# hangs
+		'tests/test_transport.py::test_transport_works'
+		# TODO
+		'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+		tests/test_client.py::test_databag_depth_stripping
+		tests/test_client.py::test_databag_string_stripping
+		tests/test_client.py::test_databag_breadth_stripping
+		tests/integrations/asgi/test_asgi.py::test_auto_session_tracking_with_aggregates
+		tests/integrations/asgi/test_asgi.py::test_websocket
+		tests/integrations/aiohttp/test_aiohttp.py::test_transaction_style
+		tests/integrations/aiohttp/test_aiohttp.py::test_traces_sampler_gets_request_object_in_sampling_context
+		tests/integrations/django/test_data_scrubbing.py::test_scrub_django_custom_session_cookies_filtered
+		# incompatible version?
+		tests/integrations/falcon/test_falcon.py
+		tests/integrations/sqlalchemy/test_sqlalchemy.py::test_large_event_not_truncated
+		tests/integrations/django/test_data_scrubbing.py::test_scrub_django_session_cookies_{filtered,removed}
+		# test_circular_references: apparently fragile
+		'tests/integrations/threading/test_threading.py::test_circular_references'
+		# test for new feature, fails with IndexError
+		tests/integrations/wsgi/test_wsgi.py::test_session_mode_defaults_to_request_mode_in_wsgi_handler
+		# TODO
+		tests/integrations/wsgi/test_wsgi.py::test_auto_session_tracking_with_aggregates
+		tests/integrations/wsgi/test_wsgi.py::test_profile_sent_when_profiling_enabled
+		tests/test_profiler.py::test_sample_buffer
+		tests/test_profiler.py::test_thread_scheduler_takes_first_samples
+		tests/test_profiler.py::test_thread_scheduler_takes_more_samples
+		tests/test_profiler.py::test_thread_scheduler_single_background_thread
+		# broken with py3.11, *shrug*
+		tests/test_profiler.py::test_extract_stack_with_max_depth
+		# TODO
+		tests/integrations/sqlalchemy/test_sqlalchemy.py::test_long_sql_query_preserved
+		tests/integrations/sqlalchemy/test_sqlalchemy.py::test_engine_name_not_string
+		tests/test_scrubber.py::test_breadcrumb_extra_scrubbing
+		tests/test_scrubber.py::test_span_data_scrubbing
+		# this is not even funny
+		tests/test_utils.py::test_installed_modules
+		# flaky hypothesis stuff
+		tests/test_serializer.py::test_bytes_serialization_repr_many
+		# TODO
+		tests/integrations/aiohttp/test_aiohttp.py::test_basic
+		tests/tracing/test_decorator_py3.py::test_trace_decorator_{,a}sync_py3
+		# crashes Python
+		tests/integrations/grpc/test_grpc_aio.py
+		# hangs
+		tests/integrations/threading/test_threading.py::test_propagates_threadpool_hub
+		# TODO
+		tests/test_utils.py::test_default_release
+		tests/integrations/sqlalchemy/test_sqlalchemy.py::test_orm_queries
+		tests/integrations/sqlalchemy/test_sqlalchemy.py::test_transactions
+		tests/integrations/sqlalchemy/test_sqlalchemy.py::test_query_source
+		tests/integrations/stdlib/test_subprocess.py::test_subprocess_basic
+		tests/integrations/threading/test_threading.py
+		tests/integrations/wsgi/test_wsgi.py
+		'tests/utils/test_contextvars.py::test_leaks[threads]'
+		# skipped without gevent but breaks stuff via broken teardown?
+		tests/test_metrics.py::test_no_metrics_with_gevent
+		# TODO
+		tests/utils/test_contextvars.py::test_leaks
+		# broken teardown?
+		tests/test_client.py::test_uwsgi_warnings
+		# too many dependencies installed, sigh
+		tests/test_new_scopes_compat_event.py
+		# TODO
+		tests/tracing/test_sampling.py::test_records_lost_event_only_if_traces_sample_rate_enabled
+		tests/tracing/test_sampling.py::test_records_lost_event_only_if_traces_sampler_enabled
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio -p aiohttp -p pytest_forked
+}
diff --git a/dev-python/setuptools/setuptools-69.2.0-r2.ebuild b/dev-python/setuptools/setuptools-69.2.0-r2.ebuild
new file mode 100644
index 000000000000..f08c9cd7cc17
--- /dev/null
+++ b/dev-python/setuptools/setuptools-69.2.0-r2.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+# please bump dev-python/ensurepip-setuptools along with this package!
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_TESTED=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="
+	https://github.com/pypa/setuptools/
+	https://pypi.org/project/setuptools/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/jaraco-text-3.7.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/more-itertools-8.12.0-r1[${PYTHON_USEDEP}]
+	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
+	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' python3_10 pypy3)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/build[${PYTHON_USEDEP}]
+			dev-python/importlib-metadata[${PYTHON_USEDEP}]
+			>=dev-python/ini2toml-0.9[${PYTHON_USEDEP}]
+			>=dev-python/filelock-3.4.0[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-envs-2.2[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/pip-run[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			>=dev-python/pytest-home-0.5[${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/tomli[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+		$(python_gen_cond_dep '
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+		' python3_10 pypy3)
+	)
+"
+# setuptools-scm is here because installing plugins apparently breaks stuff at
+# runtime, so let's pull it early. See bug #663324.
+PDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	local PATCHES=(
+		# TODO: remove this when we're 100% PEP517 mode
+		"${FILESDIR}"/setuptools-62.4.0-py-compile.patch
+	)
+
+	distutils-r1_src_prepare
+
+	# remove bundled dependencies
+	rm -r */_vendor || die
+
+	# remove the ugly */extern hack that breaks on unvendored deps
+	rm -r */extern || die
+	find -name '*.py' -exec sed \
+		-e 's:from \w*[.]\+extern ::' -e 's:\w*[.]\+extern[.]::' \
+		-i {} + || die
+}
+
+python_test() {
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# network
+		# TODO: see if PRE_BUILT_SETUPTOOLS_* helps
+		setuptools/tests/config/test_apply_pyprojecttoml.py::test_apply_pyproject_equivalent_to_setupcfg
+		setuptools/tests/integration/test_pip_install_sdist.py::test_install_sdist
+		setuptools/tests/test_build_meta.py::test_legacy_editable_install
+		setuptools/tests/test_distutils_adoption.py
+		setuptools/tests/test_editable_install.py
+		setuptools/tests/test_setuptools.py::test_its_own_wheel_does_not_contain_tests
+		setuptools/tests/test_virtualenv.py::test_clean_env_install
+		setuptools/tests/test_virtualenv.py::test_no_missing_dependencies
+		setuptools/tests/test_virtualenv.py::test_test_command_install_requirements
+		# TODO
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_basic
+		setuptools/tests/config/test_setupcfg.py::TestConfigurationReader::test_ignore_errors
+		setuptools/tests/test_extern.py::test_distribution_picklable
+		# expects bundled deps in virtualenv
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_in_sdist
+		setuptools/tests/config/test_apply_pyprojecttoml.py::TestMeta::test_example_file_not_in_wheel
+		# fails if python-xlib is installed
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		# TODO, probably some random package
+		setuptools/tests/config/test_setupcfg.py::TestOptions::test_cmdclass
+		# Internet, sigh
+		setuptools/tests/test_integration.py
+	)
+
+	case ${EPYTHON} in
+		python3.12)
+			EPYTEST_DESELECT+=(
+				# TODO
+				setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_distutils_command_dep
+				setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_transitive_extra_dependency
+			)
+	esac
+
+	local EPYTEST_XDIST=1
+	epytest -o tmp_path_retention_policy=all setuptools
+}
diff --git a/dev-python/setuptools/setuptools-69.5.1.ebuild b/dev-python/setuptools/setuptools-69.5.1-r1.ebuild
index 48473e48e55b..8649bc87d509 100644
--- a/dev-python/setuptools/setuptools-69.5.1.ebuild
+++ b/dev-python/setuptools/setuptools-69.5.1-r1.ebuild
@@ -32,8 +32,10 @@ RDEPEND="
 	>=dev-python/ordered-set-4.0.2-r1[${PYTHON_USEDEP}]
 	>=dev-python/packaging-24[${PYTHON_USEDEP}]
 	>=dev-python/platformdirs-2.6.2-r1[${PYTHON_USEDEP}]
-	>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
 	>=dev-python/wheel-0.37.1-r1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' python3_10 pypy3)
 "
 BDEPEND="
 	${RDEPEND}
@@ -52,9 +54,11 @@ BDEPEND="
 			dev-python/pytest-timeout[${PYTHON_USEDEP}]
 			dev-python/pytest-xdist[${PYTHON_USEDEP}]
 			dev-python/tomli[${PYTHON_USEDEP}]
-			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
 			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
 		' "${PYTHON_TESTED[@]}")
+		$(python_gen_cond_dep '
+			>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+		' python3_10 pypy3)
 	)
 "
 # setuptools-scm is here because installing plugins apparently breaks stuff at
diff --git a/dev-python/superqt/Manifest b/dev-python/superqt/Manifest
index bbe404ed2a09..e3c34fc11b5b 100644
--- a/dev-python/superqt/Manifest
+++ b/dev-python/superqt/Manifest
@@ -1,3 +1 @@
-DIST superqt-0.6.2.tar.gz 94990 BLAKE2B 1990dcd048fd18913d2c68eb41dd3a0fb1778e468e6c74608f6171e92c0f2a4bf828fb3f73fbbf47f2404fda9864af8bcac66a0a490c35c596e5b5090be39a3a SHA512 8c794ea8dfb8e5aedb3390ce895d392e76faa714f08c1a43c4d8b82ca6353317d9050e5b79d0696e85247fb8772c5fea20642bd7914b1713cd63a737c64397fb
-DIST superqt-0.6.3.tar.gz 95200 BLAKE2B 8cd751cd3aefeca192c795ecac4002b8556ea9f6f3a9f7be3b44ff5327dc0dd578cf81aef899453892a5fb43636016abbe808f89e46e3ab8ad88e2094c65f385 SHA512 f50a23cd2999f911160c2b4881501110ea3157640d5801d220f84e38f92cdf7c405194ddf26c990057103c75238ceebef77ec42f7da5f438b702dea10db7232b
 DIST superqt-0.6.4.tar.gz 95502 BLAKE2B 0354fbea1925bac84a72fc1d8e0402ba80fdd38cdec32a0e91c4b360dc8d906d631e5e36ffea8d20baae9d1e620417a08f19c2d4d37778f2e50ca3673e12bca3 SHA512 934df6d7c0dd80e045a03b88fb6b254fd7f7e3a09c882bcd46c3635ed7ba434c5704b110dd590a491fc9cead767c2f885245fdae09ef26e1a1e556d66cb2d7a3
diff --git a/dev-python/superqt/superqt-0.6.2.ebuild b/dev-python/superqt/superqt-0.6.2.ebuild
deleted file mode 100644
index 8aeb86dcb3a0..000000000000
--- a/dev-python/superqt/superqt-0.6.2.ebuild
+++ /dev/null
@@ -1,49 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
-
-inherit distutils-r1 pypi virtualx
-
-DESCRIPTION="Missing widgets and components for PyQt/PySide"
-HOMEPAGE="
-	https://github.com/pyapp-kit/superqt
-	https://pypi.org/project/superqt/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64"
-
-RDEPEND="
-	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
-	>=dev-python/QtPy-1.1.0[${PYTHON_USEDEP}]
-	>=dev-python/typing-extensions-3.7.4.3[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/pytest-qt[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_IGNORE=(
-	# pint and pyconify not packaged
-	tests/test_quantity.py
-)
-
-EPYTEST_DESELECT=(
-	# fails in the sandbox, but works outside of it
-	tests/test_eliding_label.py::test_wrapped_eliding_label
-)
-
-distutils_enable_tests pytest
-
-python_test() {
-	virtx distutils-r1_python_test
-}
diff --git a/dev-python/superqt/superqt-0.6.3.ebuild b/dev-python/superqt/superqt-0.6.3.ebuild
deleted file mode 100644
index 8aeb86dcb3a0..000000000000
--- a/dev-python/superqt/superqt-0.6.3.ebuild
+++ /dev/null
@@ -1,49 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=hatchling
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
-
-inherit distutils-r1 pypi virtualx
-
-DESCRIPTION="Missing widgets and components for PyQt/PySide"
-HOMEPAGE="
-	https://github.com/pyapp-kit/superqt
-	https://pypi.org/project/superqt/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64"
-
-RDEPEND="
-	>=dev-python/pygments-2.4.0[${PYTHON_USEDEP}]
-	>=dev-python/QtPy-1.1.0[${PYTHON_USEDEP}]
-	>=dev-python/typing-extensions-3.7.4.3[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	dev-python/hatch-vcs[${PYTHON_USEDEP}]
-	test? (
-		dev-python/numpy[${PYTHON_USEDEP}]
-		dev-python/pytest-qt[${PYTHON_USEDEP}]
-	)
-"
-
-EPYTEST_IGNORE=(
-	# pint and pyconify not packaged
-	tests/test_quantity.py
-)
-
-EPYTEST_DESELECT=(
-	# fails in the sandbox, but works outside of it
-	tests/test_eliding_label.py::test_wrapped_eliding_label
-)
-
-distutils_enable_tests pytest
-
-python_test() {
-	virtx distutils-r1_python_test
-}
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 197638f3473d..0bddde40eb69 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1 +1,2 @@
 DIST tox-4.14.2.tar.gz 178515 BLAKE2B 812a4e0ffe218c5799a5bdf76cc5f1f99f60c7de464953349283e3951c91aded247941cb173bfdff670c9c079b9efb3645220ff7126b7e0cf341071d561a375b SHA512 45bbd3f8d00eee05158452295230321947ec16a8bfff43e84ea9825d514976526f3889709255ed042cfb7a7ebfed020707cfc2d25b69ce90c148f4472092350d
+DIST tox-4.15.0.tar.gz 179243 BLAKE2B ba126d2dbe9598667570e1798567cf2301a60ca4859947b0b5cd15603b6f1b9c1b557bc090973a3c99960c29242edbb684d9ab81b90ecca3ac020b129a033850 SHA512 a113d8e921301dc4bc39e03103f8857604b28beedc49c764315cf99694e8a351b965e0e1b7d91555ce437a1cbb2bce0e1dd645b7c92c36e8e0e1dedcf610d1af
diff --git a/dev-python/tox/tox-4.15.0.ebuild b/dev-python/tox/tox-4.15.0.ebuild
new file mode 100644
index 000000000000..60ee4e5af69b
--- /dev/null
+++ b/dev-python/tox/tox-4.15.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}