Adding metadata

24 files changed, 642 insertions, 87 deletions

diff --git a/dev-python/boto3/Manifest b/dev-python/boto3/Manifest
index 89b1aea41c8e..c8f09622516d 100644
--- a/dev-python/boto3/Manifest
+++ b/dev-python/boto3/Manifest
@@ -1,3 +1,4 @@
 DIST boto3-1.35.86.gh.tar.gz 917880 BLAKE2B 9ebf2ff2d8674013f6edead87ff92c649e977ff942fd50dfe80da4ac7a00f812735ff38791e5572b442524d335a838f4cb16fa0cc2bf54e51ef5932cb4639bf2 SHA512 4daa945a64381aca49175211b40893bf05ec733a92ab8b972c3c3e53cfd29ac8ca142c7903ee49ba75097bdf10f7a7b36d35ff0f8cb1501b12149c9f6dffdb65
 DIST boto3-1.35.90.gh.tar.gz 918672 BLAKE2B a875ee6f59cac2a5f085719fed71090f8d717071dc7e2941075d12d3d98bd9850283c157a9176e890f67dfb78f68cd9f3942e0c8515629f70fa9cd9090eac837 SHA512 ab19a1fc324fb151cf781ac8de306af67edceb7190c6970e296c1f6dfc59e66da6c056a84aefbbe2509c7acb33ca3da81ad58736217ad45ccc16490eb4d96fc2
 DIST boto3-1.35.92.gh.tar.gz 919812 BLAKE2B fd52fbcb99538e46fd05e117353a93f8496150c6c518d445c2c78d8c91390fe6a15cdad419f25b1ced5b1433f1e63ff8204a25ee452e995f715dd915ea676d17 SHA512 7e9bc15b43e3e4babce3465e96b58f177eea316751f0c9982bc33e17ae3673cef026871bfb4bfdd254debfd3c7a342e3afa6aa65d9c97aefea13a9922b010fd0
+DIST boto3-1.35.93.gh.tar.gz 919950 BLAKE2B a16e9d7cd6d7d6ba4718705d94a1474cbe96b68cefdc6a8fba4f37e31ca736d33cb1a10018ef670005987c793f842ce58cde9690ddf6ccb7696eed91f55ec1e7 SHA512 96abe2cdb58a8cc1d6da203746b19c2742a773b540c07aebf62b75c97183b52fb0be1748a973583a7e9aa0977eccaa824a65daa4e7d126c9e761dcaaa842a9f7
diff --git a/dev-python/boto3/boto3-1.35.93.ebuild b/dev-python/boto3/boto3-1.35.93.ebuild
new file mode 100644
index 000000000000..121459c7c328
--- /dev/null
+++ b/dev-python/boto3/boto3-1.35.93.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="The AWS SDK for Python"
+HOMEPAGE="
+	https://github.com/boto/boto3/
+	https://pypi.org/project/boto3/
+"
+SRC_URI="
+	https://github.com/boto/boto3/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/botocore-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.10.0[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't lock versions to narrow ranges
+	sed -e '/botocore/ d' \
+		-e '/jmespath/ d' \
+		-e '/s3transfer/ d' \
+		-i setup.py || die
+
+	# do not rely on bundled deps in botocore (sic!)
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/botocore/Manifest b/dev-python/botocore/Manifest
index 7483062ca247..758408656aa9 100644
--- a/dev-python/botocore/Manifest
+++ b/dev-python/botocore/Manifest
@@ -1,3 +1,4 @@
 DIST botocore-1.35.86.gh.tar.gz 14177900 BLAKE2B 7b80010dca6496eceedf8598f195ac80d4416c0f2032f931586a1db2ec100185e8c9591d6d42f549fb9a579b295178aee293c4b317717b4e9264d9adc54fb2c5 SHA512 28185963f5a3a937bddcd47a3afc13fab16b32ec092bfa7b6c007ff77cfe5e0ead1b253f708ff9077638185173034d484abee0d49f97475a88dfb00fad0c31c2
 DIST botocore-1.35.90.gh.tar.gz 14180996 BLAKE2B d3b39e375d33af6515649c9be4b783e6dc7717ffc29460f83507ba392ae4b77a55811e07b7a0fc732e9d5d24b7bd0d1dee450ae7c62ef535c7f70d79936cb186 SHA512 8814eb1c435f753195f5189d21bb60ae29ccc007f16cd451bea0fc7650b6c5daf1c94e07e04d95b3c320974b2dcf27520aa3ab6b56b1351b22d137312d9dc3c2
 DIST botocore-1.35.92.gh.tar.gz 14183742 BLAKE2B daace36b81ddb44f13e785979c37d1f22a997c88e32554595a0db910a93148fccbf74def98b64210ee8159bf41fec99f57750741f13e2b468268035413d9bce0 SHA512 fb916bbe9c572c02fec36748ec3c5c3d6f9b9e8c7afd09bd48221675a6738ca9cafd2a05862236275e3b156cb392953b9a23d958afa9ad88b2a2d89fa23c02b9
