Adding metadata

16 files changed, 482 insertions, 0 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 90065c146afd..4fba7201a3b3 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,5 +1,6 @@
 DIST boto3-1.26.100.gh.tar.gz 627269 BLAKE2B 1481e456b73794a4f371e5ac935d3d777c5315c1da39f8565631f62e05bd218e85409d5e5e095057af2c05c4bbcd9c1c5a56b4d1b8d2ef8e97ec567bfdd959a3 SHA512 45fdbb31c7e39ac1775e89755f88d426bdd17be002a13c1c517f2ec4b7ce1fcf0df7d1ff6c6d678fab5a7a1d656f9f609a6d4b3ab779464ea14a3e52eb7e4771
 DIST boto3-1.26.101.gh.tar.gz 627662 BLAKE2B 322a6e723851464409512e9d8dd17b5f2aa9717d97b8fc349c22e95db09bd8b8554631cd3afe52d31e34f4972ae0e5642762bf2ba13e8e5c5d56a05c3013c218 SHA512 7a1b9a089946dcb609a8c446b4c40f4f8861770b6592b6a11992573f7281a8fec0e3ae9d77abee542a88c588dfa23102110312d969f8aa63b3b0ffaf968a8e86
+DIST boto3-1.26.102.gh.tar.gz 627980 BLAKE2B d9dc7d2f62496f2e78427b7fd96f4a210afabb4a4a574a8860767c5bb48e68410cc9f2f2b64aa5e0e5337721d2f59edc7993ee32ea5e1aa5543533d3f1e18d52 SHA512 0988f113a519ffbd6c8a2238dc66a21d4aa87a7dda77d99a4343088b7ea03855f6da12712251502e54cf60ee0bbe066b3fbb30ad7aeb18d67ed9ca96035eb1cf
 DIST boto3-1.26.89.gh.tar.gz 615718 BLAKE2B 3257e6efafaf139daf935385c252c10929be2a4277a8f0f192afc6dbd7cc32fa8f940a4e59ebbe25931c399dedb926a3c1848bd9cc0a7f0d377acb302eabe3b0 SHA512 02ee02b05023e9184f779ab8ff21afa6f7e56f7d2e883d021b2567676c5fc57cad6b475d55316a2017c2a837c41d2f5604824f440060e2f96804c5a61ccdd143
 DIST boto3-1.26.94.gh.tar.gz 617861 BLAKE2B 908b40868735038810cf75c903bbc8bad00a6ea8776b2a5a236683f18f2185971f8a13db5349086b1aef2c4d51361c8ebf30f2d671cea7f4101c9882a59b6acf SHA512 036278668afa33dfdaab9cc2e02c2c3e0596ec1c1b407767f22bc6a4cd87913f883f85430ff6a120c5e0fdd2194b70c911fe7a207bc26ed5fcd415f3754cde35
 DIST boto3-1.26.99.gh.tar.gz 625932 BLAKE2B 961a640995abdafbf2cd73f83ed5af0e1314cebbc5dc154771204e7c16532ad4a84aed08cbd7789af30de518bf2e8bd5204e9a540a2d3a08e75222c2eeb9a68a SHA512 ff726483a83a11a8c088905998af0a1a791e87503b39422811d82b3122275a24eb955636407422af7552908eee22d4c1369779a7798f09f958a8af5234c0c11d
diff --git a/dev-python/boto3/boto3-1.26.102.ebuild b/dev-python/boto3/boto3-1.26.102.ebuild
new file mode 100644
index 000000000000..2a4a7643203e
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.102.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index c1d96c236f18..721ec064f82f 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,5 +1,6 @@
 DIST botocore-1.29.100.gh.tar.gz 11306804 BLAKE2B 8ac9d592d2ea86bd600ca29c51999577e9c223fe951753052fd8d4c9a7d9f537f663491b2f31267e3ab0f082cc3b8ad49064017b268821e6d8c990e88046e144 SHA512 436b2cd40e3f7414b025463e2322fea834c1eae1243070f500dff7682a0dd049123b047a5d8183c58b001e4a793bbc81fa4a96afffff42b2d9f06c554fd261c0
 DIST botocore-1.29.101.gh.tar.gz 11311820 BLAKE2B 51be1b936b407a8d29912f6891c786826fc5a6be9caf386da56b697961613f4fe6506356f3c0b00da07386960abbde7e84c49e22142d1d401e481c8d4747d569 SHA512 1fb519861042b662d1d624223027f7a898d1975a07c6f2ad035547211bb7dad63cb07fcd6061cce75ab641801a7693313aafae7257067358d85fd43abbb82891
