Adding metadata

31 files changed, 748 insertions, 10 deletions

diff --git a/dev-python/ansible-compat/Manifest b/dev-python/ansible-compat/Manifest
index 512fb585cd08..37f74ab047c5 100644
--- a/dev-python/ansible-compat/Manifest
+++ b/dev-python/ansible-compat/Manifest
@@ -1 +1,2 @@
 DIST ansible-compat-24.9.1.gh.tar.gz 76018 BLAKE2B 581199ab65ccc884a3eeef246a8dbe527cac91fc3b588edaf1ad45e7aa83a2e77d44eab8e9dc5d7f2598b02a22fb724ccf235d25592ff8c9de0b7718b9ad5507 SHA512 d5da3cbd29bfb49b9ac68f004eb957edbfdfa303ce204e230117e9964df36c6bcbf3b47ef343d6a77b4f24c390266aebd649a8036cf9e7f29dc350d207ab7409
+DIST ansible_compat-24.10.0.tar.gz 81818 BLAKE2B 78afad41dbe2172cb485186d78a488343391b5feb39f233f8584dc65ece8f290b43c8a6b0112db4606329bc5f38a9e44c6e39fd48efcb5562292152d44276539 SHA512 636ccb66be3570bf7ab0a51f991fefe3b4754db3fddb4d45ebd116de2721082e8ad4049e0cdd975431f01daaa4cb9d24ca57a97913fa66ce1f1f47780734ab14
diff --git a/dev-python/ansible-compat/ansible-compat-24.10.0.ebuild b/dev-python/ansible-compat/ansible-compat-24.10.0.ebuild
new file mode 100644
index 000000000000..b103d207c4fc
--- /dev/null
+++ b/dev-python/ansible-compat/ansible-compat-24.10.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Contains functions that facilitate working with various versions of Ansible"
+HOMEPAGE="
+	https://pypi.org/project/ansible-compat/
+	https://github.com/ansible/ansible-compat/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=app-admin/ansible-core-2.18.1[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-4.23.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/subprocess-tee-0.4.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-plus[${PYTHON_USEDEP}]
+	)
+"
+
+# All these tests attempt to connect to galaxy.ansible.com
+EPYTEST_DESELECT=(
+	test/test_runtime.py::test_install_collection
+	test/test_runtime.py::test_install_collection_dest
+	test/test_runtime.py::test_prepare_environment_with_collections
+	test/test_runtime.py::test_prerun_reqs_v1
+	test/test_runtime.py::test_prerun_reqs_v2
+	test/test_runtime.py::test_require_collection_no_cache_dir
+	test/test_runtime.py::test_require_collection_wrong_version
+	test/test_runtime.py::test_require_collection
+	test/test_runtime.py::test_upgrade_collection
+	test/test_runtime_example.py::test_runtime
+	# pip, failing due to internets
+	test/test_runtime_scan_path.py::test_scan_sys_path
+	# internets?
+	test/test_runtime.py::test_runtime_has_playbook
+)
+
+distutils_enable_tests pytest
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 5fcf59d7fecc..b88171cc33e2 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,3 +3,4 @@ DIST boto3-1.35.71.gh.tar.gz 903019 BLAKE2B 48bf56c54a8eaa52c1850078a92cef7e5acb
 DIST boto3-1.35.76.gh.tar.gz 910113 BLAKE2B 3e7429976b348e29ba4184bffe03c643b85dd978cc520b924263e8430b5e5935b95152cced2f6c0807c65de4e6e1405c55bb24565ac5bc425292e9adac178c03 SHA512 132f37e77b7b36d525e9cf678fe2f624eed77a9eb9fa8e7d7f079a362e5d7a5f3edcd17c7d8bc1e27570171927d26e74a94d267a1b0cbddda3890ac6a0f21cdc
 DIST boto3-1.35.77.gh.tar.gz 910574 BLAKE2B a843c871e53069a7a3c818e326ea5c32d506873e2381057d269e4a04f5e3be9d37aeb6e38bff4051c4d4ce3ae30e41253008785ac9bca329a17bea0f914bdc0c SHA512 e0de5951492860d48d68888ad734e33c6e8c3747f54c7164b0fca5ee9cbf2ec84e2a1a04f2b5566874bb086dcbdd096f588def36d11038663a2762bccbaf7c8e
 DIST boto3-1.35.78.gh.tar.gz 911245 BLAKE2B 2afcee97ef800b934c7f5cc2046831cb48b277951f77dc9aa844dfae4e7f9fc33b36b9d1e58a727485720ffd66ce3440c7f6d103e771b43ac355634110b14d88 SHA512 d73db44fdcdeb7d82e755c1b66084d7e47884c880e615b537f9388a9dda97d8e825613567f7ce94eb5972880b790fe841ca3765c8689c1387ec69dc0cba667e7