+DIST botocore-1.35.93.gh.tar.gz 14185677 BLAKE2B 83e3ab9cc71d0bca546f7c18a82df5b8c1914eaafd07ba6797bcf7321cdaca491f59f89f07cd89fedb30cb5991e925d757c402cd1897c19300e10fb89b17140a SHA512 8e4da86457fea49a747226d25c31c68eba02e015451dac56fdd8f90f46b826aba7c4789f47dbaefe4c34624050e9348b0bfdc1cbb131b105d4ad192bf89e994d
diff --git a/dev-python/botocore/botocore-1.35.93.ebuild b/dev-python/botocore/botocore-1.35.93.ebuild
new file mode 100644
index 000000000000..27c19bdb74d8
--- /dev/null
+++ b/dev-python/botocore/botocore-1.35.93.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Low-level, data-driven core of boto 3"
+HOMEPAGE="
+	https://github.com/boto/botocore/
+	https://pypi.org/project/botocore/
+"
+SRC_URI="
+	https://github.com/boto/botocore/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	<dev-python/jmespath-2[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.4[${PYTHON_USEDEP}]
+"
+# unbundled packages
+RDEPEND+="
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# unpin deps
+	sed -i -e "s:>=.*':':" setup.py || die
+
+	# unbundle deps
+	rm -r botocore/vendored || die
+	find -name '*.py' -exec sed -i \
+		-e 's:from botocore[.]vendored import:import:' \
+		-e 's:from botocore[.]vendored[.]:from :' \
+		{} + || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# rely on bundled six
+		tests/functional/test_six_imports.py::test_no_bare_six_imports
+		tests/functional/test_six_threading.py::test_six_thread_safety
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests/{functional,unit}
+}
diff --git a/dev-python/environs/Manifest b/dev-python/environs/Manifest
index 199b96f75ef7..0917b4a35e0f 100644
--- a/dev-python/environs/Manifest
+++ b/dev-python/environs/Manifest
@@ -1,3 +1,2 @@
-DIST environs-11.1.0.gh.tar.gz 24227 BLAKE2B 5a4ebec604dedccf6757fa69f0ae9a5d426c23e8f0bcdbbe51f2ca190e2cfe4cebaa473656dedee4486bf7f61eef102b60a1553426ece78129aec65baded0ad0 SHA512 a7564a251228d3fa131af96a2cad312d8e3c3ba95fa56c4b0abf74a6040c70b77e147120f9646f6f3fd6339760561b63e920494fe26b4fcb1f2caac32f7d7703
-DIST environs-11.2.0.gh.tar.gz 25195 BLAKE2B eba1cf8731db715c04345bc33100ef5bb2693a81e2815195164d56ada02eff8d65f3a2328e7d87b17c858df4cb8a7418120dceb49cf1e44c42dd25d249661469 SHA512 50d1e68fec2cd47a6805cb87ce8a1f7692cc3797ca30177189d3268bc91716671735dca8c085fcb5ed733e38e88b69354a6fc5b6a4ceb480e03ecf7d9a40391e
 DIST environs-11.2.1.gh.tar.gz 25595 BLAKE2B 478818c964625965200b154ef9412a1d94ac9f78d507be0ebd378117613e7c7f8163c9db58225220ef9cde68367f973999a9914f13db6bdee02c83e9ee924518 SHA512 cd859e86b4308047ad661f3fa12788a117f70686e3f5dc7f55e876c9de38c6d2b75f208b488b99f3c9189080e8ebb45385fea45421d55e9b2f9a22ba4a3fbd86
+DIST environs-12.0.0.gh.tar.gz 26281 BLAKE2B d663ede5220bc3d1b6f3a1da5b2b8500bfc98d134bf9ec00a81796fb1619c98e96b2336e474dee2d17e6b541fd97bcd916dcdb5d19509a76f6af28e2bf26b691 SHA512 30622788d787516408cb9a6548124475a752fb37284f880c534763007c736daf0c666c8e8c773cbb078da7ac3ba5b271aaf28d3d7842afb6da630bddf5233623
diff --git a/dev-python/environs/environs-11.2.0.ebuild b/dev-python/environs/environs-11.2.0.ebuild
deleted file mode 100644
index 7b183725113f..000000000000
--- a/dev-python/environs/environs-11.2.0.ebuild
+++ /dev/null
@@ -1,39 +0,0 @@
-# Copyright 2021-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=flit
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-
-inherit distutils-r1
-
-DESCRIPTION="Python library for simplified environment variable parsing"
-HOMEPAGE="
-	https://github.com/sloria/environs/
-	https://pypi.org/project/environs/
-"
-SRC_URI="
-	https://github.com/sloria/environs/archive/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64"
-
-RDEPEND="
-	dev-python/python-dotenv[${PYTHON_USEDEP}]
-	>=dev-python/marshmallow-3.13.0[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		dev-python/django-cache-url[${PYTHON_USEDEP}]
-		dev-python/dj-database-url[${PYTHON_USEDEP}]
-		dev-python/dj-email-url[${PYTHON_USEDEP}]
-	)
-"
-
-DOCS=( CHANGELOG.md CONTRIBUTING.md README.md  )
-
-distutils_enable_tests pytest
diff --git a/dev-python/environs/environs-11.1.0.ebuild b/dev-python/environs/environs-12.0.0.ebuild
index 7b183725113f..8c076dc050bc 100644
--- a/dev-python/environs/environs-11.1.0.ebuild
+++ b/dev-python/environs/environs-12.0.0.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2021-2024 Gentoo Authors
+# Copyright 2021-2025 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
diff --git a/dev-python/hypothesis/Manifest b/dev-python/hypothesis/Manifest
index a30d84e422d1..2afa74fc4e99 100644
--- a/dev-python/hypothesis/Manifest
+++ b/dev-python/hypothesis/Manifest
@@ -1,2 +1,3 @@
 DIST hypothesis-6.122.5.gh.tar.gz 9499110 BLAKE2B 57de8290600ceadc408804d4ec5df7bc96977757dfb9039d894e39bef6c0a53fd3453ac86320353079c4835218557e5331a45894e5f61a60191c562c334827dc SHA512 67df638efaca6fccafba2305042a785c32ea532ac52336f55e38fe085351052386408399e0097572a9be546891212286228a12b48839892883284a4cee01ff33
 DIST hypothesis-6.123.2.gh.tar.gz 9506171 BLAKE2B a7033cf2b5d56753ce19c5b369889b62d88c86df8254c840341c599dd97f575fc84e73236e701f4303d6141146bdef24f13f8d666f30a578ff80b067976934ba SHA512 d46b3d83a14b629a39f7eb2dcb0915802ee8185b4796ea38d053e44f2e8e4025a053c99a0aea7b4b59442a24fd3600b78d5a19e1f0bbd13e8a2d9f93cdca3df6
