Adding metadata

38 files changed, 1022 insertions, 54 deletions

diff --git a/dev-python/absl-py/Manifest b/dev-python/absl-py/Manifest
index 8f1f7c9f5e40..051aa1598aed 100644
--- a/dev-python/absl-py/Manifest
+++ b/dev-python/absl-py/Manifest
@@ -1 +1,2 @@
 DIST abseil-py-2.0.0.gh.tar.gz 232404 BLAKE2B fc3d02b2184f6ad45ff022d80068f6ec64ec4cbdbfb9735da1309a975f634880a2c969cba9ad7bdbeec2183c058c31e8198f9396d5f937858861e42a41c40432 SHA512 1f83ee07ce4bdeed2ebc775bdf809a9998f7afba2e0322bb4ce1fbf4af8c0e638161bbd72c9222c1ae1505577c181026d5baee1c9994d4858166d015a1ffab91
+DIST abseil-py-2.1.0.gh.tar.gz 235261 BLAKE2B 85232156e722cb874e29e1f92513b24836553476d5ff379e8df32d307ca21709b5869edd80a3bb7fe757ae585bb45df21c89ae6f2218147a5812f171d946e094 SHA512 298a876ed850085836cb1ff6fddf98aca6a3283780bece8c0a7d118fd4e16cc258e51f721e4a5fcbe62b23d2da05638475d426bb650b0694ff7c1d0119e3be97
diff --git a/dev-python/absl-py/absl-py-2.1.0.ebuild b/dev-python/absl-py/absl-py-2.1.0.ebuild
new file mode 100644
index 000000000000..2b059e1ca9cb
--- /dev/null
+++ b/dev-python/absl-py/absl-py-2.1.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+MY_P=abseil-py-${PV}
+DESCRIPTION="Abseil Python Common Libraries"
+HOMEPAGE="
+	https://github.com/abseil/abseil-py/
+	https://pypi.org/project/absl-py/
+"
+SRC_URI="
+	https://github.com/abseil/abseil-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+src_prepare() {
+	# what a nightmare... well, we could have called bazel but that would
+	# even worse
+	local helpers=(
+		absl/flags/tests/argparse_flags_test_helper.py:absl/flags/tests/argparse_flags_test_helper
+		absl/logging/tests/logging_functional_test_helper.py:absl/logging/tests/logging_functional_test_helper
+		absl/testing/tests/absltest_fail_fast_test_helper.py:absl/testing/tests/absltest_fail_fast_test_helper
+		absl/testing/tests/absltest_filtering_test_helper.py:absl/testing/tests/absltest_filtering_test_helper
+		absl/testing/tests/absltest_randomization_testcase.py:absl/testing/tests/absltest_randomization_testcase
+		absl/testing/tests/absltest_sharding_test_helper.py:absl/testing/tests/absltest_sharding_test_helper
+		absl/testing/tests/absltest_sharding_test_helper_no_tests.py:absl/testing/tests/absltest_sharding_test_helper_no_tests
+		absl/testing/tests/absltest_test_helper.py:absl/testing/tests/absltest_test_helper
+		absl/testing/tests/absltest_test_helper_skipped.py:absl/testing/tests/absltest_test_helper_skipped
+		absl/testing/tests/xml_reporter_helper_test.py:absl/testing/tests/xml_reporter_helper_test
+		absl/tests/app_test_helper.py:absl/tests/app_test_helper_pure_python
+	)
+
+	local x
+	for x in "${helpers[@]}"; do
+		local script=${x%:*}
+		local sym=${x#*:}
+		sed -i -e "1i#!/usr/bin/env python" "${script}" || die
+		chmod +x "${script}" || die
+		ln -s "${script##*/}" "${sym}" || die
+	done
+
+	# i don't wanna know how these pass for upstream with wrong helper names
+	sed -i -e 's:\(app_test_helper\)\.py:\1_pure_python:' \
+		absl/tests/app_test.py || die
+	sed -i -e 's:\(logging_functional_test_helper\)\.py:\1:' \
+		absl/logging/tests/logging_functional_test.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTHONPATH=.
+	local fails=0
+	while read -r -d '' x; do
+		ebegin "${x}"
+		"${EPYTHON}" "${x}"
+		eend ${?} || : "$(( fails += 1 ))"
+	done < <(find -name '*_test.py' -print0)
+
+	[[ ${fails} -ne 0 ]] && die "${fails} tests failed on ${EPYTHON}"
+
+	# we actually need to clean this up manually before running the test
+	# suite again...
+	chmod -R u+rwX "${T}"/absl_testing || die
+	rm -rf "${T}"/absl_testing || die
+}
diff --git a/dev-python/aspectlib/Manifest b/dev-python/aspectlib/Manifest
index 72263fdfd647..7406c0e71953 100644
--- a/dev-python/aspectlib/Manifest
+++ b/dev-python/aspectlib/Manifest
@@ -1 +1,2 @@
 DIST aspectlib-2.0.0.gh.tar.gz 149206 BLAKE2B 79a9cdd6090181e28bb9f46b5dc71b5a49c6fe356f0d4687886df2b6d83867a8a8bd51e43506da09b78e3ae637a1f1257888656fd2ecb0f583986424f89d3d14 SHA512 455ae7bb7808158abc79814632cd108397bfffc4d6c5e0f8a041ca03ed0f0fc2022d0929ad3a29e9015d8b3e3b02afa071c9b28fc62845eac4f6ef8c3fa2d9b2
