Adding metadata

23 files changed, 567 insertions, 11 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 75cdd315c014..1142752b4fad 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,3 +2,4 @@ DIST boto3-1.26.133.gh.tar.gz 648114 BLAKE2B 97c71216d92baffb9e07f9c112590a1fc78
 DIST boto3-1.26.137.gh.tar.gz 650777 BLAKE2B e4a7d02ccefbda53b33558dc107457eaa1df0871bb2fc548b348246192cfdd6760bc43a6e6861622de6376244b80a94a387bbb827be2f5b749bccf6b8ff5af58 SHA512 de5d29a4139650f0527e93a9e223b7d41b285b6c263a5bc7ec9ebad1eee19373b1f2093c03414f7b575f8a7402734b4076cfaf0fa5be34ff54b55d8960e9c836
 DIST boto3-1.26.142.gh.tar.gz 655602 BLAKE2B e9d5671308e71bb43a97953407f4aba5b78594ed39b26c3c992af9db8864e3c363ab874a66b5b015083c4a18fe7415bb1761137367783a70ff22564ada8a8842 SHA512 c2eabdb47898aa26fc8ba8a8ebfa43a86153188af1f1600bfa741bd3af1ce68a8692e461aecb5a29df94885e1c977b06c3cd009f1cec52a2e7a9dc853a2c3942
 DIST boto3-1.26.143.gh.tar.gz 656551 BLAKE2B 67ed6469df9ac6f8911d0d59d1f256db424e1302315163fac71b1da94be4b9bd25dfb99c97009523cba56af48eaf32276fba3088b703daf38a40724d8e715183 SHA512 ea982542cf7138368a9223049418859a176065b03ee3919895245c35667773206ce7587b101f7af72d30893c38d05afec28ca72a7d0968bcc209d24c118709d2
+DIST boto3-1.26.144.gh.tar.gz 657264 BLAKE2B 47d9d5fe5d1b134ae2ca0992b8bb2771f85b0bbbafe595ceeaa68d7d7805596e1a7abc9617a02b70da2119cf2d5091d0981ad049b1d38fc8bcbd2be8bff8ef78 SHA512 2622ec60e3b682c09c82905ff52a3b8bc91b6f69085b18b842482597d7defc6f6740dc0969ca1bd69f2e585e35558e33e69fd63401ba0063b414d90c5434688b
diff --git a/dev-python/boto3/boto3-1.26.144.ebuild b/dev-python/boto3/boto3-1.26.144.ebuild
new file mode 100644
index 000000000000..03c610b184f7
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.144.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 5766c5121b1a..3a73d711bd59 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,3 +2,4 @@ DIST botocore-1.29.133.gh.tar.gz 11484789 BLAKE2B ce1acc51ffada796e594090e7b4d73
 DIST botocore-1.29.137.gh.tar.gz 11508178 BLAKE2B 2f74fd2f3923672a4fcd501f1c5ba48cd09965ea0f70689bd6559a4c4a6fe8921f783ef86f28ac57893c8b1366d8fca2fc79f0216747e04142ed33880f07fe39 SHA512 b800a1b73170b5fcbbf1b17477bb8f04b19f5f250a68bbb3b993b0e058d8df870eddf932f79d94eaa3255b976ce136adbdd5b359757cd79f2cfe2a16b3cfa2f4
 DIST botocore-1.29.142.gh.tar.gz 11528069 BLAKE2B 860a5ab68d26424702006b221e62e29cfe21ba93593be61e4ef7e89ab50c6afb4b305f2ef3b2d80fd428cf7791933e43b20e1d4934d330653290a7b2aa16f6c4 SHA512 f408175054095bdd3094dd789de333e4e669cee72fdbc5b03551fc006cbcda5cf69eaa6daa2eb3bf09b30524f50d4b7b334d7b18051e55eca12caa16529b41bf
 DIST botocore-1.29.143.gh.tar.gz 11539133 BLAKE2B f1845154fe406cbc06fdbaa1bf8f48a98b40f267a59b86b9574955da9ad9d01c8eb573327ff1f1e68c06682ab2068328dc3bf8cf3cfe0df277a13afe51c70a50 SHA512 647301c2570f214493a934e0deb516a3b08b1bca34b71dff1a068c67427eaaeb371894f651cfb7152e23a31f91a63af3f25f47c198b5c6b65113eb648ee0b3d6
+DIST botocore-1.29.144.gh.tar.gz 11545575 BLAKE2B cda5a1c91b44218d43a4f06f6f68ae44cad4d1ba0ff4b88a168642bf7f8be7f2a627acba2375c9d8dbc1b5648d71dba4e37a2da5dd9ce8845dd0ee716504ecbf SHA512 ddd3e8dbe334d663012e92c2839f91387751aa7a69b3bdf1331ae25f145700c26e1c62e4b3a8bb913afb38f11d02b5c0da34fdd5d45a97898bcd0b468163a4be
diff --git a/dev-python/botocore/botocore-1.29.144.ebuild b/dev-python/botocore/botocore-1.29.144.ebuild
new file mode 100644
index 000000000000..509d06dedf97
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.144.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+		# urllib3-2 compatibility, mock relies on implementation details
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_no_response_from_server
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_returned
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_continue_sends_307
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_expect_100_sends_connection_header
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_handles_expect_100_with_different_reason_phrase
+		tests/unit/test_awsrequest.py::TestAWSHTTPConnection::test_state_reset_on_connection_close
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/cachecontrol/Manifest b/dev-python/cachecontrol/Manifest
index 50764c5390a3..499975df4480 100644
--- a/dev-python/cachecontrol/Manifest
+++ b/dev-python/cachecontrol/Manifest
@@ -1 +1,2 @@
 DIST cachecontrol-0.12.11.gh.tar.gz 41338 BLAKE2B 09ce2336216b69dbe9796d658db9f5b0d378259484cba3a78ecd789843e19683adc2b1b90d579cea8700d07ed55a93ecc3a56e5da2c8ab025e5084d2847d4dbf SHA512 be1c91f58edda36192f1267a8fdfdc50685ff57da5d84f5348b608982327993333f18f5c318a20cf258b16d2bc83272ba58317e8c4c44a84d5d1f93b522dfc8b
+DIST cachecontrol-0.13.0.gh.tar.gz 43740 BLAKE2B b544d8a662a5850c629f76969fce32651c259fbdf59970c138db6418a2aa3104fe180377cfcee2613abd6d239d75d2878d95090615ff59f590c8a0080e711821 SHA512 271abe40ef66f8227fb604422de215ab99cac283c8464f3fe8eb015ecda6975034c53932565d2f2eab3bdeda94cacd3317798e9e3d1c03a16a11c52a9a0fa451
diff --git a/dev-python/cachecontrol/cachecontrol-0.13.0.ebuild b/dev-python/cachecontrol/cachecontrol-0.13.0.ebuild
new file mode 100644
index 000000000000..74fda2b4431d
--- /dev/null
+++ b/dev-python/cachecontrol/cachecontrol-0.13.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="httplib2 caching for requests"
+HOMEPAGE="
+	https://pypi.org/project/CacheControl/
+	https://github.com/psf/cachecontrol/
+"
+SRC_URI="
+	https://github.com/psf/cachecontrol/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/cherrypy[${PYTHON_USEDEP}]
+		>=dev-python/filelock-3.8.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/httpauth/httpauth-0.3-r1.ebuild b/dev-python/httpauth/httpauth-0.3-r1.ebuild
index ac413140d2e2..0392eafe34ee 100644
--- a/dev-python/httpauth/httpauth-0.3-r1.ebuild
+++ b/dev-python/httpauth/httpauth-0.3-r1.ebuild
@@ -9,7 +9,10 @@ PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
 inherit distutils-r1 pypi
 
 DESCRIPTION="A WSGI middleware that secures routes using HTTP Digest Authentication"
-HOMEPAGE="https://github.com/jonashaag/httpauth/"
+HOMEPAGE="
+	https://github.com/jonashaag/httpauth/
+	https://pypi.org/project/httpauth/
+"
 
 LICENSE="ISC"
 SLOT="0"
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index 1c19eef6a23f..17d814dd1cdd 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -2,3 +2,4 @@ DIST hypothesis-6.75.3.gh.tar.gz 9369491 BLAKE2B bae51e4f280a0773d4101b5b136ad99
 DIST hypothesis-6.75.5.gh.tar.gz 9370565 BLAKE2B e9ef05cfc24a0e5ada5ba863b4ce4c2d4884020cc8f3692c35f3f3d25b0a416e4a2c1b2061ea9bbd105a0f30264ca5d91264e99d6e65e79c909e577756803d78 SHA512 c94b5d40fda5e66a216aee5d8b40ca4df2ebf1549674ee81ad84f2456eb6f67348f468293b693708bb61b2999bc2c31d81b0fec277d39dfe256230320a4de0cb
 DIST hypothesis-6.75.6.gh.tar.gz 9370713 BLAKE2B 93996d6ff0c109c11123ad9b653502c44d51277760338c2575840d6257081bb19b0eedbf2d0feb15e9ebc9e6feacdbe79e070bfd31d35bb9c825bb4a2d44b7f5 SHA512 12396799a7f3fe661f5cb72ccf1a7299919d9f4b05a4075810803350380d217e30312d853ba72e49c28c4f1a08143cb76adc87465ba9cef7400e2dad9cc52001
 DIST hypothesis-6.75.7.gh.tar.gz 9371718 BLAKE2B 9b0c9f4589be2c81fdb79a1157fcf3815dd7f9c11e3c68e14319c10fdb7a534e90e3c1ae042889057bfdb97ae3ffcf9f0360d7fb1b17419309f31b190aa03d9e SHA512 ac4da9e837606f0d98361386e51496f21d9f53ceb0fdd9b3d14eb85456eaa3b4f7cbc7b29754b6b400093fd38b3d3c89ef74be6662f113e0eed87afbf0382ce1
+DIST hypothesis-6.75.9.gh.tar.gz 9372102 BLAKE2B 9588536fade56f4f87f54a0dfd7c911934f08aad71f31785210d99dfb8060bf9719a3bc3e9a0dcd647261a4a1927d5b7cb1cab8135dd9b97ebb321d79a23946e SHA512 29dfd1e9ff1087080a8dcd9c0c25c5e01c79839ac736d20f3eb31b1173b702e31c6b7d777c03f8f5674ec13e9bdc51aab6be8b1d20d067a30508914bcf61e8f1
diff --git a/dev-python/hypothesis/hypothesis-6.75.9.ebuild b/dev-python/hypothesis/hypothesis-6.75.9.ebuild
new file mode 100644
index 000000000000..1e59da18fac0
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.75.9.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( python3_{10..11} )
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 multiprocessing optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/requests-toolbelt-0.10.1
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=() EPYTEST_IGNORE=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+				# TODO
+				hypothesis-python/tests/cover/test_lookup.py::test_resolving_mutually_recursive_types
+				hypothesis-python/tests/cover/test_lookup.py::test_resolving_mutually_recursive_types_with_defaults
+			)
+			;;
+		python3.12)
+			EPYTEST_DESELECT+=(
+				hypothesis-python/tests/cover/test_lookup.py
+				hypothesis-python/tests/cover/test_type_lookup.py
+				hypothesis-python/tests/cover/test_type_lookup_forward_ref.py
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -n "$(makeopts_jobs)" \
+		tests/cover tests/pytest tests/quality
+}
+
+python_install() {
+	distutils-r1_python_install
+	if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..e9da2ac43cac 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index ddb5b0f1787e..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -2,9 +2,11 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
-  <email>cyber+gentoo@sysrq.in</email>
-  <name>Anna</name>
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
  </maintainer>
- 
- <origin>gentoo-guru-overlay</origin>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/leechcorepyc/leechcorepyc-2.14.3.ebuild b/dev-python/leechcorepyc/leechcorepyc-2.14.3.ebuild
index 5dcc7ccc4540..6b2c8380b926 100644
--- a/dev-python/leechcorepyc/leechcorepyc-2.14.3.ebuild
+++ b/dev-python/leechcorepyc/leechcorepyc-2.14.3.ebuild
@@ -13,7 +13,7 @@ HOMEPAGE="https://github.com/ufrisk/LeechCore"
 
 LICENSE="GPL-3"
 SLOT="0"
-KEYWORDS="amd64 ~x86"
+KEYWORDS="amd64 x86"
 
 # leechcorepyc ships with a bundled version of the LeechCore library. So we
 # don't depend on the library here. But we must be aware this module doesn't
diff --git a/dev-python/nbformat/Manifest b/dev-python/nbformat/Manifest
index 373a600c0250..a25fec331cdd 100644
--- a/dev-python/nbformat/Manifest
+++ b/dev-python/nbformat/Manifest
@@ -1 +1,2 @@
 DIST nbformat-5.8.0.tar.gz 140655 BLAKE2B e45b6fcc45fa01ceed49fba0b3a3fd749df6692e355156845cf69fd9d2e176332c61c89b5474ffa89d96da4d4453b668150e96ac266cddd254efdcb1a3b742a1 SHA512 f000db59701eec2fed8adba6c1b521bdfaf942bcd0dba2d8d6d79a7d28b078f4a29df05ca3f393c1651f3ddc6b3690f536928d6fff5937982cc52dd013bc6498
+DIST nbformat-5.9.0.tar.gz 140980 BLAKE2B e967ac0972dd2a5749694900002f9ada4171b5219249c3b6aa600fba97121aae0334516838c86b175064b0975a298fa9a1614dd2a458dd5d66ba832187731bd4 SHA512 c409feb3b6ae9b89b86d1c5e77a23a368776ccf9e62d606e2bb689927eca4d73c79a22e3f5e9e2beda78c201dc7485114e762872b305278c23c8129c7c65449b
diff --git a/dev-python/nbformat/nbformat-5.9.0.ebuild b/dev-python/nbformat/nbformat-5.9.0.ebuild
new file mode 100644
index 000000000000..03cad4511b84
--- /dev/null
+++ b/dev-python/nbformat/nbformat-5.9.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE='sqlite'
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Reference implementation of the Jupyter Notebook format"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/nbformat/
+	https://pypi.org/project/nbformat/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/fastjsonschema[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-2.6[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1[${PYTHON_USEDEP}]
+	dev-python/jupyter-core[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/numpydoc \
+	dev-python/myst-parser \
+	dev-python/pydata-sphinx-theme
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}/nbformat-5.7.1-no-node.patch"
+)
+
+EPYTEST_IGNORE=(
+	# requires pep440 package, which is not really relevant for us
+	tests/test_api.py
+)
diff --git a/dev-python/pockets/pockets-0.9.1-r3.ebuild b/dev-python/pockets/pockets-0.9.1-r3.ebuild
index 886d9ebf0ec8..9cca247c7cb9 100644
--- a/dev-python/pockets/pockets-0.9.1-r3.ebuild
+++ b/dev-python/pockets/pockets-0.9.1-r3.ebuild
@@ -12,7 +12,11 @@ inherit distutils-r1
 COMMIT="777724c8eabaf76f6d0c5e4837c982d110509b2e"
 
 DESCRIPTION="Collection of helpful Python tools"
-HOMEPAGE="https://pockets.readthedocs.io/ https://pypi.org/project/pockets/"
+HOMEPAGE="
+	https://pockets.readthedocs.io/
+	https://github.com/RobRuana/pockets/
+	https://pypi.org/project/pockets/
+"
 SRC_URI="
 	https://github.com/RobRuana/pockets/archive/${COMMIT}.tar.gz
 		-> ${P}.gh.tar.gz
@@ -23,9 +27,13 @@ LICENSE="BSD"
 SLOT="0"
 KEYWORDS="amd64 arm64 ~x86 ~amd64-linux ~x86-linux"
 
-RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+"
 BDEPEND="
-	test? ( dev-python/pytz[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/pytz[${PYTHON_USEDEP}]
+	)
 "
 
 distutils_enable_tests pytest
diff --git a/dev-python/pycryptodome/files/pycryptodome-3.18.0-python3.12-unittest.patch b/dev-python/pycryptodome/files/pycryptodome-3.18.0-python3.12-unittest.patch
new file mode 100644
index 000000000000..6e49a784af16
--- /dev/null
+++ b/dev-python/pycryptodome/files/pycryptodome-3.18.0-python3.12-unittest.patch
@@ -0,0 +1,22 @@
+https://github.com/Legrandin/pycryptodome/pull/746
+
+From 9d70fbca927516b31ef61fd7cc3ed3e0ebc95fa6 Mon Sep 17 00:00:00 2001
+From: Sam James <sam@gentoo.org>
+Date: Thu, 1 Jun 2023 08:03:18 +0100
+Subject: [PATCH] Replace deprecated unittest aliases for Python 3.12
+
+See https://docs.python.org/3.12/whatsnew/3.12.html#removed.
+--- a/lib/Crypto/SelfTest/PublicKey/test_import_ECC.py
++++ b/lib/Crypto/SelfTest/PublicKey/test_import_ECC.py
+@@ -2269,9 +2269,9 @@ def test_import_x509_pem(self):
+     def test_import_openssh_public(self):
+         key_file = load_file("ecc_ed25519_public_openssh.txt")
+         key = ECC._import_openssh_public(key_file)
+-        self.failIf(key.has_private())
++        self.assertFalse(key.has_private())
+         key = ECC.import_key(key_file)
+-        self.failIf(key.has_private())
++        self.assertFalse(key.has_private())
+ 
+     def test_import_openssh_private_clear(self):
+         key_file = load_file("ecc_ed25519_private_openssh.pem")
diff --git a/dev-python/pycryptodome/pycryptodome-3.18.0.ebuild b/dev-python/pycryptodome/pycryptodome-3.18.0.ebuild
index 91d19338100f..cd41dcff7ca5 100644
--- a/dev-python/pycryptodome/pycryptodome-3.18.0.ebuild
+++ b/dev-python/pycryptodome/pycryptodome-3.18.0.ebuild
@@ -26,11 +26,11 @@ SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
 
 DEPEND="
-	dev-libs/gmp:0=
+	dev-libs/gmp:=
 	>=dev-libs/libtomcrypt-1.18.2-r1:=
 "
 BDEPEND="
-	virtual/python-cffi[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/cffi[${PYTHON_USEDEP}]' 'python*')
 "
 RDEPEND="
 	${DEPEND}
@@ -40,6 +40,7 @@ RDEPEND="
 
 PATCHES=(
 	"${FILESDIR}/pycryptodome-3.10.1-system-libtomcrypt.patch"
+	"${FILESDIR}/pycryptodome-3.18.0-python3.12-unittest.patch"
 )
 
 python_prepare_all() {
diff --git a/dev-python/rich/Manifest b/dev-python/rich/Manifest
index 0e1fa3eab21d..2e40119deefb 100644
--- a/dev-python/rich/Manifest
+++ b/dev-python/rich/Manifest
@@ -1 +1,2 @@
 DIST rich-13.3.4.gh.tar.gz 15059899 BLAKE2B f0ca78bf4cdec19136f9372e541ea90713e55acf4dc6f709b8edba9c8dc56da9ac534c6f32b05b634a970e4c02b1f08bfcb5ff949889d6f7bfaa104a1ca6b1cd SHA512 ab3b2ef30ede12f0959671baeff299621303e09750c245b3b3d7b8f1dbd3b7465410400b39668791de57d6027fe24a0a17d5b7284eea162d819c4cb6b9535f81
+DIST rich-13.4.1.gh.tar.gz 15062357 BLAKE2B b5e0067f378910b6a93f0ec40ff47a4ce26298055fba694441962ec2443f9bb76a8ba34ffe43a05abdc077ea8b1d26bbf6294c9d2370baf724045be043c29544 SHA512 655252e9f34da17df6bc7ce74560667f4472da4df6ed699d4302a02301857543ba8756153f48ea8d5a2df5e627ed3c4c8ab732b2b2b27baf66a10c798795a885
diff --git a/dev-python/rich/rich-13.4.1.ebuild b/dev-python/rich/rich-13.4.1.ebuild
new file mode 100644
index 000000000000..6a359e8dde9c
--- /dev/null
+++ b/dev-python/rich/rich-13.4.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for rendering rich text, tables, etc. to the terminal"
+HOMEPAGE="
+	https://github.com/Textualize/rich/
+	https://pypi.org/project/rich/
+"
+SRC_URI="
+	https://github.com/Textualize/rich/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	<dev-python/markdown-it-py-3[${PYTHON_USEDEP}]
+	>=dev-python/markdown-it-py-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.13.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x COLUMNS=80
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_console.py::test_size_can_fall_back_to_std_descriptors
+		tests/test_inspect.py::test_inspect_integer_with_methods_python38_and_python39
+		# pygments?
+		tests/test_syntax.py::test_python_render_simple_indent_guides
+		tests/test_syntax.py::test_python_render_line_range_indent_guides
+	)
+	# version-specific output -- the usual deal
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# pypy3.10, to be more precise
+				tests/test_inspect.py::test_inspect_integer_with_methods_python310only
+			)
+			;;
+		python3.12)
+			EPYTEST_DESELECT+=(
+				tests/test_inspect.py::test_inspect_builtin_function_except_python311
+				tests/test_inspect.py::test_inspect_integer_with_methods_python310only
+				tests/test_inspect.py::test_inspect_integer_with_methods_python311_and_above
+				tests/test_pretty.py::test_attrs_broken
+			)
+			;;
+	esac
+	epytest -p no:pytest-qt
+}
+
+pkg_postinst() {
+	optfeature "integration with HTML widgets for Jupyter" dev-python/ipywidgets
+}
diff --git a/dev-python/ruamel-yaml/Manifest b/dev-python/ruamel-yaml/Manifest
index 5998a842e753..9260adac1fcd 100644
--- a/dev-python/ruamel-yaml/Manifest
+++ b/dev-python/ruamel-yaml/Manifest
@@ -5,3 +5,4 @@ DIST ruamel.yaml-0.17.24.tar.xz 186504 BLAKE2B d5bd5240c3ad68309ad9382dd076111f5
 DIST ruamel.yaml-0.17.26.tar.xz 186752 BLAKE2B ce3d914ac27df2d038a882535f3559b47051a1fb1206a3ab6cab7c2ee0ee9fcfb5fc0babfb3a3488e7d074798bcbdb24d67d2a37a00c9d9210e96f13bb5bcdbb SHA512 40a91002f904621632acaa73b5bd3095f933369d354a8e7579a5afe4c171ceefadb76d5ecbdd3ef6202833874ba19ed518ce5ac5c7dbf15b698dd07b95260d33
 DIST ruamel.yaml-0.17.28.tar.xz 187800 BLAKE2B 24dbf1c3fc76ec2f6255a7771dfa3bae24bf97c7014bd3205dd4968d73bdd9c4fc9e3adf721dba89c50554d13dbdd528f5f67c99692ef15b361119330b35005e SHA512 313bd7e4cfa559f90e150cf5a522b5c690b680b38df24ea3b4320484012b6e4c841f94fd21ca33283dfc0a1d04c465d38d4b5d48f95d2f1f9b876dc371a74f35
 DIST ruamel.yaml-0.17.30.tar.xz 189936 BLAKE2B 9e662551527372b3a1654d8e5da8c1e0a22f432d6564a807fe89bee7f93e2878d47e6a97f50475643575e89eb03564beb86daa7295d14513ff09615d38441f3b SHA512 0e460fa05e69d99591ff4dd1b35ae3be4ba40f21bcf514f16256a56a346b570c7c41a56e1ccf7c1d3ff14beb53800a4f0752243aa20fc37df345509c293d351a
+DIST ruamel.yaml-0.17.31.tar.xz 190068 BLAKE2B cb5682ca184d86f8acb2516f0ce515deb81f3eb1bd9ea0b340c588e738f657076d589424e71492cf8fe37f5a2f62e0c9881644770c23ef1cb8a6d42cae48a86c SHA512 5a453a31babe1b9ad3b782ae06598f5f65d5e6aee167beaf7b898a2b624578245915ef0579bb7f9eefbecee28a472d6f3e04cc721b0c7b320e79f5986225986c
diff --git a/dev-python/ruamel-yaml/ruamel-yaml-0.17.31.ebuild b/dev-python/ruamel-yaml/ruamel-yaml-0.17.31.ebuild
new file mode 100644
index 000000000000..68ab1d975c37
--- /dev/null
+++ b/dev-python/ruamel-yaml/ruamel-yaml-0.17.31.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+MY_P="${P/-/.}"
+DESCRIPTION="YAML parser/emitter that supports roundtrip comment preservation"
+HOMEPAGE="
+	https://pypi.org/project/ruamel.yaml/
+	https://sourceforge.net/projects/ruamel-yaml/
+"
+# PyPI tarballs do not include tests
+SRC_URI="mirror://sourceforge/ruamel-dl-tagged-releases/${MY_P}.tar.xz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	dev-python/ruamel-yaml-clib[${PYTHON_USEDEP}]
+	!dev-python/namespace-ruamel
+"
+BDEPEND="
+	test? (
+		dev-python/ruamel-std-pathlib[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		_test/test_deprecation.py::test_collections_deprecation
+	)
+	local EPYTEST_IGNORE=(
+		# Old PyYAML tests from lib/ require special set-up and are
+		# invoked indirectly via test_z_olddata, tell pytest itself
+		# to leave the subdir alone.
+		_test/lib/
+	)
+
+	# this is needed to keep the tests working while
+	# dev-python/namespace-ruamel is still installed
+	distutils_write_namespace ruamel
+	epytest
+}
diff --git a/dev-python/scikit-build/Manifest b/dev-python/scikit-build/Manifest
index 8c0ef17fe54d..7f517f98de26 100644
--- a/dev-python/scikit-build/Manifest
+++ b/dev-python/scikit-build/Manifest
@@ -1,3 +1,4 @@
 DIST scikit-build-0.16.4.tar.gz 271037 BLAKE2B 6cca8a3c4f4b37228b77ac098650a5eca4ad0f525ca7dcba178f4cffabb7e60e9a7bbba244e64c1a598ab5916f2f47788198eb2a19803d8d0cf7b9792f4e06e2 SHA512 90315ceac4c372e4d7248b4b56b6092362c2c43fbdc180d1a234e057209c508a05d2c6e0a3d0c2587c3adb8957e4c66d5c171a2a2bc3dbf9874a0de58d97d976
 DIST scikit-build-0.16.7.tar.gz 274287 BLAKE2B 8a5064c021d904312ccf89a396ab794b89b73ad1b6238767ca74eeb394f0f1514eedd3c746353ee3e9e7b825988b3c52c563e1f19d0acfbe69213c5a306f1dcc SHA512 5bba94214c249f891b2972301b0e37b5f10938151e37a04b845dfc9e11ae85edc7e3880984f9fbbd1c037257fc8baa3ba7b006b1f1b7abb941d1a54e049f3cbc
 DIST scikit_build-0.17.5.tar.gz 269848 BLAKE2B df1ec6ff3791efeea0ea7b672b7c5d2ad946c9c8d1e8b7035f4036315701ad1b7d61b0917e75ca8c9aff10fe8f25e53b8d1221fa6c3b554225ff8d8f5dec5fd4 SHA512 f0c9a861f9931db36df137d96a9a53d2bfa4a696efc2c1307ff50a00f7df828042d933ef1f670d14d0a339ccf5b94ce99fca7ffbab9169b6e70c47440f4eef06
