Adding metadata

19 files changed, 442 insertions, 4 deletions

diff --git a/dev-python/aiostream/Manifest b/dev-python/aiostream/Manifest
new file mode 100644
index 000000000000..de71f8352131
--- /dev/null
+++ b/dev-python/aiostream/Manifest
@@ -0,0 +1 @@
+DIST aiostream-0.4.5.gh.tar.gz 39797 BLAKE2B 5aeb4da46158d949190af22133f1798831e14f8d8da231d3dc098caaace303061bfa49dfef1d52c533ce20201937bf5da33f36806634b2e73ccbc48c00962486 SHA512 ac1a67a6d27e18e290c5ae5b069de2e7f7205120bc747885261e23155019d5630c1f7b643df3a4fef12844d52cdfc0f1fcdcf5cb35a0061000d426c62dcffb1d
diff --git a/dev-python/aiostream/aiostream-0.4.5.ebuild b/dev-python/aiostream/aiostream-0.4.5.ebuild
new file mode 100644
index 000000000000..6de9a76fbeb2
--- /dev/null
+++ b/dev-python/aiostream/aiostream-0.4.5.ebuild
@@ -0,0 +1,37 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Generator-based operators for asynchronous iteration"
+HOMEPAGE="
+	https://pypi.org/project/aiostream/
+	https://github.com/vxgmichel/aiostream/
+"
+SRC_URI="
+	https://github.com/vxgmichel/aiostream/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e 's:--cov aiostream --cov-report html --cov-report term::' \
+		setup.cfg || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/aiostream/metadata.xml b/dev-python/aiostream/metadata.xml
new file mode 100644
index 000000000000..ea8988e8af6a
--- /dev/null
+++ b/dev-python/aiostream/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="project">
+  <email>python@gentoo.org</email>
+  <name>Python</name>
+ </maintainer>
+ 
+ <origin>gentoo-staging</origin>
+ <stabilize-allarches/>
+</pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index edde922c5446..253feb55c670 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -7,4 +7,5 @@ DIST boto3-1.26.22.gh.tar.gz 574580 BLAKE2B 35027efcfaa0ec27ff7e8769af32c4ea621f
 DIST boto3-1.26.23.gh.tar.gz 575113 BLAKE2B a39f1546f5733de801f00df97a383f45a6f96ba608f441f4e889ed9b9362bef4b84bfe61a817e4e39cafb25777d4f75021130b05fe14e328006c409a77dd7eeb SHA512 92de04f42e5e94ab1b7dd6aa1d4048fdd372814ecec7742ade8b0a49a871748921f5ac600a421c412c50474e21334e910eb64ce2f3abfaf1e1add391e6dc346b
 DIST boto3-1.26.24.gh.tar.gz 575745 BLAKE2B 2dd132d9daf9dafd81549664b23bb457211adfde1da5279de9519b1a30e0f5921f763f4770f7061011de97d7a52a05cdff57ddede2c3b95f8d048398bd160e9c SHA512 ab1943be54a5979a7e73f9fafc2937528c9a010f3c8244e2951fe802a7a20e57414b2565d6b6628890f913c76386aeaa0583c01901798bcc5080e48aa7da74e4
 DIST boto3-1.26.25.gh.tar.gz 576015 BLAKE2B 55d94441c1fa2668efa31390dbe972b354a4ab69d7825b2ecdcee47d03d44cb2533b428595dfdecc374a1164429166bb1740550334e2da1ff4a20ae31a53bb83 SHA512 c85b3b591926881a08e5143413848fd14b9cbe11c376970e71fe5fc6851a43448941583b73dc40cc0335c6749e7ea31eb8b4ef4d38dcf630d68693b94757bb07