+DIST boto3-1.35.79.gh.tar.gz 911885 BLAKE2B 5b90aad921a6bd46a9bd2c1d08f12d68869ac1b8b0a7b8888b7f15ce58d25d42a9f7814b70e6453a1e84d578db1ef4f3b08940c555d11288a6b0e20128881035 SHA512 ebdb3627cd78e844635a5c0a043793aef4e2f06a3f1f220dfbb1796db9391eb84ec1248ec701075ae2660a18eb5895b26d0f0ec5fb8c4ad18f29d0feae6fd756
diff --git a/dev-python/boto3/boto3-1.35.79.ebuild b/dev-python/boto3/boto3-1.35.79.ebuild
new file mode 100644
index 000000000000..d91ce27598cf
--- /dev/null
+++ b/dev-python/boto3/boto3-1.35.79.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index c610291de8b3..ea9370b9448c 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,3 +3,4 @@ DIST botocore-1.35.71.gh.tar.gz 13908196 BLAKE2B beba990a19a2a6de3a10d9acd9f97c7
 DIST botocore-1.35.76.gh.tar.gz 14117270 BLAKE2B b072b926daae520e54871676d5afc4832ddbc8c91a2ee15f103a9d48df2e17d8cef304fab28c4050bfe6d70629979c48d8bc00d5caf42a0129a19ff5a3a2baa3 SHA512 e7433d60519a0da5118b3283c192a7199e8bfdd605fc6bb98d05cc90485a1e4aec537a035ffc08bcb6c35e9d31394422596e113a98cc00c23bd3dd350577ac1d
 DIST botocore-1.35.77.gh.tar.gz 14120607 BLAKE2B bc5f22133796be3b2749f848d62c9eeff6f58a515393beda2f41df9c734eb7167a97987d06e025ebc2693eea6214dd0f7788f9f4cf1e5ac71a91b05b6e886d7e SHA512 fa699fbffc2e7f1e9062fe1393f1cef4677cb30b5090df55bb84b4719e880a6731731ab2799450ab06f70f9a057e749529c283ebe6400b7b35e7b89a2c22eb2a
 DIST botocore-1.35.78.gh.tar.gz 14124766 BLAKE2B 53bb6a8cf63bb69c5e827e269f6efc35b56919c878eadf10f7a7017848703f8de682a7d1912965f40bbb0c0c2903a6d22a4479c8f66ec03c57410f6e3b27dc70 SHA512 74816012870b25a7344096e714c2c9319cd9ac676a3d5e194d68dcc6eaa048233630c30d33ba6ac02f2c953148f704ca068f4aead562504eba893b468408aac0
+DIST botocore-1.35.79.gh.tar.gz 14134346 BLAKE2B e3fdc5510c0ed8a693e9f34568c6918a6907c74d95e4b309725b3ba825c83a7c9f924cac0a8e7ab0cfae5ed038b9f999a1e9b9a3ade3637f630e6ac63b68ae43 SHA512 00d6c614fa65ac86cce5ece0a939a5656922e09f30a9bd19e503c5c9442c299d1b2f2d37ef4b062193e22b123636ee4568f8b903994514c53b7c35ad6f2a7047
diff --git a/dev-python/botocore/botocore-1.35.79.ebuild b/dev-python/botocore/botocore-1.35.79.ebuild
new file mode 100644
index 000000000000..7816e9efeb52
--- /dev/null
+++ b/dev-python/botocore/botocore-1.35.79.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/cli-ui/Manifest b/dev-python/cli-ui/Manifest
index 00fdc0b2f69f..15b36ec92bbf 100644
--- a/dev-python/cli-ui/Manifest
+++ b/dev-python/cli-ui/Manifest
@@ -1 +1,2 @@
 DIST cli-ui-0.17.2.tar.gz 13366 BLAKE2B b5dbccf136dad09bf213e199050c31cce545a44dd46b61f8eaad8b40679203da5b742a1deefc0f934bbbab286c101892d5b5e93c45624631f778245c4724ddcb SHA512 ea38c3c39b24f322b58f8e95e43609a22657018d36fd28d5dfa7887295eb4ad374032fdd2330762ed50826211ed11fa6a6356d93d09b2135264cf59f13749993
