Adding metadata

23 files changed, 456 insertions, 6 deletions

diff --git a/dev-python/abydos/abydos-0.5.0.ebuild b/dev-python/abydos/abydos-0.5.0.ebuild
index 2452a0ea812c..da0465a9a953 100644
--- a/dev-python/abydos/abydos-0.5.0.ebuild
+++ b/dev-python/abydos/abydos-0.5.0.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/chrislit/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 
 LICENSE="GPL-3"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 
 # Requires access to the internet
 RESTRICT="test"
diff --git a/dev-python/autoprop/Manifest b/dev-python/autoprop/Manifest
index 8b942132a453..ae49e5bef90b 100644
--- a/dev-python/autoprop/Manifest
+++ b/dev-python/autoprop/Manifest
@@ -1,3 +1,4 @@
 DIST autoprop-1.0.2.tar.gz 11040 BLAKE2B b53bdbf79947002a0c319fa84c6033908948365d18a85dd2fd4139bff2125752e0bc3fc8f19e5d38c06cdc089f423cc8a720b8040593cfbda9c04c84b7cd4ffd SHA512 281c30fded6d79ed3bbb0de5b7a37c2cc5b985a4980974503b5bbb5940cd22f3c09c3b3d9d513d5cb95239519519b277bf43536407fedb593a43122ee32a8db6
 DIST autoprop-2.0.0.tar.gz 11705 BLAKE2B 0dd6401671250f9445aaaf20345035bec683eb7e7e3889ee6c89bbefd76bff9112c848ab4b95c47f09f2487af92c3c6a3404be17bc57f47c9be33f36ec369175 SHA512 7e2f9d2d950ac8f2b0e73b483940590dbb6eb342a36204cc36fff219375eb223c62d5c0dc864b0d1212593919f1625cd282f0467a5bf84d5c1e5c158cfcf6cc1
 DIST autoprop-2.1.0.tar.gz 13258 BLAKE2B a08431a87067463278276974326ca81a8c0150193fd3a03fdc2ab422b836655a11f759154fdeeaf834bc379163e167d4815358aaefdc83a76ab4dfa87b6efee5 SHA512 c30ee4bf85d139abf1be2e7b0217bc6f394ba289ccdad423c97f1d27f472ce00eaef2be0f3cdf1c9022c6edc56006d5834d1afd6ef2c5ee2ec124eb5bf679652