+DIST scikit_build-0.17.6.tar.gz 272208 BLAKE2B 9e3f908041eca89182f798c54a1a248934dc026816f7cd041a8debc97be27096942dda42a0ae63e87b9337304a478d6f520edcd5ea7a45aae6a195d1f769eed2 SHA512 92b97146f40d8222bd8415ef8439497d5075b72e5bafc40aba0a3e2911d269a118f2f7d41f468f7add8949f550b1fd7d5a9113d249e42dfac431108182ca9198
diff --git a/dev-python/scikit-build/scikit-build-0.17.6.ebuild b/dev-python/scikit-build/scikit-build-0.17.6.ebuild
new file mode 100644
index 000000000000..0f84e9598cc9
--- /dev/null
+++ b/dev-python/scikit-build/scikit-build-0.17.6.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Improved build system generator for Python C/C++/Fortran/Cython extensions"
+HOMEPAGE="
+	https://github.com/scikit-build/scikit-build/
+	https://pypi.org/project/scikit-build/
+"
+
+SLOT="0"
+LICENSE="MIT"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/distro[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-42.0.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	>=dev-python/wheel-0.32.0[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/build-0.7[${PYTHON_USEDEP}]
+		>=dev-python/cython-0.25.1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-1.10.4[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-rtd-theme \
+	dev-python/sphinx-issues
+distutils_enable_tests pytest
+
+src_prepare() {
+	# not packaged
+	sed -i -e '/cmakedomain/d' docs/conf.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest -m "not isolated and not nosetuptoolsscm"
+	rm -r "${BUILD_DIR}/install$(python_get_sitedir)"/{easy-install.pth,*.egg,*.egg-link} || die
+}