Adding metadata

38 files changed, 646 insertions, 64 deletions

diff --git a/dev-python/astroid/Manifest b/dev-python/astroid/Manifest
index 775d87e6254b..ae98208f864a 100644
--- a/dev-python/astroid/Manifest
+++ b/dev-python/astroid/Manifest
@@ -1,3 +1,4 @@
 DIST astroid-2.6.6.tar.gz 368118 BLAKE2B c5117566579ee6c8ccf973e180b3de3cd3896110221627cfa16d17fbeb049954d4452d3f55ab4161751a9eb7892fbd49090eb8e82c5a90f5985ec13a9f5d1fdd SHA512 a077c291b90f52d353d27b8e6aee2ffca1d69bf0e1e7185c32f3959853d9f2957f411975e5bf66f27d73b66cce6bd1e55529de6b7d0a17dea5399edf3a404825
 DIST astroid-2.7.2.tar.gz 374584 BLAKE2B 09f0f70bd0caa8e4971611d2190ccfbc06a8f871abe1e47313ff574bf4680eb26ec67c0a89fc0a434a15535b2c31d005036a0780b62495ac9d6b69e7f04419d3 SHA512 c14841265b2d50a76a5f4ff9c9f19fcdab9e1de8d726e1d40185e517bd3e9c7e1c131e23e0160102f842d7233884eb66d7db7d2443e2609db87d6ec88ed7d5b6
 DIST astroid-2.7.3.tar.gz 378876 BLAKE2B 016ab6e798f1a608c0e0ce0bd81865145349c70497d09e336ec8b21eaf01ea365c204f42daf6d55d148f6873ef15e223adc9baf4a09dc8945158e4b5e24f1ebb SHA512 03a886c2daef640cf0a85f38e39b6e12080dc722862cb03386d1355f3f955ea46a7bb7b85c2887f52ba6d0ecb6243c653c7f1cd44d6c7429f2cd29c1dfd2297f
