Adding metadata

27 files changed, 691 insertions, 2 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index f4d6288a5974..f0e4947652d6 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -9,5 +9,6 @@ DIST boto3-1.28.18.gh.tar.gz 684109 BLAKE2B a16e76ec76884c0d82ad99060d2094a2fa5e
 DIST boto3-1.28.19.gh.tar.gz 684512 BLAKE2B f8cb7b2e2ad2861548420b3406e2f76f35377e90a4205353395ba3016ba7cafbffba617902b97a0680275a9e120f4b99a903e6424f6274373d8a2b540f81faef SHA512 c4a62a1ca2951536700f8a337bbce9ea1093f0db5076df9d912c66f24917aa55d79980e4a712cf05cbf329fda2ef6c216dc6ef4d2a36d51d0d9c0320d0a5ae6d
 DIST boto3-1.28.20.gh.tar.gz 684832 BLAKE2B dc8dee3e001e26fa5e9f1355ef40cb03a860fdba2585abb230213f04d443f047aeed3c8fc866c34e546d9dd74e373311172aa5a9ad235dd3f99d3c6d81dac8c2 SHA512 7409ebf4fe84b549ec701cff8f5c8373f360d1855e3834f2ff1c1882ee6c34ad5b5bed0ac8f133ae3412026c4f69ed626858c019e6338e03e4ebcbc2cbb761f1
 DIST boto3-1.28.21.gh.tar.gz 685243 BLAKE2B f6f6effd9ac42fb9d8db8ec91f628cb90b399e201a780f978e528565299488cd4d9f0333f2ff5d2127b92cff4811856c31d0b280f66b62bc1cacfb3003ae0b92 SHA512 81049ab063131e18ace8c5e6f746e1618d8268cedfdbd6931e7fffd743e8cfd335ec15a4ad354bb61cb987fd93e375d2b5970c8946ae0a9c8892e03a3e912657
+DIST boto3-1.28.22.gh.tar.gz 685817 BLAKE2B 53dc35d037fd3605ae8a63c85e77e5b449cc9d7f80c4e06c3d96104afea7fc07c11759e3bea5ba3fa5fa1d86608dfa7ce3ab2612c66239e7ec06603c81c2d744 SHA512 2d255b1eb02626f7b63503ef2324b97b59ebb1728d9c2be79f3a65810ceb13bfb4091b3f657f61422a324fae559c065e848ba24e3c7c1e25a4fcb200eab133e5
 DIST boto3-1.28.3.gh.tar.gz 675019 BLAKE2B 93b29307fbfec4e61dc60d28e4f20392ae2a730f048a0b2e8cb99fd515a036fc4ca889ddd564e09b1f3eab4cb9499c5918b4e7430d63148dd2854d126719a468 SHA512 514d0f373f25bb691abf5f1f8b0209a07097191b2ad8fb6339739e7a0bd2b8e6d5a88f1250e928ca89b1f1aa5e27a44bf2cab38a57680c01214d370d11944ded
 DIST boto3-1.28.9.gh.tar.gz 677993 BLAKE2B a800de94cfb0d317b41091fb1d2bb0fd6449df85da434879c0689bf36998b2a52331ba077c65cae9967fcce998a15d2a6f6a758931fa12a00b95487adaf81dfa SHA512 6e1e5e74d20d2e67f29597ddcda70475cbea863978ca93ec77a0f478690477c9782111701771d5b8354f4402c21496e7f5627b1398cbd6fd87627fd978f5e360
diff --git a/dev-python/boto3/boto3-1.28.22.ebuild b/dev-python/boto3/boto3-1.28.22.ebuild
new file mode 100644
index 000000000000..03c610b184f7
--- /dev/null
+++ b/dev-python/boto3/boto3-1.28.22.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 87abb800f622..f63c085af8dd 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -9,5 +9,6 @@ DIST botocore-1.31.18.gh.tar.gz 11849581 BLAKE2B b2a4800a2fc6d367e8206f3d246bc04
 DIST botocore-1.31.19.gh.tar.gz 11853202 BLAKE2B 2f5205ee0b72e945c060561462e97b4af625b9903d22dc8a602613488c879f9b3d8c4ccd81b6176a72a123bc7d35483c63395e9a3915f51a5316bacd3c6e283c SHA512 c1a7ac18325932946a1ba331b506d4903b452d3b9dabce6e3fc553e2db0d7b80c92010be6db4c5cb7b7e6b9244776dffb0486f4f2109d747514fae41017f6aaa
 DIST botocore-1.31.20.gh.tar.gz 11852972 BLAKE2B f4c4cf244de902fa4debeeb69c1981dc850751d8750c5c0af109d3f594991ed23a405688d864ac1237df39e8ac96b9d49f4cc83a973dea91ea6539eeaf2458a0 SHA512 e3f4960279c895eec503420bc1b42574fcfb53e5f1cdc6a26207ca1dbd34b36ecfc52c1dcd7b1e9918a5c3c91569baf1df524ca4269a7279fb2d0ef751355fff
 DIST botocore-1.31.21.gh.tar.gz 11852848 BLAKE2B ccdd57fdb927335ac2b5d2f56946e49c2a397673b727a80a11a4b427dffc6f8df80bf90e9b2a937e0cf7e130850fbab3610a4484a2559a5dfb9f200d69441252 SHA512 1ee2ac3ca8d75cbabe11083f2409641d71e7c96ff476f7892d13f9e33878b58526a1a05c676befe78d5ffc7d3b1384277c7ad3bb224ec4aed378029b12817868
