Adding metadata

32 files changed, 647 insertions, 491 deletions

diff --git a/dev-python/aiofiles/aiofiles-23.2.1.ebuild b/dev-python/aiofiles/aiofiles-23.2.1.ebuild
index 1b8f3d34c1e5..5bd42ead1e35 100644
--- a/dev-python/aiofiles/aiofiles-23.2.1.ebuild
+++ b/dev-python/aiofiles/aiofiles-23.2.1.ebuild
@@ -16,7 +16,7 @@ HOMEPAGE="
 
 LICENSE="Apache-2.0"
 SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 
 BDEPEND="
 	test? (
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 595879496684..fe46e614089f 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -4,3 +4,4 @@ DIST boto3-1.34.29.gh.tar.gz 769654 BLAKE2B 3eec92f78f343c1806eb7ad96a31b07592ff
 DIST boto3-1.34.30.gh.tar.gz 770197 BLAKE2B d2eabd13c0c38fddf96caed27e57c7558f5639daa343b5331c6f6d6a82eb2cd95819e77c389e05676c104a51d398515e68562fd3da8e54f7c0febf6a1d0d2419 SHA512 b0d3924ee4413f3cdb4a6efc11b30af944d6e183f5b5d49ae39b3da05f3794739f0d66c19bde0ab32243ea9ae16cbc43c042ad41b8fabff58a3a704978f9f309
 DIST boto3-1.34.31.gh.tar.gz 770337 BLAKE2B d39a6d173fbe5ddcf305260a36d5788dd920d387e28d6f8ad32f304a2e42fce04f5527568e261bfade2a3c6dca29c1519177df1c881d59b4f88e484cd6302b9f SHA512 50828306a5da7cbdfc0a1e3028da15c6db6d54d36c1c8e641f777c6b62d4fcead9a6239c7a72667b219b3cfbc9e1008e47ee16ab60deda24cf0d88136ed52d5e
 DIST boto3-1.34.32.gh.tar.gz 770755 BLAKE2B 4e2c47833d41539fb6c489ecca4d907e2ebed00e7a7ad801c839763e8001478c0be65d7db83f30b981684075549f8a2a2fce56fe6d1574ccc4d4ca2e2f46956b SHA512 33743754aed8e6bbca2fccd932719eb30065cddb57a13ff24538e539be4aaff023271a6daa7d974e3ea5048dd35734ebb04680393a7991671ef88719b94cad35
+DIST boto3-1.34.33.gh.tar.gz 771413 BLAKE2B 44322f09244e39950e481737366430d31f1a12104b426d896382f12c84439412a729b6f919ac9fd66eab51b394a826a3a3f39176b9d21ab5d27d69aa9ae2df9f SHA512 8d34ff6d05bd32f10308ac0063f062376da005d7cec65842c264079fc7cc5d87807dd32140092c6147576c27d4c465f3cd8850abaf06f2c9b9ab53c21052bea5
diff --git a/dev-python/boto3/boto3-1.34.33.ebuild b/dev-python/boto3/boto3-1.34.33.ebuild
new file mode 100644
index 000000000000..c6201d2c5818
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.33.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index dfbfd0f52d75..3d912bdda51d 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -4,3 +4,4 @@ DIST botocore-1.34.29.gh.tar.gz 12665018 BLAKE2B 928c27ae62a5e2675dc5476af05a439
 DIST botocore-1.34.30.gh.tar.gz 12666051 BLAKE2B b6a19b4145b17855a65ecfd89150613b460616413f55b112df54dd60fbd946d7bee1f33d615e859e9f56e49328ddb91cb9e1c9b350686a37eccb1892850dbdf0 SHA512 8ce09d2ffa190fb50fd2a9b98ad0bf36de886d5b9f2a0e833e425a0bbfedca7f98b8de50240eaa81d1b01b68bbc96f6fce706b0547a508140e615aa9c3927c26
 DIST botocore-1.34.31.gh.tar.gz 12665042 BLAKE2B 2cf79fb1ea31921fd9c285b71d66fc645e3d22d599533eb30754c0b39337c871ac1d660bfe0786eccd9bc8d8e03c573cef00ab0363403e387df4fcffa9ad5fb3 SHA512 a740897de2c375b668b56af5ff6da3dd01b5420dcf4ae4a5f9805267c6b33f25364e16a1c2c199b18a95d6ed222be71ad9c6ba033cd0b45daf101f8b33c2b0b7
 DIST botocore-1.34.32.gh.tar.gz 12673734 BLAKE2B d9661e779e087c1628267b936f59991a39acae836e57e118b86bc51beeec8eb88898a66f461bbcd26479b12cc7acf22371a52dfde10198ddb2a48a6d5ac29c84 SHA512 1d9a119dfb91dc73e2011becbc06b38a87ac73386a9e05741a220303a5b886d45aeac425b34c68196606591d5e6d6e82f3883494fa9f28bea532d7bdd57a5620
+DIST botocore-1.34.33.gh.tar.gz 12682547 BLAKE2B a14d110e971bdfe1bebb6dd949f27712cd079c4d23b7f4a683389c6601400eb52c5f8ba92a2cd9fb6fcfb0d709b514af16235dd9a0288e89e4ce7bfe99c7cb11 SHA512 75c7b37e97b246bb7eb628340d1fc15b0c01e42ac0d545d7d28807e2bcb2b4bd3eb365d7574ae5cf0c6429c8e3e3d25d5d2317ee471a808d069a665ba6e09090
diff --git a/dev-python/botocore/botocore-1.34.33.ebuild b/dev-python/botocore/botocore-1.34.33.ebuild
new file mode 100644
index 000000000000..fd76f2226b9c
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.33.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x EPYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/cachecontrol/Manifest b/dev-python/cachecontrol/Manifest
index 898f5abecb13..32946412bb21 100644
--- a/dev-python/cachecontrol/Manifest
+++ b/dev-python/cachecontrol/Manifest
@@ -1 +1,2 @@
 DIST cachecontrol-0.13.1.tar.gz 29069 BLAKE2B d244d62338fd3aa9fb37b22c5fb6f69191b91d63621808c8bb5b4e9dd66ac3a6aa9087d435b06669d4303c4126ee63c0c3bd930c267e0de09b6c11d7dc8ec89c SHA512 9814e074f6b7adabc0d9601193128f247110303930178f3d5dfa6d992f679ed9144398a9b995320ea13e7abe95ea52aa910e5e3ec773b2245db9fc3fe08c9d76
+DIST cachecontrol-0.14.0.tar.gz 28899 BLAKE2B 158d70333b8e5cbbee31db788c9737a92592c3c342d17e4e1ff4826759e3fe14eb855556f9363c122fbf3fd68ca43a78b34b3327260fe51a15b30dde01302508 SHA512 4bb43475d43a2b83f9196cf02af7a881ab37da3b481777f1ae6b24df0f7dab54629fcdf9e07b00e1226a7707f5c92b0473481ef7cbbcaa4275665a41487c903f
diff --git a/dev-python/cachecontrol/cachecontrol-0.14.0.ebuild b/dev-python/cachecontrol/cachecontrol-0.14.0.ebuild
new file mode 100644
index 000000000000..ec236097276c
--- /dev/null
+++ b/dev-python/cachecontrol/cachecontrol-0.14.0.ebuild
@@ -0,0 +1,33 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="httplib2 caching for requests"
+HOMEPAGE="
+	https://pypi.org/project/CacheControl/
+	https://github.com/psf/cachecontrol/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/msgpack-2[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/cherrypy[${PYTHON_USEDEP}]
+		>=dev-python/filelock-3.8.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/django-debug-toolbar/Manifest b/dev-python/django-debug-toolbar/Manifest
index fe8b6a3f728c..9d3db59fb928 100644
--- a/dev-python/django-debug-toolbar/Manifest
+++ b/dev-python/django-debug-toolbar/Manifest
@@ -1 +1,2 @@
 DIST django_debug_toolbar-4.2.0.tar.gz 259709 BLAKE2B 81172bca569f6080710db2180650b0620670a4b4d2919d8b1694bf9f15425d9378f6cd0cbb852544fca0809388bb13867500a38c9046e1feaa241cde973936d9 SHA512 ff36d92132fd9338e88a2f078747c1e54e7633aecc6babea28ccb0c080b0beb99feccf1d1c00960ba109e3e6e4805562c36c6571842ea3baeda860c71ffcbd50
+DIST django_debug_toolbar-4.3.0.tar.gz 261173 BLAKE2B d5332d205be3a08826ac8b1bf1cb1ed8cd06b66cd5efb203a4290c9e75aab96c822d46c93830182cf6bd6fe2b867e14d5a82d52f6f72aebeaa9aa8ff1bc4e558 SHA512 48e06187289fc92216e5d7c0a77f88ce2fd105eef5ae2bc8dd0d398929c86a9fe021ea1f88f03083174f846f7e43cd07353e1175694733bfa0d55e4aa612c7f3
diff --git a/dev-python/django-debug-toolbar/django-debug-toolbar-4.3.0.ebuild b/dev-python/django-debug-toolbar/django-debug-toolbar-4.3.0.ebuild
new file mode 100644
index 000000000000..e583aff46728
--- /dev/null
+++ b/dev-python/django-debug-toolbar/django-debug-toolbar-4.3.0.ebuild
@@ -0,0 +1,36 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A configurable set of panels that display various debug information"
+HOMEPAGE="
+	https://github.com/jazzband/django-debug-toolbar/
+	https://pypi.org/project/django-debug-toolbar/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/django[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/html5lib[${PYTHON_USEDEP}]
+	)
+"
+
+python_test() {
+	"${EPYTHON}" -m django test -v 2 --settings tests.settings \
+		|| die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index a11d7c268c91..e9da2ac43cac 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1 +1,3 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
+EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
+MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch b/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
deleted file mode 100644
index 637368d2f237..000000000000
--- a/dev-python/langdetect/files/langdetect-1.0.9-explicit-config.patch
+++ /dev/null
@@ -1,13 +0,0 @@
-Fix "Package 'langdetect.profiles' is absent from the `packages` configuration."
-
---- a/setup.py
-+++ b/setup.py
-@@ -18,7 +18,7 @@ setup(
-     author_email='michal.danilak@gmail.com',
-     url='https://github.com/Mimino666/langdetect',
-     keywords='language detection library',
--    packages=['langdetect', 'langdetect.utils', 'langdetect.tests'],
-+    packages=['langdetect', 'langdetect.utils', 'langdetect.tests', 'langdetect.profiles'],
-     include_package_data=True,
-     install_requires=['six'],
-     license='MIT',
diff --git a/dev-python/langdetect/langdetect-1.0.9.ebuild b/dev-python/langdetect/langdetect-1.0.9.ebuild
index 630fe63c6f53..c09b7356f549 100644
--- a/dev-python/langdetect/langdetect-1.0.9.ebuild
+++ b/dev-python/langdetect/langdetect-1.0.9.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2022-2024 Gentoo Authors
+# Copyright 2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -19,6 +19,4 @@ KEYWORDS="~amd64"
 
 RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 
-PATCHES=( "${FILESDIR}/${P}-explicit-config.patch" )
-
 distutils_enable_tests unittest
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 736a1167c898..020e07f2a3dd 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,6 +1,12 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- 
- <origin>gentoo-guru-overlay</origin>
+ <maintainer type="person">
+  <email>marcin.deranek@slonko.net</email>
+  <name>Marcin Deranek</name>
+ </maintainer>
+ <upstream>
+  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
+ </upstream>
+ <origin>slonko-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pydevd/Manifest b/dev-python/pydevd/Manifest
index cf94d827df04..aac1fef617ef 100644
--- a/dev-python/pydevd/Manifest
+++ b/dev-python/pydevd/Manifest
@@ -1,2 +1,3 @@
 DIST PyDev.Debugger-pydev_debugger_2_10_0.gh.tar.gz 4019265 BLAKE2B e72c96576588ac3cbfcdd71a1a8e96d41b9d6757b3468c372b45a9c91a887c693f7309467fe8ea27d29c4775cc8df9ebd610b015cecabaaea43c8aa75229bc25 SHA512 a475e4f4cd9f883307d30b0bb2ebd5095de426b52f0f70b1a557095c06241149ad105ca4cbb31d311fa54e4387bbed27e5cf2712ba7447b19720d46dac21a101
+DIST PyDev.Debugger-pydev_debugger_3_0_3.gh.tar.gz 4287855 BLAKE2B 2f9f9cc892a19e42a37190966f2d2897f3e5da477c88d76d4b61b3062b6482db4c4cf5672efe75a1c139aa42a6b017cb5b276cede1167d0e91ca50009706e7e7 SHA512 4a5d03ea69e9eb40ee09c8d9a2258655f1645076757fa02bf92c8ad1b4fbb0570c1ac55464d8dd44cea6187ad2fa858851e02a86dc18b2343411cd8c56dc0c6a
 DIST pydevd-2.9.5.gh.tar.gz 3982897 BLAKE2B 06f0712301b419c472bcef2443a2ed277eb477041ff2e40e41b57f61649d84a7559dcae82c30ac572b14e90b98c2b9b9542c7360deded087eec92aeb0372ad67 SHA512 9aa38bc9a238e6f2956883a6318536382726013ea9e4a9d902b36d60df0cf924c279545bcdf92afdb435bfe36598982edd5805725860798fb3970b105254ba1d
diff --git a/dev-python/pydevd/pydevd-3.0.3.ebuild b/dev-python/pydevd/pydevd-3.0.3.ebuild
new file mode 100644
index 000000000000..97012703eece
--- /dev/null
+++ b/dev-python/pydevd/pydevd-3.0.3.ebuild
@@ -0,0 +1,134 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 toolchain-funcs
+
+TAG="pydev_debugger_${PV//./_}"
+MY_P="PyDev.Debugger-${TAG}"
+DESCRIPTION="PyDev.Debugger (used in PyDev, PyCharm and VSCode Python)"
+HOMEPAGE="
+	https://github.com/fabioz/PyDev.Debugger/
+	https://pypi.org/project/pydevd/
+"
+SRC_URI="
+	https://github.com/fabioz/PyDev.Debugger/archive/${TAG}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="EPL-1.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-debug/gdb
+"
+BDEPEND="
+	test? (
+		dev-python/untangle[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# Drop -O3 and -flto compiler args
+	sed -i \
+		-e 's/extra_link_args = extra_compile_args\[\:\]/pass/g' \
+		-e '/extra_compile_args/d' \
+		setup.py || die
+
+	# Disable tests incompatible with new package versions
+	sed -e '/TEST_\(DJANGO\|FLASK\)/s:True:False:' \
+		-i tests_python/debug_constants.py || die
+
+	# Clean up some prebuilt files
+	rm -r third_party || die
+	cd pydevd_attach_to_process || die
+
+	# Remove these Windows files
+	rm attach_{amd64,x86}.dll || die
+	rm inject_dll_{amd64,x86}.exe || die
+	rm run_code_on_dllmain_{amd64,x86}.dll || die
+	rm -r windows winappdbg || die
+
+	# Remove these MacOS files
+	rm attach_x86_64.dylib || die
+
+	# Remove these prebuilt linux files
+	rm attach_linux_{amd64,x86}.so || die
+
+	cd linux_and_mac || die
+	rm compile_mac.sh || die
+}
+
+src_compile() {
+	pushd pydevd_attach_to_process/linux_and_mac || die
+	# recompile removed file (extracted from compile_linux.sh)
+	$(tc-getBUILD_CXX) ${CXXFLAGS} ${CPPFLAGS} \
+		-o "../attach_linux_${ARCH}.so" \
+		${LDFLAGS} -nostartfiles attach.cpp -ldl || die
+	popd || die
+
+	distutils-r1_src_compile
+
+	# C extensions
+	rm -r _pydevd* || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		# NB: upstream seems to run tests via runfiles.py but that script
+		# is a horror and it seems broken for us anyway
+		tests_python/test_debugger.py::test_attach_to_pid_halted
+		tests_python/test_debugger.py::test_attach_to_pid_no_threads
+		'tests_python/test_debugger.py::test_path_translation[False]'
+		tests_python/test_debugger_json.py::test_attach_to_pid
+		tests_python/test_debugger_json.py::test_evaluate_exception_trace
+		tests_python/test_debugger_json.py::test_gui_event_loop_custom
+		tests_python/test_debugger_json.py::test_path_translation_and_source_reference
+		tests_python/test_utilities.py::test_tracing_basic
+		tests_python/test_utilities.py::test_tracing_other_threads
+		# incompatible with xdist
+		tests_python/test_utilities.py::test_is_main_thread
+	)
+
+	case ${EPYTHON} in
+		python3.10)
+			EPYTEST_DESELECT+=(
+				tests_python/test_debugger.py::test_frame_eval_limitations
+			)
+			;&
+		python3.11)
+			EPYTEST_DESELECT+=(
+				tests_python/test_debugger.py::test_remote_debugger_threads
+			)
+			;;
+	esac
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# this is only used to compare against getpid() to detect that xdist
+	# is being used
+	local -x PYDEV_MAIN_PID=1
+	epytest -p rerunfailures --reruns=5
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# Remove this duplicate that is installed directly to /usr/
+	# These files are also correctly installed to the python site-packages dir
+	rm -r "${ED}/usr/pydevd_attach_to_process" || die
+}
diff --git a/dev-python/pyopencl/Manifest b/dev-python/pyopencl/Manifest
index e950e0a69346..70fe16772fd4 100644
--- a/dev-python/pyopencl/Manifest
+++ b/dev-python/pyopencl/Manifest
@@ -1 +1,2 @@
 DIST pyopencl-2023.1.4.tar.gz 473899 BLAKE2B 7d836d77b14f89b6dbf0dd2a189f3cb9442f224ff5c9c9db902aa93dc582278450b3d47576885bbe3738ee25f979a260d5c6f906366279adc30be7d3cc3545e1 SHA512 2508d21856d9b846bce14bcd11d007eedddc1cc5c1ce9f8d2ac18743ab9aa5d673c85792b535779b2f414caf47e39ed53c07d7ee8a061bcfa020a15f59463861
