Adding metadata

6 files changed, 231 insertions, 3 deletions

diff --git a/dev-python/google-api-core/google-api-core-1.26.1-r1.ebuild b/dev-python/google-api-core/google-api-core-1.26.1-r1.ebuild
new file mode 100644
index 000000000000..1f2741cdc81a
--- /dev/null
+++ b/dev-python/google-api-core/google-api-core-1.26.1-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Core Library for Google Client Libraries"
+HOMEPAGE="https://github.com/googleapis/python-api-core
+	https://googleapis.dev/python/google-api-core/latest"
+SRC_URI="https://github.com/googleapis/${PN//google/python}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P//google/python}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/googleapis-common-protos[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.21.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18.0[${PYTHON_USEDEP}]
+	<dev-python/requests-3[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/rsa[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${D}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index a38a2661369c..8e2de1470dc4 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -5,3 +5,4 @@ DIST pikepdf-2.8.0.post1.tar.gz 2370159 BLAKE2B 336f2034f3a0207d1f5522b13ff2d0a0
 DIST pikepdf-2.8.0.post2.tar.gz 2369810 BLAKE2B 67b2f88a0718076d9f28148342832ec646443b6bdf0f9ca3717a9a9caa6518563564f25e4532c3ebc5d05e18b78f2db4a9bab17f0d0cf6cf329dcc41f7c3332f SHA512 adf28106dbf58bf4b29c3930280c6f54c04ac4fc40adb4d9e7fe3a288293b077f2e4b063e4be91e661c835b474ba2b46167ce05d9f5d2c7c13ae180f6b3b76dc
 DIST pikepdf-2.8.0.tar.gz 2369623 BLAKE2B 465fbb682b973631d50b841b292ed8d86b5ff51f8466634c59c22cd86c56ace5594b74c2e36668f5f40f18ac55278978a59b0cbbc3e66d0ac49b6a6d7fe97a00 SHA512 8be9dbb20061352b482e1e4dd81cbede7cc99c294ccf7f5741b46f68244537cba225ce88e113b76e049ad5db70bfb075a8993fca1d24d99e0296e318b5107435
 DIST pikepdf-2.9.0.tar.gz 2371794 BLAKE2B 7a32542d428d67e1eb940d34ba7efc21bb3002cc573e02de383d7beeb795a0680709c0fdecb933fc7b63a09cc1fb616df9fd514d734f13b6c0ad022c6482c64c SHA512 e1c5ee04946f8c43d20ea1ff857ec463cf8ea531d5d579d0855669401b8dc931bc3ac08be20e3231aafbbc5fc8984608cd8f8aece214ebb7068c21e94981b9a1
+DIST pikepdf-2.9.1.tar.gz 2373727 BLAKE2B ae6b15384c4f01f257a00893c30212281c7ed16dc311e5409355a71db4bef20b64aaab29b52e5b951c6842100fb0cd9bb247d90dcf0a17bac85f788a4c0f7a35 SHA512 e2d87f8b3ce1b78e8153ce79bdbc33f10e85364de912a94f0629f52e654db2c7d911a5d344778c8e632a3037d4151dd4f717e4cc73161e004ac62ea3f07a526c
diff --git a/dev-python/pikepdf/pikepdf-2.9.1.ebuild b/dev-python/pikepdf/pikepdf-2.9.1.ebuild
new file mode 100644
index 000000000000..c1b5454f13e9
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-2.9.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="https://pypi.org/project/pikepdf/ https://github.com/pikepdf/pikepdf"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/v${PV/_p/.post}.tar.gz
+		-> ${MY_P}.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="app-text/qpdf:0="
+RDEPEND="${DEPEND}
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/pybind11[${PYTHON_USEDEP}]"
+BDEPEND="
+	>=dev-python/pybind11-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-4.1[${PYTHON_USEDEP}]
+	dev-python/toml[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm_git_archive[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-5[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5[${PYTHON_USEDEP}]
+		>=dev-python/pytest-6[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.0[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+	)"
+
+#distutils_enable_sphinx docs \
+#	dev-python/ipython \
+#	dev-python/matplotlib \
+#	dev-python/sphinx_rtd_theme
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/wheel/d' setup.py || die
+	sed -i -e '/-n auto/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/pymysql/pymysql-1.0.2.ebuild b/dev-python/pymysql/pymysql-1.0.2.ebuild
index 03ed5d212399..5ffca868ffab 100644
--- a/dev-python/pymysql/pymysql-1.0.2.ebuild
+++ b/dev-python/pymysql/pymysql-1.0.2.ebuild
@@ -41,6 +41,13 @@ src_test() {
 		einfo "USER set to '${USER}'"
 	fi
 
+	local mysql_install_db_cmd="${EPREFIX}/usr/share/mariadb/scripts/mysql_install_db"
+	[[ ! -x "${mysql_install_db_cmd}" ]] && mysql_install_db_cmd="${EPREFIX}/usr/bin/mysql_install_db"
+	[[ ! -x "${mysql_install_db_cmd}" ]] && die "mysql_install_db command not found!"
+
+	local mysqld_cmd="${EPREFIX}/usr/sbin/mysqld"
+	[[ ! -x "${mysqld_cmd}" ]] && die "mysqld command not found!"
+
 	local PIDFILE="${T}/mysqld.pid"
 	if pkill -0 -F "${PIDFILE}" &>/dev/null ; then
 		einfo "Killing already running mysqld process ..."
@@ -54,16 +61,16 @@ src_test() {
 
 	einfo "Creating mysql test instance ..."
 	mkdir -p "${T}"/mysql || die
-	"${BROOT}"/usr/share/mariadb/scripts/mysql_install_db \
+	"${mysql_install_db_cmd}" \
 		--no-defaults \
 		--auth-root-authentication-method=normal \
-		--basedir="${BROOT}/usr" \
+		--basedir="${EPREFIX}/usr" \
 		--datadir="${T}"/mysql 1>"${T}"/mysqld_install.log \
 		|| die
 
 	einfo "Starting mysql test instance ..."
 	# TODO: random port
-	mysqld \
+	"${mysqld_cmd}" \
 		--no-defaults \
 		--character-set-server=utf8 \
 		--bind-address=127.0.0.1 \
diff --git a/dev-python/sphinx/Manifest b/dev-python/sphinx/Manifest
index 11e83c369c0a..9064ee08bc86 100644
--- a/dev-python/sphinx/Manifest
+++ b/dev-python/sphinx/Manifest
@@ -1,2 +1,3 @@
 DIST Sphinx-3.5.1.tar.gz 5905170 BLAKE2B f374a65d66f404b2a7486c58a0e13e228e0de88985fed18cfa74e8219759af6afb1bb05cc10b6a8ed8ad7b413889b7282de7212010fe6d3bd30ce04fe9b59b9a SHA512 31a9253e30d5616c99161455fb61ab3b8298b5364d5eeb5c7b23466182913c99fea4cec14d088b6b64a530cbfb60d691ad093a6f6a0f9060f847f0b73d5e6b3f
 DIST Sphinx-3.5.2.tar.gz 5907358 BLAKE2B 59b2789d7f3cc34622f34c54b5d614be7fa22d9d61cbb6c096ac7efe8f011331f51af12986d505245a30c9583050ae8c012ac736cd8ff5234f528616999dc325 SHA512 97f1589726fe5bdf48b5bc8bfc53267fb4dfa2f21d5d9eefbd9bcc9ff5cc0c7846840b0fe5fcdd133d9735d402189d5b89202de4e462dce99a7653d6f1a86ff9
+DIST Sphinx-3.5.3.tar.gz 5907994 BLAKE2B 3bd5a08dcc860ef419a085a991bb28d16d6a721f253a0ee25333cab5add2257a0557d7b586e89193e9a26e34d39ce5ef9992a9b2c8b8457e8ae7d82a928d32c5 SHA512 4e2cb1c3632ec131cc724f306bbe084691c2178620d1dec130d3bc8be3ee116c14093863ec768242965be9f28c74ed704768b23a62a1510ff00bf1c2edb810df
diff --git a/dev-python/sphinx/sphinx-3.5.3.ebuild b/dev-python/sphinx/sphinx-3.5.3.ebuild
new file mode 100644
index 000000000000..f8651e93cc28
--- /dev/null
+++ b/dev-python/sphinx/sphinx-3.5.3.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python documentation generator"
+HOMEPAGE="https://www.sphinx-doc.org/
+	https://github.com/sphinx-doc/sphinx"
+SRC_URI="mirror://pypi/S/${PN^}/${P^}.tar.gz"
+S=${WORKDIR}/${P^}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="doc latex"
+
+RDEPEND="
+	<dev-python/alabaster-0.8[${PYTHON_USEDEP}]
+	>=dev-python/Babel-1.3[${PYTHON_USEDEP}]
+	>=dev-python/docutils-0.12[${PYTHON_USEDEP}]
+	dev-python/imagesize[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.3[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5.0[${PYTHON_USEDEP}]
+	>=dev-python/snowballstemmer-1.1[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-applehelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-devhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-jsmath[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-htmlhelp[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-serializinghtml[${PYTHON_USEDEP}]
+	dev-python/sphinxcontrib-qthelp[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/typed-ast[${PYTHON_USEDEP}]
+	' python3_7)
+	latex? (
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+BDEPEND="
+	doc? (
+		dev-python/sphinxcontrib-websupport[${PYTHON_USEDEP}]
+		media-gfx/graphviz
+	)
+	test? (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		virtual/imagemagick-tools[jpeg,png,svg]
+		dev-texlive/texlive-fontsextra
+		dev-texlive/texlive-latexextra
+		dev-texlive/texlive-luatex
+		app-text/dvipng
+	)"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.2.1-doc-link.patch"
+)
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# disable internet access
+	sed -i -e 's:^intersphinx_mapping:disabled_&:' \
+		doc/conf.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile
+
+	# Generate the grammar. It will be caught by install somehow.
+	# Note that the tests usually do it for us. However, I don't want
+	# to trust USE=test really running all the tests, especially
+	# with FEATURES=test-fail-continue.
+	pushd "${BUILD_DIR}"/lib >/dev/null || die
+	"${EPYTHON}" -m sphinx.pycode.__init__ || die "Grammar generation failed."
+	popd >/dev/null || die
+}
+
+python_compile_all() {
+	if use doc; then
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	fi
+}
+
+python_test() {
+	mkdir -p "${BUILD_DIR}/sphinx_tempdir" || die
+	local -x SPHINX_TEST_TEMPDIR="${BUILD_DIR}/sphinx_tempdir"
+
+	local deselect=(
+		# these tests require Internet access
+		tests/test_build_latex.py::test_latex_images
+		tests/test_build_linkcheck.py::test_defaults
+		tests/test_build_linkcheck.py::test_defaults_json
+		tests/test_build_linkcheck.py::test_anchors_ignored
+	)
+	[[ ${EPYTHON} == pypy3 ]] && deselect+=(
+		tests/test_ext_autodoc.py::test_autodoc_inherited_members_None
+		tests/test_ext_autodoc.py::test_automethod_for_builtin
+		tests/test_ext_autodoc.py::test_partialfunction
+		tests/test_ext_autodoc.py::test_autodoc_typed_instance_variables
+		tests/test_ext_autodoc.py::test_autodoc_typed_inherited_instance_variables
+		tests/test_ext_autodoc.py::test_cython
+		tests/test_ext_autodoc_autoclass.py::test_show_inheritance_for_subclass_of_generic_type
+		tests/test_ext_autodoc_autodata.py::test_autodata_type_comment
+		tests/test_ext_autodoc_autofunction.py::test_builtin_function
+		tests/test_ext_autodoc_autofunction.py::test_methoddescriptor
+		tests/test_ext_autodoc_configs.py::test_autodoc_typehints_signature
+		tests/test_ext_autodoc_configs.py::test_autodoc_type_aliases
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module
+		tests/test_ext_autosummary.py::test_autosummary_generate_content_for_module_skipped
+		tests/test_pycode_parser.py::test_annotated_assignment_py36
+	)
+
+	epytest ${deselect[@]/#/--deselect }
+}