Adding metadata

12 files changed, 251 insertions, 0 deletions

diff --git a/dev-python/google-api-python-client/Manifest b/dev-python/google-api-python-client/Manifest
index e10403d58cff..cf2236d3adeb 100644
--- a/dev-python/google-api-python-client/Manifest
+++ b/dev-python/google-api-python-client/Manifest
@@ -1,4 +1,5 @@
 DIST google-api-python-client-2.10.0.tar.gz 25252980 BLAKE2B 25932dec798518217eb724b3514de6f45e57543703396516f3d1a4599f40cb258893d2b2c7e706ef341a6217459a08ebfdf61e2d16949bf8831aed2f79fa80c0 SHA512 acc6ff1a6cad0d568e3af2c7fa4ac5fc3f908adcda1bc846aebc473cdf9f63b873fdf3182c44c3afe50a1f26a645be21b7b33335e67afb09210c001ba22365ad
+DIST google-api-python-client-2.11.0.tar.gz 25408815 BLAKE2B 9bc7d0163961f5b6341fcb43f41a91dfe12702254047ac2b418ce89dad4f8f40400a7df1fff5ce9d73a05c5249b7242a4d642b866b97a34140826901f74f9d6e SHA512 6d31e0ed926f87f12400b1ec244f8e193d6559c58d6775c34ef5747af3ba633e76e8a883983438e84c6d31fe81ea57ac522f924270b80993cc6396cb6f3ae60e
 DIST google-api-python-client-2.4.0.tar.gz 24853833 BLAKE2B 4ed2083a9bb8b4f8fe31ab5dbd7875c0c36c972cdb0f71a59565fe4eb23ff1ef0a40794acd7af9646c1ee3904fbab3caaeb2700a3660b66d3069d2bc4f811e76 SHA512 db545850b9d2746e3bcf7b4a2f12b0d4827bd68f44d5627fd80d39bff2ca3303c8d520f72ee17637fe700bc935548706ce885ff0d7fe737ae157668e0314fbc6
 DIST google-api-python-client-2.7.0.tar.gz 25488451 BLAKE2B a8a761944fed3970ae0cf53b2cb926a6670ac37323c39085a5f7fb4f354451292fca4bbb2c34a72d086dfa961b74a72f66319f6bbc2505ef70f5c94aff3f7a0e SHA512 531e919cc9d0cffc49b31d881a6ee3adb2d9cc166813b5884c300e9a3b63b28c9c269a0d1efe47961fa61f79ec5adb8a12e2208b644fd62ed4baa66c56d219ba
 DIST google-api-python-client-2.8.0.tar.gz 25286774 BLAKE2B b21aebda062984b9eb8f2f5c563016f0f8f663883dc8ddb913053ff3df32c652c6a83f924f3e19136e5edec085e12c43cc584bc9898630122c77a219810033bc SHA512 cc3c55438b2f5835b52d17d04a749919c4865991ff78cf95920d0941a55e1493eae502a13f6565cfe1db799ce9950659e8baaa690bada058d711309861c8d07e