+DIST pyopencl-2024.1.tar.gz 473860 BLAKE2B 803c92418a609f3ad9249c81e93af0bd2e9125ee56dc88af8ee6ae9c4a275c7ab37befddd575914eb9f0b295aaef4f135358669e384a55c04b3938b02572724d SHA512 abf27d67f8c3633c71e662938a919c88a34b0b66cc3c213644f92a8733aed3c9b7593542dd9b45a080941976dadeb4f49a23a986482110824b554e3a0d317176
diff --git a/dev-python/pyopencl/pyopencl-2024.1.ebuild b/dev-python/pyopencl/pyopencl-2024.1.ebuild
new file mode 100644
index 000000000000..8483dac1a8fa
--- /dev/null
+++ b/dev-python/pyopencl/pyopencl-2024.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 multiprocessing pypi
+
+DESCRIPTION="Python wrapper for OpenCL"
+HOMEPAGE="
+	https://mathema.tician.de/software/pyopencl/
+	https://pypi.org/project/pyopencl/
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~riscv"
+IUSE="examples opengl"
+
+# Running tests on GPUs requires both appropriate hardware and additional permissions
+# having been granted to the user running them. Testing on CPUs with dev-libs/pocl
+# is in theory possible but has been found to be very fragile, see e.g. Bug #872308.
+RESTRICT="test"
+
+COMMON=">=virtual/opencl-2"
+# libglvnd is only needed for the headers
+DEPEND="${COMMON}
+	opengl? ( media-libs/libglvnd )"
+RDEPEND="${COMMON}
+	>=dev-python/mako-0.3.6[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pytools-2021.2.7[${PYTHON_USEDEP}]"
+BDEPEND="dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pybind11-2.5.0[${PYTHON_USEDEP}]
+	test? ( dev-libs/pocl )"
+
+distutils_enable_tests pytest
+
+python_configure_all() {
+	local myconf=()
+	if use opengl; then
+		myconf+=(--cl-enable-gl)
+	fi
+
+	"${EPYTHON}" configure.py \
+		"${myconf[@]}"
+}
+
+python_test() {
+	# Use dev-libs/pocl for testing; ignore any other OpenCL devices that might be present
+	local -x PYOPENCL_TEST="portable:pthread"
+	# Set the number of threads to match MAKEOPTS
+	local -x POCL_MAX_PTHREAD_COUNT=$(makeopts_jobs)
+	# Change to the 'test' directory so that python does not try to import pyopencl from the source directory
+	# (Importing from the source directory fails, because the compiled '_cl' module is only in the build directory)
+	pushd test >/dev/null || die
+	epytest
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/pyside2-tools/Manifest b/dev-python/pyside2-tools/Manifest
index cc4972e72deb..add932021544 100644
--- a/dev-python/pyside2-tools/Manifest
+++ b/dev-python/pyside2-tools/Manifest
@@ -1,2 +1 @@
-DIST pyside-setup-opensource-src-5.15.11.tar.xz 3584760 BLAKE2B c4d60439a218451eb0c505031524fe1e30a117b7e89a28b5cd7518c193a8d2de01a5db8cb3acdd97c81da6dddff99f786c6c763427f78cdd0af4031122ac2d24 SHA512 377b3f6a793313cf7f5bea0dcef6630bac32d79b247e213d0b1b719805b35692aa8dd9a8896c75c6266f05af38809f574051d64b1a2f958a48c90167feccfb91
 DIST pyside-setup-opensource-src-5.15.12.tar.xz 3585204 BLAKE2B a664555b5a98d5ebda39c8226062e12c2b3308e6d95866cd9268de6a8089aef5d0e7a4958821a8e84642f01bffe2a9323ba0752d33fc803d4eb4b29453e2f070 SHA512 843d7352bfb7c9765b5033939b2a6211148ad79a6012685b2d07775745edf04c8420359efb2a3ae4a8686de4daaeb7f531f73fd152f0a2fe7dd54de0080c3cf4
diff --git a/dev-python/pyside2-tools/pyside2-tools-5.15.11-r1.ebuild b/dev-python/pyside2-tools/pyside2-tools-5.15.11-r1.ebuild
deleted file mode 100644
index 22e576b3e256..000000000000
--- a/dev-python/pyside2-tools/pyside2-tools-5.15.11-r1.ebuild
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# TODO: Add PyPy once officially supported. See also:
-#     https://bugreports.qt.io/browse/PYSIDE-535
-PYTHON_COMPAT=( python3_{10..11} )
-
-inherit cmake python-r1
-
-MY_P=pyside-setup-opensource-src-${PV}
-
-DESCRIPTION="PySide development tools (pyside2-lupdate with support for Python)"
-HOMEPAGE="https://wiki.qt.io/PySide2"
-SRC_URI="https://download.qt.io/official_releases/QtForPython/pyside2/PySide2-${PV}-src/${MY_P}.tar.xz"
-S="${WORKDIR}/${MY_P}/sources/${PN}"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-RDEPEND="${PYTHON_DEPS}
-	~dev-python/pyside2-${PV}[${PYTHON_USEDEP}]
-"
-DEPEND="${RDEPEND}"
-
-# the tools conflict with tools from QT
-PATCHES=(
-	"${FILESDIR}/${PN}-5.15.11-no-copy-uic.patch"
-)
-
-src_prepare() {
-	cmake_src_prepare
-
-	python_copy_sources
-}
-
-src_configure() {
-	pyside-tools_configure() {
-		local mycmakeargs=(
-			-DBUILD_TESTS=OFF
-			-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}"
-		)
-		cmake_src_configure
-	}
-
-	python_foreach_impl pyside-tools_configure
-}
-
-src_compile() {
-	pyside-tools_compile() {
-		cmake_src_compile
-	}
-
-	python_foreach_impl pyside-tools_compile
-}
-
-src_install() {
-	pyside-tools_install() {
-		# This replicates the contents of the PySide6 pypi wheel
-		DESTDIR="${BUILD_DIR}" cmake_build install
-		dobin "${BUILD_DIR}/usr/bin/pyside2-lupdate"
-		python_moduleinto PySide2/scripts
-		python_domodule "${BUILD_DIR}/usr/bin/pyside_tool.py"
-	}
-
-	python_foreach_impl pyside-tools_install
-
-	einstalldocs
-}
diff --git a/dev-python/pyside2/Manifest b/dev-python/pyside2/Manifest
index cc4972e72deb..add932021544 100644
--- a/dev-python/pyside2/Manifest
+++ b/dev-python/pyside2/Manifest
@@ -1,2 +1 @@
-DIST pyside-setup-opensource-src-5.15.11.tar.xz 3584760 BLAKE2B c4d60439a218451eb0c505031524fe1e30a117b7e89a28b5cd7518c193a8d2de01a5db8cb3acdd97c81da6dddff99f786c6c763427f78cdd0af4031122ac2d24 SHA512 377b3f6a793313cf7f5bea0dcef6630bac32d79b247e213d0b1b719805b35692aa8dd9a8896c75c6266f05af38809f574051d64b1a2f958a48c90167feccfb91
 DIST pyside-setup-opensource-src-5.15.12.tar.xz 3585204 BLAKE2B a664555b5a98d5ebda39c8226062e12c2b3308e6d95866cd9268de6a8089aef5d0e7a4958821a8e84642f01bffe2a9323ba0752d33fc803d4eb4b29453e2f070 SHA512 843d7352bfb7c9765b5033939b2a6211148ad79a6012685b2d07775745edf04c8420359efb2a3ae4a8686de4daaeb7f531f73fd152f0a2fe7dd54de0080c3cf4
diff --git a/dev-python/pyside2/pyside2-5.15.11-r1.ebuild b/dev-python/pyside2/pyside2-5.15.11-r1.ebuild
deleted file mode 100644
index 5ef575602cfe..000000000000
--- a/dev-python/pyside2/pyside2-5.15.11-r1.ebuild
+++ /dev/null
@@ -1,222 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# TODO: Add PyPy once officially supported. See also:
-#     https://bugreports.qt.io/browse/PYSIDE-535
-PYTHON_COMPAT=( python3_{10..11} )
-
-inherit cmake python-r1 virtualx
-
-# TODO: Add conditional support for "QtRemoteObjects" via a new "remoteobjects"
-# USE flag after an external "dev-qt/qtremoteobjects" package has been created.
-# TODO: Add conditional support for apidoc generation via a new "doc" USE flag.
-# Note that doing so requires the Qt source tree, sphinx, and graphviz. Once
-# ready, pass the ${QT_SRC_DIR} variable to cmake to enable this support.
-# TODO: Disable GLES support if the "gles2-only" USE flag is disabled. Note
-# that the "PySide2/QtGui/CMakeLists.txt" and
-# "PySide2/QtOpenGLFunctions/CMakeLists.txt" files test for GLES support by
-# testing whether the "Qt5::Gui" list property defined by
-# "/usr/lib64/cmake/Qt5Gui/Qt5GuiConfig.cmake" at "dev-qt/qtgui" installation
-# time contains the substring "opengles2". Since cmake does not permit
-# properties to be overridden from the command line, these files must instead
-# be conditionally patched to avoid these tests. An issue should be filed with
-# upstream requesting a CLI-settable variable to control this.
-
-MY_P=pyside-setup-opensource-src-${PV}
-
-DESCRIPTION="Python bindings for the Qt framework"
-HOMEPAGE="https://wiki.qt.io/PySide2"
-SRC_URI="https://download.qt.io/official_releases/QtForPython/pyside2/PySide2-${PV}-src/${MY_P}.tar.xz"
-S="${WORKDIR}/${MY_P}/sources/pyside2"
-
-# See "sources/pyside2/PySide2/licensecomment.txt" for licensing details.
-# Shall we allow essential modules to be disabled? They are:
-# (core), gui, widgets, printsupport, sql, network, testlib, concurrent,
-# x11extras (for X)
-LICENSE="|| ( GPL-2 GPL-3+ LGPL-3 )"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
-IUSE="
-	3d charts +concurrent datavis designer gles2-only +gui help location
-	multimedia +network positioning +printsupport qml quick
-	scxml sensors speech +sql svg test +testlib webchannel webengine websockets
-	+widgets +x11extras xml xmlpatterns
-"
-
-# Manually reextract these requirements on version bumps by running the
-# following one-liners from within "${S}":
-#     $ grep 'set.*_deps' PySide2/Qt*/CMakeLists.txt
-#     $ cat /lib64/cmake/Qt5*/Qt5*.cmake | grep -i DEPENDENCIES
-# Note that the "designer" USE flag corresponds to the "Qt5UiTools" module.
-REQUIRED_USE="${PYTHON_REQUIRED_USE}
-	3d? ( gui network )
-	charts? ( gui widgets )
-	datavis? ( gui )
-	designer? ( gui widgets xml )
-	gles2-only? ( gui )
-	help? ( gui sql widgets )
-	location? ( gui network positioning quick )
-	multimedia? ( gui network widgets )
-	printsupport? ( gui widgets )
-	qml? ( gui network )
-	quick? ( gui network qml widgets network )
-	speech? ( multimedia )
-	sql? ( widgets )
-	svg? ( widgets )
-	testlib? ( widgets )
-	webchannel? ( qml )
-	webengine? (
-		gui network positioning quick qml
-		widgets? ( printsupport network webchannel )
-	)
-	websockets? ( network )
-	widgets? ( gui )
-	x11extras? ( gui )
-"
-
-# Tests fail pretty bad and I'm not fixing them right now
-RESTRICT="test"
-
-# Minimal supported version of Qt.
-QT_PV="$(ver_cut 1-3)*:5"
-
-RDEPEND="${PYTHON_DEPS}
-	~dev-python/shiboken2-${PV}[${PYTHON_USEDEP}]
-	=dev-qt/qtcore-${QT_PV}
-	=dev-qt/qtopengl-${QT_PV}[gles2-only=]
-	=dev-qt/qtserialport-${QT_PV}
-	3d? ( =dev-qt/qt3d-${QT_PV}[qml?,gles2-only=] )
-	charts? ( =dev-qt/qtcharts-${QT_PV}[qml?] )
-	concurrent? ( =dev-qt/qtconcurrent-${QT_PV} )
-	datavis? ( =dev-qt/qtdatavis3d-${QT_PV}[qml?,gles2-only=] )
-	designer? ( =dev-qt/designer-${QT_PV} )
-	gui? ( =dev-qt/qtgui-${QT_PV}[jpeg,gles2-only=] )
-	help? ( =dev-qt/qthelp-${QT_PV} )
-	location? ( =dev-qt/qtlocation-${QT_PV} )
-	multimedia? ( =dev-qt/qtmultimedia-${QT_PV}[qml?,gles2-only=,widgets?] )
-	network? ( =dev-qt/qtnetwork-${QT_PV} )
-	positioning? ( =dev-qt/qtpositioning-${QT_PV}[qml?] )
-	printsupport? ( =dev-qt/qtprintsupport-${QT_PV}[gles2-only=] )
-	qml? ( =dev-qt/qtdeclarative-${QT_PV}[widgets?] )
-	quick? (
-		=dev-qt/qtdeclarative-${QT_PV}[widgets?]
-		=dev-qt/qtquickcontrols2-${QT_PV}[widgets?]
-	)
-	scxml? ( =dev-qt/qtscxml-${QT_PV} )
-	sensors? ( =dev-qt/qtsensors-${QT_PV}[qml?] )
-	speech? ( =dev-qt/qtspeech-${QT_PV} )
-	sql? ( =dev-qt/qtsql-${QT_PV} )
-	svg? ( =dev-qt/qtsvg-${QT_PV} )
-	testlib? ( =dev-qt/qttest-${QT_PV} )
-	webchannel? ( =dev-qt/qtwebchannel-${QT_PV}[qml] )
-	webengine? ( || (
-		=dev-qt/qtwebengine-${QT_PV}[alsa,widgets?]
-		=dev-qt/qtwebengine-${QT_PV}[pulseaudio,widgets?]
-		)
-	)
-	websockets? ( =dev-qt/qtwebsockets-${QT_PV}[qml?] )
-	widgets? ( =dev-qt/qtwidgets-${QT_PV}[gles2-only=] )
-	x11extras? ( =dev-qt/qtx11extras-${QT_PV} )
-	xml? ( =dev-qt/qtxml-${QT_PV} )
-	xmlpatterns? ( =dev-qt/qtxmlpatterns-${QT_PV}[qml?] )
-"
-DEPEND="${RDEPEND}
-	test? ( x11-misc/xvfb-run )
-"
-
-src_configure() {
-	# See COLLECT_MODULE_IF_FOUND macros in CMakeLists.txt
-	local mycmakeargs=(
-		-DBUILD_TESTS=$(usex test)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt53DAnimation=$(usex !3d)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt53DCore=$(usex !3d)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt53DExtras=$(usex !3d)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt53DInput=$(usex !3d)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt53DLogic=$(usex !3d)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt53DRender=$(usex !3d)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Charts=$(usex !charts)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Concurrent=$(usex !concurrent)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5DataVisualization=$(usex !datavis)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Designer=$(usex !designer)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Gui=$(usex !gui)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Help=$(usex !help)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Location=$(usex !location)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Multimedia=$(usex !multimedia)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5MultimediaWidgets=$(usex !multimedia yes $(usex !widgets))
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Network=$(usex !network)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Positioning=$(usex !positioning)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5PrintSupport=$(usex !printsupport)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Qml=$(usex !qml)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Quick=$(usex !quick)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5QuickControls2=$(usex !quick)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5QuickWidgets=$(usex !quick yes $(usex !widgets))
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Script=yes
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5ScriptTools=yes
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Scxml=$(usex !scxml)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Sensors=$(usex !sensors)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5TextToSpeech=$(usex !speech)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Sql=$(usex !sql)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Svg=$(usex !svg)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Test=$(usex !testlib)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5UiTools=$(usex !designer)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebChannel=$(usex !webchannel)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebEngine=$(usex !webengine)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebEngineCore=$(usex !webengine)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebEngineWidgets=$(usex !webengine yes $(usex !widgets))
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebSockets=$(usex !websockets)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Widgets=$(usex !widgets)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5X11Extras=$(usex !x11extras)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5Xml=$(usex !xml)
-		-DCMAKE_DISABLE_FIND_PACKAGE_Qt5XmlPatterns=$(usex !xmlpatterns)
-	)
-
-	pyside2_configure() {
-		local mycmakeargs=(
-			"${mycmakeargs[@]}"
-			-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}"
-			-DPYTHON_EXECUTABLE="${PYTHON}"
-			-DPYTHON_SITE_PACKAGES="$(python_get_sitedir)"
-			-DSHIBOKEN_PYTHON_SHARED_LIBRARY_SUFFIX="-${EPYTHON}"
-		)
-		cmake_src_configure
-	}
-	python_foreach_impl pyside2_configure
-}
-
-src_compile() {
-	python_foreach_impl cmake_src_compile
-}
-
-src_test() {
-	local -x PYTHONDONTWRITEBYTECODE
-	python_foreach_impl virtx cmake_src_test
-}
-
-src_install() {
-	pyside2_install() {
-		cmake_src_install
-		python_optimize
-
-		# Uniquify the shiboken2 pkgconfig dependency in the PySide2 pkgconfig
-		# file for the current Python target. See also:
-		#     https://github.com/leycec/raiagent/issues/73
-		sed -i -e 's~^Requires: shiboken2$~&-'${EPYTHON}'~' \
-			"${ED}/usr/$(get_libdir)"/pkgconfig/${PN}.pc || die
-
-		# Uniquify the PySide2 pkgconfig file for the current Python target,
-		# preserving an unversioned "pyside2.pc" file arbitrarily associated
-		# with the last Python target. (See the previously linked issue.)
-		cp "${ED}/usr/$(get_libdir)"/pkgconfig/${PN}{,-${EPYTHON}}.pc || die
-	}
-	python_foreach_impl pyside2_install
-
-	# CMakeLists.txt installs a "PySide2Targets-gentoo.cmake" file forcing
-	# downstream consumers (e.g., pyside2-tools) to target one
-	# "libpyside2-*.so" library linked to one Python interpreter. See also:
-	#     https://bugreports.qt.io/browse/PYSIDE-1053
-	#     https://github.com/leycec/raiagent/issues/74
-	sed -i -e 's~pyside2-python[[:digit:]]\+\.[[:digit:]]\+~pyside2${PYTHON_CONFIG_SUFFIX}~g' \
-		"${ED}/usr/$(get_libdir)"/cmake/PySide2*/PySide2Targets-${CMAKE_BUILD_TYPE,,}.cmake || die
-}
diff --git a/dev-python/pytz/Manifest b/dev-python/pytz/Manifest
index 51503712917b..c6b8a03995bf 100644
--- a/dev-python/pytz/Manifest
+++ b/dev-python/pytz/Manifest
@@ -1,2 +1,3 @@
 DIST pytz-2023.3.post1.tar.gz 316899 BLAKE2B 3274e11c38b34eae42089cacf92e537f1376fa721294ea2da3a68fe3491e7e95d1c88cb4687d1e83965be4730504373c72960f5dc5e9b6a8a339e541476515f4 SHA512 c2f1bd52e42c7d1014b8aebf3544b865eb5ae5e17146253406def72785af14bcfe34b9db6b71ca91a3c988c496fbe93e5d1731bee66349463c992be619d21f2c
 DIST pytz-2023.4.tar.gz 319467 BLAKE2B 59c27d2b6b748808edf81649ba08ca9230e9a14936f2307918c57fa69e5ff379d2dee1288252112bd718483e84ad1fafb551da222d26b01c4dd7c86424533993 SHA512 dc132f305d6f8f491a004f65fa823aa76713d324592ef474abfd5c0aafdf722d22386cf7f9140b2868f48e1309a64385204a129c0ed6c0bf8356844b92f13bb0
