Adding metadata

21 files changed, 399 insertions, 1 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 2f9628802d8c..e997e625e2df 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -3,4 +3,5 @@ DIST boto3-1.17.105.tar.gz 387920 BLAKE2B 475342a93440418f6fc5682e7c24f386aaac8d
 DIST boto3-1.17.106.tar.gz 388602 BLAKE2B f9cc023ce4c0810ea7eb004126941229536fc068ff51039dc9f9943d153f8fa717e832c7161f85332e3edf596f55b3ad7dfb9ef117b471f59fc269ee9c63818c SHA512 866286d91d157d513f35231f8d512cd9738c7795b044b41c8e2b1594ed83a6060bcb3a2e3c8388df2ed86c7b04e0ce2d42c88393d8a6753d04c2a007865033e4
 DIST boto3-1.17.107.tar.gz 389348 BLAKE2B 8c0893d8ad73563f63254877621440ba24dac76c577f5684bc37b5f99b9111be209f69efa324cc079209340051230a43b66004d09ccd5804d631b0c04083c384 SHA512 450222507aa3bae8062b788ac7f637dbe8a5e7a5baa0f45001a74a810c2579927a7400cef180b57a7d7e57c391d665930b577b39272681ca380b5e553385b1f8
 DIST boto3-1.17.108.tar.gz 389871 BLAKE2B 964ff0b2d7a437c569e2b19f5c24d228df6595f15d72350b2cae0cb43c5e1f4d8376c0a25ec393a0a0f085650b193afc852fef59d258dd1c3addbfff4c27ce62 SHA512 4b78af4e59f399aa022762b6d1dc14252d4f549cdbb9264e5762a927b3a7e391d336ca48d938b1245ceaaa243ec01ea642545bc97abe5f7a3f8f8774ee21e2ce
+DIST boto3-1.17.109.tar.gz 390366 BLAKE2B f39548e623fc65907b13d7d5ba8a16034e5f741a3343ef69e52984a2417b4fcf8c21cdd49854222781a41aef0e26a7ffeb38c7a2dc600321ef6e7574f43e785e SHA512 4e13a99db4be8d61b217afc9bf4626ae5e6be524684581d74b7d7ce180c8d74716a0ef196ab6b91a7ef6fa56a57887e6ab0d05da380ebf8ae5bb915ac1a844b2
 DIST boto3-1.17.97.tar.gz 383223 BLAKE2B 1a1b4e9f2c51d830762f27cf3e30038efb88322e300ac304d1cb88d5b7efc6af35ad9810cea7292c9807dcdfedb11ba039ee6d5dbb9162f2a1c6d6936ef75bcc SHA512 e74a59763cc9b8a51fd09121a790d29a7291d9380d4451c2e6af90902f18415a3780eeea7f7d63e052b295792b92c3cdd3b8597f7013241ebbbdb7e418cf73ce
diff --git a/dev-python/boto3/boto3-1.17.109.ebuild b/dev-python/boto3/boto3-1.17.109.ebuild
new file mode 100644
index 000000000000..8e0f2cecffd7
--- /dev/null
+++ b/dev-python/boto3/boto3-1.17.109.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index df94b30f007c..7016ad7dfce6 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -3,4 +3,5 @@ DIST botocore-1.20.105.tar.gz 7883335 BLAKE2B b48347e304ea54b56a37faae8bcbe9c127
 DIST botocore-1.20.106.tar.gz 7885164 BLAKE2B 3fa8b860a40a0915f6a59912fdee7b9e55fa88170da747d4d87464a5b44d6cbd5ce83cec383a7a1f41ec9a203d43a8cc006c7fc0005bfcf2869d66aa9f333b14 SHA512 135d789e2d5975697840dc4aca759b2d07d70d58efed7356a3323feb54faa2b8a339a48a3ac931270e335bc730eb8cc5e87f6fc2f9e3aebc452aab331ca49261
 DIST botocore-1.20.107.tar.gz 7893209 BLAKE2B 4e4882efef667ae91bb3e42a84748609390ef637d0a72a0b8b9dbab83a55cac9117553a0ef34bd38af98493d0972fd6178b322207c71914068eb3c634debaae9 SHA512 09c7a4bc4fab922aa7dbe94fcc0da6a462dbd90bdd51e8612431e5a790b46c56eab3b436048572a4a14c6ed2417ddca8efa52474d28fbe32558550c44b3fe0dd
 DIST botocore-1.20.108.tar.gz 7897833 BLAKE2B 3b4ee27640dbfce1c9923137ef21500649454eba8e1a5b569fb0d949253e619852b61344ff86c769e2f2314a089047fe9590a685982491b21f4f7feb0a33b220 SHA512 a394fa8fc686d07ad5e1a25f0403d4adf53aa6af565696c4bd5aab58ee8f739b761f4c8058263a05b028175d1256ab87fa7fae3035cee605f236749939cc0eab