+DIST boto3-1.26.26.gh.tar.gz 576812 BLAKE2B f88759a49f15102e02a73fedd42cf6f8332db83a1a543af180d6b2843d187ecc66449760bdc7e2500e5ff9410ed602688774f512e0a686a8a95190a2dca5b662 SHA512 60c02d960ba781117314595c9d26cd8fd947ee9c178175188140b58fa5ddf9687fc5f7c6f10dd0980f93490571a8de0e54a8dca3a0bf89b1111ccaa80017b2d0
 DIST boto3-1.26.8.gh.tar.gz 557012 BLAKE2B 211bb7441acc8b1f901ebf5251288dc7c9073fa6e34f5a34426424ef064efb0fb3031deaf48ef336ec43bb015f95f618598da43d12ec83cbf814e1b4097b28a0 SHA512 738190cedfb0b85d3a1e9558b03e7f2fb14e43b152bc9627fd95c8ecc4a0ddc17f4c87ccb6129c1fbf5f47db9eea4dbc5c2cfbb69b903bc6f3ff417ef86b6f6b
diff --git a/dev-python/boto3/boto3-1.26.26.ebuild b/dev-python/boto3/boto3-1.26.26.ebuild
new file mode 100644
index 000000000000..3d7d652a3b69
--- /dev/null
+++ b/dev-python/boto3/boto3-1.26.26.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 4b4030e8af1f..a65b0198abc7 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -7,4 +7,5 @@ DIST botocore-1.29.22.gh.tar.gz 10999477 BLAKE2B 90987611453768b9c7c00ea8f6b1645
 DIST botocore-1.29.23.gh.tar.gz 11001723 BLAKE2B d1cfefb3bc25094948a1450ee7159e81d640301eca756702e8debcfa30858c22c77c273043584641888d85c46d3be800c65c2c800ecfc83b2760e7ea40e9a03b SHA512 454ac41097385838d286f3a3d9cc44e076fea8608313895ae657683ea5441328704eaa1b46a22076cad5b7e91eead5291cd036a188ab907b80173f2b755d6160
 DIST botocore-1.29.24.gh.tar.gz 11006663 BLAKE2B 195933b78bd0c5c5881cd697c1c61c6f40557d51edb7510e40ecdd31aae80a72fe3c33946e718a98b19a1f8af6d8cc687e047e5cd0b662de9f2d0ca3b53583e3 SHA512 e6dd5a88bf6539f02d27054d5825688b80a2a582e5ebd04d31d887e6baa31a4ba54aa0ba0c0e03156b4ad22815f6aa8f8f8986c3767180a04b284341223f4c60
 DIST botocore-1.29.25.gh.tar.gz 11008437 BLAKE2B 5a569d52065c2f448adb8c765e51e8338ce0bc2ae4b13e0f39a98af319aa1a31ef3a1eb4014aae8c497ab68a234dc2d16798a0d8b7c626e0ea81da4d2489ed7a SHA512 274a713d26cc723914824cdaf729d7537b5104957751b6d4b0c974e9f45a54ee09bd1853d1ab89dec2fb3b5a5b74102fa658c1f9478a4b4301b950e44f0f1fd5
+DIST botocore-1.29.26.gh.tar.gz 11015382 BLAKE2B b9777a7db931b15bfae0e62a5095b86f8cfbf2f7d37b1111ec46d0add8d46ae5c57d1e74e8c58bd931e0a9b3faf986746d6c48149453f5921d9c084455cb3a3b SHA512 457e858e9648ff78bd1972e0772938dd608511aeeebd1f83e8bfda50bef43374f574d0a0943f6e29d0401be880e2db4e8a47d36a2e95317da58fba4920deae3f
 DIST botocore-1.29.8.gh.tar.gz 10636661 BLAKE2B 3ebd9e5cb6cc1a9d4ddb877e806e0a845e6a19a4604b4489dbdb9a0f35251201de5d7062f3b0193db3e28f5170d8c3315fdc0b2bec7668a61880ff3e9305d3bc SHA512 c4a1a3993576bd0340de4eeb25e10650219e9d74c21f7e51e5298120bc92a8359143c38d5a991b940316fc5eac483e4e838298881a5c068fa91dc3ebf92a7f5a