+DIST botocore-1.31.22.gh.tar.gz 11858266 BLAKE2B a4eb898f7e562b692592171ab239550995ab6bf472cd5d98d5f98b412b050f18610ec61db58367d0cfec28d77f973f0200d5b13a88ea5bf66e5d41a6a254ccdb SHA512 fe66dd19e38ed98449f76e921ee538132a1e8a2f1452b6a7e88175901a1275e467faac4f1ec825854b6f8e799f4a54d2bebe4a52256edbdce3004944b2c6bd1e
 DIST botocore-1.31.3.gh.tar.gz 11769948 BLAKE2B 452c494faa430b6782685b9960cc9ea15ce3dedfe1b5343ee7bdbd7544e108bbfc7bb58d527419b5dc5f4077dd806752eec927196b82ac286903992fef339e52 SHA512 0f2853c14d7695ea4eeacea6fed93e77436df143bd0b9bec967490eb88e3d6531c916dca91c1a3bde4b57253d77acabe2413acde4d1473d01e15ef69b45621e0
 DIST botocore-1.31.9.gh.tar.gz 11785638 BLAKE2B 23f2c010f98b5ca8414c9a031524b1cb7d75366bf84d34df980ef4085a73bc62643cca5255519f891f7a9468abbf0d97adddf6684c3c0a751b0f9f390122c19d SHA512 b2bf0089a81c5389d86c9f7b2545358f23a1219d7e5bf152285f58293a171210b46c22c814ab3f8da460a2acbdd5127193fa7a2e19a021db511f9d08931037bf
diff --git a/dev-python/botocore/botocore-1.31.22.ebuild b/dev-python/botocore/botocore-1.31.22.ebuild
new file mode 100644
index 000000000000..4bc7f657ecb8
--- /dev/null
+++ b/dev-python/botocore/botocore-1.31.22.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/clang-python/Manifest b/dev-python/clang-python/Manifest
index c6c293dd1492..839ce3fd55e7 100644
--- a/dev-python/clang-python/Manifest
+++ b/dev-python/clang-python/Manifest
@@ -6,4 +6,6 @@ DIST llvm-project-16.0.6.src.tar.xz 118013488 BLAKE2B 95192d39cbd2914e5609db3659
 DIST llvm-project-16.0.6.src.tar.xz.sig 566 BLAKE2B 2060cebd5ed57cb8a86a44238c43dfd4b921649298b10c3d19da308374c1e49869174294e29943c2af459fe06428264e26881d6c1288ebbc48686cc2cf467c7a SHA512 ca249262c7102e0889ec1bdc6f71a3a6f0e7e5d5fbab8abcd6fccd2871e7955eff7af5b055a76006097baf0dfaf2f5069eff3035b3107fc552abdb2481b21447
 DIST llvm-project-17.0.0rc1.src.tar.xz 127805900 BLAKE2B ab6e3b7e7af10bbb086bdd271691c259925b8047d8425b0eafb55d2c1daf637c3a56903b88e50283667955e780a47f61e7215a1e3a1acd3634c62960cf17317f SHA512 fa7ebe7fad14087861dc0eea08f68e8aa01dcc6560d70163ec38819a7fd799484f6ab1e35a69393a14962b45fa0a469c9d6c5fd2882b3609305bd01bc9f6701f
 DIST llvm-project-17.0.0rc1.src.tar.xz.sig 438 BLAKE2B 976098c616d7f01c08c5be1d76dd395950184d2c6750f3f2c14235cdf446f1d876d842b3591f827cf1157fa25c707862a374e34d61fb73afe5a7b08d6041ee4a SHA512 272e92dec1fd43819f6fafdaa7f55a975e60a1c3000a69875209b89b7f3e2d2851e32ec0f2725242479203068349aaeff8da261d998a2325a9c52733bc5d7697
+DIST llvm-project-17.0.0rc2.src.tar.xz 127795160 BLAKE2B 58ed818f61e1cd179288d578e89460782617a3791a65dbc3e1f207629004f0d61225e87b78fdc0eeb3647912e5056ab68ce35ea2639a34ded1d8bdf0452e31f8 SHA512 7eb5c5172b5e9af65c940c876779f90e20a02659bf1489cedd06c67eea205aa1f4bdc5a8134a120db98cb80ca54673902b530c3315c9b53384c091200d9162c0
+DIST llvm-project-17.0.0rc2.src.tar.xz.sig 438 BLAKE2B 55788eacc592729839dad581b507794f279d84cafcaa49785ae34e02931ee9d4f64caf9e251e280dbc8676f3cacdca52a22f36cf7282655a3fc0721a61c9f003 SHA512 141e1ba7eb9870c21b91060ca484316cc8a402d4e61c8312688023850070b255b0eebe2d10ef63925f7269ee1b347074440e1a9a18d37cb7e1b6c82a7d1a1710
 DIST llvm-project-c4bb3e073548cf436d5fa0406e3ae75e94684dec.tar.gz 195462091 BLAKE2B 982f1105db6cf63575916a20432df4c8623bdff236ce3bd95e63ffd931bc8e1f0e9ea9ad673b09d749c35c1bfe68a48f5b4080118f25040498db09a580db3a7e SHA512 1c591175f44da85eb5ee831220c0387a3d9a0604beaf7abd89fbc6d1e0e9c4f80dac73de1dc22375a45115dd4c1d764fed0a0f628993ca780eb6991682aa0b5b
diff --git a/dev-python/clang-python/clang-python-17.0.0_rc2.ebuild b/dev-python/clang-python/clang-python-17.0.0_rc2.ebuild
new file mode 100644
index 000000000000..f37802f5c2d7
--- /dev/null
+++ b/dev-python/clang-python/clang-python-17.0.0_rc2.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+DEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	test? (
+		sys-devel/clang:${LLVM_MAJOR}
+	)
+"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	# tests rely on results from a specific clang version, so override
+	# the search path
+	local -x CLANG_LIBRARY_PATH=${BROOT}/usr/lib/llvm/${LLVM_MAJOR}/$(get_libdir)
+	local -x CLANG_NO_DEFAULT_CONFIG=1
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/django-auth-ldap/Manifest b/dev-python/django-auth-ldap/Manifest
index f5b5c7fda4af..a3034fbc892a 100644
--- a/dev-python/django-auth-ldap/Manifest
+++ b/dev-python/django-auth-ldap/Manifest
@@ -1 +1,2 @@
 DIST django-auth-ldap-4.4.0.tar.gz 53117 BLAKE2B 46ae8f9788c3ed12d8b3576b4335390d3bc902a3627dd5af9028c2bd49dc64eef2f31995bcf51a6d20c55400bbd3dd5f4882ecc01e8d92564a6664db743809ca SHA512 d01f40f64e0d6cd47a0efaaf3b5e6a30a399b0a3b9a6b4c6f683a8237b84076294821970bbb265f66e06b0fbec58417287188e5f09631b21f204137d003ecfd7
+DIST django-auth-ldap-4.5.0.tar.gz 53642 BLAKE2B c603cda6ed2f7532d0ef5f69a64f7c3b4bd86981e561c14be7d818f044382b54ffb926687416a170ce068ec435d660da9965761db97cff28dc4d6f95511c59c5 SHA512 1606bee77a03a669eb4ccd906db26c80166f370e04749a5f340e4a07574032130d9f6af22d25d09c96319e45f6137c26928ad543ea592d3a172aea623e97550b
diff --git a/dev-python/django-auth-ldap/django-auth-ldap-4.5.0.ebuild b/dev-python/django-auth-ldap/django-auth-ldap-4.5.0.ebuild
new file mode 100644
index 000000000000..67c5e95d93ba
--- /dev/null
+++ b/dev-python/django-auth-ldap/django-auth-ldap-4.5.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Django LDAP authentication backend"
+HOMEPAGE="
+	https://github.com/django-auth-ldap/django-auth-ldap/
+	https://pypi.org/project/django-auth-ldap/
+"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+LICENSE="BSD-2"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/django-2.2[${PYTHON_USEDEP}]
+	>=dev-python/python-ldap-3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		$(python_gen_impl_dep sqlite)
+		net-nds/openldap[-minimal]
+	)
+"
+
+distutils_enable_sphinx docs --no-autodoc
+
+python_test() {
+	# for slapd and slapdtest
+	local -x SBIN=/usr/sbin:/usr/$(get_libdir)/openldap
+	"${EPYTHON}" -m django test -v 2 --settings tests.settings ||
+		die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index 9713eca24f3e..91d65f0dda0a 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1,3 +1,4 @@
 DIST google-api-python-client-2.93.0.tar.gz 10929939 BLAKE2B 67369eac89a12f212841923e2f912ce18b3ae39c7e0fafd45cbcbff3556919a784ec8dce2f73bcf91de3f2faa0404ec17719582a283120cf43d03a1513ed6c7c SHA512 41c6ef0cdf09e8c486b91490383bcb5914d8bd15a0ed486abcfe9b9121b035a2a9d9b8abeeb60ee0f6757e100618308df8967c6ace687d991ce9b609dd3b0747
 DIST google-api-python-client-2.94.0.tar.gz 10987576 BLAKE2B 11851577d05e15208f4dc8905a8147b753442ceb36ebac74b01ecb8f7993bbc1d02813d12f06fea3ec0bec7df180da4a4963899bc85479ac0c744627a5aed614 SHA512 750d55848ebe69605d4948e368ddbb590b69f579d394e533bbc81a28d21b7435b817d08092f508303725cb492245cae8b9f7f94628593d10e9574cfe79440b4b
 DIST google-api-python-client-2.95.0.tar.gz 11044697 BLAKE2B 1a28798146d2f321f0455dd092430cefb6d15ddc3469ba0b5ee2aab6546c4c56477379e970ac4b0eeb1a969d53a5ea002206145c046bbfa89c1b6d65dad5a2d1 SHA512 3e8419d4de8e1604365b47bc13ebb69939f2c86bc46e1e08277a3766a23f03660c25ab9113a13b6abbfee2afb4f49678144bb11c4a423c4cf05c83717863183e
+DIST google-api-python-client-2.96.0.tar.gz 11464696 BLAKE2B 5cec3b123ffe03f812909dd2f1aeb723ceacd657a5e3e796f358fde5c79fa274fb45a01a2857c9fbcb5431f00384792b1c3f721fafbf2c58e6732bb352539dc7 SHA512 94b59d38df431b1624192946f84229f100870c44eaa304f740dc1ff8973bf54f9c1bf59315aa826f122ec4b46c21507d4f2c5f691a18804e57d81379848346e8
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.96.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.96.0.ebuild
new file mode 100644
index 000000000000..0c85e8ca1676
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.96.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="
+	https://github.com/googleapis/google-api-python-client/
+	https://pypi.org/project/google-api-python-client/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	>=dev-python/google-api-core-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	epytest tests
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 23450e68c5d8..432f121d083a 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -4,3 +4,4 @@ DIST hypothesis-6.81.2.gh.tar.gz 9378154 BLAKE2B d4654e8de621af93fa6ab013bf45ea1
 DIST hypothesis-6.82.0.gh.tar.gz 9378337 BLAKE2B fb99a499c7b850c4d81f01b99969d611ee8a39a1b1d1a5306b72999b1ca20d605fb42adbc090eedbe06359056d05860e2166be9f8f8001460ea61b398a432de6 SHA512 2f8b16c1a32340a3aa742627cbbc958cb06e8966b704bd389c8677d58fc3e76e6988705315d570daeb46975839b1c725f5f6a937ff1c326cbed144659ec44d05
 DIST hypothesis-6.82.1.gh.tar.gz 9378717 BLAKE2B 2127d101f5c477fa99abe07df09928d0be475dd052f8f121ec038488eb4b5b35508b09524ae06ae8fe41712724fbb50f8db4aa72472a7315cc3ad68b9000371e SHA512 3fb983b2246aaa9860694f07eee9fafb28f560b3ba105544d3d4345ba323543f194109b710c639e86287572ad5ed141c2edf6c89c0f4a71a003505a797effddc
 DIST hypothesis-6.82.2.gh.tar.gz 9378887 BLAKE2B 8b1c65ea9080bb280a6f7b761aef0c24539c707b0875621baa2b011188839d8179dcbcac051c97fe36c870404d67ec28124857646f8d95d34b44bea081ef1658 SHA512 cd5dfa439f4f5bdbf744e25bf24b5265515c7077d142eecbb77825056e44417124ffd1f97755d6804d412424e0ef78a77e77e112cafb7972cdae1be028ab5ca6
+DIST hypothesis-6.82.3.gh.tar.gz 9378981 BLAKE2B bb73131f9982e8df71e24a5f329a2f34b7e895ffa231d55724f84a3d692608e59a4494a820ea5ee449db4c40f2521548b2dece2f1bcfa9fbd4f0ddbc4dbb9756 SHA512 02b649116630dc6be3cbd659a00c9c55d68c85a9cbf029558fc1c065909a1cadd2fb120615fa3bf7fe4a11f51d26d264cf6730ac4d3165798668d38e62c5d955
diff --git a/dev-python/hypothesis/hypothesis-6.82.3.ebuild b/dev-python/hypothesis/hypothesis-6.82.3.ebuild
new file mode 100644
index 000000000000..45ac15b82e26
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.82.3.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..12} )
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/lit/Manifest b/dev-python/lit/Manifest
index c6c293dd1492..839ce3fd55e7 100644
--- a/dev-python/lit/Manifest
+++ b/dev-python/lit/Manifest
@@ -6,4 +6,6 @@ DIST llvm-project-16.0.6.src.tar.xz 118013488 BLAKE2B 95192d39cbd2914e5609db3659
 DIST llvm-project-16.0.6.src.tar.xz.sig 566 BLAKE2B 2060cebd5ed57cb8a86a44238c43dfd4b921649298b10c3d19da308374c1e49869174294e29943c2af459fe06428264e26881d6c1288ebbc48686cc2cf467c7a SHA512 ca249262c7102e0889ec1bdc6f71a3a6f0e7e5d5fbab8abcd6fccd2871e7955eff7af5b055a76006097baf0dfaf2f5069eff3035b3107fc552abdb2481b21447
 DIST llvm-project-17.0.0rc1.src.tar.xz 127805900 BLAKE2B ab6e3b7e7af10bbb086bdd271691c259925b8047d8425b0eafb55d2c1daf637c3a56903b88e50283667955e780a47f61e7215a1e3a1acd3634c62960cf17317f SHA512 fa7ebe7fad14087861dc0eea08f68e8aa01dcc6560d70163ec38819a7fd799484f6ab1e35a69393a14962b45fa0a469c9d6c5fd2882b3609305bd01bc9f6701f
 DIST llvm-project-17.0.0rc1.src.tar.xz.sig 438 BLAKE2B 976098c616d7f01c08c5be1d76dd395950184d2c6750f3f2c14235cdf446f1d876d842b3591f827cf1157fa25c707862a374e34d61fb73afe5a7b08d6041ee4a SHA512 272e92dec1fd43819f6fafdaa7f55a975e60a1c3000a69875209b89b7f3e2d2851e32ec0f2725242479203068349aaeff8da261d998a2325a9c52733bc5d7697
+DIST llvm-project-17.0.0rc2.src.tar.xz 127795160 BLAKE2B 58ed818f61e1cd179288d578e89460782617a3791a65dbc3e1f207629004f0d61225e87b78fdc0eeb3647912e5056ab68ce35ea2639a34ded1d8bdf0452e31f8 SHA512 7eb5c5172b5e9af65c940c876779f90e20a02659bf1489cedd06c67eea205aa1f4bdc5a8134a120db98cb80ca54673902b530c3315c9b53384c091200d9162c0
+DIST llvm-project-17.0.0rc2.src.tar.xz.sig 438 BLAKE2B 55788eacc592729839dad581b507794f279d84cafcaa49785ae34e02931ee9d4f64caf9e251e280dbc8676f3cacdca52a22f36cf7282655a3fc0721a61c9f003 SHA512 141e1ba7eb9870c21b91060ca484316cc8a402d4e61c8312688023850070b255b0eebe2d10ef63925f7269ee1b347074440e1a9a18d37cb7e1b6c82a7d1a1710
 DIST llvm-project-c4bb3e073548cf436d5fa0406e3ae75e94684dec.tar.gz 195462091 BLAKE2B 982f1105db6cf63575916a20432df4c8623bdff236ce3bd95e63ffd931bc8e1f0e9ea9ad673b09d749c35c1bfe68a48f5b4080118f25040498db09a580db3a7e SHA512 1c591175f44da85eb5ee831220c0387a3d9a0604beaf7abd89fbc6d1e0e9c4f80dac73de1dc22375a45115dd4c1d764fed0a0f628993ca780eb6991682aa0b5b
diff --git a/dev-python/lit/lit-17.0.0_rc2.ebuild b/dev-python/lit/lit-17.0.0_rc2.ebuild
new file mode 100644
index 000000000000..0e39fac626c6
--- /dev/null
+++ b/dev-python/lit/lit-17.0.0_rc2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm
+	)
+"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}
diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index 967ddd1cf175..c589010af7c2 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.1.4.gh.tar.gz 134278 BLAKE2B 38e52761d54cab96727d5015e41de76cd6d7eb6dbd02829ed2ddeeb2e2d64d42a0eb6bb09e055362e1dd181d9e7781ed9f9abcb2f96de342cd5780e1f21a8708 SHA512 4833819f8828f5e2ff204ca18478704d8d66c977c747f9b550dc1ecfee57a8adbfcddaea6dded8d8ea0c0e0c7745e0704e12acae30d183cb27cf4c1fad331791
+DIST pdm-backend-2.1.5.gh.tar.gz 134316 BLAKE2B 9337990b4ed009e506f0eee82e9f8d50fc281dbf917dc964daf75230a4c2b9cc5bf0748afe9aa7b5b6f9036249b87ec338b129136b2fd92619c12000e77a7663 SHA512 867c36a9381f4e6a2c81f2d987ce33953eaf78a43b4fa03df54f78b6c9cfe645a1ae4f3dd1a514e0d14208ad7fc75af954fa46be3c8b4b54c7ac7e16eead5aaf
diff --git a/dev-python/pdm-backend/pdm-backend-2.1.5.ebuild b/dev-python/pdm-backend/pdm-backend-2.1.5.ebuild
new file mode 100644
index 000000000000..c2031e42a33b
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.1.5.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	# this must not be set during src_test()
+	local -x PDM_BUILD_SCM_VERSION=${PV}
+	distutils-r1_src_compile
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}
diff --git a/dev-python/pygccxml/Manifest b/dev-python/pygccxml/Manifest
index 509860418241..c98076c800aa 100644
--- a/dev-python/pygccxml/Manifest
+++ b/dev-python/pygccxml/Manifest
@@ -1 +1,2 @@
 DIST pygccxml-2.2.1.gh.tar.gz 3170283 BLAKE2B b53123c59d098f56d97841225d10ffd4156b993244e48c4ad30e2f62b6d95d69e0ae4bbfc86bb492e88e8f52d916401f29a6ec7024277d1e32b3af691a12e919 SHA512 32013617d4d632617b616d3787631c5b09da441a87bb15b88e3b287f17b85e1388308e85dd385276966ac09114536a5863edd5fbb96539547783fd2d41c6e8ce
+DIST pygccxml-2.3.0.gh.tar.gz 3165248 BLAKE2B 177591d818f3ff91b7981ee1b1af9d03f79869508cddd03ece8f3b5e447982dc2d9434fa42db290c98d8c5fb4f4ee4ae7ef86e2b065dc28ba4b7843a36cad4e1 SHA512 6c5710c842c8e6101af73335ea66dc18ae86861f9cd5c59b4aa1037f60914934ba22a821d7f35cf954f5c40800433bacfc0d4bd0ae1bb5946a4dd950c606ceea
diff --git a/dev-python/pygccxml/pygccxml-2.3.0.ebuild b/dev-python/pygccxml/pygccxml-2.3.0.ebuild
new file mode 100644
index 000000000000..c51ab4e54471
--- /dev/null
+++ b/dev-python/pygccxml/pygccxml-2.3.0.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit distutils-r1
+
+DESCRIPTION="A specialized XML reader to navigate C++ declarations"
+HOMEPAGE="https://github.com/CastXML/pygccxml"
+SRC_URI="https://github.com/CastXML/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~riscv ~x86"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/castxml
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_tests unittest
+distutils_enable_sphinx docs dev-python/sphinx-rtd-theme
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+}
diff --git a/dev-python/regex/Manifest b/dev-python/regex/Manifest
index 032bc9ec1190..350774846df2 100644
--- a/dev-python/regex/Manifest
+++ b/dev-python/regex/Manifest
@@ -1 +1,2 @@
 DIST regex-2023.6.3.tar.gz 392247 BLAKE2B c7735e19df80e919fd577723c54f6761698adf014dd4e936cda6a1ed745f26f083abd59ed2a772a70e16bec742f8d29a1e76a726b28e1395265c9941ff4e7b99 SHA512 092f316621a0237425a6e8124b289f4156256424b28cb36c590b8d89d731cfa363a97051199b16ede6520e12e99659497f230338a6f913587f578ededdedc408
+DIST regex-2023.8.8.tar.gz 392505 BLAKE2B 0d0f582e42c93ec4497f82ac69aaad6a69dd4bbb482bef6e06a51340a67b8d041ec554d878d8f0dcb57dce08b708fd87762ed8451f0221019f38d8188031711b SHA512 81a8421df5ab2db0eb4a5d1c434933d1513f634f32f57a48b32dede3bfddb379345baf7ecec0241338c0fc0f96463489ffa64c3214ee58a92ab5592cf9893bef
diff --git a/dev-python/regex/regex-2023.8.8.ebuild b/dev-python/regex/regex-2023.8.8.ebuild
new file mode 100644
index 000000000000..1f8050d6db4e
--- /dev/null
+++ b/dev-python/regex/regex-2023.8.8.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Alternative regular expression module to replace re"
+HOMEPAGE="
+	https://github.com/mrabarnett/mrab-regex/
+	https://pypi.org/project/regex/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="doc"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_empty_array.patch"
+	"${FILESDIR}/${PN}-2021.4.4-pypy3-fix-test_issue_18468.patch"
+)
+
+distutils_enable_tests unittest
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/Features.html )
+	local DOCS=( README.rst docs/*.rst )
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/sqlglot/Manifest b/dev-python/sqlglot/Manifest
index 07b553a4041b..92c44f7ca0f9 100644
--- a/dev-python/sqlglot/Manifest
+++ b/dev-python/sqlglot/Manifest
@@ -1,2 +1,2 @@
-DIST sqlglot-17.10.0.tar.gz 8390551 BLAKE2B 634b771dfb028feec56e643a1806801d7adaa8fb35c18e13241cf278e11da37cf5cb121f1b470b893da5d4bcb2972bfe8c271ff071a99ae2a2887568afe7b464 SHA512 1fb9dc5981e0dd57814ba1f86109a382359dedfad0dee8da241e126ae2e3365372afa3de76c4a1be60fa8993883ab643322812d71e68986bca8a97ecb5a35edd
-DIST sqlglot-17.9.1.tar.gz 8389281 BLAKE2B 97c1642a42940344cffb9a6c53db44d4850d0d4b029dde16f202288515d40cfb3a405813893140041bd19c30ed9dfa9d1ab104e0a61a6ccefa140df26fa86eb9 SHA512 925b56cf0bb84a58416b32af33ed37c30ca93d56244ab3cd6f72276dbeb448a85e3b1919c9bca77f3d0c51b9de70f0b98afc666067b1377ede8e52dea3d71267
+DIST sqlglot-17.10.1.tar.gz 8394322 BLAKE2B e7d922644e3071ccc6ce666b10081ce24095cbed6d2136c70e632d241196058762167874b175e6b000dda91922d72000fd6f57d8ae775dec588915f10a51d2e8 SHA512 6cbf3c82e5fee73dcbfe677213c10325a5fb81c8f93ba594d88abe9fb7d3a6580c6c6adebc6551cbe1dc8ae51ad68ac33a0242088e68dd80ef3e7285f4479ad1
+DIST sqlglot-17.10.2.tar.gz 8399314 BLAKE2B c9695273925485f366f155f15a741074ed9b8f91ca5dfd7b233af8c43acb9dddfd48125218f12b47a4a1ad4003299e49ce532e4ff8a24a6cf6b074b6e069b484 SHA512 806b59eaca0b90f94fea9613313763276fd4def1b34e4781b7c5a05dfec446b3d6ddbfe27bf9c6f631820220013cae390f3e251ed432816d7598ed3140993d89
diff --git a/dev-python/sqlglot/sqlglot-17.10.0.ebuild b/dev-python/sqlglot/sqlglot-17.10.1.ebuild
index 0120736dda66..0120736dda66 100644
--- a/dev-python/sqlglot/sqlglot-17.10.0.ebuild
+++ b/dev-python/sqlglot/sqlglot-17.10.1.ebuild
diff --git a/dev-python/sqlglot/sqlglot-17.9.1.ebuild b/dev-python/sqlglot/sqlglot-17.10.2.ebuild
index 0120736dda66..0120736dda66 100644
--- a/dev-python/sqlglot/sqlglot-17.9.1.ebuild
+++ b/dev-python/sqlglot/sqlglot-17.10.2.ebuild
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 7a1183c6377b..704b8aa77bbc 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -6,3 +6,4 @@ DIST tox-4.6.1.tar.gz 172090 BLAKE2B ee86b8972ee273f07ab0197ab2f0b6ce4505206eebc
 DIST tox-4.6.2.tar.gz 172333 BLAKE2B 0fa9e7782eb18b525ff7f226b0fa9b8001f69f8b620b86a19bc2c19c349b2c8c7440a1de220387bccaa7a9044796db57ae63d16851c98a73ced2c495a01b5f3e SHA512 3e4663972f8c51a634f00c57c8b9b6704a628e912ef2e1854a8dfbd7bce13e44822984af9f69cb5b8a306ede545a565044cfeb8803cff41a530de7958fc07878
 DIST tox-4.6.3.tar.gz 172585 BLAKE2B 14d895a516fdb1b767c922633185b31904149e7fea9d1ae3faaac343bfd481fc843dcb4784168c89fb6d3f5503f4ff8fb35680ed197b5df2dde1f124be1df8ea SHA512 6261998bb753556a24e869db18955eea9b26063e0b67503028571e62085c2da535dc60552192c69ba07366150c4f3a3ce6bd36dd62d2fe6f24d7b466dccf2e76
 DIST tox-4.6.4.tar.gz 172650 BLAKE2B 84164dbb02002d398e779b0c5e4617213fbfc711ded95faddde93711549eab9e69675f0a459ce60ba8357baf4e7d361f86b4cb85818972e5d018a61db179ba1a SHA512 b6a4673ea58e21b5e8b3d1330244d46ac7a36563a089b2e03cfcd7039386ab6afc437ebf4c516bbe373133a7beb54ebb380d39ab126be69f3601226f2273f3c2
+DIST tox-4.7.0.tar.gz 172893 BLAKE2B 9611cbff7937e859ad923d40978804eede6eb372868c7af85597644a3568e775627361faa64587aa44c9e1e3bcf565fb4c6956d73fe973c258c90f005f5e5b14 SHA512 17c010af1dd402dd1dff86dca9154be16212bdbdafa4d83f6337e5c4ebd6f7256b7cf813ac8bb22d755873c89179caeecbaeed05c7e6dd6903251c3548fa8042
diff --git a/dev-python/tox/tox-4.7.0.ebuild b/dev-python/tox/tox-4.7.0.ebuild
new file mode 100644
index 000000000000..fbc652a8545e
--- /dev/null
+++ b/dev-python/tox/tox-4.7.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/cachetools-5.3.1[${PYTHON_USEDEP}]
+	>=dev-python/chardet-5.1[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4.6[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3.12.2[${PYTHON_USEDEP}]
+	>=dev-python/packaging-23.1[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.9.1[${PYTHON_USEDEP}]
+	>=dev-python/pluggy-1.2[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-api-1.5.3[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	>=dev-python/virtualenv-20.24.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-vcs-0.3[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/build-0.10[${PYTHON_USEDEP}]
+		>=dev-python/distlib-0.3.6[${PYTHON_USEDEP}]
+		>=dev-python/flaky-3.7[${PYTHON_USEDEP}]
+		>=dev-python/psutil-5.9.5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-3.11.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-3.3.1[${PYTHON_USEDEP}]
+		>=dev-python/re-assert-1.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/time-machine-2.10[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}
diff --git a/dev-python/tqdm/Manifest b/dev-python/tqdm/Manifest
index e579e88c470f..385bf4c5073a 100644
--- a/dev-python/tqdm/Manifest
+++ b/dev-python/tqdm/Manifest
@@ -1 +1,2 @@
 DIST tqdm-4.65.0.tar.gz 167542 BLAKE2B b1f7b5666600dd5c476ffc9852cdc8905b8819b6b3f812e00495fa38780dda0c59e48956881d46919ce57b13da9dde519fa7e22d91ed58fe43172da8e9043653 SHA512 86315b57d8ceec69ee8970b25372b26b03d2d37f6d06e037e712bf16c7f56eac1c4049291e451c7df62273b91ba7149b400efd0186ceee90268d854e7b476c47
+DIST tqdm-4.65.2.tar.gz 167099 BLAKE2B 5b3d1444aacd3ffa46149889ed5eee3bc851da2c000fcfbd06ceda811ad6df3fd7f9b5da90e7124930ebfd8249a52d194d807d7f8e8b1170966d2b1e6128fc7b SHA512 012810c5844f4034388469a4ce71382067a42960a534e2720d412483b3668040367e94c1865dcd44855cf1f2c7e28312b6084d579348492d7ca3ba5241395f40
diff --git a/dev-python/tqdm/tqdm-4.65.2.ebuild b/dev-python/tqdm/tqdm-4.65.2.ebuild
new file mode 100644
index 000000000000..35b6983b2e5c
--- /dev/null
+++ b/dev-python/tqdm/tqdm-4.65.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Add a progress meter to your loops in a second"
+HOMEPAGE="
+	https://github.com/tqdm/tqdm/
+	https://pypi.org/project/tqdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Skip unpredictable performance tests
+	tests/tests_perf.py
+)
+
+python_install_all() {
+	doman tqdm/tqdm.1
+	newbashcomp tqdm/completion.sh tqdm
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}