+DIST botocore-1.20.109.tar.gz 7900306 BLAKE2B 1f2009ccb236ff7b4d9d3b45b34b2295c9bbbd4bce207c51514bf3f568985eb3d5fedaf0e5309266f46ad1e42466524d148d601452474b738b53c329f0164a84 SHA512 7f266b2395f79bfa629ac147abbf646bf049ea78b208228b3817912626845fffac9c89419c75444116ae6f14067805e291faeb942e6d25061d2e6f1c382d762e
 DIST botocore-1.20.97.tar.gz 7846552 BLAKE2B da0355cc229ba8a0632f67866bf06b27d7b257184b53670e5dc183c6b5a1f4d3a34145de0a3f04abd2adc08de3f0775e3c7e0dbecae729acb5bc05c7ce9acaf2 SHA512 7411d5de8ecf0c42c0142ded036189dcf378cd16f761071beb5bc2a2c240eabb0c4a8c669ce89a5b4e798a0aae92f0e67755627c2a84df77fc2e9557265a4e3b
diff --git a/dev-python/botocore/botocore-1.20.109.ebuild b/dev-python/botocore/botocore-1.20.109.ebuild
new file mode 100644
index 000000000000..5684261bd4b3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.20.109.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/dask/Manifest b/dev-python/dask/Manifest
index f3e4e8c778e9..effbcec7e5fe 100644
--- a/dev-python/dask/Manifest
+++ b/dev-python/dask/Manifest
@@ -2,3 +2,4 @@ DIST dask-2021.5.0.tar.gz 3710206 BLAKE2B d02bd280a704cf03fb403c58567be33c414171
 DIST dask-2021.6.0.tar.gz 3717136 BLAKE2B bc524dc4e885588ea92c0b24b6abe917b6a3989f7faa21d4dffa490f2952f4f7e90ce55e28ed97b34e44bf2c41a753fe80f092559999fa42e450b289c4b89933 SHA512 a4a1e86c286e0796f7ed79dd10c5c0f80e40bb246a7c25d45aed5e73a2d6c1da8743bf6b61ca784a8412403aa6e62007c937bbbdd8ffccf7170443454ff5601d
 DIST dask-2021.6.1.tar.gz 3725331 BLAKE2B 7b466507b968dafd2c6f3a3db70c3f557ed877bd489067ff5243794c44a9e77f9b72b4a000eb0865d2096845b3c6005739214bed1215ae053d9d1c313c6bb52c SHA512 c3c032ae8d67994cb924e23787a571ad75ac88ee682542aa486dd76b38ba25c809593e9bb11a716589eeea437aaf8b69a4ecdf676c417fe566d92a2b1a8678b6
 DIST dask-2021.6.2.tar.gz 3725731 BLAKE2B 957cf70c328462c87eb52bb2fe3d471705ab6bbc233badb8d5ba93ade4b7caa05e47399f26f37b69213df16e76fdf8f042a082a0d2d96797bca836311349a6b3 SHA512 2949a0a028d08794936faaeeea3b36c97ac1492288519efa0fd1e6bbb9b5b52b730657b8b342a47ca0183d98e9179836423847670fc12c14be0890daa4b773b4