diff --git a/dev-python/botocore/botocore-1.29.26.ebuild b/dev-python/botocore/botocore-1.29.26.ebuild
new file mode 100644
index 000000000000..40131f66e350
--- /dev/null
+++ b/dev-python/botocore/botocore-1.29.26.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+		# fails on unrelated warnings
+		tests/unit/test_client.py::TestAutoGeneratedClient::test_BOTO_DISABLE_COMMONNAME
+		tests/unit/test_client.py::TestClientErrors::test_BOTO_DISABLE_COMMONNAME
+		# TODO
+		tests/functional/test_credentials.py::SSOSessionTest::test_token_chosen_from_provider
+	)
+
+	epytest tests/{functional,unit} -n "$(makeopts_jobs)"
+}
diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index 1b5f8f3d33a6..c70dd861dd79 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1,3 +1,4 @@
 DIST google-api-python-client-2.65.0.gh.tar.gz 36079173 BLAKE2B 32e60989dbc6e02ed2bd128772a71c24670d16da09ca4e5be6d4f56ebf16c94ccac120e233b4efb5fb9c9b8c464d052129eb6305a57fb61f732ca9d593f1297c SHA512 3b215e290c9a63aca914c08478342ab41ef760c135d3d5a13387be52a2993b814568c86cad752de6afe16fb3097989f4d7df06f4c9ce9c453fb7d0cb55f17053
 DIST google-api-python-client-2.66.0.gh.tar.gz 36477219 BLAKE2B 1da02e7747fd1421bdc62180103784af7b50ab0a672ac932f2fe28c22141a922d6f59d9c11ee74b78ff13583bdeee98d35f7b6d616af84fe99aa3d1a0de17342 SHA512 6b3cdf7279067080ff216d184f23c76c74c586e34b70afd936f1d10671fc0c7e7a8ba446a1ca5a9003bab2e3855e939376610ff4e45811fd6ead5e4942f62247
 DIST google-api-python-client-2.68.0.gh.tar.gz 37053945 BLAKE2B 7a73b80737b73198531207d203c2010969a9dbdd5012071944ec86bd6c2c63eb0a86bf2941a4c37544629aeae32b367cc8d9209300c63e8d1be39f32bef1d91f SHA512 9b70ad6f05d28198ee82984e263e770c995143770123a8aaeb605aad880464e951b8849bbed8c7cb511bd7beebed1df965fdd53b2e6a161905a0a2e481d5b68a