+DIST hypothesis-6.123.7.gh.tar.gz 9509012 BLAKE2B 71def0634aee97b4d64bacf9b4a09e091fb209c9de2d2ecbcbb86ad0f7bc2e330e7d7b93e1c810b864fd80ecd82eb6bf51aaf6a6de99c74c338609062ce1e90e SHA512 00b26f4e040a948aaf64554ee395fad4c9b0bb116c87d97bd3ef20be1d25068a79ed1c856c497c1d3d5122481386625c3323be77c0ec851fab823a706350b437
diff --git a/dev-python/hypothesis/hypothesis-6.123.7.ebuild b/dev-python/hypothesis/hypothesis-6.123.7.ebuild
new file mode 100644
index 000000000000..b67bbcacc7ba
--- /dev/null
+++ b/dev-python/hypothesis/hypothesis-6.123.7.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+CLI_COMPAT=( pypy3 python3_{10..13} )
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+PYTHON_REQ_USE="threads(+),sqlite"
+
+inherit distutils-r1 optfeature
+
+TAG=hypothesis-python-${PV}
+MY_P=hypothesis-${TAG}
+DESCRIPTION="A library for property based testing"
+HOMEPAGE="
+	https://github.com/HypothesisWorks/hypothesis/
+	https://pypi.org/project/hypothesis/
+"
+SRC_URI="
+	https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/hypothesis-python"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="cli"
+
+RDEPEND="
+	>=dev-python/attrs-22.2.0[${PYTHON_USEDEP}]
+	>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
+	' 3.9 3.10)
+	cli? (
+		$(python_gen_cond_dep '
+			dev-python/black[${PYTHON_USEDEP}]
+			dev-python/click[${PYTHON_USEDEP}]
+		' "${CLI_COMPAT[@]}")
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/pexpect[${PYTHON_USEDEP}]
+		>=dev-python/pytest-8[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	# subtests are broken by warnings from random plugins
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local -x PYTEST_PLUGINS=xdist.plugin,_hypothesis_pytestplugin
+	local -x HYPOTHESIS_NO_PLUGINS=1
+
+	# NB: paths need to be relative to pytest.ini,
+	# i.e. start with hypothesis-python/
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# failing due to warnings from numpy/cython
+				hypothesis-python/tests/pytest/test_fixtures.py::test_given_plus_overridden_fixture
+			)
+			;;
+	esac
+
+	epytest -o filterwarnings= -p rerunfailures --reruns=5 \
+		tests/cover tests/pytest tests/quality
+}
+
+src_install() {
+	local HAD_CLI=
+
+	distutils-r1_src_install
+
+	if [[ ! ${HAD_CLI} ]]; then
+		rm -r "${ED}/usr/bin" || die
+	fi
+}
+
+python_install() {
+	distutils-r1_python_install
+	if use cli && has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
+		HAD_CLI=1
+	else
+		rm -r "${D}$(python_get_scriptdir)" || die
+	fi
+}
+
+pkg_postinst() {
+	optfeature "datetime support" dev-python/pytz
+	optfeature "dateutil support" dev-python/python-dateutil
+	optfeature "numpy support" dev-python/numpy
+	optfeature "django support" dev-python/django dev-python/pytz
+	optfeature "pandas support" dev-python/pandas
+	optfeature "pytest support" dev-python/pytest
+}
diff --git a/dev-python/iuliia/Manifest b/dev-python/iuliia/Manifest
index cbd260e4b949..5d220b4918c0 100644
--- a/dev-python/iuliia/Manifest
+++ b/dev-python/iuliia/Manifest
@@ -1 +1,2 @@
 DIST iuliia-0.11.5.tar.gz 21585 BLAKE2B 99492fb2783b92ed36231fdaaf06ff405e4ec29fa0766a29657a4fce901050e995cb88238fccffbd7bb80ab949d4b6428ad6cb251cb35568d7b95f4e650e0686 SHA512 86e9dbff7a32486ed35782055fdabb6abb014ceb4e4f26acc0933007f4be11ccbb439e13d01edfcadd19b64e241bfacbce1d4e2faf368d9aa697f3d307b4ff84
+DIST iuliia-0.13.0.tar.gz 23228 BLAKE2B 51fbcc6412a2501cd7ed9fa0c48fef28ee220fea3cf4dd1e3a551d898076c9000c226b3109d7990f346b87c268508a574458a03aaf3bb7128d3a20cb21b8e412 SHA512 98f8df0bb47412d57ec17db648b8a4842636432780f14022baaa51820a847714e8681e2b04b52f3cebc7f3ced62327747c0ec5c818b5a88ee25d491d2d66b777
diff --git a/dev-python/iuliia/iuliia-0.13.0.ebuild b/dev-python/iuliia/iuliia-0.13.0.ebuild
new file mode 100644
index 000000000000..72cd99f03f49
--- /dev/null
+++ b/dev-python/iuliia/iuliia-0.13.0.ebuild
@@ -0,0 +1,21 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+DISTUTILS_USE_PEP517="flit"
+inherit distutils-r1 pypi
+
+DESCRIPTION="Transliterate Cyrillic to Latin in every possible way"
+HOMEPAGE="
+	https://iuliia.ru/
+	https://pypi.org/project/iuliia/
+	https://github.com/nalgeon/iuliia-py
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+distutils_enable_tests pytest
diff --git a/dev-python/iuliia/metadata.xml b/dev-python/iuliia/metadata.xml
index 736a1167c898..a4431942b8d9 100644
--- a/dev-python/iuliia/metadata.xml
+++ b/dev-python/iuliia/metadata.xml
@@ -1,6 +1,15 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://liguros.gitlab.io/dtd/metadata.dtd">
 <pkgmetadata>
- 
+ <maintainer type="person">
+  <email>cyber+gentoo@sysrq.in</email>
+  <name>Anna</name>
+ </maintainer>
+ <upstream>
+  <maintainer>
+   <email>m@antonz.ru</email>
+   <name>Anton Zhiyanov</name>
+  </maintainer>
+ </upstream>
  <origin>gentoo-guru-overlay</origin>
 </pkgmetadata>
\ No newline at end of file
diff --git a/dev-python/ml-dtypes/Manifest b/dev-python/ml-dtypes/Manifest
index eb3d041189c8..2b8e67db9f36 100644
--- a/dev-python/ml-dtypes/Manifest
+++ b/dev-python/ml-dtypes/Manifest
@@ -1,2 +1,3 @@
 DIST eigen-7bf2968fed5f246c0589e1111004cb420fcd7c71.tar.bz2 2239233 BLAKE2B 3a7e81c302cb11ae1d6ef9433a9ec41506c1f37d04cfb8744ac3fcf7dbe9430c1b48d7197ca3b8e1f9354398bac3d0dbc3e0599c0b649acd6175e906befe2973 SHA512 29ee89770726e6e0f5135b7fab24649f3e69223caed90d2daa6f0014783e69fe98f0551de49bd4e393d7b7938f2943caf1ed00f3933fa771ac14fae3c63fd5dd
 DIST ml_dtypes-0.5.0.gh.tar.gz 86170 BLAKE2B a289490fd6d06801965cc72d1abfe4a3b8b48459462bc4ae73a3ace2b4385f26b46081d924c02e1342a18eb98db2df33e3dd77284e40f2357a209a85010071f3 SHA512 20b2677c1e69b9ea298ac7d8ccfee3f0d19b847a805efa183ba04845e1a1697e9030abe00d6e8a4d46981df14c8d5986bcbc3b4e0f36eef2aee1cd04e3996bfe
+DIST ml_dtypes-0.5.1.gh.tar.gz 86384 BLAKE2B 1989df40221262784983732067946bc1ac51c44db27e54d30471884508f080403107c811d33940b2de27a1cea5d5928bebdfc96b987c36d71b7f8f81f68c4615 SHA512 d0fab3492ad9f8caeec665c026baca9eca7a15fcb032267ff57d9c9b6eccb852e6659b4f7bd25f64b50974b5a93f5be9ec68ab1746ede286f22d60c13a7d2d4c
diff --git a/dev-python/ml-dtypes/ml-dtypes-0.5.1.ebuild b/dev-python/ml-dtypes/ml-dtypes-0.5.1.ebuild
new file mode 100644
index 000000000000..9741227fa923
--- /dev/null
+++ b/dev-python/ml-dtypes/ml-dtypes-0.5.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1
+
+MY_P=${PN/-/_}-${PV}
+EIGEN_CommitId="7bf2968fed5f246c0589e1111004cb420fcd7c71"
+
+DESCRIPTION="A stand-alone implementation of several NumPy dtype extensions"
+HOMEPAGE="
+	https://github.com/jax-ml/ml_dtypes/
+	https://pypi.org/project/ml-dtypes/
+"
+SRC_URI="
+	https://github.com/jax-ml/ml_dtypes/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+	https://gitlab.com/libeigen/eigen/-/archive/${EIGEN_CommitId}/eigen-${EIGEN_CommitId}.tar.bz2
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+DEPEND="
+	>=dev-python/numpy-1.21:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/pybind11[${PYTHON_USEDEP}]
+	test? (
+		dev-python/absl-py[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	rmdir third_party/eigen || die
+	mv "${WORKDIR}/eigen-${EIGEN_CommitId}" third_party/eigen || die
+	distutils-r1_python_prepare_all
+}
+
+src_test() {
+	mv ml_dtypes/tests . || die
+	rm -r ml_dtypes || die
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	distutils-r1_src_test
+}
diff --git a/dev-python/pygments/Manifest b/dev-python/pygments/Manifest
index 919fc12cef02..d452f23483b7 100644
--- a/dev-python/pygments/Manifest
+++ b/dev-python/pygments/Manifest
@@ -1,2 +1,3 @@
 DIST pygments-2.18.0.tar.gz 4891905 BLAKE2B 4ff1cc75ca348eecb96ecefe549a1e1c9a9cc81e1829a2354c70ce6f6e538bddbb9b7f90e781bbdd6433cee36e4a99fef9adaef95ca275d1be57a33ed8a77351 SHA512 2f696fed7f2120f9e3bd5f3d2837a5d6b883434b8d0f68d039c2620213508638cedf1517375019809720d56fc52f07e3bddd0defc4707703ace5d707908c00fb
 DIST pygments-2.19.0.tar.gz 4967733 BLAKE2B 0240b876edc619623f9102ef5d88a1135c9229aa34ce44a7482d6004b3b2618c1d0727bd3a43c056a0b9f745aa3fac73a13eb9875a0cd1338c43482439ba0f74 SHA512 ac7b8c85b54acf65fc4de2202c25a0dfc35daf3ac8eacc9bbae5a07fa0b66bfb5fdedd952b0917773e4f4ce5359854b2e8c4ac368c2137e5b5a794b6f267ea74
+DIST pygments-2.19.1.tar.gz 4968581 BLAKE2B 24bc120c4709af2f313010ed953a446bc29ee32269d47c3325067fea60c2a945376426a7c8d37e8916cc09e0534c2b6e63f69226768d6afd6e88dac875cc4419 SHA512 f8547b1eb032fb4c0ad15f1bb61bc6d8c25b309e61850a7ebe4e879fefe1ebb0acba53192d1294e8ef243613ba546e1e7ac7474ab1b49b1a1c1551c6733d9ec7
diff --git a/dev-python/pygments/pygments-2.19.1.ebuild b/dev-python/pygments/pygments-2.19.1.ebuild
new file mode 100644
index 000000000000..c3b50bfeb736
--- /dev/null
+++ b/dev-python/pygments/pygments-2.19.1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 bash-completion-r1 pypi
+
+DESCRIPTION="Pygments is a syntax highlighting package written in Python"
+HOMEPAGE="
+	https://pygments.org/
+	https://github.com/pygments/pygments/
+	https://pypi.org/project/Pygments/
+"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
+
+BDEPEND="
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/wcag-contrast-ratio[${PYTHON_USEDEP}]
+		virtual/ttf-fonts
+	)
+"
+
+EPYTEST_DESELECT=(
+	# fuzzing tests, very slow
+	tests/test_basic_api.py::test_random_input
+	# incompatibility with python-ctags3, apparently
+	# https://github.com/pygments/pygments/issues/2486
+	tests/test_html_formatter.py::test_ctags
+)
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+	newbashcomp external/pygments.bashcomp pygmentize
+}
diff --git a/dev-python/pytest-bdd/Manifest b/dev-python/pytest-bdd/Manifest
index 720e1d846267..ed6d832096fb 100644
--- a/dev-python/pytest-bdd/Manifest
+++ b/dev-python/pytest-bdd/Manifest
@@ -1,2 +1 @@
-DIST pytest-bdd-7.3.0.gh.tar.gz 81595 BLAKE2B 80c5323ba3c50fae17bb57ec26b968ca7d7b673d2aeb2716dee02e3543916ca8b5752d9af56d3d250f3a4b0a857a3dc760de615f0650eaf379380fb24a5b7c2a SHA512 e7c309552714a77d47e437a825e661dbf201a6945e84f4b611b5c3da3d0b4ceb535bde4809fc9633b82a74e2b52cc69c7e14b27a27032c7e4400727498442e29
 DIST pytest-bdd-8.1.0.gh.tar.gz 116529 BLAKE2B b282f42dbde9394f37e41682d44352d5895a30e2b88c20c46f8d9344f8069e25e2a7a2b6225ebd34a43b60d2392c7bc515f2ebd94bb26a0d350b7d188dd4d77e SHA512 6b03a509a8026ac242a4446caffc019b264f3528322eab8aa0ca2ce4c099bbc45640d63087a756d0d1d0daacdd2f396f121823ca500cef38391e9313a0f898ab
diff --git a/dev-python/pytest-bdd/pytest-bdd-7.3.0.ebuild b/dev-python/pytest-bdd/pytest-bdd-7.3.0.ebuild
deleted file mode 100644
index 7bf6bd13017e..000000000000
--- a/dev-python/pytest-bdd/pytest-bdd-7.3.0.ebuild
+++ /dev/null
@@ -1,43 +0,0 @@
-# Copyright 2021-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=poetry
-PYTHON_COMPAT=( python3_{9,10,11,12,13} )
-inherit distutils-r1
-
-DESCRIPTION="BDD library for the pytest runner"
-HOMEPAGE="https://pytest-bdd.readthedocs.io/"
-SRC_URI="
-	https://github.com/pytest-dev/pytest-bdd/archive/refs/tags/${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 arm64 ~x86"
-
-RDEPEND="
-	dev-python/mako[${PYTHON_USEDEP}]
-	dev-python/packaging[${PYTHON_USEDEP}]
-	dev-python/parse[${PYTHON_USEDEP}]
-	dev-python/parse-type[${PYTHON_USEDEP}]
-	dev-python/pytest[${PYTHON_USEDEP}]
-	dev-python/typing-extensions[${PYTHON_USEDEP}]
-"
-
-distutils_enable_tests pytest
-
-DOCS=( AUTHORS.rst CHANGES.rst README.rst )
-
-src_test() {
-	# terminal_reporter test needs exact wrapping
-	local -x COLUMNS=80
-
-	# hooks output parsing may be affected by other pytest-*, e.g. tornasync
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	local -x PYTEST_PLUGINS=pytest_bdd.plugin
-
-	distutils-r1_src_test
-}
diff --git a/dev-python/uv/Manifest b/dev-python/uv/Manifest
index a1e7dd1f072c..811be2e16745 100644
--- a/dev-python/uv/Manifest
+++ b/dev-python/uv/Manifest
@@ -11,6 +11,8 @@ DIST uv-0.5.13-crates.tar.xz 46487696 BLAKE2B 88805f95f170f3417fdc9c98b09fab73d9
 DIST uv-0.5.13.gh.tar.gz 3175346 BLAKE2B 86dc0b635062e17b7cb35529ba71b173b3e4d89ba8cbc747a61c3eb03a2fc751726af1f07cc20bc31b759706a893a10b9ceda9ab579dc5d1ac84a61be9ec7d4c SHA512 9dfc771c203fdb4440e38a4e8ec6d4221030c2d2eca463fb335ba8651fe702430c7497d58a0928215e3e17a20719db252959899874a38d13016f377185b5f49b
 DIST uv-0.5.14-crates.tar.xz 46533192 BLAKE2B 89451a3c162f80d4d8b9af369fe11d9661bdf06d7a5f624f91ba71d993c34faa5c412cdee352c483db0d617e2cef2db46e534a58e04cb6c741aa4a48e8d0ddf5 SHA512 dbb8d0715fb7f360dbb8d9f7af5db0a5c962bc7f91ba53edd44213074666e9abb090e2cf4d3d0e23343668028d1465c5769f24c773fef91b7d332c6d596c34b4
 DIST uv-0.5.14.gh.tar.gz 3182160 BLAKE2B c0839df464543f1ae9cf4f984c514709a44d6b11289a2dc37e33db5d15dc33c08f8bad4cfb8e62960feb63506e8395f9fa0038d6b28059677ada10be8baeaa76 SHA512 7604791df108feda9ce0a44d915785ca0520b5453c8a49c66881476606e2bf04b3d980d1200a64661decf2fa5580ba84d35bc8e766b273649f9734b5c2bbf20c