+DIST aspectlib-2.0.0.tar.gz 156591 BLAKE2B b3800164e25e4414fe502fc62efcce163070d743cd1f4ebc6f95a51123895cf0ce72f1df5088a580a345f48b2dd03cf30340b4a7b27c0cf6ecab614e6e79da38 SHA512 3611d3f887febae8a60df6ad5567437adaa2105e6622a7d9b543c02f593c9dee43002cd91b89f5d005fc70a8b197b5c568eefa3a0fdb6fc05665f4a1c5107316
diff --git a/dev-python/aspectlib/aspectlib-2.0.0-r1.ebuild b/dev-python/aspectlib/aspectlib-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..f832a90a8b7a
--- /dev/null
+++ b/dev-python/aspectlib/aspectlib-2.0.0-r1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="Aspect-oriented programming, monkey-patch and decorators library"
+HOMEPAGE="
+	https://github.com/ionelmc/python-aspectlib
+	https://pypi.org/project/aspectlib/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="dev-python/fields[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/process-tests[${PYTHON_USEDEP}]
+		dev-python/tornado[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-py3doc-enhanced-theme
+
+EEPYTEST_DESELECT=(
+	# fails because error message text is slightly different
+	tests/test_aspectlib_test.py::test_story_empty_play_proxy_class
+	tests/test_aspectlib_test.py::test_story_half_play_proxy_class
+)
diff --git a/dev-python/asyncpg/Manifest b/dev-python/asyncpg/Manifest
index af055e2fe2a2..057e9f59e011 100644
--- a/dev-python/asyncpg/Manifest
+++ b/dev-python/asyncpg/Manifest
@@ -1,2 +1,2 @@
-DIST asyncpg-0.26.0.tar.gz 809997 BLAKE2B 360dfadcd729ade63c156e3a16def7f652dbc4d0c76189ac88e01fa814f9a3ab4f1bd2852658a93e22a8e275fb1a4e69df2e3c30f457110291f0641ac6d12d8d SHA512 ef92316fd430a1819aa8170abd67ecfc1cf29c42cb6dc06cf5047cdd71d4abf441c8b86bacafaaa8c0c0fd7c66daa275e9ed68b00e5166bb27929f25cab1dcbd
 DIST asyncpg-0.27.0.tar.gz 808881 BLAKE2B e4fe88346a3fb4d9b6ce74a4e12db333f1aefd8844d6b08091a1e507a56754bb74dcbdd1b43329f1df24725f03c808a1862c8c4587c9ec95c4800f30ab78458c SHA512 66d4e16cba8ebebfa0403c7d3b1d3ee1b9b8f55a9b70f57e809d28161873d74750152e6ed548b17ceb97ca84f7a669a5fa503c824a861b295db731f86bfb0137
+DIST asyncpg-0.29.0.tar.gz 820455 BLAKE2B 9bb5606dfb103e066dcfd15c327fe8a8135bf4433c816dc354d84227e40b9f18bb2788ead0dd25b087f97b3113645b6dcfd8991a7bb6e2e71528d122c41105d5 SHA512 5db979496323fcf4068d5de111b52f2ae1ad9efe68f80c28e6303ad936eb051d1792409f1e31fb86dc35caad5ef9b92c40e4f6dcbcccc3907ab2247f61db5504
diff --git a/dev-python/asyncpg/asyncpg-0.26.0.ebuild b/dev-python/asyncpg/asyncpg-0.26.0.ebuild
deleted file mode 100644
index 14aa0787bd21..000000000000
--- a/dev-python/asyncpg/asyncpg-0.26.0.ebuild
+++ /dev/null
@@ -1,33 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )  # doesn't build with pypy3
-DISTUTILS_USE_PEP517=setuptools
-inherit distutils-r1 pypi
-
-DESCRIPTION="A fast PostgreSQL Database Client Library for Python/asyncio"
-HOMEPAGE="https://github.com/MagicStack/asyncpg"
-
-LICENSE="Apache-2.0"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-BDEPEND="
-	dev-python/cython[${PYTHON_USEDEP}]
-	test? (
-		dev-db/postgresql
-		dev-python/flake8[${PYTHON_USEDEP}]
-		dev-python/uvloop[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests unittest
-
-distutils_enable_sphinx docs dev-python/sphinxcontrib-asyncio dev-python/sphinx-rtd-theme
-
-python_test() {
-	cd "${T}" || die
-	USE_UVLOOP=1 eunittest "${S}"/tests
-}
diff --git a/dev-python/asyncpg/asyncpg-0.29.0.ebuild b/dev-python/asyncpg/asyncpg-0.29.0.ebuild
new file mode 100644
index 000000000000..05357485fc84
--- /dev/null
+++ b/dev-python/asyncpg/asyncpg-0.29.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )  # doesn't build with pypy3
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="PostgreSQL driver for asyncio"
+HOMEPAGE="
+	https://pypi.org/project/asyncpg/
+	https://github.com/MagicStack/asyncpg
+"
+
+LICENSE="Apache-2.0 PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-4.0.3[${PYTHON_USEDEP}]
+	' python3_{10..11})
+"
+BDEPEND="
+	<dev-python/cython-3[${PYTHON_USEDEP}]
+	test? (
+		dev-db/postgresql[server]
+		dev-python/uvloop[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# checks versions from env variables
+	"${S}"/tests/test__environment.py
+	# runs flake8 (???)
+	"${S}"/tests/test__sourcecode.py
+)
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx docs \
+	dev-python/sphinxcontrib-asyncio \
+	dev-python/sphinx-rtd-theme
+
+src_prepare() {
+	# remove pre-generated Cython sources
+	rm asyncpg/{pgproto/pgproto,protocol/protocol}.c || die
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	use debug && \
+		export ASYNCPG_DEBUG=1
+
+	distutils-r1_src_configure
+}
+
+python_test() {
+	cd "${T}" || die
+	for opt in "" "1"; do
+		einfo "  testing with USE_UVLOOP='${opt}'"
+		USE_UVLOOP="${opt}" epytest "${S}"/tests
+	done
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 4a84f72345b4..0f7b8905d45c 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,3 +2,4 @@ DIST boto3-1.34.11.gh.tar.gz 760539 BLAKE2B 8ce756d33b604aed9d42bcccf60be467bd51
 DIST boto3-1.34.14.gh.tar.gz 762792 BLAKE2B 87857a6ff7e19f8438fe6b57978cdb3c8d22f8a68008fad4fcfdd40358b919a1c45f810bc45637da5971d20ce221cd8343440663d072666349e32c4df2be97a2 SHA512 8b651c5946394e159d6dd719337e4a5a60f708fa22ef26026bd85a18b3f34efa06f71282b9e9ea8c8ad4995e4bd6d0c13e4dddac75a51922fc30154ac0b87ecb
 DIST boto3-1.34.18.gh.tar.gz 765458 BLAKE2B 29414e20fa034f63c899b6f2d5460d8973dd617aa97adbe1940daaf3f4a08cf9286bf24709fe9bcd745fdec8415578a87033f99cfd1335baa8ecf29f1723074d SHA512 aa5dc9363d3f04f49a40ea352ab75a30b52e9b1aa1153ab4ed9d6bef6059ea6cb0cb04301158f0e857d9abd19c670db447dda6cd9d8898d6c71c0b69242775fc
 DIST boto3-1.34.19.gh.tar.gz 764452 BLAKE2B c0388452728e54cdded0a9944e37e6725e8150b242c8e91ce812aed29a1316ce59e880d5e466e956d9c3dafcea99996801d90a1bfdef2b4eed9852f6dd861f0b SHA512 bad2a283c7c829f1de661c19058b963bfe2dca5e71513729f6099a4102d130a48e5095e44877d29e73308c8104f667229ba402503d4eba287ae975f4cef18c29
+DIST boto3-1.34.20.gh.tar.gz 766685 BLAKE2B e68cb60bdbec6ccd4e5ec1c1ae116c0cdb952862902c5e38788ea735083f515a89923b7056f862cffdd40bd967ca717a2387537f1e17bb0f76a9bf49ecb39fc8 SHA512 a2c8bc7f09571f27c45595c15794a8125a23317a785d7e8ea296455b2f63e8375fd818906bf28c6788ff65dd6d40a2abd28aaf8ef4a22fe80a56d01c6464585b
diff --git a/dev-python/boto3/boto3-1.34.20.ebuild b/dev-python/boto3/boto3-1.34.20.ebuild
new file mode 100644
index 000000000000..13391b8a8e76
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.20.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 82eb713a00fc..b6c28e68c823 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,3 +2,4 @@ DIST botocore-1.34.11.gh.tar.gz 12612317 BLAKE2B 8a8648dfb27fad0d0a52df37ce9d988
 DIST botocore-1.34.14.gh.tar.gz 12617340 BLAKE2B c4aac6682ccb8951f4652477857d58221c4f0d8f1d154b7ecfa4e536f6bdb199e4be43ef63f0fce0843e95c01cfc0a479af8c7773a9717461afc04cd4bb27912 SHA512 44b7b0e96c815b033dc603892c3940869a37c76d0826812d5778b644ca785ff27f870f3ec54c7d87696bd57d2a38cc31c4b3e70f295fe9d588afc12e8f7a914e
 DIST botocore-1.34.18.gh.tar.gz 12634296 BLAKE2B c3f18b042ea56c65f66b578f5b010613e34d4ca7a203cdbd479ef781fbebf3876b40623468e0fbbf7721f9a3e7ad82e71d1771bb24c721e3bc450acaff1f296a SHA512 bd0ace3da7e45edf98a13b1616b0699b0a2e2c3aec1e59dc7f8c11a3817fb1aefc8aae5634abcbf24f242c155df24ba93348f55fd6cb588abf129010b28f351e
 DIST botocore-1.34.19.gh.tar.gz 12634480 BLAKE2B 839124ae13bd87697bd9d2c4d62f3171244cbd9b3c1cf96ffbf2b536d9c1432a37c5cdaa6311da327e13caf0e4739bc4cf0543a26f7f3911ab41c022c54d9106 SHA512 4db43c898f93494d69e1bf33f64c7687cf4b6f43580b0a03bbe93986e4ff09c97b57365ffd4992860dc36dd43b797c5501837db1036fefdbc84a9b94d97e920f
+DIST botocore-1.34.20.gh.tar.gz 12636646 BLAKE2B 3389ad9e44b529093c26dd7cb48c64b2551237a82218dbc57e4fbe85ae8b97e07f3eb88946fa5108e2d045e58c1e46402e697992b1adfab373eae223f510f1db SHA512 1956b4c090b60e7176ed67f4b80c25305816cb4f22f41a57308daa0748a54720ebc10cd1f620484bbf7d4df6e05259553ef5e1471141db2b1f0192bc2b6219c2
diff --git a/dev-python/botocore/botocore-1.34.20.ebuild b/dev-python/botocore/botocore-1.34.20.ebuild
new file mode 100644
index 000000000000..2fc3a4924fdb
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.20.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x EPYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/griffe/Manifest b/dev-python/griffe/Manifest
index 23e54045832e..475fc049d167 100644
--- a/dev-python/griffe/Manifest
+++ b/dev-python/griffe/Manifest
@@ -1 +1,2 @@
 DIST griffe-0.38.1.gh.tar.gz 201135 BLAKE2B cdd1b7a24bb1afa6cdf68cffa696b8a19886d03b97ab6eb821fc9db150b1cd9d2e64de65f55c78f64663448e4b268c12b7d95c512e2dac3418489f0b0ef2f9c3 SHA512 74dd48d687edd399ac5da10454e68d9b226ad1b0418d9df583c364f65f5922cc29e109f1fafb3914a73a7217720f2305a4949324736a693f0065b8cae1f591d1
+DIST griffe-0.39.0.gh.tar.gz 214713 BLAKE2B e27015592ffc1a817c6236ae7a242f4968ba7ad2c649541bad9c6c31ba0459df4d7122382a6a776117bf80afb563f50a736d3d6851fcceed3113ac8372af0969 SHA512 b872c929f5dd32d7c63f3f199755c8b1e4b9bae05b21b3c4a477f3ba94ca24170907faf0d4e878b43403f448f6d067300d80e612633d801f993f5e13187f572f
diff --git a/dev-python/griffe/griffe-0.39.0.ebuild b/dev-python/griffe/griffe-0.39.0.ebuild
new file mode 100644
index 000000000000..6b674e3230b3
--- /dev/null
+++ b/dev-python/griffe/griffe-0.39.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Signature generator for Python programs"
+HOMEPAGE="
+	https://mkdocstrings.github.io/griffe/
+	https://github.com/mkdocstrings/griffe/
+	https://pypi.org/project/griffe/
+"
+# Tests need files absent from the PyPI tarballs
+SRC_URI="
+	https://github.com/mkdocstrings/griffe/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv"
+
+RDEPEND="
+	>=dev-python/colorama-0.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/jsonschema-4.17[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-2.4[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export PDM_BUILD_SCM_VERSION=${PV}
+
+EPYTEST_DESELECT=(
+	# fragile to installed packages
+	# (failed on PySide2 for me)
+	tests/test_stdlib.py::test_fuzzing_on_stdlib
+)
diff --git a/dev-python/hatch-jupyter-builder/hatch-jupyter-builder-0.8.3.ebuild b/dev-python/hatch-jupyter-builder/hatch-jupyter-builder-0.8.3.ebuild
index 8f9309f94b0c..ff379f1d72e6 100644
--- a/dev-python/hatch-jupyter-builder/hatch-jupyter-builder-0.8.3.ebuild
+++ b/dev-python/hatch-jupyter-builder/hatch-jupyter-builder-0.8.3.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -16,7 +16,7 @@ HOMEPAGE="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv ~s390 sparc x86"
+KEYWORDS="amd64 arm arm64 ~loong ~ppc ppc64 ~riscv ~s390 sparc x86"
 
 RDEPEND="
 	dev-python/hatchling[${PYTHON_USEDEP}]
diff --git a/dev-python/jupyter-server/jupyter-server-2.12.4.ebuild b/dev-python/jupyter-server/jupyter-server-2.12.4.ebuild
index 36ac44caad08..e2663ee45ce1 100644
--- a/dev-python/jupyter-server/jupyter-server-2.12.4.ebuild
+++ b/dev-python/jupyter-server/jupyter-server-2.12.4.ebuild
@@ -17,7 +17,7 @@ HOMEPAGE="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~s390 ~sparc ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 
 RDEPEND="
 	>=dev-python/anyio-3.1.0[${PYTHON_USEDEP}]
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index e9da2ac43cac..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..736a1167c898 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,12 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
- </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/mpi4py/Manifest b/dev-python/mpi4py/Manifest
index b98e7a506457..94297609a46f 100644
--- a/dev-python/mpi4py/Manifest
+++ b/dev-python/mpi4py/Manifest
@@ -1 +1,2 @@
 DIST mpi4py-3.1.4.tar.gz 2493282 BLAKE2B e1a048e6053263f6685c549e2e6f96072b7d95db68595c8848d0ecdb0a6cadf2b102e4c4ce589053ed17a090335afc56f4b3630b60944aeac7e4bc4ad82d4a1b SHA512 f59ad765bc272f8b63f74cfde4e588f640c4fc3d47d05729509da45a2155f830c1d409ec716ff374756748fa8ebfa6e72f9fbe188a6b89ea3fa115740a532b08
+DIST mpi4py-3.1.5.tar.gz 2469777 BLAKE2B 0638e3def52f731b64e2999f83f2d6ccc94dc2f8b37d964c10e49ca12470d3d3ef77ff2737294d85614b2d59d1eec49880e74f2ba3d73fd090152b63c8cc701e SHA512 04da1d6daf66cc86fa3ec574eea6e01749f895035e3394afbc68d6245394c5b03557ede0bda3642b06d9c6ff2c1e6e878a6c8c30d3fa3491392e2e13b82cdec8
diff --git a/dev-python/mpi4py/files/mpi4py-3.1.5-test_memory.testReadOnly.patch b/dev-python/mpi4py/files/mpi4py-3.1.5-test_memory.testReadOnly.patch
new file mode 100644
index 000000000000..986e565588a0
--- /dev/null
+++ b/dev-python/mpi4py/files/mpi4py-3.1.5-test_memory.testReadOnly.patch
@@ -0,0 +1,33 @@
+https://github.com/mpi4py/mpi4py/pull/452
+From: Paul Zander <negril.nx+gentoo@gmail.com>
+
+From 3adbd69b7219525f32636552394935a0a770896d Mon Sep 17 00:00:00 2001
+From: Lisandro Dalcin <dalcinl@gmail.com>
+Date: Mon, 15 Jan 2024 10:45:38 +0300
+Subject: [PATCH] fix: Fix implementation of MPI.buffer.toreadonly()
+
+---
+ src/mpi4py/MPI/asbuffer.pxi | 6 ++----
+ 1 file changed, 2 insertions(+), 4 deletions(-)
+
+diff --git a/src/mpi4py/MPI/asbuffer.pxi b/src/mpi4py/MPI/asbuffer.pxi
+index 15e06a1..6536c1f 100644
+--- a/src/mpi4py/MPI/asbuffer.pxi
++++ b/src/mpi4py/MPI/asbuffer.pxi
+@@ -257,14 +257,12 @@ cdef class memory:
+ 
+     def toreadonly(self) -> memory:
+         """Return a readonly version of the memory object"""
+-        cdef void *buf = self.view.buf
+-        cdef Py_ssize_t size = self.view.len
+         cdef object obj = self
+         if self.view.obj != NULL:
+             obj = <object>self.view.obj
+         cdef memory mem = memory.__new__(memory)
+-        PyBuffer_FillInfo(&mem.view, obj,
+-                          buf, size, 1, PyBUF_SIMPLE)
++        PyMPI_GetBuffer(obj, &mem.view, PyBUF_SIMPLE)
++        mem.view.readonly = 1
+         return mem
+ 
+     def release(self) -> None:
diff --git a/dev-python/mpi4py/mpi4py-3.1.5.ebuild b/dev-python/mpi4py/mpi4py-3.1.5.ebuild
new file mode 100644
index 000000000000..54fe704b541e
--- /dev/null
+++ b/dev-python/mpi4py/mpi4py-3.1.5.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1 pypi
+
+DESCRIPTION="Message Passing Interface for Python"
+HOMEPAGE="https://github.com/mpi4py/mpi4py https://pypi.org/project/mpi4py/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	virtual/mpi
+"
+DEPEND="${RDEPEND}
+	test? (
+		virtual/mpi[romio]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.1.5-test_memory.testReadOnly.patch"
+)
+
+python_prepare_all() {
+	# not needed on install
+	rm -vr docs/source || die
+	rm test/test_pickle.py || die # disabled by Gentoo-bug #659348
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	echo "Beginning test phase"
+	local -x PYTHONPATH="${BUILD_DIR}/install$(python_get_sitedir)"
+
+	# python want's all arguments as separate strings
+	local mpi_opts=(
+		"-n" "1"
+	)
+	# spawn is not stable in OpenMPI 4
+	# https://github.com/jsquyres/ompi/pull/4#issuecomment-806897758
+	# oob_tcp_if_include lo is needed to allow test in systemd-nspawn container
+	has_version sys-cluster/openmpi && mpi_opts+=(
+		"--use-hwthread-cpus"
+		"--mca" "btl" "tcp,self"
+		"--mca" "oob_tcp_if_include" "lo"
+	)
+	mpiexec \
+		"${mpi_opts[@]}" \
+		"${PYTHON}" -B -v ./test/runtests.py -v \
+		--exclude="test_msgspec" --exclude="test_spawn" ||
+		die "Testsuite failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/. )
+	use examples && local DOCS=( demo )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/nautilus-python/nautilus-python-4.0.ebuild b/dev-python/nautilus-python/nautilus-python-4.0.ebuild
index 6564fa3eb9a6..b8fc61561270 100644
--- a/dev-python/nautilus-python/nautilus-python-4.0.ebuild
+++ b/dev-python/nautilus-python/nautilus-python-4.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2023 Gentoo Authors
+# Copyright 1999-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -29,7 +29,7 @@ RDEPEND="
 DEPEND="${RDEPEND}"
 BDEPEND="
 	gtk-doc? ( dev-util/gtk-doc )
-	>=dev-util/gtk-doc-am-1.14
+	>=dev-build/gtk-doc-am-1.14
 	virtual/pkgconfig
 "
 
diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index 0bd949348b39..d759fb93663a 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1,2 +1,3 @@
 DIST pdm-2.11.1.tar.gz 2595425 BLAKE2B cebaf5a86045a9826a8d6a77985a064fe3e05af403818a4629f7a978a58a4fd07e4d12ba4a69542cd4cf2a090d28a826ebadf0d703543b0551f49b61039d6d38 SHA512 e62bd64b1b302bffe0f7f18a68244b108a10969108ce98df028bd56662b336db8bf019fb1d516cc1dc579b838c674ef8601b8f7056e8547a89c5d3311cd037d9
 DIST pdm-2.11.2.tar.gz 2595716 BLAKE2B 10d1c78160f45099cdbbac6f6ef402b4c9f892e229fe56e54f164b4d7c3317cc8808639b97990e9fefda879d693cba32b48fc7b4c787704e7893c0844351227f SHA512 f27c1b5704469cc846b21a090f2098dacd486b833093af661644717a6dd6cdc627b086027b1c71037d5f3b179e72eac6dde3a98320eaff4f033ae9c96b37ab2c
+DIST pdm-2.12.1.tar.gz 2598220 BLAKE2B 3aa7ea827b4f38398c8e20ea06d887add3c87c5df26acf627580278eb87ddf508fe7eb03a83ea726541f1233168eb7975dc03715673dffb8d9f30d2843765c6f SHA512 2837f96de13e4d91f0cfe1b632c1fa08d27ce44230c43933e2cf2af2f4b9f3986719104ebc8e3f250f6a005e2a97428d580af0626b55b1e6c2f8f72c14ef67cf
diff --git a/dev-python/pdm/pdm-2.12.1.ebuild b/dev-python/pdm/pdm-2.12.1.ebuild
new file mode 100644
index 000000000000..47894d19e83d
--- /dev/null
+++ b/dev-python/pdm/pdm-2.12.1.ebuild
@@ -0,0 +1,81 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	<dev-python/dep-logic-1.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/truststore[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.12.1[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.4.0[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.0.1[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/cachecontrol[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/cli/test_build.py::test_build_with_no_isolation[False]'
+		tests/test_project.py::test_access_index_with_auth
+		tests/cli/test_others.py::test_build_distributions
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[-e file:///${PROJECT_ROOT}/tests/fixtures/projects/demo-#-with-hash#egg=demo]'
+		# hangs on interactive keyring prompts
+		tests/cli/test_config.py::test_repository_overwrite_default
+		tests/cli/test_config.py::test_hide_password_in_output_repository
+		tests/cli/test_config.py::test_hide_password_in_output_pypi
+		# junk output, sigh
+		tests/cli/test_others.py::test_info_command_json
+		# why does it try to use python 2.7?!
+		tests/cli/test_run.py::test_import_another_sitecustomize
+	)
+	[[ ${EPYTHON} != python3.10 ]] && EPYTEST_DESELECT+=(
+		# test seems hardcoded to 3.10
+		tests/test_project.py::test_project_packages_path
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest  -m "not network and not integration and not path" \
+		-p pytest_mock
+}
diff --git a/dev-python/pipx/Manifest b/dev-python/pipx/Manifest
index 51a7d3359a73..59b60db3b17c 100644
--- a/dev-python/pipx/Manifest
+++ b/dev-python/pipx/Manifest
@@ -2,3 +2,4 @@ DIST pipx-1.4.0.gh.tar.gz 357942 BLAKE2B 34b0ede5a5160c8a5fcdff81c4902e0119041e7
 DIST pipx-1.4.1-test-shim.tar.xz 76316 BLAKE2B 25200c9519f8e916cba3933b4df3cc808d5575ac055c4465dbd4cf0ced92bc7f0bca5c448e324b9d61a0cf70710f584cfba6106859ffcccf42e0f59910b81cd0 SHA512 760ad73c67588747bed91b7172821a8e899e52fff8966836d7a2b3dc8cd3946006c76fdcae0320364fe0cb5afc8b51dd583c0a3720099812702fb585b98b9fef
 DIST pipx-1.4.1.gh.tar.gz 357978 BLAKE2B 2ef4f303eafacd84d4b157043a03dc9365708882080bddb1cbcbf16910686ad65938314953a1d1b5be86243fb614f7b705dd91362cd3d7199434147004d529e7 SHA512 04fa29b02a25f21544ae2bbc86fa927fd3c03f98b3f1bd6beee318cbb34849edfbd553fb3b9f94015aab16039aa49f706092a75bd2f865f04dec56a34da43f1f
 DIST pipx-1.4.2.gh.tar.gz 359349 BLAKE2B c00d5b16e8ce0eae8dd350e1db278c0f04421681c5f98ab96294153f8134cc131ed672705a6b953bed3544011ef3f3c2f43595d50d211766f98877b349ef946c SHA512 4532988943551340b33dcd0af1af51630ae9e96b0575a85eb5803ff015fe988a73d9d246380e5a0b5712b17b602ab2d4de67054ed7d8c7c183f4d8bbde169649
+DIST pipx-1.4.3.gh.tar.gz 361782 BLAKE2B 579f16fe9c8fca973a2fdd1dc6b0cee9ae9d3da37be5acd1cc9d14e37fb291f678986bcfd52b185ebce3200000817a9dacdce95473f9fd498d4f6dc89cf7d3da SHA512 423310d4a2523fdb0eca69fd5ee861f8cad144f458aaf63008ca018fea0dc3b6a4274f7cae1ffdde45013dd85eee05a4a379589a93f4c369376e122a5dc4f23e
diff --git a/dev-python/pipx/pipx-1.4.3.ebuild b/dev-python/pipx/pipx-1.4.3.ebuild
new file mode 100644
index 000000000000..70ddc22a4926
--- /dev/null
+++ b/dev-python/pipx/pipx-1.4.3.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+TEST_SHIM=pipx-1.4.1-test-shim
+DESCRIPTION="Install and Run Python Applications in Isolated Environments"
+HOMEPAGE="
+	https://pipx.pypa.io/stable/
+	https://pypi.org/project/pipx/
+	https://github.com/pypa/pipx/
+"
+# no tests in sdist
+SRC_URI="
+	https://github.com/pypa/pipx/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	test? (
+		https://dev.gentoo.org/~mgorny/dist/${TEST_SHIM}.tar.xz
+	)
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.10)
+	>=dev-python/userpath-1.9.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ensurepip-pip
+		dev-python/ensurepip-setuptools
+		dev-python/ensurepip-wheel
+		dev-python/pypiserver[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+src_prepare() {
+	if use test; then
+		cp -vs "${BROOT}"/usr/lib/python/ensurepip/{pip,setuptools,wheel}-*.whl \
+			"${WORKDIR}/${TEST_SHIM}/" || die
+		mkdir -p .pipx_tests/package_cache || die
+		local v
+		for v in 3.{10..12}; do
+			ln -s "${WORKDIR}/${TEST_SHIM}" \
+				".pipx_tests/package_cache/${v}" || die
+		done
+
+		: > scripts/update_package_cache.py || die
+		# sigh
+		sed -e 's:server = str.*:server = "pypi-server":' \
+			-i tests/conftest.py || die
+	fi
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/test_run.py::test_run_ensure_null_pythonpath
+		tests/test_run.py::test_run_script_from_internet
+		'tests/test_install.py::test_install_package_specs[pycowsay-git+https://github.com/cs01/pycowsay.git@master]'
+		tests/test_install.py::test_force_install_changes
+		'tests/test_install.py::test_install_package_specs[nox-https://github.com/wntrblm/nox/archive/2022.1.7.zip]'
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -x
+}
diff --git a/dev-python/pudb/Manifest b/dev-python/pudb/Manifest
index c928c9efea50..093db94c6654 100644
--- a/dev-python/pudb/Manifest
+++ b/dev-python/pudb/Manifest
@@ -1 +1,2 @@
 DIST pudb-2023.1.tar.gz 224307 BLAKE2B b0b8b8f4f14d86e24b2863091fd41801282b5e7f8b48cdb22a286c171f714a5e9b9a7f516261b7cc74210379f933f85e7e99e9df22deade4261c9b98aa200702 SHA512 b27184a9ece304063871e4f8ace7d7b7b13e6d4f9a88b6372f7e6c0487319d1155204beac422fd2dda9ec367ad9483ceda42562c9ad4beb3c868c50ee2d2ff3d
+DIST pudb-2024.1.tar.gz 226023 BLAKE2B ea1c2653c526d53f16362a074cb77a1c076d5311fda99517220f179d4431bec615b0fdd37eeb282c3f89e3b5ff43dd5b0c4950d0e23b06bc9caec98cea0c9658 SHA512 1e07e21a12fe8d970079faf54a26fbe5c9b71552fa8e246f9606a91384304170b8c292788c282363a486cfc5775cad23346f54b89e4a9d2d7b113abf550b0200
diff --git a/dev-python/pudb/pudb-2024.1.ebuild b/dev-python/pudb/pudb-2024.1.ebuild
new file mode 100644
index 000000000000..8b45f9b682ec
--- /dev/null
+++ b/dev-python/pudb/pudb-2024.1.ebuild
@@ -0,0 +1,29 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A full-screen, console-based Python debugger"
+HOMEPAGE="https://pypi.org/project/pudb/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/urwid-2.4[${PYTHON_USEDEP}]
+	dev-python/urwid_readline[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/pytest-asyncio/Manifest b/dev-python/pytest-asyncio/Manifest
index 9c8f5ffcf592..0b19ea50469f 100644
--- a/dev-python/pytest-asyncio/Manifest
+++ b/dev-python/pytest-asyncio/Manifest
@@ -1,3 +1,4 @@
 DIST pytest-asyncio-0.23.2.tar.gz 44174 BLAKE2B 36dbd0022416eef05c781b9f74fd143bb52fe0583461ca7e52fd4981d552bbefdddd8e3a3399bc229a8ae68b150e199237ae0ce3a375075ab8f7f507bfa59316 SHA512 aa5b5fe8b633b187303dd2958d2ea01561604044507da107e46115d9bf4c1ac3c78826b4b6a6cbf474a6ee4ce0cd1bede87a2c8fe0d35397ddf6a4069437dd84
 DIST pytest-asyncio-0.23.3.tar.gz 44841 BLAKE2B f40f18e683ff1c6d905ae81c0a399655d461065f49fc862fe0d57c9d0deb14795e9792d76ea9759ea2b8736f7815de8c1778dbcaa8f477c59cbffd1f991e7ed1 SHA512 209a36de4d74bb3ade486b7c89c58def33b4aca84b3a096012d2ba329946f084a3f70489fb4ba0682e6acd65b6862e2ea4104a8e8912e8693f4f1685de357762
 DIST pytest-asyncio-0.23.4a1.tar.gz 46294 BLAKE2B 6015cc43a8eae8a589311a579196ca9ebb392ff14cf3c68743e10ea3bf7b57958aba59432efae94c3e57e03be3f625a1f0c883e85427af3a20d1f60d634d8946 SHA512 9181a65ad427d2a0f35077019dfa6a46d5714592a754a083a7bb0efb7f97af5776192cd92961d751dba27d84c78a32a9f0c49a46b2d962d24796451311845691
+DIST pytest-asyncio-0.23.4a2.tar.gz 45187 BLAKE2B b9c7b48c2ddc29f57e7a175d4cd2a86431047223d23d2a516338b2d2e12951a422eff09736737755777b6fc764e50942b21497d53515319494d8c17100856f9c SHA512 f8d21483935c9d92b50519e71a9f88776bb10ac8d7112fd290d03d35f484177406e9a094be6ab4383a733b40a6166def97dcea881a13e82bbdbe94725aa6a070
diff --git a/dev-python/pytest-asyncio/pytest-asyncio-0.23.4_alpha2.ebuild b/dev-python/pytest-asyncio/pytest-asyncio-0.23.4_alpha2.ebuild
new file mode 100644
index 000000000000..9af91a7c12ae
--- /dev/null
+++ b/dev-python/pytest-asyncio/pytest-asyncio-0.23.4_alpha2.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2019-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Library for testing asyncio code with pytest"
+HOMEPAGE="
+	https://github.com/pytest-dev/pytest-asyncio/
+	https://pypi.org/project/pytest-asyncio/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/pytest-5.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/hypothesis-3.64[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on precise warning counts
+		tests/hypothesis/test_base.py::test_can_use_explicit_event_loop_fixture
+		tests/modes/test_legacy_mode.py
+		tests/modes/test_strict_mode.py::test_strict_mode_ignores_unmarked_fixture
+		tests/test_event_loop_fixture_finalizer.py::test_event_loop_fixture_finalizer_raises_warning_when_fixture_leaves_loop_unclosed
+		tests/test_event_loop_fixture_finalizer.py::test_event_loop_fixture_finalizer_raises_warning_when_test_leaves_loop_unclosed
+		tests/test_pytest_min_version_warning.py
+		tests/trio/test_fixtures.py::test_strict_mode_ignores_trio_fixtures
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=pytest_asyncio.plugin,_hypothesis_pytestplugin
+	epytest
+}
diff --git a/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc28.ebuild b/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc28.ebuild
index 3eb94603ead5..c67d62e186f2 100644
--- a/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc28.ebuild
+++ b/dev-python/pytest-salt-factories/pytest-salt-factories-1.0.0_rc28.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2020-2023 Gentoo Authors
+# Copyright 2020-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -21,7 +21,7 @@ S=${WORKDIR}/${P//_/}
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~riscv ~x86"
+KEYWORDS="amd64 ~riscv x86"
 
 RDEPEND="
 	dev-python/attrs[${PYTHON_USEDEP}]
diff --git a/dev-python/python-olm/python-olm-3.2.16.ebuild b/dev-python/python-olm/python-olm-3.2.16.ebuild
index 1931a42d6b72..160c258ea5fc 100644
--- a/dev-python/python-olm/python-olm-3.2.16.ebuild
+++ b/dev-python/python-olm/python-olm-3.2.16.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2023 Gentoo Authors
+# Copyright 2022-2024 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
diff --git a/dev-python/qiskit-aer/Manifest b/dev-python/qiskit-aer/Manifest
index ef5574dd4b16..0eb1dde70814 100644
--- a/dev-python/qiskit-aer/Manifest
+++ b/dev-python/qiskit-aer/Manifest
@@ -1,2 +1,3 @@
 DIST qiskit-aer-0.12.2.gh.tar.gz 6979559 BLAKE2B c7f12c9b8f53a9031844e123b8ef6d723e0099be028c5cfba03143fb8b3c7269768ade99d3ef3b4b82c0b36756bf8e82971a3f70c0f5735891eb77a78a6d9512 SHA512 2a9ed6777e5e4d60a393d5a1b21b44ea3fa90fb791aeafda8bbb4ca8b55c7e8161cd5a275fd14bf968a22537cede099dbd419d1a3c5edebe85fdb82501c4de90
 DIST qiskit-aer-0.13.1.gh.tar.gz 6979392 BLAKE2B a49f992a80ef644f34cb570d6cf85e147b7c897004c248ec749c43a64c5b950fe9d7f178c53b79202f73186c03e5bc61f36be76b904e22aa6f82a79b1b255bcf SHA512 45568fc1027bb530121a0c39b3bab7847e481e0dba57a005c1a1afb8f3523c098a11acddf96eac87bc750e19d2f7c4e47d8de797ae2501b464d68b849ec7b809
+DIST qiskit-aer-0.13.2.gh.tar.gz 6981338 BLAKE2B 583937a3515f3de0714100cf7586f42b028c5918d50e2352fa3658b6e53e185ce5db5dc4a5abbe0ad8cf4634da123a47c7708eeee7f9ec53af2fdedc2d6192ef SHA512 f31bb19da67672a9e1cddbf18b35efb4c7cd94444033275acb00c5fd4fce80b56f08610addc58d6d5d68d4da1b6a6cdf38fc929c9921d83620e793aaab51fe57
diff --git a/dev-python/qiskit-aer/qiskit-aer-0.13.2.ebuild b/dev-python/qiskit-aer/qiskit-aer-0.13.2.ebuild
new file mode 100644
index 000000000000..ca580e0a5414
--- /dev/null
+++ b/dev-python/qiskit-aer/qiskit-aer-0.13.2.ebuild
@@ -0,0 +1,126 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="High performance simulator for quantum circuits that includes noise models"
+HOMEPAGE="
+	https://github.com/Qiskit/qiskit-aer/
+	https://pypi.org/project/qiskit-aer/
+"
+SRC_URI="
+	https://github.com/Qiskit/qiskit-aer/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# The reference implementation of BLAS/CBLAS is not compatible with qiskit-aer right now,
+# because importing library causes an error.
+# /usr/lib/python3.9/site-packages/qiskit/providers/aer/backends/controller_wrappers.cpython-39-x86_64-linux-gnu.so: undefined symbol: slamch_
+# Using sci-libs/openblas instead here,
+# with the option to switch between reference/openblas implementation runtime (eselect-ldso).
+#
+# <nlohmann_json-3.10.3 for https://github.com/Qiskit/qiskit-aer/issues/1742
+DEPEND="
+	>=dev-python/numpy-1.16.3[${PYTHON_USEDEP}]
+	<dev-cpp/nlohmann_json-3.10.3
+	>=dev-cpp/nlohmann_json-3.1.1
+	>=dev-libs/spdlog-1.9.2:=
+	>=dev-cpp/muParserX-4.0.8
+	virtual/cblas[eselect-ldso]
+	sci-libs/openblas[eselect-ldso]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/psutil-5[${PYTHON_USEDEP}]
+	>=dev-python/qiskit-terra-0.45.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-build/cmake-3.17
+	>=dev-python/scikit-build-0.11.0[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.6[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+check_openblas() {
+	local libdir=$(get_libdir) me="openblas"
+
+	# check blas
+	local current_blas=$(eselect blas show ${libdir} | cut -d' ' -f2)
+	if [[ ${current_blas} != "${me}" ]]; then
+		eerror "Current eselect: BLAS/CBLAS ($libdir) -> [${current_blas}]."
+		eerror "To use qiskit-aer, you have to issue (as root):"
+		eerror "\t eselect blas set ${libdir} ${me}"
+		return 1
+	fi
+	return 0
+}
+
+pkg_setup() {
+	if use test; then
+		check_openblas
+		if [[ $? -ne 0 ]]; then
+			die "Set blas implementation to openblas using 'eselect blas set openblas'!"
+		fi
+	fi
+}
+
+python_prepare_all() {
+	export DISABLE_CONAN="ON"
+	export DISABLE_DEPENDENCY_INSTALL="ON"
+	export SKBUILD_CONFIGURE_OPTIONS="-DTEST_JSON=1"
+
+	# remove meaningless dep on the metapackage
+	sed -i -e '/qiskit>=/d' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		test/terra/states/test_aer_state.py::TestAerState::test_appply_diagonal
+		test/terra/states/test_aer_state.py::TestAerState::test_appply_measure
+		test/terra/states/test_aer_state.py::TestAerState::test_appply_reset
+
+		# TODO: GLIBCXX_ASSERTIONS, bug #897758
+		test/terra/backends/aer_simulator/test_algorithms.py::TestAlgorithms::test_extended_stabilizer_sparse_output_probs
+		test/terra/backends/aer_simulator/test_options.py::TestOptions::test_mps_options
+		test/terra/backends/aer_simulator/test_fusion.py::TestGateFusion::test_parallel_fusion_diagonal
+
+		# requires qiskit_qasm3_import
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_1___automatic____CPU__
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_2___statevector____CPU__
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_3___matrix_product_state____CPU__
+		test/terra/backends/aer_simulator/test_save_statevector.py::TestSaveStatevector::test_save_statevector_for_qasm3_circuit_4___extended_stabilizer____CPU__
+	)
+
+	# From tox.ini/tests.yml in CI
+	# Needed to suppress a warning in jupyter-core 5.x by eagerly migrating to
+	# a new internal interface that will be the default in jupyter-core 6.x.
+	# This variable should become redundant on release of jupyter-core 6.
+	local -x JUPYTER_PLATFORM_DIRS=1
+
+	rm -rf qiskit_aer || die
+	epytest -n "$(makeopts_jobs)" -s
+}
+
+pkg_postinst() {
+	check_openblas
+}
diff --git a/dev-python/tables/tables-3.9.2.ebuild b/dev-python/tables/tables-3.9.2.ebuild
index 6e3ef9b56c32..3fef8a11414f 100644
--- a/dev-python/tables/tables-3.9.2.ebuild
+++ b/dev-python/tables/tables-3.9.2.ebuild
@@ -19,7 +19,7 @@ HOMEPAGE="
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~loong ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
+KEYWORDS="amd64 ~arm arm64 ~hppa ~ia64 ~loong ~ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
 IUSE="+cpudetection examples test"
 RESTRICT="!test? ( test )"
 
@@ -28,7 +28,7 @@ DEPEND="
 	app-arch/lz4:0=
 	>=app-arch/zstd-1.0.0:=
 	>=dev-libs/c-blosc-1.11.1:0=
-	>=dev-libs/c-blosc2-2.10.4:=
+	>=dev-libs/c-blosc2-2.11.0:=
 	dev-libs/lzo:2=
 	>=dev-python/numpy-1.19.0[${PYTHON_USEDEP}]
 	>=sci-libs/hdf5-1.8.4:=
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index 4e4239e98224..4ee05e31d91e 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,3 +1,4 @@
 DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3e67825672d0efc74c1b1468bc8b8d9c14b6177c181750ba4b9a5e77d616068dd83e21f5641acfc8e2a271cc1f SHA512 64816754e6800661bb564c5c7d21c4139522d540a04fafe3c4591d596072d48d1cbe0ee2abee9c8faf3d5007774f5371431b5a7a8f49912bc879c7b168aab2ca
 DIST tox-4.11.4.tar.gz 176168 BLAKE2B 03cf6337450494772a85787f2a34eaebfd1db159689fa4c26128efacb968b6aaac995c13a70ffaf1a7dde89107c9bb1975366ff1cc47a46979c7a1cfbd6c3402 SHA512 4b6149ec5945d67d3f5afd309a71a7845fe3ca2ca1291cb08327bda2177d2623ca49d52548fabf7856416dd90973c82566559a738946038963e7aada544ddc30
 DIST tox-4.12.0.tar.gz 176784 BLAKE2B 726bf83a041fde29e28a30309cb5a6d07ae4569f665cf36eb2f8b8463159fb4464d7795c7fa8e132d186ae5eb8df398706a0a99f72f4d6eb4ac431713e866f3c SHA512 51ca9c6819e3b8ee1b7146ec451676492e34b2f2f415db5781c7ab3d0d343dbaa15d6cc4060ea62179d121fe01af162ae973ab6d0a0841824f9d98ddcb5147a4
+DIST tox-4.12.1.tar.gz 176858 BLAKE2B 805764e507ba2894e46dad6b82eb928b4f184d20b2ceb0e7c2ff15f553121158f7f84515a5922d095893a1d6a73030777300163dfdd60964ffe6c41cf2047c14 SHA512 217fbc2933999fcc5d080d97521cd01b7d9a35d4f1542cc58bcc2ff86d07884caa43fd42b09e5064cbad1334e4df9cd717c48c70041c9cf856b0beb22e1ea8a7
diff --git a/dev-python/tox/tox-4.12.1.ebuild b/dev-python/tox/tox-4.12.1.ebuild
new file mode 100644
index 000000000000..60ee4e5af69b
--- /dev/null
+++ b/dev-python/tox/tox-4.12.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}
diff --git a/dev-python/uvicorn/Manifest b/dev-python/uvicorn/Manifest
index e43923dfda1f..c37fd28234f3 100644
--- a/dev-python/uvicorn/Manifest
+++ b/dev-python/uvicorn/Manifest
@@ -1 +1,2 @@
 DIST uvicorn-0.25.0.gh.tar.gz 717386 BLAKE2B f0a472676a732d7807137f157c95574584d882bf9ae8531c4e2c1164ebe9eec2172da62f72f07032ada422b7932f221457686aa22ab6fbceac57685ad91920b8 SHA512 19c1e6438c40ab1b1d30c9c9c84d65f2dc661197adcc6be3d7825223d933d4554ec388323e16452ef0409476766af1ae18bb3252a391099bd2e2bfe2b6c4abb2
+DIST uvicorn-0.26.0.gh.tar.gz 717758 BLAKE2B 1ac4d28a6351a8e9fc9d4e0481237dd8b3265afcfd2c554093299bb6d03570809edf44a1c6278441c1a8611d380aacbfa99986ebac99b19e65d055c78c28e494 SHA512 3b561f3b5335bd52093d5aab2ab9db101a2a36f06179fe02a177a5de4dc336f2aaf700b45ceb7c0952d0b3e5e2a3bdf0387b978ac46af96def409e189bacfa23
diff --git a/dev-python/uvicorn/uvicorn-0.26.0.ebuild b/dev-python/uvicorn/uvicorn-0.26.0.ebuild
new file mode 100644
index 000000000000..5235af9d6598
--- /dev/null
+++ b/dev-python/uvicorn/uvicorn-0.26.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Lightning-fast ASGI server implementation"
+HOMEPAGE="
+	https://www.uvicorn.org/
+	https://github.com/encode/uvicorn/
+	https://pypi.org/project/uvicorn/
+"
+# as of 0.21.0, no tests in sdist
+SRC_URI="
+	https://github.com/encode/uvicorn/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="test-rust"
+
+RDEPEND="
+	>=dev-python/asgiref-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/click-7.0[${PYTHON_USEDEP}]
+	>=dev-python/h11-0.8[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/a2wsgi[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/python-dotenv[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		>=dev-python/websockets-10.4[${PYTHON_USEDEP}]
+		dev-python/wsproto[${PYTHON_USEDEP}]
+		test-rust? (
+			dev-python/cryptography[${PYTHON_USEDEP}]
+			dev-python/trustme[${PYTHON_USEDEP}]
+			dev-python/watchfiles[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# too long path for unix socket
+		tests/test_config.py::test_bind_unix_socket_works_with_reload_or_workers
+	)
+	case ${EPYTHON} in
+		pypy3)
+			# TODO
+			EPYTEST_DESELECT+=(
+				tests/middleware/test_logging.py::test_running_log_using_fd
+			)
+			;;
+	esac
+
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "auto reload on file changes" dev-python/watchfiles
+}