+DIST pytz-2024.1.tar.gz 316214 BLAKE2B 1047e11c41d3abeb10cdf55021c8702fbbb0c0dbcafc63c8c044ecf73dda2ac9344fc66e0a239302a0fd12856bbb3a7d49745eae671fac35db9c83fa502e7cf8 SHA512 cc1e4c9b34c62791cea277a0ce188d975e62135cb15bccfb49dc1a9366c7697ead9c67956846699f18b90db4c66e6c5fe1a91a524d01ae821c0eaa613550ea74
diff --git a/dev-python/pytz/pytz-2024.1.ebuild b/dev-python/pytz/pytz-2024.1.ebuild
new file mode 100644
index 000000000000..6a283f4adccb
--- /dev/null
+++ b/dev-python/pytz/pytz-2024.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="World timezone definitions for Python"
+HOMEPAGE="
+	https://pythonhosted.org/pytz/
+	https://github.com/stub42/pytz/
+	https://pypi.org/project/pytz/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	|| (
+		>=sys-libs/timezone-data-2023b
+		sys-libs/glibc[vanilla]
+	)
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+	)
+"
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unbundle timezone-data
+	rm -r pytz/zoneinfo || die
+	# remove hardcoded list of all timezones but leave subjective set
+	# of "common timezones"
+	sed -i -e '/^_all_timezones_unchecked/,/^all_timezones_set/d' pytz/__init__.py || die
+	eapply "${FILESDIR}"/pytz-2023.2-system-tzinfo.patch
+}
+
+python_test() {
+	"${EPYTHON}" pytz/tests/test_tzinfo.py -v ||
+		die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/quart-trio/quart-trio-0.11.1.ebuild b/dev-python/quart-trio/quart-trio-0.11.1.ebuild
index bf677bbd10b8..569e66ba722a 100644
--- a/dev-python/quart-trio/quart-trio-0.11.1.ebuild
+++ b/dev-python/quart-trio/quart-trio-0.11.1.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~arm ~arm64"
 
 RDEPEND="
 	>=dev-python/exceptiongroup-1.0.0[${PYTHON_USEDEP}]
diff --git a/dev-python/quart/quart-0.19.4.ebuild b/dev-python/quart/quart-0.19.4.ebuild
index edbffb9dc478..9ab22d0a0d1f 100644
--- a/dev-python/quart/quart-0.19.4.ebuild
+++ b/dev-python/quart/quart-0.19.4.ebuild
@@ -21,7 +21,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~amd64"
+KEYWORDS="~amd64 ~arm ~arm64"
 
 RDEPEND="
 	dev-python/aiofiles[${PYTHON_USEDEP}]
diff --git a/dev-python/shiboken2/Manifest b/dev-python/shiboken2/Manifest
index cc4972e72deb..add932021544 100644
--- a/dev-python/shiboken2/Manifest
+++ b/dev-python/shiboken2/Manifest
@@ -1,2 +1 @@
-DIST pyside-setup-opensource-src-5.15.11.tar.xz 3584760 BLAKE2B c4d60439a218451eb0c505031524fe1e30a117b7e89a28b5cd7518c193a8d2de01a5db8cb3acdd97c81da6dddff99f786c6c763427f78cdd0af4031122ac2d24 SHA512 377b3f6a793313cf7f5bea0dcef6630bac32d79b247e213d0b1b719805b35692aa8dd9a8896c75c6266f05af38809f574051d64b1a2f958a48c90167feccfb91
 DIST pyside-setup-opensource-src-5.15.12.tar.xz 3585204 BLAKE2B a664555b5a98d5ebda39c8226062e12c2b3308e6d95866cd9268de6a8089aef5d0e7a4958821a8e84642f01bffe2a9323ba0752d33fc803d4eb4b29453e2f070 SHA512 843d7352bfb7c9765b5033939b2a6211148ad79a6012685b2d07775745edf04c8420359efb2a3ae4a8686de4daaeb7f531f73fd152f0a2fe7dd54de0080c3cf4
diff --git a/dev-python/shiboken2/shiboken2-5.15.11.ebuild b/dev-python/shiboken2/shiboken2-5.15.11.ebuild
deleted file mode 100644
index d01c195c1218..000000000000
--- a/dev-python/shiboken2/shiboken2-5.15.11.ebuild
+++ /dev/null
@@ -1,173 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-# TODO: Split the "/usr/bin/shiboken2" binding generator from the
-# "/usr/lib64/libshiboken2-*.so" family of shared libraries. The former
-# requires everything (including Clang) at runtime; the latter only requires
-# Qt and Python at runtime. Note that "pip" separates these two as well. See:
-# https://doc.qt.io/qtforpython/shiboken2/faq.html#is-there-any-runtime-dependency-on-the-generated-binding
-# Once split, the PySide2 ebuild should be revised to require
-# "/usr/bin/shiboken2" at build time and "libshiboken2-*.so" at runtime.
-# TODO: Add PyPy once officially supported. See also:
-#     https://bugreports.qt.io/browse/PYSIDE-535
-PYTHON_COMPAT=( python3_{8,9,10,11,12} )
-
-inherit cmake llvm python-r1 toolchain-funcs
-
-MY_P=pyside-setup-opensource-src-${PV}
-
-DESCRIPTION="Python binding generator for C++ libraries"
-HOMEPAGE="https://wiki.qt.io/PySide2"
-SRC_URI="https://download.qt.io/official_releases/QtForPython/pyside2/PySide2-${PV}-src/${MY_P}.tar.xz"
-S="${WORKDIR}/${MY_P}/sources/shiboken2"
-
-# The "sources/shiboken2/libshiboken" directory is triple-licensed under the
-# GPL v2, v3+, and LGPL v3. All remaining files are licensed under the GPL v3
-# with version 1.0 of a Qt-specific exception enabling shiboken2 output to be
-# arbitrarily relicensed. (TODO)
-LICENSE="|| ( GPL-2 GPL-3+ LGPL-3 ) GPL-3"
-SLOT="0"
-KEYWORDS="amd64 ~arm arm64 ~ppc64 ~riscv x86"
-IUSE="+docstrings numpy test vulkan"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-
-# Tests fail pretty bad and I'm not fixing them right now
-RESTRICT="test"
-
-# Minimal supported version of Qt.
-QT_PV="$(ver_cut 1-3)*:5"
-
-# Since Clang is required at both build- and runtime, BDEPEND is omitted here.
-LLVM_MAX_SLOT=15
-RDEPEND="${PYTHON_DEPS}
-	=dev-qt/qtcore-${QT_PV}
-	<sys-devel/clang-16:=
-	<sys-devel/clang-runtime-16:=
-	docstrings? (
-		>=dev-libs/libxml2-2.6.32
-		>=dev-libs/libxslt-1.1.19
-		=dev-qt/qtxml-${QT_PV}
-		=dev-qt/qtxmlpatterns-${QT_PV}
-	)
-	numpy? ( dev-python/numpy[${PYTHON_USEDEP}] )
-	vulkan? ( dev-util/vulkan-headers )
-"
-DEPEND="${RDEPEND}
-	test? (	=dev-qt/qttest-${QT_PV}	)
-"
-
-DOCS=( AUTHORS )
-
-# Ensure the path returned by get_llvm_prefix() contains clang as well.
-llvm_check_deps() {
-	has_version "sys-devel/clang:${LLVM_SLOT}"
-}
-
-src_prepare() {
-	# TODO: File upstream issue requesting a sane way to disable NumPy support.
-	if ! use numpy; then
-		sed -i -e '/\bprint(os\.path\.realpath(numpy))/d' \
-			libshiboken/CMakeLists.txt || die
-	fi
-
-	# Shiboken2 assumes Vulkan headers live under either "$VULKAN_SDK/include"
-	# or "$VK_SDK_PATH/include" rather than "${EPREFIX}/usr/include/vulkan".
-	if use vulkan; then
-		sed -i -e "s~\bdetectVulkan(&headerPaths);~headerPaths.append(HeaderPath{QByteArrayLiteral(\"${EPREFIX}/usr/include/vulkan\"), HeaderType::System});~" \
-			ApiExtractor/clangparser/compilersupport.cpp || die
-	fi
-
-	local clangver="$(CPP=clang clang-major-version)"
-
-	# Clang 15 and older used the full version as a directory name.
-	if [[ ${clangver} -lt 16 ]]; then
-		clangver="$(CPP=clang clang-fullversion)"
-	fi
-
-	# Shiboken2 assumes the "/usr/lib/clang/${CLANG_NEWEST_VERSION}/include/"
-	# subdirectory provides Clang builtin includes (e.g., "stddef.h") for the
-	# currently installed version of Clang, where ${CLANG_NEWEST_VERSION} is
-	# the largest version specifier that exists under the "/usr/lib/clang/"
-	# subdirectory. This assumption is false in edge cases, including when
-	# users downgrade from newer Clang versions but fail to remove those
-	# versions with "emerge --depclean". See also:
-	#     https://github.com/leycec/raiagent/issues/85
-	#
-	# Sadly, the clang-* family of functions exported by the "toolchain-funcs"
-	# eclass are defective, returning nonsensical placeholder strings if the
-	# end user has *NOT* explicitly configured their C++ compiler to be Clang.
-	# PySide2 does *NOT* care whether the end user has done so or not, as
-	# PySide2 unconditionally requires Clang in either case. See also:
-	#     https://bugs.gentoo.org/619490
-	sed -i -e 's~(findClangBuiltInIncludesDir())~(QStringLiteral("'"${EPREFIX}"'/usr/lib/clang/'"${clangver}"'/include"))~' \
-		ApiExtractor/clangparser/compilersupport.cpp || die
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	# Minimal tests for now, 2 failing with the extended version
-	# FIXME Subscripted generics cannot be used with class and instance checks
-	local mycmakeargs=(
-		-DBUILD_TESTS=$(usex test)
-		-DDISABLE_DOCSTRINGS=$(usex !docstrings)
-	)
-
-	shiboken2_configure() {
-		local mycmakeargs=(
-			"${mycmakeargs[@]}"
-			-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}"
-			-DPYTHON_EXECUTABLE="${PYTHON}"
-			-DUSE_PYTHON_VERSION="${EPYTHON#python}"
-		)
-		# CMakeLists.txt expects LLVM_INSTALL_DIR as an environment variable.
-		local -x LLVM_INSTALL_DIR="$(get_llvm_prefix "${LLVM_MAX_SLOT}")"
-		cmake_src_configure
-	}
-	python_foreach_impl shiboken2_configure
-}
-
-src_compile() {
-	python_foreach_impl cmake_src_compile
-}
-
-src_test() {
-	python_foreach_impl cmake_src_test
-}
-
-src_install() {
-	shiboken2_install() {
-		cmake_src_install
-		python_optimize
-
-		# Uniquify the "shiboken2" executable for the current Python target,
-		# preserving an unversioned "shiboken2" file arbitrarily associated
-		# with the last Python target.
-		cp "${ED}"/usr/bin/${PN}{,-${EPYTHON}} || die
-
-		# Uniquify the Shiboken2 pkgconfig file for the current Python target,
-		# preserving an unversioned "shiboken2.pc" file arbitrarily associated
-		# with the last Python target. See also:
-		#     https://github.com/leycec/raiagent/issues/73
-		cp "${ED}/usr/$(get_libdir)"/pkgconfig/${PN}{,-${EPYTHON}}.pc || die
-	}
-	python_foreach_impl shiboken2_install
-
-	# CMakeLists.txt installs a "Shiboken2Targets-gentoo.cmake" file forcing
-	# downstream consumers (e.g., PySide2) to target one "libshiboken2-*.so"
-	# library and one "shiboken2" executable linked to one Python interpreter.
-	# See also:
-	#     https://bugreports.qt.io/browse/PYSIDE-1053
-	#     https://github.com/leycec/raiagent/issues/74
-	sed -i \
-		-e 's~shiboken2-python[[:digit:]]\+\.[[:digit:]]\+~shiboken2${PYTHON_CONFIG_SUFFIX}~g' \
-		-e 's~/bin/shiboken2~/bin/shiboken2${PYTHON_CONFIG_SUFFIX}~g' \
-		"${ED}/usr/$(get_libdir)"/cmake/Shiboken2*/Shiboken2Targets-${CMAKE_BUILD_TYPE,,}.cmake || die
-
-	# Remove the broken "shiboken_tool.py" script. By inspection, this script
-	# reduces to a noop. Moreover, this script raises the following exception:
-	#     FileNotFoundError: [Errno 2] No such file or directory: '/usr/bin/../shiboken_tool.py': '/usr/bin/../shiboken_tool.py'
-	rm "${ED}"/usr/bin/shiboken_tool.py || die
-}
diff --git a/dev-python/stripe/Manifest b/dev-python/stripe/Manifest
index c2827bc3ad84..eb9c0019afc4 100644
--- a/dev-python/stripe/Manifest
+++ b/dev-python/stripe/Manifest
@@ -3,3 +3,4 @@ DIST stripe-7.12.0.tar.gz 783948 BLAKE2B 063df7bbc118847bdee35f2919bd8023f4d58b5
 DIST stripe-7.13.0.tar.gz 789362 BLAKE2B 326a8b0987ffc7b9bcca2c3fbff548770223a6e153ac4b04fdfe70c400ce0b7d06d40182727ca2fc0ab700f57133481510aec9432c6582dec2a34eba57e682fe SHA512 0ed4d7d1781236f8e6bb3685680f59cf9c3bdf8645e0f5cd17753d079e42965660666ec76cb65ee6d4145514706fd39f6c0f1af331033d0eb3f47f8445082be7
 DIST stripe-7.14.0.tar.gz 793052 BLAKE2B fa0cf2c57a1cc6ab2eccfa5c1882e2b0ef62d3d92b392ab23df495c93dad52b43e609c1938af4403a3d1c87d9d73b08a9536d01ca5a7f98a5caebcbaf894d5be SHA512 c40b1a3a4c5af132b30402e9f3860fd2e463e2ca263bc4a072975a744a86e3659c9499cab2ed8f10dd076bb896c2ae4d8a79d8307e2307b598ebe24728a81025
 DIST stripe-8.0.0.tar.gz 1070432 BLAKE2B 9f0b605d1c2c5f58dafcc78fb3d4878406c466b92475d08510116352325f5ba6ff3dc379fbd914b25faac7ced7e3fe5f52eecabbff5c479eaaf567cdbcb6a900 SHA512 c5ed151b41e3b2b11d502d51aad7c5c575e6ff151dcab8ffd86e32b4f37eeb1a6e381380b123802af938bb2adfbdda8a71c00e9e0b68e9493469cc6a90d94185