+DIST uv-0.5.15-crates.tar.xz 46668184 BLAKE2B a7f1509d03b4725bfad125b804f08f4bc57d5fa0cc7cc6128635ff8bde48ffc4a0f11cc4154877ca4b5efc8f670b7258744e8fa247367e17bf979d770622b0d5 SHA512 f8ebd846769ba0ef2f0692c6387dfcaa01f0116b15344ed666b9250c7e692dfd9fc2d37202d438e80043508af7db4a545cf7f32b47e87bc0de72cd4170818e2c
+DIST uv-0.5.15.gh.tar.gz 3188828 BLAKE2B f3c817d584e27121ec8d0e1727a4b55d05a5c9017e1df12afe603d48c66af8768fa0688a4d96375fe56556c12ffd4e2efc2ac0ba7a0745373d1d145feba0eabf SHA512 8a79c35c13dc6bf6264d3bda9967e4f32e6658ca6636de80ad07d26b2f83d58dda3c3e4e69d104cc3f9fb5b63cd89a719f196c454db5f71f8af00205cf0e6438
 DIST uv-0.5.6-crates.tar.xz 46263172 BLAKE2B 73b1d2dc957f89f923dda09a8c038426041292c442ce253ff9110f996cd1e1f892a5a438d8e1c894fc0d823401cced0ddc8ad88b5e6a83199af7055a04ce85dc SHA512 c9d4f8085416bffb1e1872fd907d15a50cae0c0c5fba994d27b3acdc3c836dffd771558246573af4bb7467353a031ea56018d5ae1fbdffa4f63988462de00343
 DIST uv-0.5.6.gh.tar.gz 2952255 BLAKE2B b815b60b99f959751f5839365b8b210919247ad99bff93ee4d202bc152bd06b83a62914cfbf341bfddb5b2c87d9e546c5e2a6d1baff1599d0218160ee89de504 SHA512 fc8c7f4f60a3d2ce997341450daf20ad039ef379ac5dd4575f8db0327284bd8278419b66f8f9695f2701a9579ab004b5b60476bd8dc4c27314211f795118bc5a
 DIST uv-0.5.8-crates.tar.xz 46445240 BLAKE2B 119e471d7f9a851179e2e5d9cd15cb94476355e27db36b05378036b7f9a3e0021a33a2fd29ed9e5a67cd7d962783b3ea96145ca9092da0a6a114899ff2b712fd SHA512 d517fdc9e48b4cb4acacf1d3c986c7e348ee65c89cb5bdbd9c3947f66d450f7f59b5a4f5f0f45560d5241bc8f7756039014cf350a8aea22be876c197759e5aff
diff --git a/dev-python/uv/uv-0.5.15.ebuild b/dev-python/uv/uv-0.5.15.ebuild
new file mode 100644
index 000000000000..bd242a76bb09
--- /dev/null
+++ b/dev-python/uv/uv-0.5.15.ebuild
@@ -0,0 +1,170 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CRATES="
+"
+
+declare -A GIT_CRATES=(
+	[async_zip]='https://github.com/charliermarsh/rs-async-zip;c909fda63fcafe4af496a07bfda28a5aae97e58d;rs-async-zip-%commit%'
+	[pubgrub]='https://github.com/astral-sh/pubgrub;648aa343486e5529953153781fc86025c73c4a61;pubgrub-%commit%'
+	[tl]='https://github.com/astral-sh/tl;6e25b2ee2513d75385101a8ff9f591ef51f314ec;tl-%commit%'
+	[version-ranges]='https://github.com/astral-sh/pubgrub;648aa343486e5529953153781fc86025c73c4a61;pubgrub-%commit%/version-ranges'
+)
+
+RUST_MIN_VER="1.83.0"
+
+inherit cargo check-reqs
+
+CRATE_PV=${PV}
+DESCRIPTION="A Python package installer and resolver, written in Rust"
+HOMEPAGE="
+	https://github.com/astral-sh/uv/
+	https://pypi.org/project/uv/
+"
+# pypi sdist misses scripts/, needed for tests
+SRC_URI="
+	https://github.com/astral-sh/uv/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+	${CARGO_CRATE_URIS}
+"
+if [[ ${PKGBUMPING} != ${PVR} ]]; then
+	SRC_URI+="
+		https://dev.gentoo.org/~mgorny/dist/uv-${CRATE_PV}-crates.tar.xz
+	"
+fi
+
+# most of the code
+LICENSE="|| ( Apache-2.0 MIT )"
+# crates/pep508-rs is || ( Apache-2.0 BSD-2 ) which is covered below
+# Dependent crate licenses
+LICENSE+="
+	0BSD Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD ISC MIT
+	MPL-2.0 Unicode-3.0 Unicode-DFS-2016 ZLIB
+"
+# ring crate
+LICENSE+=" openssl"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="test"
+RESTRICT="test"
+PROPERTIES="test_network"
+
+DEPEND="
+	app-arch/bzip2:=
+	app-arch/xz-utils:=
+	app-arch/zstd:=
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		dev-lang/python:3.8
+		dev-lang/python:3.9
+		dev-lang/python:3.10
+		dev-lang/python:3.11
+		dev-lang/python:3.12
+		!!~dev-python/uv-0.5.0
+	)
+"
+
+QA_FLAGS_IGNORED="usr/bin/.*"
+
+check_space() {
+	local CHECKREQS_DISK_BUILD=3G
+	use debug && CHECKREQS_DISK_BUILD=9G
+	check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+	check_space
+}
+
+pkg_setup() {
+	check_space
+	rust_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	# enable system libraries where supported
+	export ZSTD_SYS_USE_PKG_CONFIG=1
+	# TODO: unbundle libz-ng-sys, tikv-jemalloc-sys?
+
+	# remove unbundled sources, just in case
+	find "${ECARGO_VENDOR}"/{bzip2,lzma,zstd}-sys-*/ -name '*.c' -delete || die
+
+	# bzip2-sys requires a pkg-config file
+	# https://github.com/alexcrichton/bzip2-rs/issues/104
+	mkdir "${T}/pkg-config" || die
+	export PKG_CONFIG_PATH=${T}/pkg-config${PKG_CONFIG_PATH+:${PKG_CONFIG_PATH}}
+	cat >> "${T}/pkg-config/bzip2.pc" <<-EOF || die
+		Name: bzip2
+		Version: 9999
+		Description:
+		Libs: -lbz2
+	EOF
+}
+
+src_configure() {
+	local myfeatures=(
+		git
+		pypi
+		python
+	)
+
+	cargo_src_configure --no-default-features
+}
+
+src_compile() {
+	cd crates/uv || die
+	cargo_src_compile
+}
+
+src_test() {
+	# work around https://github.com/astral-sh/uv/issues/4376
+	local -x PATH=${BROOT}/usr/lib/python-exec/python3.12:${PATH}
+	local -x COLUMNS=100
+	local -x PYTHONDONTWRITEBYTECODE=
+	# fix tests failing because of our config
+	local -x XDG_CONFIG_DIRS=${T}
+
+	cd crates/uv || die
+	cargo_src_test --no-fail-fast
+}
+
+src_install() {
+	cd crates/uv || die
+	cargo_src_install
+
+	insinto /etc/xdg/uv
+	newins - uv.toml <<-EOF || die
+		# These defaults match Fedora, see:
+		# https://src.fedoraproject.org/rpms/uv/pull-request/18
+
+		# By default ("automatic"), uv downloads missing Python versions
+		# automatically and keeps them in the user's home directory.
+		# Disable that to make downloading opt-in, and especially
+		# to avoid unnecessarily fetching custom Python when the distro
+		# package would be preferable.  Python builds can still be
+		# downloaded manually via "uv python install".
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-downloads
+		python-downloads = "manual"
+
+		# By default ("managed"), uv always prefers self-installed
+		# Python versions over the system Python, independently
+		# of versions.  Since we generally expect users to use that
+		# to install old Python versions not in ::gentoo anymore,
+		# this effectively means that uv would end up preferring very
+		# old Python versions over the newer ones that are provided
+		# by the system.  Default to using the system versions to avoid
+		# this counter-intuitive behavior.
+		#
+		# https://docs.astral.sh/uv/reference/settings/#python-preference
+		python-preference = "system"
+	EOF
+}
diff --git a/dev-python/xcffib/Manifest b/dev-python/xcffib/Manifest
index 87c165427006..2eb2d91a948d 100644
--- a/dev-python/xcffib/Manifest
+++ b/dev-python/xcffib/Manifest
@@ -1,2 +1,3 @@
 DIST xcffib-1.5.0.tar.gz 89544 BLAKE2B cb3820a53eb7694078e5dbb175951b6dbdc445c06f397898e52319fd8a7633f2d8115f0d096a14b2b3de0c7b07918343d077705814574ff41de2bf06a12812c0 SHA512 aaa426b57d0d8dc45cb6a2036c862af6308fb5781667b8dba3f5ff399fe5e15912860d0bb696ac09f1efd4ffbbdaf7f555ef76039bd660f36f5c6179535b654f
 DIST xcffib-1.6.0.tar.gz 101378 BLAKE2B 75b4e64f125d0948fc438202b81d0808acd988d363216382f42611e7f821f4df2cecd9464edfc0e89cacd4237d82fc0d0276a357f5625dc03811b1f9c0951a0d SHA512 53fbde4a61f061a460d8a33c70ce4189c7ea5ff30777cee0017f42fcee9d7e2954d48906d764feabbb0506be96a40350579043e9cea04f9886ff1e8f35ed3f9c