+DIST autoprop-2.1.1.tar.gz 13794 BLAKE2B 63645d0d8f9d49f5df730dca18c468e3dea7108e01cf12f6de6d80ad6cf8b5d396957d4a0cd82c737c0b12274a8534e6f48120ef1118c0fb34dba529dc74f081 SHA512 39db6c1130d0b958713f15efcd75ecbbb41659f5f7182be37f1dca22a46c18832d0f7893fadfbf4e8ad9f446417a2476e7dc7890124c9caabd6b5dde37eb7c6f
diff --git a/dev-python/autoprop/autoprop-2.1.1.ebuild b/dev-python/autoprop/autoprop-2.1.1.ebuild
new file mode 100644
index 000000000000..59992b19b15b
--- /dev/null
+++ b/dev-python/autoprop/autoprop-2.1.1.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Infer properties from accessor methods"
+HOMEPAGE="
+	https://github.com/kalekundert/autoprop/
+	https://pypi.org/project/autoprop/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64"
+SLOT="0"
+
+RDEPEND="
+	dev-python/signature_dispatch[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 47018c385807..6a5a3f675ee6 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -6,3 +6,4 @@ DIST boto3-1.17.39.tar.gz 354720 BLAKE2B bd5f9f676c346efc9264e42e802d0c5af5a3674
 DIST boto3-1.17.40.tar.gz 355270 BLAKE2B f7f3af1882ee9188e37ac90f7ebd55b4cec016a12404dfa402da8bbbfaabb904e7d16a77e4f73b1e5da14550944a97672e5ccaa555f57662616233dbfd807cfb SHA512 6d21fbfac86e9a5992ecef35cc8b29c43bd9bb5823672eb8a375c239369edb775fbddf80f2d64209a4d106e2fd02e72583b6e5c8c6c98fdcb45ea17f1dfc0e41
 DIST boto3-1.17.41.tar.gz 355972 BLAKE2B f58dc93b53850781d89db65dcdb17b60141b3dbe7a8f943bc49e3886eb1b3b6989e3720c7966346a91af4679873b8eea4ffcae3f6ea58aa755b06438de10a13a SHA512 9048d1af355397efa6b8ed26007829e2382995c202d27d2dec26b25635e563dda8fe55981483d99c248b1a6e58154ab023e57d8a1ca356a1c46536108616b5a2
 DIST boto3-1.17.42.tar.gz 357288 BLAKE2B 9a92b8dcee054e408954ea1cf31c776777fcf275ed3ccbccb2dca68acc5e6e6215576dc33bf401b5786a3c6f9995eed16f4be093f7d2bad13f781bf10fc2d13f SHA512 b7a9b06a69eefdc3b25b0bedcf7a4e775cb2099b8106541acf9cea5a95cf6a747f30497bbaacbe66931bb6280047f191cd6129815141ef3bd9a75f5691c04075
+DIST boto3-1.17.43.tar.gz 358179 BLAKE2B 7d0a9344642b8c2a4241296327e055abe700c82776e83f12f30ff510ac9364ca6e7fd49f254ce8a3e1ac7123cbb747665dcba774e9befdfd053b3db1f72615bb SHA512 d6271b4563c92097f9c670f4e9c73c01c2a6764d344bed84a4bb08fb7989cd38147890e2c9526cfcbc2e1ae1de9d1e596385c5dc662db7b75c35a69d5ff79831
diff --git a/dev-python/boto3/boto3-1.17.43.ebuild b/dev-python/boto3/boto3-1.17.43.ebuild
new file mode 100644
index 000000000000..2df16964cdb0
--- /dev/null
+++ b/dev-python/boto3/boto3-1.17.43.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="https://github.com/boto/boto3"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+	# botocore is x.(y+3).z
+	BOTOCORE_PV="$(ver_cut 1).$(( $(ver_cut 2) + 3)).$(ver_cut 3-)"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${BOTOCORE_PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# prevent an infinite loop
+	rm tests/functional/docs/test_smoke.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests -v tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index f3da1d422e8f..0eccc5e171fb 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -6,3 +6,4 @@ DIST botocore-1.20.39.tar.gz 7560051 BLAKE2B 0605b39e28e494add04d0f5ca559a3c1eac
 DIST botocore-1.20.40.tar.gz 7564881 BLAKE2B a9a84867960fdd9a97f429c25410433ee7775134b358f67bddecf84308abe1c24e3f7f0f36e5df9da88e17b4002ff99f9494c45320289472022bd3a041fad177 SHA512 cd63670d3820d18be933d225ce238b72496236f7d3aa82b385071735f59f59128502eae80093385bf95a7ba33f78ce8baff6be55e88a4539e6ee5c7816484fd6
 DIST botocore-1.20.41.tar.gz 7572739 BLAKE2B 2fde8a64fd04acd698b91e222934ba5338c24942885c7ef85754947bebac09ad3ee70d7e3df3d60af76b9840df9bceae5b465764624f2a8910503f66d474fc8d SHA512 9eabb9c74ebe6b3eb3bc21781b3c91ce39309337cc90047e636eeaf17d31c14e4107d1228655c042f13d154f28732129fa84bd08c548144028da27cbdb8df1d1
 DIST botocore-1.20.42.tar.gz 7579571 BLAKE2B 26d4a2c9e2df7df92888e9f49dba3799ccf5c0d9745cb46fd6d3ff0f4b1ea7cd5faa3bd6e173d67ec052989fbc92e4d7d6cb298c9d7807b3eea6b4c5d9e1abc1 SHA512 447c0fd5aa9864dacbb132f451f260f9d3f83fe70444993283ae0845150c383e2ef9df20e8977705d86d2698b8d12189071a2c27cb0ee1e6358eb0619ee2173b
+DIST botocore-1.20.43.tar.gz 7595391 BLAKE2B 78c7e146e2a5b204c5a4c0b6c0d8ea6ee8bdc36339698a671c90f529f74ce4e9314a901021fc7eeb93a8ad81d8442093478a365076175129a9924891dbfe34bd SHA512 2b575aed2748d5f4c8be593eb119f9453237c81a5fe53a5852a14f355626fa56111a5932ccf2825e28100414ea2ce5fd57b923e819296cf7eebe88a786bbf14a
diff --git a/dev-python/botocore/botocore-1.20.43.ebuild b/dev-python/botocore/botocore-1.20.43.ebuild
new file mode 100644
index 000000000000..9d681f87244c
--- /dev/null
+++ b/dev-python/botocore/botocore-1.20.43.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="https://github.com/boto/botocore"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/jmespath[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/1.8.6-tests-pass-all-env-vars-to-cmd-runner.patch"
+)
+
+distutils_enable_sphinx docs/source \
+	'dev-python/guzzle_sphinx_theme'
+distutils_enable_tests nose
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+	# very unstable
+	sed -i -e 's:test_stress_test_token_bucket:_&:' \
+		tests/functional/retries/test_bucket.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# note: suites need to be run separately as one of the unit tests
+	# seems to be leaking mocks and breaking a few functional tests
+	nosetests -v tests/unit ||
+		die "unit tests failed under ${EPYTHON}"
+	nosetests -v tests/functional ||
+		die "functional tests failed under ${EPYTHON}"
+}
diff --git a/dev-python/cryptography/cryptography-3.4.7.ebuild b/dev-python/cryptography/cryptography-3.4.7.ebuild
index 944f1016c669..a42f2a37a8f0 100644
--- a/dev-python/cryptography/cryptography-3.4.7.ebuild
+++ b/dev-python/cryptography/cryptography-3.4.7.ebuild
@@ -16,7 +16,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
 
 LICENSE="|| ( Apache-2.0 BSD )"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
 IUSE="libressl"
 
 RDEPEND="
diff --git a/dev-python/decorator/Manifest b/dev-python/decorator/Manifest
index 9d1118e5284a..d66aff680631 100644
--- a/dev-python/decorator/Manifest
+++ b/dev-python/decorator/Manifest
@@ -1 +1,2 @@
 DIST decorator-4.4.2.tar.gz 33629 BLAKE2B 5b2c6a1b6aba293d4b93444d4613e3c9af16bd9d6d80ae9eb21112a4a16397ff67e1f648e8118beeb7d17755a2f1bd37b867f73129c42ef7f8654d1c1f609e5f SHA512 c068efd4e70764ac447b772c9c29625c2180dad256b2b4e46a50a8479fc1d7de09b114c2ba11bb37dd58774ed9460d2e0ea9fa76061833a2d3c2676ac91a0db1
+DIST decorator-5.0.0.tar.gz 33099 BLAKE2B c59a02c2a9c27342dcfdc96ecb89bb9d7f91add52a9e823963976d750b0197255e4c68f72b61f940f36fd09c504f7fa75a10c3cf0e17758fe707a79d332070ba SHA512 010e0ac6b8929b73afdfe57d41915cf56db3edcb2759ba6224bf589e5ff1780021ef9f65a628b530422665d3fc2f9b9b48e21db5e0f21053dbb5d0d20e8da194
diff --git a/dev-python/decorator/decorator-5.0.0.ebuild b/dev-python/decorator/decorator-5.0.0.ebuild
new file mode 100644
index 000000000000..9775a5587507
--- /dev/null
+++ b/dev-python/decorator/decorator-5.0.0.ebuild
@@ -0,0 +1,21 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Simplifies the usage of decorators for the average programmer"
+HOMEPAGE="https://github.com/micheles/decorator https://pypi.org/project/decorator/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+DOCS=( CHANGES.md )
+
+python_test() {
+	"${EPYTHON}" src/tests/test.py -v || die "Tests failed with ${EPYTHON}"
+}
diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index 8213b0ea047c..3b170aa9c575 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1 +1,2 @@
 DIST fonttools-4.21.1.tar.gz 2531249 BLAKE2B 7f507f85061c67da0003ed2c4f685b22ccf0e6c5067adb934772ef0832656bbe092d1282b30b5a40071cd3a3219f5cfd810e06e9cd3f85ddd8fa93538134c943 SHA512 8c54809ab9f39e34f482ee6b17dbf8b309e8bfa0bde783e24195c1f2949ded64591c5e79565136ec8492c0095d593db20779d3f28b933f8e40e54b610130e0f4
+DIST fonttools-4.22.0.tar.gz 2544600 BLAKE2B 685da467c40fc7cffe2b33b08da53e5bd148c5190efdc8d08e2c66ef06e67b5e26ec5fa090334b9ef427b1a005c6386b0f78b978d376c7daee7f4d540faa21c7 SHA512 06db054ce488d0291f876b05b5dd09a772a702f1d45b97c1ba46d02e01fe59f7c63e268fff958baa4076c1ce72f450384e473263250c1617791d78c0e311710d
diff --git a/dev-python/fonttools/fonttools-4.22.0.ebuild b/dev-python/fonttools/fonttools-4.22.0.ebuild
new file mode 100644
index 000000000000..1c49e0e79245
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.22.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="xml(+)"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="https://github.com/fonttools/fonttools/"
+SRC_URI="https://github.com/fonttools/fonttools/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+BDEPEND="
+	test? (
+		>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx epytest Tests fontTools
+}
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index e07172618b57..6e6905e38ceb 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -2,3 +2,4 @@ DIST hypothesis-python-6.3.4.tar.gz 9112374 BLAKE2B 78867f0ff142d6059a20c437c3fa
 DIST hypothesis-python-6.6.0.tar.gz 9117847 BLAKE2B bb88ebee9db53f1c5753730d04e5dfe6a39ac4c5f7d534778b22b813ba188a55de6ad8a34f611f7863d1c3287be39ed7e10981e9d6ed8d8dd106688f154c3a49 SHA512 a446b4a11c6ee013225bfcd58e26efc6c9d867545d9bcf90a19468cb01fc5e2c5a7280ff9a80d4a1adbfe06dd155df6152941d5f53869d85e1d259e68a33a5e2
 DIST hypothesis-python-6.8.1.tar.gz 9119495 BLAKE2B 4d98e30a04f652af79dd49e921b856124a312b63f087a6fd200282e9b0a0cd6fcad1a42a6008406bc347f21bf9cd6c5ff2db79d013987281f59365bd9d91550d SHA512 2f25e994438479b5faa15b2038146ab385445bf2722b0951ff55f324b074248d7322c4c6f3e9c659c18d0aa94150eea4c6567a7ac24debf2de4b32bab37a4dcc
 DIST hypothesis-python-6.8.3.tar.gz 9120421 BLAKE2B 9511f63aafe499316750ec8a993726d4e8db87b42fb772cf79cde1be18b23e99f55c1a2638f3ee7afadae5f323792322cf87b747ac428146fea2abc92793f8f5 SHA512 83660978dc4ff49a04d7167994821a18c769039c49dcbc515b28591651bb9ab2121e3a7267cb20281efade85003a5808e0898fda5dfe1e4be563a03d4688085c
+DIST hypothesis-python-6.8.4.tar.gz 9120762 BLAKE2B 00c6348c924252207cfca30babb2b281b70067478892ec154ef6fa40f87d5a1a4d7d4047eb2cb9f3e6b8cadee240f3475c2dc912f393553b35b0a6c71cf0ae4b SHA512 bb1c14aedf51bee4394c6b27d9c92d5c13b1d1e690608efff0cb68ae3ae7e8a078c99c10d0f1c4a6977430c8ebefea083af1be28f1535f93e320579614c9f46c
diff --git a/dev-python/hypothesis/hypothesis-6.8.4.ebuild b/dev-python/hypothesis/hypothesis-6.8.4.ebuild
new file mode 100644
index 000000000000..f20e753a168b
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.8.4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 eutils multiprocessing optfeature
+
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
+SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
+S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		!!<dev-python/typing-3.7.4.1
+	)
+"
+
+distutils_enable_tests --install pytest
+
+python_prepare() {
+	if ! use cli || [[ ${EPYTHON} != python* ]]; then
+		sed -i -e '/console_scripts/d' setup.py || die
+	fi
+}
+
+python_test() {
+	distutils_install_for_testing
+	epytest tests/cover tests/pytest tests/quality \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")"
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/jellyfish/jellyfish-0.8.2.ebuild b/dev-python/jellyfish/jellyfish-0.8.2.ebuild
index 18a1e5b304f0..0fb4ce2a4c4d 100644
--- a/dev-python/jellyfish/jellyfish-0.8.2.ebuild
+++ b/dev-python/jellyfish/jellyfish-0.8.2.ebuild
@@ -12,7 +12,7 @@ SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="BSD-2"
 SLOT="0"
-KEYWORDS="~amd64 x86"
+KEYWORDS="amd64 x86"
 
 DEPEND="
 	test? (
diff --git a/dev-python/nbformat/Manifest b/dev-python/nbformat/Manifest
index 7451ce253e0a..49e579fbea11 100644
--- a/dev-python/nbformat/Manifest
+++ b/dev-python/nbformat/Manifest
@@ -1 +1,2 @@
 DIST nbformat-5.1.2.gh.tar.gz 152275 BLAKE2B 2a0758f33952547e5ef91f0ac0a8b98b97b882a8797c38feff6710a3a0824637f41396b152403e155e1af9805b7a85c189ba2a609076c591562e5f4bb783da29 SHA512 4fd574373c2f325b6d078a062878d139d741d30f9101f3344e0c7fc19bdf714f8ef71994134e76c90e1301102aac55cc490df8344f3ceb407002437f35d03944
+DIST nbformat-5.1.3.gh.tar.gz 130922 BLAKE2B 866eb53dd3f04c09f4a08303c5e84b672cc826d2d9b369cd85038b6c4075e74dce88fbcae80fc9b5450faf1c4971d121abe35e0a2ce2a8e73e020d2bed3a5594 SHA512 b4bc3d51d6e940ce1e2b1f5ca1005cf3d466b2b7b589383a31c4d2908c4e539344f4c8fb9e92993469d4d66f363c35082f0c16b8a63aa61e19fb24fa5ac910fd
diff --git a/dev-python/nbformat/nbformat-5.1.3.ebuild b/dev-python/nbformat/nbformat-5.1.3.ebuild
new file mode 100644
index 000000000000..c7d03d6c1107
--- /dev/null
+++ b/dev-python/nbformat/nbformat-5.1.3.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=no
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE='sqlite'
+
+inherit distutils-r1
+
+DESCRIPTION="Reference implementation of the Jupyter Notebook format"
+HOMEPAGE="https://jupyter.org"
+# missing on pypi
+SRC_URI="
+	https://github.com/jupyter/nbformat/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/jsonschema-2.4.0[${PYTHON_USEDEP}]
+	dev-python/ipython_genutils[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-4.1[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/fastjsonschema[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	"
+
+distutils_enable_sphinx docs \
+	dev-python/numpydoc
+distutils_enable_tests pytest
diff --git a/dev-python/pytest-subtests/pytest-subtests-0.4.0.ebuild b/dev-python/pytest-subtests/pytest-subtests-0.4.0.ebuild
index 46bdd162afc3..d6925928b093 100644
--- a/dev-python/pytest-subtests/pytest-subtests-0.4.0.ebuild
+++ b/dev-python/pytest-subtests/pytest-subtests-0.4.0.ebuild
@@ -16,7 +16,7 @@ SRC_URI="
 
 LICENSE="MIT"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~x86"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
 
 RDEPEND="
 	>=dev-python/pytest-5.3.0[${PYTHON_USEDEP}]
diff --git a/dev-python/pyxDamerauLevenshtein/pyxDamerauLevenshtein-1.7.0.ebuild b/dev-python/pyxDamerauLevenshtein/pyxDamerauLevenshtein-1.7.0.ebuild
index e8da4071a099..2f711ae268c8 100644
--- a/dev-python/pyxDamerauLevenshtein/pyxDamerauLevenshtein-1.7.0.ebuild
+++ b/dev-python/pyxDamerauLevenshtein/pyxDamerauLevenshtein-1.7.0.ebuild
@@ -13,7 +13,7 @@ SRC_URI="https://github.com/gfairchild/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.g
 
 LICENSE="BSD"
 SLOT="0"
-KEYWORDS="~amd64 x86"
+KEYWORDS="amd64 x86"
 
 RDEPEND="
 	dev-python/cython[${PYTHON_USEDEP}]
diff --git a/dev-python/ruamel-yaml-clib/metadata.xml b/dev-python/ruamel-yaml-clib/metadata.xml
index 89f4a73c584b..52155d859f10 100644
--- a/dev-python/ruamel-yaml-clib/metadata.xml
+++ b/dev-python/ruamel-yaml-clib/metadata.xml
@@ -1,6 +1,10 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
+ <maintainer type="project">
+  <email>dev@liguros.net</email>
+  <name>Development</name>
+ </maintainer>
  <maintainer type="person">
   <email>andrey_utkin@gentoo.org</email>
   <name>Andrey Utkin</name>
@@ -29,5 +33,5 @@
   <remote-id type="pypi">ruamel.yaml.clib</remote-id>
   <remote-id type="sourceforge">ruamel-yaml-clib</remote-id>
  </upstream>
- <origin>gentoo-staging</origin>
+ <origin>ports</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/ruamel-yaml-clib/ruamel-yaml-clib-0.2.2-r2.ebuild b/dev-python/ruamel-yaml-clib/ruamel-yaml-clib-0.2.2-r2.ebuild
new file mode 100644
index 000000000000..ad52f330353e
--- /dev/null
+++ b/dev-python/ruamel-yaml-clib/ruamel-yaml-clib-0.2.2-r2.ebuild
@@ -0,0 +1,39 @@
+# Copyright 2021 Liguros Authors
+# Distributed under the terms of the GNU General Public License v2
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+MY_PN="${PN//-/.}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="C-based reader/scanner and emitter for dev-python/ruamel-yaml"
+HOMEPAGE="https://pypi.org/project/ruamel.yaml.clib/ https://sourceforge.net/p/ruamel-yaml-clib"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ppc ppc64 sparc x86"
+
+RDEPEND="!<dev-python/ruamel-yaml-0.16.0"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	# Force regeneration of C files from Cython sources to ensure compatibility with python 3.10
+	cd ${S}
+	rm -v $(grep -rl '/\* Generated by Cython')
+	mkdir ruamel.yaml.clib
+	mv *.py ruamel.yaml.clib
+	cythonize ruamel.yaml.clib/*.py
+	mv ruamel.yaml.clib/* .
+	rmdir ruamel.yaml.clib
+	mv setup.c _ruamel_yaml.c
+	default
+}
+
+python_install() {
+	distutils-r1_python_install --single-version-externally-managed
+}
diff --git a/dev-python/translate-toolkit/Manifest b/dev-python/translate-toolkit/Manifest
index 3e0cdf4eadf4..1b7203da734c 100644
--- a/dev-python/translate-toolkit/Manifest
+++ b/dev-python/translate-toolkit/Manifest
@@ -1,2 +1,3 @@
 DIST translate-toolkit-3.3.2.tar.gz 6123347 BLAKE2B 9bf5f2c84d15043d25744b3bb63526177748c7c38425bd73ad34dcf3b4051c11a3ce28ccaf5c907b6ced27d1fe9ecb06cfde46481a609df64adfedec83b91680 SHA512 53baf7c1203c27335201fbf339e2747d7b22696c219e6911c191b3c89cf6d1c0d84624ffa8c4c687e45fad229d3cb09f52d15d1d80dd914ccc8e2fff34a601be
 DIST translate-toolkit-3.3.3.tar.gz 5903525 BLAKE2B a21c5d89c808615ff2f3f718e732ce5d5591a9d8a997950ae1066655cc3e4382065f75e7a86f8e37bdd0e146283f9bd941ff20479cb1af635f393e0e7f8fc196 SHA512 41964dc26dfbb983b1c2e4cbb0e9d8eb2a035369a94ef872f7703080b5ca0280a9364916a1e1256cd358b263bc72198e767462cc9065b54556fc481d1b85a836
+DIST translate-toolkit-3.3.4.tar.gz 6060105 BLAKE2B 01f8e718a4a60d0f4d439be14b30b2e3f040045630d6f6254ad291a2558d59718521bfb79761d20933f7bb1abd2229ccce67fd71ccd54f6e43dffa7e7ecedd8c SHA512 6bfc4387aa600610fa2a9e7e58368924768ddcc8eb2a697ef02c59682e1e1304b7096f48a1e6e38cd47c68c644dff01d35ffc988d378dbf4833b41d1c5432c05
diff --git a/dev-python/translate-toolkit/translate-toolkit-3.3.4.ebuild b/dev-python/translate-toolkit/translate-toolkit-3.3.4.ebuild
new file mode 100644
index 000000000000..e1b12646c6f3
--- /dev/null
+++ b/dev-python/translate-toolkit/translate-toolkit-3.3.4.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/translate/translate/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND=">=dev-python/six-1.11.0[${PYTHON_USEDEP}]"
+RDEPEND="${BDEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+BDEPEND+="
+	test? ( dev-python/phply[${PYTHON_USEDEP}] )"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-bootstrap-theme
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/translate-toolkit-3.3.0-no-install-docs.patch
+)
+
+python_test() {
+	local deselect=(
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		--deselect 'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		--deselect 'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+	)
+
+	if ! use ini; then
+		deselect+=(
+			--ignore translate/convert/test_ini2po.py
+			--ignore translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		deselect+=(
+			--ignore translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing
+	epytest "${deselect[@]}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}