diff --git a/dev-python/google-api-python-client/google-api-python-client-2.11.0.ebuild b/dev-python/google-api-python-client/google-api-python-client-2.11.0.ebuild
new file mode 100644
index 000000000000..ec59b155e2f7
--- /dev/null
+++ b/dev-python/google-api-python-client/google-api-python-client-2.11.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Google API Client for Python"
+HOMEPAGE="https://github.com/googleapis/google-api-python-client"
+SRC_URI="https://github.com/googleapis/google-api-python-client/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/httplib2-0.15[${PYTHON_USEDEP}]
+	<dev-python/httplib2-1[${PYTHON_USEDEP}]
+	dev-python/google-api-core[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.16.0[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-httplib2-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+	<dev-python/uritemplate-4[${PYTHON_USEDEP}]
+	>=dev-python/six-1.13.0[${PYTHON_USEDEP}]
+	<dev-python/six-2[${PYTHON_USEDEP}]
+	"
+BDEPEND="
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/oauth2client[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/unittest2[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests --install pytest
+
+python_test() {
+	local deselect=(
+		# require Internet access (and credentials)
+		tests/test_discovery.py::DiscoveryErrors::test_credentials_and_credentials_file_mutually_exclusive
+		tests/test_discovery.py::DiscoveryFromDocument::test_api_endpoint_override_from_client_options_mapping_object
+	)
+
+	distutils_install_for_testing
+	epytest ${deselect[@]/#/--deselect }
+}
diff --git a/dev-python/pkgconfig/files/pkgconfig-1.5.4-brittle-tests.patch b/dev-python/pkgconfig/files/pkgconfig-1.5.4-brittle-tests.patch
new file mode 100644
index 000000000000..05ba21f22acc
--- /dev/null
+++ b/dev-python/pkgconfig/files/pkgconfig-1.5.4-brittle-tests.patch
@@ -0,0 +1,14 @@
+--- a/test_pkgconfig.py
++++ b/test_pkgconfig.py
+@@ -138,9 +138,9 @@
+ def test_configure_extension():
+     ext = Extension('foo', ['foo.c'])
+     pkgconfig.configure_extension(ext, 'fake-gtk+-3.0 fake-python')
+-    assert ext.extra_compile_args == [
++    assert sorted(ext.extra_compile_args) == [
+          '-DGSEAL_ENABLE', '-I/usr/include/gtk-3.0','-I/usr/include/python2.7']
+-    assert ext.extra_link_args == [
++    assert sorted(ext.extra_link_args) == [
+         '-L/usr/lib_gtk_foo', '-L/usr/lib_python_foo', '-lgtk-3', '-lpython2.7']
+ 
+ 
diff --git a/dev-python/pkgconfig/pkgconfig-1.5.4.ebuild b/dev-python/pkgconfig/pkgconfig-1.5.4.ebuild
index 5cabb0c9e816..874b7006a92b 100644
--- a/dev-python/pkgconfig/pkgconfig-1.5.4.ebuild
+++ b/dev-python/pkgconfig/pkgconfig-1.5.4.ebuild
@@ -18,3 +18,5 @@ KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
 RDEPEND="virtual/pkgconfig"
 
 distutils_enable_tests pytest
+
+PATCHES=( "${FILESDIR}"/${P}-brittle-tests.patch )
diff --git a/dev-python/pylint/Manifest b/dev-python/pylint/Manifest
index 95131704246a..54ff4f787a30 100644
--- a/dev-python/pylint/Manifest
+++ b/dev-python/pylint/Manifest
@@ -1 +1,2 @@
 DIST pylint-2.8.2.gh.tar.gz 734667 BLAKE2B 1525273298f39163de4db7946a749768cb9bcf7e11f89791944ccb5fb8d0918eedfc80d5e559d33934d468dd5781d4cb4921b9407daf2842613a8e3ba7d134e0 SHA512 7023603668f540ecc0b35f3289377855c4c0df01e04a9af255f5c8031f568f6b76508bb3a7f0aba8e76a86b63eae423908c30f47258d6dee46bb23320c952701
+DIST pylint-2.9.0.gh.tar.gz 768301 BLAKE2B a86ccb83d3155acee0165dc7b0095f5b7741c62e7b1f127349eef643cd1d0513ed2f5aaa89d78728806f03b08645ed1579aafb073d649e928d4c415e50dc8a49 SHA512 b524a3d3241702c1fc34ca9ee38815d02e7f4572d8ff3c132141ac7d9c7ff59f88995b92ccfcf18fd57e04be8f24571ef0ab99e6b4ce615f0f6957022d1d1467
diff --git a/dev-python/pylint/pylint-2.9.0.ebuild b/dev-python/pylint/pylint-2.9.0.ebuild
new file mode 100644
index 000000000000..c0e4a405d141
--- /dev/null
+++ b/dev-python/pylint/pylint-2.9.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Python code static checker"
+HOMEPAGE="https://www.logilab.org/project/pylint
+	https://pypi.org/project/pylint/
+	https://github.com/pycqa/pylint/"
+SRC_URI="
+	https://github.com/pycqa/pylint/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="examples"
+
+RDEPEND="
+	<dev-python/astroid-2.7[${PYTHON_USEDEP}]
+	>=dev-python/astroid-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/isort-4.2.5[${PYTHON_USEDEP}]
+	<dev-python/isort-6[${PYTHON_USEDEP}]
+	>=dev-python/mccabe-0.6[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7[${PYTHON_USEDEP}]
+	>=dev-python/toml-0.7.1[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.4.4-sphinx-theme.patch"
+)
+
+distutils_enable_sphinx doc --no-autodoc
+distutils_enable_tests pytest
+
+python_test() {
+	local skipped_tests=(
+		# No need to run the benchmarks
+		tests/benchmark/test_baseline_benchmarks.py
+		# Fails when graphviz is installed (?!)
+#		tests/test_import_graph.py::test_missing_graphviz
+		# TODO
+#		'tests/lint/unittest_expand_modules.py::test_expand_modules[files_or_modules1-expected1]'
+	)
+	# Specify the test directory explicitly to avoid import file mismatches
+	epytest tests ${skipped_tests[@]/#/--deselect }
+}
+
+python_install_all() {
+	if use examples ; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/qrcode/Manifest b/dev-python/qrcode/Manifest
index c3b31a21768b..f7a38d61cdb1 100644
--- a/dev-python/qrcode/Manifest
+++ b/dev-python/qrcode/Manifest
@@ -1 +1,2 @@
 DIST qrcode-6.1.tar.gz 29363 BLAKE2B 5f31035b6c548c710d0d8198428612fc52417be7af5b5f412a42d264cb6a3ba96de65651049390107cc77e886df2b139942266aba579896f05692177b394ea11 SHA512 4831553932442f5535cba15d5958a656b399112f0f379c28ad9b610c33d88ec6d0613dc7047a2315606e49f027bfd13a15a332ce86b80040d56e1114a0f62251
+DIST qrcode-7.0.tar.gz 34548 BLAKE2B 0a5f06b73f55ecc713aa34249acf5d58f71b29c90e5433411a9208124931bfcf101f016a6f1fbcbab0eddd3ffdef763cdc92fdf09565addaa86120a80d4d0c1f SHA512 2b96528582c1d80ba1bd27b5bb769d52e238bf5a3eda2fa23c4bef90778fa2d478c50a8f2b581d5b83373d778f346c410ae3475250029b878ff527edeae0f323
diff --git a/dev-python/qrcode/qrcode-7.0.ebuild b/dev-python/qrcode/qrcode-7.0.ebuild
new file mode 100644
index 000000000000..389083c86a81
--- /dev/null
+++ b/dev-python/qrcode/qrcode-7.0.ebuild
@@ -0,0 +1,28 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="QR Code generator on top of PIL"
+HOMEPAGE="https://pypi.org/project/qrcode/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+# optional deps:
+# - pillow and lxml for svg backend, set as hard deps
+RDEPEND="
+	dev-python/lxml[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]"
+
+distutils_enable_tests unittest
+
+src_install() {
+	distutils-r1_src_install
+	doman doc/qr.1
+}
diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index 92be7df584ce..3f2c9ad75777 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
 DIST rq-1.8.1.tar.gz 585211 BLAKE2B 17feb07cb376c5aef88a7aab6d716f58a19f62f19db6c6b0490b4f666981e40304c6a23c88669a0aef9b75a39ce8cb85a9b10a2d42e83e646cdcb6282167d8f9 SHA512 b9df7b4e894a5da693827ff720be3068336d82d2f17928faf5ae6133b042ac2f98a3d673bb2ed86c9351479669e9ef0e4fffcb1dba9b8853f6f793db4a4678f8
+DIST rq-1.9.0.tar.gz 592217 BLAKE2B 831fbc7a3fe23ead59041e2556d37e4aa885a21bffa9aeeb0765382e84b56a2ee6d34a864cb03a9a12274c8ac80b714f10a7752d0bae7a79b8e2e7149be4aea7 SHA512 a2ec7b05fe1dda983cfb30182401c6e5367c54b7649ddcb1d3c6d0f0a5f6583665b39ed7c1cb6bc37d067926f089e3fd80ea7558856233edc1bca8234aa728aa
diff --git a/dev-python/rq/rq-1.9.0.ebuild b/dev-python/rq/rq-1.9.0.ebuild
new file mode 100644
index 000000000000..f884741ddb12
--- /dev/null
+++ b/dev-python/rq/rq-1.9.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="https://python-rq.org https://github.com/rq/rq"
+SRC_URI="https://github.com/rq/rq/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	>=dev-python/redis-py-3.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/sentry-sdk[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests --install pytest
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	elog "Spawning Redis"
+	elog "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
diff --git a/dev-python/zeroconf/Manifest b/dev-python/zeroconf/Manifest
index 3c80995934d8..b55e551df3db 100644
--- a/dev-python/zeroconf/Manifest
+++ b/dev-python/zeroconf/Manifest
@@ -1 +1,2 @@
 DIST python-zeroconf-0.30.0.gh.tar.gz 64301 BLAKE2B ea0d5e36f3f012f217cbd4eeff0a9cd366496e2f64b06112ee3629ad016c8e28877f62358d5b5fd27387cfe474e488e99a9ad8ca1802f6d23612f99310243c57 SHA512 1f3165500a07525ef182bb60c1804fe2002a33a9f800470bdb32bdfd44a1b8f466a818a4390537674952159e5c0e257cf9e4ca570b1a9936e1cf8be294be6311
+DIST python-zeroconf-0.32.0.gh.tar.gz 115276 BLAKE2B 7084c02f989ebc6db6686b82ce3212158595b87e00567e4857e84790a30a2fa6f688288769d1eb118da485a6755da1ef404765070d26905d10ab45b1d95ca849 SHA512 6a612b39be85e673cffc560ea5bcc16facc5a16a370ff6edb1d4f7ff978a01d6ba249a9b313caca3b3ed0c6463a4914a98063eb89f28268cec1c9a2faa4db611
diff --git a/dev-python/zeroconf/zeroconf-0.32.0.ebuild b/dev-python/zeroconf/zeroconf-0.32.0.ebuild
new file mode 100644
index 000000000000..270b97996646
--- /dev/null
+++ b/dev-python/zeroconf/zeroconf-0.32.0.ebuild
@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+MY_P=python-zeroconf-${PV}
+DESCRIPTION="Pure Python Multicast DNS Service Discovery Library (Bonjour/Avahi compatible)"
+HOMEPAGE="
+	https://github.com/jstasiak/python-zeroconf/
+	https://pypi.org/project/zeroconf/"
+SRC_URI="
+	https://github.com/jstasiak/python-zeroconf/archive/${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+
+RDEPEND=">=dev-python/ifaddr-0.1.7[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local excludes=(
+		# network
+		tests/test_core.py::Framework::test_close_multiple_times
+		tests/test_core.py::Framework::test_launch_and_close
+		tests/test_core.py::Framework::test_launch_and_close_context_manager
+		tests/test_core.py::Framework::test_launch_and_close_v4_v6
+		tests/test_core.py::Framework::test_launch_and_close_v6_only
+		tests/services/test_types.py::ServiceTypesQuery::test_integration_with_listener_ipv6
+	)
+
+	epytest ${excludes[@]/#/--deselect }
+}