+DIST xcffib-1.6.2.tar.gz 101368 BLAKE2B a4768fd7d5da875c04a45beccd8ad8bcdc2459dd9a5b3b19fe40813376262a025c04af80d75927c26c2fb26e1a5fefb29e0ff406aae206ac0edab546535e40cf SHA512 f3d3c751c2307025b2f3b3cb523a31fe4f0560af428e2705d06fc1ce7980d36a5568ad1e73c9acde065347210d754c0f30718cff28fb823f09c65025c0ecfc4a
diff --git a/dev-python/xcffib/xcffib-1.6.2.ebuild b/dev-python/xcffib/xcffib-1.6.2.ebuild
new file mode 100644
index 000000000000..252378486a9e
--- /dev/null
+++ b/dev-python/xcffib/xcffib-1.6.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A drop in replacement for xpyb, an XCB python binding"
+HOMEPAGE="
+	https://github.com/tych0/xcffib/
+	https://pypi.org/project/xcffib/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+DEPEND="
+	x11-libs/libxcb
+"
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/cffi-1.1:=[${PYTHON_USEDEP}]
+	' 'python*')
+	${DEPEND}
+"
+BDEPEND="
+	test? (
+		x11-base/xorg-server[xvfb]
+		x11-apps/xeyes
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	rm -rf xcffib || die
+	epytest
+}
diff --git a/dev-python/zeroconf/Manifest b/dev-python/zeroconf/Manifest
index 40b30d38ded3..cb1bd240a327 100644
--- a/dev-python/zeroconf/Manifest
+++ b/dev-python/zeroconf/Manifest
@@ -1 +1,2 @@
 DIST zeroconf-0.136.2.tar.gz 238720 BLAKE2B c47bd38a75f01c1e4268c6567a13e664638c05efa1a45ff1593b3d1347e369acd7a284580a02d34f398710f5faf319150c9eca151667dbb6a184bad35f24d4ce SHA512 30e352cfa2c3b7e7c3b9e38d6d1db0471d1f2c7dcd6785b0aab63a1027da21e966565803d4b2bfde6a89d4362039165f19b5c179117128a992f4960af2ac031d