+DIST cli_ui-0.18.0.tar.gz 13012 BLAKE2B c96eba706b5d7275c9ad76d1a099ff7bcda8ae894361ba8d0ac944531fe813d17156bb27cb6d342268fb28845aeedcef1d19c36f1ddda43d3b98cf46c30d9818 SHA512 69c68df27d74d167dc50088381a048265fc51603e7e13811895ac771df1cc03f9670274e73a162a67706afc9e2a4eb1ccd75872309a3c2c06f84c2ccaa03dd92
diff --git a/dev-python/cli-ui/cli-ui-0.18.0.ebuild b/dev-python/cli-ui/cli-ui-0.18.0.ebuild
new file mode 100644
index 000000000000..4afac92ca2e9
--- /dev/null
+++ b/dev-python/cli-ui/cli-ui-0.18.0.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="poetry"
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for better command line interfaces"
+HOMEPAGE="
+	https://your-tools.github.io/python-cli-ui/
+	https://github.com/your-tools/python-cli-ui/
+	https://pypi.org/project/cli-ui/
+"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/your-tools/python-cli-ui.git"
+else
+	inherit pypi
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/colorama-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/tabulate-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/unidecode-1.3.6[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/cysignals/cysignals-1.12.0.ebuild b/dev-python/cysignals/cysignals-1.12.0.ebuild
index 6da5f0ef2bd9..8a125f4d7118 100644
--- a/dev-python/cysignals/cysignals-1.12.0.ebuild
+++ b/dev-python/cysignals/cysignals-1.12.0.ebuild
@@ -20,12 +20,6 @@ LICENSE="LGPL-3+"
 SLOT="0"
 KEYWORDS="~amd64 ~riscv"
 
-DEPEND="
-	sci-mathematics/pari:=
-"
-RDEPEND="
-	${DEPEND}
-"
 BDEPEND="
 	>=dev-python/cython-3.0.0[${PYTHON_USEDEP}]
 "
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index 54f798a6edcf..81bf8843cbc7 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1 +1,2 @@
 DIST google_api_python_client-2.154.0.tar.gz 12070143 BLAKE2B 91b2838116246e04fc93a155fb27792a2efa6e258eeddf29989c62229db7975b389435efeb6342d069358797539c57ea630c7bf7da64a0cdef7ceb4801586a85 SHA512 9728f4cda59919ddec28876f27b6e7716d96c9ba08088f064aa1ac0e0a4ccd1d7ad66e592ac8e2429f04520b64d8228fd3d358f7ae7d157048c9719fcb7b8cd3
+DIST google_api_python_client-2.155.0.tar.gz 12195015 BLAKE2B f9c82244881b131dd022b7fd817c9fae28d4be6c6a1410e5e674d050e66b1361182515b6a220eef988ab4fdfa62e4cbf13de58e699672b3382a5449380c422e9 SHA512 1b2101d93178aa0507dcb2d8fb70c0ec29d547b87a7572508f56c87f8877b6c795f494c7f7f020df72d9e2b96083d135dfddd0ad80bb9d317189598fca9192f8
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.155.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.155.0.ebuild
new file mode 100644
index 000000000000..595a1e3cbd88
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.155.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="
+	https://github.com/googleapis/google-api-python-client/
+	https://pypi.org/project/google-api-python-client/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	>=dev-python/google-api-core-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+		tests/test_discovery.py::Universe::test_client_options_universe_configured_with_mtls
+		tests/test_discovery.py::Universe::test_universe_env_var_configured_with_mtls
+	)
+
+	epytest tests
+}
diff --git a/dev-python/google-auth/Manifest b/dev-python/google-auth/Manifest
index 6f3f7b791351..738835dc4a7d 100644
--- a/dev-python/google-auth/Manifest
+++ b/dev-python/google-auth/Manifest
@@ -1,2 +1,3 @@
 DIST google_auth-2.35.0.tar.gz 267223 BLAKE2B d30c8ca15f0e8183c1d50c285d578d8373bf722dddbeb2d5e423b2e25b26f038d406a6dccacf2cebbb0741a2ef07e8b0c86d0362734db3a56054ff76b6d213d7 SHA512 5c359bb94f213812c57cc2c2942d1da3aa08f0e73dde6f5b6c2f563fb51056009f3b821ec0fc39571221da267011d850c242a5ab044d88648be44759f7337973
 DIST google_auth-2.36.0.tar.gz 268336 BLAKE2B cb9df17eb367ef9be27abacb29b481490e4a471311befa2c269031b888f0a7a804b4c41a30f8914f05f3ee60e9b9664e3c694a24509418c64374d23c40cc3666 SHA512 9e61d5ab21e8973f6d9d2af8d4b73e5637efe9b09b1854bf82743e4a03a6b5fc6154a492e4b7ad5935ba3796186d6ed11e891bd0a0eb1190e06fedc824904c22
+DIST google_auth-2.37.0.tar.gz 268878 BLAKE2B da39fd1909ce93a212a71624e925df2dee753765718c5a7bb4a5ca5115dfc15c0790eeaf77d52ead7bff795f2bf9d2cfa12a6cd8cdd964d63f0dbf7d47e27b82 SHA512 08f194c99077a230845857e98ac8c4eab3ca086a288be9ce1031c9d3f6a5b40cb4fe3305be6b822b27561e4e7b0c0a144e9888be5a95ebe06de42d74fc911756
diff --git a/dev-python/google-auth/google-auth-2.37.0.ebuild b/dev-python/google-auth/google-auth-2.37.0.ebuild
new file mode 100644
index 000000000000..ca9eec15114c
--- /dev/null
+++ b/dev-python/google-auth/google-auth-2.37.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://github.com/googleapis/google-auth-library-python/
+	https://pypi.org/project/google-auth/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	<dev-python/cachetools-6.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/cryptography-38.0.3[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		>=dev-python/pyjwt-2.0[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pyu2f[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# tests are broken with up-to-date pyopenssl
+		tests/transport/test__mtls_helper.py::TestDecryptPrivateKey::test_success
+	)
+	local EPYTEST_IGNORE=(
+		# these are compatibility tests with oauth2client
+		# disable them to unblock removal of that package
+		tests/test__oauth2client.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p asyncio
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/imap-tools/Manifest b/dev-python/imap-tools/Manifest
index 44db26c88814..27c5a2c161b1 100644
--- a/dev-python/imap-tools/Manifest
+++ b/dev-python/imap-tools/Manifest
@@ -1,5 +1,5 @@
-DIST imap-tools-1.6.0.gh.tar.gz 252727 BLAKE2B 2d075c2ca41adfcef4253b3085086bd99c08e5cfe7cc9c9b1327adebcd9fd875804da09b57320ed53723a8911f67c6deee58bc11c33a06e034f53bef6580bb05 SHA512 2bcb44232c0f2416e7372ba7336a7029ff2dfc84ad2354149c446df2ec50970be0c315b8612e9ebbd5f49fa9544ce9e9d662f80d2daefd4e15d013e37eb9c061
 DIST imap-tools-1.7.4.gh.tar.gz 253760 BLAKE2B 07e956a753b39ec213be9a4d9b92896436b77b599a0bb075b816fb67e71ce8d937dc5773bd9daf6a8e722dbcf9e1c841e295039a5f1dfc96b7f9ee25e84b7f50 SHA512 394115020b7249334f7c6a95b8b03f9c2174a4c55006de9a5debc028329655903b50ed353c964d17231d73a30368b957578e0cb751a65142d54f89f3ec979ad5
-EBUILD imap-tools-1.6.0.ebuild 730 BLAKE2B ffa7d1b6169e7bc2b45ae95411db811c3dbf5600e67c82c7d2e99b44aff29289358997ad0b7e49f680463380ad0750c93268d258eb3eccd860270aec20261e77 SHA512 1bf7fe3054092530f4331e70daf304dbff73ee7bbb6738d39c37241234e65a2a5d6d24eceb87730e70321fd93fda9c3196153565c9a08e69f15549372fc223dd
+DIST imap-tools-1.8.0.gh.tar.gz 253891 BLAKE2B 6b3edb1140a6c00f65e99af8e437317c5262e45f2753377202551d96f5568745af3e6bab868bc86134353db3582bc4431c6e2d8d40c964745d5fdb5211b19518 SHA512 00a6a4101c041aa0f9f20bd91265e4253c213db25d32ffc90f64a2ea0d578dc3ff06c4b312fa1a713818824775111da92482e531ba2c5cba73bc317a5b334b61
 EBUILD imap-tools-1.7.4.ebuild 730 BLAKE2B ffa7d1b6169e7bc2b45ae95411db811c3dbf5600e67c82c7d2e99b44aff29289358997ad0b7e49f680463380ad0750c93268d258eb3eccd860270aec20261e77 SHA512 1bf7fe3054092530f4331e70daf304dbff73ee7bbb6738d39c37241234e65a2a5d6d24eceb87730e70321fd93fda9c3196153565c9a08e69f15549372fc223dd
+EBUILD imap-tools-1.8.0.ebuild 730 BLAKE2B ffa7d1b6169e7bc2b45ae95411db811c3dbf5600e67c82c7d2e99b44aff29289358997ad0b7e49f680463380ad0750c93268d258eb3eccd860270aec20261e77 SHA512 1bf7fe3054092530f4331e70daf304dbff73ee7bbb6738d39c37241234e65a2a5d6d24eceb87730e70321fd93fda9c3196153565c9a08e69f15549372fc223dd
 MISC metadata.xml 447 BLAKE2B 59e17459538187a7c9da7fbe7283f25c5131bf3188563709971176266ee42c8e27cdbf744cab7fe77c9b81b618c1246feb6450e969fb2bbe8ec996958315d158 SHA512 2d90e11910d114c0a84231c76b0103e3f4f7187294c68eb1542d396b0122baf3b066813fa95fd9386a6fbaeb778e43e8cc095747aeb7012d26d355c99e2e06ad
diff --git a/dev-python/imap-tools/imap-tools-1.6.0.ebuild b/dev-python/imap-tools/imap-tools-1.8.0.ebuild
index f4552744337d..f4552744337d 100644
--- a/dev-python/imap-tools/imap-tools-1.6.0.ebuild
+++ b/dev-python/imap-tools/imap-tools-1.8.0.ebuild
diff --git a/dev-python/markdown2/Manifest b/dev-python/markdown2/Manifest
index a42569d7660b..948bb0dbaede 100644
--- a/dev-python/markdown2/Manifest
+++ b/dev-python/markdown2/Manifest
@@ -1 +1,2 @@
 DIST markdown2-2.5.1.tar.gz 140957 BLAKE2B 204ba7b388ff4c16db603761aceb1baf4b8b2dac3e4b1e85776c0a8a99223822a41b414535691be579c78f29e146713190fe80c1cf7d1303b7c3c80d5abbb1c5 SHA512 758d2f66c157cd709edc3bd4e67839eaae37db7a2c126451c840e32b150792cd11c1cd25ff8c4d46bff2bed290af8a3c7c87361e2d62009b16a00eb8f549af98
+DIST markdown2-2.5.2.tar.gz 141583 BLAKE2B ec817df668eafcf53da9e56ebcf89391156d4bf603c1bf2e915707cce56eebee90769df83b6fd7b8f77bfbcab9efb26136e7300da4818caf335f316554f5c19f SHA512 776e8ec20a5d9489c59d4ebe5193f3544342fe1c630a3605708b674db3aa3f9ab6ecfa2a918785c29efe3fe97cf83303bb2dd810b447f4b8d46ee81b2a12766f
diff --git a/dev-python/markdown2/markdown2-2.5.2.ebuild b/dev-python/markdown2/markdown2-2.5.2.ebuild
new file mode 100644
index 000000000000..590afae8661a
--- /dev/null
+++ b/dev-python/markdown2/markdown2-2.5.2.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python Markdown language reimplementation"
+HOMEPAGE="
+	https://github.com/trentm/python-markdown2/
+	https://pypi.org/project/markdown2/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/pygments-2.7.3[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests unittest
+
+python_test() {
+	cd test || die
+	"${EPYTHON}" -m unittest test_markdown2.py -v ||
+		die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/oct2py/Manifest b/dev-python/oct2py/Manifest
index 9a3c7ea985a0..60f9e2a4810f 100644
--- a/dev-python/oct2py/Manifest
+++ b/dev-python/oct2py/Manifest
@@ -1,2 +1,2 @@
-DIST oct2py-5.7.1.tar.gz 441250 BLAKE2B b0eca421b297ca5495508cfcb75e8c3bd0f53f12ab3c367bfedfd2f0064c7d9874c6cbefa0d9fc7bea3c21865993136707dab3deb8cd442090bc1c9cc5786527 SHA512 e8018b88119a5275061e315ecd37d07284ba674d64d778215378f0f6b60d4a33e503f0d26e1d23fb054974673ade9eeae5b292498f158e0a6d476c0998da5e6e
 DIST oct2py-5.7.2.tar.gz 441373 BLAKE2B afa7a98f6d38120e8028438d243fb2baefaf3cacc00b576f32fbf666f193dad95e8468847859e8405b7796ec2132b99e347f9ea466400307d1d23ce46f9489fc SHA512 f01263d210eab9adb3f69025a2a22efebd0b1a4dff040620fd382752159992d9907451ec7a72c75f211a9a8e18a1d1c53ff5d3512d8bd807afc737b50fcae178
+DIST oct2py-5.8.0.tar.gz 442805 BLAKE2B adff195db13288fae467f1c24834dbedd369170184626ac90fd6d64960a63dd11efe4d0bf77ecbe5fad08d11c8280c0b92e5aec3868b750f44f4d3fa8f9c0b3f SHA512 4e69d0df3a8664f0601d31fbfbb6ef65ac16066668c32ca7506023e02a7416bb81da8f18a9e49f2cdd8a0d46b1c55b9c96d9c71f5482c63c8409465188174daa
diff --git a/dev-python/oct2py/oct2py-5.7.1.ebuild b/dev-python/oct2py/oct2py-5.8.0.ebuild
index 249f80e3d993..249f80e3d993 100644
--- a/dev-python/oct2py/oct2py-5.7.1.ebuild
+++ b/dev-python/oct2py/oct2py-5.8.0.ebuild
diff --git a/dev-python/opentelemetry-api/Manifest b/dev-python/opentelemetry-api/Manifest
index 145836412bcb..a6e357ee17a4 100644
--- a/dev-python/opentelemetry-api/Manifest
+++ b/dev-python/opentelemetry-api/Manifest
@@ -1 +1,2 @@
 DIST opentelemetry-python-1.28.2.gh.tar.gz 639603 BLAKE2B 6c185c91cd3f31c58f8f1f73edfbe1b5b242bf8ac855e573a40b6f3ea73dc558b40d89785a9e24d61c2b4950a008c5bc51f319013f955877d14028f9b88101b7 SHA512 49f97ffb1bec390eaa9181bfc16eb0c5b1f7b50602a5edbcf4851fb7077685eff3f261738143be59184e6a01c283fac4f766602eebd9b6daea74005cf3e0c4d9
+DIST opentelemetry-python-1.29.0.gh.tar.gz 1178849 BLAKE2B f26914c14025e77486df0c587318f96c4b27bd2caeacc877091300fc054f4670a642ca6fcafa909b986a97168ab004d4a969a05571ee38ab7797b3b38f4cc91f SHA512 92c90e6a684d8cfab3bba4d72612ccf53ae54cdd9784e3434b25adc3730fe114f21fd7aa21da80edf6e0e7c80b39c64ee31fb16f68b04809289bbf5d49d4ca2e
diff --git a/dev-python/opentelemetry-api/opentelemetry-api-1.29.0.ebuild b/dev-python/opentelemetry-api/opentelemetry-api-1.29.0.ebuild
new file mode 100644
index 000000000000..6764b9297c21
--- /dev/null
+++ b/dev-python/opentelemetry-api/opentelemetry-api-1.29.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Python API"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-api/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/deprecated-1.2.6[${PYTHON_USEDEP}]
+	dev-python/importlib-metadata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Unnecessary restriction
+	sed -i -e '/importlib-metadata/s:, <= [0-9.]*::' pyproject.toml || die
+}
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-semantic-conventions opentelemetry-sdk \
+		tests/opentelemetry-test-utils
+	do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/opentelemetry-sdk/Manifest b/dev-python/opentelemetry-sdk/Manifest
index 145836412bcb..a6e357ee17a4 100644
--- a/dev-python/opentelemetry-sdk/Manifest
+++ b/dev-python/opentelemetry-sdk/Manifest
@@ -1 +1,2 @@
 DIST opentelemetry-python-1.28.2.gh.tar.gz 639603 BLAKE2B 6c185c91cd3f31c58f8f1f73edfbe1b5b242bf8ac855e573a40b6f3ea73dc558b40d89785a9e24d61c2b4950a008c5bc51f319013f955877d14028f9b88101b7 SHA512 49f97ffb1bec390eaa9181bfc16eb0c5b1f7b50602a5edbcf4851fb7077685eff3f261738143be59184e6a01c283fac4f766602eebd9b6daea74005cf3e0c4d9
+DIST opentelemetry-python-1.29.0.gh.tar.gz 1178849 BLAKE2B f26914c14025e77486df0c587318f96c4b27bd2caeacc877091300fc054f4670a642ca6fcafa909b986a97168ab004d4a969a05571ee38ab7797b3b38f4cc91f SHA512 92c90e6a684d8cfab3bba4d72612ccf53ae54cdd9784e3434b25adc3730fe114f21fd7aa21da80edf6e0e7c80b39c64ee31fb16f68b04809289bbf5d49d4ca2e
diff --git a/dev-python/opentelemetry-sdk/opentelemetry-sdk-1.29.0.ebuild b/dev-python/opentelemetry-sdk/opentelemetry-sdk-1.29.0.ebuild
new file mode 100644
index 000000000000..499009fb6d59
--- /dev/null
+++ b/dev-python/opentelemetry-sdk/opentelemetry-sdk-1.29.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Python SDK"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-sdk/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	~dev-python/opentelemetry-api-${PV}[${PYTHON_USEDEP}]
+	~dev-python/opentelemetry-semantic-conventions-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-3.7.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+	)
+"
+
+# Tests cannot handle xdist with high makeopts
+# https://bugs.gentoo.org/928132
+distutils_enable_tests pytest
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in tests/opentelemetry-test-utils; do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local EPYTEST_DESELECT=(
+		# TODO
+		"${PN}"/tests/resources/test_resources.py::TestOTELResourceDetector::test_process_detector
+		"${PN}"/tests/metrics/integration_test/test_console_exporter.py::TestConsoleExporter::test_console_exporter_with_exemplars
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests
+}
diff --git a/dev-python/opentelemetry-semantic-conventions/Manifest b/dev-python/opentelemetry-semantic-conventions/Manifest
index 145836412bcb..a6e357ee17a4 100644
--- a/dev-python/opentelemetry-semantic-conventions/Manifest
+++ b/dev-python/opentelemetry-semantic-conventions/Manifest
@@ -1 +1,2 @@
 DIST opentelemetry-python-1.28.2.gh.tar.gz 639603 BLAKE2B 6c185c91cd3f31c58f8f1f73edfbe1b5b242bf8ac855e573a40b6f3ea73dc558b40d89785a9e24d61c2b4950a008c5bc51f319013f955877d14028f9b88101b7 SHA512 49f97ffb1bec390eaa9181bfc16eb0c5b1f7b50602a5edbcf4851fb7077685eff3f261738143be59184e6a01c283fac4f766602eebd9b6daea74005cf3e0c4d9