+DIST astroid-2.8.0.tar.gz 384821 BLAKE2B 74150d67fd883b2bd4356c49c9c1b148a5e98b4d219405e745474c536691276d029bf8a0bb9275ab9df3d09a9b3492a147c67676ab1f80c9c7d3ad10f240bec4 SHA512 0f14f094a6dc753f0171b462f856fb1bfb1b979a8853f76da14beb04a5b02662f6b4e63c3241ce2c9a37f63490a86300152cbe9509c43e0209d5ef536d693b08
diff --git a/dev-python/astroid/astroid-2.8.0.ebuild b/dev-python/astroid/astroid-2.8.0.ebuild
new file mode 100644
index 000000000000..8ff40315092e
--- /dev/null
+++ b/dev-python/astroid/astroid-2.8.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Abstract Syntax Tree for logilab packages"
+HOMEPAGE="
+	https://github.com/PyCQA/astroid/
+	https://pypi.org/project/astroid/"
+SRC_URI="
+	https://github.com/PyCQA/astroid/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+# Version specified in __pkginfo__.py.
+RDEPEND="
+	>=dev-python/lazy-object-proxy-1.4.0[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.11.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+python_test() {
+	local deselect=(
+		# no clue why it's broken
+		tests/unittest_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
+	)
+
+	# Faker causes sys.path_importer_cache keys to be overwritten
+	# with PosixPaths
+	epytest -p no:faker ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 84c2f4ab337f..89b7e1d63c73 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,3 +1,4 @@
 DIST boto3-1.18.28.tar.gz 406268 BLAKE2B 1379f65f46f287a541b098b3ae183bc7d0a6c40a58f6241d97ce39ffdde4f0655e755fe56890fda767b57c6cf7bd565d95745dbbeb80f42f729f561f6e8d9a82 SHA512 98c0d94dd4971f833677947dbfbdcd495a26fda60592130842cf2f22b8929c6f72f971294d9ddc4923372706bf7f37d3d4cb0ede32afc6955d8253c19ddab63f
 DIST boto3-1.18.40.tar.gz 412065 BLAKE2B c548c6a1f5cfac3d304384b56882943201c45f3515bcd3804b90656966ba5ada0bfd5130fef34d8ad1466aad8a45166a9e35706d4ea53e9eb4ca1fcfae7172f4 SHA512 95e0c6ea5a9741657d801b1feab1ac813b653becba442d83673168d029635928e031386c7147ce28a9407acda4b593fc32b0a4f6ff1761f4b8d903b585220cd5
 DIST boto3-1.18.41.tar.gz 412328 BLAKE2B 134ec70addcb9748d255b86d9e12dd380094a6a82c1d79ea9772dcc59e6eaac95a4337a1980d4791f856bd9a4d84b2f0a79b00b8b7f5a2e57384eca95a4090f5 SHA512 a7d0093083a6dae9a9ee8ad183027adc5d1f4cde05f244f126af022c77df457c0810626fe9ce5baf6fbc9e8d9ec2f8086bf95587d4f80b63c47bf4ef210bf61a
+DIST boto3-1.18.42.tar.gz 412699 BLAKE2B d03c4afe357def827e9169ced8b17f92caf79b8291edd5045629e1b8ee697014764caf3135910d9a0862380a94fbaabd1863535c0aad21fd1eca2b0d3e306ac2 SHA512 aae080862a3b30e23407cde6ced8a48522421be40f9eb192647f6ed2693ce6655576dd0705a998469274ba9ef74d24d51c31003798fc4f0856c417491aeab30b
diff --git a/dev-python/boto3/boto3-1.18.42.ebuild b/dev-python/boto3/boto3-1.18.42.ebuild
new file mode 100644
index 000000000000..bee358e1c595
--- /dev/null
+++ b/dev-python/boto3/boto3-1.18.42.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ ||
+		die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 314ebe366b81..32a7894381c5 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,3 +1,4 @@
 DIST botocore-1.21.28.tar.gz 8079306 BLAKE2B 26dce445746a9da1b0cf62b622597396f9b4e735701f9260fd9863410b28b884e70e41b446b8349df39c81696b64632450f4ebb3e3f7865175e538f1b465898c SHA512 29534e51465bc7ac7b6f2e2c48472768c26caa5089f4c7f4a23cc2411fd55fde473388ad181a0b5a36650a6c1252ecb3e2b65e30510adc40f6edd6ce0c89f484
 DIST botocore-1.21.40.tar.gz 8149052 BLAKE2B 0554e2b9caa08b7518f1b51b5a980d98926782f0d4d523fa5c40dc66ecdf2db75719a36a2bf320c8d473119030693e0d1ab6bc7ea34c0574de7488bff5d7e411 SHA512 5466e15f8c09f3b4df13aee951d65219be86ccf1c0e73ed17e50fb7e2418f4694409676804bf6cf3ca638419512d903708e0994cff1f8105a19f0e26f0cabc31
 DIST botocore-1.21.41.tar.gz 8152451 BLAKE2B e236a8f0f64bd18c138dc168c74cefe7af598ad72def9e1faeba222b07f01a65fb7f74627afe470f2894794fd3a617aaa1d789a983606de9329db58c5db2d975 SHA512 540848ccb054340f22c20930a3f867754accd15c6f084dd20ca97184d1c5e390d68f21272d68087b99ae6676d05cbc187e61c88dd0df09cc033e01f1ac1af0ac
+DIST botocore-1.21.42.tar.gz 8156403 BLAKE2B 199d1eeae7b51fc59b8ca6ed3ea331178e94354841144f0055f02a9cd3d67e2bf52c358a7902090bc555c96e6876dcda1b4fe9b9c5c090ce07901af60b4ed116 SHA512 5be1b82f99ea310077bef3abbca6542a1787db38d5f2004107ff2c4b51a57e39e859116daf9451b23368347e05cded84a401476ca6e3fcd13683e4fc8ceb8554
diff --git a/dev-python/botocore/botocore-1.21.42.ebuild b/dev-python/botocore/botocore-1.21.42.ebuild
new file mode 100644
index 000000000000..5684261bd4b3
--- /dev/null
+++ b/dev-python/botocore/botocore-1.21.42.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/charset_normalizer/Manifest b/dev-python/charset_normalizer/Manifest
index 091105d4d611..a60d8e20772c 100644
--- a/dev-python/charset_normalizer/Manifest
+++ b/dev-python/charset_normalizer/Manifest
@@ -1,2 +1,3 @@
 DIST charset_normalizer-2.0.3.gh.tar.gz 363159 BLAKE2B f09cd3c9da04123fc7104cfac6829ea23a82173c04469c4d98acf9311f1006f4ecb152992a397a97838f9312ad0fc8bfeea03960650873a9aaa753315245dcc3 SHA512 4fa5507c4c0c61b3722d7423f4b597514a30ad0fea176a77a1e926328003ba6c0f49c95b4f4a64b8dbb32985373706d895bae1c6e3fe1fe224851b8383576923
 DIST charset_normalizer-2.0.4.gh.tar.gz 363800 BLAKE2B 81a0474238fc2fad6792201629286c261af73ed5dc3c7c4da525b356507f53bfb3e53d1ed325647295986a16fdd2a1e4bec00ee0648cb6e44f201196ef778556 SHA512 64fdddf2b6574828cc37dcb310e5e023d994e9cd4f8a7f6fb5796e997542cb1b14d9444994ab2594267361712a125fa476205462f9c7fea95505eef3c9770d5e
+DIST charset_normalizer-2.0.5.gh.tar.gz 368109 BLAKE2B 42e4cdeaf9a4e57c87e9813a6d1f31492aee29e37eb8c42721748b658064b16f0926dc6ffd794bf165718c4caf9484e139ca4024b89651d7ccdcbc6d907cf7f0 SHA512 5be0a72e51b9454e8a1ab670815526d54e03e42a0fd6de6ff5705000b3cb9af1ab2ad7f3457a898274d39c091603cdc8e2a925dd3c8e39a63910a5e480155b0d
diff --git a/dev-python/charset_normalizer/charset_normalizer-2.0.5.ebuild b/dev-python/charset_normalizer/charset_normalizer-2.0.5.ebuild
new file mode 100644
index 000000000000..58556810e6b3
--- /dev/null
+++ b/dev-python/charset_normalizer/charset_normalizer-2.0.5.ebuild
@@ -0,0 +1,27 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+inherit distutils-r1
+
+DESCRIPTION="The Real First Universal Charset Detector"
+HOMEPAGE="
+	https://pypi.org/project/charset-normalizer/
+	https://github.com/ousret/charset_normalizer/"
+SRC_URI="
+	https://github.com/Ousret/charset_normalizer/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/addopts/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/clang-python/Manifest b/dev-python/clang-python/Manifest
index 3b45de6a465d..1e33a4201860 100644
--- a/dev-python/clang-python/Manifest
+++ b/dev-python/clang-python/Manifest
@@ -2,3 +2,4 @@ DIST llvmorg-10.0.1.tar.gz 120880730 BLAKE2B 30f19f56c4d1f6abcda5fec76256219d1e3
 DIST llvmorg-11.1.0.tar.gz 122776532 BLAKE2B ca842ff4afff8f44c82b5e7383962a9c45ca1c93b64fa4c6ebcd70a1d3849dbad2b8e4e24fba02d144c6266d7fab3607ebc6999b28c229cb35256cf40f26a985 SHA512 9a8ce022a935eed42fa71a224f2a207122aadcbef58ee855fdb4825f879e7d028e4dcff22c19b9d336db1c8bf63fb84372d44981acf84615f757e54306c92b81
 DIST llvmorg-12.0.1.tar.gz 134259748 BLAKE2B f41de787bc73ff2edfda1b22cc8602be6f65f37dd9e4c8888533cfa8c3ccdcf4f108aaab9de23ab0ab987966eb160f2a553a0bdff99461e71ddd5bfcd086090d SHA512 6eb0dc18e2c25935fabfdfc48b0114be0939158dfdef7b85b395fe2e71042672446af0e68750aae003c9847d10d1f63316fe95d3df738d18f249174292b1b9e1
 DIST llvmorg-13.0.0-rc2.tar.gz 147267736 BLAKE2B 153bf7320f2aa911112d366ffc79f7110cb04f135c2a8b176c263f0a75eb768206d9bd462893d45504b0e58aa9e127fdcafb02300eab1666e4616aa654d457dd SHA512 a01baf3eaa02f02af42bfcf6dcf24f166351bf1c09601495617c81e41def23210573bad40a344270f40c5deb881d06863536abac2a6481930766a6a56335fb44
+DIST llvmorg-13.0.0-rc3.tar.gz 147281901 BLAKE2B 640065a2f32dc48edf084d776cb6b950fae86c2a204999e2eec67f93b57615df40adec19785099b0ef2fe11837c3304794ec3585289a5b5051a557618c63c749 SHA512 1401d5a4d6bb5c930d74b9cfbc8e792872f721aab7d7f0c819e2ba5cf47fb818d160c1f71784fba69827f3c9b7414aa91a585d2b813c1851b4799f9d62cebc46
diff --git a/dev-python/clang-python/clang-python-13.0.0_rc3.ebuild b/dev-python/clang-python/clang-python-13.0.0_rc3.ebuild
new file mode 100644
index 000000000000..2f2f8087f297
--- /dev/null
+++ b/dev-python/clang-python/clang-python-13.0.0_rc3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit llvm.org python-r1
+
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+	>=sys-devel/clang-${PV}:*
+	!sys-devel/llvm:0[clang(-),python(-)]
+	!sys-devel/clang:0[python(-)]
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+LLVM_COMPONENTS=( clang/bindings/python )
+llvm.org_set_globals
+
+python_test() {
+	"${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+	python_foreach_impl python_test
+}
+
+src_install() {
+	python_foreach_impl python_domodule clang
+}
diff --git a/dev-python/cmd2/Manifest b/dev-python/cmd2/Manifest
index 5e1f0860e1f6..95541b963f2e 100644
--- a/dev-python/cmd2/Manifest
+++ b/dev-python/cmd2/Manifest
@@ -1 +1,2 @@
 DIST cmd2-2.1.2.tar.gz 660849 BLAKE2B a8c8db8036badc020b34e6d4cc62a6828a6f3788562d550826369d2ce6ddc41fdd29ab95bd56d35115a1e8c2cfdb6df97e3b25c3f414798aed9a597243b37967 SHA512 3f2edb336ec662e3b2e22abc947ffb669786142d29f0723b0d5bbf898ecff12096a91e08c4890dde79915b413c0f9a70945f1b5795ae12991e85d7ee79331d31
+DIST cmd2-2.2.0.tar.gz 667076 BLAKE2B babdf4034ea45cebce0a9b037e0bef0127c924e358c68ab6a2b95e73ed3be4577dead28d2eebce721432fefe7d2590a3e904ba84dc17bf7c06e3f777dc7b0db0 SHA512 20c204c5e5996e18face62066a179a9833c468724a947042a3b5aaf49940cad0c773ea22e7f40b8c721f7362dcefa9eb72072710072e608c4adab615332bdc22
diff --git a/dev-python/cmd2/cmd2-2.2.0.ebuild b/dev-python/cmd2/cmd2-2.2.0.ebuild
new file mode 100644
index 000000000000..bb132cac6252
--- /dev/null
+++ b/dev-python/cmd2/cmd2-2.2.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Extra features for standard library's cmd module"
+HOMEPAGE="https://github.com/python-cmd2/cmd2"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.3.7[${PYTHON_USEDEP}]
+	>=dev-python/pyperclip-1.6[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/wcwidth[${PYTHON_USEDEP}]
+"
+# pyperclip uses clipboard backends in the following preference order:
+# pygtk, xclip, xsel, klipper, qtpy, pyqt5, pyqt4.
+# klipper is known to be broken in Xvfb, and therefore causes test
+# failures.  to avoid them, we must ensure that one of the backends
+# preferred to it is available (i.e. xclip or xsel) + which(1).
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		sys-apps/which
+		|| (
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	sed -i -e '/--cov/d' setup.cfg || die
+}
+
+src_test() {
+	# tests rely on very specific text wrapping...
+	local -x COLUMNS=80
+	virtx distutils-r1_src_test
+}
diff --git a/dev-python/django-otp/Manifest b/dev-python/django-otp/Manifest
index d73c9ad2c64b..3732486bfd7a 100644
--- a/dev-python/django-otp/Manifest
+++ b/dev-python/django-otp/Manifest
@@ -1,2 +1,3 @@
 DIST django-otp-1.0.6.gh.tar.gz 69023 BLAKE2B 82534fb666e27ab654b1587160fd9fd4600d1ecb57f5b506b383c3d7b36a13d6bbff39598603c7c3bc69edc871a6a3ad1aa2531a92ea921ab07798e7e4bb1316 SHA512 ff14a786bc8b3d22c8767fa78d676951c262389dfe00def981c79894d299f393ffc86510c33866482aa246ac1643238a3de5701bb76cf56aea5e3ba0a25cbb97
 DIST django-otp-1.1.0.gh.tar.gz 71399 BLAKE2B 826677582fff6102b3e65750c367607e9641aa629a59f064af7023774017f6e7817f36e51e0fada181fa84054545367689b8b499ef9625729c8434a903911876 SHA512 b23c0e72508c890f7a84b59b7827f093aeaad77e6df7c824894bc789282db6f8a26699c9a3ee9bf755eb8e13c6fe5a80fad263659be7528762a8cc29d4636e11
+DIST django-otp-1.1.1.gh.tar.gz 71526 BLAKE2B d68c0fe99c5437d08a8a0a433b4d6f41f0068047e3899efbb24234696c3494a064982aabc02d2788662d516235413bfc804f76cf5ffa1c608d3aa61927e2fad3 SHA512 5946cd64fd0f52dac5ef9fb192f8ecf78e99c96fe7e3223b41c68d96e249f6727149ef58a2dbf48024452e078f5f93c1f9edb9db2a25def5cbb3992c16aac18c
diff --git a/dev-python/django-otp/django-otp-1.1.1.ebuild b/dev-python/django-otp/django-otp-1.1.1.ebuild
new file mode 100644
index 000000000000..8119b92ce6d4
--- /dev/null
+++ b/dev-python/django-otp/django-otp-1.1.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Django framework adding two-factor authentication using one-time passwords"
+HOMEPAGE="https://github.com/django-otp/django-otp/"
+SRC_URI="
+	https://github.com/django-otp/django-otp/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep sqlite)
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/qrcode[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)"
+
+python_test() {
+	local -x PYTHONPATH=test:${PYTHONPATH}
+	local -x DJANGO_SETTINGS_MODULE=test_project.settings
+	django-admin test -v 2 django_otp || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/django-tagging/django-tagging-0.5.0.ebuild b/dev-python/django-tagging/django-tagging-0.5.0.ebuild
index c4628db87e4f..653259fdd956 100644
--- a/dev-python/django-tagging/django-tagging-0.5.0.ebuild
+++ b/dev-python/django-tagging/django-tagging-0.5.0.ebuild
@@ -1,7 +1,8 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
+
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 
 inherit distutils-r1
diff --git a/dev-python/django-tagging/metadata.xml b/dev-python/django-tagging/metadata.xml
index d770beca13c0..1c2dada8addf 100644
--- a/dev-python/django-tagging/metadata.xml
+++ b/dev-python/django-tagging/metadata.xml
@@ -9,4 +9,5 @@
   <remote-id type="pypi">django-tagging</remote-id>
  </upstream>
  <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/easyprocess/easyprocess-0.3-r1.ebuild b/dev-python/easyprocess/easyprocess-0.3-r1.ebuild
index c4a87df0ba5a..f97316e2626d 100644
--- a/dev-python/easyprocess/easyprocess-0.3-r1.ebuild
+++ b/dev-python/easyprocess/easyprocess-0.3-r1.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
 
@@ -10,6 +10,7 @@ inherit distutils-r1
 DESCRIPTION="Easy to use Python subprocess interface"
 HOMEPAGE="https://github.com/ponty/EasyProcess"
 SRC_URI="https://github.com/ponty/EasyProcess/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/EasyProcess-${PV}"
 
 LICENSE="BSD-2"
 SLOT="0"
@@ -22,6 +23,4 @@ BDEPEND="test? (
 	x11-base/xorg-server[xvfb]
 )"
 
-S="${WORKDIR}/EasyProcess-${PV}"
-
 distutils_enable_tests pytest
diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index d91ea8ce5b56..fba652d550d8 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1,3 +1,4 @@
 DIST fonttools-4.24.4.tar.gz 2556059 BLAKE2B c415ae5214b6df7171a5f8a7ea179b1a4adbc6646598d773f0d3d6a8cd777e8fd3c74c14f00e6c4735a73e712e3fd42ddfc96f3f101d34b122fb9c471d4d94a3 SHA512 aa4ee8f0a7f9cb6d8a84497e6f33f891491cd06cc477a785715f8fde8e5b33cf781ef8b848bfab8cf9a97fc15c018d493c6baf0fb8fd314b8a348c36ff627f41
 DIST fonttools-4.26.1.tar.gz 2579211 BLAKE2B 886a803f6214658423c98bd347db6e2cc0baea5e2619ce18ba2a96589785a1b93228f5b35dd7f6c819b81ca471d6ea1a09d12ad6de04c75388ab6cb5003f5bf5 SHA512 226338cd1c3f71662080c69b0786a6a945b5a75d3a4b7ee6fcf6d7e2e089407d11b4a43950c7aebdaeccad1819e5c6e0b947938fbfbaa3caa9747b7b4a1bd5f6
 DIST fonttools-4.26.2.tar.gz 2579391 BLAKE2B 35a2533a336498aa1d5b9c2a61c1de6af03e6a7a1932a1ad71522f7f73e52590c347fe3e7d60b93b013389023792e6e6b91d6b4bfb92e007062dc2ac494adbb6 SHA512 2caa52a48574e6bdf418fe57fb4ca69686eeae65cb1f44c0cb16c64400ea666530dfcca9e8a619859cf553435f93b38f63e422c315206ecec467eed6339a5987
+DIST fonttools-4.27.0.tar.gz 2645014 BLAKE2B f08178c0fba90d4a44bf00bea054a1d4ae368a823bd30d11d152d3edbe6ea4bf0fc816620333f4ccdd3c9b43de85fce1367c09fda4a8a1dd8178826245c89416 SHA512 65602f13ecaff2881d78075ed6a9774ec8afd1c958ef75f09d146b4699e8341ada90a1fff9176e302e07d77d36a9466096fdda259025c5938e81dd0816269874
diff --git a/dev-python/fonttools/fonttools-4.27.0.ebuild b/dev-python/fonttools/fonttools-4.27.0.ebuild
new file mode 100644
index 000000000000..f795eecba533
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.27.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="https://github.com/fonttools/fonttools/"
+SRC_URI="https://github.com/fonttools/fonttools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+RDEPEND=">=dev-python/fs-2.4.9[${PYTHON_USEDEP}]"
+BDEPEND="
+	${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	DISTUTILS_ARGS=( --with-cython )
+}
+
+python_test() {
+	distutils_install_for_testing
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx epytest Tests fontTools
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index 9339deb79415..1b3c35b5a91a 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -2,3 +2,4 @@ DIST google-api-python-client-2.14.1.tar.gz 25415625 BLAKE2B 2b843a6ec6345e51c5a
 DIST google-api-python-client-2.18.0.tar.gz 26442309 BLAKE2B 84f0cadeed015e9e0cafa209f6256b6262822f7161728aa5eba88f0def718b11c555bd0d87867c1e1ebb02e93046cec068e4ac0f855c55b7abf34a8d51d42fdc SHA512 19b06a252c440d5bb8454fc79487f4009ff73a7bd4882b2d33a354d4c4f287a6ea09f30cff94df4c1d1e898ca237d8e118a7fd5e63022133338d944dcec1243c
 DIST google-api-python-client-2.19.1.tar.gz 26659303 BLAKE2B b1b5064c39b7e0d31e7ee01a7556a9ea6feaac1782d6714e50a32f0dfafedcab59628a1ff32774c426136d7ab796a1a6baf1f9ce7fbd1d233149c3a62648f280 SHA512 85272cd0741caed6ff76b930a69a67f1683886df82681b49f3069243dd40ef3f12febc7c1004ecf230d96bae005a8725d502032a9c85eb1bf9e4ee37af7018b9
 DIST google-api-python-client-2.20.0.tar.gz 26723285 BLAKE2B 3c0cb64ea8c58fe20356cd097676bc7741ea454e61d9dc8807689fe2296c3ddd0da1cb208a639e8b47a981437dea39de9a7c26b669c7dc27a79a0c5ca4a6c463 SHA512 bed0b1a0e0c5384c80e337339e9c5526e0cd5b2d39a3bd69fec1c65a3fed5bf26e6f4f983daed7663d2cd6c47b8a2a7ad54395f8e5dada2b49c15d98a9ff04dd
+DIST google-api-python-client-2.21.0.tar.gz 26754841 BLAKE2B e09b48d80d72e56656b366bd60972cde91d0c705ffe94b61d168e808e575a42f1dbbefdaf21ead1e57bab54a1b2453ba39ed5ae1d2ee616a5ba1418acc9f7534 SHA512 c572e5eab313e01ae94b026e32cf40fb479154942168cc09f2b74f184383ff5fc27cc5c0ae48c34d8ddbd8abe8840520a62a43708bd601341d5b32460f5f07df
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.21.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.21.0.ebuild
new file mode 100644
index 000000000000..8647284e7595
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.21.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-4[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests --install pytest
+
+src_prepare() {
+	find tests -name '*.py' -exec \
+		sed -i -e 's:unittest2 as ::' {} + || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local deselect=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	distutils_install_for_testing
+	epytest tests ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/google-auth/Manifest b/dev-python/google-auth/Manifest
index d522985c4378..699b48a724ae 100644
--- a/dev-python/google-auth/Manifest
+++ b/dev-python/google-auth/Manifest
@@ -1,3 +1,4 @@
 DIST google-auth-1.34.0.tar.gz 180860 BLAKE2B d536d689ff5b0c033f787228d643504d1888f0b73a9c6855fe4fae3af20772ef0640feca39c58c39f45681561dce6d5f3ec1d1f7d9699442fff0ec63fd019361 SHA512 7c3b64e8f85056fb660bbfd4f737053813a1e5b8aba52290882a0ddb9d9fd8c5365b767c78dd1e7859ef95caa6e653786d5a8747c8792bbee9c6fad1a5218910
 DIST google-auth-2.0.1.tar.gz 180467 BLAKE2B a7490931ea8cdec0978103d9bb4da11bebff1e623d847db5fb30a0a7ef1827902b4d5683835631b645e61d4282614e3efc798bedc13a581ba35d51838a64ff96 SHA512 a68f78a7d67beb4d3d00333f6953decd92e1d346aee6491c401ee091d2fb4bbac47b9ecc46f7063119724a49f15ea13c096994e5266d30975500194b9c4a9df0
 DIST google-auth-2.0.2.tar.gz 180445 BLAKE2B d4e9e7dcfd690f5eedf301e989c4a2dedf509e7c3068e4f547ea43f870979a6001d21849a7102321f6f843196f0a4e0a14f888bd3b43701c301aea3a7f94ed60 SHA512 b8cec2fec4105715edad3242f20ac26b7ab2591903785ed5c31c1af19f7a23e14e93e0d4c3644dca76db5ec0353b8a1baba0224d67987067c5580c75592a04e8
+DIST google-auth-2.1.0.tar.gz 181817 BLAKE2B 806f3541163bd2f66a533730eb0064b4697716ab58595dc678fdef106dd49dd328378710650e77efc962547834808124eda934b69cc4ef18931624822710d90f SHA512 1460ad02c6ac549245433567583f76eea680ea941b2917887f7fda3f2f6d04c5b16e536368a2f2c0016acd2bacf894d1eafa9b26f148f66b212590eb0388d181
diff --git a/dev-python/google-auth/google-auth-2.1.0.ebuild b/dev-python/google-auth/google-auth-2.1.0.ebuild
new file mode 100644
index 000000000000..5dbfea8e2d83
--- /dev/null
+++ b/dev-python/google-auth/google-auth-2.1.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Google Authentication Library"
+HOMEPAGE="
+	https://github.com/googleapis/google-auth-library-python/
+	https://pypi.org/project/google-auth/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/cachetools-2.0.0[${PYTHON_USEDEP}]
+	dev-python/namespace-google[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-0.1.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.2.1[${PYTHON_USEDEP}]
+	>=dev-python/rsa-3.1.4[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/grpcio[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/moto[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/pyu2f[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/urllib3[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}
diff --git a/dev-python/indexed_gzip/Manifest b/dev-python/indexed_gzip/Manifest
index 3dcf77a9db98..c25e404582c8 100644
--- a/dev-python/indexed_gzip/Manifest
+++ b/dev-python/indexed_gzip/Manifest
@@ -2,3 +2,4 @@ DIST indexed_gzip-0.8.10.tar.gz 79133 BLAKE2B ebb5bc69d92b627b0546c8570ea533a7d6
 DIST indexed_gzip-1.6.0.tar.gz 99260 BLAKE2B 15fff478a275baf59f152040455502f57762889959c4d2989e44b626dad25d381ff73029107c4495b477397ff5dc0763d1934f23bcc85a6296a0eec85a36b421 SHA512 0e01da5e8c527202c1f18148bad2a8ebec9ca0bc1bc49ce4804c6a32397797525cc7bfdfc254139c3c1b037d3f65171c010453ff3fae6e6256304ddf486bc58d
 DIST indexed_gzip-1.6.1.tar.gz 99290 BLAKE2B bbaa0fe55c132fef4e392c4a154cc7f5cb19e25761af298d70a8c9f5d1019701f0f470b9bcff333b02b0ecfc13b823a5cd64c16cfd2d113955f7e59837dcbd7f SHA512 8b508ac7fc161b75ee7ed9cc0ce8828e0f195c3aa676114c54d5b2767b9f2e56b0c203e63f2036245ede9649138d197dffabd67f41b41232e6c66e2ee1336529
 DIST indexed_gzip-1.6.2.tar.gz 100520 BLAKE2B 028fa28330fcb9958338226b47d2b503cb9810c03d4dbba2abb9f352ff575b05f73d660a683b2ff4be96441acbbf67c01203eb749e2b81df0d35ad7d7aed94d3 SHA512 977567074df02bf95aa11b47326458d14d7a33b29e001b67e7a52b2ffc2a0c465e361ab1d6ed6ca45b451d5ae99f81ca29034c7af52a6c5168b3a81e8c348689
+DIST indexed_gzip-1.6.3.tar.gz 101073 BLAKE2B 685a8b1d8d69dce138ba6eab8af31d537e130674ba96f9383cc28b4440c472cbdde58f97bcda2d2145177342ade369bd88c44799ba07900ebd653c30678cc58e SHA512 567a54ca23fea63b2a8b386cace0e5bd52e6cf587c7507a555f727cb549b9ab32b1395e3b1ac94c1f09e680a62bb0c079b7bb4be724994813ad52db774b83e20
diff --git a/dev-python/indexed_gzip/indexed_gzip-1.6.3.ebuild b/dev-python/indexed_gzip/indexed_gzip-1.6.3.ebuild
new file mode 100644
index 000000000000..3347625f5fd8
--- /dev/null
+++ b/dev-python/indexed_gzip/indexed_gzip-1.6.3.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Fast random access of gzip files in Python"
+HOMEPAGE="https://github.com/pauldmccarthy/indexed_gzip"
+SRC_URI="https://github.com/pauldmccarthy/indexed_gzip/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	sys-libs/zlib:="
+DEPEND=${RDEPEND}
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+	)
+	"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--cov=indexed_gzip::' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	if use test; then
+		export INDEXED_GZIP_TESTING=1
+	fi
+	distutils-r1_src_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib/indexed_gzip/tests || die
+	epytest
+}
diff --git a/dev-python/lit/Manifest b/dev-python/lit/Manifest
index 3b45de6a465d..1e33a4201860 100644
--- a/dev-python/lit/Manifest
+++ b/dev-python/lit/Manifest
@@ -2,3 +2,4 @@ DIST llvmorg-10.0.1.tar.gz 120880730 BLAKE2B 30f19f56c4d1f6abcda5fec76256219d1e3
 DIST llvmorg-11.1.0.tar.gz 122776532 BLAKE2B ca842ff4afff8f44c82b5e7383962a9c45ca1c93b64fa4c6ebcd70a1d3849dbad2b8e4e24fba02d144c6266d7fab3607ebc6999b28c229cb35256cf40f26a985 SHA512 9a8ce022a935eed42fa71a224f2a207122aadcbef58ee855fdb4825f879e7d028e4dcff22c19b9d336db1c8bf63fb84372d44981acf84615f757e54306c92b81
 DIST llvmorg-12.0.1.tar.gz 134259748 BLAKE2B f41de787bc73ff2edfda1b22cc8602be6f65f37dd9e4c8888533cfa8c3ccdcf4f108aaab9de23ab0ab987966eb160f2a553a0bdff99461e71ddd5bfcd086090d SHA512 6eb0dc18e2c25935fabfdfc48b0114be0939158dfdef7b85b395fe2e71042672446af0e68750aae003c9847d10d1f63316fe95d3df738d18f249174292b1b9e1
 DIST llvmorg-13.0.0-rc2.tar.gz 147267736 BLAKE2B 153bf7320f2aa911112d366ffc79f7110cb04f135c2a8b176c263f0a75eb768206d9bd462893d45504b0e58aa9e127fdcafb02300eab1666e4616aa654d457dd SHA512 a01baf3eaa02f02af42bfcf6dcf24f166351bf1c09601495617c81e41def23210573bad40a344270f40c5deb881d06863536abac2a6481930766a6a56335fb44
+DIST llvmorg-13.0.0-rc3.tar.gz 147281901 BLAKE2B 640065a2f32dc48edf084d776cb6b950fae86c2a204999e2eec67f93b57615df40adec19785099b0ef2fe11837c3304794ec3585289a5b5051a557618c63c749 SHA512 1401d5a4d6bb5c930d74b9cfbc8e792872f721aab7d7f0c819e2ba5cf47fb818d160c1f71784fba69827f3c9b7414aa91a585d2b813c1851b4799f9d62cebc46
diff --git a/dev-python/lit/lit-13.0.0_rc3.ebuild b/dev-python/lit/lit-13.0.0_rc3.ebuild
new file mode 100644
index 000000000000..f538abb22ff5
--- /dev/null
+++ b/dev-python/lit/lit-13.0.0_rc3.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1 llvm.org
+
+DESCRIPTION="A stand-alone install of the LLVM suite testing tool"
+HOMEPAGE="https://llvm.org/"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS=""
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+# Tests require 'FileCheck' and 'not' utilities (from llvm)
+BDEPEND="
+	test? (
+		dev-python/psutil[${PYTHON_USEDEP}]
+		sys-devel/llvm )"
+
+LLVM_COMPONENTS=( llvm/utils/lit )
+llvm.org_set_globals
+
+# TODO: move the manpage generation here (from sys-devel/llvm)
+
+src_prepare() {
+	cd "${WORKDIR}" || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x LIT_PRESERVES_TMP=1
+	local litflags=$(get_lit_flags)
+	./lit.py ${litflags//;/ } tests || die
+}
diff --git a/dev-python/pgzero/pgzero-1.2.1-r1.ebuild b/dev-python/pgzero/pgzero-1.2.1-r1.ebuild
index 5e0cd9f1d518..9a4f8bba99e4 100644
--- a/dev-python/pgzero/pgzero-1.2.1-r1.ebuild
+++ b/dev-python/pgzero/pgzero-1.2.1-r1.ebuild
@@ -24,6 +24,10 @@ RDEPEND="
 
 DEPEND="
 	${RDEPEND}
+	test? (
+		media-libs/sdl2-image[png]
+		media-libs/sdl2-mixer[vorbis]
+	)
 "
 
 S="${WORKDIR}/${MY_P}"
diff --git a/dev-python/pyGPG/pyGPG-0.2.ebuild b/dev-python/pyGPG/pyGPG-0.2.ebuild
index 193a8ff19a1f..604dd86b5697 100644
--- a/dev-python/pyGPG/pyGPG-0.2.ebuild
+++ b/dev-python/pyGPG/pyGPG-0.2.ebuild
@@ -15,7 +15,7 @@ if [[ ${PV} == *9999 ]]; then
 	EGIT_BRANCH="master"
 else
 	SRC_URI="https://dev.gentoo.org/~dolsen/releases/pyGPG/${P}.tar.gz"
-	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86"
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86"
 fi
 
 DESCRIPTION="A python interface wrapper for gnupg's gpg command"
diff --git a/dev-python/pyGPG/pyGPG-9999.ebuild b/dev-python/pyGPG/pyGPG-9999.ebuild
index ee7dec346d1d..d129e40c3210 100644
--- a/dev-python/pyGPG/pyGPG-9999.ebuild
+++ b/dev-python/pyGPG/pyGPG-9999.ebuild
@@ -15,7 +15,7 @@ if [[ ${PV} == *9999 ]]; then
 	EGIT_BRANCH="master"
 else
 	SRC_URI="https://dev.gentoo.org/~dolsen/releases/pyGPG/${P}.tar.gz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 fi
 
 DESCRIPTION="A python interface wrapper for gnupg's gpg command"
diff --git a/dev-python/pypy3-exe-bin/Manifest b/dev-python/pypy3-exe-bin/Manifest
index 71f550d01984..ed6a665aa413 100644
--- a/dev-python/pypy3-exe-bin/Manifest
+++ b/dev-python/pypy3-exe-bin/Manifest
@@ -1,2 +1,4 @@
 DIST pypy3-exe-7.3.5-1.amd64.xpak 12030139 BLAKE2B f9a76a2304b3a29985209910b2082aeb07f08a22fce771aa7d548af6e662b88563f61b66582fe0ded21a00463725d4b21cb943c6dedba090cdcfcbf2754433f6 SHA512 d223095cc28f5fceb10196a172ddc2e363dd7e0c5e55b79c959d2ff3f84cb96c652e44bf8c2f7b4555d90289fa0768b18cc26a9212264ab397dd7308a14a93df
 DIST pypy3-exe-7.3.5-1.x86.xpak 9156096 BLAKE2B c3a3a329c2f8bd843fc4c882bbddc1ad124dc797d4915818769e79663e53e787b991b04b8006e8b8548249e4e76d8b68545b9d7470d8cf41bece2cd8e085066c SHA512 b58d48e1fde3ec12b497a30035b719a64a16de1292fb34df6a8e3ecddc277a477641d7781a3440ef2b73dfb1b50ca34cbdca702f27d6a5e00ad25e88bd8ebf34
+DIST pypy3-exe-7.3.6_rc1-1.amd64.xpak 12163491 BLAKE2B 0cdf8b2a4b7c740a9f8770a33df40969d8c1711e92b7673e7cd4c6916df59637740c80be0412b3c11ac3388c1d381d5e289e0d805c8e4e9933637fb1a0767d6c SHA512 fa471617e31b84601b94f40fc887a1f3870c18184a9d561dfc88e6f2bd694af1abaf48b9709c446720dd22a47801bb9b741bf6a7e16f603145e301b245ae532a
+DIST pypy3-exe-7.3.6_rc1-1.x86.xpak 9228355 BLAKE2B 4669af53c163a979e76ebbbae20897dde14f43bc261c67cfd43516c3f342cdd5c61f503599fadb8f2e7a1849d18d1d98d59030cf190cb70903bb741138cceb7d SHA512 a02ab10b18562b864d4b08e5891cad66aa5ec085edb22e5fb19ff5f7e1e863d3ac99041362c9bcdf46a62977e658c2d3aaf853f4dbf6eaf3eafd241edd6cad4e
diff --git a/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.6_rc1.ebuild b/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.6_rc1.ebuild
new file mode 100644
index 000000000000..869d5d6e4790
--- /dev/null
+++ b/dev-python/pypy3-exe-bin/pypy3-exe-bin-7.3.6_rc1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit pax-utils
+
+MY_P=pypy3-exe-${PV}-1
+DESCRIPTION="PyPy3 executable (pre-built version)"
+HOMEPAGE="https://www.pypy.org/"
+SRC_URI="
+	amd64? (
+		https://dev.gentoo.org/~mgorny/binpkg/amd64/pypy/dev-python/pypy3-exe/${MY_P}.xpak
+			-> ${MY_P}.amd64.xpak
+	)
+	x86? (
+		https://dev.gentoo.org/~mgorny/binpkg/x86/pypy/dev-python/pypy3-exe/${MY_P}.xpak
+			-> ${MY_P}.x86.xpak
+	)"
+S="${WORKDIR}"
+
+LICENSE="MIT"
+SLOT="${PV%_p*}"
+KEYWORDS=""
+
+RDEPEND=">=sys-libs/zlib-1.1.3:0/1
+	|| (
+		dev-libs/libffi-compat:7
+		dev-libs/libffi:0/7
+	)
+	virtual/libintl:0/0
+	dev-libs/expat:0/0
+	app-arch/bzip2:0/1
+	sys-libs/ncurses:0/6
+	!dev-python/pypy-exe:${SLOT}"
+
+PYPY_PV=${SLOT%_p*}
+QA_PREBUILT="
+	usr/bin/pypy3-c-${PYPY_PV}"
+
+src_unpack() {
+	ebegin "Unpacking ${MY_P}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${MY_P}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${MY_P} failed"
+}
+
+src_install() {
+	insinto /
+	doins -r usr
+	fperms +x "/usr/bin/pypy3-c-${PYPY_PV}"
+	pax-mark m "${ED}/usr/bin/pypy3-c-${PYPY_PV}"
+}
diff --git a/dev-python/pytest-xvfb/pytest-xvfb-2.0.0-r1.ebuild b/dev-python/pytest-xvfb/pytest-xvfb-2.0.0-r1.ebuild
index 3ace1463503f..9f7ccbcba29d 100644
--- a/dev-python/pytest-xvfb/pytest-xvfb-2.0.0-r1.ebuild
+++ b/dev-python/pytest-xvfb/pytest-xvfb-2.0.0-r1.ebuild
@@ -22,13 +22,4 @@ RDEPEND="
 	x11-base/xorg-server[xvfb]
 "
 
-distutils_enable_tests pytest
-
-python_test() {
-	local -x PYTHONPATH="${BUILD_DIR}/install/lib"
-	esetup.py install \
-		--root="${BUILD_DIR}/install" \
-		--install-lib=lib
-
-	pytest -vv || die "Tests fail with ${EPYTHON}"
-}
+distutils_enable_tests --install pytest
diff --git a/dev-python/pytest/files/pytest-4.6.10-timeout.patch b/dev-python/pytest/files/pytest-4.6.10-timeout.patch
deleted file mode 100644
index 5bf9bcdbd8f5..000000000000
--- a/dev-python/pytest/files/pytest-4.6.10-timeout.patch
+++ /dev/null
@@ -1,35 +0,0 @@
-diff --git a/src/_pytest/pytester.py b/src/_pytest/pytester.py
-index f1d739c99..72406b85d 100644
---- a/src/_pytest/pytester.py
-+++ b/src/_pytest/pytester.py
-@@ -1209,7 +1209,7 @@ class Testdir(object):
-         args = self._getpytestargs() + args
-         return self.run(*args, timeout=timeout)
- 
--    def spawn_pytest(self, string, expect_timeout=10.0):
-+    def spawn_pytest(self, string, expect_timeout=60.0):
-         """Run pytest using pexpect.
- 
-         This makes sure to use the right pytest and sets up the temporary
-@@ -1223,7 +1223,7 @@ class Testdir(object):
-         cmd = "%s --basetemp=%s %s" % (invoke, basetemp, string)
-         return self.spawn(cmd, expect_timeout=expect_timeout)
- 
--    def spawn(self, cmd, expect_timeout=10.0):
-+    def spawn(self, cmd, expect_timeout=60.0):
-         """Run a command using pexpect.
- 
-         The pexpect child is returned.
-diff --git a/testing/test_terminal.py b/testing/test_terminal.py
-index 1b2e46c7c..52ba80f46 100644
---- a/testing/test_terminal.py
-+++ b/testing/test_terminal.py
-@@ -138,7 +138,7 @@ class TestTerminal(object):
-             """
-             def test_1():
-                 import time
--                time.sleep(20)
-+                time.sleep(120)
-         """
-         )
-         child = testdir.spawn_pytest("")
diff --git a/dev-python/pyvirtualdisplay/pyvirtualdisplay-2.2.ebuild b/dev-python/pyvirtualdisplay/pyvirtualdisplay-2.2.ebuild
index 3418400d52f7..5aceeefa0813 100644
--- a/dev-python/pyvirtualdisplay/pyvirtualdisplay-2.2.ebuild
+++ b/dev-python/pyvirtualdisplay/pyvirtualdisplay-2.2.ebuild
@@ -26,8 +26,9 @@ RESTRICT="test"
 RDEPEND="dev-python/easyprocess[${PYTHON_USEDEP}]"
 BDEPEND="
 	test? (
-		$(python_gen_cond_dep \
-			'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_7 python3_8 )
+		$(python_gen_cond_dep '
+			dev-python/backports-tempfile[${PYTHON_USEDEP}]
+		' python3_8 )
 		dev-python/entrypoint2[${PYTHON_USEDEP}]
 		dev-python/path-py[${PYTHON_USEDEP}]
 		dev-python/pillow[${PYTHON_USEDEP}]
diff --git a/dev-python/sqlitedict/sqlitedict-1.7.0.ebuild b/dev-python/sqlitedict/sqlitedict-1.7.0.ebuild
index 5f46420ddcc1..a52e3cdf1876 100644
--- a/dev-python/sqlitedict/sqlitedict-1.7.0.ebuild
+++ b/dev-python/sqlitedict/sqlitedict-1.7.0.ebuild
@@ -4,6 +4,7 @@
 EAPI=8
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="sqlite"
 
 inherit distutils-r1
 
diff --git a/dev-python/vncdotool/vncdotool-0.13.0.ebuild b/dev-python/vncdotool/vncdotool-0.13.0.ebuild
index a9595fa9a8ff..f87a2101014d 100644
--- a/dev-python/vncdotool/vncdotool-0.13.0.ebuild
+++ b/dev-python/vncdotool/vncdotool-0.13.0.ebuild
@@ -1,11 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-DISTUTILS_USE_SETUPTOOLS=rdepend
-
 inherit distutils-r1
 
 DESCRIPTION="Command line VNC client"
@@ -16,8 +14,9 @@ LICENSE="MIT"
 SLOT="0"
 KEYWORDS="amd64 x86"
 
-# No clue why this happens:
+# A lot of errors such as the following appear
 # pexpect.exceptions.ExceptionPexpect: The command was not found or was not executable: vncev.
+# to install those, a manual compile and install of examples from net-libs/libvncserver is needed
 RESTRICT="test"
 
 BDEPEND="test? (
@@ -30,8 +29,7 @@ BDEPEND="test? (
 	dev-python/tox[${PYTHON_USEDEP}]
 	dev-python/virtualenv[${PYTHON_USEDEP}]
 )"
-
-DEPEND="
+RDEPEND="
 	dev-python/pillow[${PYTHON_USEDEP}]
 	dev-python/twisted[${PYTHON_USEDEP}]
 	dev-python/zope-interface[${PYTHON_USEDEP}]
diff --git a/dev-python/vncdotool/vncdotool-1.0.0.ebuild b/dev-python/vncdotool/vncdotool-1.0.0.ebuild
index 6d96ff33dcc3..f87a2101014d 100644
--- a/dev-python/vncdotool/vncdotool-1.0.0.ebuild
+++ b/dev-python/vncdotool/vncdotool-1.0.0.ebuild
@@ -4,8 +4,6 @@
 EAPI=7
 
 PYTHON_COMPAT=( python3_{6,7,8,9,10} )
-DISTUTILS_USE_SETUPTOOLS=rdepend
-
 inherit distutils-r1
 
 DESCRIPTION="Command line VNC client"
@@ -16,8 +14,9 @@ LICENSE="MIT"
 SLOT="0"
 KEYWORDS="amd64 x86"
 
-# No clue why this happens:
+# A lot of errors such as the following appear
 # pexpect.exceptions.ExceptionPexpect: The command was not found or was not executable: vncev.
+# to install those, a manual compile and install of examples from net-libs/libvncserver is needed
 RESTRICT="test"
 
 BDEPEND="test? (
@@ -30,8 +29,7 @@ BDEPEND="test? (
 	dev-python/tox[${PYTHON_USEDEP}]
 	dev-python/virtualenv[${PYTHON_USEDEP}]
 )"
-
-DEPEND="
+RDEPEND="
 	dev-python/pillow[${PYTHON_USEDEP}]
 	dev-python/twisted[${PYTHON_USEDEP}]
 	dev-python/zope-interface[${PYTHON_USEDEP}]