+DIST dask-2021.7.0.tar.gz 3730549 BLAKE2B 8f76648614adbef8ca1feb01f5b39d4ad217eb5178c4b7ace72d3764062b172d83b74e9fad5eeff0a745025e0cb2bf47bdb14beb03b1520130332ece00c3e318 SHA512 3dbeefe08af6536f19a03ead69372dfa7a26eff66d768fa8e238341822136a2314fca0291694ad22bdfe3618a4ed6785d836ceb5cc4231f361d97f0cbba0edbf
diff --git a/dev-python/dask/dask-2021.7.0.ebuild b/dev-python/dask/dask-2021.7.0.ebuild
new file mode 100644
index 000000000000..8eb9ac810c44
--- /dev/null
+++ b/dev-python/dask/dask-2021.7.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Task scheduling and blocked algorithms for parallel processing"
+HOMEPAGE="https://dask.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/cloudpickle-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/fsspec-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.15.1[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.25.0[${PYTHON_USEDEP}]
+	>=dev-python/partd-0.3.10[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/toolz-0.8.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/toolz[${PYTHON_USEDEP}]
+	test? (
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/numexpr[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# require old sqlalchemy
+		dask/dataframe/io/tests/test_sql.py
+	)
+
+	epytest -p no:flaky -m "not network" ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/google-api-core/Manifest b/dev-python/google-api-core/Manifest
index fc7c8a2f70ec..467a2ccf772e 100644
--- a/dev-python/google-api-core/Manifest
+++ b/dev-python/google-api-core/Manifest
@@ -1,2 +1,3 @@
 DIST google-api-core-1.28.0.tar.gz 133640 BLAKE2B 8134e39cc3ff2fbb850d5e774d08589e3e64b83ca5d5209279f5d1b7fc2eb350a523bbe2890fba6d907689149df3872a7e0a11991b1ecc62fc64a4753dce38e4 SHA512 3702d27613e621394209047451729c1308beb88c917033b4340e3fa96bf4a5ec36ad2594c98ed14439c578f69a202d95a96d30472438a30417484cff6e06fe7d
 DIST google-api-core-1.30.0.tar.gz 134595 BLAKE2B 104f52bafb68fd91904c02cbd6d3dd2e32c160a528f58e9af3612fc4f7a9934c522f79895b50982b46ee77947af7eb52557bf304b6f2624b97b5082905511829 SHA512 cc14f9c67bac99290665e2b85a97eacf43cdd2a0e4668ecbc7dd8e7131a7e4e908aca2be6d65797d0838081a02768354703762a1a80fa0b666efb81448b27899
+DIST google-api-core-1.31.0.tar.gz 134806 BLAKE2B 8609dd1260b72bc2c8fe949625c1b592e409bcd34c90f46671ef5c1573775f1957723ab6a03909b55145370e2c06250717b15452a89400ad1b6273a28c5a98a3 SHA512 af5a134ffeb65358d1b8e39bc6b0fe0b5477572dc915d941d63fcfeea72cff46c74d5d85350417484243a298462ab1322f69657694b25472d023db4b5fb27659
diff --git a/dev-python/google-api-core/google-api-core-1.31.0.ebuild b/dev-python/google-api-core/google-api-core-1.31.0.ebuild
new file mode 100644
index 000000000000..4ed31ca98e88
--- /dev/null
+++ b/dev-python/google-api-core/google-api-core-1.31.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Core Library for Google Client Libraries"
+HOMEPAGE="https://github.com/googleapis/python-api-core
+	https://googleapis.dev/python/google-api-core/latest"
+SRC_URI="https://github.com/googleapis/${PN//google/python}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P//google/python}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/googleapis-common-protos[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.25.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/rsa[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${D}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/identify/Manifest b/dev-python/identify/Manifest
index 2a8bc56c5f8a..d9c33089e0ae 100644
--- a/dev-python/identify/Manifest
+++ b/dev-python/identify/Manifest
@@ -1 +1,2 @@
 DIST identify-2.2.10.tar.gz 101073 BLAKE2B 7049424855d23727180a4af137ebd7cbf88d6ca0187901bbe43abfcb820c1db17af8ff89345612909fc869f9ee8503d84e3d1218548535abb6f499eade284def SHA512 a6f9dfc3d969a30f50922cb9ad285d76c39774706b8c0d868bcbf96564a49841e54b6021e4fced56f17cebd25fadc69dd93714d475e4f517a05677bdabada4dc
+DIST identify-2.2.11.tar.gz 101117 BLAKE2B e316bd18a91b3d073b2bb24743ffcf5e6551ce5a9ddf62b1a30aaf937311b2d07de08d9abe01040de48c607d51e4cab121d778385f8336bc911409bedcd5fce3 SHA512 083dd600bc65f61c1aa41f87943b59a4f2edcbbc7a7d07d7a1375d181761edc4b853df87d4a2b2c0f3122f4f27ed10eb784d2dd75078418b50a471b1d5a0ad0f
diff --git a/dev-python/identify/identify-2.2.11.ebuild b/dev-python/identify/identify-2.2.11.ebuild
new file mode 100644
index 000000000000..c7cb163dd983
--- /dev/null
+++ b/dev-python/identify/identify-2.2.11.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="File identification library for Python"
+HOMEPAGE="https://github.com/pre-commit/identify"
+SRC_URI="https://github.com/pre-commit/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~riscv"
+
+RDEPEND="dev-python/editdistance-s[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
diff --git a/dev-python/oslo-utils/Manifest b/dev-python/oslo-utils/Manifest
index 6619a59a2079..faf4b3fdb0cb 100644
--- a/dev-python/oslo-utils/Manifest
+++ b/dev-python/oslo-utils/Manifest
@@ -1 +1,2 @@
 DIST oslo.utils-4.6.0.tar.gz 94148 BLAKE2B 2de92b22b849522a43e81f0fa9bb5e92d2c380c07eca81cd916c536e10ec55869d5933a3a9dcc65b682ac793534094e6b0aaa74b7ac9c74724231dccc0dbae3b SHA512 fe91522c9860a7637af8b8521c297d6467f2af643f026abc97b72fd3032789219d2b3fdc9a6d8beecb0e55e4e7c319e800be295abf9639b52e32da81dae0c9a7
+DIST oslo.utils-4.9.2.tar.gz 100047 BLAKE2B 4dab375254015d312bb20a61597e24d55c228dac1970b3724e188d96ce8319f2f7b72d6d14220265dbb1543732f86af73ec2b3be2c1d2fc364a5c419fe7dd228 SHA512 17e32d63292b95f3bf44baa83d68575f7b9050a220f091d8a5e4da4347e9b543d02008558c1fdc61fea9f4d2c0b0dd8b6552b694d45fd698095530952adcbe11
diff --git a/dev-python/oslo-utils/oslo-utils-4.9.2.ebuild b/dev-python/oslo-utils/oslo-utils-4.9.2.ebuild
new file mode 100644
index 000000000000..e13b87f40584
--- /dev/null
+++ b/dev-python/oslo-utils/oslo-utils-4.9.2.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+DESCRIPTION="Oslo Utility library"
+HOMEPAGE="https://launchpad.net/oslo"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+CDEPEND=">=dev-python/pbr-2.0.0[${PYTHON_USEDEP}]
+	!~dev-python/pbr-2.1.0[${PYTHON_USEDEP}]"
+RDEPEND="
+	${CDEPEND}
+	>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2013.6[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/netifaces-0.10.4[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pyparsing-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${CDEPEND}
+	>dev-python/eventlet-0.23.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/oslotest-3.2.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
diff --git a/dev-python/pkginfo/Manifest b/dev-python/pkginfo/Manifest
index 86b740be7c3f..f077f2fd9639 100644
--- a/dev-python/pkginfo/Manifest
+++ b/dev-python/pkginfo/Manifest
@@ -1 +1,2 @@
 DIST pkginfo-1.7.0.tar.gz 37209 BLAKE2B 70e2c7d69d4b9b5544017c0b0c388e375060f063a35a3467a420d8819d77eb0e9772735db78c0ad03560aa9e35dd0485945517f305056bd52d435e2462a3878b SHA512 0e41899fac552e6a3c401c7dab3e3cd57f31cc5f052e07537f15b699c85113800edac27d232571ecab4852fab1d73374eca381d1ab70c9a7461bb422ff03de3b
+DIST pkginfo-1.7.1.tar.gz 34280 BLAKE2B ad928cf80423977e5944e3110150afb3e5ae416bf1fd28aec8099c3f25e41956b49e4134cdee5e0621e5bdff44d7161c3b1783b3c6d15555eee86e2e14c29fbb SHA512 5b6374e45e7ccd68f3a28145c2fc350e630e97fcc5e97d46d05c32f0958a51e4713487b809099ddf0a9ab07840f7fb4409438ab7b7a9b0b05e94d292088b2c26
diff --git a/dev-python/pkginfo/pkginfo-1.7.1.ebuild b/dev-python/pkginfo/pkginfo-1.7.1.ebuild
new file mode 100644
index 000000000000..9e2e019ce3c6
--- /dev/null
+++ b/dev-python/pkginfo/pkginfo-1.7.1.ebuild
@@ -0,0 +1,18 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Provides an API for querying the distutils metadata written in a PKG-INFO file"
+HOMEPAGE="https://pypi.org/project/pkginfo/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x64-macos"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs
diff --git a/dev-python/pyilmbase/pyilmbase-2.5.7.ebuild b/dev-python/pyilmbase/pyilmbase-2.5.7.ebuild
index 1394d3017f80..aab6641694f7 100644
--- a/dev-python/pyilmbase/pyilmbase-2.5.7.ebuild
+++ b/dev-python/pyilmbase/pyilmbase-2.5.7.ebuild
@@ -13,7 +13,7 @@ S="${WORKDIR}/openexr-${PV}/PyIlmBase"
 
 LICENSE="BSD"
 SLOT="0/25"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 ~x86"
 IUSE="exceptions test"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 RESTRICT="!test? ( test )"
diff --git a/dev-python/simplejson/Manifest b/dev-python/simplejson/Manifest
index 64688c3d8311..dcf8fae79243 100644
--- a/dev-python/simplejson/Manifest
+++ b/dev-python/simplejson/Manifest
@@ -1 +1,2 @@
 DIST simplejson-3.17.2.tar.gz 83210 BLAKE2B 1b9f97a43bfe84f1ad506713d81483ebcd4006d1174558b7a27373f99d014e23ed72a9ec2b2006e64760c61e1e500a4f1ea4547104e7f4c71ba51003df0a5052 SHA512 003b2fbcb3f8e0849bdbd958c78f8b470081d97527bef82306db77940c6734a1cbf3b5dcb0984d2f9c9d14aa525e7865a08e70a10971f8841e138f7ad6476e4a
+DIST simplejson-3.17.3.tar.gz 82434 BLAKE2B ae6f303a204f0c5a6bc7a10aa8da3dadbd4fc3a257abb15e330d13299dcbd5bc6be97506f6d5b48f3a3fe24570ac28b331644870d03aa30f80d40e69f4d2ec15 SHA512 b4ccdff3df2c87ed6f5119e93560ea7ddf60fcc64f996efeef1f6077f3a559c8f9ea77fd217348c1cba2de50e40523714899de110614953baf8385bb78d10af6
diff --git a/dev-python/simplejson/simplejson-3.17.3.ebuild b/dev-python/simplejson/simplejson-3.17.3.ebuild
new file mode 100644
index 000000000000..08ea4619941f
--- /dev/null
+++ b/dev-python/simplejson/simplejson-3.17.3.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Simple, fast, extensible JSON encoder/decoder for Python"
+HOMEPAGE="https://github.com/simplejson/simplejson https://pypi.org/project/simplejson/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( MIT AFL-2.1 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+DOCS=( README.rst CHANGES.txt )
+
+distutils_enable_tests unittest
diff --git a/dev-python/stripe/Manifest b/dev-python/stripe/Manifest
index 4d4e137ea6a0..e9b79d40f9e4 100644
--- a/dev-python/stripe/Manifest
+++ b/dev-python/stripe/Manifest
@@ -1,3 +1,4 @@
 DIST stripe-2.56.0.tar.gz 216066 BLAKE2B 1473c0b5a0f53cea18120b6234ed7f310c3625592423f16e77ca3a87c8a79f61c19c0c5f09d071a2be84e4f0d8b5323cc9f1de2e24a74bd24e557c9eb48b2c38 SHA512 1f2f08b5425ad48df9afc78f574109604319ccfcdb2fba8ca574008de5dadb349eec84d0e6cf532c57218bc8624af9b256a29ef01facb950a3cfd1168d8c2660
 DIST stripe-2.57.0.tar.gz 216286 BLAKE2B 9f2c3b7d4ae3f100647a1cae32d09f258703890eb97637ab2a9d3fc1d2fc30eae7042e4245d8f62a5cb4a5226337a7b22813d992842326aaa57d7ecb3a1da200 SHA512 c63efabc8febe79a01167ad4c166d9498f8623a3b1d36c292a3554cbacfc6aada1bf5ec720723b5a9de6e5c4fb770b8f44d1c95289aff4394a70a0301df61e93
 DIST stripe-2.58.0.tar.gz 216926 BLAKE2B 398b16ddab4050373ba5d7da3c8404b85b88d50749a5c3ce2e1704dbe04cdb99abc90b6c8837afbc3e086551e8dfa72baa3a5e68edf2ebb4e30aff157fb3ce8c SHA512 eee6154384fae69632e5e9ae7f972d97915b07da85c9f1af3849f5b9fea1e6f291c3d3e5b0e319c0d6dc0c035fec167f7711f650032016d3eb4709b333f3d5b7
+DIST stripe-2.59.0.tar.gz 219952 BLAKE2B f59d7e7f7c03f620dd2f43b5678208d72de0f947bf748c9c41d6782a6b01450a0547ddd5972a731fd1b8187479e1b813f890993ae097ec8c32acd4691256a4c3 SHA512 f27ed8457d1097aac43aaddaf39b8d1d9df25e837160407edea354b2fa8faf122ed86a9d36583ff56885e22663b230ee63af04baab0edad2711f3c691c8de51c
diff --git a/dev-python/stripe/stripe-2.59.0.ebuild b/dev-python/stripe/stripe-2.59.0.ebuild
new file mode 100644
index 000000000000..b80e0fe3c937
--- /dev/null
+++ b/dev-python/stripe/stripe-2.59.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="Stripe python bindings"
+HOMEPAGE="https://github.com/stripe/stripe-python"
+SRC_URI="mirror://pypi/s/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-util/stripe-mock-0.103.0
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		net-misc/curl
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=(LONG_DESCRIPTION.rst CHANGELOG.md README.md)
+
+src_test() {
+	local stripe_mock_port=12111
+	local stripe_mock_max_port=12121
+	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
+	# Try to start stripe-mock until we find a free port
+	while [[ "${stripe_mock_port}" -le "${stripe_mock_max_port}" ]]; do
+		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
+		stripe-mock --http-port ${stripe_mock_port} &> "${stripe_mock_logfile}" &
+		local stripe_mock_pid=$!
+		sleep 2
+		# Did stripe-mock start?
+		curl --fail -u "sk_test_123:" \
+			http://127.0.0.1:${stripe_mock_port}/v1/customers &> /dev/null
+		eend $? "Port ${stripe_mock_port} unavailable"
+		if [[ $? -eq 0 ]]; then
+			einfo "stripe-mock running on port ${stripe_mock_port}"
+			break
+		fi
+		(( stripe_mock_port++ ))
+	done
+	if [[ "${stripe_mock_port}" -gt "${stripe_mock_max_port}" ]]; then
+		eerror "Unable to start stripe-mock for tests"
+		die "Please see the logfile located at: ${stripe_mock_logfile}"
+	fi
+
+	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
+	distutils-r1_src_test
+
+	# Tear down stripe-mock
+	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
+}
diff --git a/dev-python/threadpoolctl/Manifest b/dev-python/threadpoolctl/Manifest
index 4c8c9ea54fc7..f8db3eb3ef6c 100644
--- a/dev-python/threadpoolctl/Manifest
+++ b/dev-python/threadpoolctl/Manifest
@@ -1 +1,2 @@
 DIST threadpoolctl-2.1.0.tar.gz 25255 BLAKE2B 3afa8e8c44567d3833dee89e761b2f384129c386c5c5b9d8084c1b301f007be7f461f1ef99738e06551f793feefa5c312dce1d608e7012215fd759866a52e2d4 SHA512 09b745b0d164bf3fc4f293bd92f1fd2e02180ec538bf3da1cdb986e31d9336ba3e1301aede72f53700d00298bae7b91b4ec8fa3212accb4cde6c3f5f88ff5c62
+DIST threadpoolctl-2.2.0.tar.gz 25875 BLAKE2B 4fc77efb181a91888d2d47cf1f9fa67157366e3ce33a958244b606019389624e83b1903581bfe88f8b4c798b4a8f07d0a50269282efaa323d3cae9f3d5ea8258 SHA512 edc310a9447b1782cedc98aadd065ce9291eca04518f6223090c1dd57f714b85f32293f16cfc1d95639130db47aa04806cac77a42922471e07582293416450fc
diff --git a/dev-python/threadpoolctl/threadpoolctl-2.2.0.ebuild b/dev-python/threadpoolctl/threadpoolctl-2.2.0.ebuild
new file mode 100644
index 000000000000..dc17b355155d
--- /dev/null
+++ b/dev-python/threadpoolctl/threadpoolctl-2.2.0.ebuild
@@ -0,0 +1,20 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+inherit distutils-r1
+
+DESCRIPTION="Limit the number of threads used in native libs that have their own threadpool"
+HOMEPAGE="https://github.com/joblib/threadpoolctl"
+SRC_URI="https://github.com/joblib/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+BDEPEND="dev-python/cython[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest