Adding metadata

6 files changed, 225 insertions, 10 deletions

diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index d12ab8aeaca8..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 494 BLAKE2B 9cd8a2a93a8d45bf51fe2324402b175d641762ea591fcb99459427f977a95eccffa6ca4777ca4df39814eea6eac62711567faa654456d32f79023a4685804504 SHA512 d973b85ba1a44389a4275f02a779a93a005f7c2e096467b94b072862e4984d5b42cf33f9821ac68aa5b85b12c98983a90b96049989d8c84497969174b6bb838e
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
new file mode 100644
index 000000000000..637368d2f237
--- /dev/null
+++ b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
@@ -0,0 +1,13 @@
+Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
+
+--- a/setup.py
++++ b/setup.py
+@@ -18,7 +18,7 @@ setup(
+     author_email='michal.danilak@gmail.com',
+     url='https://github.com/Mimino666/langdetect',
+     keywords='language detection library',
+-    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
++    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
+     include_package_data=True,
+     install_requires=['six'],
+     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index 56733bbffc48..98b2b0bf8d0b 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,9 +1,9 @@
-# Copyright 2022 Gentoo Authors
+# Copyright 2022-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+PYTHON_COMPAT=( python3_{11..14} )
 DISTUTILS_USE_PEP517=setuptools
 inherit distutils-r1 pypi
 
@@ -19,4 +19,6 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
+PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
+
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..c0f74ac187e2 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -2,11 +2,9 @@
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
  <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
+  <email>pastalian46@gmail.com</email>
+  <name>Takuya Wakazono</name>
  </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index a89319b817a0..1e6541ac98e0 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,2 +1,3 @@
 DIST spyder-6.0.7.gh.tar.gz 15831723 BLAKE2B a9f3760415cc979f00ceab0d2ec5cd0d51ac4052bd61d17c611dd5ed380a79f78bb64f6765a19d6591dcbb630e4ae80d6ab37be0a2a32f50404dde1b0fcfdbab SHA512 29753fbc666999dbc289337589907e3752230e46cf10913d19d18245eec28dc70719464c135e1096aa37e525779d64b3ddba97df8e04a53447fc4c83131a45d5
+DIST spyder-6.0.8.gh.tar.gz 15831723 BLAKE2B 0f9feb6f6a2178799f5dc8fc20c8130fdc66a861902f6c2984ad4ceabbe6dc6bb9468289cfb702f7ac25b465b340d6e928f5dfcf59f4754720d5a50bd92cd474 SHA512 555ad56fcec1926626a18f8edc71aedfdbc0a85fa0bf4e5a69935489434b6d4a83d37a600b5720a34d37f6da967684dd7c890c9e6e5d66283a301fba164e833c
 DIST spyder-docs-98004cb46d97fa9fa1cfc3f469919928761e7054.gh.tar.gz 93375891 BLAKE2B c98d391bb33b1ba70bf9c8e8072073e87437541aacd4be42140711b786e8ae07bf5a7ca53dffdb826922b5523150fa2950b04117c335dc57f7c2c22eb693c23f SHA512 55e13f9a55075aed007be32581af954d406703dd9586352084162e01865f943c5aff3aa11b50bdc9813dd8a3a52f8fa8f961c73cfc3f96d95930f2a7b823a1d1
diff --git a/dev-python/spyder/spyder-6.0.8.ebuild b/dev-python/spyder/spyder-6.0.8.ebuild
new file mode 100644
index 000000000000..2db0edb41bc6
--- /dev/null
+++ b/dev-python/spyder/spyder-6.0.8.ebuild
@@ -0,0 +1,203 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 optfeature xdg #virtualx
+
+# Commit of documentation to fetch
+DOCS_PV="98004cb46d97fa9fa1cfc3f469919928761e7054"
+
+DESCRIPTION="The Scientific Python Development Environment"
+HOMEPAGE="
+	https://www.spyder-ide.org/
+	https://github.com/spyder-ide/spyder/
+	https://pypi.org/project/spyder/
+"
+SRC_URI="
+	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz
+	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+# Missing deps and broken
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/aiohttp-3.9.3[${PYTHON_USEDEP}]
+	>=dev-python/asyncssh-2.14.0[${PYTHON_USEDEP}]
+	<dev-python/asyncssh-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/bcrypt-4.3.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
+	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
+	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
+	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/ipython-pygments-lexers-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jellyfish-0.7[${PYTHON_USEDEP}]
+	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
+	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
+	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
+	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
+	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
+	>=dev-python/pygithub-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
+	>=dev-python/pylint-venv-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/python-lsp-black-2.0.0[${PYTHON_USEDEP}]
+	<dev-python/python-lsp-black-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/pyuca-1.2[${PYTHON_USEDEP}]
+	>=dev-python/qdarkstyle-3.2.0[${PYTHON_USEDEP}]
+	<dev-python/qdarkstyle-3.3.0[${PYTHON_USEDEP}]
+	>=dev-python/qstylizer-0.2.2[${PYTHON_USEDEP}]
+	>=dev-python/qtawesome-1.4.0[${PYTHON_USEDEP}]
+	<dev-python/qtawesome-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/qtconsole-5.6.1[${PYTHON_USEDEP}]
+	<dev-python/qtconsole-5.7.0[${PYTHON_USEDEP}]
+	>=dev-python/qtpy-2.4.0[${PYTHON_USEDEP},pyqt6,quick,svg,webengine]
+	>=dev-python/rtree-0.9.7[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
+	>=dev-python/spyder-kernels-3.0.5[${PYTHON_USEDEP}]
+	<dev-python/spyder-kernels-3.1.0[${PYTHON_USEDEP}]
+	>=dev-python/superqt-0.6.2[${PYTHON_USEDEP}]
+	<dev-python/superqt-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
+	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.9.4[${PYTHON_USEDEP}]
+"
+
+# BDEPEND="
+# 	test? (
+# 		dev-python/cython[${PYTHON_USEDEP}]
+# 		dev-python/flaky[${PYTHON_USEDEP}]
+# 		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
+# 		dev-python/pandas[${PYTHON_USEDEP}]
+# 		dev-python/pillow[${PYTHON_USEDEP}]
+# 		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+# 		dev-python/pytest-mock[${PYTHON_USEDEP}]
+# 		dev-python/pytest-order[${PYTHON_USEDEP}]
+# 		dev-python/pytest-qt[${PYTHON_USEDEP}]
+# 		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+# 		dev-python/pyyaml[${PYTHON_USEDEP}]
+# 		dev-python/qtpy[${PYTHON_USEDEP}]
+# 		dev-python/scipy[${PYTHON_USEDEP}]
+# 		dev-python/sympy[${PYTHON_USEDEP}]
+# 	)"
+
+# Based on the courtesy of Arfrever
+# This patch removes a call to update-desktop-database during build
+# This fails because access is denied to this command during build
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.0-build.patch"
+	"${FILESDIR}/${PN}-6.0.3-no-dep-on-importlib.patch"
+)
+
+DOCS=(
+	"AUTHORS.txt"
+	"Announcements.md"
+	"CHANGELOG.md"
+	"CODE_OF_CONDUCT.md"
+	"CONTRIBUTING.md"
+	"NOTICE.txt"
+	"README.md"
+	"RELEASE.md"
+)
+
+distutils_enable_tests pytest
+# TODO: Package sphinx-design
+# distutils_enable_sphinx docs/doc \
+# 	dev-python/sphinx-panels \
+# 	dev-python/pydata-sphinx-theme \
+# 	dev-python/sphinx-multiversion
+
+python_prepare_all() {
+	# move docs into workdir
+	mv ../spyder-docs-${DOCS_PV}* docs || die
+
+	# these dependencies are packaged separately:
+	#    dev-python/spyder-kernels,
+	#    dev-python/python-lsp-server,
+	#    dev-python/qdarkstyle
+	rm -r external-deps/* || die
+	# runs against things packaged in external-deps dir
+	rm conftest.py || die
+
+	# Do not depend on pyqt5<5.16, this dependency is carried by QtPy[pyqt5]
+	# Do not depend on pyqtwebengine<5.16, this dependency is carried by QtPy[webengine]
+	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
+	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
+	# Do not depend on ipython, this dependency is carried in spyder-kernels
+	# The explicit version requirements only make things more complicated, if e.g.
+	# pyls-spyder gains compatibility with a newer version of python-lsp-server
+	# in a new release it will take time for this information to propagate into
+	# the next spyder release. So just remove the dependency and let the other
+	# ebuilds handle the version requirements to speed things up and prevent
+	# issues such as Bug 803269.
+	sed -i \
+		-e "/'pyqt5[ 0-9<=>.,]*',/d" \
+		-e "/'pyqtwebengine[ 0-9<=>.,]*',/d" \
+		-e "/'python-lsp-server\[all\][ 0-9<=>.,]*',/d" \
+		-e "/'parso[ 0-9<=>.,]*',/d" \
+		-e "/'jedi[ 0-9<=>.,]*',/d" \
+		-e "/'pylint[ 0-9<=>.,]*',/d" \
+			setup.py || die
+		# -e "/'ipython[ 0-9<=>.,]*',/d" \
+	sed -i \
+		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
+		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
+		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
+		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
+		-e "/^PYLINT_REQVER/c\PYLINT_REQVER = '>=0.0.1'" \
+			spyder/dependencies.py || die
+		# -e "/^IPYTHON_REQVER/c\IPYTHON_REQVER = '>=0.0.1'" \
+
+	# do not check deps, fails because we removed dependencies above
+	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
+		spyder/tests/test_dependencies_in_sync.py || die
+
+	# skip online test
+	rm spyder/widgets/github/tests/test_github_backend.py || die
+
+	export SPYDER_QT_BINDING=pyqt6
+
+	distutils-r1_python_prepare_all
+}
+
+# Calling pytest directly somehow passes the pytest arguments to spyder
+# causing an invalid argument error
+# python_test() {
+# 	virtx "${EPYTHON}" runtests.py
+# }
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
+	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
+	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
+	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
+	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
+	optfeature "Run Cython files in the IPython console" dev-python/cython
+	optfeature "The hdf5/h5py plugin" dev-python/h5py
+	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
+	optfeature "Vim key bindings" dev-python/spyder-vim
+	optfeature "Unittest support" dev-python/spyder-unittest
+	optfeature "System terminal inside spyder" dev-python/spyder-terminal
+	optfeature "Jupyter notebook support" dev-python/spyder-notebook
+	# spyder-memory-profiler is not compatible with spyder-5.2+ yet
+	# optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
+	# spyder-reports not yet updated to >=spyder-4.0.0
+	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
+	# Plugins with no release yet:
+	# optfeature "Manage virtual environments and packages" dev-python/spyder-env-manager
+	# optfeature "VCS (e.g. git) integration" dev-python/spyder-vcs
+}