Adding metadata

20 files changed, 475 insertions, 10 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index af591f26f66e..ce4db56498ba 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -2,4 +2,5 @@ DIST boto3-1.34.11.gh.tar.gz 760539 BLAKE2B 8ce756d33b604aed9d42bcccf60be467bd51
 DIST boto3-1.34.14.gh.tar.gz 762792 BLAKE2B 87857a6ff7e19f8438fe6b57978cdb3c8d22f8a68008fad4fcfdd40358b919a1c45f810bc45637da5971d20ce221cd8343440663d072666349e32c4df2be97a2 SHA512 8b651c5946394e159d6dd719337e4a5a60f708fa22ef26026bd85a18b3f34efa06f71282b9e9ea8c8ad4995e4bd6d0c13e4dddac75a51922fc30154ac0b87ecb
 DIST boto3-1.34.15.gh.tar.gz 763117 BLAKE2B 52172262ea046139e1e828ded5f47564523a4e32e290e994333b73fc003c61537b8db77480dc5f7a6a2b4d5c4428819d53e0b43337fb32b1e0ea27dd81c2819d SHA512 8f6f11553d4226c6fbf9e5642a99a9a3f17f55882b80a79b6e584f0848524da0af98bf5c0729820bb73102cbcb733433febe01a188b8fc29f0187b7e4dbfb2a6
 DIST boto3-1.34.16.gh.tar.gz 763874 BLAKE2B 9186b3f5e1dad7ef235bb1e1ff25b02d07bc9fcfb59803c99f489f67128f15305dce7bee998d20f9bf33d48bb24e76f864420dd834f44a70aabbbd85bc1f22fc SHA512 25b828f4bfcd51d5d1812970dd205429317f77e90d7ce0576370302b20a2f1bb972674b82bfa95b6398088ca059009d3980569ab1e132fc33e6af8d1dc33c37a
+DIST boto3-1.34.17.gh.tar.gz 764676 BLAKE2B a6e98ad81c3eb2a028c3d474860d8ec49f55be78bd832433e22444625a03adff7f7a7b21bb2cc435837831c008aa11a9186affc0cf09ab13279db09140ed0f4d SHA512 83e17c46e9c839b6ec500ecdf3b1982f8b76c0b8ad63d66da3feb49646107be89c9ee3c913b3b03427eaf3d3d46cb34e7ef761261f3d72b78bc6771bd3f89c4e
 DIST boto3-1.34.7.gh.tar.gz 759909 BLAKE2B 059228d7bd57ac34274437f77b3510dff6dca7d1293ffd6f7672b0fcc0acefffeeda2c5c2b4e19ef49bbffd4746dc226edfba52d57f5f8629516c9e830dbdd90 SHA512 43395937977ad3c860ede35d2adbb9575312ddab4972b8d258e41a7d6e86f3e6a74037dadb0f0e0f4f3d5ed715a66390041ac9c980bc8a3cfb727a44e252113e