+DIST opentelemetry-python-1.29.0.gh.tar.gz 1178849 BLAKE2B f26914c14025e77486df0c587318f96c4b27bd2caeacc877091300fc054f4670a642ca6fcafa909b986a97168ab004d4a969a05571ee38ab7797b3b38f4cc91f SHA512 92c90e6a684d8cfab3bba4d72612ccf53ae54cdd9784e3434b25adc3730fe114f21fd7aa21da80edf6e0e7c80b39c64ee31fb16f68b04809289bbf5d49d4ca2e
diff --git a/dev-python/opentelemetry-semantic-conventions/opentelemetry-semantic-conventions-1.29.0.ebuild b/dev-python/opentelemetry-semantic-conventions/opentelemetry-semantic-conventions-1.29.0.ebuild
new file mode 100644
index 000000000000..1da141e261fd
--- /dev/null
+++ b/dev-python/opentelemetry-semantic-conventions/opentelemetry-semantic-conventions-1.29.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Semantic Conventions"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-sdk/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/deprecated-1.2.6[${PYTHON_USEDEP}]
+	~dev-python/opentelemetry-api-${PV}[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in opentelemetry-sdk tests/opentelemetry-test-utils; do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/pyaml/Manifest b/dev-python/pyaml/Manifest
index ef3ba9bcab71..569afe76e157 100644
--- a/dev-python/pyaml/Manifest
+++ b/dev-python/pyaml/Manifest
@@ -1 +1,2 @@
+DIST pyaml-24.12.1.tar.gz 29288 BLAKE2B 392579d0afbf1b71e0cc38d875c0f8492e9f33b33bdd619f1a9b3d9f042d1cc62ba19a495bab14331c53e745691e802a80b772ff0293dabb8da00da75a3a53ce SHA512 46125a594609cbcfc91f5005d5f551ab8b20ff4615bf8df586f68b1afcda090c1649d973f8e281c1aacd139c27359d44625b8e5aa2f9792a49bde9b2942993b5
 DIST pyaml-24.9.0.tar.gz 28111 BLAKE2B ff3dcf2ece6e3b03b8f9837e7ea7db04cd1bcffd94e0101c73e5cc38b5c140e65f45c9936b5353fe73950d8b88ee0265c8be290a795ac6e844e64fb853faae18 SHA512 a10026d2e69c5bbfabbe5ed02814fecb8838c969761eec0137a93465478abc518ba83cfae4b9df643040aa5fe46a62fc9def1fd763830ae8d2cfdce3b3061365
diff --git a/dev-python/pyaml/pyaml-24.12.1.ebuild b/dev-python/pyaml/pyaml-24.12.1.ebuild
new file mode 100644
index 000000000000..88bd2947fea6
--- /dev/null
+++ b/dev-python/pyaml/pyaml-24.12.1.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="PyYAML-based module to produce pretty and readable YAML-serialized data"
+HOMEPAGE="
+	https://github.com/mk-fg/pretty-yaml/
+	https://pypi.org/project/pyaml/
+"
+
+LICENSE="WTFPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/unidecode[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/tekore/Manifest b/dev-python/tekore/Manifest
index 315f197e2065..26f750358e5a 100644
--- a/dev-python/tekore/Manifest
+++ b/dev-python/tekore/Manifest
@@ -1,2 +1,2 @@
-DIST tekore-5.5.0.tar.gz 270803 BLAKE2B 37b7410e701b67917af76bac07499a9a910916eed8e9dd87e394e420309ed9a3094a6cf600182db084523eeb6942c6a9ebfdda108f8b1f5ef848be4a02a32f6a SHA512 b78eea1fafd27bbeb230f9b697783e3b8cd1aebc93633f168dba07d94bee80ddefedf792ea7870b258757559256424db74d21f3e14201e8c3df801fac4d12067
 DIST tekore-5.5.1.tar.gz 270328 BLAKE2B 44a03289ff908b97da7ef089513156b00b8858d99172139981ce6b618074a628796f3f965a1180f7ee0cb2c23e5c97fd0f7ce1ea9da3d6352102e2da3406b1cf SHA512 aec3eddadfd27098a4608a193750bb521d1e4c5c786c09b98e4295ed167dc3ac88b9382528778513a8b2143153950a02b7cbbdbbae1775259ab29c3df17abe05
+DIST tekore-6.0.0.tar.gz 271904 BLAKE2B f5b0b8b296506c2d91e4cb763c535485a5c0ecb872e0d9e4920a74e58b97ecb8304d9daf24ebb08a47512fa922c9962e37a1b744affaba3bf846805a07d227db SHA512 204599394d6b7fdfd0c43f6e8ab692de2105fafddd00694194be036c12f705203d46b11be672c8b258c1cb2e7605c31f3e7721d5f8dd52b75dd83c9741615972
diff --git a/dev-python/tekore/tekore-5.5.0.ebuild b/dev-python/tekore/tekore-6.0.0.ebuild
index b9d4ffec416f..b9d4ffec416f 100644
--- a/dev-python/tekore/tekore-5.5.0.ebuild
+++ b/dev-python/tekore/tekore-6.0.0.ebuild
diff --git a/dev-python/uv/Manifest b/dev-python/uv/Manifest
index ac4197f2b6e8..c5ea64495c4f 100644
--- a/dev-python/uv/Manifest
+++ b/dev-python/uv/Manifest
@@ -5,3 +5,5 @@ DIST uv-0.5.6-crates.tar.xz 46263172 BLAKE2B 73b1d2dc957f89f923dda09a8c038426041
 DIST uv-0.5.6.gh.tar.gz 2952255 BLAKE2B b815b60b99f959751f5839365b8b210919247ad99bff93ee4d202bc152bd06b83a62914cfbf341bfddb5b2c87d9e546c5e2a6d1baff1599d0218160ee89de504 SHA512 fc8c7f4f60a3d2ce997341450daf20ad039ef379ac5dd4575f8db0327284bd8278419b66f8f9695f2701a9579ab004b5b60476bd8dc4c27314211f795118bc5a
 DIST uv-0.5.7-crates.tar.xz 46271856 BLAKE2B 5ffadeaaed6797be56f0bb74a696e1fe4d7df2bd7baf1db51380a1da6db7a462d7189fb16c07732dcf80066715f890dc55cb64ae2bf8b18b5b1a149858a8e84e SHA512 99be269ec5e9557ffcdf01feda9b697f65c43b81421dba395ab3b2203d37393a92bf9bb768608c3d91e350d415682e2828a754be8f7c15031eca5544f5b33a98
 DIST uv-0.5.7.gh.tar.gz 2973450 BLAKE2B 7da87d81a53517c075963e5af538ac7f1c5ad8a47931d75c1d6ec8377d533910a2a8953a164f131f269a0d39859fab101f1f9300f22e3af00374d78395bf16b0 SHA512 1bfcfd4406df25b8fd14dba65d7fd16a6b7294e848a9fc5c206f7517cabbf480fac36378d6c03be8b06c978a5118acabf7feed432110a53d305ecc3476b39781
+DIST uv-0.5.8-crates.tar.xz 46445240 BLAKE2B 119e471d7f9a851179e2e5d9cd15cb94476355e27db36b05378036b7f9a3e0021a33a2fd29ed9e5a67cd7d962783b3ea96145ca9092da0a6a114899ff2b712fd SHA512 d517fdc9e48b4cb4acacf1d3c986c7e348ee65c89cb5bdbd9c3947f66d450f7f59b5a4f5f0f45560d5241bc8f7756039014cf350a8aea22be876c197759e5aff
+DIST uv-0.5.8.gh.tar.gz 3104599 BLAKE2B 40e80eec119c6403f1f2c9f9a0373eedf6cbd510165c385dd9c9647968183cb129b3849755913dcacbca0f85efea7e6d2f1c367a87e0d60ad3ce329cfb48a236 SHA512 eec291c3b0135a4063b6259033387e543dd2e422d169bd4bccbd86d899a3f05add4f6348249f4c6fc3c026b612bb92e5d9dd941f2f37613453a6730ff8f5844e
diff --git a/dev-python/uv/uv-0.5.8.ebuild b/dev-python/uv/uv-0.5.8.ebuild
new file mode 100644
index 000000000000..c67a480aec6d
--- /dev/null
+++ b/dev-python/uv/uv-0.5.8.ebuild
@@ -0,0 +1,170 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+
+declare -A GIT_CRATES=(
+	[async_zip]='https://github.com/charliermarsh/rs-async-zip;c909fda63fcafe4af496a07bfda28a5aae97e58d;rs-async-zip-%commit%'
+	[pubgrub]='https://github.com/astral-sh/pubgrub;57832d0588fbb7aab824813481104761dc1c7740;pubgrub-%commit%'
+	[tl]='https://github.com/astral-sh/tl;6e25b2ee2513d75385101a8ff9f591ef51f314ec;tl-%commit%'
+	[version-ranges]='https://github.com/astral-sh/pubgrub;57832d0588fbb7aab824813481104761dc1c7740;pubgrub-%commit%/version-ranges'
+)
+
+RUST_MIN_VER="1.80.1"
+
+inherit cargo check-reqs
+
+CRATE_PV=${PV}
+DESCRIPTION="A Python package installer and resolver, written in Rust"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv/
+"
+# pypi sdist misses scripts/, needed for tests
+SRC_URI="
+	https://github.com/astral-sh/uv/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://dev.gentoo.org/~mgorny/dist/uv-${CRATE_PV}-crates.tar.xz
+	"
+fi
+
+# most of the code
+LICENSE="|| ( Apache-2.0 MIT )"
+# crates/pep508-rs is || ( Apache-2.0 BSD-2 ) which is covered below
+# Dependent crate licenses
+LICENSE+="
+	0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD ISC MIT
+	MPL-2.0 Unicode-3.0 Unicode-DFS-2016 ZLIB
+"
+# ring crate
+LICENSE+=" openssl"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils:=
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		dev-lang/python:3.8
+		dev-lang/python:3.9
+		dev-lang/python:3.10
+		dev-lang/python:3.11
+		dev-lang/python:3.12
+		!!~dev-python/uv-0.5.0
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/.*"
+
+check_space() {
+	local CHECKREQS_DISK_BUILD=3G
+	use debug && CHECKREQS_DISK_BUILD=9G
+	check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+	check_space
+}
+
+pkg_setup() {
+	check_space
+	rust_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# enable system libraries where supported
+	export ZSTD_SYS_USE_PKG_CONFIG=1
+	# TODO: unbundle libz-ng-sys, tikv-jemalloc-sys?
+
+	# remove unbundled sources, just in case
+	find "${ECARGO_VENDOR}"/{bzip2,lzma,zstd}-sys-*/ -name '*.c' -delete || die
+
+	# bzip2-sys requires a pkg-config file
+	# https://github.com/alexcrichton/bzip2-rs/issues/104
+	mkdir "${T}/pkg-config" || die
+	export PKG_CONFIG_PATH=${T}/pkg-config${PKG_CONFIG_PATH+:${PKG_CONFIG_PATH}}
+	cat >> "${T}/pkg-config/bzip2.pc" <<-EOF || die
+		Name: bzip2
+		Version: 9999
+		Description:
+		Libs: -lbz2
+	EOF
+}
+
+src_configure() {
+	local myfeatures=(
+		git
+		pypi
+		python
+	)
+
+	cargo_src_configure --no-default-features
+}
+
+src_compile() {
+	cd crates/uv || die
+	cargo_src_compile
+}
+
+src_test() {
+	# work around https://github.com/astral-sh/uv/issues/4376
+	local -x PATH=${BROOT}/usr/lib/python-exec/python3.12:${PATH}
+	local -x COLUMNS=100
+	local -x PYTHONDONTWRITEBYTECODE=
+	# fix tests failing because of our config
+	local -x XDG_CONFIG_DIRS=${T}
+
+	cd crates/uv || die
+	cargo_src_test --no-fail-fast
+}
+
+src_install() {
+	cd crates/uv || die
+	cargo_src_install
+
+	insinto /etc/xdg/uv
+	newins - uv.toml <<-EOF || die
+		# These defaults match Fedora, see:
+		# https://src.fedoraproject.org/rpms/uv/pull-request/18
+
+		# By default ("automatic"), uv downloads missing Python versions
+		# automatically and keeps them in the user's home directory.
+		# Disable that to make downloading opt-in, and especially
+		# to avoid unnecessarily fetching custom Python when the distro
+		# package would be preferable.  Python builds can still be
+		# downloaded manually via "uv python install".
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-downloads
+		python-downloads = "manual"
+
+		# By default ("managed"), uv always prefers self-installed
+		# Python versions over the system Python, independently
+		# of versions.  Since we generally expect users to use that
+		# to install old Python versions not in ::gentoo anymore,
+		# this effectively means that uv would end up preferring very
+		# old Python versions over the newer ones that are provided
+		# by the system.  Default to using the system versions to avoid
+		# this counter-intuitive behavior.
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-preference
+		python-preference = "system"
+	EOF
+}