Adding metadata

15 files changed, 303 insertions, 6 deletions

diff --git a/dev-python/PyQt-builder/Manifest b/dev-python/PyQt-builder/Manifest
index 250b654500af..3ea0cb980312 100644
--- a/dev-python/PyQt-builder/Manifest
+++ b/dev-python/PyQt-builder/Manifest
@@ -1 +1,2 @@
 DIST PyQt-builder-1.12.2.tar.gz 5727071 BLAKE2B ca5d55989fec2a9a6f9d37abc307d4db7305bb06449cbf982aa3a2a3f210113319f7fb303ec0d77b513cce844b529e0e56f62c9d62ab3c51cf85a061ecd00c7a SHA512 022f2cd40c100543c4b442fc5b27bbf2ec853d94b531f8f6dc1d7f92b07bcc20e8f0a4eb64feb96d094ba0d5f01fddcc8aed23ddf67a61417e07983a73918230
+DIST PyQt-builder-1.14.1.tar.gz 3907982 BLAKE2B f2ac51b6af3b90d14e1acea1c292f71df6b84e4a6b930b70762a29d58e34303d9788911c99127ff15b85b4f7f7ae699ed2aa3094b7f187aeb92338feaaaadfb0 SHA512 4de9be2c42f38fbc22d46a31dd6da37c02620bb112a674ef846a4eb7f862715852e1d7328da1e0d0e33f78475166fe3c690e710e18bfeb48f840f137831a2182
diff --git a/dev-python/PyQt-builder/PyQt-builder-1.14.1.ebuild b/dev-python/PyQt-builder/PyQt-builder-1.14.1.ebuild
new file mode 100644
index 000000000000..760497dc734f
--- /dev/null
+++ b/dev-python/PyQt-builder/PyQt-builder-1.14.1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit distutils-r1
+
+DESCRIPTION="The PEP 517 compliant PyQt build system"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqt-builder/ https://pypi.org/project/PyQt-builder/"
+
+MY_P=${PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+fi
+S=${WORKDIR}/${MY_P}
+
+LICENSE="|| ( GPL-2 GPL-3 SIP )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.7.1[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx doc --no-autodoc
+
+python_prepare_all() {
+	# don't install prebuilt Windows DLLs
+	sed -i -e "s:'dlls/\*/\*',::" setup.py || die
+	rm -r "${PN/-/_}.egg-info" || die
+
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/PyQt5-sip/Manifest b/dev-python/PyQt5-sip/Manifest
index a901c627763c..738d7d738639 100644
--- a/dev-python/PyQt5-sip/Manifest
+++ b/dev-python/PyQt5-sip/Manifest
@@ -1 +1,2 @@
 DIST PyQt5_sip-12.11.0.tar.gz 122792 BLAKE2B a2cde0a741fb5ef6d6805a382b66405dcebe09a18cbe1b7d88b277d96995b93b0a939900be9ed347ab46c8ed5d14b222c56f2e19e1506b72ebfda46aab8a22b1 SHA512 1542747ef1912c05b0054ffec16294046e20dd4eb757bb664fb92d7b6ed924521469e88d27e515146f725d153e3ebe3a3bf72805de6451fb52ff86ed5b9128d7
+DIST PyQt5_sip-12.11.1.tar.gz 122858 BLAKE2B 6e7dd31b290ed211b73162ee12b923ba46d7af1661094367ecf4d69f572bd7394576a55667fb99ada306c05eced79c1df68f4184d8fe937a1dedd0913f75379f SHA512 9a24b6e8356fdb1070672ee37e5f4259d72a75bb60376ad0946274331ae29a6cceb98a6c5a278bf5e8015a3d493c925bacab8593ef02c310ff3773bd3ee46a5d
diff --git a/dev-python/PyQt5-sip/PyQt5-sip-12.11.1.ebuild b/dev-python/PyQt5-sip/PyQt5-sip-12.11.1.ebuild
new file mode 100644
index 000000000000..3101d0d2566a
--- /dev/null
+++ b/dev-python/PyQt5-sip/PyQt5-sip-12.11.1.ebuild
@@ -0,0 +1,23 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="sip extension module for PyQt5"
+HOMEPAGE="https://www.riverbankcomputing.com/software/sip/ https://pypi.org/project/PyQt5-sip/"
+
+MY_P=${PN/-/_}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+fi
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="|| ( GPL-2 GPL-3 SIP )"
+SLOT="0/$(ver_cut 1)"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
diff --git a/dev-python/PyQt5/Manifest b/dev-python/PyQt5/Manifest
index 33d5bc51cbf9..13d008c95ef0 100644
--- a/dev-python/PyQt5/Manifest
+++ b/dev-python/PyQt5/Manifest
@@ -1 +1,2 @@
 DIST PyQt5-5.15.7.tar.gz 3238978 BLAKE2B 8e810444d9e4fe0c5af702161bc834848eefb6fdf04b282bbf42a9057d564aa778a01a5d40c249c10eecafb0dce8d160f032668f0d1fc87714fd874f002ec88a SHA512 815065f88454f767525fdd2caf97b0192eaf6095133c9c708ee4efa3d222742720a169856be65c84400a6e8d42d69ae65697d7f9dd17b9b4a347d75db93c5129
+DIST PyQt5-5.15.9.tar.gz 3241160 BLAKE2B 37d7227e09c48576a51030729217d2c0771b2f833cfac76ff05dd0c9315889548934ceb459e590a5a9bc3a9ea2b26200791e470788f7d5b28a80fbc21539aa2f SHA512 1c07d93aefe1c24e80851eb4631b80a99e7ba06e823181325456edb90285d3d22417a9f7d4c3ff9c6195bd801e7dc2bbabf0587af844a5e4b0a410c4611d119e
diff --git a/dev-python/PyQt5/PyQt5-5.15.9.ebuild b/dev-python/PyQt5/PyQt5-5.15.9.ebuild
new file mode 100644
index 000000000000..ee75dc9d7fe0
--- /dev/null
+++ b/dev-python/PyQt5/PyQt5-5.15.9.ebuild
@@ -0,0 +1,183 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit python-r1 qmake-utils
+
+DESCRIPTION="Python bindings for the Qt framework"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqt/ https://pypi.org/project/PyQt5/"
+
+MY_P=${PN}-${PV/_pre/.dev}
+if [[ ${PV} == *_pre* ]]; then
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+fi
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+# TODO: QtNfc, QtQuick3D, QtRemoteObjects
+IUSE="bluetooth dbus debug declarative designer examples gles2-only gui help location
+	multimedia network opengl positioning printsupport sensors serialport speech
+	sql +ssl svg testlib webchannel websockets widgets x11extras xmlpatterns"
+
+# The requirements below were extracted from the qmake_QT declarations
+# in project.py and from the output of 'grep -r "%Import " ${S}/sip'
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	bluetooth? ( gui )
+	declarative? ( gui network )
+	designer? ( widgets )
+	help? ( gui widgets )
+	location? ( positioning )
+	multimedia? ( gui network )
+	opengl? ( gui widgets )
+	positioning? ( gui )
+	printsupport? ( gui widgets )
+	sensors? ( gui )
+	serialport? ( gui )
+	sql? ( widgets )
+	svg? ( gui widgets )
+	testlib? ( widgets )
+	webchannel? ( network )
+	websockets? ( network )
+	widgets? ( gui )
+	xmlpatterns? ( network )
+"
+
+# Minimal supported version of Qt.
+QT_PV="5.15:5"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtcore-${QT_PV}
+	>=dev-qt/qtxml-${QT_PV}
+	bluetooth? ( >=dev-qt/qtbluetooth-${QT_PV} )
+	dbus? (
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		>=dev-qt/qtdbus-${QT_PV}
+	)
+	declarative? ( >=dev-qt/qtdeclarative-${QT_PV}[widgets?] )
+	designer? ( >=dev-qt/designer-${QT_PV} )
+	gui? ( >=dev-qt/qtgui-${QT_PV}[gles2-only=] )
+	help? ( >=dev-qt/qthelp-${QT_PV} )
+	location? ( >=dev-qt/qtlocation-${QT_PV} )
+	multimedia? ( >=dev-qt/qtmultimedia-${QT_PV}[widgets?] )
+	network? ( >=dev-qt/qtnetwork-${QT_PV}[ssl=] )
+	opengl? ( >=dev-qt/qtopengl-${QT_PV} )
+	positioning? ( >=dev-qt/qtpositioning-${QT_PV} )
+	printsupport? ( >=dev-qt/qtprintsupport-${QT_PV} )
+	sensors? ( >=dev-qt/qtsensors-${QT_PV} )
+	serialport? ( >=dev-qt/qtserialport-${QT_PV} )
+	speech? ( >=dev-qt/qtspeech-${QT_PV} )
+	sql? ( >=dev-qt/qtsql-${QT_PV} )
+	svg? ( >=dev-qt/qtsvg-${QT_PV} )
+	testlib? ( >=dev-qt/qttest-${QT_PV} )
+	webchannel? ( >=dev-qt/qtwebchannel-${QT_PV} )
+	websockets? ( >=dev-qt/qtwebsockets-${QT_PV} )
+	widgets? ( >=dev-qt/qtwidgets-${QT_PV} )
+	x11extras? ( >=dev-qt/qtx11extras-${QT_PV} )
+	xmlpatterns? ( >=dev-qt/qtxmlpatterns-${QT_PV} )
+"
+RDEPEND="${DEPEND}
+	>=dev-python/PyQt5-sip-12.11:=[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/PyQt-builder-1.14.1[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.6.2[${PYTHON_USEDEP}]
+	>=dev-qt/qtcore-${QT_PV}
+	dbus? ( virtual/pkgconfig )
+"
+
+src_configure() {
+	pyqt_use_enable() {
+		use "$1" || return
+
+		if [[ $# -eq 1 ]]; then
+			echo --enable=Qt${1^}
+		else
+			shift
+			echo ${@/#/--enable=}
+		fi
+	}
+
+	configuration() {
+		local myconf=(
+			sip-build
+			--verbose
+			--confirm-license
+			--build-dir="${BUILD_DIR}"
+			--scripts-dir="$(python_get_scriptdir)"
+			--qmake="$(qt5_get_bindir)"/qmake
+			--no-make
+			$(usev debug '--debug --qml-debug --tracing')
+			$(usev !dbus --no-dbus-python)
+			$(usev !declarative --no-qml-plugin)
+			$(usev !designer --no-designer-plugin)
+			$(usev gles2-only --disabled-feature=PyQt_Desktop_OpenGL)
+			$(usev !ssl --disabled-feature=PyQt_SSL)
+			--enable=pylupdate
+			--enable=pyrcc
+			--enable=Qt
+			$(pyqt_use_enable bluetooth)
+			--enable=QtCore
+			$(pyqt_use_enable dbus QtDBus)
+			$(pyqt_use_enable declarative QtQml QtQuick $(usev widgets QtQuickWidgets))
+			$(pyqt_use_enable designer)
+			$(pyqt_use_enable gui)
+			$(pyqt_use_enable gui $(use gles2-only && echo _QOpenGLFunctions_ES2 || echo _QOpenGLFunctions_{2_0,2_1,4_1_Core}))
+			$(pyqt_use_enable help)
+			$(pyqt_use_enable location)
+			$(pyqt_use_enable multimedia QtMultimedia $(usev widgets QtMultimediaWidgets))
+			$(pyqt_use_enable network)
+			$(pyqt_use_enable opengl QtOpenGL)
+			$(pyqt_use_enable positioning)
+			$(pyqt_use_enable printsupport QtPrintSupport)
+			$(pyqt_use_enable sensors)
+			$(pyqt_use_enable serialport QtSerialPort)
+			$(pyqt_use_enable speech QtTextToSpeech)
+			$(pyqt_use_enable sql)
+			$(pyqt_use_enable svg)
+			$(pyqt_use_enable testlib QtTest)
+			$(pyqt_use_enable webchannel QtWebChannel)
+			$(pyqt_use_enable websockets QtWebSockets)
+			$(pyqt_use_enable widgets)
+			$(pyqt_use_enable x11extras QtX11Extras)
+			--enable=QtXml
+			$(pyqt_use_enable xmlpatterns QtXmlPatterns)
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+
+		# Run eqmake to respect toolchain and build flags
+		run_in_build_dir eqmake5 -recursive ${PN}.pro
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	installation() {
+		emake INSTALL_ROOT="${D}" install
+		python_optimize
+
+		local exe
+		for exe in "${D}$(python_get_scriptdir)"/*; do
+			python_doexe "${exe}"
+		done
+	}
+	python_foreach_impl run_in_build_dir installation
+
+	einstalldocs
+
+	if use examples; then
+		dodoc -r examples
+	fi
+}
diff --git a/dev-python/accessible-pygments/accessible-pygments-0.0.3.ebuild b/dev-python/accessible-pygments/accessible-pygments-0.0.3.ebuild
index b7f10287bf45..5b6db291869b 100644
--- a/dev-python/accessible-pygments/accessible-pygments-0.0.3.ebuild
+++ b/dev-python/accessible-pygments/accessible-pygments-0.0.3.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~riscv ~sparc"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 
 RDEPEND="
 	>=dev-python/pygments-1.5[${PYTHON_USEDEP}]
diff --git a/dev-python/bandit/bandit-1.7.5.ebuild b/dev-python/bandit/bandit-1.7.5-r1.ebuild
index 921434461b9f..f6adf2bbfef4 100644
--- a/dev-python/bandit/bandit-1.7.5.ebuild
+++ b/dev-python/bandit/bandit-1.7.5-r1.ebuild
@@ -22,6 +22,7 @@ RDEPEND="
 	>=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
 	>=dev-python/GitPython-1.0.1[${PYTHON_USEDEP}]
 	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
 	>=dev-python/stevedore-1.20.0[${PYTHON_USEDEP}]
 "
 BDEPEND="
diff --git a/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.13.1.ebuild b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.13.1.ebuild
index 6582bd61c423..6ffad3211c37 100644
--- a/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.13.1.ebuild
+++ b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.13.1.ebuild
@@ -22,7 +22,7 @@ SRC_URI="
 
 LICENSE="BSD-with-disclosure"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~riscv ~sparc"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 
 RDEPEND="
 	dev-python/accessible-pygments[${PYTHON_USEDEP}]
diff --git a/dev-python/selenium/selenium-4.8.2.ebuild b/dev-python/selenium/selenium-4.8.2.ebuild
index 36834f5e72fc..4346d4e90835 100644
--- a/dev-python/selenium/selenium-4.8.2.ebuild
+++ b/dev-python/selenium/selenium-4.8.2.ebuild
@@ -25,7 +25,7 @@ SRC_URI+="
 	)
 "
 
-KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+KEYWORDS="~amd64 ~ppc ~riscv ~sparc ~x86"
 LICENSE="Apache-2.0"
 SLOT="0"
 
@@ -38,6 +38,11 @@ RDEPEND="
 	<dev-python/urllib3-2[${PYTHON_USEDEP}]
 	>=dev-python/urllib3-1.26[${PYTHON_USEDEP}]
 "
+BDEPEND="
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
 
 distutils_enable_tests pytest
 
diff --git a/dev-python/sip/Manifest b/dev-python/sip/Manifest
index f33cd69f4a37..cc216d27b17e 100644
--- a/dev-python/sip/Manifest
+++ b/dev-python/sip/Manifest
@@ -1,2 +1,3 @@
 DIST sip-4.19.25.tar.gz 1056384 BLAKE2B f92e105e6b30e871aea2883dc9cd459e4032fb139a9eaff153a3412a66b39df4d7ac985711a2693aee83195ff3850ae648bee4102f7fc3cc30d09885799f2b98 SHA512 60fb4133c68869bf0993144978b4847d94a0f9c7b477f64a346ea133cfe35bc11820204ab327dcf9a929b6f65a26d16cc7efbce65e49967c3347b39376e57001
 DIST sip-6.7.5.tar.gz 1160691 BLAKE2B 64572687e026854c3e8ba7de637925f13a880e51e574993e37190b9b1fafa1850da686600a652bab9d399f58516e2c4e4d8a93f5fb13d53a12ecc5ec3885a98c SHA512 2dc38a6c0489e374a016b7db1f9443bb5d2fb29dc1fa7647ed2dd5bb4aa8758586e2b85569f9fb3b992e15eded0f7a783ec1a53b3d18bee3f8be53d43b79b7b9
+DIST sip-6.7.7.tar.gz 1161807 BLAKE2B b9a49e2d86f3b13b5852b91403946920c25e9b7c3cb3129f6beece1ba6d607493a04fb0d5c0dd564fbe4b7e814ad9837daf6331096b7a1a4a24ff2a7bb11acb4 SHA512 b41a1e53e8bad1fca08eda2c89b8a7cabe6cb9e54d0ddeba0c718499b0288633fb6b90128d54f3df2420e20bb217d3df224750d30e865487d2b0a640fba82444
diff --git a/dev-python/sip/sip-6.7.7.ebuild b/dev-python/sip/sip-6.7.7.ebuild
new file mode 100644
index 000000000000..ba94e17b49b5
--- /dev/null
+++ b/dev-python/sip/sip-6.7.7.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+DESCRIPTION="Python bindings generator for C/C++ libraries"
+HOMEPAGE="
+	https://www.riverbankcomputing.com/software/sip/
+	https://pypi.org/project/sip/
+"
+
+if [[ ${PV} == *_pre* ]]; then
+	MY_P=${PN}-${PV/_pre/.dev}
+	SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${MY_P}.tar.gz"
+	S=${WORKDIR}/${MY_P}
+else
+	inherit pypi
+fi
+
+LICENSE="|| ( GPL-2 GPL-3 SIP )"
+SLOT="5"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	!<dev-python/sip-4.19.25-r1[${PYTHON_USEDEP}]
+	!=dev-python/sip-5.5.0-r0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/ply[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{8..10})
+"
+
+distutils_enable_sphinx doc --no-autodoc
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.7.5-tomli.patch
+)
diff --git a/dev-python/sphinx-rtd-theme/sphinx-rtd-theme-1.2.0.ebuild b/dev-python/sphinx-rtd-theme/sphinx-rtd-theme-1.2.0.ebuild
index d761be07cd42..2a6f41ecbf61 100644
--- a/dev-python/sphinx-rtd-theme/sphinx-rtd-theme-1.2.0.ebuild
+++ b/dev-python/sphinx-rtd-theme/sphinx-rtd-theme-1.2.0.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 
 RDEPEND="
 	dev-python/docutils[${PYTHON_USEDEP}]
diff --git a/dev-python/sphinxcontrib-jquery/sphinxcontrib-jquery-3.0.0.ebuild b/dev-python/sphinxcontrib-jquery/sphinxcontrib-jquery-3.0.0.ebuild
index e1141a8a71da..b3cb84658a7a 100644
--- a/dev-python/sphinxcontrib-jquery/sphinxcontrib-jquery-3.0.0.ebuild
+++ b/dev-python/sphinxcontrib-jquery/sphinxcontrib-jquery-3.0.0.ebuild
@@ -23,7 +23,7 @@ S=${WORKDIR}/${MY_P}
 # MIT for jQuery
 LICENSE="0BSD MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/trio-websocket/trio-websocket-0.9.2.ebuild b/dev-python/trio-websocket/trio-websocket-0.9.2.ebuild
index 37fa927ed8a6..f8f131e4b6a3 100644
--- a/dev-python/trio-websocket/trio-websocket-0.9.2.ebuild
+++ b/dev-python/trio-websocket/trio-websocket-0.9.2.ebuild
@@ -20,7 +20,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+KEYWORDS="~amd64 ~ppc ~riscv ~sparc ~x86"
 
 RDEPEND="
 	>=dev-python/async_generator-1.10[${PYTHON_USEDEP}]