diff --git a/dev-python/boto3/boto3-1.34.17.ebuild b/dev-python/boto3/boto3-1.34.17.ebuild
new file mode 100644
index 000000000000..13391b8a8e76
--- /dev/null
+++ b/dev-python/boto3/boto3-1.34.17.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/boto3"
+	inherit git-r3
+	BOTOCORE_PV=${PV}
+else
+	SRC_URI="
+		https://github.com/boto/boto3/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 6c6a37c60233..dfe1429fa178 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -2,4 +2,5 @@ DIST botocore-1.34.11.gh.tar.gz 12612317 BLAKE2B 8a8648dfb27fad0d0a52df37ce9d988
 DIST botocore-1.34.14.gh.tar.gz 12617340 BLAKE2B c4aac6682ccb8951f4652477857d58221c4f0d8f1d154b7ecfa4e536f6bdb199e4be43ef63f0fce0843e95c01cfc0a479af8c7773a9717461afc04cd4bb27912 SHA512 44b7b0e96c815b033dc603892c3940869a37c76d0826812d5778b644ca785ff27f870f3ec54c7d87696bd57d2a38cc31c4b3e70f295fe9d588afc12e8f7a914e
 DIST botocore-1.34.15.gh.tar.gz 12619235 BLAKE2B 00e264f689946985207fa9dfc65ea1a1e90a7d41008a87bfe32c3c49542d4d26fa1a41f2a263fd395a32ef7eb7ae03846c1681325a61e8409a75c05a5eeccc67 SHA512 c2a137d45f05c355f912dcedcc690ec61cb1e3ff53e8fd5ccc055c49fd4b7acdafa0e88099bdad6eb8112fdcd1ab26b259efe409df340f885f9b7ca7d305d572
 DIST botocore-1.34.16.gh.tar.gz 12620688 BLAKE2B 5b08650867649d6aafbd2219e3e5f9af8f2dbcbfbed2eb293c725d50242edd7584021c9f8cbed3232916bac46e7b323903e2f3767c3488d156a31e68dd678138 SHA512 b48b63b35d127732ccf6b37b029dc5d84c27e5104a9898b1a918db76afb4f2bddf428be97f6cda3d1107af30e4c3579f283add1ffbb51f075c5a445af42b83ca
+DIST botocore-1.34.17.gh.tar.gz 12627762 BLAKE2B 127afe95d4bf1bd09912b7725d601656a8fc6098d97cdbecedd9c5117d6b2bfd640a90f9f8d457af49308e59b369b31a3123785999c11dee17d8ae9b9ba03ec9 SHA512 d01061b2b4b887ba409e60ad84c5fae6d91f5773839d18ad29db1567921383b89be4b0a2c56c9b7ada59d7a73236fc305fb7b3a8abeff359daecf939b26b13ad
 DIST botocore-1.34.7.gh.tar.gz 12606475 BLAKE2B 387ee7dfab43c44c39c7b0566b6ddcb2b666024b5b7bee2c996194988781c169e1e9462b36d09861d1c3ca899d263392f3d79129e7a2f2fc4bbfed402f5c7dd6 SHA512 3f162d4d028dd81da552e0117671971aa891bf8fab513730f40083660fa83c1f82bf1b52875cf9f7f11089ecdd79f084f3c8e76227aa826c1aac7e5735032450
diff --git a/dev-python/botocore/botocore-1.34.17.ebuild b/dev-python/botocore/botocore-1.34.17.ebuild
new file mode 100644
index 000000000000..2fc3a4924fdb
--- /dev/null
+++ b/dev-python/botocore/botocore-1.34.17.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+if [[ "${PV}" == "9999" ]]; then
+	EGIT_REPO_URI="https://github.com/boto/botocore"
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/boto/botocore/archive/${PV}.tar.gz
+			-> ${P}.gh.tar.gz
+	"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x EPYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/environs/Manifest b/dev-python/environs/Manifest
index e34d30ab6146..4adff21d96f3 100644
--- a/dev-python/environs/Manifest
+++ b/dev-python/environs/Manifest
@@ -1,3 +1,4 @@
 DIST environs-10.0.0.gh.tar.gz 23500 BLAKE2B c99a5972416a7959d06bb4541f6b319a948727386e621252e86389e3f271130917f6a056abe1363bd3bc4f10eb9d79107d9a6859fb4a745436fc35dd7a45e4d0 SHA512 4f2a485eb6a42687bd641f1468e70578eadaf01bd16fc121a9ba89725f560da1f1a4f0ba4476fbca561ffc6f4538c9a742b9335b89398d0abe09434e5e135957
 DIST environs-10.1.0.gh.tar.gz 23613 BLAKE2B 6a0e47ba5397f21d4aa4026e8046a49f1a0f19f495725e9980786fe31b03ce492ce9233d279cb960c13a7d0b592034b643e3d719732d53fe0fb28ec15fc7c815 SHA512 5faf0e3e8fb67b01e4b809c817c5547914a499642324c0a9a2e2158e686ce80416656f29865cfee60e28e72360b6a65ec8045ef682a3a02ab49639f10e180bf5
 DIST environs-10.2.0.gh.tar.gz 23749 BLAKE2B 1da049ebe9af97cc3364ffed8cf749f28ffb30453303696f421220da5b1fb86d5965b4c218b4f24cb7ea28cdf78e7e51cb0994d379fb05f0330f033b6f58d778 SHA512 c6e9fe693b3d59b1d15dad66ac29aff1a7ade7a8e3199c613fc29b2c3741506e6d87c27962aa0e764fae37e37a0a797de0bf490ceebce38e6319223fe1cc5b87
