Adding metadata

7 files changed, 167 insertions, 0 deletions

diff --git a/dev-python/kicad-python/Manifest b/dev-python/kicad-python/Manifest
new file mode 100644
index 000000000000..e32ced13f190
--- /dev/null
+++ b/dev-python/kicad-python/Manifest
@@ -0,0 +1 @@
+DIST kicad_python-0.5.0.tar.gz 198708 BLAKE2B 6a4e756289de711e633f3adc07e1aaaa6820dad9c5ec6d605bf96bdc0ea74ea622394e15078268c0d1c47b73f304f99b04cb77d86a673e441b7680b3893691d2 SHA512 7d4f0d005525e6a646df0e25fb59cf93a55f9ea072821062c0384a386c382b24f9ccad204f06bc52d4f90158eefb923692497470e0a43ee2947f1b2057a73779
diff --git a/dev-python/kicad-python/kicad-python-0.5.0.ebuild b/dev-python/kicad-python/kicad-python-0.5.0.ebuild
new file mode 100644
index 000000000000..98cdac326f5d
--- /dev/null
+++ b/dev-python/kicad-python/kicad-python-0.5.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..14} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="KiCad API Python Bindings for interacting with running KiCad sessions"
+HOMEPAGE="https://gitlab.com/kicad/code/kicad-python https://pypi.org/project/kicad-python"
+
+LICENSE="MIT"
+SLOT=0
+KEYWORDS="~amd64"
+
+# Tests not included in PyPI sdist
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/protobuf-5.29[${PYTHON_USEDEP}]
+	<dev-python/protobuf-6[${PYTHON_USEDEP}]
+	>=dev-python/pynng-0.8.0[${PYTHON_USEDEP}]
+	<dev-python/pynng-0.9.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.13.2[${PYTHON_USEDEP}]
+	' python3_{10..12})
+"
+BDEPEND="${RDEPEND}"
+
+src_prepare() {
+	# Remove build script config from pyproject.toml
+	# The sdist already contains pre-generated protobuf files
+	sed -i '/\[tool.poetry.build\]/,/^$/d' pyproject.toml || die
+	rm -f setup.py build.py || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/kicad-python/metadata.xml b/dev-python/kicad-python/metadata.xml
new file mode 100644
index 000000000000..719c1cf0f530
--- /dev/null
+++ b/dev-python/kicad-python/metadata.xml
@@ -0,0 +1,28 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>vowstar@gmail.com</email>
+  <name>Huang Rui</name>
+ </maintainer>
+ <longdescription lang="en">
+		kicad-python is the official Python library for interacting with running
+		KiCad sessions through the IPC API. It enables development of scripts
+		and tools for electronic design automation workflows. The library requires
+		KiCad 9.0 or higher with the API server enabled in Preferences. Note that
+		the IPC API requires communication with a running instance of KiCad; it
+		is not possible to use kicad-python to manipulate KiCad design files
+		without KiCad running.
+	</longdescription>
+ <longdescription lang="zh">
+		kicad-python是用于通过IPC API与运行中的KiCad会话进行交互的官方Python库。
+		它支持开发用于电子设计自动化工作流程的脚本和工具。该库需要KiCad 9.0或更高版本，
+		并在首选项中启用API服务器。请注意，IPC API需要与正在运行的KiCad实例通信；
+		如果没有运行KiCad，则无法使用kicad-python操作KiCad设计文件。
+	</longdescription>
+ <upstream>
+  <bugs-to>https://gitlab.com/kicad/code/kicad-python/-/issues</bugs-to>
+  <doc>https://docs.kicad.org/kicad-python-main/</doc>
+ </upstream>
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pynng/Manifest b/dev-python/pynng/Manifest
new file mode 100644
index 000000000000..ad65ff108c41
--- /dev/null
+++ b/dev-python/pynng/Manifest
@@ -0,0 +1 @@
+DIST pynng-0.8.1.tar.gz 6364925 BLAKE2B ae10e9155997474634ca7cf6e1ff01572f877dc8157aea069e11866b29fe92a2ee8343fd1512fad57f25e5c4cbf7297c784ab9fcdc7c262aba889cd65595775d SHA512 b150a83b65169aa67aaf99d963ae43ede29ccf22f1ddc9989a0d999f32dd93412bbf464ad0c3eed7aa645e0f5e2726743d131e48276955dad034e219b23c93c4
diff --git a/dev-python/pynng/metadata.xml b/dev-python/pynng/metadata.xml
new file mode 100644
index 000000000000..8e5fae92b5bc
--- /dev/null
+++ b/dev-python/pynng/metadata.xml
@@ -0,0 +1,25 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+  <email>vowstar@gmail.com</email>
+  <name>Huang Rui</name>
+ </maintainer>
+ <longdescription lang="en">
+		pynng provides ergonomic Python bindings for nanomsg next generation (nng),
+		a lightweight messaging library. It enables inter-process communication
+		across single computers or networks using various messaging patterns
+		including Pair, Pub/Sub, Surveyor/Respondent, Req/Rep, and Push/Pull.
+		The library supports async frameworks like trio, curio, and asyncio.
+	</longdescription>
+ <longdescription lang="zh">
+		pynng为nanomsg下一代（nng）轻量级消息库提供符合人体工程学的Python绑定。
+		它支持在单台计算机或网络上进行进程间通信，使用多种消息模式，包括Pair（配对）、
+		Pub/Sub（发布/订阅）、Surveyor/Respondent（调查者/响应者）、Req/Rep（请求/回复）
+		和Push/Pull（推/拉）。该库支持trio、curio和asyncio等异步框架。
+	</longdescription>
+ <upstream>
+  <bugs-to>https://github.com/codypiersall/pynng/issues</bugs-to>
+ </upstream>
+ <origin>gentoo-guru-overlay</origin>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pynng/pynng-0.8.1.ebuild b/dev-python/pynng/pynng-0.8.1.ebuild
new file mode 100644
index 000000000000..1cd3bb3da713
--- /dev/null
+++ b/dev-python/pynng/pynng-0.8.1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+inherit distutils-r1 pypi
+
+DESCRIPTION="Ergonomic bindings for nanomsg next generation (nng) in Python"
+HOMEPAGE="https://github.com/codypiersall/pynng https://pypi.org/project/pynng"
+
+LICENSE="MIT"
+SLOT=0
+KEYWORDS="~amd64"
+
+DEPEND="dev-libs/nng"
+RDEPEND="
+	${DEPEND}
+	dev-python/cffi[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cffi[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-trio[${PYTHON_USEDEP}]
+		dev-python/sniffio[${PYTHON_USEDEP}]
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# Remove source pynng directory to avoid import conflicts
+	# Tests must run against the installed C extension module
+	rm -rf pynng || die
+	epytest
+}
diff --git a/dev-python/whitenoise/whitenoise-6.11.0-r1.ebuild b/dev-python/whitenoise/whitenoise-6.11.0-r1.ebuild
new file mode 100644
index 000000000000..7524caeab37e
--- /dev/null
+++ b/dev-python/whitenoise/whitenoise-6.11.0-r1.ebuild
@@ -0,0 +1,33 @@
+# Copyright 2025 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Radically simplified static file serving for Python web apps"
+HOMEPAGE="https://github.com/evansd/whitenoise"
+SRC_URI="https://github.com/evansd/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/furo
+
+pkg_postinst() {
+	optfeature "brotli compression" "app-arch/brotli[python]"
+}