+DIST botocore-1.29.102.gh.tar.gz 11312537 BLAKE2B 6e5ac46612a692c72c7b9f3587d651a37422143dfae1fd25e999e255028e82a185dbd51ecf0a5de7d66a1ee715a6296d5d9c1f9474c210286b2df4e84946a3b8 SHA512 c0f0a69f81e1f2e57b3c048bae8e297e488f3e18bd2a443a6a6e56d49b97776c6b0fd7e613353eda3a7ee1f807ed717b639cc5fb685f83708f24de9d432f20fd
 DIST botocore-1.29.89.gh.tar.gz 11227280 BLAKE2B 41a1243972e591ea23fb2eebaa5b5fb9547bbd8ccd72fc907c487fd56ebf90d8120ceee472e34a29cd2b036926bc93bda33b564b1b7083e8984daf366eced1f8 SHA512 356298fd3be39957dd60e6268cfd2652998e62950b9060e0774c68e158506dcfea8188059b588c08f520617af38b91eb6b71c16b92f7a71f75f33cb73e7786cf
 DIST botocore-1.29.94.gh.tar.gz 11242930 BLAKE2B d6abdda0ad69bfa635c2cdccefff5c0feaa27fb1a307d5cacb140ded35c246a52ebbe5657a9317bdc1441939d2bd62d5829b2ecce01c05976f56737f92fc3f62 SHA512 23c1fb835d492f414a0a67ac03e50ea31f6343676c7e6e8649067b11e3213f84eb068562fe5bd9a49ead9e37381ab132ac820d98fa4af805b41eaf53b0f9cb1b
 DIST botocore-1.29.99.gh.tar.gz 11285143 BLAKE2B ba594544fb219cec77659cfa48fb6e3a8241b92c911d9983450648ce97652cad7654181637fed8373fe49e33524f63920128afd4ca9c00bce45603b1ab917648 SHA512 319d70412843149aa43c8d7faeff04122d96091081d30c2da0962fadb27104a24cc147fac2c95492aa407b2f8a25ebed9e7d149c29d5d38134d836581c801bdd
diff --git a/dev-python/botocore/botocore-1.29.102.ebuild b/dev-python/botocore/botocore-1.29.102.ebuild
new file mode 100644
index 000000000000..491b6bbc21f2
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.102.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index 537a2de25d7c..b601d27dda70 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1 +1,2 @@
 DIST plotly.py-5.13.1.gh.tar.gz 30629767 BLAKE2B 818fc888f8bc15b2dc95557363214c69fa3cbba6c973cfde02c1b9a718cdaaa22e03a95e8d5876003bc12bece3460d50216395b94d503516ceed6c836dd1675d SHA512 75b57d212e9c1e277c9136a30e95e2d1d64049fb719c9c97646760b69a2ff61576db0b8e06eed799552e9388bdb9459720030d027d466cb88fec38492b61c79b