+DIST google-api-python-client-2.69.0.gh.tar.gz 37357078 BLAKE2B 1f8c421823a1ef5483a137d72f705e35a7c43426f2a2d7d2fba97ce64cf07fb10892bd6553bcd9331873a2ba7a9b51364f80781e8b811fe8f14208d1447c1d32 SHA512 2b6ead1e0133bed9aa25a42b70da49a11c867493c6ae9f3ded5c2964cd2fa4132eed7ef7670d43f616c3dae7bb0c4ad8e17986758ea76d81f35227edf20208b3
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.69.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.69.0.ebuild
new file mode 100644
index 000000000000..63e5333c4693
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.69.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="
+	https://github.com/googleapis/google-api-python-client/
+	https://pypi.org/project/google-api-python-client/
+"
+SRC_URI="
+	https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	>=dev-python/google-api-core-2.3.1[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.35.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-5[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	epytest tests
+}
diff --git a/dev-python/ipykernel/Manifest b/dev-python/ipykernel/Manifest
index 2268a5244f17..109371dfadfd 100644
--- a/dev-python/ipykernel/Manifest
+++ b/dev-python/ipykernel/Manifest
@@ -6,3 +6,4 @@ DIST ipykernel-6.18.1.tar.gz 141559 BLAKE2B 4c12ff56d2e9c34a278e68e141032768ede7
 DIST ipykernel-6.18.2.tar.gz 141693 BLAKE2B 6990354a26dcf9572e52e8d12b3df4f2b34cfff79afd05905f23a3957d3d79c0f28fa27d4bdb8978616fff272d626fb60e1ad8094c05020b2307b8aa5d3e68c6 SHA512 c8c2a1132e8cefec0e5b66cd3cfec14ce18d62d48119e644e1f8849d1472baf3b95b158feb6887cb1788229ac4a0bdff95d0d71141b32930e4e4962688ae5bfd
 DIST ipykernel-6.18.3.tar.gz 141999 BLAKE2B da5b0b2a36a58f2c91fdeab95a7e4bb33e09f9663eccb6d394f69a5a25e7e55e3f18315d017aaf435607efa73acca955665f7720b75ac4aa3256aa034698082d SHA512 0687ac146bac38bbdd6abad11df31572cb105bd41b79de98b40c18b60cdcb550b7ea10d68acf99f26d70c00ed4ef371d6dc2b6a4ce27eccae3f736955754ca1a
 DIST ipykernel-6.19.1.tar.gz 143329 BLAKE2B 324744ab8633338d15d9d72e931fe1c708909ab50c41f2c82192c2c7dd1ad6ffd04b6564265b9d4d09919767b496793aa639bec60fdad8f3e9b2de49f3a6333b SHA512 8c0a3a4cdef050d5fc059bd416a139a89bdacac6d68e31af8c800a7a0cfebf069c2df968b256ac8af1528fdd1d499a020428529ead10c0d96f2205b28906f690
+DIST ipykernel-6.19.2.tar.gz 143367 BLAKE2B f6f38f5eed3a11951d303f49c58131d9473040b34032c133cf0f788bb648fc7c8529e3879dce315dcd3eda4eb1be45eb4891d10d4a2d006bb7947f2b342a47a7 SHA512 67ccbffb2d9eba27e9b87c7bd9dc471955c0109ea30caf77412f74c803dc25ab526de90d8351c9459b5d7b2009c746f73ac4a08ae8c277d2e2de8344aef71834
diff --git a/dev-python/ipykernel/ipykernel-6.19.2.ebuild b/dev-python/ipykernel/ipykernel-6.19.2.ebuild
new file mode 100644
index 000000000000..caf88dc23796
--- /dev/null
+++ b/dev-python/ipykernel/ipykernel-6.19.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="IPython Kernel for Jupyter"
+HOMEPAGE="
+	https://github.com/ipython/ipykernel/
+	https://pypi.org/project/ipykernel/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
+	>=dev-python/debugpy-1.0[${PYTHON_USEDEP}]
+	>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
+	>=dev-python/jupyter_client-6.1.12[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
+	dev-python/nest_asyncio[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/psutil[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
+	>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
+"
+# RDEPEND seems specifically needed in BDEPEND, at least jupyter
+# bug #816486
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/ipyparallel[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# TODO
+	ipykernel/tests/test_debugger.py::test_attach_debug
+	ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
+	ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
+	ipykernel/tests/test_debugger.py::test_set_breakpoints
+	ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
+)
+
+src_prepare() {
+	sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	# Use python3 in kernel.json configuration, bug #784764
+	sed -i -e '/python3.[0-9]\+/s//python3/' \
+		"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
+}
diff --git a/dev-python/markdown-include/markdown-include-0.7.0.ebuild b/dev-python/markdown-include/markdown-include-0.7.0.ebuild
index 3888a29f1e11..b54e0e1cd9e0 100644
--- a/dev-python/markdown-include/markdown-include-0.7.0.ebuild
+++ b/dev-python/markdown-include/markdown-include-0.7.0.ebuild
@@ -3,6 +3,7 @@
 
 EAPI=8
 
+DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10,11} )
 
 inherit distutils-r1
@@ -16,3 +17,8 @@ KEYWORDS="~amd64 ~x86"
 SLOT="0"
 
 RDEPEND=">=dev-python/markdown-3.4[${PYTHON_USEDEP}]"
+
+src_prepare() {
+	sed -i "s/description-file/description_file/" setup.cfg || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/markdown-include/markdown-include-0.8.0.ebuild b/dev-python/markdown-include/markdown-include-0.8.0.ebuild
index 6817122709f5..80fc78ec5a16 100644
--- a/dev-python/markdown-include/markdown-include-0.8.0.ebuild
+++ b/dev-python/markdown-include/markdown-include-0.8.0.ebuild
@@ -3,7 +3,7 @@
 
 EAPI=8
 
-#DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_USE_PEP517=setuptools
 PYTHON_COMPAT=( python3_{7,8,9,10,11} )
 
 inherit distutils-r1
@@ -15,5 +15,13 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 LICENSE="GPL-3"
 KEYWORDS="~amd64 ~x86"
 SLOT="0"
+RESTRICT="!test? ( test )"
 
 RDEPEND=">=dev-python/markdown-3.4[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i "s/description-file/description_file/" setup.cfg || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/traitlets/Manifest b/dev-python/traitlets/Manifest
index 4b1f1948c72c..ee513f4e5ddb 100644
--- a/dev-python/traitlets/Manifest
+++ b/dev-python/traitlets/Manifest
@@ -1,2 +1,3 @@
 DIST traitlets-5.5.0.tar.gz 131686 BLAKE2B 1206c2f86367eb421202070a48fe12b20b214f446d8d54a0720e9474f77e2c9382186a6b3e32fc5896bd30c27f8fe7d2e1bdcaf24d88b445001b7203c6655a82 SHA512 c99c28fb503b0322599563ad934a6160fa9e2c1cc41c37e19f4d6cb0343a1a2228cbead9a6a296997fd9eb24f3e077d3043b349a7b7e765fdf1955cf63c49266
 DIST traitlets-5.6.0.tar.gz 133316 BLAKE2B 736ef860ed8f7d9cfde990c755d50f47d09344edf1d2f55347d693cc3c453ae1f2315c168bd52dc82ea4e29ee7ab1d2494c9fd095bf56d03cf8b52b89d209ff2 SHA512 7af0fb619ddb2991b6285bb07642f700b0bb822c0eb5770fe6d337f42ac9c2fbb59cd971e9a8991277c47f3a9be2cfde21712080cca4733f8bba3339f91c8311
+DIST traitlets-5.7.0.tar.gz 136290 BLAKE2B ddc7190f0c14b6dae36effca4966801834d868f5072e3780ecaf10e5aadc2a05372e49028a7e08719e6d8a7536cd0e6a3dc36815322fc62933bca3311e55dee8 SHA512 252d6d93b863e099a739d0f1ad2a97421791ae9349c8720bc41dfeacfd3ee22f966cb75ee3895449a0e1b987f8d2db9d8665cbdacaed6a46ab05638e382d2e9e
diff --git a/dev-python/traitlets/traitlets-5.7.0.ebuild b/dev-python/traitlets/traitlets-5.7.0.ebuild
new file mode 100644
index 000000000000..773f198b02f1
--- /dev/null
+++ b/dev-python/traitlets/traitlets-5.7.0.ebuild
@@ -0,0 +1,30 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+
+inherit distutils-r1
+
+DESCRIPTION="A configuration system for Python applications"
+HOMEPAGE="
+	https://github.com/ipython/traitlets/
+	https://pypi.org/project/traitlets/
+"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+distutils_enable_sphinx docs/source \
+	dev-python/myst_parser \
+	dev-python/pydata-sphinx-theme
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
diff --git a/dev-python/vdirsyncer/Manifest b/dev-python/vdirsyncer/Manifest
index c4b5782242fd..1173cae68ca4 100644
--- a/dev-python/vdirsyncer/Manifest
+++ b/dev-python/vdirsyncer/Manifest
@@ -1 +1,2 @@
 DIST vdirsyncer-0.18.0.tar.gz 115125 BLAKE2B d81bb9b51658d16a3b9ea044846561a1ce2dac3a839d7e0a165f0136069fcd0716525ab2b908be7cafed60846a1aed6fd72aa1d31fc2a38dbe6de8d0e6585226 SHA512 7fb3d0f7d982d8390d278de1a620231e6ead1ec64057c5dbac98dcff491fa3e6b9ed8ba953995458e393aab73b0b9ab8ba14010e06f90a04d8ee2c28c7c7fbfd
+DIST vdirsyncer-0.19.0.tar.gz 122533 BLAKE2B 18e3359fb743a8ce71f80c46da21555c4984ca47791e1a4e899408050e4a4bbad184fa94026fede1168fa3a7695539d93f1985b85c640aa1c0ca4fdf52920766 SHA512 9b8e467bdc9daf6d50981bfec1f67a1c990b07bc62a6e2d3ede35712fde60206672af53d53aca6587daee132ab74bf74f04d8bb4dbaa804dfe97dca9370b323c
diff --git a/dev-python/vdirsyncer/vdirsyncer-0.19.0.ebuild b/dev-python/vdirsyncer/vdirsyncer-0.19.0.ebuild
new file mode 100644
index 000000000000..1637f8cd87ce
--- /dev/null
+++ b/dev-python/vdirsyncer/vdirsyncer-0.19.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="Synchronize calendars and contacts"
+HOMEPAGE="
+	https://github.com/pimutils/vdirsyncer/
+	https://pypi.org/project/vdirsyncer/
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/click-9[${PYTHON_USEDEP}]
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	<dev-python/click-log-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/click-log-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-toolbelt-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/atomicwrites-0.1.7[${PYTHON_USEDEP}]
+	<dev-python/aiohttp-4[${PYTHON_USEDEP}]
+	>=dev-python/aiohttp-3.8.0[${PYTHON_USEDEP}]
+	<dev-python/aiostream-0.5.0[${PYTHON_USEDEP}]
+	>=dev-python/aiostream-0.4.3[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/aioresponses[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( AUTHORS.rst CHANGELOG.rst CONTRIBUTING.rst README.rst config.example )
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/cov/d' setup.cfg || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# skip tests needing servers running
+	local -x DAV_SERVER=skip
+	local -x REMOTESTORAGE_SERVER=skip
+	# pytest dies hard if the envvars do not have any value...
+	local -x CI=false
+	local -x DETERMINISTIC_TESTS=false
+
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/system/utils/test_main.py::test_request_ssl
+	)
+
+	epytest
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	systemd_douserunit contrib/vdirsyncer.{service,timer}
+}
diff --git a/dev-python/w3lib/Manifest b/dev-python/w3lib/Manifest
index adacabab340e..bf48f2408d94 100644
--- a/dev-python/w3lib/Manifest
+++ b/dev-python/w3lib/Manifest
@@ -1,2 +1,2 @@
-DIST v2.0.1.tar.gz 43905 BLAKE2B 35d5ef1b326074a86f98341c50ed08f8ec8bc3e13433b7dc8ee6db453375fa0a1958f0f83d4274eeef89b95a177c3f92994c0927367c420d5a03c8400420cc91 SHA512 c4c1a00ad6d0c8f9a3a3a6581fb513328f89bfd9f797bf6289133580581c2579b04da8a2c815d14214bc0dbc87839de3d9f7949ad9398402312d3c522361414e
 DIST v2.1.0.tar.gz 50706 BLAKE2B 95b27b84e22bbbffbf8c58eb76a7ddb920a22ec663ca79ea888d0ea7c2d40a5af17c29c6bd8641778f77e055492b281975a37870a3833e5627645d19f2e227f6 SHA512 a511711e8be7669e80e82bd3ccafa507a57a6f7755af4fab95bd27d3987507cc6ec73497af76ac316831e6f43d103aa98b71388452a83fc01ddbba1f40414bf3
+DIST v2.1.1.tar.gz 50908 BLAKE2B 324080f01509b736b76bc03f2c5c11e1244e71a509b29be5dcc6f7978c932deae18e26faa53e9ad9928d086c24688c91f38984d3e32b6dcb67605657e30abd0f SHA512 897a2ead229c1cfdba83c78383169bb731840a024e1304e47482e24b38687f49d57474ec02bbbb6282f348ae4bff5398f3e8da923aed29bde52a2ac400f100b0
diff --git a/dev-python/w3lib/w3lib-2.0.1.ebuild b/dev-python/w3lib/w3lib-2.1.1.ebuild
index 3c60b8b0979c..d12d9ef2be7d 100644
--- a/dev-python/w3lib/w3lib-2.0.1.ebuild
+++ b/dev-python/w3lib/w3lib-2.1.1.ebuild
@@ -2,7 +2,7 @@
 # Distributed under the terms of the GNU General Public License v2
 EAPI=8
 
-PYTHON_COMPAT=( python3_{7,8,9,10,11} pypy3 )
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
 
 inherit distutils-r1
 
@@ -21,6 +21,5 @@ RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
 distutils_enable_tests pytest
 
 EPYTEST_DESELECT=(
-	# https://github.com/scrapy/w3lib/issues/164
 	tests/test_url.py::UrlTests::test_add_or_replace_parameter
 )