+DIST zeroconf-0.137.2.tar.gz 237962 BLAKE2B 9ff84381cbd465a49fffeb18e671e8ab55f1c0d0e44f96312177d5a6372c6558e2175846d0cbd96c8e8b8ccd449e56ce614078e0ae22eeed8458b8a421f97192 SHA512 a4ed7146016a68bbc077cc1c61e9299d0f7d636b96da0d3dc9a4d161f709b429d7d44948435a0ed1151e280c173093dd1aaeacf4370958fd2c1b30337e3216af
diff --git a/dev-python/zeroconf/zeroconf-0.137.2.ebuild b/dev-python/zeroconf/zeroconf-0.137.2.ebuild
new file mode 100644
index 000000000000..4922d99649a2
--- /dev/null
+++ b/dev-python/zeroconf/zeroconf-0.137.2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{9,10,11,12,13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
+HOMEPAGE="
+	https://github.com/python-zeroconf/python-zeroconf/
+	https://pypi.org/project/zeroconf/
+"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND="
+	>=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/async-timeout-3.0.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+# the build system uses custom build script that uses distutils to build
+# C extensions, sigh
+BDEPEND="
+	>=dev-python/cython-3.0.8[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.6.3[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+python_test() {
+	local -x SKIP_IPV6=1
+	local EPYTEST_DESELECT=(
+		# network
+		tests/test_core.py::Framework::test_close_multiple_times
+		tests/test_core.py::Framework::test_launch_and_close
+		tests/test_core.py::Framework::test_launch_and_close_context_manager
+
+		# fragile to timeouts (?)
+		tests/services/test_browser.py::test_service_browser_expire_callbacks
+		tests/utils/test_asyncio.py::test_run_coro_with_timeout
+	)
+	local EPYTEST_IGNORE=(
+		tests/benchmarks
+	)
+
+	epytest -o addopts=
+}