+DIST plotly.py-5.14.0.gh.tar.gz 30697515 BLAKE2B 53c17d418cacc7da6783b5ac1b1212a9d2e1cb957a196a398dcdd9185829389592a428ca7b173f4ad78c59171336cbb15efc0b35a46581bc9206fbd2a302b3bc SHA512 c36610d3bb6e0f0f2c25cb06672bbcb16adc83f4203b7ec0a79b18a04e20bed26bcc253d8082e4d4dca63f0253a8c0143e65e006e52f9044be6b526994857d8c
diff --git a/dev-python/plotly/plotly-5.14.0.ebuild b/dev-python/plotly/plotly-5.14.0.ebuild
new file mode 100644
index 000000000000..760cd2ec5a69
--- /dev/null
+++ b/dev-python/plotly/plotly-5.14.0.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1
+
+MY_P=plotly.py-${PV}
+DESCRIPTION="Browser-based graphing library for Python"
+HOMEPAGE="
+	https://plotly.com/python/
+	https://github.com/plotly/plotly.py/
+	https://pypi.org/project/plotly/
+"
+SRC_URI="
+	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/packages/python/plotly"
+# The tests are not included in the PyPI tarball, to use the GitHub tarball
+# we have to skip npm, which means that the resulting install will
+# unfortunately lack the jupyterlab extension.
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/tenacity-6.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		dev-python/jupyter[${PYTHON_USEDEP}]
+		dev-python/jupyterlab[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/shapely[${PYTHON_USEDEP}]
+		dev-python/statsmodels[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+		sci-libs/scikit-image[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.8.0-fix-versioneer-import.patch
+)
+
+EPYTEST_IGNORE=(
+	# Needs porting to newer numpy
+	_plotly_utils/tests/validators/test_integer_validator.py
+
+	# kaleido not packaged
+	plotly/tests/test_optional/test_kaleido
+
+	# plotly-orca not packaged
+	plotly/tests/test_orca
+)
+
+EPYTEST_DESELECT=(
+	# Also needs porting to newer numpy
+	plotly/tests/test_io/test_to_from_plotly_json.py::test_object_numpy_encoding
+
+	# kaleido not packaged
+	plotly/tests/test_orca/test_to_image.py::test_bytesio
+
+	# Fails if not already installed
+	test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
+	test_init/test_lazy_imports.py::test_lazy_imports
+
+	# Minor matplotlib incompatibility
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_path_collection
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
+	plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
+
+	# In python 3.11 the produced error is slightly different
+	plotly/tests/test_core/test_errors/test_dict_path_errors.py::test_described_subscript_error_on_type_error
+)
+
+# There are sphinx docs but we are missing a bunch of dependencies.
+# distutils_enable_sphinx ../../../doc/apidoc
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# Do not try to fetch stuff with npm
+	export SKIP_NPM=1
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	mv "${ED}"/{usr/etc,etc} || die
+}
diff --git a/dev-python/pychromecast/Manifest b/dev-python/pychromecast/Manifest
index 3be18cab9f9e..2b2a3fdba898 100644
--- a/dev-python/pychromecast/Manifest
+++ b/dev-python/pychromecast/Manifest
@@ -1 +1,2 @@
 DIST PyChromecast-13.0.4.tar.gz 51996 BLAKE2B 11dad948443e9e5957de6b22cf6c1d33d19030d53cecddd9be5595dc82bb108e4746c382bae5c6d22d5219bcb90ed5bed7ca94c714ec7bbe7ad1330a1ee3cf2f SHA512 2f9bd925e452448a387a04babc0d71a35fc83edd30142cdd129479b5b20cf7aa9691a8d46f45edf5f12fd6f3052564c2956dd241eaf1a1c468b8399b065286ec
+DIST PyChromecast-13.0.6.tar.gz 52068 BLAKE2B f1ac2885106221f9dc2b4ec78b33a5664458e08b8b63588183ecc6a6365fa5baeedda86cbc803dbcc5ce5b7c9b1f0323309ef6cebb3a0a5c7326dc970967176d SHA512 9ab70b1c47b1bb67b9d6d95395c8cb0bff9920e0ac371133d7121f86ad4f392b97009b502a05c19f4d169f28c09b8f7e391c6b6c0be6fffd8015753eb1df47de
diff --git a/dev-python/pychromecast/pychromecast-13.0.6.ebuild b/dev-python/pychromecast/pychromecast-13.0.6.ebuild
new file mode 100644
index 000000000000..ba21201d1914
--- /dev/null
+++ b/dev-python/pychromecast/pychromecast-13.0.6.ebuild
@@ -0,0 +1,27 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=PyChromecast
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python module to talk to Google Chromecast"
+HOMEPAGE="
+	https://github.com/home-assistant-libs/pychromecast/
+	https://pypi.org/project/PyChromecast/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/casttube-0.2.0[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.19.1[${PYTHON_USEDEP}]
+	>=dev-python/zeroconf-0.25.1[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/pydata-sphinx-theme/Manifest b/dev-python/pydata-sphinx-theme/Manifest
index 7ba5d62b2c3c..bbe1038cf224 100644
--- a/dev-python/pydata-sphinx-theme/Manifest
+++ b/dev-python/pydata-sphinx-theme/Manifest
@@ -1,3 +1,5 @@
 DIST pydata-sphinx-theme-0.13.1.gh.tar.gz 3391663 BLAKE2B 411b3dfb81b84189da86b0d11bf983348ecc6cef25142616f997f6301bc7873360835ba87309c055df46800ba34c30cf0d82bc3fb2c1984214d0c3e02556d17b SHA512 c88db817891800ee3483f724770354ab8c02abb0e430537ecd29b2e4b566fbdccb0a461926858a20da2da98dff37c6f09fa3f29dc538ecc30abd87597a9c08c2
+DIST pydata-sphinx-theme-0.13.2.gh.tar.gz 3367549 BLAKE2B 29a219b865c3c8f9c7ab8acba50ded75585c240cb120d8cb21234fdb6c1126f6ddadc1582de5aeaf253a7ec7126a9395cc12dbead5f7b0c54a5727634d965aa2 SHA512 e26a8ed2791489f23df774e024bc04e2600b70228bf0db1cc69edd1fb4f615425e8e1f06ea849516fd7601bea23caecad3641a4547c78cd9b7e808a61aa79008
 DIST pydata-sphinx-theme-0.7.2.gh.tar.gz 2632129 BLAKE2B 2beb9fac60b5f6c863ee4c570b88c4331135d2c8a10d84599f97944002576424caae06d062104a58c7f329f85e046eaa820d03a4117396009084707d563608d7 SHA512 2f6cac080807eab04f1c4de2fdd1563de17f1214f79c094f69b5ff116bcc47f1b0e159d6c87412c8cbe7691b19eebb3b228ca8243d05c81bba94d0aacbdb3e5e
 DIST pydata_sphinx_theme-0.13.1-py3-none-any.whl 1624783 BLAKE2B 9ff997244b12320dccbec56866af4cf780a5341a5d75b7040de3623d15a2593561a6506f31be769b63bb72905e1e428e9fe0955988b2919732bdfe1dfba68062 SHA512 1f31d59b0041aa6302ea3d6a03d089adb7108e334813f2ceb576b04b5767a96ef4b3d6d3d3f4bc40c399932b193575a21f418dba2a1737a14ba90deead951457
+DIST pydata_sphinx_theme-0.13.2-py3-none-any.whl 1976897 BLAKE2B 3934bdee8210e3c384a284f402627a9d6716c3664a613a7de8ba3e05d143551d2fadbbce3929b837ce1af96019887fbc56d84129b75bb01922562f011dccee04 SHA512 9daed721a90411453cc150e80472fae592a477ce58dc815e60475c579ab62453953c300587cbd1fb8c830ad986cc49f3278f2d781c44a8c35463c1cd2e09bd0e
diff --git a/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.13.2.ebuild b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.13.2.ebuild
new file mode 100644
index 000000000000..811b919ee08d
--- /dev/null
+++ b/dev-python/pydata-sphinx-theme/pydata-sphinx-theme-0.13.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Bootstrap-based Sphinx theme from the PyData community"
+HOMEPAGE="
+	https://github.com/pydata/pydata-sphinx-theme/
+	https://pypi.org/project/pydata-sphinx-theme/
+"
+SRC_URI="
+	https://github.com/pydata/pydata-sphinx-theme/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	$(pypi_wheel_url)
+"
+
+LICENSE="BSD-with-disclosure"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/accessible-pygments[${PYTHON_USEDEP}]
+	dev-python/Babel[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-4.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-regressions[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	distutils_wheel_install "${BUILD_DIR}/install" \
+		"${DISTDIR}/$(pypi_wheel_name)"
+}
diff --git a/dev-python/pydyf/Manifest b/dev-python/pydyf/Manifest
index a9486f31a3ea..ddaa6b2b1b40 100644
--- a/dev-python/pydyf/Manifest
+++ b/dev-python/pydyf/Manifest
@@ -1 +1,2 @@
 DIST pydyf-0.5.0.gh.tar.gz 14949 BLAKE2B 07669872135568781b9976bf3fb027784e6a5fee5cddb76c719ca3be7cf20d2ad3416435e1ca9ae2eca097ffdcd8ffc0596e5961e128cb8ce75519de9496e89c SHA512 aeef3b90853b7fd9c157d558185c66887dc227950f087248f53860da43830eb488154b80059ccb7d8f61192111028a129442c185b99f88acf8c9417ebdc873a3
+DIST pydyf-0.6.0.tar.gz 16027 BLAKE2B 8dcbcb0cdd6f27aae53d74c1f60646bda17b05862d3fcdfdf18d459fd0f419f9418488bddf210f29cca945adba3670b41d67d958ebff031934db57ab954ab554 SHA512 2819aab7b9e72abd02b8658923b595fe0775f341a829b732e1448c02a4aeb8538a7eb5d42307499e255e240c00f8a991687f42122348bcc39e6660c8c27e4f85
diff --git a/dev-python/pydyf/pydyf-0.6.0.ebuild b/dev-python/pydyf/pydyf-0.6.0.ebuild
new file mode 100644
index 000000000000..caa52fdde90e
--- /dev/null
+++ b/dev-python/pydyf/pydyf-0.6.0.ebuild
@@ -0,0 +1,28 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A low-level PDF generator"
+HOMEPAGE="
+	https://pypi.org/project/pydyf/
+	https://github.com/CourtBouillon/pydyf/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	test? (
+		app-text/ghostscript-gpl
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/redis/Manifest b/dev-python/redis/Manifest
index b3d110fc3dbe..79951c957926 100644
--- a/dev-python/redis/Manifest
+++ b/dev-python/redis/Manifest
@@ -1,3 +1,4 @@
 DIST redis-py-4.5.1.gh.tar.gz 4737828 BLAKE2B ce4f44c32e0c0bf050c868725e41b037dc9c8bc1915f83994db5196a44fc618acfb9670e61e640c4c756c9e66794a96f9d4d140c58fccc06b181dce040275377 SHA512 bbee0aee1568a95a591c9083a901c2f47dfb5c9cfa9186b4a47a6575691cd7634d2c461fad84c54fc6df53a83029d1facd19e7c59cafa4331254ef8f04967cb6
 DIST redis-py-4.5.2.gh.tar.gz 4738198 BLAKE2B d3b566bee468c46536811580c21a66b94b157079858502edd2f2359944b1029e56370b5763ba27b55f446cb6eef45c99e0132547d02b4dcb63a0d910c7c477ad SHA512 6f4a30051749b31a0fcde1e61996fb9a92e71094a8f3dabeaef8aa1794431e59be8c67f337f6476b73eaca78ab14edd6e2c4de4621b9311f9124e70c68c1eec1
 DIST redis-py-4.5.3.gh.tar.gz 4740507 BLAKE2B 82fe7ac66bbae1100d3ea65142d7cda98493121fb6631f5e865e1611e7facc6186246b1cbd54f548abc869f1d47f6ec8b580e383944bf5711d5fc06493605f6f SHA512 2d09c01d8651f39dd12608748a13fe9f78f63d99cd46ea914ceeae104ae3629181d0a768a1484f77d17820ea0a076c2bcc936a43ce20379d2d2d254d09146464
+DIST redis-py-4.5.4.gh.tar.gz 4739418 BLAKE2B a02a581dc12a09cedd0f5158bc261ffb0efcf0346d193ebcb060f50fa95dbaadb7322446c242ac68094bbfbd80c9879d8c9a9fc8362aa6a6e9be85d7e46d9aaa SHA512 55c4530ab715c4bddb502ce58ae3c62db9c27d16ddbfa8f87c88e9425e0285d9fd570338428c30d0a3f1fe2d81868fd8385da0255d58c3dd9b9813f9454eeb30
diff --git a/dev-python/redis/redis-4.5.4.ebuild b/dev-python/redis/redis-4.5.4.ebuild
new file mode 100644
index 000000000000..a2bd31a2e7f5
--- /dev/null
+++ b/dev-python/redis/redis-4.5.4.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+MY_P=redis-py-${PV}
+DESCRIPTION="Python client for Redis key-value store"
+HOMEPAGE="
+	https://github.com/redis/redis-py/
+	https://pypi.org/project/redis/
+"
+SRC_URI="
+	https://github.com/redis/redis-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-4.0.2[${PYTHON_USEDEP}]
+	' 3.{9..10})
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Flaky test
+		tests/test_pubsub.py::TestPubSubDeadlock::test_pubsub_deadlock
+		# TODO
+		tests/test_commands.py::TestRedisCommands::test_acl_list
+		# redis-7 different return
+		tests/test_commands.py::TestRedisCommands::test_xautoclaim
+	)
+
+	# TODO: try to run more servers?
+	epytest -m "not redismod and not onlycluster and not replica and not ssl"
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	if has_version ">=dev-db/redis-7"; then
+		local extra_conf="
+			enable-debug-command yes
+			enable-module-command yes
+		"
+	fi
+
+	# Spawn Redis itself for testing purposes
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF || die "Unable to start redis server"
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1 ::1
+		${extra_conf}
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
diff --git a/dev-python/zope-deprecation/Manifest b/dev-python/zope-deprecation/Manifest
index 2a4b6b01e909..0ab62602dff8 100644
--- a/dev-python/zope-deprecation/Manifest
+++ b/dev-python/zope-deprecation/Manifest
@@ -1 +1,2 @@
 DIST zope.deprecation-4.4.0.tar.gz 24737 BLAKE2B 993959f47e7808ad9d024d5df9d141cdbce3a1a3c281acc0d90bdb20747743936411714b52a29fcac6968cea50d5ab54820954f74c3f59081ce98f097715b9a3 SHA512 62371dc45fad6715f24cdcac1d25b559ed5248da774b5ecd215fb4d0b6fc0ab655bfb9e0fbceda964e8ffb7d70536e43f8fcf09d9f2742904717a6473869fa4a
+DIST zope.deprecation-5.0.tar.gz 23353 BLAKE2B 9b98291fe252942a8235c70c0a13bfbaf2cb3091e1502099f8a0651b517e748645cbda957f92c790c4d4f2b6ed7324cd5e21bae9d2906f2943e507376a980d76 SHA512 11313626e4141c2f92805c7c533b32160f88bf45667cd5a53a867daad3172947e5ac80433893c515243276030400a8a8e3d3a623ea51cb2b15bd5a5a0927bc46
diff --git a/dev-python/zope-deprecation/zope-deprecation-5.0.ebuild b/dev-python/zope-deprecation/zope-deprecation-5.0.ebuild
new file mode 100644
index 000000000000..762cbc587576
--- /dev/null
+++ b/dev-python/zope-deprecation/zope-deprecation-5.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Zope Deprecation Infrastructure"
+HOMEPAGE="
+	https://pypi.org/project/zope.deprecation/
+	https://github.com/zopefoundation/zope.deprecation/
+"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	!dev-python/namespace-zope
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "s:'setuptools',::" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}