+DIST stripe-8.1.0.tar.gz 1065303 BLAKE2B be82278fa4b401c0259e5d48a4d232557cda98771254cec5dddd7ef5bcd2896e7545d9a3463c9d27da5b6df0b98ff07de292888c00c92fa51f4ebe1b04806e7b SHA512 fbc2c7d3d8da5d0ba261c38bd9371df26beab4a509c86fac6f759678fe8fb387a178bcf49b4cf4a10d44469bbac1626a0bc79d5ba99797f6fbdaa7fc5fdd34b4
diff --git a/dev-python/stripe/stripe-8.1.0.ebuild b/dev-python/stripe/stripe-8.1.0.ebuild
new file mode 100644
index 000000000000..0a616061ffd8
--- /dev/null
+++ b/dev-python/stripe/stripe-8.1.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Stripe python bindings"
+HOMEPAGE="
+	https://github.com/stripe/stripe-python/
+	https://pypi.org/project/stripe/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="telemetry"
+
+RDEPEND="
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
+"
+# please bump dev-util/stripe-mock dep to the latest version on every bump
+BDEPEND="
+	test? (
+		>=dev-util/stripe-mock-0.181.0
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		net-misc/curl
+	)
+"
+
+distutils_enable_tests pytest
+
+DOCS=( LONG_DESCRIPTION.rst CHANGELOG.md README.md )
+
+src_prepare() {
+	if ! use telemetry; then
+		sed -i -e '/enable_telemetry/s:True:False:' stripe/__init__.py || die
+	fi
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests -p pytest_mock
+}
+
+src_test() {
+	local stripe_mock_port=12111
+	local stripe_mock_max_port=12121
+	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
+	# Try to start stripe-mock until we find a free port
+	while [[ ${stripe_mock_port} -le ${stripe_mock_max_port} ]]; do
+		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
+		stripe-mock --http-port "${stripe_mock_port}" &> "${stripe_mock_logfile}" &
+		local stripe_mock_pid=${!}
+		sleep 2
+		# Did stripe-mock start?
+		curl --fail -u "sk_test_123:" \
+			"http://127.0.0.1:${stripe_mock_port}/v1/customers" &> /dev/null
+		eend ${?} "Port ${stripe_mock_port} unavailable"
+		if [[ ${?} -eq 0 ]]; then
+			einfo "stripe-mock running on port ${stripe_mock_port}"
+			break
+		fi
+		(( stripe_mock_port++ ))
+	done
+	if [[ ${stripe_mock_port} -gt ${stripe_mock_max_port} ]]; then
+		eerror "Unable to start stripe-mock for tests"
+		die "Please see the logfile located at: ${stripe_mock_logfile}"
+	fi
+
+	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
+	distutils-r1_src_test
+
+	# Tear down stripe-mock
+	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
+}
diff --git a/dev-python/urllib3/Manifest b/dev-python/urllib3/Manifest
index 855662b68156..47e287b8e799 100644
--- a/dev-python/urllib3/Manifest
+++ b/dev-python/urllib3/Manifest
@@ -1,3 +1,5 @@
+DIST hypercorn-d1719f8c1570cbd8e6a3719ffdb14a4d72880abb.gh.tar.gz 156216 BLAKE2B fcb5f49653401e6e4079e1c770d3cd407602d4d6764437b735bd4ec04191dec59cdc930822fa2aff726ee25cddd0f71fd457dedf31026bff1da121d93af8b768 SHA512 62d6787d88a2e716f0ac04fc49f6cdc586e473a660ee754ff66961922ae78bcc75d1f78b091e78557dd60f006e8e480114738c7b4ff71beac804e4fc9603240b
 DIST urllib3-1.26.18.tar.gz 305687 BLAKE2B f2f673761a8d80eee715a8726ba36ab6b09800fd4a4f03f27438553c36072e2abb5ff26cff71dcf30fd114f4d28c4ad9907533965b83c8a0581d3d4661904b70 SHA512 c89e93a032bf6b11375c06ef7c5abc1868f93e7655cfdca09e9bd939ad415d206ea159fe151ecd2e5f725e0e18a831c7a5382ad01dbc32264154fc8af7aec156
 DIST urllib3-2.0.7.tar.gz 282546 BLAKE2B d4fbb9e1d0b6d1f3c3d71efc3fc479c7b1c49f87ca849c387701fb0c8b4124082de6d83d958c8b2afc225a84b80e7665df857e7b0918ba50e4ad1431f8facc4d SHA512 ca21dd330cfc7f53e6f00a92be1df1d24acbe61b6ca31c52a272dccd6f50d1bb797eece9132860adc84c21a9bebc3030a12816081451fcb8384c11a6cd2d1e8b
 DIST urllib3-2.1.0.tar.gz 263900 BLAKE2B 9e0438a11b7178c5004c1253179bb6bfcb1fa8711db47084377bb14c5834f7b88b04a5560b99bf6fff5f1f4622d4b1998d19dd517ab6b7453fd53c832ee7fefa SHA512 33d6eafd9b6ecd97ee2dca8a4f1612a6fcc584961bcfd3a0a188f557a73f4c1576f98dc525c3b2feecb2d676f4bf4364aafeef093d6686e4b3ef2043726561a8