+DIST environs-10.3.0.gh.tar.gz 23931 BLAKE2B fbf6780de3a98078b76edb941361ff52cd93df51cc4c9003fa780b8fc8e366be4420de2f3ff69293f0379462c0ddfc4cf132ab67443c9b0508cca7f3b2d227fc SHA512 de58aaa2dc46b9e0db026ff7c2bef9dbf247fa96eb7d12ef105981395f3141e1726f19062551ed139daa33ba1fd9b584d11b425c836496da1ecf9f69fcb409e9
diff --git a/dev-python/environs/environs-10.3.0.ebuild b/dev-python/environs/environs-10.3.0.ebuild
new file mode 100644
index 000000000000..e7f26f7ddc94
--- /dev/null
+++ b/dev-python/environs/environs-10.3.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for simplified environment variable parsing"
+HOMEPAGE="
+	https://github.com/sloria/environs/
+	https://pypi.org/project/environs/
+"
+SRC_URI="
+	https://github.com/sloria/environs/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	dev-python/marshmallow[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/django-cache-url[${PYTHON_USEDEP}]
+		dev-python/dj-database-url[${PYTHON_USEDEP}]
+		dev-python/dj-email-url[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( CHANGELOG.md CONTRIBUTING.md README.md  )
+
+distutils_enable_tests pytest
diff --git a/dev-python/jsonpath-ng/Manifest b/dev-python/jsonpath-ng/Manifest
index 739fddd28291..4c6c86029e4e 100644
--- a/dev-python/jsonpath-ng/Manifest
+++ b/dev-python/jsonpath-ng/Manifest
@@ -1 +1,2 @@
 DIST jsonpath-ng-1.6.0.tar.gz 37132 BLAKE2B 5af13db8ab85482656d5c1501edfb2c61dc62a08a2c90a12a7ba7b141b538b5ebfca86c856b9f65ef1c1b82329eb0ed7db5c1890d881e4cb968cb6ca31ddeb6f SHA512 46eefe57330887143b98ef4deb97c5d7242f0cfbd923dffc17bd4147326ea4333c76df2451fbbb27933ada872628ad1ec04bdb9fc8e2c288c89bf37ec3783c43
+DIST jsonpath-ng-1.6.1.tar.gz 36024 BLAKE2B ed6b47974e55c8bb5e086249c24d847dc0e1719d6912c0097bf6bcc06ad096f54b99f9c7053c088bb2efae4c612a49364cae3b061593890508e408b6776e73fb SHA512 84f4ceb3b2e76665b56df6c6cd9bf8c155d3677cc6b4798531bb35e95a591e98186c7fa756d400cbbde4c62acc7da077d0fdf989f5101846fb74bba83dd4be58
diff --git a/dev-python/jsonpath-ng/jsonpath-ng-1.6.1.ebuild b/dev-python/jsonpath-ng/jsonpath-ng-1.6.1.ebuild
new file mode 100644
index 000000000000..7b71d7e70c4c
--- /dev/null
+++ b/dev-python/jsonpath-ng/jsonpath-ng-1.6.1.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_NO_NORMALIZE=1
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python JSONPath Next-Generation"
+HOMEPAGE="
+	https://github.com/h2non/jsonpath-ng/
+	https://pypi.org/project/jsonpath-ng/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/ply[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/oslotest[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/langdetect/Manifest b/dev-python/langdetect/Manifest
index e9da2ac43cac..a11d7c268c91 100644
--- a/dev-python/langdetect/Manifest
+++ b/dev-python/langdetect/Manifest
@@ -1,3 +1 @@
 DIST langdetect-1.0.9.tar.gz 981474 BLAKE2B ea8a9c3f16a2987c080742473bff4f2c1503f53fb3c2b40b0b1d6212bb6133ea22dce7864ffcfb8968c3a46b157d45cb3e2cf6f84bdbed0266cc716a853b032c SHA512 7558d674c47b080c79e43a00a25d2c7f77188cf60bea2cecb3bebb803d75e1aa42b43c74bd26ea1b541f4cb927421908882cbec01a91f0913984217e71ccc8db
-EBUILD langdetect-1.0.9.ebuild 493 BLAKE2B 0df8bce19bc80f79f8e76bcef5a4c2caf333365fe0cb9a3c076b7858bceded5a3e58921474f866a2709dd657b7ed330c1ec4a7f9d7bab0fcf1bc92d77cabc32d SHA512 ea2a1adcb133ac5fc951ba1aa90ef1ce3dfcc424e59727591763d4875aa044a74188be2d15fd89c6b2e83ed6ea04ec3d9851ed584ae79d2c2c127bde7d994b48
-MISC metadata.xml 457 BLAKE2B 630128a3e982b6d60cc7b9f74c79fcb5ee47a71a02c73a50af9da8cedb6fad8e20a7f74b881e5b25c6483b92c9edbd56552cd38b2d9cbfa8b3eb4530facea969 SHA512 674f4f5cd809c6c77bc14e0f5687fa972bef14bdfa0b3343c5d66b7163eef1906eb87d060c8288732f825de71dce291ad0b841a5f2f0dd230f957b5687e45d45
diff --git a/dev-python/langdetect/metadata.xml b/dev-python/langdetect/metadata.xml
index 020e07f2a3dd..736a1167c898 100644
--- a/dev-python/langdetect/metadata.xml
+++ b/dev-python/langdetect/metadata.xml
@@ -1,12 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- <maintainer type="person">
-  <email>marcin.deranek@slonko.net</email>
-  <name>Marcin Deranek</name>
- </maintainer>
- <upstream>
-  <bugs-to>https://github.com/Mimino666/langdetect/issues</bugs-to>
- </upstream>
- <origin>slonko-overlay</origin>
+ 
+ <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/pytoolconfig/Manifest b/dev-python/pytoolconfig/Manifest
index 0480a5f8ff9f..9e401f84587f 100644
--- a/dev-python/pytoolconfig/Manifest
+++ b/dev-python/pytoolconfig/Manifest
@@ -1,2 +1,3 @@
 DIST pytoolconfig-1.2.6.tar.gz 16425 BLAKE2B 669c3bc906b06ac48ecb5649f1bef8a6af53e85d8f8d23f4059b63e4d1e57e10b0a66d2e89e72e0b4afe7d00aa9d26b4ceb23cc49b8e46a891e7fae60d228686 SHA512 beade8cd1780eb986dab1d630c1583c9c75fea5067d399081a5b8361789fdec96087243d8d79291655c83aca481d5888b3414a1b445200a9d8c59703761a83b2
 DIST pytoolconfig-1.3.0.tar.gz 16686 BLAKE2B 77459f0d19bfd362ed8f0919ce27a3362e76add948dab224d38b3faa0dc07055181276fe2406150bdb5fdebf485031ef5e3de8344edc07bf6558e902c8c703e0 SHA512 9128f2ae116fb97edf991553207a97041df6b866e2ee4b4d05333418564a0429fdeb28c7807c3784707259f0700bb870955e89702fd5b723f19ae7639daaf150
+DIST pytoolconfig-1.3.1.tar.gz 16655 BLAKE2B 8a35f6e1751b99e7bccb81f173ee56dfc94b586237e28e8ddcc859befb6ff502469fd70f02521216585367bc87c85ac81503055f055cf355be12476bc3efe608 SHA512 c8321a5e46593044828d737532926a2df0341f563bd15ee7ffa39ebba8ab2ddcf8a56d6c099d3b8801cb65bbe7e688fddd916fc9f2babc862d00f0a925837a12
diff --git a/dev-python/pytoolconfig/pytoolconfig-1.3.1.ebuild b/dev-python/pytoolconfig/pytoolconfig-1.3.1.ebuild
new file mode 100644
index 000000000000..64f7baf3e41f
--- /dev/null
+++ b/dev-python/pytoolconfig/pytoolconfig-1.3.1.ebuild
@@ -0,0 +1,35 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python tool configuration"
+HOMEPAGE="
+	https://pypi.org/project/pytoolconfig/
+	https://github.com/bagel897/pytoolconfig/
+"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-23.2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-3.11.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10 )
+"
+BDEPEND="
+	test? (
+		>=dev-python/sphinx-4.5.0[${PYTHON_USEDEP}]
+		>=dev-python/tabulate-0.8.9[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
diff --git a/dev-python/sphinx-celery/Manifest b/dev-python/sphinx-celery/Manifest
index 0715199e3548..231c4b5222b7 100644
--- a/dev-python/sphinx-celery/Manifest
+++ b/dev-python/sphinx-celery/Manifest
@@ -1,2 +1,3 @@
 DIST sphinx_celery-2.0.0.tar.gz 16203 BLAKE2B 439a9cd20e09071491338016ba83514e37c7cdfa34966e93e3c6062ed94cdaa0750351a0de9fc7b27be1b7e557b5625be73f01f1de59d15f36335e9d46d35cae SHA512 1beca69fe9b56d04cd3c42aa9244d50a364a860e9cf53f94897c0f690b8465f4e2a7b10ed6d310d3fa706d86f5882a338cd982a3ac7cec36586269756e9128a5
 DIST sphinx_celery-2.1.0.tar.gz 16612 BLAKE2B 8fc50186f589e00b26b7550f28ee4b4e863b58ccde682a53a70e90d53d4cd31777f6363a8d2dc58000db86bff0cdb957b74234d15d68c189cb9371c6e4b06cd0 SHA512 63abdf8de1f30550172f15c41eb51c1f200b83eaacda1b6c209138d9a4057fa6c0f711904fe11611ea08d18e957b3966038a0b6b4ca4d5d7cdbbaeab9bab601a
+DIST sphinx_celery-2.1.1.tar.gz 16615 BLAKE2B a4e3e92d54b78e04638185afb1f51f093303a2008b80369263357d3ca7e8cd18c1292e621c14a600def0c2e88c214d940fbd505aa70c8b7e29f546f5654e130a SHA512 8236409ee05647f4d78cf7e7ea210a0b3d9052df48d493c120ed9a21601e132885c5b054a5f550489e0787ea7e7bb34c84bab81251a0578a7ef59a4be04ff65d
diff --git a/dev-python/sphinx-celery/sphinx-celery-2.1.1.ebuild b/dev-python/sphinx-celery/sphinx-celery-2.1.1.ebuild
new file mode 100644
index 000000000000..392b1263ad6a
--- /dev/null
+++ b/dev-python/sphinx-celery/sphinx-celery-2.1.1.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Celery Sphinx Theme and Utilities"
+HOMEPAGE="
+	https://github.com/celery/sphinx_celery/
+	https://pypi.org/project/sphinx-celery/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/sphinx-2.0.0[${PYTHON_USEDEP}]
+"
diff --git a/dev-python/starlette/Manifest b/dev-python/starlette/Manifest
index 3ccb07851380..b0f1c69ed9b7 100644
--- a/dev-python/starlette/Manifest
+++ b/dev-python/starlette/Manifest
@@ -1 +1,2 @@
 DIST starlette-0.34.0.gh.tar.gz 2841390 BLAKE2B c7eb980fe0a1a6fff0e2bb0c2bb0af4a409933a51de28d2641698f39f8280e7e1d767927f6f919cbb6e5817d34f81b48835c3ad8600c05c6194f70e4f0475d39 SHA512 bf8ce6b665f91e0410dca7b4f427f07cf977f5e9dd6614cf7c06ef2521e359410cdfc2008d7324a500c68bb8b1ecfd9b3a165c7dfc62a84c01762910debb981e
+DIST starlette-0.35.1.gh.tar.gz 2842796 BLAKE2B 1ea63f30d65103754559700eb2db699b3d03ce1dfc78081e7d2b9a680839dd0a453059d858e8b1390da2779ba755d5074033c53b5392ee7071fee27cc6739935 SHA512 75703c2ee23dd19e9c8bdd24a0a3d84f50486c0df0cad9609e0e08eb1fd3c61a4f56887d60018fbec4227bde2b3e12fb09decc865b8d5073bc4a1e066b6d5f69
diff --git a/dev-python/starlette/starlette-0.35.1.ebuild b/dev-python/starlette/starlette-0.35.1.ebuild
new file mode 100644
index 000000000000..0106c8d8c43b
--- /dev/null
+++ b/dev-python/starlette/starlette-0.35.1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="The little ASGI framework that shines"
+HOMEPAGE="
+	https://www.starlette.io/
+	https://github.com/encode/starlette/
+	https://pypi.org/project/starlette/
+"
+# no docs or tests in sdist, as of 0.27.0
+SRC_URI="
+	https://github.com/encode/starlette/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/anyio-5[${PYTHON_USEDEP}]
+	>=dev-python/anyio-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.22.0[${PYTHON_USEDEP}]
+	dev-python/itsdangerous[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/python-multipart[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/trio[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Unpackaged 'databases' dependency
+	tests/test_database.py
+)
+
+distutils_enable_tests pytest
diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index f8f718d0d18d..4e4239e98224 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -1,2 +1,3 @@
 DIST tox-3.28.0.gh.tar.gz 309472 BLAKE2B 9896411426f6aebb3efa468c01696ecc5f17ec3e67825672d0efc74c1b1468bc8b8d9c14b6177c181750ba4b9a5e77d616068dd83e21f5641acfc8e2a271cc1f SHA512 64816754e6800661bb564c5c7d21c4139522d540a04fafe3c4591d596072d48d1cbe0ee2abee9c8faf3d5007774f5371431b5a7a8f49912bc879c7b168aab2ca
 DIST tox-4.11.4.tar.gz 176168 BLAKE2B 03cf6337450494772a85787f2a34eaebfd1db159689fa4c26128efacb968b6aaac995c13a70ffaf1a7dde89107c9bb1975366ff1cc47a46979c7a1cfbd6c3402 SHA512 4b6149ec5945d67d3f5afd309a71a7845fe3ca2ca1291cb08327bda2177d2623ca49d52548fabf7856416dd90973c82566559a738946038963e7aada544ddc30
+DIST tox-4.12.0.tar.gz 176784 BLAKE2B 726bf83a041fde29e28a30309cb5a6d07ae4569f665cf36eb2f8b8463159fb4464d7795c7fa8e132d186ae5eb8df398706a0a99f72f4d6eb4ac431713e866f3c SHA512 51ca9c6819e3b8ee1b7146ec451676492e34b2f2f415db5781c7ab3d0d343dbaa15d6cc4060ea62179d121fe01af162ae973ab6d0a0841824f9d98ddcb5147a4
diff --git a/dev-python/tox/tox-4.12.0.ebuild b/dev-python/tox/tox-4.12.0.ebuild
new file mode 100644
index 000000000000..383832e92fad
--- /dev/null
+++ b/dev-python/tox/tox-4.12.0.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{8,9,10,11,12} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/tomli[${PYTHON_USEDEP}]
+	' 3.{9..10})
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	[[ ${EPYTHON} == pypy3 ]] && EPYTEST_DESELECT+=(
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[constraints-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[explicit+requirements-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_indirect-True-True]'
+		'tests/tox_env/python/pip/test_pip_install.py::test_constrain_package_deps[requirements_constraints_indirect-True-True]'
+	)
+
+	epytest
+}
diff --git a/dev-python/trimesh/Manifest b/dev-python/trimesh/Manifest
index 6cc1cbcf083b..7c55b65104f6 100644
--- a/dev-python/trimesh/Manifest
+++ b/dev-python/trimesh/Manifest
@@ -1,2 +1,3 @@
 DIST trimesh-4.0.7.gh.tar.gz 13435408 BLAKE2B 72c9bf419e8a2e74f80922cba41cd999b6245e2376b38034b31d3741b9c9095ad578b46a45f02986f4735fc31086751f6eff1ac49f22af50c7061bf815550e62 SHA512 fcbc6cd917d1b6d0d23064efe6c484c8f920e966c9108cc9664cea502d43abc4cd3fb77cdd54491bb3098efae964910a9fb211aef763f576cf0ab1ae1267f657
 DIST trimesh-4.0.8.gh.tar.gz 13434746 BLAKE2B 858ad7daf9cff3bbedef3ea124d6af1be96233b09a2bd9abd0d2cc43b6f981f844300a36dfef751caf1abf721dd0481a189e0d80ddba8a3fcacbe87183c3d26e SHA512 77472e954b9defdf39fac7813aad892f56f02da475801effdac7de28b6e28f6ca5a7c99fa51013e44435a2143f01a5a2be1e8419c1c81c0c02dca237b8e21dd3
+DIST trimesh-4.0.9.gh.tar.gz 13435804 BLAKE2B 7e07ad04f7c08b01763ce0d4f50ad7a00fa4888f43abab92bbce495cb0c1dc8815e0c346e326f19c811fbe8d9d2657b45390016f1508e1d994ee529af182b2c1 SHA512 8d6d48a7889693536a54355efac5dc35eb2a8babeb5c93d71127e65935e7750d7330bd9b96b31b37dded7a5fd50151d39b6c38a29e0075374ee29ca975e5ed9d
diff --git a/dev-python/trimesh/trimesh-4.0.9.ebuild b/dev-python/trimesh/trimesh-4.0.9.ebuild
new file mode 100644
index 000000000000..364d5a02286d
--- /dev/null
+++ b/dev-python/trimesh/trimesh-4.0.9.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8,9,10,11,12} )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for loading and using triangular meshes"
+HOMEPAGE="
+	https://trimesh.org/
+	https://github.com/mikedh/trimesh/
+	https://pypi.org/project/trimesh/
+"
+SRC_URI="
+	https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/chardet[${PYTHON_USEDEP}]
+	dev-python/colorlog[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	dev-python/jsonschema[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/networkx[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycollada[${PYTHON_USEDEP}]
+	dev-python/pyglet[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/scipy[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
+	dev-python/svg-path[${PYTHON_USEDEP}]
+	dev-python/sympy[${PYTHON_USEDEP}]
+	dev-python/xxhash[${PYTHON_USEDEP}]
+	sci-libs/rtree[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/mapbox_earcut[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_TIMEOUT=900
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
+
+pkg_postinst() {
+	optfeature_header "${PN} functionality can be extended by installing the following packages:"
+	optfeature "making GUI applications with 3D stuff" dev-python/glooey
+	optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
+	optfeature "loading a number of additional mesh formats" dev-python/meshio
+	optfeature "figuring out how much memory we have" dev-python/psutil
+	optfeature "marching cubes and other nice stuff" sci-libs/scikit-image
+}