+DIST urllib3-2.2.0.tar.gz 287152 BLAKE2B 126949265c6558e8743f8e2e05e80fd211845c67436db096796f453ed248d348dcc73d3822c77bb94b55b711eb4b10899b60808be1f4981159f772a2066d5e39 SHA512 8fa2735ff623ec549802290a2317d3d24cdd18e43b8b0702dcee03ecba31428bd0dd12e5b8e129135a3f254bcf5bcd6a8b608c3a43192b50e3a815c73906f6cd
diff --git a/dev-python/urllib3/metadata.xml b/dev-python/urllib3/metadata.xml
index cef61f226361..67bd6c255e5d 100644
--- a/dev-python/urllib3/metadata.xml
+++ b/dev-python/urllib3/metadata.xml
@@ -8,6 +8,9 @@
  <upstream>
   <remote-id type="cpe">cpe:/a:urllib3:urllib3</remote-id>
  </upstream>
+ <use>
+  <flag name="http2">Enable HTTP/2.0 support.</flag>
+ </use>
  <origin>gentoo-staging</origin>
  <stabilize-allarches/>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/urllib3/urllib3-2.2.0.ebuild b/dev-python/urllib3/urllib3-2.2.0.ebuild
new file mode 100644
index 000000000000..270235f43300
--- /dev/null
+++ b/dev-python/urllib3/urllib3-2.2.0.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_TESTED=( python3_{8,9,10,11,12} pypy3 )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1 pypi
+
+# The package has a test dependency on their own hypercorn fork.
+HYPERCORN_COMMIT=d1719f8c1570cbd8e6a3719ffdb14a4d72880abb
+DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
+HOMEPAGE="
+	https://github.com/urllib3/urllib3/
+	https://pypi.org/project/urllib3/
+"
+SRC_URI+="
+	test? (
+		https://github.com/urllib3/hypercorn/archive/${HYPERCORN_COMMIT}.tar.gz
+			-> hypercorn-${HYPERCORN_COMMIT}.gh.tar.gz
+	)
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64"
+IUSE="brotli http2 test zstd"
+RESTRICT="!test? ( test )"
+
+# [secure] extra is deprecated and slated for removal, we don't need it:
+# https://github.com/urllib3/urllib3/issues/2680
+RDEPEND="
+	>=dev-python/PySocks-1.5.8[${PYTHON_USEDEP}]
+	<dev-python/PySocks-2.0[${PYTHON_USEDEP}]
+	brotli? ( >=dev-python/brotlicffi-0.8.0[${PYTHON_USEDEP}] )
+	http2? (
+		<dev-python/h2-5[${PYTHON_USEDEP}]
+		>=dev-python/h2-4[${PYTHON_USEDEP}]
+	)
+	zstd? ( >=dev-python/zstandard-0.18.0[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep "
+			${RDEPEND}
+			dev-python/brotlicffi[\${PYTHON_USEDEP}]
+			dev-python/freezegun[\${PYTHON_USEDEP}]
+			dev-python/h2[\${PYTHON_USEDEP}]
+			dev-python/httpx[\${PYTHON_USEDEP}]
+			dev-python/pytest[\${PYTHON_USEDEP}]
+			dev-python/pytest-rerunfailures[\${PYTHON_USEDEP}]
+			dev-python/pytest-timeout[\${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[\${PYTHON_USEDEP}]
+			dev-python/quart[\${PYTHON_USEDEP}]
+			dev-python/quart-trio[\${PYTHON_USEDEP}]
+			dev-python/trio[\${PYTHON_USEDEP}]
+			>=dev-python/tornado-4.2.1[\${PYTHON_USEDEP}]
+			>=dev-python/trustme-0.5.3[\${PYTHON_USEDEP}]
+			>=dev-python/zstandard-0.18.0[\${PYTHON_USEDEP}]
+		" "${PYTHON_TESTED[@]}")
+	)
+"
+
+src_prepare() {
+	# upstream considers 0.5 s to be "long" for a timeout
+	# we get tons of test failures on *fast* systems because of that
+	sed -i -e '/LONG_TIMEOUT/s:0.5:5:' test/__init__.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x PYTHONPATH=${WORKDIR}/hypercorn-${HYPERCORN_COMMIT}/src
+	local -x CI=1
+	if ! has "${EPYTHON}" "${PYTHON_TESTED[@]/_/.}"; then
+		einfo "Skipping tests on ${EPYTHON}"
+		return
+	fi
+
+	local EPYTEST_DESELECT=(
+		# TODO: timeouts
+		test/contrib/test_pyopenssl.py::TestSocketClosing::test_timeout_errors_cause_retries
+		test/with_dummyserver/test_socketlevel.py::TestSocketClosing::test_timeout_errors_cause_retries
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local EPYTEST_XDIST=1
+	epytest -p timeout -p rerunfailures --reruns=10 --reruns-delay=2
+}